configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 #######################
   5 ### Base configuration
   6
   7 # Configure autoconf
   8 AC_PREREQ([2.64])
   9
  10 dnl Use something like this if you need to patch autoconf files and
  11 dnl regenerate configure outside upstream git tree:
  12 dnl AC_INIT([lldpd], [0.5.7], [bernat@luffy.cx])
  13 AC_INIT([lldpd],
  14         [m4_esyscmd_s([git describe --tags --always 2> /dev/null || date +%F])],
  15         [bernat@luffy.cx])
  16
  17 AC_CONFIG_SRCDIR([src/log.c])
  18 AC_CONFIG_HEADER([config.h])
  19 AC_CONFIG_FILES([Makefile src/Makefile src/compat/Makefile src/daemon/Makefile
  20                           src/lib/Makefile src/lib/lldpctl.pc src/client/Makefile
  21                           tests/Makefile])
  22 AC_CONFIG_MACRO_DIR([m4])
  23
  24 # Configure automake
  25 AM_INIT_AUTOMAKE([foreign -Wall -Werror])
  26 AM_MAINTAINER_MODE
  27 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES(yes)])
  28
  29 # Configure libtool
  30 #LT_PREREQ([2.2])
  31 LT_INIT
  32
  33 #######################
  34 ### Checks
  35
  36 # Checks for programs.
  37 AC_PROG_CC
  38 AC_PROG_CC_C99
  39 AC_PROG_CXX
  40 AM_PROG_CC_C_O
  41 AC_PROG_LIBTOOL
  42
  43 # Doxygen
  44 DX_HTML_FEATURE(ON)
  45 DX_DOT_FEATURE(OFF)
  46 DX_CHM_FEATURE(OFF)
  47 DX_CHI_FEATURE(OFF)
  48 DX_MAN_FEATURE(OFF)
  49 DX_RTF_FEATURE(OFF)
  50 DX_XML_FEATURE(OFF)
  51 DX_PDF_FEATURE(ON)
  52 DX_PS_FEATURE(OFF)
  53 DX_INIT_DOXYGEN([lldpd], [doxygen.cfg], [doxygen])
  54
  55 # Check some compiler flags
  56 AX_CFLAGS_GCC_OPTION([-fdiagnostics-show-option])
  57 AX_CFLAGS_GCC_OPTION([-pipe])
  58 AX_CFLAGS_GCC_OPTION([-Wall])
  59 AX_CFLAGS_GCC_OPTION([-W])
  60 AX_CFLAGS_GCC_OPTION([-Wextra])
  61 AX_CFLAGS_GCC_OPTION([-Wformat])
  62 AX_CFLAGS_GCC_OPTION([-Wformat-security])
  63 AX_CFLAGS_GCC_OPTION([-Wfatal-errors])
  64 AX_CFLAGS_GCC_OPTION([-Wcast-align])
  65 AX_CFLAGS_GCC_OPTION([-Winline])
  66 AX_CFLAGS_GCC_OPTION([-fstack-protector])
  67 AX_CFLAGS_GCC_OPTION([-D_FORTIFY_SOURCE=2])
  68 AX_CFLAGS_GCC_OPTION([-Wno-unused-parameter])
  69 AX_CFLAGS_GCC_OPTION([-Wno-missing-field-initializers])
  70 AX_CFLAGS_GCC_OPTION([-Wno-sign-compare]) dnl Should be fixed later
  71 AX_LDFLAGS_OPTION([-Wl,-z,relro])
  72 AX_LDFLAGS_OPTION([-Wl,-z,now])
  73
  74 # OS
  75 lldp_CHECK_OS
  76
  77 AC_CACHE_SAVE
  78
  79 # Checks for header files.
  80 AC_HEADER_RESOLV
  81 AC_CHECK_HEADERS([valgrind/valgrind.h])
  82
  83 # Check for ETHERTYPE_VLAN, put it in compat.h if not defined
  84 AC_CHECK_DECLS([ETHERTYPE_VLAN],[],[],[[@%:@include <net/ethernet.h>]])
  85
  86 AC_CACHE_SAVE
  87
  88 # Checks for typedefs, structures, and compiler characteristics.
  89 lldp_CHECK___PROGNAME
  90
  91 # Checks for library functions.
  92 AC_CONFIG_LIBOBJ_DIR([src/compat])
  93 AC_FUNC_MALLOC
  94 AC_FUNC_REALLOC
  95 AC_REPLACE_FUNCS([strlcpy])
  96 AC_CACHE_SAVE
  97
  98 ## Unit tests wich check
  99 PKG_CHECK_MODULES([CHECK], [check >= 0.9.4], [have_check=yes], [have_check=no])
 100
 101 # Libevent
 102 lldp_CHECK_LIBEVENT
 103
 104 #######################
 105 ### Options
 106
 107 # SNMP
 108 AC_ARG_WITH([snmp],
 109   AS_HELP_STRING(
 110     [--with-snmp],
 111     [Enable the use of SNMP @<:@default=no@:>@]
 112   ))
 113 if test x"$with_snmp" = x"yes"; then
 114    lldp_CHECK_SNMP
 115 fi
 116
 117 # XML
 118 AC_ARG_WITH([xml],
 119   AC_HELP_STRING(
 120     [--with-xml],
 121     [Enable XML output via libxml2 @<:@default=no@:>@]
 122   ))
 123 if test x"$with_xml" = x"yes"; then
 124    lldp_CHECK_XML2
 125 fi
 126
 127 # JSON
 128 AC_ARG_WITH([json],
 129   AC_HELP_STRING(
 130     [--with-json],
 131     [Enable JSON output via Jansson @<:@default=no@:>@]
 132   ))
 133 if test x"$with_json" = x"yes"; then
 134    lldp_CHECK_JANSSON
 135 fi
 136
 137 # Privsep settings
 138 lldp_ARG_WITH([privsep-user], [Which user to use for privilege separation], [_lldpd])
 139 lldp_ARG_WITH([privsep-group], [Which group to use for privilege separation], [_lldpd])
 140 lldp_ARG_WITH([privsep-chroot], [Which directory to use to chroot lldpd], [/var/run/lldpd])
 141
 142 # CDP/FDP/EDP/SONMP
 143 lldp_ARG_ENABLE([cdp], [Cisco Discovery Protocol], [yes])
 144 lldp_ARG_ENABLE([fdp], [Foundry Discovery Protocol], [yes])
 145 lldp_ARG_ENABLE([edp], [Extreme Discovery Protocol], [yes])
 146 lldp_ARG_ENABLE([sonmp], [SynOptics Network Management Protocol], [yes])
 147
 148 # LLDPMED/Dot1/Dot3
 149 lldp_ARG_ENABLE([lldpmed], [LLDP-MED extension], [yes])
 150 lldp_ARG_ENABLE([dot1], [Dot1 extension (VLAN stuff)], [yes])
 151 lldp_ARG_ENABLE([dot3], [Dot3 extension (PHY stuff)], [yes])
 152
 153 # Oldies
 154 lldp_ARG_ENABLE([oldies], [compatibility with Linux kernel older than 2.6.18], [no])
 155
 156 #######################
 157 # Output results
 158 AM_CONDITIONAL([HAVE_CHECK], [test x"$have_check" = x"yes"])
 159 AM_CONDITIONAL([USE_SNMP], [test x"$with_snmp" = x"yes"])
 160 AM_CONDITIONAL([USE_XML], [test x"$with_xml" = x"yes"])
 161 AM_CONDITIONAL([USE_JSON], [test x"$with_json" = x"yes"])
 162 AC_OUTPUT
 163
 164 if test x"$LIBEVENT_LDFLAGS" = x; then
 165    libevent=system
 166 else
 167    libevent=embedded
 168 fi
 169
 170 cat <<EOF
 171
 172 ------------------ Summary ------------------
 173  $PACKAGE_NAME version $PACKAGE_VERSION
 174   Prefix.........: $prefix
 175   C Compiler.....: $CC $CFLAGS $CPPFLAGS
 176   Linker.........: $LD $LDFLAGS $LIBS
 177   Libevent.......: $libevent
 178  Optional features:
 179   SNMP support...: ${with_snmp-no}
 180   CDP............: $enable_cdp
 181   FDP............: $enable_fdp
 182   EDP............: $enable_edp
 183   SONMP..........: $enable_sonmp
 184   LLDPMED........: $enable_lldpmed
 185   DOT1...........: $enable_dot1
 186   DOT3...........: $enable_dot3
 187   XML output.....: ${with_xml-no}
 188   JSON output....: ${with_json-no}
 189   Oldies support.: $enable_oldies
 190 ---------------------------------------------
 191
 192 Check the above options and compile with:
 193  ${MAKE-make}
 194
 195 EOF