bfd/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT
   6 AC_CONFIG_SRCDIR([libbfd.c])
   7
   8 AC_CANONICAL_TARGET
   9 AC_ISC_POSIX
  10
  11 AM_INIT_AUTOMAKE(bfd, 2.16.90)
  12
  13 dnl These must be called before AM_PROG_LIBTOOL, because it may want
  14 dnl to call AC_CHECK_PROG.
  15 AC_CHECK_TOOL(AR, ar)
  16 AC_CHECK_TOOL(RANLIB, ranlib, :)
  17
  18 dnl Default to a non shared library.  This may be overridden by the
  19 dnl configure option --enable-shared.
  20 AM_DISABLE_SHARED
  21
  22 AM_PROG_LIBTOOL
  23
  24 AC_ARG_ENABLE(64-bit-bfd,
  25 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  26 [case "${enableval}" in
  27   yes)  want64=true  ;;
  28   no)   want64=false ;;
  29   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  30 esac],[want64=false])dnl
  31 AC_ARG_ENABLE(targets,
  32 [  --enable-targets        alternative target configurations],
  33 [case "${enableval}" in
  34   yes | "") AC_MSG_ERROR([enable-targets option must specify target names or 'all'])
  35             ;;
  36   no)       enable_targets= ;;
  37   *)        enable_targets=$enableval ;;
  38 esac])dnl
  39 AC_ARG_ENABLE(commonbfdlib,
  40 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  41 [case "${enableval}" in
  42   yes) commonbfdlib=true ;;
  43   no)  commonbfdlib=false ;;
  44   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  45 esac])dnl
  46 AC_ARG_WITH(mmap,
  47 [  --with-mmap             try using mmap for BFD input files if available],
  48 [case "${withval}" in
  49   yes)  want_mmap=true ;;
  50   no)   want_mmap=false ;;
  51   *)    AC_MSG_ERROR(bad value ${withval} for BFD with-mmap option) ;;
  52 esac],[want_mmap=false])dnl
  53
  54 AM_BINUTILS_WARNINGS
  55
  56 AM_CONFIG_HEADER(config.h:config.in)
  57
  58 if test -z "$target" ; then
  59     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
  60 fi
  61
  62 AM_MAINTAINER_MODE
  63 AM_INSTALL_LIBBFD
  64 AC_EXEEXT
  65
  66 host64=false
  67 target64=false
  68 bfd_default_target_size=32
  69
  70 # host stuff:
  71
  72 AC_PROG_CC
  73 AC_GNU_SOURCE
  74
  75 ALL_LINGUAS="fr tr ja es sv da zh_CN ro rw"
  76 CY_GNU_GETTEXT
  77
  78 # Permit host specific settings.
  79 . ${srcdir}/configure.host
  80
  81 AC_SUBST(HDEFINES)
  82 AC_PROG_INSTALL
  83
  84 BFD_HOST_64BIT_LONG=0
  85 BFD_HOST_LONG_LONG=0
  86 BFD_HOST_64_BIT_DEFINED=0
  87 BFD_HOST_64_BIT=
  88 BFD_HOST_U_64_BIT=
  89
  90 AC_MSG_CHECKING([for long long])
  91 AC_CACHE_VAL(bfd_cv_has_long_long,
  92 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[unsigned long long ll = 18446744073709551615ULL;]])],[bfd_cv_has_long_long=yes],[bfd_cv_has_long_long=no])])
  93 AC_MSG_RESULT($bfd_cv_has_long_long)
  94 if test $bfd_cv_has_long_long = yes; then
  95   BFD_HOST_LONG_LONG=1
  96   AC_COMPILE_CHECK_SIZEOF(long long)
  97 fi
  98
  99 AC_COMPILE_CHECK_SIZEOF(long)
 100 if test "x${ac_cv_sizeof_long}" = "x8"; then
 101   host64=true
 102   BFD_HOST_64BIT_LONG=1
 103   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long"
 104   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long"
 105 elif test "x${ac_cv_sizeof_long_long}" = "x8"; then
 106   test -n "${HOST_64BIT_TYPE}" || HOST_64BIT_TYPE="long long"
 107   test -n "${HOST_U_64BIT_TYPE}" || HOST_U_64BIT_TYPE="unsigned long long"
 108 fi
 109
 110 if test -n "${HOST_64BIT_TYPE}" -a -n "${HOST_U_64BIT_TYPE}"; then
 111   BFD_HOST_64_BIT_DEFINED=1
 112   BFD_HOST_64_BIT="${HOST_64BIT_TYPE}"
 113   BFD_HOST_U_64_BIT="${HOST_U_64BIT_TYPE}"
 114 fi
 115
 116 AC_SUBST(BFD_HOST_64BIT_LONG)
 117 AC_SUBST(BFD_HOST_LONG_LONG)
 118 AC_SUBST(BFD_HOST_64_BIT_DEFINED)
 119 AC_SUBST(BFD_HOST_64_BIT)
 120 AC_SUBST(BFD_HOST_U_64_BIT)
 121
 122 BFD_CC_FOR_BUILD
 123
 124 AC_CHECK_HEADERS(stddef.h string.h strings.h stdlib.h time.h unistd.h)
 125 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h)
 126 AC_HEADER_TIME
 127 AC_HEADER_DIRENT
 128 AC_CHECK_FUNCS(fcntl getpagesize setitimer sysconf fdopen getuid getgid)
 129 AC_CHECK_FUNCS(strtoull)
 130
 131 AC_CHECK_DECLS(basename)
 132 AC_CHECK_DECLS(ftello)
 133 AC_CHECK_DECLS(ftello64)
 134 AC_CHECK_DECLS(fseeko)
 135 AC_CHECK_DECLS(fseeko64)
 136
 137 BFD_BINARY_FOPEN
 138
 139 AC_CHECK_DECLS(ffs)
 140 AC_CHECK_DECLS(free)
 141 AC_CHECK_DECLS(getenv)
 142 AC_CHECK_DECLS(malloc)
 143 AC_CHECK_DECLS(realloc)
 144 AC_CHECK_DECLS(stpcpy)
 145 AC_CHECK_DECLS(strstr)
 146
 147 # If we are configured native, pick a core file support file.
 148 COREFILE=
 149 COREFLAG=
 150 TRAD_HEADER=
 151 if test "${target}" = "${host}"; then
 152   case "${host}" in
 153   alpha*-*-freebsd* | alpha*-*-kfreebsd*-gnu)
 154         COREFILE=''
 155         ;;
 156   alpha*-*-linux-*)
 157         COREFILE=trad-core.lo
 158         TRAD_HEADER='"hosts/alphalinux.h"'
 159         ;;
 160   alpha*-*-netbsd* | alpha*-*-openbsd*)
 161         COREFILE=netbsd-core.lo
 162         ;;
 163   alpha*-*-*)           COREFILE=osf-core.lo ;;
 164   arm-*-freebsd* | arm-*-kfreebsd*-gnu)
 165                         COREFILE='' ;;
 166   arm-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 167   arm-*-riscix)         COREFILE=trad-core.lo ;;
 168   hppa*-*-hpux*)        COREFILE=hpux-core.lo ;;
 169   hppa*-*-hiux*)        COREFILE=hpux-core.lo ;;
 170   hppa*-*-mpeix*)       COREFILE=hpux-core.lo ;;
 171   hppa*-*-bsd*)         COREFILE="hpux-core.lo hppabsd-core.lo"
 172                         COREFLAG="-DHPUX_CORE -DHPPABSD_CORE" ;;
 173   hppa*-*-netbsd* | hppa*-*-openbsd*)
 174         COREFILE=netbsd-core.lo
 175         ;;
 176
 177   i370-*-*)
 178         COREFILE=trad-core.lo
 179         TRAD_HEADER='"hosts/i370linux.h"'
 180         ;;
 181
 182 changequote(,)dnl
 183   i[3-7]86-sequent-bsd*)
 184 changequote([,])dnl
 185         COREFILE=trad-core.lo
 186         TRAD_HEADER='"hosts/symmetry.h"'
 187         ;;
 188 changequote(,)dnl
 189   i[3-7]86-sequent-sysv4*) ;;
 190   i[3-7]86-sequent-sysv*)
 191 changequote([,])dnl
 192         COREFILE=trad-core.lo
 193         TRAD_HEADER='"hosts/symmetry.h"'
 194         ;;
 195 changequote(,)dnl
 196   i[3-7]86-*-bsdi)
 197 changequote([,])dnl
 198         COREFILE=
 199         ;;
 200 changequote(,)dnl
 201   i[3-7]86-*-bsd* | i[3-7]86-*-freebsd[123] | i[3-7]86-*-freebsd[123]\.* | i[3-7]86-*-freebsd4\.[01234] | i[3-7]86-*-freebsd4\.[01234]\.* | i[3-7]86-*-freebsd*aout*)
 202 changequote([,])dnl
 203         COREFILE=trad-core.lo
 204         TRAD_HEADER='"hosts/i386bsd.h"'
 205         ;;
 206 changequote(,)dnl
 207   i[3-7]86-*-freebsd* | i[3-7]86-*-kfreebsd*-gnu)
 208 changequote([,])dnl
 209         COREFILE=''
 210         TRAD_HEADER='"hosts/i386bsd.h"'
 211         ;;
 212 changequote(,)dnl
 213   i[3-7]86-*-netbsd* | i[3-7]86-*-knetbsd*-gnu | i[3-7]86-*-openbsd*)
 214 changequote([,])dnl
 215         COREFILE=netbsd-core.lo
 216         ;;
 217 changequote(,)dnl
 218   i[3-7]86-esix-sysv3*)
 219 changequote([,])dnl
 220         COREFILE=trad-core.lo
 221         TRAD_HEADER='"hosts/esix.h"'
 222         ;;
 223 changequote(,)dnl
 224   i[3-7]86-*-sco3.2v5*)
 225 changequote([,])dnl
 226         COREFILE=sco5-core.lo
 227         ;;
 228 changequote(,)dnl
 229   i[3-7]86-*-sco* | i[3-7]86-*-isc*)
 230 changequote([,])dnl
 231         COREFILE=trad-core.lo
 232         TRAD_HEADER='"hosts/i386sco.h"'
 233         ;;
 234 changequote(,)dnl
 235   i[3-7]86-*-mach3*)
 236 changequote([,])dnl
 237         COREFILE=trad-core.lo
 238         TRAD_HEADER='"hosts/i386mach3.h"'
 239         ;;
 240 changequote(,)dnl
 241   i[3-7]86-*-linux-*)
 242 changequote([,])dnl
 243         COREFILE=trad-core.lo
 244         TRAD_HEADER='"hosts/i386linux.h"'
 245         ;;
 246 changequote(,)dnl
 247   i[3-7]86-*-isc*)      COREFILE=trad-core.lo ;;
 248   i[3-7]86-*-aix*)      COREFILE=aix386-core.lo ;;
 249 changequote([,])dnl
 250   i860-*-mach3* | i860-*-osf1*)
 251         COREFILE=trad-core.lo
 252         TRAD_HEADER='"hosts/i860mach3.h"'
 253         ;;
 254   mips-*-netbsd* | mips*-*-openbsd*)
 255         COREFILE=netbsd-core.lo
 256         ;;
 257   mips-dec-*)
 258         COREFILE=trad-core.lo
 259         TRAD_HEADER='"hosts/decstation.h"'
 260         ;;
 261   mips-sgi-irix4*)      COREFILE=irix-core.lo ;;
 262   mips-sgi-irix5*)      COREFILE=irix-core.lo ;;
 263   mips-sgi-irix6*)      COREFILE=irix-core.lo ;;
 264   mips-*-sysv4*)        ;;
 265   mips-*-sysv* | mips-*-riscos*)
 266         COREFILE=trad-core.lo
 267         TRAD_HEADER='"hosts/riscos.h"'
 268         ;;
 269   mips-sony-bsd*)
 270         COREFILE=trad-core.lo
 271         TRAD_HEADER='"hosts/news-mips.h"'
 272         ;;
 273   m68*-bull*-sysv*)
 274         COREFILE=trad-core.lo
 275         TRAD_HEADER='"hosts/dpx2.h"'
 276         ;;
 277   m68*-hp-hpux*)        COREFILE=hpux-core.lo ;;
 278   m68*-hp-bsd*)
 279         COREFILE=trad-core.lo
 280         TRAD_HEADER='"hosts/hp300bsd.h"'
 281         ;;
 282   m68*-*-linux-*)
 283         COREFILE=trad-core.lo
 284         TRAD_HEADER='"hosts/m68klinux.h"'
 285         ;;
 286   m68*-motorola-sysv*)
 287         COREFILE=trad-core.lo
 288         TRAD_HEADER='"hosts/delta68.h"'
 289         ;;
 290   m68*-sony-*)
 291         COREFILE=trad-core.lo
 292         TRAD_HEADER='"hosts/news.h"'
 293         ;;
 294   m68*-*-netbsd* | m68*-*-openbsd*)
 295         COREFILE=netbsd-core.lo
 296         ;;
 297   m68*-apple-aux*)
 298         COREFILE=trad-core.lo
 299         TRAD_HEADER='"hosts/m68kaux.h"'
 300         ;;
 301   m88*-*-sysv4*)
 302         ;;
 303   m88*-motorola-sysv*)
 304         COREFILE=ptrace-core.lo
 305         ;;
 306   m88*-*-mach3*)
 307         COREFILE=trad-core.lo
 308         TRAD_HEADER='"hosts/m88kmach3.h"'
 309         ;;
 310   m88*-*-openbsd*)
 311         COREFILE=netbsd-core.lo
 312         ;;
 313   ns32k-pc532-mach)
 314         COREFILE=trad-core.lo
 315         TRAD_HEADER='"hosts/pc532mach.h"'
 316         ;;
 317   ns32k-*-netbsd* | ns32k-*-openbsd*)
 318         COREFILE=netbsd-core.lo
 319         ;;
 320   rs6000-*-lynx*)
 321         COREFILE=lynx-core.lo
 322         ;;
 323   rs6000-*-aix5.* | powerpc-*-aix5.*)
 324         COREFILE=rs6000-core.lo
 325         COREFLAG="$COREFLAG -DAIX_5_CORE -DAIX_CORE_DUMPX_CORE"
 326         ;;
 327 changequote(,)dnl
 328   rs6000-*-aix4.[3-9]* | powerpc-*-aix4.[3-9]*)
 329 changequote([,])dnl
 330         COREFILE=rs6000-core.lo
 331         COREFLAG="$COREFLAG -DAIX_CORE_DUMPX_CORE"
 332         # Not all versions of AIX with -DAIX_CORE_DUMPX_CORE
 333         # have c_impl as a member of struct core_dumpx
 334         AC_MSG_CHECKING([for c_impl in struct core_dumpx])
 335         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <core.h>]], [[struct core_dumpx c; c.c_impl = 0;]])],[AC_DEFINE(HAVE_ST_C_IMPL, 1,
 336             [Define if struct core_dumpx has member c_impl])
 337           AC_MSG_RESULT(yes)],[AC_MSG_RESULT(no)])
 338         ;;
 339   rs6000-*-aix4*)       COREFILE=rs6000-core.lo ;;
 340   rs6000-*-*)           COREFILE=rs6000-core.lo ;;
 341   powerpc-*-aix4*)      COREFILE=rs6000-core.lo ;;
 342   powerpc-*-aix*)       COREFILE=rs6000-core.lo ;;
 343   powerpc-*-beos*)      ;;
 344   powerpc-*-freebsd* | powerpc-*-kfreebsd*-gnu)
 345                         COREFILE='' ;;
 346   powerpc-*-netbsd*)    COREFILE=netbsd-core.lo ;;
 347   powerpc-*-*bsd*)      COREFILE=netbsd-core.lo ;;
 348   s390*-*-*)            COREFILE=trad-core.lo ;;
 349   sh*-*-netbsd*)        COREFILE=netbsd-core.lo ;;
 350   sparc-*-netbsd* | sparc*-*-openbsd*)
 351         COREFILE=netbsd-core.lo
 352         ;;
 353   tahoe-*-*)
 354         COREFILE=trad-core.lo
 355         TRAD_HEADER='"hosts/tahoe.h"'
 356         ;;
 357   vax-*-netbsd* | vax-*-openbsd*)
 358         COREFILE=netbsd-core.lo
 359         ;;
 360   vax-*-ultrix2*)
 361         COREFILE=trad-core.lo
 362         TRAD_HEADER='"hosts/vaxult2.h"'
 363         ;;
 364   vax-*-ultrix*)
 365         COREFILE=trad-core.lo
 366         TRAD_HEADER='"hosts/vaxult2.h"'
 367         ;;
 368   vax-*-linux-*)
 369         COREFILE=trad-core.lo
 370         TRAD_HEADER='"hosts/vaxlinux.h"'
 371         ;;
 372   vax-*-*)
 373         COREFILE=trad-core.lo
 374         TRAD_HEADER='"hosts/vaxbsd.h"'
 375         ;;
 376   x86_64-*-netbsd* | x86_64-*-openbsd*)
 377         COREFILE=netbsd-core.lo
 378         ;;
 379   esac
 380
 381   case "$COREFILE" in
 382   aix386-core.lo)       COREFLAG=-DAIX386_CORE ;;
 383   hppabsd-core.lo)      COREFLAG=-DHPPABSD_CORE ;;
 384   hpux-core.lo)         COREFLAG=-DHPUX_CORE ;;
 385   irix-core.lo)         COREFLAG=-DIRIX_CORE ;;
 386   lynx-core.lo)         COREFLAG=-DLYNX_CORE ;;
 387   netbsd-core.lo)       COREFLAG=-DNETBSD_CORE ;;
 388   osf-core.lo)          COREFLAG=-DOSF_CORE ;;
 389   ptrace-core.lo)       COREFLAG=-DPTRACE_CORE ;;
 390   rs6000-core.lo)       COREFLAG="$COREFLAG -DAIX_CORE" ;;
 391   sco5-core.lo)         COREFLAG="$COREFLAG -DSCO5_CORE" ;;
 392   trad-core.lo)         COREFLAG="$COREFLAG -DTRAD_CORE" ;;
 393   esac
 394
 395   # ELF corefile support has several flavors, but all of
 396   # them use something called <sys/procfs.h>
 397   AC_CHECK_HEADERS(sys/procfs.h)
 398   if test "$ac_cv_header_sys_procfs_h" = yes; then
 399     BFD_HAVE_SYS_PROCFS_TYPE(prstatus_t)
 400     BFD_HAVE_SYS_PROCFS_TYPE(prstatus32_t)
 401     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus_t, pr_who)
 402     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(prstatus32_t, pr_who)
 403     BFD_HAVE_SYS_PROCFS_TYPE(pstatus_t)
 404     BFD_HAVE_SYS_PROCFS_TYPE(pxstatus_t)
 405     BFD_HAVE_SYS_PROCFS_TYPE(pstatus32_t)
 406     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo_t)
 407     BFD_HAVE_SYS_PROCFS_TYPE(prpsinfo32_t)
 408     BFD_HAVE_SYS_PROCFS_TYPE(psinfo_t)
 409     BFD_HAVE_SYS_PROCFS_TYPE(psinfo32_t)
 410     BFD_HAVE_SYS_PROCFS_TYPE(lwpstatus_t)
 411     BFD_HAVE_SYS_PROCFS_TYPE(lwpxstatus_t)
 412     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_context)
 413     BFD_HAVE_SYS_PROCFS_TYPE_MEMBER(lwpstatus_t, pr_reg)
 414     BFD_HAVE_SYS_PROCFS_TYPE(win32_pstatus_t)
 415   fi
 416 fi
 417 AC_SUBST(COREFILE)
 418 AC_SUBST(COREFLAG)
 419 if test -n "$TRAD_HEADER"; then
 420   AC_DEFINE_UNQUOTED(TRAD_HEADER, $TRAD_HEADER,
 421     [Name of host specific header file to include in trad-core.c.])
 422 fi
 423
 424 # Horrible hacks to build DLLs on Windows.
 425 WIN32LDFLAGS=
 426 WIN32LIBADD=
 427 case "${host}" in
 428 *-*-cygwin*)
 429   if test "$enable_shared" = "yes"; then
 430     WIN32LDFLAGS="-no-undefined"
 431     WIN32LIBADD="-L`pwd`/../libiberty -liberty -L`pwd`/../intl -lintl -lcygwin -lkernel32"
 432   fi
 433   ;;
 434 *-*-linux*)
 435   # We borrow WIN32LIBADD so that the shared libbfd won't depend on
 436   # libiberty.a.
 437   case "${host}" in
 438   mips*-*-linux*)
 439     # Linux/MIPS uses PIC by default.
 440     if test "$enable_shared" = "yes"; then
 441       WIN32LIBADD="-L../libiberty -liberty"
 442     fi
 443     ;;
 444   *)
 445 changequote(,)dnl
 446     x=`sed -n -e 's/^[  ]*PICFLAG[      ]*=[    ]*//p' < ../libiberty/Makefile | sed -n '$p'`
 447 changequote([,])dnl
 448     if test -n "$x"; then
 449       WIN32LIBADD="-L../libiberty/pic -liberty"
 450     fi
 451   ;;
 452   esac
 453   ;;
 454 esac
 455 AC_SUBST(WIN32LDFLAGS)
 456 AC_SUBST(WIN32LIBADD)
 457
 458 # target stuff:
 459
 460 # Canonicalize the secondary target names.
 461 if test -n "$enable_targets" ; then
 462     for targ in `echo $enable_targets | sed 's/,/ /g'`
 463     do
 464         result=`$ac_config_sub $targ 2>/dev/null`
 465         if test -n "$result" ; then
 466             canon_targets="$canon_targets $result"
 467         else
 468             # Allow targets that config.sub doesn't recognize, like "all".
 469             canon_targets="$canon_targets $targ"
 470         fi
 471     done
 472 fi
 473
 474 all_targets=false
 475 defvec=
 476 selvecs=
 477 assocvecs=
 478 selarchs=
 479 TDEFINES=
 480 for targ in $target $canon_targets
 481 do
 482     if test "x$targ" = "xall"; then
 483         all_targets=true
 484         assocvecs="$assocvecs $targ_defvec $targ_selvecs"
 485     else
 486         . $srcdir/config.bfd
 487         if test "x$targ" = "x$target"; then
 488             defvec=$targ_defvec
 489         fi
 490         selvecs="$selvecs $targ_defvec $targ_selvecs"
 491         selarchs="$selarchs $targ_archs"
 492         TDEFINES="$TDEFINES $targ_cflags"
 493     fi
 494 done
 495 AC_SUBST(TDEFINES)
 496
 497 # This processing still needs to be done if we're to decide properly whether
 498 # 64-bit support needs to be compiled in.  Currently, it will be included if
 499 # the default or any other explicitly requested target requires it; it
 500 # will not be included on a 32-bit host if no 64-bit target is requested, and
 501 # no "--with-64-bit-bfd" option is given, even if "--enable-targets=all" is
 502 # used.
 503
 504 # uniq the default and selected vectors in all the configured targets.
 505 f=""
 506 for i in $selvecs ; do
 507     case " $f " in
 508     *" $i "*) ;;
 509     *) f="$f $i" ;;
 510     esac
 511 done
 512 selvecs="$f"
 513
 514
 515 # uniq the associated vectors in all the configured targets.
 516 f=""
 517 for i in $assocvecs ; do
 518     case " $f " in
 519     *" $i "*) ;;
 520     *) f="$f $i" ;;
 521     esac
 522 done
 523 assocvecs="$f"
 524
 525
 526 # uniq the architectures in all the configured targets.
 527 f=""
 528 for i in $selarchs ; do
 529     case " $f " in
 530     *" $i "*) ;;
 531     *) f="$f $i" ;;
 532     esac
 533 done
 534 selarchs="$f"
 535
 536 # Target backend .o files.
 537 tb=
 538
 539 elf="elf.lo elflink.lo elf-strtab.lo elf-eh-frame.lo dwarf1.lo"
 540
 541 for vec in $selvecs
 542 do
 543     target_size=32
 544     case "$vec" in
 545     # This list is alphabetized to make it easy to compare
 546     # with the two vector lists in targets.c.  For the same reason,
 547     # use one entry per line, even though this leads to long lines.
 548     a29kcoff_big_vec)           tb="$tb coff-a29k.lo cofflink.lo" ;;
 549     a_out_adobe_vec)            tb="$tb aout-adobe.lo aout32.lo" ;;
 550     aix5coff64_vec)             tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 551     aout0_big_vec)              tb="$tb aout0.lo aout32.lo" ;;
 552     aout_arm_big_vec)           tb="$tb aout-arm.lo aout32.lo" ;;
 553     aout_arm_little_vec)        tb="$tb aout-arm.lo aout32.lo" ;;
 554     apollocoff_vec)             tb="$tb coff-apollo.lo" ;;
 555     arm_epoc_pe_big_vec)        tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 556     arm_epoc_pe_little_vec)     tb="$tb epoc-pe-arm.lo peigen.lo cofflink.lo " ;;
 557     arm_epoc_pei_big_vec)       tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 558     arm_epoc_pei_little_vec)    tb="$tb epoc-pei-arm.lo peigen.lo cofflink.lo " ;;
 559     armcoff_big_vec)            tb="$tb coff-arm.lo cofflink.lo " ;;
 560     armcoff_little_vec)         tb="$tb coff-arm.lo cofflink.lo " ;;
 561     armnetbsd_vec)              tb="$tb armnetbsd.lo aout32.lo" ;;
 562     armpe_big_vec)              tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 563     armpe_little_vec)           tb="$tb pe-arm.lo peigen.lo cofflink.lo " ;;
 564     armpei_big_vec)             tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 565     armpei_little_vec)          tb="$tb pei-arm.lo peigen.lo cofflink.lo " ;;
 566     b_out_vec_big_host)         tb="$tb bout.lo aout32.lo" ;;
 567     b_out_vec_little_host)      tb="$tb bout.lo aout32.lo" ;;
 568     bfd_efi_app_ia32_vec)       tb="$tb efi-app-ia32.lo peigen.lo cofflink.lo" ;;
 569     bfd_efi_app_ia64_vec)       tb="$tb efi-app-ia64.lo pepigen.lo cofflink.lo"; target_size=64 ;;
 570     bfd_elf32_am33lin_vec)      tb="$tb elf32-am33lin.lo elf32.lo $elf" ;;
 571     bfd_elf32_avr_vec)          tb="$tb elf32-avr.lo elf32.lo $elf" ;;
 572     bfd_elf32_big_generic_vec)  tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 573     bfd_elf32_bigarc_vec)       tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 574     bfd_elf32_bigarm_vec)       tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 575     bfd_elf32_bigarm_symbian_vec)
 576                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 577     bfd_elf32_bigarm_vxworks_vec)
 578                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 579     bfd_elf32_bigmips_vec)      tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 580     bfd_elf32_cr16c_vec)        tb="$tb elf32-cr16c.lo elf32.lo $elf" ;;
 581     bfd_elf32_cris_vec)         tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 582     bfd_elf32_crx_vec)          tb="$tb elf32-crx.lo elf32.lo $elf" ;;
 583     bfd_elf32_d10v_vec)         tb="$tb elf32-d10v.lo elf32.lo $elf" ;;
 584     bfd_elf32_d30v_vec)         tb="$tb elf32-d30v.lo elf32.lo $elf" ;;
 585     bfd_elf32_dlx_big_vec)      tb="$tb elf32-dlx.lo elf32.lo $elf" ;;
 586     bfd_elf32_fr30_vec)         tb="$tb elf32-fr30.lo elf32.lo $elf" ;;
 587     bfd_elf32_frv_vec)          tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 588     bfd_elf32_frvfdpic_vec)     tb="$tb elf32-frv.lo elf32.lo $elf" ;;
 589     bfd_elf32_h8300_vec)        tb="$tb elf32-h8300.lo elf32.lo $elf" ;;
 590     bfd_elf32_hppa_linux_vec)   tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 591     bfd_elf32_hppa_nbsd_vec)    tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 592     bfd_elf32_hppa_vec)         tb="$tb elf32-hppa.lo elf32.lo $elf" ;;
 593     bfd_elf32_i370_vec)         tb="$tb elf32-i370.lo elf32.lo $elf" ;;
 594     bfd_elf32_i386_freebsd_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 595     bfd_elf32_i386_vxworks_vec) tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 596     bfd_elf32_i386_vec)         tb="$tb elf32-i386.lo elf-vxworks.lo elf32.lo $elf" ;;
 597     bfd_elf32_i860_little_vec)  tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 598     bfd_elf32_i860_vec)         tb="$tb elf32-i860.lo elf32.lo $elf" ;;
 599     bfd_elf32_i960_vec)         tb="$tb elf32-i960.lo elf32.lo $elf" ;;
 600     bfd_elf32_ia64_big_vec)     tb="$tb elf32-ia64.lo elf32.lo $elf" ;;
 601     bfd_elf32_ia64_hpux_big_vec) tb="$tb elf32-ia64.lo elf32.lo $elf";;
 602     bfd_elf32_ip2k_vec)         tb="$tb elf32-ip2k.lo elf32.lo $elf" ;;
 603     bfd_elf32_iq2000_vec)       tb="$tb elf32-iq2000.lo elf32.lo $elf" ;;
 604     bfd_elf32_little_generic_vec) tb="$tb elf32-gen.lo elf32.lo $elf" ;;
 605     bfd_elf32_littlearc_vec)    tb="$tb elf32-arc.lo elf32.lo $elf" ;;
 606     bfd_elf32_littlearm_symbian_vec)
 607                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 608     bfd_elf32_littlearm_vxworks_vec)
 609                                 tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 610     bfd_elf32_littlearm_vec)    tb="$tb elf32-arm.lo elf32.lo $elf" ;;
 611     bfd_elf32_littlemips_vec)   tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 612     bfd_elf32_m32r_vec)         tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 613     bfd_elf32_m32rle_vec)       tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 614     bfd_elf32_m32rlin_vec)      tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 615     bfd_elf32_m32rlelin_vec)    tb="$tb elf32-m32r.lo elf32.lo $elf" ;;
 616     bfd_elf32_m68hc11_vec)      tb="$tb elf32-m68hc11.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 617     bfd_elf32_m68hc12_vec)      tb="$tb elf32-m68hc12.lo elf32-m68hc1x.lo elf32.lo $elf" ;;
 618     bfd_elf32_m68k_vec)         tb="$tb elf32-m68k.lo elf32.lo $elf" ;;
 619     bfd_elf32_m88k_vec)         tb="$tb elf32-m88k.lo elf32.lo $elf" ;;
 620     bfd_elf32_mcore_big_vec)    tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 621     bfd_elf32_mcore_little_vec) tb="$tb elf32-mcore.lo elf32.lo $elf" ;;
 622     bfd_elf32_mn10200_vec)      tb="$tb elf-m10200.lo elf32.lo $elf" ;;
 623     bfd_elf32_mn10300_vec)      tb="$tb elf-m10300.lo elf32.lo $elf" ;;
 624     bfd_elf32_msp430_vec)       tb="$tb elf32-msp430.lo elf32.lo $elf" ;;
 625     bfd_elf32_nbigmips_vec)     tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 626     bfd_elf32_nlittlemips_vec)  tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 627     bfd_elf32_ntradbigmips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 628     bfd_elf32_ntradlittlemips_vec) tb="$tb elfn32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 629     bfd_elf32_openrisc_vec)     tb="$tb elf32-openrisc.lo elf32.lo $elf" ;;
 630     bfd_elf32_or32_big_vec)     tb="$tb elf32-or32.lo elf32.lo $elf" ;;
 631     bfd_elf32_pj_vec)           tb="$tb elf32-pj.lo elf32.lo $elf";;
 632     bfd_elf32_pjl_vec)          tb="$tb elf32-pj.lo elf32.lo $elf";;
 633     bfd_elf32_powerpc_vec)      tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 634     bfd_elf32_powerpcle_vec)    tb="$tb elf32-ppc.lo elf32.lo $elf" ;;
 635     bfd_elf32_s390_vec)         tb="$tb elf32-s390.lo elf32.lo $elf" ;;
 636     # FIXME: We include cofflink.lo not because it's needed for
 637     # bfd_elf32_sh64[l]_vec, but because we include bfd_elf32_sh[l]_vec
 638     # which needs it but does not list it.  Should be fixed in right place.
 639     bfd_elf32_sh64_vec)         tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 640     bfd_elf32_sh64l_vec)        tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 641     bfd_elf32_sh64lin_vec)      tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 642     bfd_elf32_sh64blin_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" target_size=64 ;;
 643     bfd_elf32_sh64lnbsd_vec)    tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 644     bfd_elf32_sh64nbsd_vec)     tb="$tb elf32-sh64.lo elf32-sh64-com.lo elf32.lo $elf cofflink.lo" ;;
 645     bfd_elf32_sh_vec)           tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 646     bfd_elf32_shblin_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 647     bfd_elf32_shl_vec)          tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo" ;;
 648     bfd_elf32_shl_symbian_vec)  tb="$tb elf32-sh-symbian.lo elf32-sh64-com.lo elf32.lo $elf coff-sh.lo" ;;
 649     bfd_elf32_shlin_vec)        tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 650     bfd_elf32_shlnbsd_vec)      tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 651     bfd_elf32_shnbsd_vec)       tb="$tb elf32-sh.lo elf32.lo $elf coff-sh.lo cofflink.lo" ;;
 652     bfd_elf32_sparc_vec)        tb="$tb elf32-sparc.lo elfxx-sparc.lo elf32.lo $elf" ;;
 653     bfd_elf32_tradbigmips_vec)  tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 654     bfd_elf32_tradlittlemips_vec) tb="$tb elf32-mips.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo" ;;
 655     bfd_elf32_us_cris_vec)      tb="$tb elf32-cris.lo elf32.lo $elf" ;;
 656     bfd_elf32_v850_vec)         tb="$tb elf32-v850.lo elf32.lo $elf" ;;
 657     bfd_elf32_vax_vec)          tb="$tb elf32-vax.lo elf32.lo $elf" ;;
 658     bfd_elf32_xstormy16_vec)    tb="$tb elf32-xstormy16.lo elf32.lo $elf" ;;
 659     bfd_elf32_xtensa_le_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 660     bfd_elf32_xtensa_be_vec)    tb="$tb xtensa-isa.lo xtensa-modules.lo elf32-xtensa.lo elf32.lo $elf" ;;
 661     bfd_elf64_alpha_freebsd_vec) tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 662     bfd_elf64_alpha_vec)        tb="$tb elf64-alpha.lo elf64.lo $elf"; target_size=64 ;;
 663     bfd_elf64_big_generic_vec)  tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 664     bfd_elf64_bigmips_vec)      tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 665     bfd_elf64_hppa_linux_vec)   tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 666     bfd_elf64_hppa_vec)         tb="$tb elf64-hppa.lo elf64.lo $elf"; target_size=64 ;;
 667     bfd_elf64_ia64_big_vec)     tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 668     bfd_elf64_ia64_hpux_big_vec) tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 669     bfd_elf64_ia64_little_vec)  tb="$tb elf64-ia64.lo elf64.lo $elf"; target_size=64 ;;
 670     bfd_elf64_little_generic_vec) tb="$tb elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 671     bfd_elf64_littlemips_vec)   tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 672     bfd_elf64_mmix_vec)         tb="$tb elf64-mmix.lo elf64.lo $elf" target_size=64 ;;
 673     bfd_elf64_powerpc_vec)      tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf"; target_size=64 ;;
 674     bfd_elf64_powerpcle_vec)    tb="$tb elf64-ppc.lo elf64-gen.lo elf64.lo $elf" target_size=64 ;;
 675     bfd_elf64_s390_vec)         tb="$tb elf64-s390.lo elf64.lo $elf"; target_size=64 ;;
 676     bfd_elf64_sh64_vec)         tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 677     bfd_elf64_sh64l_vec)        tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 678     bfd_elf64_sh64lin_vec)      tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 679     bfd_elf64_sh64blin_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 680     bfd_elf64_sh64lnbsd_vec)    tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 681     bfd_elf64_sh64nbsd_vec)     tb="$tb elf64-sh64.lo elf64.lo $elf" target_size=64 ;;
 682     bfd_elf64_sparc_vec)        tb="$tb elf64-sparc.lo elfxx-sparc.lo elf64.lo $elf"; target_size=64 ;;
 683     bfd_elf64_tradbigmips_vec)  tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 684     bfd_elf64_tradlittlemips_vec) tb="$tb elf64-mips.lo elf64.lo elfxx-mips.lo elf32.lo $elf ecofflink.lo"; target_size=64 ;;
 685     bfd_elf64_x86_64_vec)       tb="$tb elf64-x86-64.lo elf64.lo $elf"; target_size=64 ;;
 686     bfd_mmo_vec)                tb="$tb mmo.lo" target_size=64 ;;
 687     bfd_powerpc_pe_vec)         tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 688     bfd_powerpc_pei_vec)        tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 689     bfd_powerpcle_pe_vec)       tb="$tb pe-ppc.lo peigen.lo cofflink.lo" ;;
 690     bfd_powerpcle_pei_vec)      tb="$tb pei-ppc.lo peigen.lo cofflink.lo" ;;
 691     cris_aout_vec)              tb="$tb aout-cris.lo" ;;
 692     demo_64_vec)                tb="$tb demo64.lo aout64.lo"; target_size=64 ;;
 693     ecoff_big_vec)              tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 694     ecoff_biglittle_vec)        tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 695     ecoff_little_vec)           tb="$tb coff-mips.lo ecoff.lo ecofflink.lo" ;;
 696     ecoffalpha_little_vec)      tb="$tb coff-alpha.lo ecoff.lo ecofflink.lo"; target_size=64 ;;
 697     go32coff_vec)               tb="$tb coff-go32.lo cofflink.lo" ;;
 698     go32stubbedcoff_vec)        tb="$tb coff-stgo32.lo cofflink.lo" ;;
 699     h8300coff_vec)              tb="$tb coff-h8300.lo reloc16.lo" ;;
 700     h8500coff_vec)              tb="$tb coff-h8500.lo reloc16.lo" ;;
 701     host_aout_vec)              tb="$tb host-aout.lo aout32.lo" ;;
 702     hp300bsd_vec)               tb="$tb hp300bsd.lo aout32.lo" ;;
 703     hp300hpux_vec)              tb="$tb hp300hpux.lo aout32.lo" ;;
 704     i386aout_vec)               tb="$tb i386aout.lo aout32.lo" ;;
 705     i386bsd_vec)                tb="$tb i386bsd.lo aout32.lo" ;;
 706     i386coff_vec)               tb="$tb coff-i386.lo cofflink.lo" ;;
 707     i386dynix_vec)              tb="$tb i386dynix.lo aout32.lo" ;;
 708     i386freebsd_vec)            tb="$tb i386freebsd.lo aout32.lo" ;;
 709     i386linux_vec)              tb="$tb i386linux.lo aout32.lo" ;;
 710     i386lynx_aout_vec)          tb="$tb i386lynx.lo lynx-core.lo aout32.lo" ;;
 711     i386lynx_coff_vec)          tb="$tb cf-i386lynx.lo cofflink.lo lynx-core.lo" ;;
 712     i386mach3_vec)              tb="$tb i386mach3.lo aout32.lo" ;;
 713     i386msdos_vec)              tb="$tb i386msdos.lo" ;;
 714     i386netbsd_vec)             tb="$tb i386netbsd.lo aout32.lo" ;;
 715     i386os9k_vec)               tb="$tb i386os9k.lo aout32.lo" ;;
 716     i386pe_vec)                 tb="$tb pe-i386.lo peigen.lo cofflink.lo" ;;
 717     i386pei_vec)                tb="$tb pei-i386.lo peigen.lo cofflink.lo" ;;
 718     i860coff_vec)               tb="$tb coff-i860.lo cofflink.lo" ;;
 719     icoff_big_vec)              tb="$tb coff-i960.lo cofflink.lo" ;;
 720     icoff_little_vec)           tb="$tb coff-i960.lo cofflink.lo" ;;
 721     ieee_vec)                   tb="$tb ieee.lo" ;;
 722     m68k4knetbsd_vec)           tb="$tb m68k4knetbsd.lo aout32.lo" ;;
 723     m68kaux_coff_vec)           tb="$tb coff-aux.lo coff-m68k.lo cofflink.lo" ;;
 724     m68kcoff_vec)               tb="$tb coff-m68k.lo cofflink.lo" ;;
 725     m68kcoffun_vec)             tb="$tb coff-u68k.lo coff-m68k.lo cofflink.lo" ;;
 726     m68klinux_vec)              tb="$tb m68klinux.lo aout32.lo" ;;
 727     m68klynx_aout_vec)          tb="$tb m68klynx.lo lynx-core.lo aout32.lo" ;;
 728     m68klynx_coff_vec)          tb="$tb cf-m68klynx.lo coff-m68k.lo cofflink.lo lynx-core.lo" ;;
 729     m68knetbsd_vec)             tb="$tb m68knetbsd.lo aout32.lo" ;;
 730     m68ksysvcoff_vec)           tb="$tb coff-svm68k.lo cofflink.lo" ;;
 731     m88kbcs_vec)                tb="$tb coff-m88k.lo" ;;
 732     m88kmach3_vec)              tb="$tb m88kmach3.lo aout32.lo" ;;
 733     m88kopenbsd_vec)            tb="$tb m88kopenbsd.lo aout32.lo" ;;
 734     maxqcoff_vec)               tb="$tb coff-maxq.lo" ;;
 735     mach_o_be_vec)              tb="$tb mach-o.lo" ;;
 736     mach_o_le_vec)              tb="$tb mach-o.lo" ;;
 737     mach_o_fat_vec)             tb="$tb mach-o.lo" ;;
 738     mcore_pe_big_vec)           tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 739     mcore_pe_little_vec)        tb="$tb pe-mcore.lo peigen.lo cofflink.lo" ;;
 740     mcore_pei_big_vec)          tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 741     mcore_pei_little_vec)       tb="$tb pei-mcore.lo peigen.lo cofflink.lo" ;;
 742     mipslpe_vec)                tb="$tb pe-mips.lo peigen.lo cofflink.lo" ;;
 743     mipslpei_vec)               tb="$tb pei-mips.lo peigen.lo cofflink.lo" ;;
 744     newsos3_vec)                tb="$tb newsos3.lo aout32.lo" ;;
 745     nlm32_alpha_vec)            tb="$tb nlm32-alpha.lo nlm32.lo nlm.lo"; target_size=64 ;;
 746     nlm32_i386_vec)             tb="$tb nlm32-i386.lo nlm32.lo nlm.lo" ;;
 747     nlm32_powerpc_vec)          tb="$tb nlm32-ppc.lo nlm32.lo nlm.lo" ;;
 748     nlm32_sparc_vec)            tb="$tb nlm32-sparc.lo nlm32.lo nlm.lo" ;;
 749     or32coff_big_vec)           tb="$tb coff-or32.lo cofflink.lo" ;;
 750     pc532machaout_vec)          tb="$tb pc532-mach.lo aout-ns32k.lo" ;;
 751     pc532netbsd_vec)            tb="$tb ns32knetbsd.lo aout-ns32k.lo" ;;
 752     pef_vec)                    tb="$tb pef.lo" ;;
 753     pef_xlib_vec)               tb="$tb pef.lo" ;;
 754     pdp11_aout_vec)             tb="$tb pdp11.lo" ;;
 755     pmac_xcoff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 756     ppcboot_vec)                tb="$tb ppcboot.lo" ;;
 757     riscix_vec)                 tb="$tb aout32.lo riscix.lo" ;;
 758     rs6000coff64_vec)           tb="$tb coff64-rs6000.lo xcofflink.lo aix5ppc-core.lo"; target_size=64 ;;
 759     rs6000coff_vec)             tb="$tb coff-rs6000.lo xcofflink.lo" ;;
 760     shcoff_small_vec)           tb="$tb coff-sh.lo cofflink.lo" ;;
 761     shcoff_vec)                 tb="$tb coff-sh.lo cofflink.lo" ;;
 762     shlcoff_small_vec)          tb="$tb coff-sh.lo cofflink.lo" ;;
 763     shlcoff_vec)                tb="$tb coff-sh.lo cofflink.lo" ;;
 764     shlpe_vec)                  tb="$tb pe-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 765     shlpei_vec)                 tb="$tb pei-sh.lo coff-sh.lo peigen.lo cofflink.lo" ;;
 766     som_vec)                    tb="$tb som.lo" ;;
 767     sparccoff_vec)              tb="$tb coff-sparc.lo" ;;
 768     sparcle_aout_vec)           tb="$tb aout-sparcle.lo aout32.lo" ;;
 769     sparclinux_vec)             tb="$tb sparclinux.lo aout32.lo" ;;
 770     sparclynx_aout_vec)         tb="$tb sparclynx.lo lynx-core.lo aout32.lo" ;;
 771     sparclynx_coff_vec)         tb="$tb cf-sparclynx.lo lynx-core.lo" ;;
 772     sparcnetbsd_vec)            tb="$tb sparcnetbsd.lo aout32.lo" ;;
 773     sunos_big_vec)              tb="$tb sunos.lo aout32.lo" ;;
 774     sym_vec)                    tb="$tb xsym.lo" ;;
 775     tic30_aout_vec)             tb="$tb aout-tic30.lo" ;;
 776     tic30_coff_vec)             tb="$tb coff-tic30.lo" ;;
 777     tic4x_coff0_vec)            tb="$tb coff-tic4x.lo" ;;
 778     tic4x_coff0_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 779     tic4x_coff1_vec)            tb="$tb coff-tic4x.lo" ;;
 780     tic4x_coff1_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 781     tic4x_coff2_vec)            tb="$tb coff-tic4x.lo" ;;
 782     tic4x_coff2_beh_vec)        tb="$tb coff-tic4x.lo" ;;
 783     tic54x_coff0_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 784     tic54x_coff0_vec)           tb="$tb coff-tic54x.lo" ;;
 785     tic54x_coff1_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 786     tic54x_coff1_vec)           tb="$tb coff-tic54x.lo" ;;
 787     tic54x_coff2_beh_vec)       tb="$tb coff-tic54x.lo" ;;
 788     tic54x_coff2_vec)           tb="$tb coff-tic54x.lo" ;;
 789     tic80coff_vec)              tb="$tb coff-tic80.lo cofflink.lo" ;;
 790     vaxnetbsd_vec)              tb="$tb vaxnetbsd.lo aout32.lo" ;;
 791     vax1knetbsd_vec)            tb="$tb vax1knetbsd.lo aout32.lo" ;;
 792     vaxbsd_vec)                 tb="$tb vaxbsd.lo aout32.lo" ;;
 793     versados_vec)               tb="$tb versados.lo" ;;
 794     vms_alpha_vec)              tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo"; target_size=64 ;;
 795     vms_vax_vec)                tb="$tb vms.lo vms-hdr.lo vms-gsd.lo vms-tir.lo vms-misc.lo" ;;
 796     w65_vec)                    tb="$tb coff-w65.lo reloc16.lo" ;;
 797     we32kcoff_vec)              tb="$tb coff-we32k.lo" ;;
 798     z8kcoff_vec)                tb="$tb coff-z8k.lo reloc16.lo" ;;
 799
 800     # These appear out of order in targets.c
 801     srec_vec)                   tb="$tb srec.lo" ;;
 802     symbolsrec_vec)             tb="$tb srec.lo" ;;
 803     tekhex_vec)                 tb="$tb tekhex.lo" ;;
 804     cisco_core_big_vec)         tb="$tb cisco-core.lo" ;;
 805     cisco_core_little_vec)      tb="$tb cisco-core.lo" ;;
 806
 807     "")                 ;;
 808     *) AC_MSG_ERROR(*** unknown target vector $vec) ;;
 809     esac
 810
 811     if test ${target_size} = 64; then
 812         target64=true
 813     fi
 814     if test x"${vec}" = x"${defvec}"; then
 815         bfd_default_target_size=${target_size}
 816     fi
 817 done
 818
 819 # Target architecture .o files.
 820 # A couple of CPUs use shorter file names to avoid problems on DOS
 821 # filesystems.
 822 ta=`echo $selarchs | sed -e s/bfd_/cpu-/g -e s/_arch/.lo/g -e s/mn10200/m10200/ -e s/mn10300/m10300/`
 823
 824 # Weed out duplicate .o files.
 825 f=""
 826 for i in $tb ; do
 827     case " $f " in
 828     *" $i "*) ;;
 829     *) f="$f $i" ;;
 830     esac
 831 done
 832 tb="$f"
 833
 834 f=""
 835 for i in $ta ; do
 836     case " $f " in
 837     *" $i "*) ;;
 838     *) f="$f $i" ;;
 839     esac
 840 done
 841 ta="$f"
 842
 843 bfd_backends="$tb"
 844 bfd_machines="$ta"
 845
 846 if test x${all_targets} = xtrue ; then
 847   bfd_backends="${bfd_backends}"' $(ALL_BACKENDS)'
 848   bfd_machines="${bfd_machines}"' $(ALL_MACHINES)'
 849   selvecs=
 850   havevecs=
 851   selarchs=
 852   test -n "$assocvecs" &&
 853     assocvecs=`echo $assocvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 854 else    # all_targets is true
 855   # Only set these if they will be nonempty, for the clever echo.
 856   havevecs=
 857   assocvecs=
 858   test -n "$selvecs" &&
 859     havevecs=`echo $selvecs | sed -e 's/^/-DHAVE_/' -e 's/ \(.\)/ -DHAVE_\1/g'`
 860   test -n "$selvecs" &&
 861     selvecs=`echo $selvecs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 862   test -n "$selarchs" &&
 863     selarchs=`echo $selarchs | sed -e 's/^/\&/' -e 's/ \(.\)/,\&\1/g'`
 864 fi      # all_targets is true
 865
 866 case ${host64}-${target64}-${want64} in
 867   *true*)
 868     wordsize=64
 869     bfd_libs='$(BFD64_LIBS) $(BFD32_LIBS)'
 870     all_backends='$(BFD64_BACKENDS) $(BFD32_BACKENDS)'
 871     if test $BFD_HOST_64_BIT_DEFINED = 0; then
 872       AC_MSG_WARN([You have requested a 64 bit BFD configuration, but])
 873       AC_MSG_WARN([your compiler may not have a 64 bit integral type])
 874     fi
 875     if test -n "$GCC" ; then
 876        bad_64bit_gcc=no;
 877        AC_MSG_CHECKING([for gcc version with buggy 64-bit support])
 878        # Add more tests for gcc versions with non-working 64-bit support here.
 879        AC_EGREP_CPP([: 2 : 91 : 1 :],[:__GNUC__:__GNUC_MINOR__:__i386__:],
 880                     bad_64bit_gcc=yes;
 881                     AC_MSG_RESULT([yes: egcs-1.1.2 on ix86 spotted]),
 882                     AC_MSG_RESULT(no))
 883        if test $bad_64bit_gcc = yes ; then
 884          AC_MSG_ERROR([A newer version of gcc is needed for the requested 64-bit BFD configuration])
 885        fi
 886     fi
 887     ;;
 888   false-false-false)
 889     wordsize=32
 890     bfd_libs='$(BFD32_LIBS)'
 891     all_backends='$(BFD32_BACKENDS)'
 892     ;;
 893 esac
 894
 895 AC_SUBST(wordsize)
 896 AC_SUBST(bfd_libs)
 897 AC_SUBST(all_backends)
 898 AC_SUBST(bfd_backends)
 899 AC_SUBST(bfd_machines)
 900 AC_SUBST(bfd_default_target_size)
 901
 902 # Determine the host dependant file_ptr a.k.a. off_t type.  In order
 903 # prefer: off64_t - if ftello64 and fseeko64, off_t - if ftello and
 904 # fseeko, long.  This assumes that sizeof off_t is .ge. sizeof long.
 905 # Hopefully a reasonable assumption since fseeko et.al. should be
 906 # upward compatible.
 907 AC_CHECK_FUNCS(ftello ftello64 fseeko fseeko64)
 908 if test x"$ac_cv_func_ftello" = xyes -a x"$ac_cv_func_fseeko" = xyes; then
 909     AC_COMPILE_CHECK_SIZEOF(off_t)
 910 fi
 911 AC_MSG_CHECKING([file_ptr type])
 912 bfd_file_ptr="long"
 913 bfd_ufile_ptr="unsigned long"
 914 if test x"$ac_cv_func_ftello64" = xyes -a x"$ac_cv_func_fseeko64" = xyes \
 915         -o x"${ac_cv_sizeof_off_t}" = x8; then
 916     bfd_file_ptr=BFD_HOST_64_BIT
 917     bfd_ufile_ptr=BFD_HOST_U_64_BIT
 918 fi
 919 AC_MSG_RESULT($bfd_file_ptr)
 920 AC_SUBST(bfd_file_ptr)
 921 AC_SUBST(bfd_ufile_ptr)
 922
 923
 924 tdefaults=""
 925 test -n "${defvec}" && tdefaults="${tdefaults} -DDEFAULT_VECTOR=${defvec}"
 926 test -n "${selvecs}" && tdefaults="${tdefaults} -DSELECT_VECS='${selvecs}'"
 927 test -n "${assocvecs}" && tdefaults="${tdefaults} -DASSOCIATED_VECS='${assocvecs}'"
 928 test -n "${selarchs}" && tdefaults="${tdefaults} -DSELECT_ARCHITECTURES='${selarchs}'"
 929 test -n "${havevecs}" && tdefaults="${tdefaults} ${havevecs}"
 930 AC_SUBST(tdefaults)
 931
 932 dnl AC_CHECK_HEADERS(sys/mman.h)
 933 AC_FUNC_MMAP
 934 AC_CHECK_FUNCS(madvise mprotect)
 935 case ${want_mmap}+${ac_cv_func_mmap_fixed_mapped} in
 936   true+yes )  AC_DEFINE(USE_MMAP, 1, [Use mmap if it's available?]) ;;
 937 esac
 938
 939 rm -f doc/config.status
 940 AC_CONFIG_FILES([Makefile doc/Makefile bfd-in3.h:bfd-in2.h po/Makefile.in:po/Make-in])
 941 AC_CONFIG_COMMANDS([default],[[sed -e '/SRC-POTFILES =/r po/SRC-POTFILES' -e '/BLD-POTFILES =/r po/BLD-POTFILES' po/Makefile.in > po/Makefile]],[[]])
 942 AC_OUTPUT
 943