config-scripts/cups-defaults.m4

   1 dnl
   2 dnl "$Id: cups-defaults.m4 7649 2008-06-16 17:46:57Z mike $"
   3 dnl
   4 dnl   Default cupsd configuration settings for the Common UNIX Printing System
   5 dnl   (CUPS).
   6 dnl
   7 dnl   Copyright 2007-2008 by Apple Inc.
   8 dnl   Copyright 2006-2007 by Easy Software Products, all rights reserved.
   9 dnl
  10 dnl   These coded instructions, statements, and computer programs are the
  11 dnl   property of Apple Inc. and are protected by Federal copyright
  12 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  13 dnl   which should have been included with this file.  If this file is
  14 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  15 dnl
  16
  17 dnl Default languages...
  18 LANGUAGES="`ls -1 locale/cups_*.po | sed -e '1,$s/locale\/cups_//' -e '1,$s/\.po//' | tr '\n' ' '`"
  19
  20 AC_ARG_WITH(languages, [  --with-languages        set installed languages, default=all ],[
  21         case "$withval" in
  22                 none | no) LANGUAGES="" ;;
  23                 all) ;;
  24                 *) LANGUAGES="$withval" ;;
  25         esac])
  26 AC_SUBST(LANGUAGES)
  27
  28 dnl Default ConfigFilePerm
  29 AC_ARG_WITH(config_file_perm, [  --with-config-file-perm set default ConfigFilePerm value, default=0640],
  30         CUPS_CONFIG_FILE_PERM="$withval",
  31         if test "x$uname" = xDarwin; then
  32                 CUPS_CONFIG_FILE_PERM="644"
  33         else
  34                 CUPS_CONFIG_FILE_PERM="640"
  35         fi)
  36 AC_SUBST(CUPS_CONFIG_FILE_PERM)
  37 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_CONFIG_FILE_PERM, 0$CUPS_CONFIG_FILE_PERM)
  38
  39 dnl Default LogFilePerm
  40 AC_ARG_WITH(log_file_perm, [  --with-log-file-perm    set default LogFilePerm value, default=0644],
  41         CUPS_LOG_FILE_PERM="$withval",
  42         CUPS_LOG_FILE_PERM="644")
  43 AC_SUBST(CUPS_LOG_FILE_PERM)
  44 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_FILE_PERM, 0$CUPS_LOG_FILE_PERM)
  45
  46 dnl Default LogLevel
  47 AC_ARG_WITH(log_level, [  --with-log-level        set default LogLevel value, default=warn],
  48         CUPS_LOG_LEVEL="$withval",
  49         CUPS_LOG_LEVEL="warn")
  50 AC_SUBST(CUPS_LOG_LEVEL)
  51 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LOG_LEVEL, "$CUPS_LOG_LEVEL")
  52
  53 dnl Default AccessLogLevel
  54 AC_ARG_WITH(log_level, [  --with-access-log-level set default AccessLogLevel value, default=actions],
  55         CUPS_LOG_LEVEL="$withval",
  56         CUPS_LOG_LEVEL="actions")
  57 AC_SUBST(CUPS_ACCESS_LOG_LEVEL)
  58 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_ACCESS_LOG_LEVEL, "$CUPS_ACCESS_LOG_LEVEL")
  59
  60 dnl Default Browsing
  61 AC_ARG_ENABLE(browsing, [  --enable-browsing       enable Browsing by default, default=yes])
  62 if test "x$enable_browsing" = xno; then
  63         CUPS_BROWSING="No"
  64         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 0)
  65 else
  66         CUPS_BROWSING="Yes"
  67         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSING, 1)
  68 fi
  69 AC_SUBST(CUPS_BROWSING)
  70
  71 dnl Default BrowseLocalProtocols
  72 AC_ARG_WITH(local_protocols, [  --with-local-protocols  set default BrowseLocalProtocols, default="CUPS"],
  73         default_local_protocols="$withval",
  74         default_local_protocols="default")
  75
  76 if test x$with_local_protocols != xno; then
  77         if test "x$default_local_protocols" = "xdefault"; then
  78                 if test "x$DNSSDLIBS" != "x"; then
  79                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS dnssd"
  80         else
  81                 CUPS_BROWSE_LOCAL_PROTOCOLS="CUPS"
  82                 fi
  83         else
  84                 CUPS_BROWSE_LOCAL_PROTOCOLS="$default_local_protocols"
  85         fi
  86 else
  87         CUPS_BROWSE_LOCAL_PROTOCOLS=""
  88 fi
  89
  90 AC_SUBST(CUPS_BROWSE_LOCAL_PROTOCOLS)
  91 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_LOCAL_PROTOCOLS,
  92         "$CUPS_BROWSE_LOCAL_PROTOCOLS")
  93
  94 dnl Default BrowseRemoteProtocols
  95 AC_ARG_WITH(remote_protocols, [  --with-remote-protocols set default BrowseRemoteProtocols, default="CUPS"],
  96         default_remote_protocols="$withval",
  97         default_remote_protocols="default")
  98
  99 if test x$with_remote_protocols != xno; then
 100         if test "x$default_remote_protocols" = "xdefault"; then
 101                 if test "$uname" = "Darwin" -a $uversion -ge 90; then
 102                         CUPS_BROWSE_REMOTE_PROTOCOLS=""
 103                 else
 104                         CUPS_BROWSE_REMOTE_PROTOCOLS="CUPS"
 105                 fi
 106         else
 107                 CUPS_BROWSE_REMOTE_PROTOCOLS="$default_remote_protocols"
 108         fi
 109 else
 110         CUPS_BROWSE_REMOTE_PROTOCOLS=""
 111 fi
 112
 113 AC_SUBST(CUPS_BROWSE_REMOTE_PROTOCOLS)
 114 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_REMOTE_PROTOCOLS,
 115         "$CUPS_BROWSE_REMOTE_PROTOCOLS")
 116
 117 dnl Default BrowseShortNames
 118 AC_ARG_ENABLE(browse_short, [  --enable-browse-short-names
 119                           enable BrowseShortNames by default, default=yes])
 120 if test "x$enable_browse_short" = xno; then
 121         CUPS_BROWSE_SHORT_NAMES="No"
 122         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 0)
 123 else
 124         CUPS_BROWSE_SHORT_NAMES="Yes"
 125         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_BROWSE_SHORT_NAMES, 1)
 126 fi
 127 AC_SUBST(CUPS_BROWSE_SHORT_NAMES)
 128
 129 dnl Default DefaultShared
 130 AC_ARG_ENABLE(default_shared, [  --enable-default-shared enable DefaultShared by default, default=yes])
 131 if test "x$enable_default_shared" = xno; then
 132         CUPS_DEFAULT_SHARED="No"
 133         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 0)
 134 else
 135         CUPS_DEFAULT_SHARED="Yes"
 136         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_DEFAULT_SHARED, 1)
 137 fi
 138 AC_SUBST(CUPS_DEFAULT_SHARED)
 139
 140 dnl Default ImplicitClasses
 141 AC_ARG_ENABLE(implicit, [  --enable-implicit-classes
 142                           enable ImplicitClasses by default, default=yes])
 143 if test "x$enable_implicit" = xno; then
 144         CUPS_IMPLICIT_CLASSES="No"
 145         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 0)
 146 else
 147         CUPS_IMPLICIT_CLASSES="Yes"
 148         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IMPLICIT_CLASSES, 1)
 149 fi
 150 AC_SUBST(CUPS_IMPLICIT_CLASSES)
 151
 152 dnl Default UseNetworkDefault
 153 AC_ARG_ENABLE(use_network_default, [  --enable-use-network-default
 154                           enable UseNetworkDefault by default, default=auto])
 155 if test "x$enable_use_network_default" != xno; then
 156         AC_MSG_CHECKING(whether to use network default printers)
 157         if test "x$enable_use_network_default" = xyes -o $uname != Darwin; then
 158                 CUPS_USE_NETWORK_DEFAULT="Yes"
 159                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 1)
 160                 AC_MSG_RESULT(yes)
 161         else
 162                 CUPS_USE_NETWORK_DEFAULT="No"
 163                 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 164                 AC_MSG_RESULT(no)
 165         fi
 166 else
 167         CUPS_USE_NETWORK_DEFAULT="No"
 168         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USE_NETWORK_DEFAULT, 0)
 169 fi
 170 AC_SUBST(CUPS_USE_NETWORK_DEFAULT)
 171
 172 dnl Determine the correct username and group for this OS...
 173 AC_ARG_WITH(cups_user, [  --with-cups-user        set default user for CUPS],
 174         CUPS_USER="$withval",
 175         AC_MSG_CHECKING(for default print user)
 176         if test x$uname = xDarwin; then
 177                 if test x`id -u _lp 2>/dev/null` = x; then
 178                         CUPS_USER="lp";
 179                 else
 180                         CUPS_USER="_lp";
 181                 fi
 182                 AC_MSG_RESULT($CUPS_USER)
 183         elif test -f /etc/passwd; then
 184                 CUPS_USER=""
 185                 for user in lp lpd guest daemon nobody; do
 186                         if test "`grep \^${user}: /etc/passwd`" != ""; then
 187                                 CUPS_USER="$user"
 188                                 AC_MSG_RESULT($user)
 189                                 break;
 190                         fi
 191                 done
 192
 193                 if test x$CUPS_USER = x; then
 194                         CUPS_USER="nobody"
 195                         AC_MSG_RESULT(not found, using "$CUPS_USER")
 196                 fi
 197         else
 198                 CUPS_USER="nobody"
 199                 AC_MSG_RESULT(no password file, using "$CUPS_USER")
 200         fi)
 201
 202 AC_ARG_WITH(cups_group, [  --with-cups-group       set default group for CUPS],
 203         CUPS_GROUP="$withval",
 204         AC_MSG_CHECKING(for default print group)
 205         if test x$uname = xDarwin; then
 206                 if test x`id -g _lp 2>/dev/null` = x; then
 207                         CUPS_GROUP="lp";
 208                 else
 209                         CUPS_GROUP="_lp";
 210                 fi
 211                 AC_MSG_RESULT($CUPS_GROUP)
 212         elif test -f /etc/group; then
 213                 GROUP_LIST="_lp lp nobody"
 214                 CUPS_GROUP=""
 215                 for group in $GROUP_LIST; do
 216                         if test "`grep \^${group}: /etc/group`" != ""; then
 217                                 CUPS_GROUP="$group"
 218                                 AC_MSG_RESULT($group)
 219                                 break;
 220                         fi
 221                 done
 222
 223                 if test x$CUPS_GROUP = x; then
 224                         CUPS_GROUP="nobody"
 225                         AC_MSG_RESULT(not found, using "$CUPS_GROUP")
 226                 fi
 227         else
 228                 CUPS_GROUP="nobody"
 229                 AC_MSG_RESULT(no group file, using "$CUPS_GROUP")
 230         fi)
 231
 232 AC_ARG_WITH(system_groups, [  --with-system-groups    set default system groups for CUPS],
 233         CUPS_SYSTEM_GROUPS="$withval",
 234         if test x$uname = xDarwin; then
 235                 CUPS_SYSTEM_GROUPS="admin"
 236         else
 237                 AC_MSG_CHECKING(for default system groups)
 238                 if test -f /etc/group; then
 239                         CUPS_SYSTEM_GROUPS=""
 240                         GROUP_LIST="lpadmin sys system root"
 241                         for group in $GROUP_LIST; do
 242                                 if test "`grep \^${group}: /etc/group`" != ""; then
 243                                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 244                                                 CUPS_SYSTEM_GROUPS="$group"
 245                                         else
 246                                                 CUPS_SYSTEM_GROUPS="$CUPS_SYSTEM_GROUPS $group"
 247                                         fi
 248                                 fi
 249                         done
 250
 251                         if test "x$CUPS_SYSTEM_GROUPS" = x; then
 252                                 CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 253                                 AC_MSG_RESULT(no groups found, using "$CUPS_SYSTEM_GROUPS")
 254                         else
 255                                 AC_MSG_RESULT("$CUPS_SYSTEM_GROUPS")
 256                         fi
 257                 else
 258                         CUPS_SYSTEM_GROUPS="$GROUP_LIST"
 259                         AC_MSG_RESULT(no group file, using "$CUPS_SYSTEM_GROUPS")
 260                 fi
 261         fi)
 262
 263
 264 CUPS_PRIMARY_SYSTEM_GROUP="`echo $CUPS_SYSTEM_GROUPS | awk '{print $1}'`"
 265
 266 AC_SUBST(CUPS_USER)
 267 AC_SUBST(CUPS_GROUP)
 268 AC_SUBST(CUPS_SYSTEM_GROUPS)
 269 AC_SUBST(CUPS_PRIMARY_SYSTEM_GROUP)
 270
 271 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_USER, "$CUPS_USER")
 272 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_GROUP, "$CUPS_GROUP")
 273 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SYSTEM_GROUPS, "$CUPS_SYSTEM_GROUPS")
 274
 275 dnl Default printcap file...
 276 AC_ARG_WITH(printcap, [  --with-printcap         set default printcap file],
 277         default_printcap="$withval",
 278         default_printcap="default")
 279
 280 if test x$default_printcap != xno; then
 281         if test "x$default_printcap" = "xdefault"; then
 282                 case $uname in
 283                         Darwin*)
 284                                 if test $uversion -ge 90; then
 285                                         CUPS_DEFAULT_PRINTCAP=""
 286                                 else
 287                                         CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 288                                 fi
 289                                 ;;
 290                         SunOS*)
 291                                 CUPS_DEFAULT_PRINTCAP="/etc/printers.conf"
 292                                 ;;
 293                         *)
 294                                 CUPS_DEFAULT_PRINTCAP="/etc/printcap"
 295                                 ;;
 296                 esac
 297         else
 298                 CUPS_DEFAULT_PRINTCAP="$default_printcap"
 299         fi
 300 else
 301         CUPS_DEFAULT_PRINTCAP=""
 302 fi
 303
 304 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_PRINTCAP, "$CUPS_DEFAULT_PRINTCAP")
 305
 306 dnl Default LPD config file...
 307 AC_ARG_WITH(lpdconfigfile, [  --with-lpdconfigfile    set default LPDConfigFile URI],
 308         default_lpdconfigfile="$withval",
 309         default_lpdconfigfile="default")
 310
 311 if test x$default_lpdconfigfile != xno; then
 312         if test "x$default_lpdconfigfile" = "xdefault"; then
 313                 case $uname in
 314                         Darwin*)
 315                                 CUPS_DEFAULT_LPD_CONFIG_FILE="launchd:///System/Library/LaunchDaemons/org.cups.cups-lpd.plist"
 316                                 ;;
 317                         *)
 318                                 if test -d /etc/xinetd.d; then
 319                                         CUPS_DEFAULT_LPD_CONFIG_FILE="xinetd:///etc/xinetd.d/cups-lpd"
 320                                 else
 321                                         CUPS_DEFAULT_LPD_CONFIG_FILE=""
 322                                 fi
 323                                 ;;
 324                 esac
 325         else
 326                 CUPS_DEFAULT_LPD_CONFIG_FILE="$default_lpdconfigfile"
 327         fi
 328 else
 329         CUPS_DEFAULT_LPD_CONFIG_FILE=""
 330 fi
 331
 332 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG_FILE, "$CUPS_DEFAULT_LPD_CONFIG_FILE")
 333
 334 dnl Default SMB config file...
 335 AC_ARG_WITH(smbconfigfile, [  --with-smbconfigfile    set default SMBConfigFile URI],
 336         default_smbconfigfile="$withval",
 337         default_smbconfigfile="default")
 338
 339 if test x$default_smbconfigfile != xno; then
 340         if test "x$default_smbconfigfile" = "xdefault"; then
 341                 if test -f /etc/smb.conf; then
 342                         CUPS_DEFAULT_SMB_CONFIG_FILE="samba:///etc/smb.conf"
 343                 else
 344                         CUPS_DEFAULT_SMB_CONFIG_FILE=""
 345                 fi
 346         else
 347                 CUPS_DEFAULT_SMB_CONFIG_FILE="$default_smbconfigfile"
 348         fi
 349 else
 350         CUPS_DEFAULT_SMB_CONFIG_FILE=""
 351 fi
 352
 353 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG_FILE, "$CUPS_DEFAULT_SMB_CONFIG_FILE")
 354
 355 dnl Default MaxCopies value...
 356 AC_ARG_WITH(max-copies, [  --with-max-copies       set default max copies value, default=auto ],
 357         CUPS_MAX_COPIES="$withval",
 358         if test "x$uname" = xDarwin; then
 359                 CUPS_MAX_COPIES="9999"
 360         else
 361                 CUPS_MAX_COPIES="100"
 362         fi)
 363
 364 AC_SUBST(CUPS_MAX_COPIES)
 365 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_MAX_COPIES, $CUPS_MAX_COPIES)
 366
 367 dnl Default raw printing state
 368 AC_ARG_ENABLE(raw_printing, [  --enable-raw-printing   enable raw printing by default, default=auto])
 369 if test "x$enable_raw_printing" != xno; then
 370         AC_MSG_CHECKING(whether to enable raw printing)
 371         if test "x$enable_raw_printing" = xyes -o $uname = Darwin; then
 372                 DEFAULT_RAW_PRINTING=""
 373                 AC_MSG_RESULT(yes)
 374         else
 375                 DEFAULT_RAW_PRINTING="#"
 376                 AC_MSG_RESULT(no)
 377         fi
 378 else
 379         DEFAULT_RAW_PRINTING="#"
 380 fi
 381 AC_SUBST(DEFAULT_RAW_PRINTING)
 382
 383 dnl Default SNMP options...
 384 AC_ARG_WITH(snmp-address, [  --with-snmp-address     set SNMP query address, default=auto ],
 385         if test "x$withval" = x; then
 386                 CUPS_SNMP_ADDRESS=""
 387         else
 388                 CUPS_SNMP_ADDRESS="Address $withval"
 389         fi,
 390         if test "x$uname" = xDarwin; then
 391                 CUPS_SNMP_ADDRESS=""
 392         else
 393                 CUPS_SNMP_ADDRESS="Address @LOCAL"
 394         fi)
 395
 396 AC_ARG_WITH(snmp-community, [  --with-snmp-community   set SNMP community, default=public ],
 397         CUPS_SNMP_COMMUNITY="Community $withval",
 398         CUPS_SNMP_COMMUNITY="Community public")
 399
 400 AC_SUBST(CUPS_SNMP_ADDRESS)
 401 AC_SUBST(CUPS_SNMP_COMMUNITY)
 402
 403 dnl New default port definition for IPP...
 404 AC_ARG_WITH(ipp-port, [  --with-ipp-port         set default port number for IPP ],
 405         DEFAULT_IPP_PORT="$withval",
 406         DEFAULT_IPP_PORT="631")
 407
 408 AC_SUBST(DEFAULT_IPP_PORT)
 409 AC_DEFINE_UNQUOTED(CUPS_DEFAULT_IPP_PORT,$DEFAULT_IPP_PORT)
 410
 411 dnl
 412 dnl End of "$Id: cups-defaults.m4 7649 2008-06-16 17:46:57Z mike $".
 413 dnl