Configure

   1 #! /usr/bin/env perl
   2 # -*- mode: perl; -*-
   3 # Copyright 2016-2018 The OpenSSL Project Authors. All Rights Reserved.
   4 #
   5 # Licensed under the Apache License 2.0 (the "License").  You may not use
   6 # this file except in compliance with the License.  You can obtain a copy
   7 # in the file LICENSE in the source distribution or at
   8 # https://www.openssl.org/source/license.html
   9
  10 ##  Configure -- OpenSSL source tree configuration script
  11
  12 use 5.10.0;
  13 use strict;
  14 use Config;
  15 use FindBin;
  16 use lib "$FindBin::Bin/util/perl";
  17 use File::Basename;
  18 use File::Spec::Functions qw/:DEFAULT abs2rel rel2abs splitdir/;
  19 use File::Path qw/mkpath/;
  20 use OpenSSL::Glob;
  21
  22 # see INSTALL for instructions.
  23
  24 my $orig_death_handler = $SIG{__DIE__};
  25 $SIG{__DIE__} = \&death_handler;
  26
  27 my $usage="Usage: Configure [no-<cipher> ...] [enable-<cipher> ...] [-Dxxx] [-lxxx] [-Lxxx] [-fxxx] [-Kxxx] [no-hw-xxx|no-hw] [[no-]threads] [[no-]shared] [[no-]zlib|zlib-dynamic] [no-asm] [no-egd] [sctp] [386] [--prefix=DIR] [--openssldir=OPENSSLDIR] [--with-xxx[=vvv]] [--config=FILE] os/compiler[:flags]\n";
  28
  29 # Options:
  30 #
  31 # --config      add the given configuration file, which will be read after
  32 #               any "Configurations*" files that are found in the same
  33 #               directory as this script.
  34 # --prefix      prefix for the OpenSSL installation, which includes the
  35 #               directories bin, lib, include, share/man, share/doc/openssl
  36 #               This becomes the value of INSTALLTOP in Makefile
  37 #               (Default: /usr/local)
  38 # --openssldir  OpenSSL data area, such as openssl.cnf, certificates and keys.
  39 #               If it's a relative directory, it will be added on the directory
  40 #               given with --prefix.
  41 #               This becomes the value of OPENSSLDIR in Makefile and in C.
  42 #               (Default: PREFIX/ssl)
  43 #
  44 # --cross-compile-prefix Add specified prefix to binutils components.
  45 #
  46 # --api         One of 0.9.8, 1.0.0, 1.0.1, 1.0.2, 1.1.0, 1.1.1, or 3.0.0 / 3.
  47 #               Do not compile support for interfaces deprecated as of the
  48 #               specified OpenSSL version.
  49 #
  50 # no-hw-xxx     do not compile support for specific crypto hardware.
  51 #               Generic OpenSSL-style methods relating to this support
  52 #               are always compiled but return NULL if the hardware
  53 #               support isn't compiled.
  54 # no-hw         do not compile support for any crypto hardware.
  55 # [no-]threads  [don't] try to create a library that is suitable for
  56 #               multithreaded applications (default is "threads" if we
  57 #               know how to do it)
  58 # [no-]shared   [don't] try to create shared libraries when supported.
  59 # [no-]pic      [don't] try to build position independent code when supported.
  60 #               If disabled, it also disables shared and dynamic-engine.
  61 # no-asm        do not use assembler
  62 # no-egd        do not compile support for the entropy-gathering daemon APIs
  63 # [no-]zlib     [don't] compile support for zlib compression.
  64 # zlib-dynamic  Like "zlib", but the zlib library is expected to be a shared
  65 #               library and will be loaded in run-time by the OpenSSL library.
  66 # sctp          include SCTP support
  67 # no-uplink     Don't build support for UPLINK interface.
  68 # enable-weak-ssl-ciphers
  69 #               Enable weak ciphers that are disabled by default.
  70 # 386           generate 80386 code in assembly modules
  71 # no-sse2       disables IA-32 SSE2 code in assembly modules, the above
  72 #               mentioned '386' option implies this one
  73 # no-<cipher>   build without specified algorithm (rsa, idea, rc5, ...)
  74 # -<xxx> +<xxx> compiler options are passed through
  75 # -static       while -static is also a pass-through compiler option (and
  76 #               as such is limited to environments where it's actually
  77 #               meaningful), it triggers a number configuration options,
  78 #               namely no-pic, no-shared and no-threads. It is
  79 #               argued that the only reason to produce statically linked
  80 #               binaries (and in context it means executables linked with
  81 #               -static flag, and not just executables linked with static
  82 #               libcrypto.a) is to eliminate dependency on specific run-time,
  83 #               a.k.a. libc version. The mentioned config options are meant
  84 #               to achieve just that. Unfortunately on Linux it's impossible
  85 #               to eliminate the dependency completely for openssl executable
  86 #               because of getaddrinfo and gethostbyname calls, which can
  87 #               invoke dynamically loadable library facility anyway to meet
  88 #               the lookup requests. For this reason on Linux statically
  89 #               linked openssl executable has rather debugging value than
  90 #               production quality.
  91 #
  92 # BN_LLONG      use the type 'long long' in crypto/bn/bn.h
  93 # RC4_CHAR      use 'char' instead of 'int' for RC4_INT in crypto/rc4/rc4.h
  94 # Following are set automatically by this script
  95 #
  96 # MD5_ASM       use some extra md5 assembler,
  97 # SHA1_ASM      use some extra sha1 assembler, must define L_ENDIAN for x86
  98 # RMD160_ASM    use some extra ripemd160 assembler,
  99 # SHA256_ASM    sha256_block is implemented in assembler
 100 # SHA512_ASM    sha512_block is implemented in assembler
 101 # AES_ASM       AES_[en|de]crypt is implemented in assembler
 102
 103 # Minimum warning options... any contributions to OpenSSL should at least
 104 # get past these.  Note that we only use these with C compilers, not with
 105 # C++ compilers.
 106
 107 # DEBUG_UNUSED enables __owur (warn unused result) checks.
 108 # -DPEDANTIC complements -pedantic and is meant to mask code that
 109 # is not strictly standard-compliant and/or implementation-specific,
 110 # e.g. inline assembly, disregards to alignment requirements, such
 111 # that -pedantic would complain about. Incidentally -DPEDANTIC has
 112 # to be used even in sanitized builds, because sanitizer too is
 113 # supposed to and does take notice of non-standard behaviour. Then
 114 # -pedantic with pre-C9x compiler would also complain about 'long
 115 # long' not being supported. As 64-bit algorithms are common now,
 116 # it grew impossible to resolve this without sizeable additional
 117 # code, so we just tell compiler to be pedantic about everything
 118 # but 'long long' type.
 119
 120 my @gcc_devteam_warn = qw(
 121     -DDEBUG_UNUSED
 122     -DPEDANTIC -pedantic -Wno-long-long
 123     -Wall
 124     -Wextra
 125     -Wno-unused-parameter
 126     -Wno-missing-field-initializers
 127     -Wswitch
 128     -Wsign-compare
 129     -Wshadow
 130     -Wformat
 131     -Wtype-limits
 132     -Wundef
 133     -Werror
 134     -Wmissing-prototypes
 135     -Wstrict-prototypes
 136 );
 137
 138 # These are used in addition to $gcc_devteam_warn when the compiler is clang.
 139 # TODO(openssl-team): fix problems and investigate if (at least) the
 140 # following warnings can also be enabled:
 141 #       -Wcast-align
 142 #       -Wunreachable-code -- no, too ugly/compiler-specific
 143 #       -Wlanguage-extension-token -- no, we use asm()
 144 #       -Wunused-macros -- no, too tricky for BN and _XOPEN_SOURCE etc
 145 #       -Wextended-offsetof -- no, needed in CMS ASN1 code
 146 my @clang_devteam_warn = qw(
 147     -Wswitch-default
 148     -Wno-parentheses-equality
 149     -Wno-language-extension-token
 150     -Wno-extended-offsetof
 151     -Wconditional-uninitialized
 152     -Wincompatible-pointer-types-discards-qualifiers
 153     -Wno-unknown-warning-option
 154     -Wmissing-variable-declarations
 155 );
 156
 157 # This adds backtrace information to the memory leak info.  Is only used
 158 # when crypto-mdebug-backtrace is enabled.
 159 my $memleak_devteam_backtrace = "-rdynamic";
 160
 161 my $strict_warnings = 0;
 162
 163 # As for $BSDthreads. Idea is to maintain "collective" set of flags,
 164 # which would cover all BSD flavors. -pthread applies to them all,
 165 # but is treated differently. OpenBSD expands is as -D_POSIX_THREAD
 166 # -lc_r, which is sufficient. FreeBSD 4.x expands it as -lc_r,
 167 # which has to be accompanied by explicit -D_THREAD_SAFE and
 168 # sometimes -D_REENTRANT. FreeBSD 5.x expands it as -lc_r, which
 169 # seems to be sufficient?
 170 our $BSDthreads="-pthread -D_THREAD_SAFE -D_REENTRANT";
 171
 172 #
 173 # API compatibility name to version number mapping.
 174 #
 175 my $maxapi = "3.0.0";           # API for "no-deprecated" builds
 176 my $apitable = {
 177     "3.0.0" => 3,
 178     "1.1.1" => 2,
 179     "1.1.0" => 2,
 180     "1.0.2" => 1,
 181     "1.0.1" => 1,
 182     "1.0.0" => 1,
 183     "0.9.8" => 0,
 184 };
 185
 186 our %table = ();
 187 our %config = ();
 188 our %withargs = ();
 189 our $now_printing;      # set to current entry's name in print_table_entry
 190                         # (todo: right thing would be to encapsulate name
 191                         # into %target [class] and make print_table_entry
 192                         # a method)
 193
 194 # Forward declarations ###############################################
 195
 196 # read_config(filename)
 197 #
 198 # Reads a configuration file and populates %table with the contents
 199 # (which the configuration file places in %targets).
 200 sub read_config;
 201
 202 # resolve_config(target)
 203 #
 204 # Resolves all the late evaluations, inheritances and so on for the
 205 # chosen target and any target it inherits from.
 206 sub resolve_config;
 207
 208
 209 # Information collection #############################################
 210
 211 # Unified build supports separate build dir
 212 my $srcdir = catdir(absolutedir(dirname($0))); # catdir ensures local syntax
 213 my $blddir = catdir(absolutedir("."));         # catdir ensures local syntax
 214 my $dofile = abs2rel(catfile($srcdir, "util/dofile.pl"));
 215
 216 my $local_config_envname = 'OPENSSL_LOCAL_CONFIG_DIR';
 217
 218 $config{sourcedir} = abs2rel($srcdir);
 219 $config{builddir} = abs2rel($blddir);
 220
 221 # Collect reconfiguration information if needed
 222 my @argvcopy=@ARGV;
 223
 224 if (grep /^reconf(igure)?$/, @argvcopy) {
 225     die "reconfiguring with other arguments present isn't supported"
 226         if scalar @argvcopy > 1;
 227     if (-f "./configdata.pm") {
 228         my $file = "./configdata.pm";
 229         unless (my $return = do $file) {
 230             die "couldn't parse $file: $@" if $@;
 231             die "couldn't do $file: $!"    unless defined $return;
 232             die "couldn't run $file"       unless $return;
 233         }
 234
 235         @argvcopy = defined($configdata::config{perlargv}) ?
 236             @{$configdata::config{perlargv}} : ();
 237         die "Incorrect data to reconfigure, please do a normal configuration\n"
 238             if (grep(/^reconf/,@argvcopy));
 239         $config{perlenv} = $configdata::config{perlenv} // {};
 240     } else {
 241         die "Insufficient data to reconfigure, please do a normal configuration\n";
 242     }
 243 }
 244
 245 $config{perlargv} = [ @argvcopy ];
 246
 247 # Collect version numbers
 248 $config{major} = "unknown";
 249 $config{minor} = "unknown";
 250 $config{patch} = "unknown";
 251 $config{prerelease} = "";
 252 $config{build_metadata} = "";
 253 $config{shlib_version} = "unknown";
 254
 255 collect_information(
 256     collect_from_file(catfile($srcdir,'include/openssl/opensslv.h')),
 257     qr/#\s+define\s+OPENSSL_VERSION_MAJOR\s+(\d+)/ =>
 258         sub { $config{major} = $1; },
 259     qr/#\s+define\s+OPENSSL_VERSION_MINOR\s+(\d+)/ =>
 260         sub { $config{minor} = $1; },
 261     qr/#\s+define\s+OPENSSL_VERSION_PATCH\s+(\d+)/ =>
 262         sub { $config{patch} = $1; },
 263     qr/#\s+define\s+OPENSSL_VERSION_PRE_RELEASE\s+"((?:\\.|[^"])*)"/ =>
 264         sub { $config{prerelease} = $1; },
 265     qr/#\s+define\s+OPENSSL_VERSION_BUILD_METADATA\s+"((?:\\.|[^"])*)"/ =>
 266         sub { $config{build_metadata} = $1; },
 267     qr/#\s+define\s+OPENSSL_SHLIB_VERSION\s+([\d\.]+)/ =>
 268         sub { $config{shlib_version} = $1; },
 269     );
 270 die "erroneous version information in opensslv.h: ",
 271     "$config{major}.$config{minor}.$config{patch}, $config{shlib_version}\n"
 272     if ($config{major} eq "unknown"
 273             || $config{minor} eq "unknown"
 274             || $config{patch} eq "unknown"
 275             || $config{shlib_version} eq "unknown");
 276
 277 $config{version} = "$config{major}.$config{minor}.$config{patch}";
 278 $config{full_version} = "$config{version}$config{prerelease}$config{build_metadata}";
 279
 280 # Collect target configurations
 281
 282 my $pattern = catfile(dirname($0), "Configurations", "*.conf");
 283 foreach (sort glob($pattern)) {
 284     &read_config($_);
 285 }
 286
 287 if (defined env($local_config_envname)) {
 288     if ($^O eq 'VMS') {
 289         # VMS environment variables are logical names,
 290         # which can be used as is
 291         $pattern = $local_config_envname . ':' . '*.conf';
 292     } else {
 293         $pattern = catfile(env($local_config_envname), '*.conf');
 294     }
 295
 296     foreach (sort glob($pattern)) {
 297         &read_config($_);
 298     }
 299 }
 300
 301 # Save away perl command information
 302 $config{perl_cmd} = $^X;
 303 $config{perl_version} = $Config{version};
 304 $config{perl_archname} = $Config{archname};
 305
 306 $config{prefix}="";
 307 $config{openssldir}="";
 308 $config{processor}="";
 309 $config{libdir}="";
 310 my $auto_threads=1;    # enable threads automatically? true by default
 311 my $default_ranlib;
 312
 313 # Known TLS and DTLS protocols
 314 my @tls = qw(ssl3 tls1 tls1_1 tls1_2 tls1_3);
 315 my @dtls = qw(dtls1 dtls1_2);
 316
 317 # Explicitly known options that are possible to disable.  They can
 318 # be regexps, and will be used like this: /^no-${option}$/
 319 # For developers: keep it sorted alphabetically
 320
 321 my @disablables = (
 322     "ktls",
 323     "afalgeng",
 324     "aria",
 325     "asan",
 326     "asm",
 327     "async",
 328     "autoalginit",
 329     "autoerrinit",
 330     "autoload-config",
 331     "bf",
 332     "blake2",
 333     "buildtest-c++",
 334     "camellia",
 335     "capieng",
 336     "cast",
 337     "chacha",
 338     "cmac",
 339     "cmp",
 340     "cms",
 341     "comp",
 342     "crypto-mdebug",
 343     "crypto-mdebug-backtrace",
 344     "ct",
 345     "deprecated",
 346     "des",
 347     "devcryptoeng",
 348     "dgram",
 349     "dh",
 350     "dsa",
 351     "dtls",
 352     "dynamic-engine",
 353     "ec",
 354     "ec2m",
 355     "ecdh",
 356     "ecdsa",
 357     "ec_nistp_64_gcc_128",
 358     "egd",
 359     "engine",
 360     "err",
 361     "external-tests",
 362     "filenames",
 363     "fips",
 364     "fuzz-libfuzzer",
 365     "fuzz-afl",
 366     "gost",
 367     "idea",
 368     "legacy",
 369     "makedepend",
 370     "md2",
 371     "md4",
 372     "mdc2",
 373     "module",
 374     "msan",
 375     "multiblock",
 376     "nextprotoneg",
 377     "pinshared",
 378     "ocb",
 379     "ocsp",
 380     "padlockeng",
 381     "pic",
 382     "poly1305",
 383     "posix-io",
 384     "psk",
 385     "rc2",
 386     "rc4",
 387     "rc5",
 388     "rdrand",
 389     "rfc3779",
 390     "rmd160",
 391     "scrypt",
 392     "sctp",
 393     "seed",
 394     "shared",
 395     "siphash",
 396     "siv",
 397     "sm2",
 398     "sm3",
 399     "sm4",
 400     "sock",
 401     "srp",
 402     "srtp",
 403     "sse2",
 404     "ssl",
 405     "ssl-trace",
 406     "static-engine",
 407     "stdio",
 408     "tests",
 409     "threads",
 410     "tls",
 411     "trace",
 412     "ts",
 413     "ubsan",
 414     "ui-console",
 415     "unit-test",
 416     "uplink",
 417     "whirlpool",
 418     "weak-ssl-ciphers",
 419     "zlib",
 420     "zlib-dynamic",
 421     );
 422 foreach my $proto ((@tls, @dtls))
 423         {
 424         push(@disablables, $proto);
 425         push(@disablables, "$proto-method") unless $proto eq "tls1_3";
 426         }
 427
 428 # Internal disablables, for aliasing purposes.  They serve no special
 429 # purpose here, but allow scripts to get to know them through configdata.pm,
 430 # where these are merged with @disablables.
 431 # The actual aliasing mechanism is done via %disable_cascades
 432 my @disablables_int = qw(
 433     crmf
 434     );
 435
 436 my %deprecated_disablables = (
 437     "ssl2" => undef,
 438     "buf-freelists" => undef,
 439     "hw" => "hw",               # causes cascade, but no macro
 440     "hw-padlock" => "padlockeng",
 441     "ripemd" => "rmd160",
 442     "ui" => "ui-console",
 443     "dso" => undef,
 444     "heartbeats" => undef,
 445     );
 446
 447 # All of the following are disabled by default:
 448
 449 our %disabled = ( # "what"         => "comment"
 450                   "asan"                => "default",
 451                   "buildtest-c++"       => "default",
 452                   "crypto-mdebug"       => "default",
 453                   "crypto-mdebug-backtrace" => "default",
 454                   "devcryptoeng"        => "default",
 455                   "ec_nistp_64_gcc_128" => "default",
 456                   "egd"                 => "default",
 457                   "external-tests"      => "default",
 458                   "fuzz-libfuzzer"      => "default",
 459                   "fuzz-afl"            => "default",
 460                   "md2"                 => "default",
 461                   "msan"                => "default",
 462                   "rc5"                 => "default",
 463                   "sctp"                => "default",
 464                   "ssl-trace"           => "default",
 465                   "ssl3"                => "default",
 466                   "ssl3-method"         => "default",
 467                   "trace"               => "default",
 468                   "ubsan"               => "default",
 469                   "unit-test"           => "default",
 470                   "weak-ssl-ciphers"    => "default",
 471                   "zlib"                => "default",
 472                   "zlib-dynamic"        => "default",
 473                   "ktls"                => "default",
 474                 );
 475
 476 # Note: => pair form used for aesthetics, not to truly make a hash table
 477 my @disable_cascades = (
 478     # "what"            => [ "cascade", ... ]
 479     sub { $config{processor} eq "386" }
 480                         => [ "sse2" ],
 481     "ssl"               => [ "ssl3" ],
 482     "ssl3-method"       => [ "ssl3" ],
 483     "zlib"              => [ "zlib-dynamic" ],
 484     "des"               => [ "mdc2" ],
 485     "ec"                => [ "ecdsa", "ecdh", "sm2" ],
 486     sub { $disabled{"ec"} && $disabled{"dh"} }
 487                         => [ "tls1_3" ],
 488     "dgram"             => [ "dtls", "sctp" ],
 489     "sock"              => [ "dgram" ],
 490     "dtls"              => [ @dtls ],
 491     sub { 0 == scalar grep { !$disabled{$_} } @dtls }
 492                         => [ "dtls" ],
 493
 494     "tls"               => [ @tls ],
 495     sub { 0 == scalar grep { !$disabled{$_} } @tls }
 496                         => [ "tls" ],
 497
 498     "crypto-mdebug"     => [ "crypto-mdebug-backtrace" ],
 499
 500     # If no modules, then no dynamic engines either
 501     "module"            => [ "dynamic-engine" ],
 502
 503     # Without shared libraries, dynamic engines aren't possible.
 504     # This is due to them having to link with libcrypto and register features
 505     # using the ENGINE functionality, and since that relies on global tables,
 506     # those *have* to be exacty the same as the ones accessed from the app,
 507     # which cannot be guaranteed if shared libraries aren't present.
 508     # (note that even with shared libraries, both the app and dynamic engines
 509     # must be linked with the same library)
 510     "shared"            => [ "dynamic-engine", "uplink" ],
 511     # Other modules don't necessarily have to link with libcrypto, so shared
 512     # libraries do not have to be a condition to produce those.
 513
 514     # Without position independent code, there can be no shared libraries
 515     # or modules.
 516     "pic"               => [ "shared", "module" ],
 517
 518     "module"            => [ "fips", "legacy" ],
 519
 520     "engine"            => [ grep /eng$/, @disablables ],
 521     "hw"                => [ "padlockeng" ],
 522
 523     # no-autoalginit is only useful when building non-shared
 524     "autoalginit"       => [ "shared", "apps" ],
 525
 526     "stdio"             => [ "apps", "capieng", "egd" ],
 527     "apps"              => [ "tests" ],
 528     "tests"             => [ "external-tests" ],
 529     "comp"              => [ "zlib" ],
 530     "sm3"               => [ "sm2" ],
 531     sub { !$disabled{"unit-test"} } => [ "heartbeats" ],
 532
 533     sub { !$disabled{"msan"} } => [ "asm" ],
 534
 535     sub { $disabled{cmac}; } => [ "siv" ],
 536     "legacy"                 => [ "md2" ],
 537
 538     "cmp"               => [ "crmf" ],
 539     );
 540
 541 # Avoid protocol support holes.  Also disable all versions below N, if version
 542 # N is disabled while N+1 is enabled.
 543 #
 544 my @list = (reverse @tls);
 545 while ((my $first, my $second) = (shift @list, shift @list)) {
 546     last unless @list;
 547     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 548                               => [ @list ] );
 549     unshift @list, $second;
 550 }
 551 my @list = (reverse @dtls);
 552 while ((my $first, my $second) = (shift @list, shift @list)) {
 553     last unless @list;
 554     push @disable_cascades, ( sub { !$disabled{$first} && $disabled{$second} }
 555                               => [ @list ] );
 556     unshift @list, $second;
 557 }
 558
 559 # Explicit "no-..." options will be collected in %disabled along with the defaults.
 560 # To remove something from %disabled, use "enable-foo".
 561 # For symmetry, "disable-foo" is a synonym for "no-foo".
 562
 563 &usage if ($#ARGV < 0);
 564
 565 # For the "make variables" CINCLUDES and CDEFINES, we support lists with
 566 # platform specific list separators.  Users from those platforms should
 567 # recognise those separators from how you set up the PATH to find executables.
 568 # The default is the Unix like separator, :, but as an exception, we also
 569 # support the space as separator.
 570 my $list_separator_re =
 571     { VMS           => qr/(?<!\^),/,
 572       MSWin32       => qr/(?<!\\);/ } -> {$^O} // qr/(?<!\\)[:\s]/;
 573 # All the "make variables" we support
 574 # Some get pre-populated for the sake of backward compatibility
 575 # (we supported those before the change to "make variable" support.
 576 my %user = (
 577     AR          => env('AR'),
 578     ARFLAGS     => [],
 579     AS          => undef,
 580     ASFLAGS     => [],
 581     CC          => env('CC'),
 582     CFLAGS      => [ env('CFLAGS') || () ],
 583     CXX         => env('CXX'),
 584     CXXFLAGS    => [ env('CXXFLAGS') || () ],
 585     CPP         => undef,
 586     CPPFLAGS    => [ env('CPPFLAGS') || () ],  # -D, -I, -Wp,
 587     CPPDEFINES  => [],  # Alternative for -D
 588     CPPINCLUDES => [],  # Alternative for -I
 589     CROSS_COMPILE => env('CROSS_COMPILE'),
 590     HASHBANGPERL=> env('HASHBANGPERL') || env('PERL'),
 591     LD          => undef,
 592     LDFLAGS     => [ env('LDFLAGS') || () ],  # -L, -Wl,
 593     LDLIBS      => [ env('LDLIBS') || () ],  # -l
 594     MT          => undef,
 595     MTFLAGS     => [],
 596     PERL        => env('PERL') || ($^O ne "VMS" ? $^X : "perl"),
 597     RANLIB      => env('RANLIB'),
 598     RC          => env('RC') || env('WINDRES'),
 599     RCFLAGS     => [ env('RCFLAGS') || () ],
 600     RM          => undef,
 601    );
 602 # Info about what "make variables" may be prefixed with the cross compiler
 603 # prefix.  This should NEVER mention any such variable with a list for value.
 604 my @user_crossable = qw ( AR AS CC CXX CPP LD MT RANLIB RC );
 605 # The same but for flags given as Configure options.  These are *additional*
 606 # input, as opposed to the VAR=string option that override the corresponding
 607 # config target attributes
 608 my %useradd = (
 609     CPPDEFINES  => [],
 610     CPPINCLUDES => [],
 611     CPPFLAGS    => [],
 612     CFLAGS      => [],
 613     CXXFLAGS    => [],
 614     LDFLAGS     => [],
 615     LDLIBS      => [],
 616     RCFLAGS     => [],
 617    );
 618
 619 my %user_synonyms = (
 620     HASHBANGPERL=> 'PERL',
 621     RC          => 'WINDRES',
 622    );
 623
 624 # Some target attributes have been renamed, this is the translation table
 625 my %target_attr_translate =(
 626     ar          => 'AR',
 627     as          => 'AS',
 628     cc          => 'CC',
 629     cxx         => 'CXX',
 630     cpp         => 'CPP',
 631     hashbangperl => 'HASHBANGPERL',
 632     ld          => 'LD',
 633     mt          => 'MT',
 634     ranlib      => 'RANLIB',
 635     rc          => 'RC',
 636     rm          => 'RM',
 637    );
 638
 639 # Initialisers coming from 'config' scripts
 640 $config{defines} = [ split(/$list_separator_re/, env('__CNF_CPPDEFINES')) ];
 641 $config{includes} = [ split(/$list_separator_re/, env('__CNF_CPPINCLUDES')) ];
 642 $config{cppflags} = [ env('__CNF_CPPFLAGS') || () ];
 643 $config{cflags} = [ env('__CNF_CFLAGS') || () ];
 644 $config{cxxflags} = [ env('__CNF_CXXFLAGS') || () ];
 645 $config{lflags} = [ env('__CNF_LDFLAGS') || () ];
 646 $config{ex_libs} = [ env('__CNF_LDLIBS') || () ];
 647
 648 $config{openssl_api_defines}=[];
 649 $config{openssl_sys_defines}=[];
 650 $config{openssl_feature_defines}=[];
 651 $config{options}="";
 652 $config{build_type} = "release";
 653 my $target="";
 654
 655 my %cmdvars = ();               # Stores FOO='blah' type arguments
 656 my %unsupported_options = ();
 657 my %deprecated_options = ();
 658 # If you change this, update apps/version.c
 659 my @known_seed_sources = qw(getrandom devrandom os egd none rdcpu librandom);
 660 my @seed_sources = ();
 661 while (@argvcopy)
 662         {
 663         $_ = shift @argvcopy;
 664
 665         # Support env variable assignments among the options
 666         if (m|^(\w+)=(.+)?$|)
 667                 {
 668                 $cmdvars{$1} = $2;
 669                 # Every time a variable is given as a configuration argument,
 670                 # it acts as a reset if the variable.
 671                 if (exists $user{$1})
 672                         {
 673                         $user{$1} = ref $user{$1} eq "ARRAY" ? [] : undef;
 674                         }
 675                 #if (exists $useradd{$1})
 676                 #       {
 677                 #       $useradd{$1} = [];
 678                 #       }
 679                 next;
 680                 }
 681
 682         # VMS is a case insensitive environment, and depending on settings
 683         # out of our control, we may receive options uppercased.  Let's
 684         # downcase at least the part before any equal sign.
 685         if ($^O eq "VMS")
 686                 {
 687                 s/^([^=]*)/lc($1)/e;
 688                 }
 689
 690         # some people just can't read the instructions, clang people have to...
 691         s/^-no-(?!integrated-as)/no-/;
 692
 693         # rewrite some options in "enable-..." form
 694         s /^-?-?shared$/enable-shared/;
 695         s /^sctp$/enable-sctp/;
 696         s /^threads$/enable-threads/;
 697         s /^zlib$/enable-zlib/;
 698         s /^zlib-dynamic$/enable-zlib-dynamic/;
 699
 700         if (/^(no|disable|enable)-(.+)$/)
 701                 {
 702                 my $word = $2;
 703                 if ($word !~ m|hw(?:-.+)| # special treatment for hw regexp opt
 704                         && !exists $deprecated_disablables{$word}
 705                         && !grep { $word eq $_ } @disablables)
 706                         {
 707                         $unsupported_options{$_} = 1;
 708                         next;
 709                         }
 710                 }
 711         if (/^no-(.+)$/ || /^disable-(.+)$/)
 712                 {
 713                 foreach my $proto ((@tls, @dtls))
 714                         {
 715                         if ($1 eq "$proto-method")
 716                                 {
 717                                 $disabled{"$proto"} = "option($proto-method)";
 718                                 last;
 719                                 }
 720                         }
 721                 if ($1 eq "dtls")
 722                         {
 723                         foreach my $proto (@dtls)
 724                                 {
 725                                 $disabled{$proto} = "option(dtls)";
 726                                 }
 727                         $disabled{"dtls"} = "option(dtls)";
 728                         }
 729                 elsif ($1 eq "ssl")
 730                         {
 731                         # Last one of its kind
 732                         $disabled{"ssl3"} = "option(ssl)";
 733                         }
 734                 elsif ($1 eq "tls")
 735                         {
 736                         # XXX: Tests will fail if all SSL/TLS
 737                         # protocols are disabled.
 738                         foreach my $proto (@tls)
 739                                 {
 740                                 $disabled{$proto} = "option(tls)";
 741                                 }
 742                         }
 743                 elsif ($1 eq "static-engine")
 744                         {
 745                         delete $disabled{"dynamic-engine"};
 746                         }
 747                 elsif ($1 eq "dynamic-engine")
 748                         {
 749                         $disabled{"dynamic-engine"} = "option";
 750                         }
 751                 elsif (exists $deprecated_disablables{$1})
 752                         {
 753                         $deprecated_options{$_} = 1;
 754                         if (defined $deprecated_disablables{$1})
 755                                 {
 756                                 $disabled{$deprecated_disablables{$1}} = "option";
 757                                 }
 758                         }
 759                 elsif ($1 =~ m|hw(?:-.+)|) # deprecate hw options in regexp form
 760                         {
 761                         $deprecated_options{$_} = 1;
 762                         }
 763                 else
 764                         {
 765                         $disabled{$1} = "option";
 766                         }
 767                 # No longer an automatic choice
 768                 $auto_threads = 0 if ($1 eq "threads");
 769                 }
 770         elsif (/^enable-(.+)$/)
 771                 {
 772                 if ($1 eq "static-engine")
 773                         {
 774                         $disabled{"dynamic-engine"} = "option";
 775                         }
 776                 elsif ($1 eq "dynamic-engine")
 777                         {
 778                         delete $disabled{"dynamic-engine"};
 779                         }
 780                 elsif ($1 eq "zlib-dynamic")
 781                         {
 782                         delete $disabled{"zlib"};
 783                         }
 784                 my $algo = $1;
 785                 delete $disabled{$algo};
 786
 787                 # No longer an automatic choice
 788                 $auto_threads = 0 if ($1 eq "threads");
 789                 }
 790         elsif (/^--strict-warnings$/)
 791                 {
 792                 # Pretend that our strict flags is a C flag, and replace it
 793                 # with the proper flags later on
 794                 push @{$useradd{CFLAGS}}, '--ossl-strict-warnings';
 795                 $strict_warnings=1;
 796                 }
 797         elsif (/^--debug$/)
 798                 {
 799                 $config{build_type} = "debug";
 800                 }
 801         elsif (/^--release$/)
 802                 {
 803                 $config{build_type} = "release";
 804                 }
 805         elsif (/^386$/)
 806                 { $config{processor}=386; }
 807         elsif (/^fips$/)
 808                 {
 809                 die "FIPS mode not supported\n";
 810                 }
 811         elsif (/^rsaref$/)
 812                 {
 813                 # No RSAref support any more since it's not needed.
 814                 # The check for the option is there so scripts aren't
 815                 # broken
 816                 }
 817         elsif (/^nofipscanistercheck$/)
 818                 {
 819                 die "FIPS mode not supported\n";
 820                 }
 821         elsif (/^[-+]/)
 822                 {
 823                 if (/^--prefix=(.*)$/)
 824                         {
 825                         $config{prefix}=$1;
 826                         die "Directory given with --prefix MUST be absolute\n"
 827                                 unless file_name_is_absolute($config{prefix});
 828                         }
 829                 elsif (/^--api=(.*)$/)
 830                         {
 831                         $config{api}=$1;
 832                         }
 833                 elsif (/^--libdir=(.*)$/)
 834                         {
 835                         $config{libdir}=$1;
 836                         }
 837                 elsif (/^--openssldir=(.*)$/)
 838                         {
 839                         $config{openssldir}=$1;
 840                         }
 841                 elsif (/^--with-zlib-lib=(.*)$/)
 842                         {
 843                         $withargs{zlib_lib}=$1;
 844                         }
 845                 elsif (/^--with-zlib-include=(.*)$/)
 846                         {
 847                         $withargs{zlib_include}=$1;
 848                         }
 849                 elsif (/^--with-fuzzer-lib=(.*)$/)
 850                         {
 851                         $withargs{fuzzer_lib}=$1;
 852                         }
 853                 elsif (/^--with-fuzzer-include=(.*)$/)
 854                         {
 855                         $withargs{fuzzer_include}=$1;
 856                         }
 857                 elsif (/^--with-rand-seed=(.*)$/)
 858                         {
 859                         foreach my $x (split(m|,|, $1))
 860                             {
 861                             die "Unknown --with-rand-seed choice $x\n"
 862                                 if ! grep { $x eq $_ } @known_seed_sources;
 863                             push @seed_sources, $x;
 864                             }
 865                         }
 866                 elsif (/^--cross-compile-prefix=(.*)$/)
 867                         {
 868                         $user{CROSS_COMPILE}=$1;
 869                         }
 870                 elsif (/^--config=(.*)$/)
 871                         {
 872                         read_config $1;
 873                         }
 874                 elsif (/^-l(.*)$/)
 875                         {
 876                         push @{$useradd{LDLIBS}}, $_;
 877                         }
 878                 elsif (/^-framework$/)
 879                         {
 880                         push @{$useradd{LDLIBS}}, $_, shift(@argvcopy);
 881                         }
 882                 elsif (/^-L(.*)$/ or /^-Wl,/)
 883                         {
 884                         push @{$useradd{LDFLAGS}}, $_;
 885                         }
 886                 elsif (/^-rpath$/ or /^-R$/)
 887                         # -rpath is the OSF1 rpath flag
 888                         # -R is the old Solaris rpath flag
 889                         {
 890                         my $rpath = shift(@argvcopy) || "";
 891                         $rpath .= " " if $rpath ne "";
 892                         push @{$useradd{LDFLAGS}}, $_, $rpath;
 893                         }
 894                 elsif (/^-static$/)
 895                         {
 896                         push @{$useradd{LDFLAGS}}, $_;
 897                         }
 898                 elsif (/^-D(.*)$/)
 899                         {
 900                         push @{$useradd{CPPDEFINES}}, $1;
 901                         }
 902                 elsif (/^-I(.*)$/)
 903                         {
 904                         push @{$useradd{CPPINCLUDES}}, $1;
 905                         }
 906                 elsif (/^-Wp,$/)
 907                         {
 908                         push @{$useradd{CPPFLAGS}}, $1;
 909                         }
 910                 else    # common if (/^[-+]/), just pass down...
 911                         {
 912                         $_ =~ s/%([0-9a-f]{1,2})/chr(hex($1))/gei;
 913                         push @{$useradd{CFLAGS}}, $_;
 914                         push @{$useradd{CXXFLAGS}}, $_;
 915                         }
 916                 }
 917         else
 918                 {
 919                 die "target already defined - $target (offending arg: $_)\n" if ($target ne "");
 920                 $target=$_;
 921                 }
 922         unless ($_ eq $target || /^no-/ || /^disable-/)
 923                 {
 924                 # "no-..." follows later after implied deactivations
 925                 # have been derived.  (Don't take this too seriously,
 926                 # we really only write OPTIONS to the Makefile out of
 927                 # nostalgia.)
 928
 929                 if ($config{options} eq "")
 930                         { $config{options} = $_; }
 931                 else
 932                         { $config{options} .= " ".$_; }
 933                 }
 934         }
 935
 936 if (defined($config{api}) && !exists $apitable->{$config{api}}) {
 937         die "***** Unsupported api compatibility level: $config{api}\n",
 938 }
 939
 940 if (keys %deprecated_options)
 941         {
 942         warn "***** Deprecated options: ",
 943                 join(", ", keys %deprecated_options), "\n";
 944         }
 945 if (keys %unsupported_options)
 946         {
 947         die "***** Unsupported options: ",
 948                 join(", ", keys %unsupported_options), "\n";
 949         }
 950
 951 # If any %useradd entry has been set, we must check that the "make
 952 # variables" haven't been set.  We start by checking of any %useradd entry
 953 # is set.
 954 if (grep { scalar @$_ > 0 } values %useradd) {
 955     # Hash of env / make variables names.  The possible values are:
 956     # 1 - "make vars"
 957     # 2 - %useradd entry set
 958     # 3 - both set
 959     my %detected_vars =
 960         map { my $v = 0;
 961               $v += 1 if $cmdvars{$_};
 962               $v += 2 if @{$useradd{$_}};
 963               $_ => $v }
 964         keys %useradd;
 965
 966     # If any of the corresponding "make variables" is set, we error
 967     if (grep { $_ & 1 } values %detected_vars) {
 968         my $names = join(', ', grep { $detected_vars{$_} > 0 }
 969                                sort keys %detected_vars);
 970         die <<"_____";
 971 ***** Mixing make variables and additional compiler/linker flags as
 972 ***** configure command line option is not permitted.
 973 ***** Affected make variables: $names
 974 _____
 975     }
 976 }
 977
 978 # Check through all supported command line variables to see if any of them
 979 # were set, and canonicalise the values we got.  If no compiler or linker
 980 # flag or anything else that affects %useradd was set, we also check the
 981 # environment for values.
 982 my $anyuseradd =
 983     grep { defined $_ && (ref $_ ne 'ARRAY' || @$_) } values %useradd;
 984 foreach (keys %user) {
 985     my $value = $cmdvars{$_};
 986     $value //= env($_) unless $anyuseradd;
 987     $value //=
 988         defined $user_synonyms{$_} ? $cmdvars{$user_synonyms{$_}} : undef;
 989     $value //= defined $user_synonyms{$_} ? env($user_synonyms{$_}) : undef
 990         unless $anyuseradd;
 991
 992     if (defined $value) {
 993         if (ref $user{$_} eq 'ARRAY') {
 994             $user{$_} = [ split /$list_separator_re/, $value ];
 995         } elsif (!defined $user{$_}) {
 996             $user{$_} = $value;
 997         }
 998     }
 999 }
1000
1001 if (grep { /-rpath\b/ } ($user{LDFLAGS} ? @{$user{LDFLAGS}} : ())
1002     && !$disabled{shared}
1003     && !($disabled{asan} && $disabled{msan} && $disabled{ubsan})) {
1004     die "***** Cannot simultaneously use -rpath, shared libraries, and\n",
1005         "***** any of asan, msan or ubsan\n";
1006 }
1007
1008 sub disable {
1009     my $disable_type = shift;
1010
1011     for (@_) {
1012         $disabled{$_} = $disable_type;
1013     }
1014
1015     my @tocheckfor = (@_ ? @_ : keys %disabled);
1016     while (@tocheckfor) {
1017         my %new_tocheckfor = ();
1018         my @cascade_copy = (@disable_cascades);
1019         while (@cascade_copy) {
1020             my ($test, $descendents) =
1021                 (shift @cascade_copy, shift @cascade_copy);
1022             if (ref($test) eq "CODE" ? $test->() : defined($disabled{$test})) {
1023                 foreach (grep { !defined($disabled{$_}) } @$descendents) {
1024                     $new_tocheckfor{$_} = 1; $disabled{$_} = "cascade";
1025                 }
1026             }
1027         }
1028         @tocheckfor = (keys %new_tocheckfor);
1029     }
1030 }
1031 disable();                     # First cascade run
1032
1033 our $die = sub { die @_; };
1034 if ($target eq "TABLE") {
1035     local $die = sub { warn @_; };
1036     foreach (sort keys %table) {
1037         print_table_entry($_, "TABLE");
1038     }
1039     exit 0;
1040 }
1041
1042 if ($target eq "LIST") {
1043     foreach (sort keys %table) {
1044         print $_,"\n" unless $table{$_}->{template};
1045     }
1046     exit 0;
1047 }
1048
1049 if ($target eq "HASH") {
1050     local $die = sub { warn @_; };
1051     print "%table = (\n";
1052     foreach (sort keys %table) {
1053         print_table_entry($_, "HASH");
1054     }
1055     exit 0;
1056 }
1057
1058 print "Configuring OpenSSL version $config{full_version} ";
1059 print "for target $target\n";
1060
1061 if (scalar(@seed_sources) == 0) {
1062     print "Using os-specific seed configuration\n";
1063     push @seed_sources, 'os';
1064 }
1065 if (scalar(grep { $_ eq 'none' } @seed_sources) > 0) {
1066     die "Cannot seed with none and anything else" if scalar(@seed_sources) > 1;
1067     warn <<_____ if scalar(@seed_sources) == 1;
1068
1069 ============================== WARNING ===============================
1070 You have selected the --with-rand-seed=none option, which effectively
1071 disables automatic reseeding of the OpenSSL random generator.
1072 All operations depending on the random generator such as creating keys
1073 will not work unless the random generator is seeded manually by the
1074 application.
1075
1076 Please read the 'Note on random number generation' section in the
1077 INSTALL instructions and the RAND_DRBG(7) manual page for more details.
1078 ============================== WARNING ===============================
1079
1080 _____
1081 }
1082 push @{$config{openssl_feature_defines}},
1083      map { (my $x = $_) =~ tr|[\-a-z]|[_A-Z]|; "OPENSSL_RAND_SEED_$x" }
1084         @seed_sources;
1085
1086 # Backward compatibility?
1087 if ($target =~ m/^CygWin32(-.*)$/) {
1088     $target = "Cygwin".$1;
1089 }
1090
1091 # Support for legacy targets having a name starting with 'debug-'
1092 my ($d, $t) = $target =~ m/^(debug-)?(.*)$/;
1093 if ($d) {
1094     $config{build_type} = "debug";
1095
1096     # If we do not find debug-foo in the table, the target is set to foo.
1097     if (!$table{$target}) {
1098         $target = $t;
1099     }
1100 }
1101
1102 &usage if !$table{$target} || $table{$target}->{template};
1103
1104 $config{target} = $target;
1105 my %target = resolve_config($target);
1106
1107 foreach (keys %target_attr_translate) {
1108     $target{$target_attr_translate{$_}} = $target{$_}
1109         if $target{$_};
1110     delete $target{$_};
1111 }
1112
1113 %target = ( %{$table{DEFAULTS}}, %target );
1114
1115 my %conf_files = map { $_ => 1 } (@{$target{_conf_fname_int}});
1116 $config{conf_files} = [ sort keys %conf_files ];
1117
1118 # Using sub disable within these loops may prove fragile, so we run
1119 # a cascade afterwards
1120 foreach my $feature (@{$target{disable}}) {
1121     if (exists $deprecated_disablables{$feature}) {
1122         warn "***** config $target disables deprecated feature $feature\n";
1123     } elsif (!grep { $feature eq $_ } @disablables) {
1124         die "***** config $target disables unknown feature $feature\n";
1125     }
1126     $disabled{$feature} = 'config';
1127 }
1128 foreach my $feature (@{$target{enable}}) {
1129     if ("default" eq ($disabled{$feature} // "")) {
1130         if (exists $deprecated_disablables{$feature}) {
1131             warn "***** config $target enables deprecated feature $feature\n";
1132         } elsif (!grep { $feature eq $_ } @disablables) {
1133             die "***** config $target enables unknown feature $feature\n";
1134         }
1135         delete $disabled{$feature};
1136     }
1137 }
1138
1139 # If uplink_arch isn't defined, disable uplink
1140 $disabled{uplink} = 'no uplink_arch' unless (defined $target{uplink_arch});
1141 # If asm_arch isn't defined, disable asm
1142 $disabled{asm} = 'no asm_arch' unless (defined $target{asm_arch});
1143
1144 disable();                      # Run a cascade now
1145
1146 $target{CXXFLAGS}//=$target{CFLAGS} if $target{CXX};
1147 $target{cxxflags}//=$target{cflags} if $target{CXX};
1148 $target{exe_extension}=".exe" if ($config{target} eq "DJGPP");
1149 $target{exe_extension}=".pm"  if ($config{target} =~ /vos/);
1150
1151 # Fill %config with values from %user, and in case those are undefined or
1152 # empty, use values from %target (acting as a default).
1153 foreach (keys %user) {
1154     my $ref_type = ref $user{$_};
1155
1156     # Temporary function.  Takes an intended ref type (empty string or "ARRAY")
1157     # and a value that's to be coerced into that type.
1158     my $mkvalue = sub {
1159         my $type = shift;
1160         my $value = shift;
1161         my $undef_p = shift;
1162
1163         die "Too many arguments for \$mkvalue" if @_;
1164
1165         while (ref $value eq 'CODE') {
1166             $value = $value->();
1167         }
1168
1169         if ($type eq 'ARRAY') {
1170             return undef unless defined $value;
1171             return undef if ref $value ne 'ARRAY' && !$value;
1172             return undef if ref $value eq 'ARRAY' && !@$value;
1173             return [ $value ] unless ref $value eq 'ARRAY';
1174         }
1175         return undef unless $value;
1176         return $value;
1177     };
1178
1179     $config{$_} =
1180         $mkvalue->($ref_type, $user{$_})
1181         || $mkvalue->($ref_type, $target{$_});
1182     delete $config{$_} unless defined $config{$_};
1183 }
1184
1185 # Finish up %config by appending things the user gave us on the command line
1186 # apart from "make variables"
1187 foreach (keys %useradd) {
1188     # The must all be lists, so we assert that here
1189     die "internal error: \$useradd{$_} isn't an ARRAY\n"
1190         unless ref $useradd{$_} eq 'ARRAY';
1191
1192     if (defined $config{$_}) {
1193         push @{$config{$_}}, @{$useradd{$_}};
1194     } else {
1195         $config{$_} = [ @{$useradd{$_}} ];
1196     }
1197 }
1198 # At this point, we can forget everything about %user and %useradd,
1199 # because it's now all been merged into the corresponding $config entry
1200
1201 # Allow overriding the build file name
1202 $config{build_file} = env('BUILDFILE') || $target{build_file} || "Makefile";
1203
1204 ######################################################################
1205 # Build up information for skipping certain directories depending on disabled
1206 # features, as well as setting up macros for disabled features.
1207
1208 # This is a tentative database of directories to skip.  Some entries may not
1209 # correspond to anything real, but that's ok, they will simply be ignored.
1210 # The actual processing of these entries is done in the build.info lookup
1211 # loop further down.
1212 #
1213 # The key is a Unix formated path in the source tree, the value is an index
1214 # into %disabled_info, so any existing path gets added to a corresponding
1215 # 'skipped' entry in there with the list of skipped directories.
1216 my %skipdir = ();
1217 my %disabled_info = ();         # For configdata.pm
1218 foreach my $what (sort keys %disabled) {
1219     # There are deprecated disablables that translate to themselves.
1220     # They cause disabling cascades, but should otherwise not regiter.
1221     next if $deprecated_disablables{$what};
1222
1223     $config{options} .= " no-$what";
1224
1225     if (!grep { $what eq $_ } ( 'buildtest-c++', 'fips', 'threads', 'shared',
1226                                 'module', 'pic', 'dynamic-engine', 'makedepend',
1227                                 'zlib-dynamic', 'zlib', 'sse2', 'legacy' )) {
1228         (my $WHAT = uc $what) =~ s|-|_|g;
1229         my $skipdir = $what;
1230
1231         # fix-up crypto/directory name(s)
1232         $skipdir = "ripemd" if $what eq "rmd160";
1233         $skipdir = "whrlpool" if $what eq "whirlpool";
1234
1235         my $macro = $disabled_info{$what}->{macro} = "OPENSSL_NO_$WHAT";
1236         push @{$config{openssl_feature_defines}}, $macro;
1237
1238         $skipdir{engines} = $what if $what eq 'engine';
1239         $skipdir{"crypto/$skipdir"} = $what
1240             unless $what eq 'async' || $what eq 'err';
1241     }
1242 }
1243
1244 # Make sure build_scheme is consistent.
1245 $target{build_scheme} = [ $target{build_scheme} ]
1246     if ref($target{build_scheme}) ne "ARRAY";
1247
1248 my ($builder, $builder_platform, @builder_opts) =
1249     @{$target{build_scheme}};
1250
1251 foreach my $checker (($builder_platform."-".$target{build_file}."-checker.pm",
1252                       $builder_platform."-checker.pm")) {
1253     my $checker_path = catfile($srcdir, "Configurations", $checker);
1254     if (-f $checker_path) {
1255         my $fn = $ENV{CONFIGURE_CHECKER_WARN}
1256             ? sub { warn $@; } : sub { die $@; };
1257         if (! do $checker_path) {
1258             if ($@) {
1259                 $fn->($@);
1260             } elsif ($!) {
1261                 $fn->($!);
1262             } else {
1263                 $fn->("The detected tools didn't match the platform\n");
1264             }
1265         }
1266         last;
1267     }
1268 }
1269
1270 push @{$config{defines}}, "NDEBUG"    if $config{build_type} eq "release";
1271
1272 if ($target =~ /^mingw/ && `$config{CC} --target-help 2>&1` =~ m/-mno-cygwin/m)
1273         {
1274         push @{$config{cflags}}, "-mno-cygwin";
1275         push @{$config{cxxflags}}, "-mno-cygwin" if $config{CXX};
1276         push @{$config{shared_ldflag}}, "-mno-cygwin";
1277         }
1278
1279 if ($target =~ /linux.*-mips/ && !$disabled{asm}
1280         && !grep { $_ !~ /-m(ips|arch=)/ } (@{$config{CFLAGS}})) {
1281         # minimally required architecture flags for assembly modules
1282         my $value;
1283         $value = '-mips2' if ($target =~ /mips32/);
1284         $value = '-mips3' if ($target =~ /mips64/);
1285         unshift @{$config{cflags}}, $value;
1286         unshift @{$config{cxxflags}}, $value if $config{CXX};
1287 }
1288
1289 # If threads aren't disabled, check how possible they are
1290 unless ($disabled{threads}) {
1291     if ($auto_threads) {
1292         # Enabled by default, disable it forcibly if unavailable
1293         if ($target{thread_scheme} eq "(unknown)") {
1294             disable("unavailable", 'threads');
1295         }
1296     } else {
1297         # The user chose to enable threads explicitly, let's see
1298         # if there's a chance that's possible
1299         if ($target{thread_scheme} eq "(unknown)") {
1300             # If the user asked for "threads" and we don't have internal
1301             # knowledge how to do it, [s]he is expected to provide any
1302             # system-dependent compiler options that are necessary.  We
1303             # can't truly check that the given options are correct, but
1304             # we expect the user to know what [s]He is doing.
1305             if (!@{$config{CFLAGS}} && !@{$config{CPPDEFINES}}) {
1306                 die "You asked for multi-threading support, but didn't\n"
1307                     ,"provide any system-specific compiler options\n";
1308             }
1309         }
1310     }
1311 }
1312
1313 # Find out if clang's sanitizers have been enabled with -fsanitize
1314 # flags and ensure that the corresponding %disabled elements area
1315 # removed to reflect that the sanitizers are indeed enabled.
1316 my %detected_sanitizers = ();
1317 foreach (grep /^-fsanitize=/, @{$config{CFLAGS} || []}) {
1318     (my $checks = $_) =~ s/^-fsanitize=//;
1319     foreach (split /,/, $checks) {
1320         my $d = { address       => 'asan',
1321                   undefined     => 'ubsan',
1322                   memory        => 'msan' } -> {$_};
1323         next unless defined $d;
1324
1325         $detected_sanitizers{$d} = 1;
1326         if (defined $disabled{$d}) {
1327             die "***** Conflict between disabling $d and enabling $_ sanitizer"
1328                 if $disabled{$d} ne "default";
1329             delete $disabled{$d};
1330         }
1331     }
1332 }
1333
1334 # If threads still aren't disabled, add a C macro to ensure the source
1335 # code knows about it.  Any other flag is taken care of by the configs.
1336 unless($disabled{threads}) {
1337     push @{$config{openssl_feature_defines}}, "OPENSSL_THREADS";
1338 }
1339
1340 # With "deprecated" disable all deprecated features.
1341 if (defined($disabled{"deprecated"})) {
1342         $config{api} = $maxapi;
1343 }
1344
1345 my $no_shared_warn=0;
1346 if ($target{shared_target} eq "")
1347         {
1348         $no_shared_warn = 1
1349             if (!$disabled{shared} || !$disabled{"dynamic-engine"});
1350         disable('no-shared-target', 'pic');
1351         }
1352
1353 if ($disabled{"dynamic-engine"}) {
1354         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_DYNAMIC_ENGINE";
1355         $config{dynamic_engines} = 0;
1356 } else {
1357         push @{$config{openssl_feature_defines}}, "OPENSSL_NO_STATIC_ENGINE";
1358         $config{dynamic_engines} = 1;
1359 }
1360
1361 unless ($disabled{asan} || defined $detected_sanitizers{asan}) {
1362     push @{$config{cflags}}, "-fsanitize=address";
1363 }
1364
1365 unless ($disabled{ubsan} || defined $detected_sanitizers{ubsan}) {
1366     # -DPEDANTIC or -fnosanitize=alignment may also be required on some
1367     # platforms.
1368     push @{$config{cflags}}, "-fsanitize=undefined", "-fno-sanitize-recover=all";
1369 }
1370
1371 unless ($disabled{msan} || defined $detected_sanitizers{msan}) {
1372   push @{$config{cflags}}, "-fsanitize=memory";
1373 }
1374
1375 unless ($disabled{"fuzz-libfuzzer"} && $disabled{"fuzz-afl"}
1376         && $disabled{asan} && $disabled{ubsan} && $disabled{msan}) {
1377     push @{$config{cflags}}, "-fno-omit-frame-pointer", "-g";
1378     push @{$config{cxxflags}}, "-fno-omit-frame-pointer", "-g" if $config{CXX};
1379 }
1380 #
1381 # Platform fix-ups
1382 #
1383
1384 # This saves the build files from having to check
1385 if ($disabled{pic})
1386         {
1387         foreach (qw(shared_cflag shared_cxxflag shared_cppflag
1388                     shared_defines shared_includes shared_ldflag
1389                     module_cflags module_cxxflags module_cppflags
1390                     module_defines module_includes module_lflags))
1391                 {
1392                 delete $config{$_};
1393                 $target{$_} = "";
1394                 }
1395         }
1396 else
1397         {
1398         push @{$config{lib_defines}}, "OPENSSL_PIC";
1399         }
1400
1401 if ($target{sys_id} ne "")
1402         {
1403         push @{$config{openssl_sys_defines}}, "OPENSSL_SYS_$target{sys_id}";
1404         }
1405
1406 unless ($disabled{asm}) {
1407     if ($target{keccak1600_asm_src} ne $table{DEFAULTS}->{keccak1600_asm_src}) {
1408         push @{$config{lib_defines}}, "KECCAK1600_ASM";
1409     }
1410     if ($target{rc4_asm_src} ne $table{DEFAULTS}->{rc4_asm_src}) {
1411         push @{$config{lib_defines}}, "RC4_ASM";
1412     }
1413     $target{cast_asm_src}=$table{DEFAULTS}->{cast_asm_src} unless $disabled{pic}; # CAST assembler is not PIC
1414     if ($target{rmd160_asm_src}) {
1415         push @{$config{lib_defines}}, "RMD160_ASM";
1416     }
1417     if ($target{wp_asm_src} =~ /mmx/) {
1418         if ($config{processor} eq "386") {
1419             $target{wp_asm_src}=$table{DEFAULTS}->{wp_asm_src};
1420         } elsif (!$disabled{"whirlpool"}) {
1421             push @{$config{lib_defines}}, "WHIRLPOOL_ASM";
1422         }
1423     }
1424     if ($target{modes_asm_src} =~ /ghash-/) {
1425         push @{$config{lib_defines}}, "GHASH_ASM";
1426     }
1427     if ($target{padlock_asm_src} ne $table{DEFAULTS}->{padlock_asm_src}) {
1428         push @{$config{dso_defines}}, "PADLOCK_ASM";
1429     }
1430     if ($target{poly1305_asm_src} ne "") {
1431         push @{$config{lib_defines}}, "POLY1305_ASM";
1432     }
1433 }
1434
1435 my %predefined_C = compiler_predefined($config{CROSS_COMPILE}.$config{CC});
1436 my %predefined_CXX = $config{CXX}
1437     ? compiler_predefined($config{CROSS_COMPILE}.$config{CXX})
1438     : ();
1439
1440 # Check for makedepend capabilities.
1441 if (!$disabled{makedepend}) {
1442     if ($config{target} =~ /^(VC|vms)-/) {
1443         # For VC- and vms- targets, there's nothing more to do here.  The
1444         # functionality is hard coded in the corresponding build files for
1445         # cl (Windows) and CC/DECC (VMS).
1446     } elsif (($predefined_C{__GNUC__} // -1) >= 3
1447              && !($predefined_C{__APPLE_CC__} && !$predefined_C{__clang__})) {
1448         # We know that GNU C version 3 and up as well as all clang
1449         # versions support dependency generation, but Xcode did not
1450         # handle $cc -M before clang support (but claims __GNUC__ = 3)
1451         $config{makedepprog} = "\$(CROSS_COMPILE)$config{CC}";
1452     } else {
1453         # In all other cases, we look for 'makedepend', and disable the
1454         # capability if not found.
1455         $config{makedepprog} = which('makedepend');
1456         disable('unavailable', 'makedepend') unless $config{makedepprog};
1457     }
1458 }
1459
1460 if (!$disabled{asm} && !$predefined_C{__MACH__} && $^O ne 'VMS') {
1461     # probe for -Wa,--noexecstack option...
1462     if ($predefined_C{__clang__}) {
1463         # clang has builtin assembler, which doesn't recognize --help,
1464         # but it apparently recognizes the option in question on all
1465         # supported platforms even when it's meaningless. In other words
1466         # probe would fail, but probed option always accepted...
1467         push @{$config{cflags}}, "-Wa,--noexecstack", "-Qunused-arguments";
1468     } else {
1469         my $cc = $config{CROSS_COMPILE}.$config{CC};
1470         open(PIPE, "$cc -Wa,--help -c -o null.$$.o -x assembler /dev/null 2>&1 |");
1471         while(<PIPE>) {
1472             if (m/--noexecstack/) {
1473                 push @{$config{cflags}}, "-Wa,--noexecstack";
1474                 last;
1475             }
1476         }
1477         close(PIPE);
1478         unlink("null.$$.o");
1479     }
1480 }
1481
1482 # Deal with bn_ops ###################################################
1483
1484 $config{bn_ll}                  =0;
1485 $config{export_var_as_fn}       =0;
1486 my $def_int="unsigned int";
1487 $config{rc4_int}                =$def_int;
1488 ($config{b64l},$config{b64},$config{b32})=(0,0,1);
1489
1490 my $count = 0;
1491 foreach (sort split(/\s+/,$target{bn_ops})) {
1492     $count++ if /SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT/;
1493     $config{export_var_as_fn}=1                 if $_ eq 'EXPORT_VAR_AS_FN';
1494     $config{bn_ll}=1                            if $_ eq 'BN_LLONG';
1495     $config{rc4_int}="unsigned char"            if $_ eq 'RC4_CHAR';
1496     ($config{b64l},$config{b64},$config{b32})
1497         =(0,1,0)                                if $_ eq 'SIXTY_FOUR_BIT';
1498     ($config{b64l},$config{b64},$config{b32})
1499         =(1,0,0)                                if $_ eq 'SIXTY_FOUR_BIT_LONG';
1500     ($config{b64l},$config{b64},$config{b32})
1501         =(0,0,1)                                if $_ eq 'THIRTY_TWO_BIT';
1502 }
1503 die "Exactly one of SIXTY_FOUR_BIT|SIXTY_FOUR_BIT_LONG|THIRTY_TWO_BIT can be set in bn_ops\n"
1504     if $count > 1;
1505
1506
1507 # Hack cflags for better warnings (dev option) #######################
1508
1509 # "Stringify" the C and C++ flags string.  This permits it to be made part of
1510 # a string and works as well on command lines.
1511 $config{cflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1512                         @{$config{cflags}} ];
1513 $config{cxxflags} = [ map { (my $x = $_) =~ s/([\\\"])/\\$1/g; $x }
1514                           @{$config{cxxflags}} ] if $config{CXX};
1515
1516 $config{openssl_api_defines} = [
1517     "OPENSSL_MIN_API=".($apitable->{$config{api} // ""} // -1)
1518 ];
1519
1520 my @strict_warnings_collection=();
1521 if ($strict_warnings)
1522         {
1523         my $wopt;
1524         my $gccver = $predefined_C{__GNUC__} // -1;
1525
1526         warn "WARNING --strict-warnings requires gcc[>=4] or gcc-alike"
1527             unless $gccver >= 4;
1528         push @strict_warnings_collection, @gcc_devteam_warn;
1529         push @strict_warnings_collection, @clang_devteam_warn
1530             if (defined($predefined_C{__clang__}));
1531         }
1532
1533 if (grep { $_ eq '-static' } @{$config{LDFLAGS}}) {
1534     disable('static', 'pic', 'threads');
1535 }
1536
1537 $config{CFLAGS} = [ map { $_ eq '--ossl-strict-warnings'
1538                               ? @strict_warnings_collection
1539                               : ( $_ ) }
1540                     @{$config{CFLAGS}} ];
1541
1542 unless ($disabled{"crypto-mdebug-backtrace"})
1543         {
1544         foreach my $wopt (split /\s+/, $memleak_devteam_backtrace)
1545                 {
1546                 push @{$config{cflags}}, $wopt
1547                         unless grep { $_ eq $wopt } @{$config{cflags}};
1548                 }
1549         if ($target =~ /^BSD-/)
1550                 {
1551                 push @{$config{ex_libs}}, "-lexecinfo";
1552                 }
1553         }
1554
1555 unless ($disabled{afalgeng}) {
1556     $config{afalgeng}="";
1557     if (grep { $_ eq 'afalgeng' } @{$target{enable}}) {
1558         my $minver = 4*10000 + 1*100 + 0;
1559         if ($config{CROSS_COMPILE} eq "") {
1560             my $verstr = `uname -r`;
1561             my ($ma, $mi1, $mi2) = split("\\.", $verstr);
1562             ($mi2) = $mi2 =~ /(\d+)/;
1563             my $ver = $ma*10000 + $mi1*100 + $mi2;
1564             if ($ver < $minver) {
1565                 disable('too-old-kernel', 'afalgeng');
1566             } else {
1567                 push @{$config{engdirs}}, "afalg";
1568             }
1569         } else {
1570             disable('cross-compiling', 'afalgeng');
1571         }
1572     } else {
1573         disable('not-linux', 'afalgeng');
1574     }
1575 }
1576
1577 push @{$config{openssl_feature_defines}}, "OPENSSL_NO_AFALGENG" if ($disabled{afalgeng});
1578
1579 unless ($disabled{ktls}) {
1580     $config{ktls}="";
1581     if ($target =~ m/^linux/) {
1582         my $usr = "/usr/$config{cross_compile_prefix}";
1583         chop($usr);
1584         if ($config{cross_compile_prefix} eq "") {
1585             $usr = "/usr";
1586         }
1587         my $minver = (4 << 16) + (13 << 8) + 0;
1588         my @verstr = split(" ",`cat $usr/include/linux/version.h | grep LINUX_VERSION_CODE`);
1589
1590         if ($verstr[2] < $minver) {
1591             disable('too-old-kernel', 'ktls');
1592         }
1593     } else {
1594         disable('not-linux', 'ktls');
1595     }
1596 }
1597
1598 push @{$config{openssl_other_defines}}, "OPENSSL_NO_KTLS" if ($disabled{ktls});
1599
1600 # Get the extra flags used when building shared libraries and modules.  We
1601 # do this late because some of them depend on %disabled.
1602
1603 # Make the flags to build DSOs the same as for shared libraries unless they
1604 # are already defined
1605 $target{module_cflags} = $target{shared_cflag} unless defined $target{module_cflags};
1606 $target{module_cxxflags} = $target{shared_cxxflag} unless defined $target{module_cxxflags};
1607 $target{module_ldflags} = $target{shared_ldflag} unless defined $target{module_ldflags};
1608 {
1609     my $shared_info_pl =
1610         catfile(dirname($0), "Configurations", "shared-info.pl");
1611     my %shared_info = read_eval_file($shared_info_pl);
1612     push @{$target{_conf_fname_int}}, $shared_info_pl;
1613     my $si = $target{shared_target};
1614     while (ref $si ne "HASH") {
1615         last if ! defined $si;
1616         if (ref $si eq "CODE") {
1617             $si = $si->();
1618         } else {
1619             $si = $shared_info{$si};
1620         }
1621     }
1622
1623     # Some of the 'shared_target' values don't have any entries in
1624     # %shared_info.  That's perfectly fine, AS LONG AS the build file
1625     # template knows how to handle this.  That is currently the case for
1626     # Windows and VMS.
1627     if (defined $si) {
1628         # Just as above, copy certain shared_* attributes to the corresponding
1629         # module_ attribute unless the latter is already defined
1630         $si->{module_cflags} = $si->{shared_cflag} unless defined $si->{module_cflags};
1631         $si->{module_cxxflags} = $si->{shared_cxxflag} unless defined $si->{module_cxxflags};
1632         $si->{module_ldflags} = $si->{shared_ldflag} unless defined $si->{module_ldflags};
1633         foreach (sort keys %$si) {
1634             $target{$_} = defined $target{$_}
1635                 ? add($si->{$_})->($target{$_})
1636                 : $si->{$_};
1637         }
1638     }
1639 }
1640
1641 # ALL MODIFICATIONS TO %disabled, %config and %target MUST BE DONE FROM HERE ON
1642
1643 # If we use the unified build, collect information from build.info files
1644 my %unified_info = ();
1645
1646 my $buildinfo_debug = defined($ENV{CONFIGURE_DEBUG_BUILDINFO});
1647 if ($builder eq "unified") {
1648     use with_fallback qw(Text::Template);
1649
1650     sub cleandir {
1651         my $base = shift;
1652         my $dir = shift;
1653         my $relativeto = shift || ".";
1654
1655         $dir = catdir($base,$dir) unless isabsolute($dir);
1656
1657         # Make sure the directories we're building in exists
1658         mkpath($dir);
1659
1660         my $res = abs2rel(absolutedir($dir), rel2abs($relativeto));
1661         #print STDERR "DEBUG[cleandir]: $dir , $base => $res\n";
1662         return $res;
1663     }
1664
1665     sub cleanfile {
1666         my $base = shift;
1667         my $file = shift;
1668         my $relativeto = shift || ".";
1669
1670         $file = catfile($base,$file) unless isabsolute($file);
1671
1672         my $d = dirname($file);
1673         my $f = basename($file);
1674
1675         # Make sure the directories we're building in exists
1676         mkpath($d);
1677
1678         my $res = abs2rel(catfile(absolutedir($d), $f), rel2abs($relativeto));
1679         #print STDERR "DEBUG[cleanfile]: $d , $f => $res\n";
1680         return $res;
1681     }
1682
1683     # Store the name of the template file we will build the build file from
1684     # in %config.  This may be useful for the build file itself.
1685     my @build_file_template_names =
1686         ( $builder_platform."-".$target{build_file}.".tmpl",
1687           $target{build_file}.".tmpl" );
1688     my @build_file_templates = ();
1689
1690     # First, look in the user provided directory, if given
1691     if (defined env($local_config_envname)) {
1692         @build_file_templates =
1693             map {
1694                 if ($^O eq 'VMS') {
1695                     # VMS environment variables are logical names,
1696                     # which can be used as is
1697                     $local_config_envname . ':' . $_;
1698                 } else {
1699                     catfile(env($local_config_envname), $_);
1700                 }
1701             }
1702             @build_file_template_names;
1703     }
1704     # Then, look in our standard directory
1705     push @build_file_templates,
1706         ( map { cleanfile($srcdir, catfile("Configurations", $_), $blddir) }
1707           @build_file_template_names );
1708
1709     my $build_file_template;
1710     for $_ (@build_file_templates) {
1711         $build_file_template = $_;
1712         last if -f $build_file_template;
1713
1714         $build_file_template = undef;
1715     }
1716     if (!defined $build_file_template) {
1717         die "*** Couldn't find any of:\n", join("\n", @build_file_templates), "\n";
1718     }
1719     $config{build_file_templates}
1720       = [ cleanfile($srcdir, catfile("Configurations", "common0.tmpl"),
1721                     $blddir),
1722           $build_file_template,
1723           cleanfile($srcdir, catfile("Configurations", "common.tmpl"),
1724                     $blddir) ];
1725
1726     my @build_dirs = ( [ ] );   # current directory
1727
1728     $config{build_infos} = [ ];
1729
1730     my %ordinals = ();
1731     while (@build_dirs) {
1732         my @curd = @{shift @build_dirs};
1733         my $sourced = catdir($srcdir, @curd);
1734         my $buildd = catdir($blddir, @curd);
1735
1736         my $unixdir = join('/', @curd);
1737         if (exists $skipdir{$unixdir}) {
1738             my $what = $skipdir{$unixdir};
1739             push @{$disabled_info{$what}->{skipped}}, catdir(@curd);
1740             next;
1741         }
1742
1743         mkpath($buildd);
1744
1745         my $f = 'build.info';
1746         # The basic things we're trying to build
1747         my @programs = ();
1748         my @libraries = ();
1749         my @modules = ();
1750         my @scripts = ();
1751
1752         my %attributes = ();
1753         my %sources = ();
1754         my %shared_sources = ();
1755         my %includes = ();
1756         my %defines = ();
1757         my %depends = ();
1758         my %generate = ();
1759
1760         # Support for $variablename in build.info files.
1761         # Embedded perl code is the ultimate master, still.  If its output
1762         # contains a dollar sign, it had better be escaped, or it will be
1763         # taken for a variable name prefix.
1764         my %variables = ();
1765         my $variable_re = qr/\$([[:alpha:]][[:alnum:]_]*)/;
1766         my $expand_variables = sub {
1767             my $value = '';
1768             my $value_rest = shift;
1769
1770             while ($value_rest =~ /(?<!\\)${variable_re}/) {
1771                 $value .= $`;
1772                 $value .= $variables{$1};
1773                 $value_rest = $';
1774             }
1775             return $value . $value_rest;
1776         };
1777
1778         # We want to detect configdata.pm in the source tree, so we
1779         # don't use it if the build tree is different.
1780         my $src_configdata = cleanfile($srcdir, "configdata.pm", $blddir);
1781
1782         push @{$config{build_infos}}, catfile(abs2rel($sourced, $blddir), $f);
1783         my $template =
1784             Text::Template->new(TYPE => 'FILE',
1785                                 SOURCE => catfile($sourced, $f),
1786                                 PREPEND => qq{use lib "$FindBin::Bin/util/perl";});
1787         die "Something went wrong with $sourced/$f: $!\n" unless $template;
1788         my @text =
1789             split /^/m,
1790             $template->fill_in(HASH => { config => \%config,
1791                                          target => \%target,
1792                                          disabled => \%disabled,
1793                                          withargs => \%withargs,
1794                                          builddir => abs2rel($buildd, $blddir),
1795                                          sourcedir => abs2rel($sourced, $blddir),
1796                                          buildtop => abs2rel($blddir, $blddir),
1797                                          sourcetop => abs2rel($srcdir, $blddir) },
1798                                DELIMITERS => [ "{-", "-}" ]);
1799
1800         # The top item of this stack has the following values
1801         # -2 positive already run and we found ELSE (following ELSIF should fail)
1802         # -1 positive already run (skip until ENDIF)
1803         # 0 negatives so far (if we're at a condition, check it)
1804         # 1 last was positive (don't skip lines until next ELSE, ELSIF or ENDIF)
1805         # 2 positive ELSE (following ELSIF should fail)
1806         my @skip = ();
1807         collect_information(
1808             collect_from_array([ @text ],
1809                                qr/\\$/ => sub { my $l1 = shift; my $l2 = shift;
1810                                                 $l1 =~ s/\\$//; $l1.$l2 }),
1811             # Info we're looking for
1812             qr/^\s*IF\[((?:\\.|[^\\\]])*)\]\s*$/
1813             => sub {
1814                 if (! @skip || $skip[$#skip] > 0) {
1815                     push @skip, !! $expand_variables->($1);
1816                 } else {
1817                     push @skip, -1;
1818                 }
1819             },
1820             qr/^\s*ELSIF\[((?:\\.|[^\\\]])*)\]\s*$/
1821             => sub { die "ELSIF out of scope" if ! @skip;
1822                      die "ELSIF following ELSE" if abs($skip[$#skip]) == 2;
1823                      $skip[$#skip] = -1 if $skip[$#skip] != 0;
1824                      $skip[$#skip] = !! $expand_variables->($1)
1825                          if $skip[$#skip] == 0; },
1826             qr/^\s*ELSE\s*$/
1827             => sub { die "ELSE out of scope" if ! @skip;
1828                      $skip[$#skip] = -2 if $skip[$#skip] != 0;
1829                      $skip[$#skip] = 2 if $skip[$#skip] == 0; },
1830             qr/^\s*ENDIF\s*$/
1831             => sub { die "ENDIF out of scope" if ! @skip;
1832                      pop @skip; },
1833             qr/^\s*${variable_re}\s*=\s*(.*?)\s*$/
1834             => sub {
1835                 if (!@skip || $skip[$#skip] > 0) {
1836                     my $n = $1;
1837                     my $v = $2;
1838                     $variables{$n} = $expand_variables->($v);
1839                 }
1840             },
1841             qr/^\s*SUBDIRS\s*=\s*(.*)\s*$/
1842             => sub {
1843                 if (!@skip || $skip[$#skip] > 0) {
1844                     foreach (tokenize($expand_variables->($1))) {
1845                         push @build_dirs, [ @curd, splitdir($_, 1) ];
1846                     }
1847                 }
1848             },
1849             qr/^\s*PROGRAMS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1850             => sub {
1851                 if (!@skip || $skip[$#skip] > 0) {
1852                     my @a = tokenize($1, qr|\s*,\s*|);
1853                     my @p = tokenize($expand_variables->($2));
1854                     push @programs, @p;
1855                     foreach my $a (@a) {
1856                         my $ak = $a;
1857                         my $av = 1;
1858                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1859                             $ak = $1;
1860                             $av = $2;
1861                         }
1862                         foreach my $p (@p) {
1863                             $attributes{$p}->{$ak} = $av;
1864                         }
1865                     }
1866                 }
1867             },
1868             qr/^\s*LIBS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1869             => sub {
1870                 if (!@skip || $skip[$#skip] > 0) {
1871                     my @a = tokenize($1, qr|\s*,\s*|);
1872                     my @l = tokenize($expand_variables->($2));
1873                     push @libraries, @l;
1874                     foreach my $a (@a) {
1875                         my $ak = $a;
1876                         my $av = 1;
1877                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1878                             $ak = $1;
1879                             $av = $2;
1880                         }
1881                         foreach my $l (@l) {
1882                             $attributes{$l}->{$ak} = $av;
1883                         }
1884                     }
1885                 }
1886             },
1887             qr/^\s*MODULES(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1888             => sub {
1889                 if (!@skip || $skip[$#skip] > 0) {
1890                     my @a = tokenize($1, qr|\s*,\s*|);
1891                     my @m = tokenize($expand_variables->($2));
1892                     push @modules, @m;
1893                     foreach my $a (@a) {
1894                         my $ak = $a;
1895                         my $av = 1;
1896                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1897                             $ak = $1;
1898                             $av = $2;
1899                         }
1900                         foreach my $m (@m) {
1901                             $attributes{$m}->{$ak} = $av;
1902                         }
1903                     }
1904                 }
1905             },
1906             qr/^\s*SCRIPTS(?:{([\w=]+(?:\s*,\s*[\w=]+)*)})?\s*=\s*(.*)\s*$/
1907             => sub {
1908                 if (!@skip || $skip[$#skip] > 0) {
1909                     my @a = tokenize($1, qr|\s*,\s*|);
1910                     my @s = tokenize($expand_variables->($2));
1911                     push @scripts, @s;
1912                     foreach my $a (@a) {
1913                         my $ak = $a;
1914                         my $av = 1;
1915                         if ($a =~ m|^(.*?)\s*=\s*(.*?)$|) {
1916                             $ak = $1;
1917                             $av = $2;
1918                         }
1919                         foreach my $s (@s) {
1920                             $attributes{$s}->{$ak} = $av;
1921                         }
1922                     }
1923                 }
1924             },
1925
1926             qr/^\s*ORDINALS\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/,
1927             => sub { push @{$ordinals{$1}}, tokenize($expand_variables->($2))
1928                          if !@skip || $skip[$#skip] > 0 },
1929             qr/^\s*SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1930             => sub { push @{$sources{$1}}, tokenize($expand_variables->($2))
1931                          if !@skip || $skip[$#skip] > 0 },
1932             qr/^\s*SHARED_SOURCE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1933             => sub { push @{$shared_sources{$1}},
1934                          tokenize($expand_variables->($2))
1935                          if !@skip || $skip[$#skip] > 0 },
1936             qr/^\s*INCLUDE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1937             => sub { push @{$includes{$1}}, tokenize($expand_variables->($2))
1938                          if !@skip || $skip[$#skip] > 0 },
1939             qr/^\s*DEFINE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1940             => sub { push @{$defines{$1}}, tokenize($expand_variables->($2))
1941                          if !@skip || $skip[$#skip] > 0 },
1942             qr/^\s*DEPEND\[((?:\\.|[^\\\]])*)\]\s*=\s*(.*)\s*$/
1943             => sub { push @{$depends{$1}}, tokenize($expand_variables->($2))
1944                          if !@skip || $skip[$#skip] > 0 },
1945             qr/^\s*GENERATE\[((?:\\.|[^\\\]])+)\]\s*=\s*(.*)\s*$/
1946             => sub { push @{$generate{$1}}, $2
1947                          if !@skip || $skip[$#skip] > 0 },
1948             qr/^\s*(?:#.*)?$/ => sub { },
1949             "OTHERWISE" => sub { die "Something wrong with this line:\n$_\nat $sourced/$f" },
1950             "BEFORE" => sub {
1951                 if ($buildinfo_debug) {
1952                     print STDERR "DEBUG: Parsing ",join(" ", @_),"\n";
1953                     print STDERR "DEBUG: ... before parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1954                 }
1955             },
1956             "AFTER" => sub {
1957                 if ($buildinfo_debug) {
1958                     print STDERR "DEBUG: .... after parsing, skip stack is ",join(" ", map { int($_) } @skip),"\n";
1959                 }
1960             },
1961             );
1962         die "runaway IF?" if (@skip);
1963
1964         if (grep { defined $attributes{$_}->{engine} } keys %attributes
1965                 and !$config{dynamic_engines}) {
1966             die <<"EOF"
1967 ENGINES can only be used if configured with 'dynamic-engine'.
1968 This is usually a fault in a build.info file.
1969 EOF
1970         }
1971
1972         foreach (keys %attributes) {
1973             my $dest = $_;
1974             my $ddest = cleanfile($buildd, $_, $blddir);
1975             foreach (keys %{$attributes{$dest} // {}}) {
1976                 $unified_info{attributes}->{$ddest}->{$_} =
1977                     $attributes{$dest}->{$_};
1978             }
1979         }
1980
1981         {
1982             my %infos = ( programs  => [ @programs  ],
1983                           libraries => [ @libraries ],
1984                           modules   => [ @modules   ],
1985                           scripts   => [ @scripts   ] );
1986             foreach my $k (keys %infos) {
1987                 foreach (@{$infos{$k}}) {
1988                     my $item = cleanfile($buildd, $_, $blddir);
1989                     $unified_info{$k}->{$item} = 1;
1990                 }
1991             }
1992         }
1993
1994         # Check that we haven't defined any library as both shared and
1995         # explicitly static.  That is forbidden.
1996         my @doubles = ();
1997         foreach (grep /\.a$/, keys %{$unified_info{libraries}}) {
1998             (my $l = $_) =~ s/\.a$//;
1999             push @doubles, $l if defined $unified_info{libraries}->{$l};
2000         }
2001         die "these libraries are both explicitly static and shared:\n  ",
2002             join(" ", @doubles), "\n"
2003             if @doubles;
2004
2005         foreach (keys %sources) {
2006             my $dest = $_;
2007             my $ddest = cleanfile($buildd, $_, $blddir);
2008             foreach (@{$sources{$dest}}) {
2009                 my $s = cleanfile($sourced, $_, $blddir);
2010
2011                 # If it isn't in the source tree, we assume it's generated
2012                 # in the build tree
2013                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2014                     $s = cleanfile($buildd, $_, $blddir);
2015                 }
2016                 # We recognise C++, C and asm files
2017                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2018                     my $o = $_;
2019                     $o =~ s/\.[csS]$/.o/; # C and assembler
2020                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2021                     $o = cleanfile($buildd, $o, $blddir);
2022                     $unified_info{sources}->{$ddest}->{$o} = -1;
2023                     $unified_info{sources}->{$o}->{$s} = -1;
2024                 } elsif ($s =~ /\.rc$/) {
2025                     # We also recognise resource files
2026                     my $o = $_;
2027                     $o =~ s/\.rc$/.res/; # Resource configuration
2028                     my $o = cleanfile($buildd, $o, $blddir);
2029                     $unified_info{sources}->{$ddest}->{$o} = -1;
2030                     $unified_info{sources}->{$o}->{$s} = -1;
2031                 } else {
2032                     $unified_info{sources}->{$ddest}->{$s} = 1;
2033                 }
2034             }
2035         }
2036
2037         foreach (keys %shared_sources) {
2038             my $dest = $_;
2039             my $ddest = cleanfile($buildd, $_, $blddir);
2040             foreach (@{$shared_sources{$dest}}) {
2041                 my $s = cleanfile($sourced, $_, $blddir);
2042
2043                 # If it isn't in the source tree, we assume it's generated
2044                 # in the build tree
2045                 if ($s eq $src_configdata || ! -f $s || $generate{$_}) {
2046                     $s = cleanfile($buildd, $_, $blddir);
2047                 }
2048
2049                 if ($s =~ /\.(cc|cpp|c|s|S)$/) {
2050                     # We recognise C++, C and asm files
2051                     my $o = $_;
2052                     $o =~ s/\.[csS]$/.o/; # C and assembler
2053                     $o =~ s/\.(cc|cpp)$/_cc.o/; # C++
2054                     $o = cleanfile($buildd, $o, $blddir);
2055                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2056                     $unified_info{sources}->{$o}->{$s} = -1;
2057                 } elsif ($s =~ /\.rc$/) {
2058                     # We also recognise resource files
2059                     my $o = $_;
2060                     $o =~ s/\.rc$/.res/; # Resource configuration
2061                     my $o = cleanfile($buildd, $o, $blddir);
2062                     $unified_info{shared_sources}->{$ddest}->{$o} = -1;
2063                     $unified_info{sources}->{$o}->{$s} = -1;
2064                 } elsif ($s =~ /\.ld$/) {
2065                     # We also recognise linker scripts (or corresponding)
2066                     # We know they are generated files
2067                     my $ld = cleanfile($buildd, $_, $blddir);
2068                     $unified_info{shared_sources}->{$ddest}->{$ld} = 1;
2069                 } else {
2070                     die "unrecognised source file type for shared library: $s\n";
2071                 }
2072             }
2073         }
2074
2075         foreach (keys %generate) {
2076             my $dest = $_;
2077             my $ddest = cleanfile($buildd, $_, $blddir);
2078             die "more than one generator for $dest: "
2079                     ,join(" ", @{$generate{$_}}),"\n"
2080                     if scalar @{$generate{$_}} > 1;
2081             my @generator = split /\s+/, $generate{$dest}->[0];
2082             $generator[0] = cleanfile($sourced, $generator[0], $blddir),
2083             $unified_info{generate}->{$ddest} = [ @generator ];
2084         }
2085
2086         foreach (keys %depends) {
2087             my $dest = $_;
2088             my $ddest = $dest eq "" ? "" : cleanfile($sourced, $_, $blddir);
2089
2090             # If the destination doesn't exist in source, it can only be
2091             # a generated file in the build tree.
2092             if ($ddest ne "" && ($ddest eq $src_configdata || ! -f $ddest)) {
2093                 $ddest = cleanfile($buildd, $_, $blddir);
2094             }
2095             foreach (@{$depends{$dest}}) {
2096                 my $d = cleanfile($sourced, $_, $blddir);
2097
2098                 # If we know it's generated, or assume it is because we can't
2099                 # find it in the source tree, we set file we depend on to be
2100                 # in the build tree rather than the source tree, and assume
2101                 # and that there are lines to build it in a BEGINRAW..ENDRAW
2102                 # section or in the Makefile template.
2103                 if ($d eq $src_configdata
2104                     || ! -f $d
2105                     || (grep { $d eq $_ }
2106                         map { cleanfile($srcdir, $_, $blddir) }
2107                         grep { /\.h$/ } keys %{$unified_info{generate}})) {
2108                     $d = cleanfile($buildd, $_, $blddir);
2109                 }
2110                 # Take note if the file to depend on is being renamed
2111                 # Take extra care with files ending with .a, they should
2112                 # be treated without that extension, and the extension
2113                 # should be added back after treatment.
2114                 $d =~ /(\.a)?$/;
2115                 my $e = $1 // "";
2116                 $d = $`.$e;
2117                 $unified_info{depends}->{$ddest}->{$d} = 1;
2118             }
2119         }
2120
2121         foreach (keys %includes) {
2122             my $dest = $_;
2123             my $ddest = cleanfile($sourced, $_, $blddir);
2124
2125             # If the destination doesn't exist in source, it can only be
2126             # a generated file in the build tree.
2127             if ($ddest eq $src_configdata || ! -f $ddest) {
2128                 $ddest = cleanfile($buildd, $_, $blddir);
2129             }
2130             foreach (@{$includes{$dest}}) {
2131                 my $is = cleandir($sourced, $_, $blddir);
2132                 my $ib = cleandir($buildd, $_, $blddir);
2133                 push @{$unified_info{includes}->{$ddest}->{source}}, $is
2134                     unless grep { $_ eq $is } @{$unified_info{includes}->{$ddest}->{source}};
2135                 push @{$unified_info{includes}->{$ddest}->{build}}, $ib
2136                     unless grep { $_ eq $ib } @{$unified_info{includes}->{$ddest}->{build}};
2137             }
2138         }
2139
2140         foreach (keys %defines) {
2141             my $dest = $_;
2142             my $ddest = cleanfile($sourced, $_, $blddir);
2143
2144             # If the destination doesn't exist in source, it can only be
2145             # a generated file in the build tree.
2146             if (! -f $ddest) {
2147                 $ddest = cleanfile($buildd, $_, $blddir);
2148                 if ($unified_info{rename}->{$ddest}) {
2149                     $ddest = $unified_info{rename}->{$ddest};
2150                 }
2151             }
2152             foreach (@{$defines{$dest}}) {
2153                 m|^([^=]*)(=.*)?$|;
2154                 die "0 length macro name not permitted\n" if $1 eq "";
2155                 die "$1 defined more than once\n"
2156                     if defined $unified_info{defines}->{$ddest}->{$1};
2157                 $unified_info{defines}->{$ddest}->{$1} = $2;
2158             }
2159         }
2160     }
2161
2162     my $ordinals_text = join(', ', sort keys %ordinals);
2163     warn <<"EOF" if $ordinals_text;
2164
2165 WARNING: ORDINALS were specified for $ordinals_text
2166 They are ignored and should be replaced with a combination of GENERATE,
2167 DEPEND and SHARED_SOURCE.
2168 EOF
2169
2170
2171     # Go through the sources of all libraries and check that the same basename
2172     # doesn't appear more than once.  Some static library archivers depend on
2173     # them being unique.
2174     {
2175         my $err = 0;
2176         foreach my $prod (keys %{$unified_info{libraries}}) {
2177             my @prod_sources =
2178                 map { keys %{$unified_info{sources}->{$_}} }
2179                 keys %{$unified_info{sources}->{$prod}};
2180             my %srccnt = ();
2181
2182             # Count how many times a given each source basename
2183             # appears for each product.
2184             foreach my $src (@prod_sources) {
2185                 $srccnt{basename $src}++;
2186             }
2187
2188             foreach my $src (keys %srccnt) {
2189                 if ((my $cnt = $srccnt{$src}) > 1) {
2190                     print STDERR "$src appears $cnt times for the product $prod\n";
2191                     $err++
2192                 }
2193             }
2194         }
2195         die if $err > 0;
2196     }
2197
2198     # Massage the result
2199
2200     # If we depend on a header file or a perl module, add an inclusion of
2201     # its directory to allow smoothe inclusion
2202     foreach my $dest (keys %{$unified_info{depends}}) {
2203         next if $dest eq "";
2204         foreach my $d (keys %{$unified_info{depends}->{$dest}}) {
2205             next unless $d =~ /\.(h|pm)$/;
2206             my $i = dirname($d);
2207             my $spot =
2208                 $d eq "configdata.pm" || defined($unified_info{generate}->{$d})
2209                 ? 'build' : 'source';
2210             push @{$unified_info{includes}->{$dest}->{$spot}}, $i
2211                 unless grep { $_ eq $i } @{$unified_info{includes}->{$dest}->{$spot}};
2212         }
2213     }
2214
2215     # Go through all intermediary files and change their names to something that
2216     # reflects what they will be built for.  Note that for some source files,
2217     # this leads to duplicate object files because they are used multiple times.
2218     # the goal is to rename all object files according to this scheme:
2219     #    {productname}-{midfix}-{origobjname}.[o|res]
2220     # the {midfix} is a keyword indicating the type of product, which is mostly
2221     # valuable for libraries since they come in two forms.
2222     #
2223     # This also reorganises the {sources} and {shared_sources} so that the
2224     # former only contains ALL object files that are supposed to end up in
2225     # static libraries and programs, while the latter contains ALL object files
2226     # that are supposed to end up in shared libraries and DSOs.
2227     # The main reason for having two different source structures is to allow
2228     # the same name to be used for the static and the shared variants of a
2229     # library.
2230     {
2231         # Take copies so we don't get interference from added stuff
2232         my %unified_copy = ();
2233         foreach (('sources', 'shared_sources')) {
2234             $unified_copy{$_} = { %{$unified_info{$_}} }
2235                 if defined($unified_info{$_});
2236             delete $unified_info{$_};
2237         }
2238         foreach my $prodtype (('programs', 'libraries', 'modules', 'scripts')) {
2239             # $intent serves multi purposes:
2240             # - give a prefix for the new object files names
2241             # - in the case of libraries, rearrange the object files so static
2242             #   libraries use the 'sources' structure exclusively, while shared
2243             #   libraries use the 'shared_sources' structure exclusively.
2244             my $intent = {
2245                 programs  => { bin    => { src => [ 'sources' ],
2246                                            dst => 'sources' } },
2247                 libraries => { lib    => { src => [ 'sources' ],
2248                                            dst => 'sources' },
2249                                shlib  => { prodselect =>
2250                                                sub { grep !/\.a$/, @_ },
2251                                            src => [ 'sources',
2252                                                     'shared_sources' ],
2253                                            dst => 'shared_sources' } },
2254                 modules   => { dso    => { src => [ 'sources' ],
2255                                            dst => 'sources' } },
2256                 scripts   => { script => { src => [ 'sources' ],
2257                                            dst => 'sources' } }
2258                } -> {$prodtype};
2259             foreach my $kind (keys %$intent) {
2260                 next if ($intent->{$kind}->{dst} eq 'shared_sources'
2261                              && $disabled{shared});
2262
2263                 my @src = @{$intent->{$kind}->{src}};
2264                 my $dst = $intent->{$kind}->{dst};
2265                 my $prodselect = $intent->{$kind}->{prodselect} // sub { @_ };
2266                 foreach my $prod ($prodselect->(keys %{$unified_info{$prodtype}})) {
2267                     # %prod_sources has all applicable objects as keys, and
2268                     # their corresponding sources as values
2269                     my %prod_sources =
2270                         map { $_ => [ keys %{$unified_copy{sources}->{$_}} ] }
2271                         map { keys %{$unified_copy{$_}->{$prod}} }
2272                         @src;
2273                     foreach (keys %prod_sources) {
2274                         # Only affect object files and resource files,
2275                         # the others simply get a new value
2276                         # (+1 instead of -1)
2277                         if ($_ =~ /\.(o|res)$/) {
2278                             (my $prodname = $prod) =~ s|\.a$||;
2279                             my $newobj =
2280                                 catfile(dirname($_),
2281                                         basename($prodname)
2282                                             . '-' . $kind
2283                                             . '-' . basename($_));
2284                             $unified_info{$dst}->{$prod}->{$newobj} = 1;
2285                             foreach my $src (@{$prod_sources{$_}}) {
2286                                 $unified_info{sources}->{$newobj}->{$src} = 1;
2287                             }
2288                             # Adjust dependencies
2289                             foreach my $deps (keys %{$unified_info{depends}->{$_}}) {
2290                                 $unified_info{depends}->{$_}->{$deps} = -1;
2291                                 $unified_info{depends}->{$newobj}->{$deps} = 1;
2292                             }
2293                             # Adjust includes
2294                             foreach my $k (('source', 'build')) {
2295                                 next unless
2296                                     defined($unified_info{includes}->{$_}->{$k});
2297                                 my @incs = @{$unified_info{includes}->{$_}->{$k}};
2298                                 $unified_info{includes}->{$newobj}->{$k} = [ @incs ];
2299                             }
2300                         } else {
2301                             $unified_info{$dst}->{$prod}->{$_} = 1;
2302                         }
2303                     }
2304                 }
2305             }
2306         }
2307     }
2308
2309     # At this point, we have a number of sources with the value -1.  They
2310     # aren't part of the local build and are probably meant for a different
2311     # platform, and can therefore be cleaned away.  That happens when making
2312     # %unified_info more efficient below.
2313
2314     ### Make unified_info a bit more efficient
2315     # One level structures
2316     foreach (("programs", "libraries", "modules", "scripts")) {
2317         $unified_info{$_} = [ sort keys %{$unified_info{$_}} ];
2318     }
2319     # Two level structures
2320     foreach my $l1 (("sources", "shared_sources", "ldadd", "depends")) {
2321         foreach my $l2 (sort keys %{$unified_info{$l1}}) {
2322             my @items =
2323                 sort
2324                 grep { $unified_info{$l1}->{$l2}->{$_} > 0 }
2325                 keys %{$unified_info{$l1}->{$l2}};
2326             if (@items) {
2327                 $unified_info{$l1}->{$l2} = [ @items ];
2328             } else {
2329                 delete $unified_info{$l1}->{$l2};
2330             }
2331         }
2332     }
2333     # Defines
2334     foreach my $dest (sort keys %{$unified_info{defines}}) {
2335         $unified_info{defines}->{$dest}
2336             = [ map { $_.$unified_info{defines}->{$dest}->{$_} }
2337                 sort keys %{$unified_info{defines}->{$dest}} ];
2338     }
2339     # Includes
2340     foreach my $dest (sort keys %{$unified_info{includes}}) {
2341         if (defined($unified_info{includes}->{$dest}->{build})) {
2342             my @source_includes = ();
2343             @source_includes = ( @{$unified_info{includes}->{$dest}->{source}} )
2344                 if defined($unified_info{includes}->{$dest}->{source});
2345             $unified_info{includes}->{$dest} =
2346                 [ @{$unified_info{includes}->{$dest}->{build}} ];
2347             foreach my $inc (@source_includes) {
2348                 push @{$unified_info{includes}->{$dest}}, $inc
2349                     unless grep { $_ eq $inc } @{$unified_info{includes}->{$dest}};
2350             }
2351         } elsif (defined($unified_info{includes}->{$dest}->{source})) {
2352             $unified_info{includes}->{$dest} =
2353                 [ @{$unified_info{includes}->{$dest}->{source}} ];
2354         } else {
2355             delete $unified_info{includes}->{$dest};
2356         }
2357     }
2358
2359     # For convenience collect information regarding directories where
2360     # files are generated, those generated files and the end product
2361     # they end up in where applicable.  Then, add build rules for those
2362     # directories
2363     my %loopinfo = ( "lib" => [ @{$unified_info{libraries}} ],
2364                      "dso" => [ @{$unified_info{modules}} ],
2365                      "bin" => [ @{$unified_info{programs}} ],
2366                      "script" => [ @{$unified_info{scripts}} ] );
2367     foreach my $type (keys %loopinfo) {
2368         foreach my $product (@{$loopinfo{$type}}) {
2369             my %dirs = ();
2370             my $pd = dirname($product);
2371
2372             foreach (@{$unified_info{sources}->{$product} // []},
2373                      @{$unified_info{shared_sources}->{$product} // []}) {
2374                 my $d = dirname($_);
2375
2376                 # We don't want to create targets for source directories
2377                 # when building out of source
2378                 next if ($config{sourcedir} ne $config{builddir}
2379                              && $d =~ m|^\Q$config{sourcedir}\E|);
2380                 # We already have a "test" target, and the current directory
2381                 # is just silly to make a target for
2382                 next if $d eq "test" || $d eq ".";
2383
2384                 $dirs{$d} = 1;
2385                 push @{$unified_info{dirinfo}->{$d}->{deps}}, $_
2386                     if $d ne $pd;
2387             }
2388             foreach (keys %dirs) {
2389                 push @{$unified_info{dirinfo}->{$_}->{products}->{$type}},
2390                     $product;
2391             }
2392         }
2393     }
2394 }
2395
2396 # For the schemes that need it, we provide the old *_obj configs
2397 # from the *_asm_obj ones
2398 foreach (grep /_(asm|aux)_src$/, keys %target) {
2399     my $src = $_;
2400     (my $obj = $_) =~ s/_(asm|aux)_src$/_obj/;
2401     $target{$obj} = $target{$src};
2402     $target{$obj} =~ s/\.[csS]\b/.o/g; # C and assembler
2403     $target{$obj} =~ s/\.(cc|cpp)\b/_cc.o/g; # C++
2404 }
2405
2406 # Write down our configuration where it fits #########################
2407
2408 print "Creating configdata.pm\n";
2409 open(OUT,">configdata.pm") || die "unable to create configdata.pm: $!\n";
2410 print OUT <<"EOF";
2411 #! $config{HASHBANGPERL}
2412
2413 package configdata;
2414
2415 use strict;
2416 use warnings;
2417
2418 use Exporter;
2419 #use vars qw(\@ISA \@EXPORT);
2420 our \@ISA = qw(Exporter);
2421 our \@EXPORT = qw(\%config \%target \%disabled \%withargs \%unified_info \@disablables \@disablables_int);
2422
2423 EOF
2424 print OUT "our %config = (\n";
2425 foreach (sort keys %config) {
2426     if (ref($config{$_}) eq "ARRAY") {
2427         print OUT "  ", $_, " => [ ", join(", ",
2428                                            map { quotify("perl", $_) }
2429                                            @{$config{$_}}), " ],\n";
2430     } elsif (ref($config{$_}) eq "HASH") {
2431         print OUT "  ", $_, " => {";
2432         if (scalar keys %{$config{$_}} > 0) {
2433             print OUT "\n";
2434             foreach my $key (sort keys %{$config{$_}}) {
2435                 print OUT "      ",
2436                     join(" => ",
2437                          quotify("perl", $key),
2438                          defined $config{$_}->{$key}
2439                              ? quotify("perl", $config{$_}->{$key})
2440                              : "undef");
2441                 print OUT ",\n";
2442             }
2443             print OUT "  ";
2444         }
2445         print OUT "},\n";
2446     } else {
2447         print OUT "  ", $_, " => ", quotify("perl", $config{$_}), ",\n"
2448     }
2449 }
2450 print OUT <<"EOF";
2451 );
2452
2453 EOF
2454 print OUT "our %target = (\n";
2455 foreach (sort keys %target) {
2456     if (ref($target{$_}) eq "ARRAY") {
2457         print OUT "  ", $_, " => [ ", join(", ",
2458                                            map { quotify("perl", $_) }
2459                                            @{$target{$_}}), " ],\n";
2460     } else {
2461         print OUT "  ", $_, " => ", quotify("perl", $target{$_}), ",\n"
2462     }
2463 }
2464 print OUT <<"EOF";
2465 );
2466
2467 EOF
2468 print OUT "our \%available_protocols = (\n";
2469 print OUT "  tls => [ ", join(", ", map { quotify("perl", $_) } @tls), " ],\n";
2470 print OUT "  dtls => [ ", join(", ", map { quotify("perl", $_) } @dtls), " ],\n";
2471 print OUT <<"EOF";
2472 );
2473
2474 EOF
2475 print OUT "our \@disablables = (\n";
2476 foreach (@disablables) {
2477     print OUT "  ", quotify("perl", $_), ",\n";
2478 }
2479 print OUT <<"EOF";
2480 );
2481
2482 EOF
2483 print OUT "# The following come from Configure's @disablables_int\n";
2484 print OUT "our \@disablables_int = (\n";
2485 foreach (@disablables_int) {
2486     print OUT "  ", quotify("perl", $_), ",\n";
2487 }
2488 print OUT <<"EOF";
2489 );
2490
2491 EOF
2492 print OUT "our \%disabled = (\n";
2493 foreach (sort keys %disabled) {
2494     print OUT "  ", quotify("perl", $_), " => ", quotify("perl", $disabled{$_}), ",\n";
2495 }
2496 print OUT <<"EOF";
2497 );
2498
2499 EOF
2500 print OUT "our %withargs = (\n";
2501 foreach (sort keys %withargs) {
2502     if (ref($withargs{$_}) eq "ARRAY") {
2503         print OUT "  ", $_, " => [ ", join(", ",
2504                                            map { quotify("perl", $_) }
2505                                            @{$withargs{$_}}), " ],\n";
2506     } else {
2507         print OUT "  ", $_, " => ", quotify("perl", $withargs{$_}), ",\n"
2508     }
2509 }
2510 print OUT <<"EOF";
2511 );
2512
2513 EOF
2514 if ($builder eq "unified") {
2515     my $recurse;
2516     $recurse = sub {
2517         my $indent = shift;
2518         foreach (@_) {
2519             if (ref $_ eq "ARRAY") {
2520                 print OUT " "x$indent, "[\n";
2521                 foreach (@$_) {
2522                     $recurse->($indent + 4, $_);
2523                 }
2524                 print OUT " "x$indent, "],\n";
2525             } elsif (ref $_ eq "HASH") {
2526                 my %h = %$_;
2527                 print OUT " "x$indent, "{\n";
2528                 foreach (sort keys %h) {
2529                     if (ref $h{$_} eq "") {
2530                         print OUT " "x($indent + 4), quotify("perl", $_), " => ", quotify("perl", $h{$_}), ",\n";
2531                     } else {
2532                         print OUT " "x($indent + 4), quotify("perl", $_), " =>\n";
2533                         $recurse->($indent + 8, $h{$_});
2534                     }
2535                 }
2536                 print OUT " "x$indent, "},\n";
2537             } else {
2538                 print OUT " "x$indent, quotify("perl", $_), ",\n";
2539             }
2540         }
2541     };
2542     print OUT "our %unified_info = (\n";
2543     foreach (sort keys %unified_info) {
2544         if (ref $unified_info{$_} eq "") {
2545             print OUT " "x4, quotify("perl", $_), " => ", quotify("perl", $unified_info{$_}), ",\n";
2546         } else {
2547             print OUT " "x4, quotify("perl", $_), " =>\n";
2548             $recurse->(8, $unified_info{$_});
2549         }
2550     }
2551     print OUT <<"EOF";
2552 );
2553
2554 EOF
2555 }
2556 print OUT
2557     "# The following data is only used when this files is use as a script\n";
2558 print OUT "my \@makevars = (\n";
2559 foreach (sort keys %user) {
2560     print OUT "    '",$_,"',\n";
2561 }
2562 print OUT ");\n";
2563 print OUT "my \%disabled_info = (\n";
2564 foreach my $what (sort keys %disabled_info) {
2565     print OUT "    '$what' => {\n";
2566     foreach my $info (sort keys %{$disabled_info{$what}}) {
2567         if (ref $disabled_info{$what}->{$info} eq 'ARRAY') {
2568             print OUT "        $info => [ ",
2569                 join(', ', map { "'$_'" } @{$disabled_info{$what}->{$info}}),
2570                 " ],\n";
2571         } else {
2572             print OUT "        $info => '", $disabled_info{$what}->{$info},
2573                 "',\n";
2574         }
2575     }
2576     print OUT "    },\n";
2577 }
2578 print OUT ");\n";
2579 print OUT 'my @user_crossable = qw( ', join (' ', @user_crossable), " );\n";
2580 print OUT << 'EOF';
2581 # If run directly, we can give some answers, and even reconfigure
2582 unless (caller) {
2583     use Getopt::Long;
2584     use File::Spec::Functions;
2585     use File::Basename;
2586     use Pod::Usage;
2587
2588     my $here = dirname($0);
2589
2590     my $dump = undef;
2591     my $cmdline = undef;
2592     my $options = undef;
2593     my $target = undef;
2594     my $envvars = undef;
2595     my $makevars = undef;
2596     my $buildparams = undef;
2597     my $reconf = undef;
2598     my $verbose = undef;
2599     my $help = undef;
2600     my $man = undef;
2601     GetOptions('dump|d'                 => \$dump,
2602                'command-line|c'         => \$cmdline,
2603                'options|o'              => \$options,
2604                'target|t'               => \$target,
2605                'environment|e'          => \$envvars,
2606                'make-variables|m'       => \$makevars,
2607                'build-parameters|b'     => \$buildparams,
2608                'reconfigure|reconf|r'   => \$reconf,
2609                'verbose|v'              => \$verbose,
2610                'help'                   => \$help,
2611                'man'                    => \$man)
2612         or die "Errors in command line arguments\n";
2613
2614     unless ($dump || $cmdline || $options || $target || $envvars || $makevars
2615             || $buildparams || $reconf || $verbose || $help || $man) {
2616         print STDERR <<"_____";
2617 You must give at least one option.
2618 For more information, do '$0 --help'
2619 _____
2620         exit(2);
2621     }
2622
2623     if ($help) {
2624         pod2usage(-exitval => 0,
2625                   -verbose => 1);
2626     }
2627     if ($man) {
2628         pod2usage(-exitval => 0,
2629                   -verbose => 2);
2630     }
2631     if ($dump || $cmdline) {
2632         print "\nCommand line (with current working directory = $here):\n\n";
2633         print '    ',join(' ',
2634                           $config{PERL},
2635                           catfile($config{sourcedir}, 'Configure'),
2636                           @{$config{perlargv}}), "\n";
2637         print "\nPerl information:\n\n";
2638         print '    ',$config{perl_cmd},"\n";
2639         print '    ',$config{perl_version},' for ',$config{perl_archname},"\n";
2640     }
2641     if ($dump || $options) {
2642         my $longest = 0;
2643         my $longest2 = 0;
2644         foreach my $what (@disablables) {
2645             $longest = length($what) if $longest < length($what);
2646             $longest2 = length($disabled{$what})
2647                 if $disabled{$what} && $longest2 < length($disabled{$what});
2648         }
2649         print "\nEnabled features:\n\n";
2650         foreach my $what (@disablables) {
2651             print "    $what\n" unless $disabled{$what};
2652         }
2653         print "\nDisabled features:\n\n";
2654         foreach my $what (@disablables) {
2655             if ($disabled{$what}) {
2656                 print "    $what", ' ' x ($longest - length($what) + 1),
2657                     "[$disabled{$what}]", ' ' x ($longest2 - length($disabled{$what}) + 1);
2658                 print $disabled_info{$what}->{macro}
2659                     if $disabled_info{$what}->{macro};
2660                 print ' (skip ',
2661                     join(', ', @{$disabled_info{$what}->{skipped}}),
2662                     ')'
2663                     if $disabled_info{$what}->{skipped};
2664                 print "\n";
2665             }
2666         }
2667     }
2668     if ($dump || $target) {
2669         print "\nConfig target attributes:\n\n";
2670         foreach (sort keys %target) {
2671             next if $_ =~ m|^_| || $_ eq 'template';
2672             my $quotify = sub {
2673                 map { (my $x = $_) =~ s|([\\\$\@"])|\\$1|g; "\"$x\""} @_;
2674             };
2675             print '    ', $_, ' => ';
2676             if (ref($target{$_}) eq "ARRAY") {
2677                 print '[ ', join(', ', $quotify->(@{$target{$_}})), " ],\n";
2678             } else {
2679                 print $quotify->($target{$_}), ",\n"
2680             }
2681         }
2682     }
2683     if ($dump || $envvars) {
2684         print "\nRecorded environment:\n\n";
2685         foreach (sort keys %{$config{perlenv}}) {
2686             print '    ',$_,' = ',($config{perlenv}->{$_} || ''),"\n";
2687         }
2688     }
2689     if ($dump || $makevars) {
2690         print "\nMakevars:\n\n";
2691         foreach my $var (@makevars) {
2692             my $prefix = '';
2693             $prefix = $config{CROSS_COMPILE}
2694                 if grep { $var eq $_ } @user_crossable;
2695             $prefix //= '';
2696             print '    ',$var,' ' x (16 - length $var),'= ',
2697                 (ref $config{$var} eq 'ARRAY'
2698                  ? join(' ', @{$config{$var}})
2699                  : $prefix.$config{$var}),
2700                 "\n"
2701                 if defined $config{$var};
2702         }
2703
2704         my @buildfile = ($config{builddir}, $config{build_file});
2705         unshift @buildfile, $here
2706             unless file_name_is_absolute($config{builddir});
2707         my $buildfile = canonpath(catdir(@buildfile));
2708         print <<"_____";
2709
2710 NOTE: These variables only represent the configuration view.  The build file
2711 template may have processed these variables further, please have a look at the
2712 build file for more exact data:
2713     $buildfile
2714 _____
2715     }
2716     if ($dump || $buildparams) {
2717         my @buildfile = ($config{builddir}, $config{build_file});
2718         unshift @buildfile, $here
2719             unless file_name_is_absolute($config{builddir});
2720         print "\nbuild file:\n\n";
2721         print "    ", canonpath(catfile(@buildfile)),"\n";
2722
2723         print "\nbuild file templates:\n\n";
2724         foreach (@{$config{build_file_templates}}) {
2725             my @tmpl = ($_);
2726             unshift @tmpl, $here
2727                 unless file_name_is_absolute($config{sourcedir});
2728             print '    ',canonpath(catfile(@tmpl)),"\n";
2729         }
2730     }
2731     if ($reconf) {
2732         if ($verbose) {
2733             print 'Reconfiguring with: ', join(' ',@{$config{perlargv}}), "\n";
2734             foreach (sort keys %{$config{perlenv}}) {
2735                 print '    ',$_,' = ',($config{perlenv}->{$_} || ""),"\n";
2736             }
2737         }
2738
2739         chdir $here;
2740         exec $^X,catfile($config{sourcedir}, 'Configure'),'reconf';
2741     }
2742 }
2743
2744 1;
2745
2746 __END__
2747
2748 =head1 NAME
2749
2750 configdata.pm - configuration data for OpenSSL builds
2751
2752 =head1 SYNOPSIS
2753
2754 Interactive:
2755
2756   perl configdata.pm [options]
2757
2758 As data bank module:
2759
2760   use configdata;
2761
2762 =head1 DESCRIPTION
2763
2764 This module can be used in two modes, interactively and as a module containing
2765 all the data recorded by OpenSSL's Configure script.
2766
2767 When used interactively, simply run it as any perl script, with at least one
2768 option, and you will get the information you ask for.  See L</OPTIONS> below.
2769
2770 When loaded as a module, you get a few databanks with useful information to
2771 perform build related tasks.  The databanks are:
2772
2773     %config             Configured things.
2774     %target             The OpenSSL config target with all inheritances
2775                         resolved.
2776     %disabled           The features that are disabled.
2777     @disablables        The list of features that can be disabled.
2778     %withargs           All data given through --with-THING options.
2779     %unified_info       All information that was computed from the build.info
2780                         files.
2781
2782 =head1 OPTIONS
2783
2784 =over 4
2785
2786 =item B<--help>
2787
2788 Print a brief help message and exit.
2789
2790 =item B<--man>
2791
2792 Print the manual page and exit.
2793
2794 =item B<--dump> | B<-d>
2795
2796 Print all relevant configuration data.  This is equivalent to B<--command-line>
2797 B<--options> B<--target> B<--environment> B<--make-variables>
2798 B<--build-parameters>.
2799
2800 =item B<--command-line> | B<-c>
2801
2802 Print the current configuration command line.
2803
2804 =item B<--options> | B<-o>
2805
2806 Print the features, both enabled and disabled, and display defined macro and
2807 skipped directories where applicable.
2808
2809 =item B<--target> | B<-t>
2810
2811 Print the config attributes for this config target.
2812
2813 =item B<--environment> | B<-e>
2814
2815 Print the environment variables and their values at the time of configuration.
2816
2817 =item B<--make-variables> | B<-m>
2818
2819 Print the main make variables generated in the current configuration
2820
2821 =item B<--build-parameters> | B<-b>
2822
2823 Print the build parameters, i.e. build file and build file templates.
2824
2825 =item B<--reconfigure> | B<--reconf> | B<-r>
2826
2827 Redo the configuration.
2828
2829 =item B<--verbose> | B<-v>
2830
2831 Verbose output.
2832
2833 =back
2834
2835 =cut
2836
2837 EOF
2838 close(OUT);
2839 if ($builder_platform eq 'unix') {
2840     my $mode = (0755 & ~umask);
2841     chmod $mode, 'configdata.pm'
2842         or warn sprintf("WARNING: Couldn't change mode for 'configdata.pm' to 0%03o: %s\n",$mode,$!);
2843 }
2844
2845 my %builders = (
2846     unified => sub {
2847         print 'Creating ',$target{build_file},"\n";
2848         run_dofile(catfile($blddir, $target{build_file}),
2849                    @{$config{build_file_templates}});
2850     },
2851     );
2852
2853 $builders{$builder}->($builder_platform, @builder_opts);
2854
2855 $SIG{__DIE__} = $orig_death_handler;
2856
2857 print <<"EOF" if ($disabled{threads} eq "unavailable");
2858
2859 The library could not be configured for supporting multi-threaded
2860 applications as the compiler options required on this system are not known.
2861 See file INSTALL for details if you need multi-threading.
2862 EOF
2863
2864 print <<"EOF" if ($no_shared_warn);
2865
2866 The options 'shared', 'pic' and 'dynamic-engine' aren't supported on this
2867 platform, so we will pretend you gave the option 'no-pic', which also disables
2868 'shared' and 'dynamic-engine'.  If you know how to implement shared libraries
2869 or position independent code, please let us know (but please first make sure
2870 you have tried with a current version of OpenSSL).
2871 EOF
2872
2873 print <<"EOF";
2874
2875 **********************************************************************
2876 ***                                                                ***
2877 ***   OpenSSL has been successfully configured                     ***
2878 ***                                                                ***
2879 ***   If you encounter a problem while building, please open an    ***
2880 ***   issue on GitHub <https://github.com/openssl/openssl/issues>  ***
2881 ***   and include the output from the following command:           ***
2882 ***                                                                ***
2883 ***       perl configdata.pm --dump                                ***
2884 ***                                                                ***
2885 ***   (If you are new to OpenSSL, you might want to consult the    ***
2886 ***   'Troubleshooting' section in the INSTALL file first)         ***
2887 ***                                                                ***
2888 **********************************************************************
2889 EOF
2890
2891 exit(0);
2892
2893 ######################################################################
2894 #
2895 # Helpers and utility functions
2896 #
2897
2898 # Death handler, to print a helpful message in case of failure #######
2899 #
2900 sub death_handler {
2901     die @_ if $^S;              # To prevent the added message in eval blocks
2902     my $build_file = $target{build_file} // "build file";
2903     my @message = ( <<"_____", @_ );
2904
2905 Failure!  $build_file wasn't produced.
2906 Please read INSTALL and associated NOTES files.  You may also have to look over
2907 your available compiler tool chain or change your configuration.
2908
2909 _____
2910
2911     # Dying is terminal, so it's ok to reset the signal handler here.
2912     $SIG{__DIE__} = $orig_death_handler;
2913     die @message;
2914 }
2915
2916 # Configuration file reading #########################################
2917
2918 # Note: All of the helper functions are for lazy evaluation.  They all
2919 # return a CODE ref, which will return the intended value when evaluated.
2920 # Thus, whenever there's mention of a returned value, it's about that
2921 # intended value.
2922
2923 # Helper function to implement conditional inheritance depending on the
2924 # value of $disabled{asm}.  Used in inherit_from values as follows:
2925 #
2926 #      inherit_from => [ "template", asm("asm_tmpl") ]
2927 #
2928 sub asm {
2929     my @x = @_;
2930     sub {
2931         $disabled{asm} ? () : @x;
2932     }
2933 }
2934
2935 # Helper function to implement conditional value variants, with a default
2936 # plus additional values based on the value of $config{build_type}.
2937 # Arguments are given in hash table form:
2938 #
2939 #       picker(default => "Basic string: ",
2940 #              debug   => "debug",
2941 #              release => "release")
2942 #
2943 # When configuring with --debug, the resulting string will be
2944 # "Basic string: debug", and when not, it will be "Basic string: release"
2945 #
2946 # This can be used to create variants of sets of flags according to the
2947 # build type:
2948 #
2949 #       cflags => picker(default => "-Wall",
2950 #                        debug   => "-g -O0",
2951 #                        release => "-O3")
2952 #
2953 sub picker {
2954     my %opts = @_;
2955     return sub { add($opts{default} || (),
2956                      $opts{$config{build_type}} || ())->(); }
2957 }
2958
2959 # Helper function to combine several values of different types into one.
2960 # This is useful if you want to combine a string with the result of a
2961 # lazy function, such as:
2962 #
2963 #       cflags => combine("-Wall", sub { $disabled{zlib} ? () : "-DZLIB" })
2964 #
2965 sub combine {
2966     my @stuff = @_;
2967     return sub { add(@stuff)->(); }
2968 }
2969
2970 # Helper function to implement conditional values depending on the value
2971 # of $disabled{threads}.  Can be used as follows:
2972 #
2973 #       cflags => combine("-Wall", threads("-pthread"))
2974 #
2975 sub threads {
2976     my @flags = @_;
2977     return sub { add($disabled{threads} ? () : @flags)->(); }
2978 }
2979
2980 sub shared {
2981     my @flags = @_;
2982     return sub { add($disabled{shared} ? () : @flags)->(); }
2983 }
2984
2985 our $add_called = 0;
2986 # Helper function to implement adding values to already existing configuration
2987 # values.  It handles elements that are ARRAYs, CODEs and scalars
2988 sub _add {
2989     my $separator = shift;
2990
2991     # If there's any ARRAY in the collection of values OR the separator
2992     # is undef, we will return an ARRAY of combined values, otherwise a
2993     # string of joined values with $separator as the separator.
2994     my $found_array = !defined($separator);
2995
2996     my @values =
2997         map {
2998             my $res = $_;
2999             while (ref($res) eq "CODE") {
3000                 $res = $res->();
3001             }
3002             if (defined($res)) {
3003                 if (ref($res) eq "ARRAY") {
3004                     $found_array = 1;
3005                     @$res;
3006                 } else {
3007                     $res;
3008                 }
3009             } else {
3010                 ();
3011             }
3012     } (@_);
3013
3014     $add_called = 1;
3015
3016     if ($found_array) {
3017         [ @values ];
3018     } else {
3019         join($separator, grep { defined($_) && $_ ne "" } @values);
3020     }
3021 }
3022 sub add_before {
3023     my $separator = " ";
3024     if (ref($_[$#_]) eq "HASH") {
3025         my $opts = pop;
3026         $separator = $opts->{separator};
3027     }
3028     my @x = @_;
3029     sub { _add($separator, @x, @_) };
3030 }
3031 sub add {
3032     my $separator = " ";
3033     if (ref($_[$#_]) eq "HASH") {
3034         my $opts = pop;
3035         $separator = $opts->{separator};
3036     }
3037     my @x = @_;
3038     sub { _add($separator, @_, @x) };
3039 }
3040
3041 sub read_eval_file {
3042     my $fname = shift;
3043     my $content;
3044     my @result;
3045
3046     open F, "< $fname" or die "Can't open '$fname': $!\n";
3047     {
3048         undef local $/;
3049         $content = <F>;
3050     }
3051     close F;
3052     {
3053         local $@;
3054
3055         @result = ( eval $content );
3056         warn $@ if $@;
3057     }
3058     return wantarray ? @result : $result[0];
3059 }
3060
3061 # configuration reader, evaluates the input file as a perl script and expects
3062 # it to fill %targets with target configurations.  Those are then added to
3063 # %table.
3064 sub read_config {
3065     my $fname = shift;
3066     my %targets;
3067
3068     {
3069         # Protect certain tables from tampering
3070         local %table = ();
3071
3072         %targets = read_eval_file($fname);
3073     }
3074     my %preexisting = ();
3075     foreach (sort keys %targets) {
3076         $preexisting{$_} = 1 if $table{$_};
3077     }
3078     die <<"EOF",
3079 The following config targets from $fname
3080 shadow pre-existing config targets with the same name:
3081 EOF
3082         map { "  $_\n" } sort keys %preexisting
3083         if %preexisting;
3084
3085
3086     # For each target, check that it's configured with a hash table.
3087     foreach (keys %targets) {
3088         if (ref($targets{$_}) ne "HASH") {
3089             if (ref($targets{$_}) eq "") {
3090                 warn "Deprecated target configuration for $_, ignoring...\n";
3091             } else {
3092                 warn "Misconfigured target configuration for $_ (should be a hash table), ignoring...\n";
3093             }
3094             delete $targets{$_};
3095         } else {
3096             $targets{$_}->{_conf_fname_int} = add([ $fname ]);
3097         }
3098     }
3099
3100     %table = (%table, %targets);
3101
3102 }
3103
3104 # configuration resolver.  Will only resolve all the lazy evaluation
3105 # codeblocks for the chosen target and all those it inherits from,
3106 # recursively
3107 sub resolve_config {
3108     my $target = shift;
3109     my @breadcrumbs = @_;
3110
3111 #    my $extra_checks = defined($ENV{CONFIGURE_EXTRA_CHECKS});
3112
3113     if (grep { $_ eq $target } @breadcrumbs) {
3114         die "inherit_from loop!  target backtrace:\n  "
3115             ,$target,"\n  ",join("\n  ", @breadcrumbs),"\n";
3116     }
3117
3118     if (!defined($table{$target})) {
3119         warn "Warning! target $target doesn't exist!\n";
3120         return ();
3121     }
3122     # Recurse through all inheritances.  They will be resolved on the
3123     # fly, so when this operation is done, they will all just be a
3124     # bunch of attributes with string values.
3125     # What we get here, though, are keys with references to lists of
3126     # the combined values of them all.  We will deal with lists after
3127     # this stage is done.
3128     my %combined_inheritance = ();
3129     if ($table{$target}->{inherit_from}) {
3130         my @inherit_from =
3131             map { ref($_) eq "CODE" ? $_->() : $_ } @{$table{$target}->{inherit_from}};
3132         foreach (@inherit_from) {
3133             my %inherited_config = resolve_config($_, $target, @breadcrumbs);
3134
3135             # 'template' is a marker that's considered private to
3136             # the config that had it.
3137             delete $inherited_config{template};
3138
3139             foreach (keys %inherited_config) {
3140                 if (!$combined_inheritance{$_}) {
3141                     $combined_inheritance{$_} = [];
3142                 }
3143                 push @{$combined_inheritance{$_}}, $inherited_config{$_};
3144             }
3145         }
3146     }
3147
3148     # We won't need inherit_from in this target any more, since we've
3149     # resolved all the inheritances that lead to this
3150     delete $table{$target}->{inherit_from};
3151
3152     # Now is the time to deal with those lists.  Here's the place to
3153     # decide what shall be done with those lists, all based on the
3154     # values of the target we're currently dealing with.
3155     # - If a value is a coderef, it will be executed with the list of
3156     #   inherited values as arguments.
3157     # - If the corresponding key doesn't have a value at all or is the
3158     #   empty string, the inherited value list will be run through the
3159     #   default combiner (below), and the result becomes this target's
3160     #   value.
3161     # - Otherwise, this target's value is assumed to be a string that
3162     #   will simply override the inherited list of values.
3163     my $default_combiner = add();
3164
3165     my %all_keys =
3166         map { $_ => 1 } (keys %combined_inheritance,
3167                          keys %{$table{$target}});
3168
3169     sub process_values {
3170         my $object    = shift;
3171         my $inherited = shift;  # Always a [ list ]
3172         my $target    = shift;
3173         my $entry     = shift;
3174
3175         $add_called = 0;
3176
3177         while(ref($object) eq "CODE") {
3178             $object = $object->(@$inherited);
3179         }
3180         if (!defined($object)) {
3181             return ();
3182         }
3183         elsif (ref($object) eq "ARRAY") {
3184             local $add_called;  # To make sure recursive calls don't affect it
3185             return [ map { process_values($_, $inherited, $target, $entry) }
3186                      @$object ];
3187         } elsif (ref($object) eq "") {
3188             return $object;
3189         } else {
3190             die "cannot handle reference type ",ref($object)
3191                 ," found in target ",$target," -> ",$entry,"\n";
3192         }
3193     }
3194
3195     foreach (sort keys %all_keys) {
3196         my $previous = $combined_inheritance{$_};
3197
3198         # Current target doesn't have a value for the current key?
3199         # Assign it the default combiner, the rest of this loop body
3200         # will handle it just like any other coderef.
3201         if (!exists $table{$target}->{$_}) {
3202             $table{$target}->{$_} = $default_combiner;
3203         }
3204
3205         $table{$target}->{$_} = process_values($table{$target}->{$_},
3206                                                $combined_inheritance{$_},
3207                                                $target, $_);
3208         unless(defined($table{$target}->{$_})) {
3209             delete $table{$target}->{$_};
3210         }
3211 #        if ($extra_checks &&
3212 #            $previous && !($add_called ||  $previous ~~ $table{$target}->{$_})) {
3213 #            warn "$_ got replaced in $target\n";
3214 #        }
3215     }
3216
3217     # Finally done, return the result.
3218     return %{$table{$target}};
3219 }
3220
3221 sub usage
3222         {
3223         print STDERR $usage;
3224         print STDERR "\npick os/compiler from:\n";
3225         my $j=0;
3226         my $i;
3227         my $k=0;
3228         foreach $i (sort keys %table)
3229                 {
3230                 next if $table{$i}->{template};
3231                 next if $i =~ /^debug/;
3232                 $k += length($i) + 1;
3233                 if ($k > 78)
3234                         {
3235                         print STDERR "\n";
3236                         $k=length($i);
3237                         }
3238                 print STDERR $i . " ";
3239                 }
3240         foreach $i (sort keys %table)
3241                 {
3242                 next if $table{$i}->{template};
3243                 next if $i !~ /^debug/;
3244                 $k += length($i) + 1;
3245                 if ($k > 78)
3246                         {
3247                         print STDERR "\n";
3248                         $k=length($i);
3249                         }
3250                 print STDERR $i . " ";
3251                 }
3252         print STDERR "\n\nNOTE: If in doubt, on Unix-ish systems use './config'.\n";
3253         exit(1);
3254         }
3255
3256 sub run_dofile
3257 {
3258     my $out = shift;
3259     my @templates = @_;
3260
3261     unlink $out || warn "Can't remove $out, $!"
3262         if -f $out;
3263     foreach (@templates) {
3264         die "Can't open $_, $!" unless -f $_;
3265     }
3266     my $perlcmd = (quotify("maybeshell", $config{PERL}))[0];
3267     my $cmd = "$perlcmd \"-I.\" \"-Mconfigdata\" \"$dofile\" -o\"Configure\" \"".join("\" \"",@templates)."\" > \"$out.new\"";
3268     #print STDERR "DEBUG[run_dofile]: \$cmd = $cmd\n";
3269     system($cmd);
3270     exit 1 if $? != 0;
3271     rename("$out.new", $out) || die "Can't rename $out.new, $!";
3272 }
3273
3274 sub compiler_predefined {
3275     state %predefined;
3276     my $cc = shift;
3277
3278     return () if $^O eq 'VMS';
3279
3280     die 'compiler_predefined called without a compiler command'
3281         unless $cc;
3282
3283     if (! $predefined{$cc}) {
3284
3285         $predefined{$cc} = {};
3286
3287         # collect compiler pre-defines from gcc or gcc-alike...
3288         open(PIPE, "$cc -dM -E -x c /dev/null 2>&1 |");
3289         while (my $l = <PIPE>) {
3290             $l =~ m/^#define\s+(\w+(?:\(\w+\))?)(?:\s+(.+))?/ or last;
3291             $predefined{$cc}->{$1} = $2 // '';
3292         }
3293         close(PIPE);
3294     }
3295
3296     return %{$predefined{$cc}};
3297 }
3298
3299 sub which
3300 {
3301     my ($name)=@_;
3302
3303     if (eval { require IPC::Cmd; 1; }) {
3304         IPC::Cmd->import();
3305         return scalar IPC::Cmd::can_run($name);
3306     } else {
3307         # if there is $directories component in splitpath,
3308         # then it's not something to test with $PATH...
3309         return $name if (File::Spec->splitpath($name))[1];
3310
3311         foreach (File::Spec->path()) {
3312             my $fullpath = catfile($_, "$name$target{exe_extension}");
3313             if (-f $fullpath and -x $fullpath) {
3314                 return $fullpath;
3315             }
3316         }
3317     }
3318 }
3319
3320 sub env
3321 {
3322     my $name = shift;
3323     my %opts = @_;
3324
3325     unless ($opts{cacheonly}) {
3326         # Note that if $ENV{$name} doesn't exist or is undefined,
3327         # $config{perlenv}->{$name} will be created with the value
3328         # undef.  This is intentional.
3329
3330         $config{perlenv}->{$name} = $ENV{$name}
3331             if ! exists $config{perlenv}->{$name};
3332     }
3333     return $config{perlenv}->{$name};
3334 }
3335
3336 # Configuration printer ##############################################
3337
3338 sub print_table_entry
3339 {
3340     local $now_printing = shift;
3341     my %target = resolve_config($now_printing);
3342     my $type = shift;
3343
3344     # Don't print the templates
3345     return if $target{template};
3346
3347     my @sequence = (
3348         "sys_id",
3349         "cpp",
3350         "cppflags",
3351         "defines",
3352         "includes",
3353         "cc",
3354         "cflags",
3355         "unistd",
3356         "ld",
3357         "lflags",
3358         "loutflag",
3359         "ex_libs",
3360         "bn_ops",
3361         "cast_asm_src",
3362         "rc4_asm_src",
3363         "rmd160_asm_src",
3364         "rc5_asm_src",
3365         "wp_asm_src",
3366         "cmll_asm_src",
3367         "modes_asm_src",
3368         "padlock_asm_src",
3369         "chacha_asm_src",
3370         "poly1035_asm_src",
3371         "thread_scheme",
3372         "perlasm_scheme",
3373         "dso_scheme",
3374         "shared_target",
3375         "shared_cflag",
3376         "shared_defines",
3377         "shared_ldflag",
3378         "shared_rcflag",
3379         "shared_extension",
3380         "dso_extension",
3381         "obj_extension",
3382         "exe_extension",
3383         "ranlib",
3384         "ar",
3385         "arflags",
3386         "aroutflag",
3387         "rc",
3388         "rcflags",
3389         "rcoutflag",
3390         "mt",
3391         "mtflags",
3392         "mtinflag",
3393         "mtoutflag",
3394         "multilib",
3395         "build_scheme",
3396         );
3397
3398     if ($type eq "TABLE") {
3399         print "\n";
3400         print "*** $now_printing\n";
3401         foreach (@sequence) {
3402             if (ref($target{$_}) eq "ARRAY") {
3403                 printf "\$%-12s = %s\n", $_, join(" ", @{$target{$_}});
3404             } else {
3405                 printf "\$%-12s = %s\n", $_, $target{$_};
3406             }
3407         }
3408     } elsif ($type eq "HASH") {
3409         my $largest =
3410             length((sort { length($a) <=> length($b) } @sequence)[-1]);
3411         print "    '$now_printing' => {\n";
3412         foreach (@sequence) {
3413             if ($target{$_}) {
3414                 if (ref($target{$_}) eq "ARRAY") {
3415                     print "      '",$_,"'"," " x ($largest - length($_))," => [ ",join(", ", map { "'$_'" } @{$target{$_}})," ],\n";
3416                 } else {
3417                     print "      '",$_,"'"," " x ($largest - length($_))," => '",$target{$_},"',\n";
3418                 }
3419             }
3420         }
3421         print "    },\n";
3422     }
3423 }
3424
3425 # Utility routines ###################################################
3426
3427 # On VMS, if the given file is a logical name, File::Spec::Functions
3428 # will consider it an absolute path.  There are cases when we want a
3429 # purely syntactic check without checking the environment.
3430 sub isabsolute {
3431     my $file = shift;
3432
3433     # On non-platforms, we just use file_name_is_absolute().
3434     return file_name_is_absolute($file) unless $^O eq "VMS";
3435
3436     # If the file spec includes a device or a directory spec,
3437     # file_name_is_absolute() is perfectly safe.
3438     return file_name_is_absolute($file) if $file =~ m|[:\[]|;
3439
3440     # Here, we know the given file spec isn't absolute
3441     return 0;
3442 }
3443
3444 # Makes a directory absolute and cleans out /../ in paths like foo/../bar
3445 # On some platforms, this uses rel2abs(), while on others, realpath() is used.
3446 # realpath() requires that at least all path components except the last is an
3447 # existing directory.  On VMS, the last component of the directory spec must
3448 # exist.
3449 sub absolutedir {
3450     my $dir = shift;
3451
3452     # realpath() is quite buggy on VMS.  It uses LIB$FID_TO_NAME, which
3453     # will return the volume name for the device, no matter what.  Also,
3454     # it will return an incorrect directory spec if the argument is a
3455     # directory that doesn't exist.
3456     if ($^O eq "VMS") {
3457         return rel2abs($dir);
3458     }
3459
3460     # We use realpath() on Unix, since no other will properly clean out
3461     # a directory spec.
3462     use Cwd qw/realpath/;
3463
3464     return realpath($dir);
3465 }
3466
3467 sub quotify {
3468     my %processors = (
3469         perl    => sub { my $x = shift;
3470                          $x =~ s/([\\\$\@"])/\\$1/g;
3471                          return '"'.$x.'"'; },
3472         maybeshell => sub { my $x = shift;
3473                             (my $y = $x) =~ s/([\\\"])/\\$1/g;
3474                             if ($x ne $y || $x =~ m|\s|) {
3475                                 return '"'.$y.'"';
3476                             } else {
3477                                 return $x;
3478                             }
3479                         },
3480         );
3481     my $for = shift;
3482     my $processor =
3483         defined($processors{$for}) ? $processors{$for} : sub { shift; };
3484
3485     return map { $processor->($_); } @_;
3486 }
3487
3488 # collect_from_file($filename, $line_concat_cond_re, $line_concat)
3489 # $filename is a file name to read from
3490 # $line_concat_cond_re is a regexp detecting a line continuation ending
3491 # $line_concat is a CODEref that takes care of concatenating two lines
3492 sub collect_from_file {
3493     my $filename = shift;
3494     my $line_concat_cond_re = shift;
3495     my $line_concat = shift;
3496
3497     open my $fh, $filename || die "unable to read $filename: $!\n";
3498     return sub {
3499         my $saved_line = "";
3500         $_ = "";
3501         while (<$fh>) {
3502             s|\R$||;
3503             if (defined $line_concat) {
3504                 $_ = $line_concat->($saved_line, $_);
3505                 $saved_line = "";
3506             }
3507             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3508                 $saved_line = $_;
3509                 next;
3510             }
3511             return $_;
3512         }
3513         die "$filename ending with continuation line\n" if $_;
3514         close $fh;
3515         return undef;
3516     }
3517 }
3518
3519 # collect_from_array($array, $line_concat_cond_re, $line_concat)
3520 # $array is an ARRAYref of lines
3521 # $line_concat_cond_re is a regexp detecting a line continuation ending
3522 # $line_concat is a CODEref that takes care of concatenating two lines
3523 sub collect_from_array {
3524     my $array = shift;
3525     my $line_concat_cond_re = shift;
3526     my $line_concat = shift;
3527     my @array = (@$array);
3528
3529     return sub {
3530         my $saved_line = "";
3531         $_ = "";
3532         while (defined($_ = shift @array)) {
3533             s|\R$||;
3534             if (defined $line_concat) {
3535                 $_ = $line_concat->($saved_line, $_);
3536                 $saved_line = "";
3537             }
3538             if (defined $line_concat_cond_re && /$line_concat_cond_re/) {
3539                 $saved_line = $_;
3540                 next;
3541             }
3542             return $_;
3543         }
3544         die "input text ending with continuation line\n" if $_;
3545         return undef;
3546     }
3547 }
3548
3549 # collect_information($lineiterator, $line_continue, $regexp => $CODEref, ...)
3550 # $lineiterator is a CODEref that delivers one line at a time.
3551 # All following arguments are regex/CODEref pairs, where the regexp detects a
3552 # line and the CODEref does something with the result of the regexp.
3553 sub collect_information {
3554     my $lineiterator = shift;
3555     my %collectors = @_;
3556
3557     while(defined($_ = $lineiterator->())) {
3558         s|\R$||;
3559         my $found = 0;
3560         if ($collectors{"BEFORE"}) {
3561             $collectors{"BEFORE"}->($_);
3562         }
3563         foreach my $re (keys %collectors) {
3564             if ($re !~ /^OTHERWISE|BEFORE|AFTER$/ && /$re/) {
3565                 $collectors{$re}->($lineiterator);
3566                 $found = 1;
3567             };
3568         }
3569         if ($collectors{"OTHERWISE"}) {
3570             $collectors{"OTHERWISE"}->($lineiterator, $_)
3571                 unless $found || !defined $collectors{"OTHERWISE"};
3572         }
3573         if ($collectors{"AFTER"}) {
3574             $collectors{"AFTER"}->($_);
3575         }
3576     }
3577 }
3578
3579 # tokenize($line)
3580 # tokenize($line,$separator)
3581 # $line is a line of text to split up into tokens
3582 # $separator [optional] is a regular expression that separates the tokens,
3583 # the default being spaces.  Do not use quotes of any kind as separators,
3584 # that will give undefined results.
3585 # Returns a list of tokens.
3586 #
3587 # Tokens are divided by separator (spaces by default).  If the tokens include
3588 # the separators, they have to be quoted with single or double quotes.
3589 # Double quotes inside a double quoted token must be escaped.  Escaping is done
3590 # with backslash.
3591 # Basically, the same quoting rules apply for " and ' as in any
3592 # Unix shell.
3593 sub tokenize {
3594     my $line = my $debug_line = shift;
3595     my $separator = shift // qr|\s+|;
3596     my @result = ();
3597
3598     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3599         print STDERR "DEBUG[tokenize]: \$separator = $separator\n";
3600     }
3601
3602     while ($line =~ s|^${separator}||, $line ne "") {
3603         my $token = "";
3604     again:
3605         $line =~ m/^(.*?)(${separator}|"|'|$)/;
3606         $token .= $1;
3607         $line = $2.$';
3608
3609         if ($line =~ m/^"((?:[^"\\]+|\\.)*)"/) {
3610             $token .= $1;
3611             $line = $';
3612             goto again;
3613         } elsif ($line =~ m/^'([^']*)'/) {
3614             $token .= $1;
3615             $line = $';
3616             goto again;
3617         }
3618         push @result, $token;
3619     }
3620
3621     if ($ENV{CONFIGURE_DEBUG_TOKENIZE}) {
3622         print STDERR "DEBUG[tokenize]: Parsed '$debug_line' into:\n";
3623         print STDERR "DEBUG[tokenize]: ('", join("', '", @result), "')\n";
3624     }
3625     return @result;
3626 }