arch/sh/cpu/sh2/u-boot.lds

   1 /*
   2  * Copyright (C) 2008 Nobuhiro Iwamatsu
   3  * Copyright (C) 2008 Renesas Solutions Corp.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_FORMAT("elf32-sh-linux", "elf32-sh-linux", "elf32-sh-linux")
   9 OUTPUT_ARCH(sh)
  10 ENTRY(_start)
  11
  12 SECTIONS
  13 {
  14         /*
  15          * entry and reloct_dst will be provided via ldflags
  16          */
  17         . = .;
  18
  19         PROVIDE (_ftext = .);
  20         PROVIDE (_fcode = .);
  21         PROVIDE (_start = .);
  22
  23         .text :
  24         {
  25                 KEEP(arch/sh/cpu/sh2/start.o    (.text))
  26                 . = ALIGN(8192);
  27                 common/env_embedded.o   (.ppcenv)
  28                 . = ALIGN(8192);
  29                 common/env_embedded.o   (.ppcenvr)
  30                 . = ALIGN(8192);
  31                 *(.text)
  32                 . = ALIGN(4);
  33         } =0xFF
  34         PROVIDE (_ecode = .);
  35         .rodata :
  36         {
  37                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  38                 . = ALIGN(4);
  39         }
  40         PROVIDE (_etext = .);
  41
  42
  43         PROVIDE (_fdata = .);
  44         .data :
  45         {
  46                 *(.data)
  47                 . = ALIGN(4);
  48         }
  49         PROVIDE (_edata = .);
  50
  51         PROVIDE (_fgot = .);
  52         .got :
  53         {
  54                 *(.got)
  55                 . = ALIGN(4);
  56         }
  57         PROVIDE (_egot = .);
  58
  59
  60         .u_boot_list : {
  61                 KEEP(*(SORT(.u_boot_list*)));
  62         }
  63
  64         PROVIDE (reloc_dst_end = .);
  65
  66         PROVIDE (bss_start = .);
  67         PROVIDE (__bss_start = .);
  68         .bss :
  69         {
  70                 *(.bss)
  71                 . = ALIGN(4);
  72         }
  73         PROVIDE (bss_end = .);
  74
  75         PROVIDE (__bss_end = .);
  76 }