config-scripts/cups-directories.m4

   1 dnl
   2 dnl "$Id: cups-directories.m4 7799 2008-07-25 20:06:08Z mike $"
   3 dnl
   4 dnl   Directory stuff for the Common UNIX Printing System (CUPS).
   5 dnl
   6 dnl   Copyright 2007 by Apple Inc.
   7 dnl   Copyright 1997-2007 by Easy Software Products, all rights reserved.
   8 dnl
   9 dnl   These coded instructions, statements, and computer programs are the
  10 dnl   property of Apple Inc. and are protected by Federal copyright
  11 dnl   law.  Distribution and use rights are outlined in the file "LICENSE.txt"
  12 dnl   which should have been included with this file.  If this file is
  13 dnl   file is missing or damaged, see the license at "http://www.cups.org/".
  14 dnl
  15
  16 AC_PREFIX_DEFAULT(/)
  17
  18 dnl Fix "prefix" variable if it hasn't been specified...
  19 if test "$prefix" = "NONE"; then
  20         prefix="/"
  21 fi
  22
  23 dnl Fix "exec_prefix" variable if it hasn't been specified...
  24 if test "$exec_prefix" = "NONE"; then
  25         if test "$prefix" = "/"; then
  26                 exec_prefix="/usr"
  27         else
  28                 exec_prefix="$prefix"
  29         fi
  30 fi
  31
  32 dnl Fix "bindir" variable...
  33 if test "$bindir" = "\${exec_prefix}/bin"; then
  34         bindir="$exec_prefix/bin"
  35 fi
  36
  37 AC_DEFINE_UNQUOTED(CUPS_BINDIR, "$bindir")
  38
  39 dnl Fix "sbindir" variable...
  40 if test "$sbindir" = "\${exec_prefix}/sbin"; then
  41         sbindir="$exec_prefix/sbin"
  42 fi
  43
  44 AC_DEFINE_UNQUOTED(CUPS_SBINDIR, "$sbindir")
  45
  46 dnl Fix "sharedstatedir" variable if it hasn't been specified...
  47 if test "$sharedstatedir" = "\${prefix}/com" -a "$prefix" = "/"; then
  48         sharedstatedir="/usr/com"
  49 fi
  50
  51 dnl Fix "datarootdir" variable if it hasn't been specified...
  52 if test "$datarootdir" = "\${prefix}/share"; then
  53         if test "$prefix" = "/"; then
  54                 datarootdir="/usr/share"
  55         else
  56                 datarootdir="$prefix/share"
  57         fi
  58 fi
  59
  60 dnl Fix "datadir" variable if it hasn't been specified...
  61 if test "$datadir" = "\${prefix}/share"; then
  62         if test "$prefix" = "/"; then
  63                 datadir="/usr/share"
  64         else
  65                 datadir="$prefix/share"
  66         fi
  67 elif test "$datadir" = "\${datarootdir}"; then
  68         datadir="$datarootdir"
  69 fi
  70
  71 dnl Fix "includedir" variable if it hasn't been specified...
  72 if test "$includedir" = "\${prefix}/include" -a "$prefix" = "/"; then
  73         includedir="/usr/include"
  74 fi
  75
  76 dnl Fix "localstatedir" variable if it hasn't been specified...
  77 if test "$localstatedir" = "\${prefix}/var"; then
  78         if test "$prefix" = "/"; then
  79                 if test "$uname" = Darwin; then
  80                         localstatedir="/private/var"
  81                 else
  82                         localstatedir="/var"
  83                 fi
  84         else
  85                 localstatedir="$prefix/var"
  86         fi
  87 fi
  88
  89 dnl Fix "sysconfdir" variable if it hasn't been specified...
  90 if test "$sysconfdir" = "\${prefix}/etc"; then
  91         if test "$prefix" = "/"; then
  92                 if test "$uname" = Darwin; then
  93                         sysconfdir="/private/etc"
  94                 else
  95                         sysconfdir="/etc"
  96                 fi
  97         else
  98                 sysconfdir="$prefix/etc"
  99         fi
 100 fi
 101
 102 dnl Fix "libdir" variable...
 103 if test "$libdir" = "\${exec_prefix}/lib"; then
 104         case "$uname" in
 105                 IRIX*)
 106                         libdir="$exec_prefix/lib32"
 107                         ;;
 108                 Linux*)
 109                         if test -d /usr/lib64; then
 110                                 libdir="$exec_prefix/lib64"
 111                         fi
 112                         ;;
 113                 HP-UX*)
 114                         if test -d /usr/lib/hpux32; then
 115                                 libdir="$exec_prefix/lib/hpux32"
 116                         fi
 117                         ;;
 118         esac
 119 fi
 120
 121 dnl Setup init.d locations...
 122 AC_ARG_WITH(rcdir, [  --with-rcdir            set path for rc scripts],rcdir="$withval",rcdir="")
 123 AC_ARG_WITH(rclevels, [  --with-rclevels         set run levels for rc scripts],rclevels="$withval",rclevels="2 3 5")
 124 AC_ARG_WITH(rcstart, [  --with-rcstart          set start number for rc scripts],rcstart="$withval",rcstart="99")
 125 AC_ARG_WITH(rcstop, [  --with-rcstop           set stop number for rc scripts],rcstop="$withval",rcstop="00")
 126 AC_ARG_WITH(smfmanifestdir, [  --with-smfmanifestdir   set path for Solaris SMF manifest],smfmanifestdir="$withval",smfmanifestdir="")
 127
 128 INITDIR=""
 129 INITDDIR=""
 130 RCLEVELS="$rclevels"
 131 RCSTART="$rcstart"
 132 RCSTOP="$rcstop"
 133 SMFMANIFESTDIR=""
 134
 135 if test x$rcdir = x; then
 136         case "$uname" in
 137                 AIX*)
 138                         INITDIR="/etc/rc.d"
 139                         ;;
 140
 141                 Darwin*)
 142                         # Darwin and MacOS X...
 143                         if test -x /sbin/launchd; then
 144                                 INITDDIR="/System/Library/LaunchDaemons"
 145                         else
 146                                 INITDDIR="/System/Library/StartupItems/PrintingServices"
 147                         fi
 148                         ;;
 149
 150                 FreeBSD* | OpenBSD* | MirBSD* | ekkoBSD*)
 151                         # FreeBSD and OpenBSD
 152                         ;;
 153
 154                 HP-UX*)
 155                         INITDIR="/sbin"
 156                         RCLEVELS="2"
 157                         RCSTART="380"
 158                         RCSTOP="620"
 159                         ;;
 160
 161                 IRIX*)
 162                         # IRIX
 163                         INITDIR="/etc"
 164                         RCSTART="60"
 165                         RCSTOP="25"
 166                         ;;
 167
 168                 Linux | GNU | GNU/k*BSD*)
 169                         # Linux/HURD seems to choose an init.d directory at random...
 170                         if test -d /sbin/init.d; then
 171                                 # SuSE
 172                                 INITDIR="/sbin/init.d"
 173                         else
 174                                 if test -d /etc/init.d; then
 175                                         # Others
 176                                         INITDIR="/etc"
 177                                 else
 178                                         # RedHat
 179                                         INITDIR="/etc/rc.d"
 180                                 fi
 181                         fi
 182                         RCSTART="81"
 183                         RCSTOP="36"
 184                         ;;
 185
 186                 NetBSD*)
 187                         # NetBSD
 188                         INITDDIR="/etc/rc.d"
 189                         ;;
 190
 191                 OSF1*)
 192                         INITDIR="/sbin"
 193                         ;;
 194
 195                 SunOS*)
 196                         # Solaris
 197                         if test "x$smfmanifestdir" != x; then
 198                                 SMFMANIFESTDIR=$smfmanifestdir
 199                         else
 200                                 INITDIR="/etc"
 201                                 RCSTART="81"
 202                         fi
 203                         ;;
 204
 205                 *)
 206                         INITDIR="/etc"
 207                         ;;
 208
 209         esac
 210 elif test "x$rcdir" != xno; then
 211         if test "x$rclevels" = x; then
 212                 INITDDIR="$rcdir"
 213         else
 214                 INITDIR="$rcdir"
 215         fi
 216 fi
 217
 218 AC_SUBST(INITDIR)
 219 AC_SUBST(INITDDIR)
 220 AC_SUBST(RCLEVELS)
 221 AC_SUBST(RCSTART)
 222 AC_SUBST(RCSTOP)
 223 AC_SUBST(SMFMANIFESTDIR)
 224
 225 dnl Xinetd support...
 226 AC_ARG_WITH(xinetd, [  --with-xinetd           set path for xinetd config files],XINETD="$withval",XINETD="")
 227
 228 if test "x$XINETD" = x -a ! -x /sbin/launchd; then
 229         for dir in /private/etc/xinetd.d /etc/xinetd.d /usr/local/etc/xinetd.d; do
 230                 if test -d $dir; then
 231                         XINETD="$dir"
 232                         break
 233                 fi
 234         done
 235 elif test "x$XINETD" = xno; then
 236         XINETD=""
 237 fi
 238
 239 AC_SUBST(XINETD)
 240
 241 dnl LPD sharing support...
 242 AC_ARG_WITH(lpdconfig, [  --with-lpdconfig        set URI for LPD config file],
 243         LPDCONFIG="$withval", LPDCONFIG="")
 244
 245 if test "x$LPDCONFIG" = x; then
 246         if test -f /System/Library/LaunchDaemons/org.cups.cups-lpd.plist; then
 247                 LPDCONFIG="launchd:///System/Library/LaunchDaemons/org.cups.cups-lpd.plist"
 248         elif test "x$XINETD" != x; then
 249                 LPDCONFIG="xinetd://$XINETD/cups-lpd"
 250         fi
 251 fi
 252
 253 if test "x$LPDCONFIG" = xoff; then
 254         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG, "")
 255 else
 256         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_LPD_CONFIG, "$LPDCONFIG")
 257 fi
 258
 259 dnl SMB sharing support...
 260 AC_ARG_WITH(smbconfig, [  --with-smbconfig        set URI for Samba config file],
 261         SMBCONFIG="$withval", SMBCONFIG="")
 262
 263 if test "x$SMBCONFIG" = x; then
 264         if test -f /System/Library/LaunchDaemons/smbd.plist; then
 265                 SMBCONFIG="launchd:///System/Library/LaunchDaemons/smbd.plist"
 266         else
 267                 for dir in /etc /etc/samba /usr/local/etc; do
 268                         if test -f $dir/smb.conf; then
 269                                 SMBCONFIG="samba://$dir/smb.conf"
 270                                 break
 271                         fi
 272                 done
 273         fi
 274 fi
 275
 276 if test "x$SMBCONFIG" = xoff; then
 277         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG, "")
 278 else
 279         AC_DEFINE_UNQUOTED(CUPS_DEFAULT_SMB_CONFIG, "$SMBCONFIG")
 280 fi
 281
 282 dnl Setup default locations...
 283 # Cache data...
 284 AC_ARG_WITH(cachedir, [  --with-cachedir         set path for cache files],cachedir="$withval",cachedir="")
 285
 286 if test x$cachedir = x; then
 287         if test "x$uname" = xDarwin; then
 288                 CUPS_CACHEDIR="$localstatedir/spool/cups/cache"
 289         else
 290                 CUPS_CACHEDIR="$localstatedir/cache/cups"
 291         fi
 292 else
 293         CUPS_CACHEDIR="$cachedir"
 294 fi
 295 AC_DEFINE_UNQUOTED(CUPS_CACHEDIR, "$CUPS_CACHEDIR")
 296 AC_SUBST(CUPS_CACHEDIR)
 297
 298 # Data files
 299 CUPS_DATADIR="$datadir/cups"
 300 AC_DEFINE_UNQUOTED(CUPS_DATADIR, "$datadir/cups")
 301 AC_SUBST(CUPS_DATADIR)
 302
 303 # Icon directory
 304 AC_ARG_WITH(icondir, [  --with-icondir          set path for application icons],icondir="$withval",icondir="")
 305
 306 if test "x$icondir" = x -a -d /usr/share/icons; then
 307         ICONDIR="/usr/share/icons"
 308 else
 309         ICONDIR="$icondir"
 310 fi
 311
 312 AC_SUBST(ICONDIR)
 313
 314 # Menu directory
 315 AC_ARG_WITH(menudir, [  --with-menudir          set path for application menus],menudir="$withval",menudir="")
 316
 317 if test "x$menudir" = x -a -d /usr/share/applications; then
 318         MENUDIR="/usr/share/applications"
 319 else
 320         MENUDIR="$menudir"
 321 fi
 322
 323 AC_SUBST(MENUDIR)
 324
 325 # Documentation files
 326 AC_ARG_WITH(docdir, [  --with-docdir           set path for documentation],docdir="$withval",docdir="")
 327
 328 if test x$docdir = x; then
 329         CUPS_DOCROOT="$datadir/doc/cups"
 330         docdir="$datadir/doc/cups"
 331 else
 332         CUPS_DOCROOT="$docdir"
 333 fi
 334
 335 AC_DEFINE_UNQUOTED(CUPS_DOCROOT, "$docdir")
 336 AC_SUBST(CUPS_DOCROOT)
 337
 338 # Fonts
 339 AC_ARG_WITH(fontpath, [  --with-fontpath         set font path for pstoraster],fontpath="$withval",fontpath="")
 340
 341 if test "x$fontpath" = "x"; then
 342         CUPS_FONTPATH="$datadir/cups/fonts"
 343 else
 344         CUPS_FONTPATH="$fontpath"
 345 fi
 346
 347 AC_SUBST(CUPS_FONTPATH)
 348 AC_DEFINE_UNQUOTED(CUPS_FONTPATH, "$CUPS_FONTPATH")
 349
 350 # Locale data
 351 if test "$localedir" = "\${datarootdir}/locale"; then
 352         case "$uname" in
 353                 Linux | GNU | *BSD* | Darwin*)
 354                         CUPS_LOCALEDIR="$datarootdir/locale"
 355                         ;;
 356
 357                 OSF1* | AIX*)
 358                         CUPS_LOCALEDIR="$exec_prefix/lib/nls/msg"
 359                         ;;
 360
 361                 *)
 362                         # This is the standard System V location...
 363                         CUPS_LOCALEDIR="$exec_prefix/lib/locale"
 364                         ;;
 365         esac
 366 else
 367         CUPS_LOCALEDIR="$localedir"
 368 fi
 369
 370 AC_DEFINE_UNQUOTED(CUPS_LOCALEDIR, "$CUPS_LOCALEDIR")
 371 AC_SUBST(CUPS_LOCALEDIR)
 372
 373 # Log files...
 374 AC_ARG_WITH(logdir, [  --with-logdir           set path for log files],logdir="$withval",logdir="")
 375
 376 if test x$logdir = x; then
 377         CUPS_LOGDIR="$localstatedir/log/cups"
 378         AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$localstatedir/log/cups")
 379 else
 380         CUPS_LOGDIR="$logdir"
 381 fi
 382 AC_DEFINE_UNQUOTED(CUPS_LOGDIR, "$CUPS_LOGDIR")
 383 AC_SUBST(CUPS_LOGDIR)
 384
 385 # Longer-term spool data
 386 CUPS_REQUESTS="$localstatedir/spool/cups"
 387 AC_DEFINE_UNQUOTED(CUPS_REQUESTS, "$localstatedir/spool/cups")
 388 AC_SUBST(CUPS_REQUESTS)
 389
 390 # Server executables...
 391 case "$uname" in
 392         *BSD* | Darwin*)
 393                 # *BSD and Darwin (MacOS X)
 394                 INSTALL_SYSV=""
 395                 CUPS_SERVERBIN="$exec_prefix/libexec/cups"
 396                 ;;
 397         *)
 398                 # All others
 399                 INSTALL_SYSV="install-sysv"
 400                 CUPS_SERVERBIN="$exec_prefix/lib/cups"
 401                 ;;
 402 esac
 403
 404 AC_DEFINE_UNQUOTED(CUPS_SERVERBIN, "$CUPS_SERVERBIN")
 405 AC_SUBST(CUPS_SERVERBIN)
 406 AC_SUBST(INSTALL_SYSV)
 407
 408 # Configuration files
 409 CUPS_SERVERROOT="$sysconfdir/cups"
 410 AC_DEFINE_UNQUOTED(CUPS_SERVERROOT, "$sysconfdir/cups")
 411 AC_SUBST(CUPS_SERVERROOT)
 412
 413 # Transient run-time state
 414 CUPS_STATEDIR="$localstatedir/run/cups"
 415 AC_DEFINE_UNQUOTED(CUPS_STATEDIR, "$localstatedir/run/cups")
 416 AC_SUBST(CUPS_STATEDIR)
 417
 418 dnl
 419 dnl End of "$Id: cups-directories.m4 7799 2008-07-25 20:06:08Z mike $".
 420 dnl