board/hymod/u-boot.lds

   1 /*
   2  * (C) Copyright 2000
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * SPDX-License-Identifier:     GPL-2.0+
   6  */
   7
   8 OUTPUT_ARCH(powerpc)
   9 /* Do we need any of these for elf?
  10    __DYNAMIC = 0;    */
  11 SECTIONS
  12 {
  13   /* Read-only sections, merged into text segment: */
  14   . = + SIZEOF_HEADERS;
  15   .interp : { *(.interp) }
  16   .hash          : { *(.hash)           }
  17   .dynsym        : { *(.dynsym)         }
  18   .dynstr        : { *(.dynstr)         }
  19   .rel.text      : { *(.rel.text)               }
  20   .rela.text     : { *(.rela.text)      }
  21   .rel.data      : { *(.rel.data)               }
  22   .rela.data     : { *(.rela.data)      }
  23   .rel.rodata    : { *(.rel.rodata)     }
  24   .rela.rodata   : { *(.rela.rodata)    }
  25   .rel.got       : { *(.rel.got)                }
  26   .rela.got      : { *(.rela.got)               }
  27   .rel.ctors     : { *(.rel.ctors)      }
  28   .rela.ctors    : { *(.rela.ctors)     }
  29   .rel.dtors     : { *(.rel.dtors)      }
  30   .rela.dtors    : { *(.rela.dtors)     }
  31   .rel.bss       : { *(.rel.bss)                }
  32   .rela.bss      : { *(.rela.bss)               }
  33   .rel.plt       : { *(.rel.plt)                }
  34   .rela.plt      : { *(.rela.plt)               }
  35   .init          : { *(.init)   }
  36   .plt : { *(.plt) }
  37   .text      :
  38   {
  39     /* WARNING - the following is hand-optimized to fit within  */
  40     /* the sector layout of our flash chips!    XXX FIXME XXX   */
  41
  42     arch/powerpc/cpu/mpc8260/start.o    (.text)
  43 /*
  44     common/dlmalloc.o   (.text)
  45     arch/powerpc/lib/ppcstring.o        (.text)
  46     lib/vsprintf.o      (.text)
  47     lib/crc32.o         (.text)
  48     lib/zlib.o          (.text)
  49
  50     . = env_offset;
  51 */
  52     common/env_embedded.o(.text)
  53
  54     *(.text)
  55     *(.got1)
  56   }
  57   _etext = .;
  58   PROVIDE (etext = .);
  59   .rodata    :
  60   {
  61     *(.eh_frame)
  62     *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  63   }
  64   .fini      : { *(.fini)    } =0
  65   .ctors     : { *(.ctors)   }
  66   .dtors     : { *(.dtors)   }
  67
  68   /* Read-write section, merged into data segment: */
  69   . = (. + 0x0FFF) & 0xFFFFF000;
  70   _erotext = .;
  71   PROVIDE (erotext = .);
  72   .reloc   :
  73   {
  74     _GOT2_TABLE_ = .;
  75     KEEP(*(.got2))
  76     KEEP(*(.got))
  77     PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  78     _FIXUP_TABLE_ = .;
  79     *(.fixup)
  80   }
  81   __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  82   __fixup_entries = (. - _FIXUP_TABLE_)>>2;
  83
  84   .data    :
  85   {
  86     *(.data)
  87     *(.data1)
  88     *(.sdata)
  89     *(.sdata2)
  90     *(.dynamic)
  91     CONSTRUCTORS
  92   }
  93   _edata  =  .;
  94   PROVIDE (edata = .);
  95
  96   . = .;
  97
  98   . = ALIGN(4);
  99   .u_boot_list : {
 100         KEEP(*(SORT(.u_boot_list*)));
 101   }
 102
 103
 104   . = .;
 105   __start___ex_table = .;
 106   __ex_table : { *(__ex_table) }
 107   __stop___ex_table = .;
 108
 109   . = ALIGN(4096);
 110   __init_begin = .;
 111   .text.init : { *(.text.init) }
 112   .data.init : { *(.data.init) }
 113   . = ALIGN(4096);
 114   __init_end = .;
 115
 116   __bss_start = .;
 117   .bss (NOLOAD)       :
 118   {
 119    *(.sbss) *(.scommon)
 120    *(.dynbss)
 121    *(.bss)
 122    *(COMMON)
 123   }
 124   . = ALIGN(256 * 1024);
 125   .ppcenv       :
 126   {
 127     common/env_embedded.o (.ppcenv)
 128   }
 129   . = ALIGN(4);
 130   __bss_end = . ;
 131   PROVIDE (end = .);
 132 }