board/gen860t/u-boot-flashenv.lds

   1 /*
   2  * Linker command file for the GEN860T board when the environment is
   3  * stored in flash memory.
   4  *
   5  * (C) Copyright 2000
   6  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   7  *
   8  * See file CREDITS for list of people who contributed to this
   9  * project.
  10  *
  11  * This program is free software; you can redistribute it and/or
  12  * modify it under the terms of the GNU General Public License as
  13  * published by the Free Software Foundation; either version 2 of
  14  * the License, or (at your option) any later version.
  15  *
  16  * This program is distributed in the hope that it will be useful,
  17  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  18  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19  * GNU General Public License for more details.
  20  *
  21  * You should have received a copy of the GNU General Public License
  22  * along with this program; if not, write to the Free Software
  23  * Foundation, Inc., 59 Temple Place, Suite 330, Boston,
  24  * MA 02111-1307 USA
  25  */
  26
  27 OUTPUT_ARCH(powerpc)
  28 SECTIONS
  29 {
  30   /*
  31    * Read-only sections, merged into text segment:
  32    */
  33   . = + SIZEOF_HEADERS;
  34   .interp        : { *(.interp)         }
  35   .hash          : { *(.hash)           }
  36   .dynsym        : { *(.dynsym)         }
  37   .dynstr        : { *(.dynstr)         }
  38   .rel.text      : { *(.rel.text)       }
  39   .rela.text     : { *(.rela.text)      }
  40   .rel.data      : { *(.rel.data)       }
  41   .rela.data     : { *(.rela.data)      }
  42   .rel.rodata    : { *(.rel.rodata)     }
  43   .rela.rodata   : { *(.rela.rodata)    }
  44   .rel.got       : { *(.rel.got)        }
  45   .rela.got      : { *(.rela.got)       }
  46   .rel.ctors     : { *(.rel.ctors)      }
  47   .rela.ctors    : { *(.rela.ctors)     }
  48   .rel.dtors     : { *(.rel.dtors)      }
  49   .rela.dtors    : { *(.rela.dtors)     }
  50   .rel.bss       : { *(.rel.bss)        }
  51   .rela.bss      : { *(.rela.bss)       }
  52   .rel.plt       : { *(.rel.plt)        }
  53   .rela.plt      : { *(.rela.plt)       }
  54   .init          : { *(.init)           }
  55   .plt           : { *(.plt)            }
  56   .text :
  57   {
  58     arch/ppc/cpu/mpc8xx/start.o (.text)
  59     *(.text)
  60     *(.got1)
  61   }
  62   _etext = .;
  63   PROVIDE (etext = .);
  64   .rodata    :
  65   {
  66     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  67   }
  68   .fini      : { *(.fini)    } =0
  69   .ctors     : { *(.ctors)   }
  70   .dtors     : { *(.dtors)   }
  71
  72   /*
  73    * Read-write section, merged into data segment:
  74    */
  75   . = (. + 0x00FF) & 0xFFFFFF00;
  76   _erotext = .;
  77   PROVIDE (erotext = .);
  78   .reloc   :
  79   {
  80     *(.got)
  81     _GOT2_TABLE_ = .;
  82     *(.got2)
  83     _FIXUP_TABLE_ = .;
  84     *(.fixup)
  85   }
  86   __got2_entries = (_FIXUP_TABLE_ - _GOT2_TABLE_) >>2;
  87   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  88
  89   .data:
  90   {
  91     *(.data)
  92     *(.data1)
  93     *(.sdata)
  94     *(.sdata2)
  95     *(.dynamic)
  96     CONSTRUCTORS
  97   }
  98   _edata  =  .;
  99   PROVIDE (edata = .);
 100
 101   . = .;
 102   __u_boot_cmd_start = .;
 103   .u_boot_cmd : { *(.u_boot_cmd) }
 104   __u_boot_cmd_end = .;
 105
 106   . = .;
 107   __start___ex_table = .;
 108   __ex_table : { *(__ex_table) }
 109   __stop___ex_table = .;
 110
 111   . = ALIGN(256);
 112   __init_begin = .;
 113   .text.init : { *(.text.init) }
 114   .data.init : { *(.data.init) }
 115   . = ALIGN(256);
 116   __init_end = .;
 117
 118   __bss_start = .;
 119   .bss (NOLOAD)       :
 120   {
 121    *(.sbss) *(.scommon)
 122    *(.dynbss)
 123    *(.bss)
 124    *(COMMON)
 125    . = ALIGN(4);
 126   }
 127
 128   _end = . ;
 129   PROVIDE (end = .);
 130
 131   .ppcenv:
 132   {
 133     . = env_offset;
 134     common/env_embedded.o
 135   }
 136 }