binutils/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl   Copyright (C) 2012-2022 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 m4_include([../config/debuginfod.m4])
  22 AC_INIT([binutils], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ar.c)
  24
  25 AC_CANONICAL_TARGET
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29
  30 AC_PROG_CC
  31 AC_GNU_SOURCE
  32 AC_USE_SYSTEM_EXTENSIONS
  33
  34 LT_INIT
  35 ACX_LARGEFILE
  36
  37 ac_checking=
  38 . ${srcdir}/../bfd/development.sh
  39 test "$development" = true && ac_checking=yes
  40 AC_ARG_ENABLE(checking,
  41 [  --enable-checking       enable run-time checks],
  42 [case "${enableval}" in
  43   no|none)  ac_checking= ;;
  44   *)        ac_checking=yes ;;
  45 esac])dnl
  46 if test x$ac_checking != x ; then
  47   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  48 fi
  49
  50 AC_ARG_ENABLE(targets,
  51 [  --enable-targets        alternative target configurations],
  52 [case "${enableval}" in
  53   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  54             ;;
  55   no)       enable_targets= ;;
  56   *)        enable_targets=$enableval ;;
  57 esac])dnl
  58
  59
  60 AC_ARG_ENABLE(deterministic-archives,
  61 [AS_HELP_STRING([--enable-deterministic-archives],
  62                 [ar and ranlib default to -D behavior])], [
  63 if test "${enableval}" = no; then
  64   default_ar_deterministic=0
  65 else
  66   default_ar_deterministic=1
  67 fi], [default_ar_deterministic=0])
  68
  69 AC_DEFINE_UNQUOTED(DEFAULT_AR_DETERMINISTIC, $default_ar_deterministic,
  70                    [Should ar and ranlib use -D behavior by default?])
  71
  72
  73 AC_ARG_ENABLE(default-strings-all,
  74 [AS_HELP_STRING([--disable-default-strings-all],
  75                 [strings defaults to --data behavior])], [
  76 if test "${enableval}" = no; then
  77   default_strings_all=0
  78 else
  79   default_strings_all=1
  80 fi], [default_strings_all=1])
  81
  82 AC_DEFINE_UNQUOTED(DEFAULT_STRINGS_ALL, $default_strings_all,
  83                    [Should strings use -a behavior by default?])
  84
  85
  86 AC_ARG_ENABLE(f-for-ifunc-symbols,
  87 [AS_HELP_STRING([--enable-f-for-ifunc-symbols],
  88         [Have nm use F and f for global and local ifunc symbols])], [
  89 if test "${enableval}" = no; then
  90   default_f_for_ifunc=0
  91 else
  92   default_f_for_ifunc=1
  93 fi], [default_f_for_ifunc=0])
  94
  95 AC_DEFINE_UNQUOTED(DEFAULT_F_FOR_IFUNC_SYMBOLS, $default_f_for_ifunc,
  96                    [Have nm use F and f for global and local ifunc symbols])
  97
  98
  99 AC_ARG_ENABLE(follow-debug-links,
 100 [AS_HELP_STRING([--enable-follow-debug-links],
 101         [Have readelf and objdump follow debug links by default])], [
 102 if test "${enableval}" = no; then
 103   default_for_follow_links=0
 104 else
 105   default_for_follow_links=1
 106 fi], [default_for_follow_links=1])
 107
 108 AC_DEFINE_UNQUOTED(DEFAULT_FOR_FOLLOW_LINKS, $default_for_follow_links,
 109                    [Have readelf and objdump follow debug links by default])
 110
 111
 112 AC_DEBUGINFOD
 113
 114 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 115 if test "${enable_libctf}" = yes; then
 116     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 117 fi
 118 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 119
 120 AM_BINUTILS_WARNINGS
 121
 122 AC_CONFIG_HEADERS(config.h:config.in)
 123
 124 AH_VERBATIM([00_CONFIG_H_CHECK],
 125 [/* Check that config.h is #included before system headers
 126    (this works only for glibc, but that should be enough).  */
 127 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 128 #  error config.h must be #included before system headers
 129 #endif
 130 #define __CONFIG_H__ 1])
 131
 132 if test -z "$target" ; then
 133     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 134 fi
 135 if test -z "$host" ; then
 136     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 137 fi
 138
 139 AC_PROG_YACC
 140 AM_PROG_LEX
 141
 142 ALL_LINGUAS="bg ca da es fi fr hr id it ja pt ro ru rw sk sr sv tr uk vi zh_CN zh_TW"
 143 ZW_GNU_GETTEXT_SISTER_DIR
 144 AM_PO_SUBDIRS
 145
 146 AM_MAINTAINER_MODE
 147 AM_CONDITIONAL(GENINSRC_NEVER, false)
 148 AC_EXEEXT
 149 if test -n "$EXEEXT"; then
 150   AC_DEFINE(HAVE_EXECUTABLE_SUFFIX, 1,
 151             [Does the platform use an executable suffix?])
 152 fi
 153 AC_DEFINE_UNQUOTED(EXECUTABLE_SUFFIX, "${EXEEXT}",
 154                    [Suffix used for executables, if any.])
 155
 156 # host-specific stuff:
 157
 158 HDEFINES=
 159
 160 . ${srcdir}/../bfd/configure.host
 161
 162 AC_SUBST(HDEFINES)
 163 AR=${AR-ar}
 164 AC_SUBST(AR)
 165 AC_PROG_RANLIB
 166 AC_PROG_INSTALL
 167
 168 BFD_CC_FOR_BUILD
 169
 170 DEMANGLER_NAME=c++filt
 171 case "${host}" in
 172   *-*-go32* | *-*-msdos*)
 173     DEMANGLER_NAME=cxxfilt
 174 esac
 175 AC_SUBST(DEMANGLER_NAME)
 176
 177 # We use headers from include/ that check various HAVE_*_H macros, thus
 178 # should ensure they are set by configure.  This is true even when C99
 179 # guarantees they are available.
 180 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 181 # Besides those, we need to check anything used in binutils/ not in C99.
 182 AC_CHECK_HEADERS(fcntl.h inttypes.h stdint.h sys/file.h \
 183                  sys/stat.h sys/time.h sys/types.h unistd.h)
 184 AC_HEADER_SYS_WAIT
 185 AC_FUNC_MMAP
 186 AC_CHECK_FUNCS(getc_unlocked mkdtemp mkstemp utimensat utimes)
 187
 188 AC_MSG_CHECKING([for mbstate_t])
 189 AC_TRY_COMPILE([#include <wchar.h>],
 190 [mbstate_t teststate;],
 191 have_mbstate_t=yes, have_mbstate_t=no)
 192 AC_MSG_RESULT($have_mbstate_t)
 193 if test x"$have_mbstate_t" = xyes; then
 194   AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
 195 fi
 196
 197 # Copied from gnulib stat-time.m4.
 198 # We should just switch over to using gnulib.
 199 AC_CHECK_MEMBERS([struct stat.st_atim.tv_nsec],
 200   [AC_CACHE_CHECK([whether struct stat.st_atim is of type struct timespec],
 201      [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec],
 202      [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
 203         [[
 204           #include <sys/types.h>
 205           #include <sys/stat.h>
 206           #if HAVE_SYS_TIME_H
 207           # include <sys/time.h>
 208           #endif
 209           #include <time.h>
 210           struct timespec ts;
 211           struct stat st;
 212         ]],
 213         [[
 214           st.st_atim = ts;
 215         ]])],
 216         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=yes],
 217         [ac_cv_typeof_struct_stat_st_atim_is_struct_timespec=no])])
 218    if test $ac_cv_typeof_struct_stat_st_atim_is_struct_timespec = yes; then
 219      AC_DEFINE([TYPEOF_STRUCT_STAT_ST_ATIM_IS_STRUCT_TIMESPEC], [1],
 220        [Define to 1 if the type of the st_atim member of a struct stat is
 221         struct timespec.])
 222    fi],
 223   [AC_CHECK_MEMBERS([struct stat.st_atimespec.tv_nsec], [],
 224      [AC_CHECK_MEMBERS([struct stat.st_atimensec], [],
 225         [AC_CHECK_MEMBERS([struct stat.st_atim.st__tim.tv_nsec], [], [],
 226            [#include <sys/types.h>
 227             #include <sys/stat.h>])],
 228         [#include <sys/types.h>
 229          #include <sys/stat.h>])],
 230      [#include <sys/types.h>
 231       #include <sys/stat.h>])],
 232   [#include <sys/types.h>
 233    #include <sys/stat.h>])
 234
 235 # Some systems have frexp only in -lm, not in -lc.
 236 AC_SEARCH_LIBS(frexp, m)
 237
 238 AM_LC_MESSAGES
 239
 240 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 241 AC_CACHE_VAL(bu_cv_decl_getopt_unistd_h,
 242 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 243 bu_cv_decl_getopt_unistd_h=yes, bu_cv_decl_getopt_unistd_h=no)])
 244 AC_MSG_RESULT($bu_cv_decl_getopt_unistd_h)
 245 if test $bu_cv_decl_getopt_unistd_h = yes; then
 246   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 247             [Is the prototype for getopt in <unistd.h> in the expected format?])
 248 fi
 249
 250 # Under Next 3.2 <utime.h> apparently does not define struct utimbuf
 251 # by default.
 252 AC_MSG_CHECKING([for utime.h])
 253 AC_CACHE_VAL(bu_cv_header_utime_h,
 254 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <sys/types.h>
 255 #ifdef HAVE_TIME_H
 256 #include <time.h>
 257 #endif
 258 #include <utime.h>],
 259 [struct utimbuf s;])],
 260 bu_cv_header_utime_h=yes, bu_cv_header_utime_h=no)])
 261 AC_MSG_RESULT($bu_cv_header_utime_h)
 262 if test $bu_cv_header_utime_h = yes; then
 263   AC_DEFINE(HAVE_GOOD_UTIME_H, 1, [Does <utime.h> define struct utimbuf?])
 264 fi
 265
 266 AC_CHECK_DECLS([asprintf, environ, getc_unlocked, stpcpy, strnlen])
 267
 268 # Link in zlib if we can.  This allows us to read compressed debug
 269 # sections.  This is used only by readelf.c (objdump uses bfd for
 270 # reading compressed sections).
 271 AM_ZLIB
 272
 273 BFD_BINARY_FOPEN
 274
 275 # Support for the msgpack C library.
 276 AC_ARG_WITH([msgpack],
 277             AC_HELP_STRING([--with-msgpack], [Enable msgpack support (auto/yes/no)]),
 278             [],
 279             [with_msgpack=auto])
 280
 281 AS_IF([test "$with_msgpack" != no],
 282   [PKG_CHECK_MODULES(MSGPACK, msgpack,
 283     [AC_DEFINE([HAVE_MSGPACK], [1], [Define to 1 if msgpack is available.])],
 284     [AS_IF([test "$with_msgpack" = yes],
 285       [AC_MSG_ERROR([--with-msgpack was given, but msgpack is missing or unusable.])])])])
 286
 287 # target-specific stuff:
 288
 289 # Canonicalize the secondary target names.
 290 if test -n "$enable_targets"; then
 291     for targ in `echo $enable_targets | sed 's/,/ /g'`
 292     do
 293         result=`$ac_config_sub $targ 2>/dev/null`
 294         if test -n "$result"; then
 295             canon_targets="$canon_targets $result"
 296         else
 297             # Allow targets that config.sub doesn't recognize, like "all".
 298             canon_targets="$canon_targets $targ"
 299         fi
 300     done
 301 fi
 302
 303 AC_CHECK_HEADER(iconv.h)
 304 AM_ICONV
 305
 306 all_targets=false
 307 BUILD_SRCONV=
 308 BUILD_DLLTOOL=
 309 DLLTOOL_DEFS=
 310 DLLTOOL_DEFAULT=
 311 BUILD_WINDRES=
 312 BUILD_WINDMC=
 313 BUILD_DLLWRAP=
 314 BUILD_MISC=
 315 BUILD_INSTALL_MISC=
 316 OBJDUMP_DEFS=
 317 OBJDUMP_PRIVATE_VECTORS=
 318 OBJDUMP_PRIVATE_OFILES=
 319 od_vectors=
 320
 321 for targ in $target $canon_targets
 322 do
 323     if test "x$targ" = "xall"; then
 324         all_targets=true
 325         BUILD_SRCONV='$(SRCONV_PROG)'
 326         BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 327         BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 328         BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 329         BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 330         if test -z "$DLLTOOL_DEFAULT"; then
 331           DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 332         fi
 333         DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 334         BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 335         od_vectors="$od_vectors objdump_private_desc_xcoff"
 336     else
 337         case $targ in
 338         *-*-hms*) BUILD_SRCONV='$(SRCONV_PROG)' ;;
 339         esac
 340
 341         case $targ in
 342         arm-wince-pe* | arm-*-wince | arm*-*-cegcc* | arm*-*-mingw32ce*)
 343           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 344           if test -z "$DLLTOOL_DEFAULT"; then
 345             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM_WINCE"
 346           fi
 347           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM_WINCE -DDLLTOOL_ARM"
 348           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 349           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 350           ;;
 351         arm-*-pe*)
 352           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 353           if test -z "$DLLTOOL_DEFAULT"; then
 354             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_ARM"
 355           fi
 356           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_ARM"
 357           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 358           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 359           ;;
 360         x86_64-*-mingw* | x86_64-*-cygwin*)
 361           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 362           if test -z "$DLLTOOL_DEFAULT"; then
 363             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MX86_64"
 364           fi
 365           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MX86_64"
 366           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 367           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 368           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 369           ;;
 370 changequote(,)dnl
 371         i[3-7]86-*-pe* | i[3-7]86-*-cygwin* | i[3-7]86-*-mingw32**)
 372 changequote([,])dnl
 373           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 374           if test -z "$DLLTOOL_DEFAULT"; then
 375             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 376           fi
 377           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 378           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 379           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 380           BUILD_DLLWRAP='$(DLLWRAP_PROG)$(EXEEXT)'
 381           ;;
 382 changequote(,)dnl
 383         i[3-7]86-*-interix)
 384 changequote([,])dnl
 385           BUILD_DLLTOOL='$(DLLTOOL_PROG)'
 386           if test -z "$DLLTOOL_DEFAULT"; then
 387             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_I386"
 388           fi
 389           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_I386"
 390           ;;
 391 changequote(,)dnl
 392         powerpc*-aix5.[01])
 393 changequote([,])dnl
 394           ;;
 395 changequote(,)dnl
 396         powerpc*-aix[5-9].*)
 397 changequote([,])dnl
 398           OBJDUMP_DEFS="-DAIX_WEAK_SUPPORT"
 399           ;;
 400         powerpc*-*-linux* | powerpc*-*-elf* | powerpc*-*-eabi*)
 401           case "$BUILD_INSTALL_MISC" in
 402             *embedspu*) ;;
 403             *) BUILD_INSTALL_MISC="${BUILD_INSTALL_MISC} embedspu"
 404           esac
 405           ;;
 406         sh*-*-pe)
 407           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 408           if test -z "$DLLTOOL_DEFAULT"; then
 409             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_SH"
 410           fi
 411           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_SH"
 412           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 413           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 414           ;;
 415         spu-*-*)
 416           BUILD_MISC="${BUILD_MISC} "'bin2c$(EXEEXT_FOR_BUILD)'
 417           ;;
 418         mips*-*-pe)
 419           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 420           if test -z "$DLLTOOL_DEFAULT"; then
 421             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MIPS"
 422           fi
 423           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MIPS"
 424           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 425           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 426           ;;
 427         mcore-*-pe)
 428           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 429           if test -z "$DLLTOOL_DEFAULT"; then
 430             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE"
 431           fi
 432           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE"
 433           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 434           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 435           ;;
 436         mcore-*-elf)
 437           BUILD_DLLTOOL='$(DLLTOOL_PROG)$(EXEEXT)'
 438           if test -z "$DLLTOOL_DEFAULT"; then
 439             DLLTOOL_DEFAULT="-DDLLTOOL_DEFAULT_MCORE_ELF"
 440           fi
 441           DLLTOOL_DEFS="$DLLTOOL_DEFS -DDLLTOOL_MCORE_ELF"
 442           ;;
 443         mep-*)
 444           OBJDUMP_DEFS="-DSKIP_ZEROES=256 -DSKIP_ZEROES_AT_END=0"
 445           ;;
 446         esac
 447
 448         # Add objdump private vectors.
 449         case $targ in
 450         avr-*-*)
 451           od_vectors="$od_vectors objdump_private_desc_elf32_avr"
 452           ;;
 453         powerpc*-*-aix* | rs6000-*-aix*)
 454           od_vectors="$od_vectors objdump_private_desc_xcoff"
 455           ;;
 456         *-*-darwin*)
 457           od_vectors="$od_vectors objdump_private_desc_mach_o"
 458           ;;
 459         esac
 460     fi
 461 done
 462
 463 # Uniq objdump private vector, build objdump target ofiles.
 464 od_files=
 465 f=""
 466 for i in $od_vectors ; do
 467     case " $f " in
 468     *" $i "*) ;;
 469     *)
 470         f="$f $i"
 471         OBJDUMP_PRIVATE_VECTORS="$OBJDUMP_PRIVATE_VECTORS &$i,"
 472         case $i in
 473         objdump_private_desc_elf32_avr)
 474             od_files="$od_files od-elf32_avr" ;;
 475         objdump_private_desc_xcoff)
 476             od_files="$od_files od-xcoff" ;;
 477         objdump_private_desc_mach_o)
 478             od_files="$od_files od-macho" ;;
 479         *) AC_MSG_ERROR(*** unknown private vector $i) ;;
 480         esac
 481         ;;
 482     esac
 483 done
 484
 485 # Uniq objdump target ofiles
 486 f=""
 487 for i in $od_files ; do
 488     case " $f " in
 489     *" $i "*) ;;
 490     *)
 491         f="$f $i"
 492         OBJDUMP_PRIVATE_OFILES="$OBJDUMP_PRIVATE_OFILES $i.$objext"
 493         ;;
 494     esac
 495 done
 496
 497 DLLTOOL_DEFS="$DLLTOOL_DEFS $DLLTOOL_DEFAULT"
 498
 499 if test "${with_windres+set}" = set; then
 500           BUILD_WINDRES='$(WINDRES_PROG)$(EXEEXT)'
 501 fi
 502
 503 if test "${with_windmc+set}" = set; then
 504           BUILD_WINDMC='$(WINDMC_PROG)$(EXEEXT)'
 505 fi
 506
 507 OBJDUMP_DEFS="${OBJDUMP_DEFS} -DOBJDUMP_PRIVATE_VECTORS=\"${OBJDUMP_PRIVATE_VECTORS}\""
 508
 509 AC_SUBST(BUILD_SRCONV)
 510 AC_SUBST(BUILD_DLLTOOL)
 511 AC_SUBST(DLLTOOL_DEFS)
 512 AC_SUBST(BUILD_WINDRES)
 513 AC_SUBST(BUILD_WINDMC)
 514 AC_SUBST(BUILD_DLLWRAP)
 515 AC_SUBST(BUILD_MISC)
 516 AC_SUBST(BUILD_INSTALL_MISC)
 517 AC_SUBST(OBJDUMP_DEFS)
 518 AC_SUBST(OBJDUMP_PRIVATE_OFILES)
 519
 520 AC_DEFINE_UNQUOTED(TARGET, "${target}", [Configured target name.])
 521
 522 targ=$target
 523 . $srcdir/../bfd/config.bfd
 524 if test "x$targ_underscore" = "xyes"; then
 525     UNDERSCORE=1
 526 else
 527     UNDERSCORE=0
 528 fi
 529 AC_DEFINE_UNQUOTED(TARGET_PREPENDS_UNDERSCORE, $UNDERSCORE,
 530  [Define to 1 if user symbol names have a leading underscore, 0 if not.])
 531
 532 # Emulation
 533 targ=$target
 534 . ${srcdir}/configure.tgt
 535 EMULATION=$targ_emul
 536 EMULATION_VECTOR=$targ_emul_vector
 537
 538 AC_SUBST(EMULATION)
 539 AC_SUBST(EMULATION_VECTOR)
 540
 541 # Required for html and install-html
 542 AC_SUBST(datarootdir)
 543 AC_SUBST(docdir)
 544 AC_SUBST(htmldir)
 545 AC_SUBST(pdfdir)
 546
 547 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 548 AC_OUTPUT
 549
 550 GNU_MAKE_JOBSERVER