Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::fallback "$FindBin::Bin/external/perl/MODULES.txt";
  21 use OpenSSL::Glob;
  22 use OpenSSL::Template;
  23
  24 # see INSTALL for instructions.
  25
  26 my $orig_death_handler = $SIG{__DIE__};
  27 $SIG{__DIE__} = \&death_handler;
  28
  29 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  30
  31 # Options:
  32 #
  33 # --config      add the given configuration file, which will be read after
  34 #               any "Configurations*" files that are found in the same
  35 #               directory as this script.
  36 # --prefix      prefix for the OpenSSL installation, which includes the
  37 #               directories bin, lib, include, share/man, share/doc/openssl
  38 #               This becomes the value of INSTALLTOP in Makefile
  39 #               (Default: /usr/local)
  40 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  41 #               If it's a relative directory, it will be added on the directory
  42 #               given with --prefix.
  43 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  44 #               (Default: PREFIX/ssl)
  45 #
  46 # --cross-compile-prefix Add specified prefix to binutils components.
  47 #
  48 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  49 #               Do not compile support for interfaces deprecated as of the
  50 #               specified OpenSSL version.
  51 #
  52 # no-hw-xxx     do not compile support for specific crypto hardware.
  53 #               Generic OpenSSL-style methods relating to this support
  54 #               are always compiled but return NULL if the hardware
  55 #               support isn't compiled.
  56 # no-hw         do not compile support for any crypto hardware.
  57 # [no-]threads  [don't] try to create a library that is suitable for
  58 #               multithreaded applications (default is "threads" if we
  59 #               know how to do it)
  60 # [no-]shared   [don't] try to create shared libraries when supported.
  61 # [no-]pic      [don't] try to build position independent code when supported.
  62 #               If disabled, it also disables shared and dynamic-engine.
  63 # no-asm        do not use assembler
  64 # no-egd        do not compile support for the entropy-gathering daemon APIs
  65 # [no-]zlib     [don't] compile support for zlib compression.
  66 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  67 #               library and will be loaded in run-time by the OpenSSL library.
  68 # sctp          include SCTP support
  69 # no-uplink     Don't build support for UPLINK interface.
  70 # enable-weak-ssl-ciphers
  71 #               Enable weak ciphers that are disabled by default.
  72 # 386           generate 80386 code in assembly modules
  73 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  74 #               mentioned '386' option implies this one
  75 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  76 # -<xxx> +<xxx> All options which are unknown to the 'Configure' script are
  77 # /<xxx>        passed through to the compiler. Unix-style options beginning
  78 #               with a '-' or '+' are recognized, as well as Windows-style
  79 #               options beginning with a '/'. If the option contains arguments
  80 #               separated by spaces, then the URL-style notation %20 can be
  81 #               used for the space character in order to avoid having to quote
  82 #               the option. For example, -opt%20arg gets expanded to -opt arg.
  83 #               In fact, any ASCII character can be encoded as %xx using its
  84 #               hexadecimal encoding.
  85 # -static       while -static is also a pass-through compiler option (and
  86 #               as such is limited to environments where it's actually
  87 #               meaningful), it triggers a number configuration options,
  88 #               namely no-pic, no-shared and no-threads. It is
  89 #               argued that the only reason to produce statically linked
  90 #               binaries (and in context it means executables linked with
  91 #               -static flag, and not just executables linked with static
  92 #               libcrypto.a) is to eliminate dependency on specific run-time,
  93 #               a.k.a. libc version. The mentioned config options are meant
  94 #               to achieve just that. Unfortunately on Linux it's impossible
  95 #               to eliminate the dependency completely for openssl executable
  96 #               because of getaddrinfo and gethostbyname calls, which can
  97 #               invoke dynamically loadable library facility anyway to meet
  98 #               the lookup requests. For this reason on Linux statically
  99 #               linked openssl executable has rather debugging value than
 100 #               production quality.
 101 #
 102 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
 103 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
 104 # Following are set automatically by this script
 105 #
 106 # MD5_ASM       use some extra md5 assembler,
 107 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
 108 # RMD160_ASM    use some extra ripemd160 assembler,
 109 # SHA256_ASM    sha256_block is implemented in assembler
 110 # SHA512_ASM    sha512_block is implemented in assembler
 111 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 112
 113 # Minimum warning options... any contributions to OpenSSL should at least
 114 # get past these.  Note that we only use these with C compilers, not with
 115 # C++ compilers.
 116
 117 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 118 # -DPEDANTIC complements -pedantic and is meant to mask code that
 119 # is not strictly standard-compliant and/or implementation-specific,
 120 # e.g. inline assembly, disregards to alignment requirements, such
 121 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 122 # to be used even in sanitized builds, because sanitizer too is
 123 # supposed to and does take notice of non-standard behaviour. Then
 124 # -pedantic with pre-C9x compiler would also complain about 'long
 125 # long' not being supported. As 64-bit algorithms are common now,
 126 # it grew impossible to resolve this without sizeable additional
 127 # code, so we just tell compiler to be pedantic about everything
 128 # but 'long long' type.
 129
 130 my @gcc_devteam_warn = qw(
 131     -DDEBUG_UNUSED
 132     -DPEDANTIC -pedantic -Wno-long-long
 133     -Wall
 134     -Wextra
 135     -Wno-unused-parameter
 136     -Wno-missing-field-initializers
 137     -Wswitch
 138     -Wsign-compare
 139     -Wshadow
 140     -Wformat
 141     -Wtype-limits
 142     -Wundef
 143     -Werror
 144     -Wmissing-prototypes
 145     -Wstrict-prototypes
 146 );
 147
 148 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 149 # TODO(openssl-team): fix problems and investigate if (at least) the
 150 # following warnings can also be enabled:
 151 #       -Wcast-align
 152 #       -Wunreachable-code -- no, too ugly/compiler-specific
 153 #       -Wlanguage-extension-token -- no, we use asm()
 154 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 155 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 156 my @clang_devteam_warn = qw(
 157     -Wno-unknown-warning-option
 158     -Wswitch-default
 159     -Wno-parentheses-equality
 160     -Wno-language-extension-token
 161     -Wno-extended-offsetof
 162     -Wconditional-uninitialized
 163     -Wincompatible-pointer-types-discards-qualifiers
 164     -Wmissing-variable-declarations
 165 );
 166
 167 my @cl_devteam_warn = qw(
 168     /WX
 169 );
 170
 171 # This adds backtrace information to the memory leak info.  Is only used
 172 # when crypto-mdebug-backtrace is enabled.
 173 my $memleak_devteam_backtrace = "-rdynamic";
 174
 175 my $strict_warnings = 0;
 176
 177 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 178 # which would cover all BSD flavors. -pthread applies to them all,
 179 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 180 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 181 # which has to be accompanied by explicit -D_THREAD_SAFE and
 182 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 183 # seems to be sufficient?
 184 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 185
 186 #
 187 # API compatibility name to version number mapping.
 188 #
 189 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 190 my $apitable = {
 191     "3.0.0" => 3,
 192     "1.1.1" => 2,
 193     "1.1.0" => 2,
 194     "1.0.2" => 1,
 195     "1.0.1" => 1,
 196     "1.0.0" => 1,
 197     "0.9.8" => 0,
 198 };
 199
 200 our %table = ();
 201 our %config = ();
 202 our %withargs = ();
 203 our $now_printing;      # set to current entry's name in print_table_entry
 204                         # (todo: right thing would be to encapsulate name
 205                         # into %target [class] and make print_table_entry
 206                         # a method)
 207
 208 # Forward declarations ###############################################
 209
 210 # read_config(filename)
 211 #
 212 # Reads a configuration file and populates %table with the contents
 213 # (which the configuration file places in %targets).
 214 sub read_config;
 215
 216 # resolve_config(target)
 217 #
 218 # Resolves all the late evaluations, inheritances and so on for the
 219 # chosen target and any target it inherits from.
 220 sub resolve_config;
 221
 222
 223 # Information collection #############################################
 224
 225 # Unified build supports separate build dir
 226 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 227 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 228 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 229
 230 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 231
 232 $config{sourcedir} = abs2rel($srcdir);
 233 $config{builddir} = abs2rel($blddir);
 234
 235 # Collect reconfiguration information if needed
 236 my @argvcopy=@ARGV;
 237
 238 if (grep /^reconf(igure)?$/, @argvcopy) {
 239     die "reconfiguring with other arguments present isn't supported"
 240         if scalar @argvcopy > 1;
 241     if (-f "./configdata.pm") {
 242         my $file = "./configdata.pm";
 243         unless (my $return = do $file) {
 244             die "couldn't parse $file: $@" if $@;
 245             die "couldn't do $file: $!"    unless defined $return;
 246             die "couldn't run $file"       unless $return;
 247         }
 248
 249         @argvcopy = defined($configdata::config{perlargv}) ?
 250             @{$configdata::config{perlargv}} : ();
 251         die "Incorrect data to reconfigure, please do a normal configuration\n"
 252             if (grep(/^reconf/,@argvcopy));
 253         $config{perlenv} = $configdata::config{perlenv} // {};
 254     } else {
 255         die "Insufficient data to reconfigure, please do a normal configuration\n";
 256     }
 257 }
 258
 259 $config{perlargv} = [ @argvcopy ];
 260
 261 # Collect version numbers
 262 my %version = ();
 263
 264 collect_information(
 265     collect_from_file(catfile($srcdir,'VERSION')),
 266     qr/\s*(\w+)\s*=\s*(.*?)\s*$/ =>
 267         sub {
 268             # Only define it if there is a value at all
 269             $version{uc $1} = $2 if $2 ne '';
 270         },
 271     "OTHERWISE" =>
 272         sub { die "Something wrong with this line:\n$_\nin $srcdir/VERSION" },
 273     );
 274
 275 $config{major} = $version{MAJOR} // 'unknown';
 276 $config{minor} = $version{MINOR} // 'unknown';
 277 $config{patch} = $version{PATCH} // 'unknown';
 278 $config{prerelease} =
 279     defined $version{PRE_RELEASE_TAG} ? "-$version{PRE_RELEASE_TAG}" : '';
 280 $config{build_metadata} =
 281     defined $version{BUILD_METADATA} ? "+$version{BUILD_METADATA}" : '';
 282 $config{shlib_version} = $version{SHLIB_VERSION} // 'unknown';
 283 $config{release_date} = $version{RELEASE_DATE} // 'xx XXX xxxx';
 284
 285 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 286 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 287
 288 die "erroneous version information in VERSION: ",
 289     "$config{version}, $config{shlib_version}\n"
 290     unless (defined $version{MAJOR}
 291             && defined $version{MINOR}
 292             && defined $version{PATCH}
 293             && defined $version{SHLIB_VERSION});
 294
 295 # Collect target configurations
 296
 297 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 298 foreach (sort glob($pattern)) {
 299     &read_config($_);
 300 }
 301
 302 if (defined env($local_config_envname)) {
 303     if ($^O eq 'VMS') {
 304         # VMS environment variables are logical names,
 305         # which can be used as is
 306         $pattern = $local_config_envname . ':' . '*.conf';
 307     } else {
 308         $pattern = catfile(env($local_config_envname), '*.conf');
 309     }
 310
 311     foreach (sort glob($pattern)) {
 312         &read_config($_);
 313     }
 314 }
 315
 316 # Save away perl command information
 317 $config{perl_cmd} = $^X;
 318 $config{perl_version} = $Config{version};
 319 $config{perl_archname} = $Config{archname};
 320
 321 $config{prefix}="";
 322 $config{openssldir}="";
 323 $config{processor}="";
 324 $config{libdir}="";
 325 my $auto_threads=1;    # enable threads automatically? true by default
 326 my $default_ranlib;
 327
 328 # Known TLS and DTLS protocols
 329 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 330 my @dtls = qw(dtls1 dtls1_2);
 331
 332 # Explicitly known options that are possible to disable.  They can
 333 # be regexps, and will be used like this: /^no-${option}$/
 334 # For developers: keep it sorted alphabetically
 335
 336 my @disablables = (
 337     "ktls",
 338     "afalgeng",
 339     "aria",
 340     "asan",
 341     "asm",
 342     "async",
 343     "autoalginit",
 344     "autoerrinit",
 345     "autoload-config",
 346     "bf",
 347     "blake2",
 348     "buildtest-c++",
 349     "camellia",
 350     "capieng",
 351     "cast",
 352     "chacha",
 353     "cmac",
 354     "cmp",
 355     "cms",
 356     "comp",
 357     "crypto-mdebug",
 358     "crypto-mdebug-backtrace",
 359     "ct",
 360     "deprecated",
 361     "des",
 362     "devcryptoeng",
 363     "dgram",
 364     "dh",
 365     "dsa",
 366     "dso",
 367     "dtls",
 368     "dynamic-engine",
 369     "ec",
 370     "ec2m",
 371     "ecdh",
 372     "ecdsa",
 373     "ec_nistp_64_gcc_128",
 374     "egd",
 375     "engine",
 376     "err",
 377     "external-tests",
 378     "filenames",
 379     "fips",
 380     "fuzz-libfuzzer",
 381     "fuzz-afl",
 382     "gost",
 383     "idea",
 384     "legacy",
 385     "makedepend",
 386     "md2",
 387     "md4",
 388     "mdc2",
 389     "module",
 390     "msan",
 391     "multiblock",
 392     "nextprotoneg",
 393     "pinshared",
 394     "ocb",
 395     "ocsp",
 396     "padlockeng",
 397     "pic",
 398     "poly1305",
 399     "posix-io",
 400     "psk",
 401     "rc2",
 402     "rc4",
 403     "rc5",
 404     "rdrand",
 405     "rfc3779",
 406     "rmd160",
 407     "scrypt",
 408     "sctp",
 409     "seed",
 410     "shared",
 411     "siphash",
 412     "siv",
 413     "sm2",
 414     "sm3",
 415     "sm4",
 416     "sock",
 417     "srp",
 418     "srtp",
 419     "sse2",
 420     "ssl",
 421     "ssl-trace",
 422     "static-engine",
 423     "stdio",
 424     "tests",
 425     "threads",
 426     "tls",
 427     "trace",
 428     "ts",
 429     "ubsan",
 430     "ui-console",
 431     "unit-test",
 432     "uplink",
 433     "whirlpool",
 434     "weak-ssl-ciphers",
 435     "zlib",
 436     "zlib-dynamic",
 437     );
 438 foreach my $proto ((@tls, @dtls))
 439         {
 440         push(@disablables, $proto);
 441         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 442         }
 443
 444 # Internal disablables, for aliasing purposes.  They serve no special
 445 # purpose here, but allow scripts to get to know them through configdata.pm,
 446 # where these are merged with @disablables.
 447 # The actual aliasing mechanism is done via %disable_cascades
 448 my @disablables_int = qw(
 449     crmf
 450     );
 451
 452 my %deprecated_disablables = (
 453     "ssl2" => undef,
 454     "buf-freelists" => undef,
 455     "hw" => "hw",               # causes cascade, but no macro
 456     "hw-padlock" => "padlockeng",
 457     "ripemd" => "rmd160",
 458     "ui" => "ui-console",
 459     "heartbeats" => undef,
 460     );
 461
 462 # All of the following are disabled by default:
 463
 464 our %disabled = ( # "what"         => "comment"
 465                   "asan"                => "default",
 466                   "buildtest-c++"       => "default",
 467                   "crypto-mdebug"       => "default",
 468                   "crypto-mdebug-backtrace" => "default",
 469                   "devcryptoeng"        => "default",
 470                   "ec_nistp_64_gcc_128" => "default",
 471                   "egd"                 => "default",
 472                   "external-tests"      => "default",
 473                   "fuzz-libfuzzer"      => "default",
 474                   "fuzz-afl"            => "default",
 475                   "md2"                 => "default",
 476                   "msan"                => "default",
 477                   "rc5"                 => "default",
 478                   "sctp"                => "default",
 479                   "ssl-trace"           => "default",
 480                   "ssl3"                => "default",
 481                   "ssl3-method"         => "default",
 482                   "trace"               => "default",
 483                   "ubsan"               => "default",
 484                   "unit-test"           => "default",
 485                   "weak-ssl-ciphers"    => "default",
 486                   "zlib"                => "default",
 487                   "zlib-dynamic"        => "default",
 488                   "ktls"                => "default",
 489                 );
 490
 491 # Note: => pair form used for aesthetics, not to truly make a hash table
 492 my @disable_cascades = (
 493     # "what"            => [ "cascade", ... ]
 494     sub { $config{processor} eq "386" }
 495                         => [ "sse2" ],
 496     "ssl"               => [ "ssl3" ],
 497     "ssl3-method"       => [ "ssl3" ],
 498     "zlib"              => [ "zlib-dynamic" ],
 499     "des"               => [ "mdc2" ],
 500     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 501     sub { $disabled{"ec"} && $disabled{"dh"} }
 502                         => [ "tls1_3" ],
 503     "dgram"             => [ "dtls", "sctp" ],
 504     "sock"              => [ "dgram" ],
 505     "dtls"              => [ @dtls ],
 506     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 507                         => [ "dtls" ],
 508
 509     "tls"               => [ @tls ],
 510     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 511                         => [ "tls" ],
 512
 513     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 514
 515     # If no modules, then no dynamic engines either
 516     "module"            => [ "dynamic-engine" ],
 517
 518     # Without shared libraries, dynamic engines aren't possible.
 519     # This is due to them having to link with libcrypto and register features
 520     # using the ENGINE functionality, and since that relies on global tables,
 521     # those *have* to be exacty the same as the ones accessed from the app,
 522     # which cannot be guaranteed if shared libraries aren't present.
 523     # (note that even with shared libraries, both the app and dynamic engines
 524     # must be linked with the same library)
 525     "shared"            => [ "dynamic-engine", "uplink" ],
 526     "dso"               => [ "dynamic-engine", "module" ],
 527     # Other modules don't necessarily have to link with libcrypto, so shared
 528     # libraries do not have to be a condition to produce those.
 529
 530     # Without position independent code, there can be no shared libraries
 531     # or modules.
 532     "pic"               => [ "shared", "module" ],
 533
 534     "module"            => [ "fips" ],
 535
 536     "engine"            => [ grep /eng$/, @disablables ],
 537     "hw"                => [ "padlockeng" ],
 538
 539     # no-autoalginit is only useful when building non-shared
 540     "autoalginit"       => [ "shared", "apps" ],
 541
 542     "stdio"             => [ "apps", "capieng", "egd" ],
 543     "apps"              => [ "tests" ],
 544     "tests"             => [ "external-tests" ],
 545     "comp"              => [ "zlib" ],
 546     "sm3"               => [ "sm2" ],
 547     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 548
 549     sub { !$disabled{"msan"} } => [ "asm" ],
 550
 551     sub { $disabled{cmac}; } => [ "siv" ],
 552     "legacy"                 => [ "md2" ],
 553
 554     "cmp"               => [ "crmf" ],
 555     );
 556
 557 # Avoid protocol support holes.  Also disable all versions below N, if version
 558 # N is disabled while N+1 is enabled.
 559 #
 560 my @list = (reverse @tls);
 561 while ((my $first, my $second) = (shift @list, shift @list)) {
 562     last unless @list;
 563     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 564                               => [ @list ] );
 565     unshift @list, $second;
 566 }
 567 my @list = (reverse @dtls);
 568 while ((my $first, my $second) = (shift @list, shift @list)) {
 569     last unless @list;
 570     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 571                               => [ @list ] );
 572     unshift @list, $second;
 573 }
 574
 575 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 576 # To remove something from %disabled, use "enable-foo".
 577 # For symmetry, "disable-foo" is a synonym for "no-foo".
 578
 579 &usage if ($#ARGV < 0);
 580
 581 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 582 # platform specific list separators.  Users from those platforms should
 583 # recognise those separators from how you set up the PATH to find executables.
 584 # The default is the Unix like separator, :, but as an exception, we also
 585 # support the space as separator.
 586 my $list_separator_re =
 587     { VMS           => qr/(?<!\^),/,
 588       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 589 # All the "make variables" we support
 590 # Some get pre-populated for the sake of backward compatibility
 591 # (we supported those before the change to "make variable" support.
 592 my %user = (
 593     AR          => env('AR'),
 594     ARFLAGS     => [],
 595     AS          => undef,
 596     ASFLAGS     => [],
 597     CC          => env('CC'),
 598     CFLAGS      => [ env('CFLAGS') || () ],
 599     CXX         => env('CXX'),
 600     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 601     CPP         => undef,
 602     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 603     CPPDEFINES  => [],  # Alternative for -D
 604     CPPINCLUDES => [],  # Alternative for -I
 605     CROSS_COMPILE => env('CROSS_COMPILE'),
 606     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 607     LD          => undef,
 608     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 609     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 610     MT          => undef,
 611     MTFLAGS     => [],
 612     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 613     RANLIB      => env('RANLIB'),
 614     RC          => env('RC') || env('WINDRES'),
 615     RCFLAGS     => [ env('RCFLAGS') || () ],
 616     RM          => undef,
 617    );
 618 # Info about what "make variables" may be prefixed with the cross compiler
 619 # prefix.  This should NEVER mention any such variable with a list for value.
 620 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 621 # The same but for flags given as Configure options.  These are *additional*
 622 # input, as opposed to the VAR=string option that override the corresponding
 623 # config target attributes
 624 my %useradd = (
 625     CPPDEFINES  => [],
 626     CPPINCLUDES => [],
 627     CPPFLAGS    => [],
 628     CFLAGS      => [],
 629     CXXFLAGS    => [],
 630     LDFLAGS     => [],
 631     LDLIBS      => [],
 632     RCFLAGS     => [],
 633    );
 634
 635 my %user_synonyms = (
 636     HASHBANGPERL=> 'PERL',
 637     RC          => 'WINDRES',
 638    );
 639
 640 # Some target attributes have been renamed, this is the translation table
 641 my %target_attr_translate =(
 642     ar          => 'AR',
 643     as          => 'AS',
 644     cc          => 'CC',
 645     cxx         => 'CXX',
 646     cpp         => 'CPP',
 647     hashbangperl => 'HASHBANGPERL',
 648     ld          => 'LD',
 649     mt          => 'MT',
 650     ranlib      => 'RANLIB',
 651     rc          => 'RC',
 652     rm          => 'RM',
 653    );
 654
 655 # Initialisers coming from 'config' scripts
 656 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 657 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 658 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 659 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 660 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 661 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 662 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 663
 664 $config{openssl_api_defines}=[];
 665 $config{openssl_sys_defines}=[];
 666 $config{openssl_feature_defines}=[];
 667 $config{options}="";
 668 $config{build_type} = "release";
 669 my $target="";
 670
 671 my %cmdvars = ();               # Stores FOO='blah' type arguments
 672 my %unsupported_options = ();
 673 my %deprecated_options = ();
 674 # If you change this, update apps/version.c
 675 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 676 my @seed_sources = ();
 677 while (@argvcopy)
 678         {
 679         $_ = shift @argvcopy;
 680
 681         # Support env variable assignments among the options
 682         if (m|^(\w+)=(.+)?$|)
 683                 {
 684                 $cmdvars{$1} = $2;
 685                 # Every time a variable is given as a configuration argument,
 686                 # it acts as a reset if the variable.
 687                 if (exists $user{$1})
 688                         {
 689                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 690                         }
 691                 #if (exists $useradd{$1})
 692                 #       {
 693                 #       $useradd{$1} = [];
 694                 #       }
 695                 next;
 696                 }
 697
 698         # VMS is a case insensitive environment, and depending on settings
 699         # out of our control, we may receive options uppercased.  Let's
 700         # downcase at least the part before any equal sign.
 701         if ($^O eq "VMS")
 702                 {
 703                 s/^([^=]*)/lc($1)/e;
 704                 }
 705
 706         # some people just can't read the instructions, clang people have to...
 707         s/^-no-(?!integrated-as)/no-/;
 708
 709         # rewrite some options in "enable-..." form
 710         s /^-?-?shared$/enable-shared/;
 711         s /^sctp$/enable-sctp/;
 712         s /^threads$/enable-threads/;
 713         s /^zlib$/enable-zlib/;
 714         s /^zlib-dynamic$/enable-zlib-dynamic/;
 715
 716         if (/^(no|disable|enable)-(.+)$/)
 717                 {
 718                 my $word = $2;
 719                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 720                         && !exists $deprecated_disablables{$word}
 721                         && !grep { $word eq $_ } @disablables)
 722                         {
 723                         $unsupported_options{$_} = 1;
 724                         next;
 725                         }
 726                 }
 727         if (/^no-(.+)$/ || /^disable-(.+)$/)
 728                 {
 729                 foreach my $proto ((@tls, @dtls))
 730                         {
 731                         if ($1 eq "$proto-method")
 732                                 {
 733                                 $disabled{"$proto"} = "option($proto-method)";
 734                                 last;
 735                                 }
 736                         }
 737                 if ($1 eq "dtls")
 738                         {
 739                         foreach my $proto (@dtls)
 740                                 {
 741                                 $disabled{$proto} = "option(dtls)";
 742                                 }
 743                         $disabled{"dtls"} = "option(dtls)";
 744                         }
 745                 elsif ($1 eq "ssl")
 746                         {
 747                         # Last one of its kind
 748                         $disabled{"ssl3"} = "option(ssl)";
 749                         }
 750                 elsif ($1 eq "tls")
 751                         {
 752                         # XXX: Tests will fail if all SSL/TLS
 753                         # protocols are disabled.
 754                         foreach my $proto (@tls)
 755                                 {
 756                                 $disabled{$proto} = "option(tls)";
 757                                 }
 758                         }
 759                 elsif ($1 eq "static-engine")
 760                         {
 761                         delete $disabled{"dynamic-engine"};
 762                         }
 763                 elsif ($1 eq "dynamic-engine")
 764                         {
 765                         $disabled{"dynamic-engine"} = "option";
 766                         }
 767                 elsif (exists $deprecated_disablables{$1})
 768                         {
 769                         $deprecated_options{$_} = 1;
 770                         if (defined $deprecated_disablables{$1})
 771                                 {
 772                                 $disabled{$deprecated_disablables{$1}} = "option";
 773                                 }
 774                         }
 775                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 776                         {
 777                         $deprecated_options{$_} = 1;
 778                         }
 779                 else
 780                         {
 781                         $disabled{$1} = "option";
 782                         }
 783                 # No longer an automatic choice
 784                 $auto_threads = 0 if ($1 eq "threads");
 785                 }
 786         elsif (/^enable-(.+)$/)
 787                 {
 788                 if ($1 eq "static-engine")
 789                         {
 790                         $disabled{"dynamic-engine"} = "option";
 791                         }
 792                 elsif ($1 eq "dynamic-engine")
 793                         {
 794                         delete $disabled{"dynamic-engine"};
 795                         }
 796                 elsif ($1 eq "zlib-dynamic")
 797                         {
 798                         delete $disabled{"zlib"};
 799                         }
 800                 my $algo = $1;
 801                 delete $disabled{$algo};
 802
 803                 # No longer an automatic choice
 804                 $auto_threads = 0 if ($1 eq "threads");
 805                 }
 806         elsif (/^--strict-warnings$/)
 807                 {
 808                 # Pretend that our strict flags is a C flag, and replace it
 809                 # with the proper flags later on
 810                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 811                 $strict_warnings=1;
 812                 }
 813         elsif (/^--debug$/)
 814                 {
 815                 $config{build_type} = "debug";
 816                 }
 817         elsif (/^--release$/)
 818                 {
 819                 $config{build_type} = "release";
 820                 }
 821         elsif (/^386$/)
 822                 { $config{processor}=386; }
 823         elsif (/^fips$/)
 824                 {
 825                 die "FIPS mode not supported\n";
 826                 }
 827         elsif (/^rsaref$/)
 828                 {
 829                 # No RSAref support any more since it's not needed.
 830                 # The check for the option is there so scripts aren't
 831                 # broken
 832                 }
 833         elsif (/^nofipscanistercheck$/)
 834                 {
 835                 die "FIPS mode not supported\n";
 836                 }
 837         elsif (m|^[-+/]|)
 838                 {
 839                 if (/^--prefix=(.*)$/)
 840                         {
 841                         $config{prefix}=$1;
 842                         die "Directory given with --prefix MUST be absolute\n"
 843                                 unless file_name_is_absolute($config{prefix});
 844                         }
 845                 elsif (/^--api=(.*)$/)
 846                         {
 847                         $config{api}=$1;
 848                         }
 849                 elsif (/^--libdir=(.*)$/)
 850                         {
 851                         $config{libdir}=$1;
 852                         }
 853                 elsif (/^--openssldir=(.*)$/)
 854                         {
 855                         $config{openssldir}=$1;
 856                         }
 857                 elsif (/^--with-zlib-lib=(.*)$/)
 858                         {
 859                         $withargs{zlib_lib}=$1;
 860                         }
 861                 elsif (/^--with-zlib-include=(.*)$/)
 862                         {
 863                         $withargs{zlib_include}=$1;
 864                         }
 865                 elsif (/^--with-fuzzer-lib=(.*)$/)
 866                         {
 867                         $withargs{fuzzer_lib}=$1;
 868                         }
 869                 elsif (/^--with-fuzzer-include=(.*)$/)
 870                         {
 871                         $withargs{fuzzer_include}=$1;
 872                         }
 873                 elsif (/^--with-rand-seed=(.*)$/)
 874                         {
 875                         foreach my $x (split(m|,|, $1))
 876                             {
 877                             die "Unknown --with-rand-seed choice $x\n"
 878                                 if ! grep { $x eq $_ } @known_seed_sources;
 879                             push @seed_sources, $x;
 880                             }
 881                         }
 882                 elsif (/^--cross-compile-prefix=(.*)$/)
 883                         {
 884                         $user{CROSS_COMPILE}=$1;
 885                         }
 886                 elsif (/^--config=(.*)$/)
 887                         {
 888                         read_config $1;
 889                         }
 890                 elsif (/^-l(.*)$/)
 891                         {
 892                         push @{$useradd{LDLIBS}}, $_;
 893                         }
 894                 elsif (/^-framework$/)
 895                         {
 896                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 897                         }
 898                 elsif (/^-L(.*)$/ or /^-Wl,/)
 899                         {
 900                         push @{$useradd{LDFLAGS}}, $_;
 901                         }
 902                 elsif (/^-rpath$/ or /^-R$/)
 903                         # -rpath is the OSF1 rpath flag
 904                         # -R is the old Solaris rpath flag
 905                         {
 906                         my $rpath = shift(@argvcopy) || "";
 907                         $rpath .= " " if $rpath ne "";
 908                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 909                         }
 910                 elsif (/^-static$/)
 911                         {
 912                         push @{$useradd{LDFLAGS}}, $_;
 913                         }
 914                 elsif (m|^[-/]D(.*)$|)
 915                         {
 916                         push @{$useradd{CPPDEFINES}}, $1;
 917                         }
 918                 elsif (m|^[-/]I(.*)$|)
 919                         {
 920                         push @{$useradd{CPPINCLUDES}}, $1;
 921                         }
 922                 elsif (/^-Wp,$/)
 923                         {
 924                         push @{$useradd{CPPFLAGS}}, $1;
 925                         }
 926                 else    # common if (/^[-+]/), just pass down...
 927                         {
 928                         # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 929                         # This provides a simple way to pass options with arguments separated
 930                         # by spaces without quoting (e.g. -opt%20arg translates to -opt arg).
 931                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 932                         push @{$useradd{CFLAGS}}, $_;
 933                         push @{$useradd{CXXFLAGS}}, $_;
 934                         }
 935                 }
 936         elsif (m|^/|)
 937                 {
 938                 # Treat %xx as an ASCII code (e.g. replace %20 by a space character).
 939                 # This provides a simple way to pass options with arguments separated
 940                 # by spaces without quoting (e.g. /opt%20arg translates to /opt arg).
 941                 $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 942                 push @{$useradd{CFLAGS}}, $_;
 943                 push @{$useradd{CXXFLAGS}}, $_;
 944                 }
 945         else
 946                 {
 947                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 948                 $target=$_;
 949                 }
 950         unless ($_ eq $target || /^no-/ || /^disable-/)
 951                 {
 952                 # "no-..." follows later after implied deactivations
 953                 # have been derived.  (Don't take this too seriously,
 954                 # we really only write OPTIONS to the Makefile out of
 955                 # nostalgia.)
 956
 957                 if ($config{options} eq "")
 958                         { $config{options} = $_; }
 959                 else
 960                         { $config{options} .= " ".$_; }
 961                 }
 962         }
 963
 964 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 965         die "***** Unsupported api compatibility level: $config{api}\n",
 966 }
 967
 968 if (keys %deprecated_options)
 969         {
 970         warn "***** Deprecated options: ",
 971                 join(", ", keys %deprecated_options), "\n";
 972         }
 973 if (keys %unsupported_options)
 974         {
 975         die "***** Unsupported options: ",
 976                 join(", ", keys %unsupported_options), "\n";
 977         }
 978
 979 # If any %useradd entry has been set, we must check that the "make
 980 # variables" haven't been set.  We start by checking of any %useradd entry
 981 # is set.
 982 if (grep { scalar @$_ > 0 } values %useradd) {
 983     # Hash of env / make variables names.  The possible values are:
 984     # 1 - "make vars"
 985     # 2 - %useradd entry set
 986     # 3 - both set
 987     my %detected_vars =
 988         map { my $v = 0;
 989               $v += 1 if $cmdvars{$_};
 990               $v += 2 if @{$useradd{$_}};
 991               $_ => $v }
 992         keys %useradd;
 993
 994     # If any of the corresponding "make variables" is set, we error
 995     if (grep { $_ & 1 } values %detected_vars) {
 996         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 997                                sort keys %detected_vars);
 998         die <<"_____";
 999 ***** Mixing make variables and additional compiler/linker flags as
1000 ***** configure command line option is not permitted.
1001 ***** Affected make variables: $names
1002 _____
1003     }
1004 }
1005
1006 # Check through all supported command line variables to see if any of them
1007 # were set, and canonicalise the values we got.  If no compiler or linker
1008 # flag or anything else that affects %useradd was set, we also check the
1009 # environment for values.
1010 my $anyuseradd =
1011     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
1012 foreach (keys %user) {
1013     my $value = $cmdvars{$_};
1014     $value //= env($_) unless $anyuseradd;
1015     $value //=
1016         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
1017     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
1018         unless $anyuseradd;
1019
1020     if (defined $value) {
1021         if (ref $user{$_} eq 'ARRAY') {
1022             $user{$_} = [ split /$list_separator_re/, $value ];
1023         } elsif (!defined $user{$_}) {
1024             $user{$_} = $value;
1025         }
1026     }
1027 }
1028
1029 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1030     && !$disabled{shared}
1031     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1032     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1033         "***** any of asan, msan or ubsan\n";
1034 }
1035
1036 sub disable {
1037     my $disable_type = shift;
1038
1039     for (@_) {
1040         $disabled{$_} = $disable_type;
1041     }
1042
1043     my @tocheckfor = (@_ ? @_ : keys %disabled);
1044     while (@tocheckfor) {
1045         my %new_tocheckfor = ();
1046         my @cascade_copy = (@disable_cascades);
1047         while (@cascade_copy) {
1048             my ($test, $descendents) =
1049                 (shift @cascade_copy, shift @cascade_copy);
1050             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1051                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1052                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1053                 }
1054             }
1055         }
1056         @tocheckfor = (keys %new_tocheckfor);
1057     }
1058 }
1059 disable();                     # First cascade run
1060
1061 our $die = sub { die @_; };
1062 if ($target eq "TABLE") {
1063     local $die = sub { warn @_; };
1064     foreach (sort keys %table) {
1065         print_table_entry($_, "TABLE");
1066     }
1067     exit 0;
1068 }
1069
1070 if ($target eq "LIST") {
1071     foreach (sort keys %table) {
1072         print $_,"\n" unless $table{$_}->{template};
1073     }
1074     exit 0;
1075 }
1076
1077 if ($target eq "HASH") {
1078     local $die = sub { warn @_; };
1079     print "%table = (\n";
1080     foreach (sort keys %table) {
1081         print_table_entry($_, "HASH");
1082     }
1083     exit 0;
1084 }
1085
1086 print "Configuring OpenSSL version $config{full_version} ";
1087 print "for target $target\n";
1088
1089 if (scalar(@seed_sources) == 0) {
1090     print "Using os-specific seed configuration\n";
1091     push @seed_sources, 'os';
1092 }
1093 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1094     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1095     warn <<_____ if scalar(@seed_sources) == 1;
1096
1097 ============================== WARNING ===============================
1098 You have selected the --with-rand-seed=none option, which effectively
1099 disables automatic reseeding of the OpenSSL random generator.
1100 All operations depending on the random generator such as creating keys
1101 will not work unless the random generator is seeded manually by the
1102 application.
1103
1104 Please read the 'Note on random number generation' section in the
1105 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1106 ============================== WARNING ===============================
1107
1108 _____
1109 }
1110 push @{$config{openssl_feature_defines}},
1111      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1112         @seed_sources;
1113
1114 # Backward compatibility?
1115 if ($target =~ m/^CygWin32(-.*)$/) {
1116     $target = "Cygwin".$1;
1117 }
1118
1119 # Support for legacy targets having a name starting with 'debug-'
1120 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1121 if ($d) {
1122     $config{build_type} = "debug";
1123
1124     # If we do not find debug-foo in the table, the target is set to foo.
1125     if (!$table{$target}) {
1126         $target = $t;
1127     }
1128 }
1129
1130 &usage if !$table{$target} || $table{$target}->{template};
1131
1132 $config{target} = $target;
1133 my %target = resolve_config($target);
1134
1135 foreach (keys %target_attr_translate) {
1136     $target{$target_attr_translate{$_}} = $target{$_}
1137         if $target{$_};
1138     delete $target{$_};
1139 }
1140
1141 %target = ( %{$table{DEFAULTS}}, %target );
1142
1143 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1144 $config{conf_files} = [ sort keys %conf_files ];
1145
1146 # Using sub disable within these loops may prove fragile, so we run
1147 # a cascade afterwards
1148 foreach my $feature (@{$target{disable}}) {
1149     if (exists $deprecated_disablables{$feature}) {
1150         warn "***** config $target disables deprecated feature $feature\n";
1151     } elsif (!grep { $feature eq $_ } @disablables) {
1152         die "***** config $target disables unknown feature $feature\n";
1153     }
1154     $disabled{$feature} = 'config';
1155 }
1156 foreach my $feature (@{$target{enable}}) {
1157     if ("default" eq ($disabled{$feature} // "")) {
1158         if (exists $deprecated_disablables{$feature}) {
1159             warn "***** config $target enables deprecated feature $feature\n";
1160         } elsif (!grep { $feature eq $_ } @disablables) {
1161             die "***** config $target enables unknown feature $feature\n";
1162         }
1163         delete $disabled{$feature};
1164     }
1165 }
1166
1167 # If uplink_arch isn't defined, disable uplink
1168 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1169 # If asm_arch isn't defined, disable asm
1170 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1171
1172 disable();                      # Run a cascade now
1173
1174 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1175 $target{cxxflags}//=$target{cflags} if $target{CXX};
1176 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1177 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1178
1179 # Fill %config with values from %user, and in case those are undefined or
1180 # empty, use values from %target (acting as a default).
1181 foreach (keys %user) {
1182     my $ref_type = ref $user{$_};
1183
1184     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1185     # and a value that's to be coerced into that type.
1186     my $mkvalue = sub {
1187         my $type = shift;
1188         my $value = shift;
1189         my $undef_p = shift;
1190
1191         die "Too many arguments for \$mkvalue" if @_;
1192
1193         while (ref $value eq 'CODE') {
1194             $value = $value->();
1195         }
1196
1197         if ($type eq 'ARRAY') {
1198             return undef unless defined $value;
1199             return undef if ref $value ne 'ARRAY' && !$value;
1200             return undef if ref $value eq 'ARRAY' && !@$value;
1201             return [ $value ] unless ref $value eq 'ARRAY';
1202         }
1203         return undef unless $value;
1204         return $value;
1205     };
1206
1207     $config{$_} =
1208         $mkvalue->($ref_type, $user{$_})
1209         || $mkvalue->($ref_type, $target{$_});
1210     delete $config{$_} unless defined $config{$_};
1211 }
1212
1213 # Finish up %config by appending things the user gave us on the command line
1214 # apart from "make variables"
1215 foreach (keys %useradd) {
1216     # The must all be lists, so we assert that here
1217     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1218         unless ref $useradd{$_} eq 'ARRAY';
1219
1220     if (defined $config{$_}) {
1221         push @{$config{$_}}, @{$useradd{$_}};
1222     } else {
1223         $config{$_} = [ @{$useradd{$_}} ];
1224     }
1225 }
1226 # At this point, we can forget everything about %user and %useradd,
1227 # because it's now all been merged into the corresponding $config entry
1228
1229 # Allow overriding the build file name
1230 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1231
1232 ######################################################################
1233 # Build up information for skipping certain directories depending on disabled
1234 # features, as well as setting up macros for disabled features.
1235
1236 # This is a tentative database of directories to skip.  Some entries may not
1237 # correspond to anything real, but that's ok, they will simply be ignored.
1238 # The actual processing of these entries is done in the build.info lookup
1239 # loop further down.
1240 #
1241 # The key is a Unix formatted path in the source tree, the value is an index
1242 # into %disabled_info, so any existing path gets added to a corresponding
1243 # 'skipped' entry in there with the list of skipped directories.
1244 my %skipdir = ();
1245 my %disabled_info = ();         # For configdata.pm
1246 foreach my $what (sort keys %disabled) {
1247     # There are deprecated disablables that translate to themselves.
1248     # They cause disabling cascades, but should otherwise not regiter.
1249     next if $deprecated_disablables{$what};
1250
1251     $config{options} .= " no-$what";
1252
1253     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1254                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1255                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1256         (my $WHAT = uc $what) =~ s|-|_|g;
1257         my $skipdir = $what;
1258
1259         # fix-up crypto/directory name(s)
1260         $skipdir = "ripemd" if $what eq "rmd160";
1261         $skipdir = "whrlpool" if $what eq "whirlpool";
1262
1263         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1264         push @{$config{openssl_feature_defines}}, $macro;
1265
1266         $skipdir{engines} = $what if $what eq 'engine';
1267         $skipdir{"crypto/$skipdir"} = $what
1268             unless $what eq 'async' || $what eq 'err' || $what eq 'dso';
1269     }
1270 }
1271
1272 # Make sure build_scheme is consistent.
1273 $target{build_scheme} = [ $target{build_scheme} ]
1274     if ref($target{build_scheme}) ne "ARRAY";
1275
1276 my ($builder, $builder_platform, @builder_opts) =
1277     @{$target{build_scheme}};
1278
1279 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1280                       $builder_platform."-checker.pm")) {
1281     my $checker_path = catfile($srcdir, "Configurations", $checker);
1282     if (-f $checker_path) {
1283         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1284             ? sub { warn $@; } : sub { die $@; };
1285         if (! do $checker_path) {
1286             if ($@) {
1287                 $fn->($@);
1288             } elsif ($!) {
1289                 $fn->($!);
1290             } else {
1291                 $fn->("The detected tools didn't match the platform\n");
1292             }
1293         }
1294         last;
1295     }
1296 }
1297
1298 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1299
1300 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1301         {
1302         push @{$config{cflags}}, "-mno-cygwin";
1303         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1304         push @{$config{shared_ldflag}}, "-mno-cygwin";
1305         }
1306
1307 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1308         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1309         # minimally required architecture flags for assembly modules
1310         my $value;
1311         $value = '-mips2' if ($target =~ /mips32/);
1312         $value = '-mips3' if ($target =~ /mips64/);
1313         unshift @{$config{cflags}}, $value;
1314         unshift @{$config{cxxflags}}, $value if $config{CXX};
1315 }
1316
1317 # If threads aren't disabled, check how possible they are
1318 unless ($disabled{threads}) {
1319     if ($auto_threads) {
1320         # Enabled by default, disable it forcibly if unavailable
1321         if ($target{thread_scheme} eq "(unknown)") {
1322             disable("unavailable", 'threads');
1323         }
1324     } else {
1325         # The user chose to enable threads explicitly, let's see
1326         # if there's a chance that's possible
1327         if ($target{thread_scheme} eq "(unknown)") {
1328             # If the user asked for "threads" and we don't have internal
1329             # knowledge how to do it, [s]he is expected to provide any
1330             # system-dependent compiler options that are necessary.  We
1331             # can't truly check that the given options are correct, but
1332             # we expect the user to know what [s]He is doing.
1333             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1334                 die "You asked for multi-threading support, but didn't\n"
1335                     ,"provide any system-specific compiler options\n";
1336             }
1337         }
1338     }
1339 }
1340
1341 # Find out if clang's sanitizers have been enabled with -fsanitize
1342 # flags and ensure that the corresponding %disabled elements area
1343 # removed to reflect that the sanitizers are indeed enabled.
1344 my %detected_sanitizers = ();
1345 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1346     (my $checks = $_) =~ s/^-fsanitize=//;
1347     foreach (split /,/, $checks) {
1348         my $d = { address       => 'asan',
1349                   undefined     => 'ubsan',
1350                   memory        => 'msan' } -> {$_};
1351         next unless defined $d;
1352
1353         $detected_sanitizers{$d} = 1;
1354         if (defined $disabled{$d}) {
1355             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1356                 if $disabled{$d} ne "default";
1357             delete $disabled{$d};
1358         }
1359     }
1360 }
1361
1362 # If threads still aren't disabled, add a C macro to ensure the source
1363 # code knows about it.  Any other flag is taken care of by the configs.
1364 unless($disabled{threads}) {
1365     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1366 }
1367
1368 # With "deprecated" disable all deprecated features.
1369 if (defined($disabled{"deprecated"})) {
1370         $config{api} = $maxapi;
1371 }
1372
1373 my $no_shared_warn=0;
1374 if ($target{shared_target} eq "")
1375         {
1376         $no_shared_warn = 1
1377             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1378         disable('no-shared-target', 'pic');
1379         }
1380
1381 if ($disabled{"dynamic-engine"}) {
1382         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1383         $config{dynamic_engines} = 0;
1384 } else {
1385         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1386         $config{dynamic_engines} = 1;
1387 }
1388
1389 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1390     push @{$config{cflags}}, "-fsanitize=address";
1391 }
1392
1393 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1394     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1395     # platforms.
1396     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1397 }
1398
1399 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1400   push @{$config{cflags}}, "-fsanitize=memory";
1401 }
1402
1403 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1404         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1405     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1406     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1407 }
1408 #
1409 # Platform fix-ups
1410 #
1411
1412 # This saves the build files from having to check
1413 if ($disabled{pic})
1414         {
1415         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1416                     shared_defines shared_includes shared_ldflag
1417                     module_cflags module_cxxflags module_cppflags
1418                     module_defines module_includes module_lflags))
1419                 {
1420                 delete $config{$_};
1421                 $target{$_} = "";
1422                 }
1423         }
1424 else
1425         {
1426         push @{$config{lib_defines}}, "OPENSSL_PIC";
1427         }
1428
1429 if ($target{sys_id} ne "")
1430         {
1431         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1432         }
1433
1434 unless ($disabled{asm}) {
1435 }
1436
1437 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1438 my %predefined_CXX = $config{CXX}
1439     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1440     : ();
1441
1442 # Check for makedepend capabilities.
1443 if (!$disabled{makedepend}) {
1444     if ($config{target} =~ /^(VC|vms)-/) {
1445         # For VC- and vms- targets, there's nothing more to do here.  The
1446         # functionality is hard coded in the corresponding build files for
1447         # cl (Windows) and CC/DECC (VMS).
1448     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1449              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1450         # We know that GNU C version 3 and up as well as all clang
1451         # versions support dependency generation, but Xcode did not
1452         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1453         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1454     } else {
1455         # In all other cases, we look for 'makedepend', and disable the
1456         # capability if not found.
1457         $config{makedepprog} = which('makedepend');
1458         disable('unavailable', 'makedepend') unless $config{makedepprog};
1459     }
1460 }
1461
1462 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1463     # probe for -Wa,--noexecstack option...
1464     if ($predefined_C{__clang__}) {
1465         # clang has builtin assembler, which doesn't recognize --help,
1466         # but it apparently recognizes the option in question on all
1467         # supported platforms even when it's meaningless. In other words
1468         # probe would fail, but probed option always accepted...
1469         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1470     } else {
1471         my $cc = $config{CROSS_COMPILE}.$config{CC};
1472         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1473         while(<PIPE>) {
1474             if (m/--noexecstack/) {
1475                 push @{$config{cflags}}, "-Wa,--noexecstack";
1476                 last;
1477             }
1478         }
1479         close(PIPE);
1480         unlink("null.$$.o");
1481     }
1482 }
1483
1484 # Deal with bn_ops ###################################################
1485
1486 $config{bn_ll}                  =0;
1487 my $def_int="unsigned int";
1488 $config{rc4_int}                =$def_int;
1489 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1490
1491 my $count = 0;
1492 foreach (sort split(/\s+/,$target{bn_ops})) {
1493     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1494     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1495     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1496     ($config{b64l},$config{b64},$config{b32})
1497         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1498     ($config{b64l},$config{b64},$config{b32})
1499         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1500     ($config{b64l},$config{b64},$config{b32})
1501         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1502 }
1503 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1504     if $count > 1;
1505
1506
1507 # Hack cflags for better warnings (dev option) #######################
1508
1509 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1510 # a string and works as well on command lines.
1511 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1512                         @{$config{cflags}} ];
1513 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1514                           @{$config{cxxflags}} ] if $config{CXX};
1515
1516 $config{openssl_api_defines} = [
1517     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1518 ];
1519
1520 my @strict_warnings_collection=();
1521 if ($strict_warnings)
1522         {
1523         my $wopt;
1524         my $gccver = $predefined_C{__GNUC__} // -1;
1525
1526         if ($gccver >= 4)
1527                 {
1528                 push @strict_warnings_collection, @gcc_devteam_warn;
1529                 push @strict_warnings_collection, @clang_devteam_warn
1530                     if (defined($predefined_C{__clang__}));
1531                 }
1532         elsif ($config{target} =~ /^VC-/)
1533                 {
1534                 push @strict_warnings_collection, @cl_devteam_warn;
1535                 }
1536         else
1537                 {
1538                 warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike, or MSVC"
1539                 }
1540         }
1541
1542 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1543     disable('static', 'pic', 'threads');
1544 }
1545
1546 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1547                               ? @strict_warnings_collection
1548                               : ( $_ ) }
1549                     @{$config{CFLAGS}} ];
1550
1551 unless ($disabled{"crypto-mdebug-backtrace"})
1552         {
1553         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1554                 {
1555                 push @{$config{cflags}}, $wopt
1556                         unless grep { $_ eq $wopt } @{$config{cflags}};
1557                 }
1558         if ($target =~ /^BSD-/)
1559                 {
1560                 push @{$config{ex_libs}}, "-lexecinfo";
1561                 }
1562         }
1563
1564 unless ($disabled{afalgeng}) {
1565     $config{afalgeng}="";
1566     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1567         my $minver = 4*10000 + 1*100 + 0;
1568         if ($config{CROSS_COMPILE} eq "") {
1569             my $verstr = `uname -r`;
1570             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1571             ($mi2) = $mi2 =~ /(\d+)/;
1572             my $ver = $ma*10000 + $mi1*100 + $mi2;
1573             if ($ver < $minver) {
1574                 disable('too-old-kernel', 'afalgeng');
1575             } else {
1576                 push @{$config{engdirs}}, "afalg";
1577             }
1578         } else {
1579             disable('cross-compiling', 'afalgeng');
1580         }
1581     } else {
1582         disable('not-linux', 'afalgeng');
1583     }
1584 }
1585
1586 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1587
1588 unless ($disabled{ktls}) {
1589     $config{ktls}="";
1590     if ($target =~ m/^linux/) {
1591         my $usr = "/usr/$config{cross_compile_prefix}";
1592         chop($usr);
1593         if ($config{cross_compile_prefix} eq "") {
1594             $usr = "/usr";
1595         }
1596         my $minver = (4 << 16) + (13 << 8) + 0;
1597         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1598
1599         if ($verstr[2] < $minver) {
1600             disable('too-old-kernel', 'ktls');
1601         }
1602     } elsif ($target =~ m/^BSD/) {
1603         my $cc = $config{CROSS_COMPILE}.$config{CC};
1604         system("printf '#include <sys/types.h>\n#include <sys/ktls.h>' | $cc -E - >/dev/null 2>&1");
1605         if ($? != 0) {
1606             disable('too-old-freebsd', 'ktls');
1607         }
1608     } else {
1609         disable('not-linux-or-freebsd', 'ktls');
1610     }
1611 }
1612
1613 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1614
1615 # Get the extra flags used when building shared libraries and modules.  We
1616 # do this late because some of them depend on %disabled.
1617
1618 # Make the flags to build DSOs the same as for shared libraries unless they
1619 # are already defined
1620 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1621 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1622 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1623 {
1624     my $shared_info_pl =
1625         catfile(dirname($0), "Configurations", "shared-info.pl");
1626     my %shared_info = read_eval_file($shared_info_pl);
1627     push @{$target{_conf_fname_int}}, $shared_info_pl;
1628     my $si = $target{shared_target};
1629     while (ref $si ne "HASH") {
1630         last if ! defined $si;
1631         if (ref $si eq "CODE") {
1632             $si = $si->();
1633         } else {
1634             $si = $shared_info{$si};
1635         }
1636     }
1637
1638     # Some of the 'shared_target' values don't have any entries in
1639     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1640     # template knows how to handle this.  That is currently the case for
1641     # Windows and VMS.
1642     if (defined $si) {
1643         # Just as above, copy certain shared_* attributes to the corresponding
1644         # module_ attribute unless the latter is already defined
1645         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1646         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1647         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1648         foreach (sort keys %$si) {
1649             $target{$_} = defined $target{$_}
1650                 ? add($si->{$_})->($target{$_})
1651                 : $si->{$_};
1652         }
1653     }
1654 }
1655
1656 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1657
1658 # If we use the unified build, collect information from build.info files
1659 my %unified_info = ();
1660
1661 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1662 if ($builder eq "unified") {
1663     use Text::Template 1.46;
1664
1665     sub cleandir {
1666         my $base = shift;
1667         my $dir = shift;
1668         my $relativeto = shift || ".";
1669
1670         $dir = catdir($base,$dir) unless isabsolute($dir);
1671
1672         # Make sure the directories we're building in exists
1673         mkpath($dir);
1674
1675         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1676         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1677         return $res;
1678     }
1679
1680     sub cleanfile {
1681         my $base = shift;
1682         my $file = shift;
1683         my $relativeto = shift || ".";
1684
1685         $file = catfile($base,$file) unless isabsolute($file);
1686
1687         my $d = dirname($file);
1688         my $f = basename($file);
1689
1690         # Make sure the directories we're building in exists
1691         mkpath($d);
1692
1693         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1694         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1695         return $res;
1696     }
1697
1698     # Store the name of the template file we will build the build file from
1699     # in %config.  This may be useful for the build file itself.
1700     my @build_file_template_names =
1701         ( $builder_platform."-".$target{build_file}.".tmpl",
1702           $target{build_file}.".tmpl" );
1703     my @build_file_templates = ();
1704
1705     # First, look in the user provided directory, if given
1706     if (defined env($local_config_envname)) {
1707         @build_file_templates =
1708             map {
1709                 if ($^O eq 'VMS') {
1710                     # VMS environment variables are logical names,
1711                     # which can be used as is
1712                     $local_config_envname . ':' . $_;
1713                 } else {
1714                     catfile(env($local_config_envname), $_);
1715                 }
1716             }
1717             @build_file_template_names;
1718     }
1719     # Then, look in our standard directory
1720     push @build_file_templates,
1721         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1722           @build_file_template_names );
1723
1724     my $build_file_template;
1725     for $_ (@build_file_templates) {
1726         $build_file_template = $_;
1727         last if -f $build_file_template;
1728
1729         $build_file_template = undef;
1730     }
1731     if (!defined $build_file_template) {
1732         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1733     }
1734     $config{build_file_templates}
1735       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1736                     $blddir),
1737           $build_file_template,
1738           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1739                     $blddir) ];
1740
1741     my @build_dirs = ( [ ] );   # current directory
1742
1743     $config{build_infos} = [ ];
1744
1745     my %ordinals = ();
1746     while (@build_dirs) {
1747         my @curd = @{shift @build_dirs};
1748         my $sourced = catdir($srcdir, @curd);
1749         my $buildd = catdir($blddir, @curd);
1750
1751         my $unixdir = join('/', @curd);
1752         if (exists $skipdir{$unixdir}) {
1753             my $what = $skipdir{$unixdir};
1754             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1755             next;
1756         }
1757
1758         mkpath($buildd);
1759
1760         my $f = 'build.info';
1761         # The basic things we're trying to build
1762         my @programs = ();
1763         my @libraries = ();
1764         my @modules = ();
1765         my @scripts = ();
1766
1767         my %sources = ();
1768         my %shared_sources = ();
1769         my %includes = ();
1770         my %defines = ();
1771         my %depends = ();
1772         my %generate = ();
1773
1774         # Support for $variablename in build.info files.
1775         # Embedded perl code is the ultimate master, still.  If its output
1776         # contains a dollar sign, it had better be escaped, or it will be
1777         # taken for a variable name prefix.
1778         my %variables = ();
1779         my $variable_re = qr/\$(?P<VARIABLE>[[:alpha:]][[:alnum:]_]*)/;
1780         my $expand_variables = sub {
1781             my $value = '';
1782             my $value_rest = shift;
1783
1784             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1785                 print STDERR
1786                     "DEBUG[\$expand_variables] Parsed '$value_rest' into:\n"
1787             }
1788             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1789                 $value .= $`;
1790                 $value .= $variables{$+{VARIABLE}};
1791                 $value_rest = $';
1792             }
1793             if ($ENV{CONFIGURE_DEBUG_VARIABLE_EXPAND}) {
1794                 print STDERR
1795                     "DEBUG[\$expand_variables] ... '$value$value_rest'\n";
1796             }
1797             return $value . $value_rest;
1798         };
1799
1800         # Support for attributes in build.info files
1801         my %attributes = ();
1802         my $handle_attributes = sub {
1803             my $attr_str = shift;
1804             my $ref = shift;
1805             my @goals = @_;
1806
1807             return unless defined $attr_str;
1808
1809             my @a = tokenize($attr_str, qr|\s*,\s*|);
1810             foreach my $a (@a) {
1811                 my $ac = 1;
1812                 my $ak = $a;
1813                 my $av = 1;
1814                 if ($a =~ m|^(!)?(.*?)\s* = \s*(.*?)$|) {
1815                     $ac = ! $1;
1816                     $ak = $1;
1817                     $av = $2;
1818                 }
1819                 foreach my $g (@goals) {
1820                     if ($ac) {
1821                         $$ref->{$g}->{$ak} = $av;
1822                     } else {
1823                         delete $$ref->{$g}->{$ak};
1824                     }
1825                 }
1826             }
1827         };
1828
1829         # We want to detect configdata.pm in the source tree, so we
1830         # don't use it if the build tree is different.
1831         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1832
1833         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1834         my $template =
1835             Text::Template->new(TYPE => 'FILE',
1836                                 SOURCE => catfile($sourced, $f),
1837                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1838         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1839         my @text =
1840             split /^/m,
1841             $template->fill_in(HASH => { config => \%config,
1842                                          target => \%target,
1843                                          disabled => \%disabled,
1844                                          withargs => \%withargs,
1845                                          builddir => abs2rel($buildd, $blddir),
1846                                          sourcedir => abs2rel($sourced, $blddir),
1847                                          buildtop => abs2rel($blddir, $blddir),
1848                                          sourcetop => abs2rel($srcdir, $blddir) },
1849                                DELIMITERS => [ "{-", "-}" ]);
1850
1851         # The top item of this stack has the following values
1852         # -2 positive already run and we found ELSE (following ELSIF should fail)
1853         # -1 positive already run (skip until ENDIF)
1854         # 0 negatives so far (if we're at a condition, check it)
1855         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1856         # 2 positive ELSE (following ELSIF should fail)
1857         my @skip = ();
1858
1859         # A few useful generic regexps
1860         my $index_re = qr/\[\s*(?P<INDEX>(?:\\.|.)*?)\s*\]/;
1861         my $cond_re = qr/\[\s*(?P<COND>(?:\\.|.)*?)\s*\]/;
1862         my $attribs_re = qr/(?:\{\s*(?P<ATTRIBS>(?:\\.|.)*?)\s*\})?/;
1863         my $value_re = qr/\s*(?P<VALUE>.*?)\s*/;
1864         collect_information(
1865             collect_from_array([ @text ],
1866                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1867                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1868             # Info we're looking for
1869             qr/^\s* IF ${cond_re} \s*$/x
1870             => sub {
1871                 if (! @skip || $skip[$#skip] > 0) {
1872                     push @skip, !! $expand_variables->($+{COND});
1873                 } else {
1874                     push @skip, -1;
1875                 }
1876             },
1877             qr/^\s* ELSIF ${cond_re} \s*$/x
1878             => sub { die "ELSIF out of scope" if ! @skip;
1879                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1880                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1881                      $skip[$#skip] = !! $expand_variables->($+{COND})
1882                          if $skip[$#skip] == 0; },
1883             qr/^\s* ELSE \s*$/x
1884             => sub { die "ELSE out of scope" if ! @skip;
1885                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1886                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1887             qr/^\s* ENDIF \s*$/x
1888             => sub { die "ENDIF out of scope" if ! @skip;
1889                      pop @skip; },
1890             qr/^\s* ${variable_re} \s* = ${value_re} $/x
1891             => sub {
1892                 if (!@skip || $skip[$#skip] > 0) {
1893                     $variables{$+{VARIABLE}} = $expand_variables->($+{VALUE});
1894                 }
1895             },
1896             qr/^\s* SUBDIRS \s* = ${value_re} $/x
1897             => sub {
1898                 if (!@skip || $skip[$#skip] > 0) {
1899                     foreach (tokenize($expand_variables->($+{VALUE}))) {
1900                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1901                     }
1902                 }
1903             },
1904             qr/^\s* PROGRAMS ${attribs_re} \s* =  ${value_re} $/x
1905             => sub {
1906                 if (!@skip || $skip[$#skip] > 0) {
1907                     my @p = tokenize($expand_variables->($+{VALUE}));
1908                     push @programs, @p;
1909                     $handle_attributes->($+{ATTRIBS},
1910                                          \$attributes{programs},
1911                                          @p);
1912                 }
1913             },
1914             qr/^\s* LIBS ${attribs_re} \s* =  ${value_re} $/x
1915             => sub {
1916                 if (!@skip || $skip[$#skip] > 0) {
1917                     my @l = tokenize($expand_variables->($+{VALUE}));
1918                     push @libraries, @l;
1919                     $handle_attributes->($+{ATTRIBS},
1920                                          \$attributes{libraries},
1921                                          @l);
1922                 }
1923             },
1924             qr/^\s* MODULES ${attribs_re} \s* =  ${value_re} $/x
1925             => sub {
1926                 if (!@skip || $skip[$#skip] > 0) {
1927                     my @m = tokenize($expand_variables->($+{VALUE}));
1928                     push @modules, @m;
1929                     $handle_attributes->($+{ATTRIBS},
1930                                          \$attributes{modules},
1931                                          @m);
1932                 }
1933             },
1934             qr/^\s* SCRIPTS ${attribs_re} \s* =  ${value_re} $/x
1935             => sub {
1936                 if (!@skip || $skip[$#skip] > 0) {
1937                     my @s = tokenize($expand_variables->($+{VALUE}));
1938                     push @scripts, @s;
1939                     $handle_attributes->($+{ATTRIBS},
1940                                          \$attributes{scripts},
1941                                          @s);
1942                 }
1943             },
1944
1945             qr/^\s* ORDINALS ${index_re} = ${value_re} $/x
1946             => sub { push @{$ordinals{$expand_variables->($+{INDEX})}},
1947                          tokenize($expand_variables->($+{VALUE}))
1948                          if !@skip || $skip[$#skip] > 0 },
1949             qr/^\s* SOURCE ${index_re} = ${value_re} $/x
1950             => sub { push @{$sources{$expand_variables->($+{INDEX})}},
1951                          tokenize($expand_variables->($+{VALUE}))
1952                          if !@skip || $skip[$#skip] > 0 },
1953             qr/^\s* SHARED_SOURCE ${index_re} = ${value_re} $/x
1954             => sub { push @{$shared_sources{$expand_variables->($+{INDEX})}},
1955                          tokenize($expand_variables->($+{VALUE}))
1956                          if !@skip || $skip[$#skip] > 0 },
1957             qr/^\s* INCLUDE ${index_re} = ${value_re} $/x
1958             => sub { push @{$includes{$expand_variables->($+{INDEX})}},
1959                          tokenize($expand_variables->($+{VALUE}))
1960                          if !@skip || $skip[$#skip] > 0 },
1961             qr/^\s* DEFINE ${index_re} = ${value_re} $/x
1962             => sub { push @{$defines{$expand_variables->($+{INDEX})}},
1963                          tokenize($expand_variables->($+{VALUE}))
1964                          if !@skip || $skip[$#skip] > 0 },
1965             qr/^\s* DEPEND ${index_re} ${attribs_re} = ${value_re} $/x
1966             => sub {
1967                 if (!@skip || $skip[$#skip] > 0) {
1968                     my $i = $expand_variables->($+{INDEX});
1969                     my @d = tokenize($expand_variables->($+{VALUE}));
1970                     push @{$depends{$i}}, @d;
1971                     $handle_attributes->($+{ATTRIBS},
1972                                          \$attributes{depends}->{$i},
1973                                          @d);
1974                 }
1975             },
1976             qr/^\s* GENERATE ${index_re} = ${value_re} $/x
1977             => sub { push @{$generate{$expand_variables->($+{INDEX})}},
1978                          $+{VALUE}
1979                          if !@skip || $skip[$#skip] > 0 },
1980             qr/^\s* (?:\#.*)? $/x => sub { },
1981             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1982             "BEFORE" => sub {
1983                 if ($buildinfo_debug) {
1984                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1985                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1986                 }
1987             },
1988             "AFTER" => sub {
1989                 if ($buildinfo_debug) {
1990                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1991                 }
1992             },
1993             );
1994         die "runaway IF?" if (@skip);
1995
1996         if (grep { defined $attributes{modules}->{$_}->{engine} } keys %attributes
1997                 and !$config{dynamic_engines}) {
1998             die <<"EOF"
1999 ENGINES can only be used if configured with 'dynamic-engine'.
2000 This is usually a fault in a build.info file.
2001 EOF
2002         }
2003
2004         {
2005             my %infos = ( programs  => [ @programs  ],
2006                           libraries => [ @libraries ],
2007                           modules   => [ @modules   ],
2008                           scripts   => [ @scripts   ] );
2009             foreach my $k (keys %infos) {
2010                 foreach (@{$infos{$k}}) {
2011                     my $item = cleanfile($buildd, $_, $blddir);
2012                     $unified_info{$k}->{$item} = 1;
2013
2014                     # Fix up associated attributes
2015                     $unified_info{attributes}->{$k}->{$item} =
2016                         $attributes{$k}->{$_}
2017                         if defined $attributes{$k}->{$_};
2018                 }
2019             }
2020         }
2021
2022         # Check that we haven't defined any library as both shared and
2023         # explicitly static.  That is forbidden.
2024         my @doubles = ();
2025         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
2026             (my $l = $_) =~ s/\.a$//;
2027             push @doubles, $l if defined $unified_info{libraries}->{$l};
2028         }
2029         die "these libraries are both explicitly static and shared:\n  ",
2030             join(" ", @doubles), "\n"
2031             if @doubles;
2032
2033         foreach (keys %sources) {
2034             my $dest = $_;
2035             my $ddest = cleanfile($buildd, $_, $blddir);
2036             foreach (@{$sources{$dest}}) {
2037                 my $s = cleanfile($sourced, $_, $blddir);
2038
2039                 # If it isn't in the source tree, we assume it's generated
2040                 # in the build tree
2041                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2042                     $s = cleanfile($buildd, $_, $blddir);
2043                 }
2044                 # We recognise C++, C and asm files
2045                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2046                     my $o = $_;
2047                     $o =~ s/\.[csS]$/.o/; # C and assembler
2048                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2049                     $o = cleanfile($buildd, $o, $blddir);
2050                     $unified_info{sources}->{$ddest}->{$o} = -1;
2051                     $unified_info{sources}->{$o}->{$s} = -1;
2052                 } elsif ($s =~ /\.rc$/) {
2053                     # We also recognise resource files
2054                     my $o = $_;
2055                     $o =~ s/\.rc$/.res/; # Resource configuration
2056                     my $o = cleanfile($buildd, $o, $blddir);
2057                     $unified_info{sources}->{$ddest}->{$o} = -1;
2058                     $unified_info{sources}->{$o}->{$s} = -1;
2059                 } else {
2060                     $unified_info{sources}->{$ddest}->{$s} = 1;
2061                 }
2062             }
2063         }
2064
2065         foreach (keys %shared_sources) {
2066             my $dest = $_;
2067             my $ddest = cleanfile($buildd, $_, $blddir);
2068             foreach (@{$shared_sources{$dest}}) {
2069                 my $s = cleanfile($sourced, $_, $blddir);
2070
2071                 # If it isn't in the source tree, we assume it's generated
2072                 # in the build tree
2073                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2074                     $s = cleanfile($buildd, $_, $blddir);
2075                 }
2076
2077                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2078                     # We recognise C++, C and asm files
2079                     my $o = $_;
2080                     $o =~ s/\.[csS]$/.o/; # C and assembler
2081                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2082                     $o = cleanfile($buildd, $o, $blddir);
2083                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2084                     $unified_info{sources}->{$o}->{$s} = -1;
2085                 } elsif ($s =~ /\.rc$/) {
2086                     # We also recognise resource files
2087                     my $o = $_;
2088                     $o =~ s/\.rc$/.res/; # Resource configuration
2089                     my $o = cleanfile($buildd, $o, $blddir);
2090                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2091                     $unified_info{sources}->{$o}->{$s} = -1;
2092                 } elsif ($s =~ /\.ld$/) {
2093                     # We also recognise linker scripts (or corresponding)
2094                     # We know they are generated files
2095                     my $ld = cleanfile($buildd, $_, $blddir);
2096                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2097                 } else {
2098                     die "unrecognised source file type for shared library: $s\n";
2099                 }
2100             }
2101         }
2102
2103         foreach (keys %generate) {
2104             my $dest = $_;
2105             my $ddest = cleanfile($buildd, $_, $blddir);
2106             die "more than one generator for $dest: "
2107                     ,join(" ", @{$generate{$_}}),"\n"
2108                     if scalar @{$generate{$_}} > 1;
2109             my @generator = split /\s+/, $generate{$dest}->[0];
2110             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2111             $unified_info{generate}->{$ddest} = [ @generator ];
2112         }
2113
2114         foreach (keys %depends) {
2115             my $dest = $_;
2116             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2117
2118             # If the destination doesn't exist in source, it can only be
2119             # a generated file in the build tree.
2120             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2121                 $ddest = cleanfile($buildd, $_, $blddir);
2122             }
2123             foreach (@{$depends{$dest}}) {
2124                 my $d = cleanfile($sourced, $_, $blddir);
2125
2126                 # If we know it's generated, or assume it is because we can't
2127                 # find it in the source tree, we set file we depend on to be
2128                 # in the build tree rather than the source tree, and assume
2129                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2130                 # section or in the Makefile template.
2131                 if ($d eq $src_configdata
2132                     || ! -f $d
2133                     || (grep { $d eq $_ }
2134                         map { cleanfile($srcdir, $_, $blddir) }
2135                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2136                     $d = cleanfile($buildd, $_, $blddir);
2137                 }
2138                 # Take note if the file to depend on is being renamed
2139                 # Take extra care with files ending with .a, they should
2140                 # be treated without that extension, and the extension
2141                 # should be added back after treatment.
2142                 $d =~ /(\.a)?$/;
2143                 my $e = $1 // "";
2144                 $d = $`.$e;
2145                 $unified_info{depends}->{$ddest}->{$d} = 1;
2146
2147                 # Fix up associated attributes
2148                 $unified_info{attributes}->{depends}->{$ddest}->{$d} =
2149                     $attributes{depends}->{$dest}->{$_}
2150                     if defined $attributes{depends}->{$dest}->{$_};
2151             }
2152         }
2153
2154         foreach (keys %includes) {
2155             my $dest = $_;
2156             my $ddest = cleanfile($sourced, $_, $blddir);
2157
2158             # If the destination doesn't exist in source, it can only be
2159             # a generated file in the build tree.
2160             if ($ddest eq $src_configdata || ! -f $ddest) {
2161                 $ddest = cleanfile($buildd, $_, $blddir);
2162             }
2163             foreach (@{$includes{$dest}}) {
2164                 my $is = cleandir($sourced, $_, $blddir);
2165                 my $ib = cleandir($buildd, $_, $blddir);
2166                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2167                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2168                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2169                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2170             }
2171         }
2172
2173         foreach my $dest (keys %defines) {
2174             my $ddest;
2175
2176             if ($dest ne "") {
2177                 $ddest = cleanfile($sourced, $dest, $blddir);
2178
2179                 # If the destination doesn't exist in source, it can only
2180                 # be a generated file in the build tree.
2181                 if (! -f $ddest) {
2182                     $ddest = cleanfile($buildd, $dest, $blddir);
2183                     if ($unified_info{rename}->{$ddest}) {
2184                         $ddest = $unified_info{rename}->{$ddest};
2185                     }
2186                 }
2187             }
2188             foreach my $v (@{$defines{$dest}}) {
2189                 $v =~ m|^([^=]*)(=.*)?$|;
2190                 die "0 length macro name not permitted\n" if $1 eq "";
2191                 if ($dest ne "") {
2192                     die "$1 defined more than once\n"
2193                         if defined $unified_info{defines}->{$ddest}->{$1};
2194                     $unified_info{defines}->{$ddest}->{$1} = $2;
2195                 } else {
2196                     die "$1 defined more than once\n"
2197                         if grep { $v eq $_ } @{$config{defines}};
2198                     push @{$config{defines}}, $v;
2199                 }
2200             }
2201         }
2202     }
2203
2204     my $ordinals_text = join(', ', sort keys %ordinals);
2205     warn <<"EOF" if $ordinals_text;
2206
2207 WARNING: ORDINALS were specified for $ordinals_text
2208 They are ignored and should be replaced with a combination of GENERATE,
2209 DEPEND and SHARED_SOURCE.
2210 EOF
2211
2212
2213     # Go through the sources of all libraries and check that the same basename
2214     # doesn't appear more than once.  Some static library archivers depend on
2215     # them being unique.
2216     {
2217         my $err = 0;
2218         foreach my $prod (keys %{$unified_info{libraries}}) {
2219             my @prod_sources =
2220                 map { keys %{$unified_info{sources}->{$_}} }
2221                 keys %{$unified_info{sources}->{$prod}};
2222             my %srccnt = ();
2223
2224             # Count how many times a given each source basename
2225             # appears for each product.
2226             foreach my $src (@prod_sources) {
2227                 $srccnt{basename $src}++;
2228             }
2229
2230             foreach my $src (keys %srccnt) {
2231                 if ((my $cnt = $srccnt{$src}) > 1) {
2232                     print STDERR "$src appears $cnt times for the product $prod\n";
2233                     $err++
2234                 }
2235             }
2236         }
2237         die if $err > 0;
2238     }
2239
2240     # Massage the result
2241
2242     # If we depend on a header file or a perl module, add an inclusion of
2243     # its directory to allow smoothe inclusion
2244     foreach my $dest (keys %{$unified_info{depends}}) {
2245         next if $dest eq "";
2246         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2247             next unless $d =~ /\.(h|pm)$/;
2248             my $i = dirname($d);
2249             my $spot =
2250                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2251                 ? 'build' : 'source';
2252             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2253                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2254         }
2255     }
2256
2257     # Go through all intermediary files and change their names to something that
2258     # reflects what they will be built for.  Note that for some source files,
2259     # this leads to duplicate object files because they are used multiple times.
2260     # the goal is to rename all object files according to this scheme:
2261     #    {productname}-{midfix}-{origobjname}.[o|res]
2262     # the {midfix} is a keyword indicating the type of product, which is mostly
2263     # valuable for libraries since they come in two forms.
2264     #
2265     # This also reorganises the {sources} and {shared_sources} so that the
2266     # former only contains ALL object files that are supposed to end up in
2267     # static libraries and programs, while the latter contains ALL object files
2268     # that are supposed to end up in shared libraries and DSOs.
2269     # The main reason for having two different source structures is to allow
2270     # the same name to be used for the static and the shared variants of a
2271     # library.
2272     {
2273         # Take copies so we don't get interference from added stuff
2274         my %unified_copy = ();
2275         foreach (('sources', 'shared_sources')) {
2276             $unified_copy{$_} = { %{$unified_info{$_}} }
2277                 if defined($unified_info{$_});
2278             delete $unified_info{$_};
2279         }
2280         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2281             # $intent serves multi purposes:
2282             # - give a prefix for the new object files names
2283             # - in the case of libraries, rearrange the object files so static
2284             #   libraries use the 'sources' structure exclusively, while shared
2285             #   libraries use the 'shared_sources' structure exclusively.
2286             my $intent = {
2287                 programs  => { bin    => { src => [ 'sources' ],
2288                                            dst => 'sources' } },
2289                 libraries => { lib    => { src => [ 'sources' ],
2290                                            dst => 'sources' },
2291                                shlib  => { prodselect =>
2292                                                sub { grep !/\.a$/, @_ },
2293                                            src => [ 'sources',
2294                                                     'shared_sources' ],
2295                                            dst => 'shared_sources' } },
2296                 modules   => { dso    => { src => [ 'sources' ],
2297                                            dst => 'sources' } },
2298                 scripts   => { script => { src => [ 'sources' ],
2299                                            dst => 'sources' } }
2300                } -> {$prodtype};
2301             foreach my $kind (keys %$intent) {
2302                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2303                              && $disabled{shared});
2304
2305                 my @src = @{$intent->{$kind}->{src}};
2306                 my $dst = $intent->{$kind}->{dst};
2307                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2308                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2309                     # %prod_sources has all applicable objects as keys, and
2310                     # their corresponding sources as values
2311                     my %prod_sources =
2312                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2313                         map { keys %{$unified_copy{$_}->{$prod}} }
2314                         @src;
2315                     foreach (keys %prod_sources) {
2316                         # Only affect object files and resource files,
2317                         # the others simply get a new value
2318                         # (+1 instead of -1)
2319                         if ($_ =~ /\.(o|res)$/) {
2320                             (my $prodname = $prod) =~ s|\.a$||;
2321                             my $newobj =
2322                                 catfile(dirname($_),
2323                                         basename($prodname)
2324                                             . '-' . $kind
2325                                             . '-' . basename($_));
2326                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2327                             foreach my $src (@{$prod_sources{$_}}) {
2328                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2329                             }
2330                             # Adjust dependencies
2331                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2332                                 $unified_info{depends}->{$_}->{$deps} = -1;
2333                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2334                             }
2335                             # Adjust includes
2336                             foreach my $k (('source', 'build')) {
2337                                 next unless
2338                                     defined($unified_info{includes}->{$_}->{$k});
2339                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2340                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2341                             }
2342                         } else {
2343                             $unified_info{$dst}->{$prod}->{$_} = 1;
2344                         }
2345                     }
2346                 }
2347             }
2348         }
2349     }
2350
2351     # At this point, we have a number of sources with the value -1.  They
2352     # aren't part of the local build and are probably meant for a different
2353     # platform, and can therefore be cleaned away.  That happens when making
2354     # %unified_info more efficient below.
2355
2356     ### Make unified_info a bit more efficient
2357     # One level structures
2358     foreach (("programs", "libraries", "modules", "scripts")) {
2359         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2360     }
2361     # Two level structures
2362     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2363         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2364             my @items =
2365                 sort
2366                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2367                 keys %{$unified_info{$l1}->{$l2}};
2368             if (@items) {
2369                 $unified_info{$l1}->{$l2} = [ @items ];
2370             } else {
2371                 delete $unified_info{$l1}->{$l2};
2372             }
2373         }
2374     }
2375     # Defines
2376     foreach my $dest (sort keys %{$unified_info{defines}}) {
2377         $unified_info{defines}->{$dest}
2378             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2379                 sort keys %{$unified_info{defines}->{$dest}} ];
2380     }
2381     # Includes
2382     foreach my $dest (sort keys %{$unified_info{includes}}) {
2383         if (defined($unified_info{includes}->{$dest}->{build})) {
2384             my @source_includes = ();
2385             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2386                 if defined($unified_info{includes}->{$dest}->{source});
2387             $unified_info{includes}->{$dest} =
2388                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2389             foreach my $inc (@source_includes) {
2390                 push @{$unified_info{includes}->{$dest}}, $inc
2391                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2392             }
2393         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2394             $unified_info{includes}->{$dest} =
2395                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2396         } else {
2397             delete $unified_info{includes}->{$dest};
2398         }
2399     }
2400
2401     # For convenience collect information regarding directories where
2402     # files are generated, those generated files and the end product
2403     # they end up in where applicable.  Then, add build rules for those
2404     # directories
2405     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2406                      "dso" => [ @{$unified_info{modules}} ],
2407                      "bin" => [ @{$unified_info{programs}} ],
2408                      "script" => [ @{$unified_info{scripts}} ] );
2409     foreach my $type (keys %loopinfo) {
2410         foreach my $product (@{$loopinfo{$type}}) {
2411             my %dirs = ();
2412             my $pd = dirname($product);
2413
2414             foreach (@{$unified_info{sources}->{$product} // []},
2415                      @{$unified_info{shared_sources}->{$product} // []}) {
2416                 my $d = dirname($_);
2417
2418                 # We don't want to create targets for source directories
2419                 # when building out of source
2420                 next if ($config{sourcedir} ne $config{builddir}
2421                              && $d =~ m|^\Q$config{sourcedir}\E|);
2422                 # We already have a "test" target, and the current directory
2423                 # is just silly to make a target for
2424                 next if $d eq "test" || $d eq ".";
2425
2426                 $dirs{$d} = 1;
2427                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2428                     if $d ne $pd;
2429             }
2430             foreach (keys %dirs) {
2431                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2432                     $product;
2433             }
2434         }
2435     }
2436 }
2437
2438 # For the schemes that need it, we provide the old *_obj configs
2439 # from the *_asm_obj ones
2440 foreach (grep /_(asm|aux)_src$/, keys %target) {
2441     my $src = $_;
2442     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2443     $target{$obj} = $target{$src};
2444     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2445     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2446 }
2447
2448 # Write down our configuration where it fits #########################
2449
2450 my %template_vars = (
2451     config => \%config,
2452     target => \%target,
2453     disablables => \@disablables,
2454     disablables_int => \@disablables_int,
2455     disabled => \%disabled,
2456     withargs => \%withargs,
2457     unified_info => \%unified_info,
2458     tls => \@tls,
2459     dtls => \@dtls,
2460     makevars => [ sort keys %user ],
2461     disabled_info => \%disabled_info,
2462     user_crossable => \@user_crossable,
2463 );
2464 my $configdata_outname = 'configdata.pm';
2465 print "Creating $configdata_outname\n";
2466 open CONFIGDATA, ">$configdata_outname.new"
2467             or die "Trying to create $configdata_outname.new: $!";
2468 my $configdata_tmplname = cleanfile($srcdir, "configdata.pm.in", $blddir);
2469 my $configdata_tmpl =
2470     OpenSSL::Template->new(TYPE => 'FILE', SOURCE => $configdata_tmplname);
2471 $configdata_tmpl->fill_in(
2472     FILENAME => $configdata_tmplname,
2473     OUTPUT => \*CONFIGDATA,
2474     HASH => { %template_vars,
2475               autowarntext => [
2476                   'WARNING: do not edit!',
2477                   "Generated by Configure from $configdata_tmplname",
2478               ] }
2479 ) or die $Text::Template::ERROR;
2480 close CONFIGDATA;
2481 rename "$configdata_outname.new", $configdata_outname;
2482 if ($builder_platform eq 'unix') {
2483     my $mode = (0755 & ~umask);
2484     chmod $mode, 'configdata.pm'
2485         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2486 }
2487
2488 print "Running $configdata_outname\n";
2489 my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
2490 my $cmd = "$perlcmd $configdata_outname";
2491 #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
2492 system($cmd);
2493 exit 1 if $? != 0;
2494
2495 $SIG{__DIE__} = $orig_death_handler;
2496
2497 print <<"EOF" if ($disabled{threads} eq "unavailable");
2498
2499 The library could not be configured for supporting multi-threaded
2500 applications as the compiler options required on this system are not known.
2501 See file INSTALL for details if you need multi-threading.
2502 EOF
2503
2504 print <<"EOF" if ($no_shared_warn);
2505
2506 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2507 platform, so we will pretend you gave the option 'no-pic', which also disables
2508 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2509 or position independent code, please let us know (but please first make sure
2510 you have tried with a current version of OpenSSL).
2511 EOF
2512
2513 print <<"EOF";
2514
2515 **********************************************************************
2516 ***                                                                ***
2517 ***   OpenSSL has been successfully configured                     ***
2518 ***                                                                ***
2519 ***   If you encounter a problem while building, please open an    ***
2520 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2521 ***   and include the output from the following command:           ***
2522 ***                                                                ***
2523 ***       perl configdata.pm --dump                                ***
2524 ***                                                                ***
2525 ***   (If you are new to OpenSSL, you might want to consult the    ***
2526 ***   'Troubleshooting' section in the INSTALL file first)         ***
2527 ***                                                                ***
2528 **********************************************************************
2529 EOF
2530
2531 exit(0);
2532
2533 ######################################################################
2534 #
2535 # Helpers and utility functions
2536 #
2537
2538 # Death handler, to print a helpful message in case of failure #######
2539 #
2540 sub death_handler {
2541     die @_ if $^S;              # To prevent the added message in eval blocks
2542     my $build_file = $target{build_file} // "build file";
2543     my @message = ( <<"_____", @_ );
2544
2545 Failure!  $build_file wasn't produced.
2546 Please read INSTALL and associated NOTES files.  You may also have to look over
2547 your available compiler tool chain or change your configuration.
2548
2549 _____
2550
2551     # Dying is terminal, so it's ok to reset the signal handler here.
2552     $SIG{__DIE__} = $orig_death_handler;
2553     die @message;
2554 }
2555
2556 # Configuration file reading #########################################
2557
2558 # Note: All of the helper functions are for lazy evaluation.  They all
2559 # return a CODE ref, which will return the intended value when evaluated.
2560 # Thus, whenever there's mention of a returned value, it's about that
2561 # intended value.
2562
2563 # Helper function to implement conditional value variants, with a default
2564 # plus additional values based on the value of $config{build_type}.
2565 # Arguments are given in hash table form:
2566 #
2567 #       picker(default => "Basic string: ",
2568 #              debug   => "debug",
2569 #              release => "release")
2570 #
2571 # When configuring with --debug, the resulting string will be
2572 # "Basic string: debug", and when not, it will be "Basic string: release"
2573 #
2574 # This can be used to create variants of sets of flags according to the
2575 # build type:
2576 #
2577 #       cflags => picker(default => "-Wall",
2578 #                        debug   => "-g -O0",
2579 #                        release => "-O3")
2580 #
2581 sub picker {
2582     my %opts = @_;
2583     return sub { add($opts{default} || (),
2584                      $opts{$config{build_type}} || ())->(); }
2585 }
2586
2587 # Helper function to combine several values of different types into one.
2588 # This is useful if you want to combine a string with the result of a
2589 # lazy function, such as:
2590 #
2591 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2592 #
2593 sub combine {
2594     my @stuff = @_;
2595     return sub { add(@stuff)->(); }
2596 }
2597
2598 # Helper function to implement conditional values depending on the value
2599 # of $disabled{threads}.  Can be used as follows:
2600 #
2601 #       cflags => combine("-Wall", threads("-pthread"))
2602 #
2603 sub threads {
2604     my @flags = @_;
2605     return sub { add($disabled{threads} ? () : @flags)->(); }
2606 }
2607
2608 sub shared {
2609     my @flags = @_;
2610     return sub { add($disabled{shared} ? () : @flags)->(); }
2611 }
2612
2613 our $add_called = 0;
2614 # Helper function to implement adding values to already existing configuration
2615 # values.  It handles elements that are ARRAYs, CODEs and scalars
2616 sub _add {
2617     my $separator = shift;
2618
2619     # If there's any ARRAY in the collection of values OR the separator
2620     # is undef, we will return an ARRAY of combined values, otherwise a
2621     # string of joined values with $separator as the separator.
2622     my $found_array = !defined($separator);
2623
2624     my @values =
2625         map {
2626             my $res = $_;
2627             while (ref($res) eq "CODE") {
2628                 $res = $res->();
2629             }
2630             if (defined($res)) {
2631                 if (ref($res) eq "ARRAY") {
2632                     $found_array = 1;
2633                     @$res;
2634                 } else {
2635                     $res;
2636                 }
2637             } else {
2638                 ();
2639             }
2640     } (@_);
2641
2642     $add_called = 1;
2643
2644     if ($found_array) {
2645         [ @values ];
2646     } else {
2647         join($separator, grep { defined($_) && $_ ne "" } @values);
2648     }
2649 }
2650 sub add_before {
2651     my $separator = " ";
2652     if (ref($_[$#_]) eq "HASH") {
2653         my $opts = pop;
2654         $separator = $opts->{separator};
2655     }
2656     my @x = @_;
2657     sub { _add($separator, @x, @_) };
2658 }
2659 sub add {
2660     my $separator = " ";
2661     if (ref($_[$#_]) eq "HASH") {
2662         my $opts = pop;
2663         $separator = $opts->{separator};
2664     }
2665     my @x = @_;
2666     sub { _add($separator, @_, @x) };
2667 }
2668
2669 sub read_eval_file {
2670     my $fname = shift;
2671     my $content;
2672     my @result;
2673
2674     open F, "< $fname" or die "Can't open '$fname': $!\n";
2675     {
2676         undef local $/;
2677         $content = <F>;
2678     }
2679     close F;
2680     {
2681         local $@;
2682
2683         @result = ( eval $content );
2684         warn $@ if $@;
2685     }
2686     return wantarray ? @result : $result[0];
2687 }
2688
2689 # configuration reader, evaluates the input file as a perl script and expects
2690 # it to fill %targets with target configurations.  Those are then added to
2691 # %table.
2692 sub read_config {
2693     my $fname = shift;
2694     my %targets;
2695
2696     {
2697         # Protect certain tables from tampering
2698         local %table = ();
2699
2700         %targets = read_eval_file($fname);
2701     }
2702     my %preexisting = ();
2703     foreach (sort keys %targets) {
2704         $preexisting{$_} = 1 if $table{$_};
2705     }
2706     die <<"EOF",
2707 The following config targets from $fname
2708 shadow pre-existing config targets with the same name:
2709 EOF
2710         map { "  $_\n" } sort keys %preexisting
2711         if %preexisting;
2712
2713
2714     # For each target, check that it's configured with a hash table.
2715     foreach (keys %targets) {
2716         if (ref($targets{$_}) ne "HASH") {
2717             if (ref($targets{$_}) eq "") {
2718                 warn "Deprecated target configuration for $_, ignoring...\n";
2719             } else {
2720                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
2721             }
2722             delete $targets{$_};
2723         } else {
2724             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
2725         }
2726     }
2727
2728     %table = (%table, %targets);
2729
2730 }
2731
2732 # configuration resolver.  Will only resolve all the lazy evaluation
2733 # codeblocks for the chosen target and all those it inherits from,
2734 # recursively
2735 sub resolve_config {
2736     my $target = shift;
2737     my @breadcrumbs = @_;
2738
2739 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
2740
2741     if (grep { $_ eq $target } @breadcrumbs) {
2742         die "inherit_from loop!  target backtrace:\n  "
2743             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
2744     }
2745
2746     if (!defined($table{$target})) {
2747         warn "Warning! target $target doesn't exist!\n";
2748         return ();
2749     }
2750     # Recurse through all inheritances.  They will be resolved on the
2751     # fly, so when this operation is done, they will all just be a
2752     # bunch of attributes with string values.
2753     # What we get here, though, are keys with references to lists of
2754     # the combined values of them all.  We will deal with lists after
2755     # this stage is done.
2756     my %combined_inheritance = ();
2757     if ($table{$target}->{inherit_from}) {
2758         my @inherit_from =
2759             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
2760         foreach (@inherit_from) {
2761             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
2762
2763             # 'template' is a marker that's considered private to
2764             # the config that had it.
2765             delete $inherited_config{template};
2766
2767             foreach (keys %inherited_config) {
2768                 if (!$combined_inheritance{$_}) {
2769                     $combined_inheritance{$_} = [];
2770                 }
2771                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
2772             }
2773         }
2774     }
2775
2776     # We won't need inherit_from in this target any more, since we've
2777     # resolved all the inheritances that lead to this
2778     delete $table{$target}->{inherit_from};
2779
2780     # Now is the time to deal with those lists.  Here's the place to
2781     # decide what shall be done with those lists, all based on the
2782     # values of the target we're currently dealing with.
2783     # - If a value is a coderef, it will be executed with the list of
2784     #   inherited values as arguments.
2785     # - If the corresponding key doesn't have a value at all or is the
2786     #   empty string, the inherited value list will be run through the
2787     #   default combiner (below), and the result becomes this target's
2788     #   value.
2789     # - Otherwise, this target's value is assumed to be a string that
2790     #   will simply override the inherited list of values.
2791     my $default_combiner = add();
2792
2793     my %all_keys =
2794         map { $_ => 1 } (keys %combined_inheritance,
2795                          keys %{$table{$target}});
2796
2797     sub process_values {
2798         my $object    = shift;
2799         my $inherited = shift;  # Always a [ list ]
2800         my $target    = shift;
2801         my $entry     = shift;
2802
2803         $add_called = 0;
2804
2805         while(ref($object) eq "CODE") {
2806             $object = $object->(@$inherited);
2807         }
2808         if (!defined($object)) {
2809             return ();
2810         }
2811         elsif (ref($object) eq "ARRAY") {
2812             local $add_called;  # To make sure recursive calls don't affect it
2813             return [ map { process_values($_, $inherited, $target, $entry) }
2814                      @$object ];
2815         } elsif (ref($object) eq "") {
2816             return $object;
2817         } else {
2818             die "cannot handle reference type ",ref($object)
2819                 ," found in target ",$target," -> ",$entry,"\n";
2820         }
2821     }
2822
2823     foreach (sort keys %all_keys) {
2824         my $previous = $combined_inheritance{$_};
2825
2826         # Current target doesn't have a value for the current key?
2827         # Assign it the default combiner, the rest of this loop body
2828         # will handle it just like any other coderef.
2829         if (!exists $table{$target}->{$_}) {
2830             $table{$target}->{$_} = $default_combiner;
2831         }
2832
2833         $table{$target}->{$_} = process_values($table{$target}->{$_},
2834                                                $combined_inheritance{$_},
2835                                                $target, $_);
2836         unless(defined($table{$target}->{$_})) {
2837             delete $table{$target}->{$_};
2838         }
2839 #        if ($extra_checks &&
2840 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
2841 #            warn "$_ got replaced in $target\n";
2842 #        }
2843     }
2844
2845     # Finally done, return the result.
2846     return %{$table{$target}};
2847 }
2848
2849 sub usage
2850         {
2851         print STDERR $usage;
2852         print STDERR "\npick os/compiler from:\n";
2853         my $j=0;
2854         my $i;
2855         my $k=0;
2856         foreach $i (sort keys %table)
2857                 {
2858                 next if $table{$i}->{template};
2859                 next if $i =~ /^debug/;
2860                 $k += length($i) + 1;
2861                 if ($k > 78)
2862                         {
2863                         print STDERR "\n";
2864                         $k=length($i);
2865                         }
2866                 print STDERR $i . " ";
2867                 }
2868         foreach $i (sort keys %table)
2869                 {
2870                 next if $table{$i}->{template};
2871                 next if $i !~ /^debug/;
2872                 $k += length($i) + 1;
2873                 if ($k > 78)
2874                         {
2875                         print STDERR "\n";
2876                         $k=length($i);
2877                         }
2878                 print STDERR $i . " ";
2879                 }
2880         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
2881         exit(1);
2882         }
2883
2884 sub compiler_predefined {
2885     state %predefined;
2886     my $cc = shift;
2887
2888     return () if $^O eq 'VMS';
2889
2890     die 'compiler_predefined called without a compiler command'
2891         unless $cc;
2892
2893     if (! $predefined{$cc}) {
2894
2895         $predefined{$cc} = {};
2896
2897         # collect compiler pre-defines from gcc or gcc-alike...
2898         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
2899         while (my $l = <PIPE>) {
2900             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
2901             $predefined{$cc}->{$1} = $2 // '';
2902         }
2903         close(PIPE);
2904     }
2905
2906     return %{$predefined{$cc}};
2907 }
2908
2909 sub which
2910 {
2911     my ($name)=@_;
2912
2913     if (eval { require IPC::Cmd; 1; }) {
2914         IPC::Cmd->import();
2915         return scalar IPC::Cmd::can_run($name);
2916     } else {
2917         # if there is $directories component in splitpath,
2918         # then it's not something to test with $PATH...
2919         return $name if (File::Spec->splitpath($name))[1];
2920
2921         foreach (File::Spec->path()) {
2922             my $fullpath = catfile($_, "$name$target{exe_extension}");
2923             if (-f $fullpath and -x $fullpath) {
2924                 return $fullpath;
2925             }
2926         }
2927     }
2928 }
2929
2930 sub env
2931 {
2932     my $name = shift;
2933     my %opts = @_;
2934
2935     unless ($opts{cacheonly}) {
2936         # Note that if $ENV{$name} doesn't exist or is undefined,
2937         # $config{perlenv}->{$name} will be created with the value
2938         # undef.  This is intentional.
2939
2940         $config{perlenv}->{$name} = $ENV{$name}
2941             if ! exists $config{perlenv}->{$name};
2942     }
2943     return $config{perlenv}->{$name};
2944 }
2945
2946 # Configuration printer ##############################################
2947
2948 sub print_table_entry
2949 {
2950     local $now_printing = shift;
2951     my %target = resolve_config($now_printing);
2952     my $type = shift;
2953
2954     # Don't print the templates
2955     return if $target{template};
2956
2957     my @sequence = (
2958         "sys_id",
2959         "cpp",
2960         "cppflags",
2961         "defines",
2962         "includes",
2963         "cc",
2964         "cflags",
2965         "ld",
2966         "lflags",
2967         "loutflag",
2968         "ex_libs",
2969         "bn_ops",
2970         "poly1035_asm_src",
2971         "thread_scheme",
2972         "perlasm_scheme",
2973         "dso_scheme",
2974         "shared_target",
2975         "shared_cflag",
2976         "shared_defines",
2977         "shared_ldflag",
2978         "shared_rcflag",
2979         "shared_extension",
2980         "dso_extension",
2981         "obj_extension",
2982         "exe_extension",
2983         "ranlib",
2984         "ar",
2985         "arflags",
2986         "aroutflag",
2987         "rc",
2988         "rcflags",
2989         "rcoutflag",
2990         "mt",
2991         "mtflags",
2992         "mtinflag",
2993         "mtoutflag",
2994         "multilib",
2995         "build_scheme",
2996         );
2997
2998     if ($type eq "TABLE") {
2999         print "\n";
3000         print "*** $now_printing\n";
3001         foreach (@sequence) {
3002             if (ref($target{$_}) eq "ARRAY") {
3003                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3004             } else {
3005                 printf "\$%-12s = %s\n", $_, $target{$_};
3006             }
3007         }
3008     } elsif ($type eq "HASH") {
3009         my $largest =
3010             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3011         print "    '$now_printing' => {\n";
3012         foreach (@sequence) {
3013             if ($target{$_}) {
3014                 if (ref($target{$_}) eq "ARRAY") {
3015                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3016                 } else {
3017                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3018                 }
3019             }
3020         }
3021         print "    },\n";
3022     }
3023 }
3024
3025 # Utility routines ###################################################
3026
3027 # On VMS, if the given file is a logical name, File::Spec::Functions
3028 # will consider it an absolute path.  There are cases when we want a
3029 # purely syntactic check without checking the environment.
3030 sub isabsolute {
3031     my $file = shift;
3032
3033     # On non-platforms, we just use file_name_is_absolute().
3034     return file_name_is_absolute($file) unless $^O eq "VMS";
3035
3036     # If the file spec includes a device or a directory spec,
3037     # file_name_is_absolute() is perfectly safe.
3038     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3039
3040     # Here, we know the given file spec isn't absolute
3041     return 0;
3042 }
3043
3044 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3045 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3046 # realpath() requires that at least all path components except the last is an
3047 # existing directory.  On VMS, the last component of the directory spec must
3048 # exist.
3049 sub absolutedir {
3050     my $dir = shift;
3051
3052     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3053     # will return the volume name for the device, no matter what.  Also,
3054     # it will return an incorrect directory spec if the argument is a
3055     # directory that doesn't exist.
3056     if ($^O eq "VMS") {
3057         return rel2abs($dir);
3058     }
3059
3060     # We use realpath() on Unix, since no other will properly clean out
3061     # a directory spec.
3062     use Cwd qw/realpath/;
3063
3064     return realpath($dir);
3065 }
3066
3067 sub quotify {
3068     my %processors = (
3069         perl    => sub { my $x = shift;
3070                          $x =~ s/([\\\$\@"])/\\$1/g;
3071                          return '"'.$x.'"'; },
3072         maybeshell => sub { my $x = shift;
3073                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3074                             if ($x ne $y || $x =~ m|\s|) {
3075                                 return '"'.$y.'"';
3076                             } else {
3077                                 return $x;
3078                             }
3079                         },
3080         );
3081     my $for = shift;
3082     my $processor =
3083         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3084
3085     return map { $processor->($_); } @_;
3086 }
3087
3088 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3089 # $filename is a file name to read from
3090 # $line_concat_cond_re is a regexp detecting a line continuation ending
3091 # $line_concat is a CODEref that takes care of concatenating two lines
3092 sub collect_from_file {
3093     my $filename = shift;
3094     my $line_concat_cond_re = shift;
3095     my $line_concat = shift;
3096
3097     open my $fh, $filename || die "unable to read $filename: $!\n";
3098     return sub {
3099         my $saved_line = "";
3100         $_ = "";
3101         while (<$fh>) {
3102             s|\R$||;
3103             if (defined $line_concat) {
3104                 $_ = $line_concat->($saved_line, $_);
3105                 $saved_line = "";
3106             }
3107             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3108                 $saved_line = $_;
3109                 next;
3110             }
3111             return $_;
3112         }
3113         die "$filename ending with continuation line\n" if $_;
3114         close $fh;
3115         return undef;
3116     }
3117 }
3118
3119 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3120 # $array is an ARRAYref of lines
3121 # $line_concat_cond_re is a regexp detecting a line continuation ending
3122 # $line_concat is a CODEref that takes care of concatenating two lines
3123 sub collect_from_array {
3124     my $array = shift;
3125     my $line_concat_cond_re = shift;
3126     my $line_concat = shift;
3127     my @array = (@$array);
3128
3129     return sub {
3130         my $saved_line = "";
3131         $_ = "";
3132         while (defined($_ = shift @array)) {
3133             s|\R$||;
3134             if (defined $line_concat) {
3135                 $_ = $line_concat->($saved_line, $_);
3136                 $saved_line = "";
3137             }
3138             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3139                 $saved_line = $_;
3140                 next;
3141             }
3142             return $_;
3143         }
3144         die "input text ending with continuation line\n" if $_;
3145         return undef;
3146     }
3147 }
3148
3149 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3150 # $lineiterator is a CODEref that delivers one line at a time.
3151 # All following arguments are regex/CODEref pairs, where the regexp detects a
3152 # line and the CODEref does something with the result of the regexp.
3153 sub collect_information {
3154     my $lineiterator = shift;
3155     my %collectors = @_;
3156
3157     while(defined($_ = $lineiterator->())) {
3158         s|\R$||;
3159         my $found = 0;
3160         if ($collectors{"BEFORE"}) {
3161             $collectors{"BEFORE"}->($_);
3162         }
3163         foreach my $re (keys %collectors) {
3164             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3165                 $collectors{$re}->($lineiterator);
3166                 $found = 1;
3167             };
3168         }
3169         if ($collectors{"OTHERWISE"}) {
3170             $collectors{"OTHERWISE"}->($lineiterator, $_)
3171                 unless $found || !defined $collectors{"OTHERWISE"};
3172         }
3173         if ($collectors{"AFTER"}) {
3174             $collectors{"AFTER"}->($_);
3175         }
3176     }
3177 }
3178
3179 # tokenize($line)
3180 # tokenize($line,$separator)
3181 # $line is a line of text to split up into tokens
3182 # $separator [optional] is a regular expression that separates the tokens,
3183 # the default being spaces.  Do not use quotes of any kind as separators,
3184 # that will give undefined results.
3185 # Returns a list of tokens.
3186 #
3187 # Tokens are divided by separator (spaces by default).  If the tokens include
3188 # the separators, they have to be quoted with single or double quotes.
3189 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3190 # with backslash.
3191 # Basically, the same quoting rules apply for " and ' as in any
3192 # Unix shell.
3193 sub tokenize {
3194     my $line = my $debug_line = shift;
3195     my $separator = shift // qr|\s+|;
3196     my @result = ();
3197
3198     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3199         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3200     }
3201
3202     while ($line =~ s|^${separator}||, $line ne "") {
3203         my $token = "";
3204     again:
3205         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3206         $token .= $1;
3207         $line = $2.$';
3208
3209         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3210             $token .= $1;
3211             $line = $';
3212             goto again;
3213         } elsif ($line =~ m/^'([^']*)'/) {
3214             $token .= $1;
3215             $line = $';
3216             goto again;
3217         }
3218         push @result, $token;
3219     }
3220
3221     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3222         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3223         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3224     }
3225     return @result;
3226 }