configure.ac

   1 ## Copyright (C) 1996-2023 The Squid Software Foundation and contributors
   2 ##
   3 ## Squid software is distributed under GPLv2+ license and includes
   4 ## contributions from numerous individuals and organizations.
   5 ## Please see the COPYING and CONTRIBUTORS files for details.
   6 ##
   7
   8 AC_INIT([Squid Web Proxy],[7.0.0-VCS],[https://bugs.squid-cache.org/],[squid])
   9 AC_PREREQ(2.61)
  10 AC_CONFIG_HEADERS([include/autoconf.h])
  11 AC_CONFIG_AUX_DIR(cfgaux)
  12 AC_CONFIG_SRCDIR([src/main.cc])
  13 AM_INIT_AUTOMAKE([tar-ustar nostdinc subdir-objects dist-xz])
  14 AC_REVISION($Revision$)dnl
  15 AC_PREFIX_DEFAULT(/usr/local/squid)
  16 AM_MAINTAINER_MODE
  17
  18 m4_include([acinclude/ax_with_prog.m4])
  19 m4_include([acinclude/init.m4])
  20 m4_include([acinclude/squid-util.m4])
  21 m4_include([acinclude/compiler-flags.m4])
  22 m4_include([acinclude/os-deps.m4])
  23 m4_include([acinclude/krb5.m4])
  24 m4_include([acinclude/ldap.m4])
  25 m4_include([acinclude/pam.m4])
  26 m4_include([acinclude/pkg.m4])
  27 m4_include([acinclude/tdb.m4])
  28 m4_include([acinclude/lib-checks.m4])
  29 m4_include([acinclude/ax_cxx_compile_stdcxx.m4])
  30 m4_include([acinclude/win32-sspi.m4])
  31
  32 PRESET_CFLAGS="$CFLAGS"
  33 PRESET_CXXFLAGS="$CXXFLAGS"
  34 PRESET_LDFLAGS="$LDFLAGS"
  35
  36 dnl Set default LDFLAGS
  37 AS_IF([test "x$LDFLAGS" = "x"],[LDFLAGS="-g"])
  38
  39 # check for host OS detail
  40 AC_CANONICAL_HOST
  41 AC_MSG_CHECKING([simplified host os])
  42 simple_host_os=`echo $host_os|sed 's/[0-9].*//g;s/-.*//g'`
  43 squid_host_os_version=`echo $host_os|tr -d "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ-"`
  44 AS_IF([test -n "$squid_host_os_version"],[
  45   squid_host_os="`echo $simple_host_os| sed s/$squid_host_os_version//g`"
  46 ],[
  47   squid_host_os="$simple_host_os"
  48 ])
  49 AC_MSG_RESULT($squid_host_os (version $squid_host_os_version))
  50 # on windows squid_host_os is either mingw or cygwin, version is 32
  51
  52 AC_PROG_CC
  53 AM_PROG_CC_C_O
  54 AC_PROG_CXX
  55
  56 # AC_USE_SYSTEM_EXTENSIONS should be called before any macros that run the C compiler.
  57 AC_USE_SYSTEM_EXTENSIONS
  58
  59 AC_LANG([C++])
  60
  61 # Clang 3.2 on some CPUs requires -march-native to detect correctly.
  62 # GCC 4.3+ can also produce faster executables when its used.
  63 # But building inside a virtual machine environment has been found to
  64 # cause random Illegal Instruction errors due to mis-detection of CPU.
  65 AC_ARG_ENABLE(arch-native,
  66   AS_HELP_STRING([--disable-arch-native],[Some compilers offer CPU-specific
  67                  optimizations with the -march=native parameter.
  68                  This flag disables the optimization. The default is to
  69                  auto-detect compiler support and use where available.]), [
  70   SQUID_YESNO([$enableval],[--enable-arch-native])
  71 ])
  72 AC_MSG_NOTICE([CPU arch native optimization enabled: ${enable_arch_native:=auto}])
  73 AS_IF([test "x${enable_arch_native}" != "xno"],[
  74   SQUID_CC_CHECK_ARGUMENT([squid_cv_check_marchnative],[-march=native])
  75 ])
  76
  77 # If the user did not specify a C++ version.
  78 user_cxx=`echo "$PRESET_CXXFLAGS" | grep -o -E "(-)std="`
  79 AS_IF([test "x$user_cxx" = "x"],[
  80   # Check for C++17 compiler support
  81   # May change CXX.
  82   AX_CXX_COMPILE_STDCXX([17],[noext],[mandatory])
  83 ])
  84
  85 # Prerequisite: CXX has been finalized.
  86 # BUILDCXXFLAGS are defined later, after CXXFLAGS have been finalized.
  87 AC_ARG_VAR([BUILDCXX],[path to compiler for building compile-time tools. e.g. cf_gen])
  88 AS_IF([test "x$HOSTCXX" != "x" -a "x$BUILDCXX" = "x"],[
  89   AC_MSG_WARN([Cross-compiling with HOSTCXX is deprecated. Use BUILDCXX instead.])
  90   BUILDCXX="$HOSTCXX"
  91 ])
  92 AS_IF([test "x$BUILDCXX" = "x"],[
  93   BUILDCXX="$CXX"
  94   AS_IF([test "x$squid_cv_check_marchnative" = "xyes"],[
  95     CXXFLAGS="$CXXFLAGS -march=native"
  96   ])
  97 ])
  98 AC_SUBST(BUILDCXX)
  99
 100 # test for programs
 101 AC_PROG_RANLIB
 102 AC_PROG_CPP
 103 AC_PROG_INSTALL
 104 AC_PROG_LN_S
 105 AC_PROG_EGREP
 106
 107 AC_PATH_PROG(SH, sh, /bin/sh)
 108 AC_PATH_PROG(FALSE, false, /usr/bin/false)
 109 AC_PATH_PROG(TRUE, true, /usr/bin/true)
 110 AC_PATH_PROG(MV, mv, $FALSE)
 111 AC_PATH_PROG(MKDIR, mkdir, $FALSE)
 112 AC_PATH_PROG(LN, ln, cp)
 113 AC_PATH_PROG(CHMOD, chmod, $FALSE)
 114 AC_PATH_PROG(TR, tr, $FALSE)
 115 AC_PATH_PROG(RM, rm, $FALSE)
 116 dnl Libtool 2.2.6 requires: rm -f
 117 RM="$RM -f"
 118
 119 PKG_PROG_PKG_CONFIG
 120
 121 AC_PATH_PROG(PERL, perl, none)
 122 AS_IF([test "x$ac_cv_path_PERL" = "xnone"],[
 123   AC_MSG_FAILURE([Perl is required to compile Squid. Please install Perl and then re-run configure ])
 124 ])
 125 AC_PATH_PROG(POD2MAN, pod2man, $FALSE)
 126 AM_CONDITIONAL(ENABLE_POD2MAN_DOC, test "x${ac_cv_path_POD2MAN}" != "x$FALSE")
 127
 128 AC_PATH_PROG(AR, ar, $FALSE)
 129 AR_R="$AR r"
 130 AC_SUBST(AR_R)
 131
 132 AC_PATH_PROG(LINUXDOC, linuxdoc, $FALSE)
 133 AM_CONDITIONAL(ENABLE_RELEASE_DOCS, test "x${ac_cv_path_LINUXDOC}" != "x$FALSE")
 134
 135 SQUID_RELEASE=`echo $VERSION | cut -d. -f1`
 136 AC_SUBST(SQUID_RELEASE)
 137
 138 # pre-define DEFAULT_PREFIX, some modules need it.
 139 AS_IF([test "${prefix}" = "NONE"],[squid_prefix=$ac_default_prefix],[squid_prefix=$prefix])
 140 AC_DEFINE_UNQUOTED(DEFAULT_PREFIX,[$squid_prefix],[The install prefix])
 141
 142 AC_ARG_ENABLE(strict-error-checking,
 143   AS_HELP_STRING([--disable-strict-error-checking],[By default squid is compiled
 144                  with all possible static compiler error-checks enabled.
 145                  This flag disables the behavior]), [
 146   SQUID_YESNO([$enableval],[--enable-strict-error-checking])
 147 ])
 148 AC_MSG_NOTICE([strict error checking enabled: ${enable_strict_error_checking:=yes}])
 149
 150 # LT_INIT requires libtool v2, might as well state it loud
 151 LT_PREREQ([2.2])
 152 LT_INIT([dlopen])
 153 AS_IF([test "x$ac_top_build_prefix" != "x"],[
 154   # LTDL v3-v7 macros assume the autoconf 2.62 variable top_build_prefix is defined
 155   # But from autoconf 2.64 its called ac_top_build_prefix and not automatically added to the Makefile
 156   # This fixes Linux LTDLv3-v7, and BSD LTDL v2.2
 157   top_build_prefix=${ac_top_build_prefix}
 158   AC_SUBST(top_build_prefix)
 159 ])
 160 LTDL_INIT
 161
 162 dnl LibTool environment is now prepared for setup. Check that it is usable and initialize.
 163 LT_LIB_DLLOAD
 164
 165 # Do we need these unconditionally for "make distcheck" to work?
 166 AC_SUBST(INCLTDL)
 167 AC_SUBST(LIBLTDL)
 168
 169 AC_MSG_CHECKING(whether to use loadable modules)
 170 AS_IF([test "x${enable_shared:=yes}" = "xyes"],[AC_DEFINE(USE_LOADABLE_MODULES,1,[Support Loadable Modules])])
 171 AM_CONDITIONAL(ENABLE_LOADABLE_MODULES, test "x${enable_shared:=yes}" = "xyes")
 172 AC_MSG_RESULT([$enable_shared])
 173
 174 SQUID_CC_GUESS_VARIANT
 175 SQUID_CC_GUESS_OPTIONS
 176
 177 dnl find out the exe extension for this platform.
 178 dnl If it is not empty, use it for CGI as well.
 179 AC_EXEEXT
 180 AC_OBJEXT
 181 AS_IF([test "x$EXEEXT" = "x"],[CGIEXT=".cgi"],[CGIEXT=""])
 182 AC_SUBST(CGIEXT)
 183
 184 AM_CONDITIONAL(ENABLE_WIN32SPECIFIC,[test "x$squid_host_os" = "xmingw"])
 185 AM_CONDITIONAL(ENABLE_WIN32_IPC,[test "x$squid_host_os" = "xmingw"])
 186
 187 AS_CASE(["$squid_host_os"],
 188   [mingw],[
 189     CFLAGS="$CFLAGS -mthreads"
 190     CXXFLAGS="$CXXFLAGS -mthreads -static-libgcc -static-libstdc++"
 191     dnl Check for Winsock only on MinGW
 192     SQUID_CHECK_WINSOCK_LIB
 193     AC_CHECK_HEADERS([ws2tcpip.h winsock2.h windows.h io.h],,,[
 194 #if HAVE_WS2TCPIP_H
 195 #include <ws2tcpip.h>
 196 #endif
 197 #if HAVE_WINSOCK2_H
 198 #include <winsock2.h>
 199 #endif
 200 #if HAVE_WINDOWS_H
 201 #include <windows.h>
 202 #endif
 203     ])
 204     MINGW_LIBS="-lmingwex"
 205     AC_SUBST(MINGW_LIBS)
 206     AC_CHECK_FUNCS([fsync])
 207   ],
 208
 209   [freebsd],[
 210     # FreeBSD places local libraries and packages in /usr/local
 211     CFLAGS="$CFLAGS -I/usr/local/include"
 212     CXXFLAGS="$CXXFLAGS -I/usr/local/include"
 213     LDFLAGS="$LDFLAGS -L/usr/local/lib -Wl,-R/usr/local/lib"
 214   ]
 215 )
 216
 217 dnl Substitutions
 218 AC_DEFINE_UNQUOTED(CONFIG_HOST_TYPE, "$host",[Host type from configure])
 219
 220 AC_DEFINE_UNQUOTED(SQUID_CONFIGURE_OPTIONS, "$ac_configure_args",
 221                        [configure command line used to configure Squid])
 222
 223 CACHE_EFFECTIVE_USER="nobody"
 224 AC_ARG_WITH(default-user,
 225   AS_HELP_STRING([--with-default-user=USER],[System user account for squid permissions. Default: nobody]),
 226  [ CACHE_EFFECTIVE_USER="$withval" ]
 227 )
 228 AC_SUBST(CACHE_EFFECTIVE_USER)
 229
 230 DEFAULT_LOG_DIR="$localstatedir/logs"
 231 AC_ARG_WITH(logdir,
 232   AS_HELP_STRING([--with-logdir=PATH],
 233     [Default location for squid logs. default: PREFIX/var/logs]),[
 234   AS_CASE([$withval],
 235     [yes|no],[AC_MSG_ERROR([--with-logdir requires a directory PATH. --with-logdir=PATH])],
 236     [DEFAULT_LOG_DIR="$withval"]
 237   )
 238 ])
 239 AC_SUBST(DEFAULT_LOG_DIR)
 240
 241 DEFAULT_PID_FILE="$localstatedir/run/@SERVICE_NAME@.pid"
 242 AC_ARG_WITH(pidfile,
 243   AS_HELP_STRING([--with-pidfile=PATH],
 244     [Default location for squid pid file. Default: PREFIX/var/run/squid.pid]),[
 245   AS_CASE([$withval],
 246     [yes|no],[AC_MSG_ERROR([--with-pidfile requires a file PATH. --with-pidfile=PATH])],
 247     [DEFAULT_PID_FILE="$withval"]
 248   )
 249 ])
 250 AC_SUBST(DEFAULT_PID_FILE)
 251
 252 DEFAULT_SWAP_DIR="$localstatedir/cache/squid"
 253 AC_ARG_WITH(swapdir,
 254   AS_HELP_STRING([--with-swapdir=PATH],
 255     [Default location for squid cache directories. Default: PREFIX/var/cache/squid]),[
 256   AS_CASE([$withval],
 257     [yes|no],[AC_MSG_ERROR([--with-swapdir requires a directory PATH. --with-swapdir=PATH])],
 258     [DEFAULT_SWAP_DIR="$withval"]
 259   )
 260 ])
 261 AC_SUBST(DEFAULT_SWAP_DIR)
 262
 263 dnl Set Default CFLAGS
 264 AS_IF([test "x$PRESET_CFLAGS" = "x"],[
 265   AS_IF([test "$squid_cv_compiler" = "gcc"],[
 266     # TODO check if these exceptions are still necessary
 267     AS_CASE(["$host"],
 268       [*-sun-sunos*],[
 269         # sunos has too many warnings for -Wall to be useful
 270       ],
 271       [CFLAGS="$squid_cv_cc_option_wall $CFLAGS"]
 272     )
 273   ],[
 274     AS_CASE(["$host"],
 275       [*mips-sgi-irix6.*],[
 276         # suggested by Rafael Seidl <rafaels@cthulhu.engr.sgi.com>
 277         CFLAGS="$squid_cv_cc_option_optimize -OPT:Olimit=0:space=OFF \
 278                 -woff 1009,1014,1110,1116,1183,1185,1188,1204,1230,1233,1355 \
 279                 -Wl,-woff,85,-woff,84,-woff,134 \
 280                 -nostdinc -I/usr/include -D_BSD_SIGNALS $CFLAGS"
 281         CXXFLAGS="$squid_cv_cc_option_optimize -OPT:Olimit=0:space=OFF \
 282                   -woff 1009,1014,1110,1116,1183,1185,1188,1204,1230,1233,1355 \
 283                   -Wl,-woff,85,-woff,84,-woff,134 \
 284                   -nostdinc -I/usr/include -D_BSD_SIGNALS $CXXFLAGS"
 285     ])
 286   ])
 287 ])
 288
 289 AC_MSG_CHECKING([compiler name-version])
 290 squid_cv_cc_name=`$CC --version | head -1 | cut -f1 -d" "`
 291 AS_CASE([$squid_cv_cc_name],
 292   [gcc|clang],[squid_cv_cc_majversion=`$CC -dumpversion | cut -f1 -d.`],
 293   [squid_cv_cc_majversion="unknown"]
 294 )
 295 squid_cv_cc_simplified="$squid_cv_cc_name-$squid_cv_cc_majversion"
 296 AC_MSG_RESULT($squid_cv_cc_simplified)
 297
 298 # warning flags
 299
 300 # -Wall
 301 SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([$squid_cv_cc_option_wall])
 302
 303 # -Wextra
 304 AS_IF([test "$squid_cv_cc_simplified" = "gcc-4"],[
 305     AC_MSG_NOTICE([skipping -Wextra on $squid_cv_cc_simplified])
 306 ],[
 307     SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wextra])
 308
 309     # Now disable or configure certain warnings enabled by -Wextra
 310
 311     # -Wunused-private-field causes a huge number of false positives
 312     #    in unit tests. Disable that
 313     SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wno-unused-private-field])
 314
 315     # ...=5: Do not trust comments about fallthrough cases (GCC).
 316     SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wimplicit-fallthrough=5])
 317     AS_IF([test "x$squid_cv_cc_arg_wimplicit_fallthrough_5" != "xyes"], [
 318         SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wno-implicit-fallthrough])
 319     ])
 320 ])
 321
 322 # useful warnings that may not be included in -Wall -Wextra
 323 SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wpointer-arith])
 324 SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wwrite-strings])
 325 SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wcomments])
 326 SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wshadow])
 327 SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Wmissing-declarations])
 328 SQUID_CC_ADD_CXXFLAG_WARNING_IF_SUPPORTED([-Woverloaded-virtual])
 329
 330 dnl CentOS (and RHEL) still define ntohs() using deprecated C++ features
 331 SQUID_CC_REQUIRE_ARGUMENT([ac_cv_require_wno_deprecated_register],[-Werror -Wno-deprecated-register],[[#include <arpa/inet.h>]],[[int fox=ntohs(1);]])
 332
 333 AS_IF([test "x$enable_strict_error_checking" != "xno"],[
 334   SQUID_CFLAGS="$SQUID_CFLAGS $squid_cv_cc_option_werror"
 335   SQUID_CXXFLAGS="$SQUID_CXXFLAGS $squid_cv_cxx_option_werror"
 336 ])
 337
 338 AS_IF([test "x$ac_cv_require_wno_deprecated_register" = "xyes"],[
 339   SQUID_CXXFLAGS="$SQUID_CXXFLAGS -Wno-deprecated-register"
 340 ])
 341
 342 # squid_cv_cc_arg_pipe is set by SQUID_CC_GUESS_OPTIONS
 343 SQUID_CXXFLAGS="$SQUID_CXXFLAGS $squid_cv_cc_arg_pipe"
 344 SQUID_CFLAGS="$SQUID_CFLAGS $squid_cv_cc_arg_pipe"
 345
 346 # possibly include some build info tag into squid -v
 347 SQUID_EMBED_BUILD_INFO
 348
 349 AC_ARG_ENABLE(optimizations,
 350   AS_HELP_STRING([--disable-optimizations],
 351                  [Do not compile Squid with compiler optimizations enabled.
 352                   Optimization is good for production builds, but not
 353                   good for debugging. During development, use
 354                   --disable-optimizations to reduce compilation times
 355                   and allow easier debugging.]), [
 356   AS_IF([test "x$enableval" = "xno"],[
 357     AC_MSG_NOTICE([Disabling compiler optimizations (-O flag)])
 358     CFLAGS="`echo $CFLAGS | sed -e 's/-O[[0-9g]]*//'`"
 359     CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-O[[0-9g]]*//'`"
 360   ])
 361 ])
 362
 363 dnl Nasty hack to get autoconf 2.64 on Linux to run.
 364 dnl all other uses of RUN_IFELSE are wrapped inside CACHE_CHECK which breaks on 2.64
 365 AC_RUN_IFELSE([AC_LANG_SOURCE([[ int main(int argc, char **argv) { return 0; } ]])],[],[],[:])
 366
 367 AH_TEMPLATE(XMALLOC_STATISTICS,[Define to have malloc statistics])
 368 AC_ARG_ENABLE(xmalloc-statistics,
 369   AS_HELP_STRING([--enable-xmalloc-statistics],
 370                  [Show malloc statistics in status page]), [
 371   SQUID_YESNO([$enableval],[--enable-xmalloc-statistics])
 372 ])
 373 SQUID_DEFINE_BOOL(XMALLOC_STATISTICS,${enable_xmalloc_statistics:=no},
 374     [Show malloc statistics in status page])
 375 AC_MSG_NOTICE([xmalloc stats display: $enable_xmalloc_statistics])
 376
 377 squid_opt_aufs_threads=""
 378 AC_ARG_WITH(aufs-threads,
 379   AS_HELP_STRING([--with-aufs-threads=N_THREADS],
 380     [Tune the number of worker threads for the aufs object store.]), [
 381   AS_CASE([$withval],
 382     [@<:@0-9@:>@*],[squid_opt_aufs_threads=$withval],
 383     AC_MSG_ERROR(--with-aufs-threads expects a numeric argument)
 384   )
 385 ])
 386 AS_IF([test "x$squid_opt_aufs_threads" != "x"],[
 387   AC_MSG_NOTICE([With $squid_opt_aufs_threads aufs threads])
 388   AC_DEFINE_UNQUOTED(AUFS_IO_THREADS,$squid_opt_aufs_threads,
 389     [Defines how many threads aufs uses for I/O])
 390 ])
 391
 392 ## TODO check if this is necessary, LT_INIT does these checks
 393 SQUID_AUTO_LIB(dl,[dynamic linking],[LIBDL])
 394 SQUID_CHECK_LIB_WORKS(dl,[
 395   LDFLAGS="$LIBDL_PATH $LDFLAGS"
 396   AC_CHECK_LIB(dl, dlopen,[LIBDL_LIBS="-ldl"])
 397   LIBS="$LIBDL_LIBS $LIBS"
 398 ])
 399
 400 AC_DEFUN([LIBATOMIC_CHECKER],[
 401   AC_MSG_CHECKING(whether linking $1 -latomic works)
 402   AC_LINK_IFELSE([
 403     AC_LANG_SOURCE([[
 404 #include <atomic>
 405 #include <cstdint>
 406       int
 407       main(int argc, char **) {
 408           return (
 409               std::atomic<uint8_t>(uint8_t(argc)).exchange(0) &&
 410               std::atomic<uint64_t>{}.is_lock_free()
 411               ) ? 0 : 1;
 412       }
 413   ]])],[
 414     AC_MSG_RESULT(yes)
 415     libatomic_checker_result="yes"],[
 416     AC_MSG_RESULT(no)
 417     libatomic_checker_result="no"
 418 ])])
 419
 420 ## check for atomics library before anything that might need it
 421 SQUID_STATE_SAVE(LIBATOMIC)
 422 LIBATOMIC_CHECKER(without)
 423 AS_IF([test "x$libatomic_checker_result" = "xno"],[
 424   LIBS="$LIBS -latomic"
 425   LIBATOMIC_CHECKER(with)
 426   AS_IF([test "x$libatomic_checker_result" = "xyes"],[
 427     ATOMICLIB="-latomic"],[
 428     AC_MSG_ERROR([Required library libatomic not found.])
 429 ])])
 430 SQUID_STATE_ROLLBACK(LIBATOMIC)
 431 AC_SUBST(ATOMICLIB)
 432
 433 SQUID_AUTO_LIB(psapi,[Windows PSAPI.dll],[LIBPSAPI])
 434 SQUID_CHECK_LIB_WORKS(psapi,[
 435   SQUID_STATE_SAVE(squid_psapi_state)
 436   CPPFLAGS="$LIBPSAPI_CFLAGS $CPPFLAGS"
 437   LIBS="$LIBPSAPI_PATH $LIBS"
 438   AC_CHECK_LIB([psapi],[K32GetProcessMemoryInfo],[
 439     LIBPSAPI_LIBS="-lpsapi"
 440     AC_CHECK_HEADERS([psapi.h],,,[
 441 #if HAVE_WINDOWS_H
 442 #include <windows.h>
 443 #endif
 444     ])
 445   ])
 446   SQUID_STATE_ROLLBACK(squid_psapi_state)
 447 ])
 448
 449 AC_SEARCH_LIBS([shm_open], [rt])
 450 AS_IF([test "x$ac_cv_search_shm_open" != "xno"],[
 451   AC_DEFINE(HAVE_SHM,1,[Support shared memory features])
 452 ])
 453
 454 squid_disk_module_candidates=
 455 AC_ARG_ENABLE(disk-io,
 456   AS_HELP_STRING([--enable-disk-io="list of modules"],
 457     [Build support for the list of disk I/O modules.
 458      Set without a value or omitted, all available modules will be built.
 459      See src/DiskIO for a list of available modules, or
 460      Programmers Guide section on DiskIO
 461      for details on how to build your custom disk module]),
 462   AS_CASE(["$enableval"],
 463     [yes],[],
 464     [no|none],[enable_disk_io="no"],
 465     [
 466       enable_disk_io="yes"
 467       squid_disk_module_candidates="$enableval"
 468   ])
 469 )
 470 AS_IF([test "x${enable_disk_io:=yes}" = "xyes"],[
 471   SQUID_LOOK_FOR_MODULES([$srcdir/src/DiskIO],[squid_disk_module_candidates])
 472   AS_IF([test "x$ac_cv_search_shm_open" = "xno"],[
 473     squid_disk_module_candidates=`echo "$squid_disk_module_candidates" | sed 's/IpcIo//g'`
 474   ])
 475 ])
 476 SQUID_CLEANUP_MODULES_LIST([squid_disk_module_candidates])
 477 SQUID_CHECK_EXISTING_MODULES([$srcdir/src/DiskIO],[squid_disk_module_candidates])
 478 AC_MSG_NOTICE([DiskIO modules built: ${squid_disk_module_candidates:-none}])
 479 SQUID_DEFINE_BOOL(USE_DISKIO,$enable_disk_io,[DiskIO modules are expected to be available.])
 480
 481 dnl Some autoconf.h defines we might enable later...
 482 AC_ARG_WITH(pthreads,AS_HELP_STRING([--without-pthreads],[Disable POSIX Threads]))
 483 AC_ARG_WITH(aio, AS_HELP_STRING([--without-aio],[Do not use POSIX AIO. Default: auto-detect]))
 484 ENABLE_WIN32_AIOPS=0
 485 squid_opt_use_aio=
 486 squid_opt_use_diskthreads=
 487 AIOLIB=
 488
 489 dnl Setup the module paths etc.
 490 DISK_LIBS=
 491 DISK_MODULES=
 492 AH_TEMPLATE(HAVE_DISKIO_MODULE_AIO, [Whether POSIX AIO Disk I/O module is built])
 493 AH_TEMPLATE(HAVE_DISKIO_MODULE_BLOCKING, [Whether Blocking Disk I/O module is built])
 494 AH_TEMPLATE(HAVE_DISKIO_MODULE_DISKDAEMON, [Whether DiskDaemon Disk I/O module is built])
 495 AH_TEMPLATE(HAVE_DISKIO_MODULE_DISKTHREADS, [Whether DiskThreads Disk I/O module is built])
 496 AH_TEMPLATE(HAVE_DISKIO_MODULE_IPCIO, [Whether IpcIo Disk I/O module is built])
 497 AH_TEMPLATE(HAVE_DISKIO_MODULE_MMAPPED, [Whether Mmapped Disk I/O module is built])
 498 for module in $squid_disk_module_candidates none; do
 499   # maybe not needed
 500   AS_IF([test "x$module" = "xnone"],[continue])
 501   AS_IF([! test -d "$srcdir/src/DiskIO/$module"],[AC_MSG_ERROR([disk-io $module does not exist])])
 502   AS_CASE(["$module"],
 503     [AIO],[
 504       dnl Check for POSIX AIO availability
 505       squid_opt_use_aio="yes"
 506       AIOLIB=
 507       AS_IF([test "x$with_aio" != "xno"],[
 508         have_aio_header=no
 509         AC_CHECK_HEADERS(aio.h,[have_aio_header=yes])
 510         dnl On some systems POSIX AIO functions are in librt
 511         dnl On some systems POSIX AIO functions are in libaio
 512         AC_CHECK_LIB(rt,aio_read,[AIOLIB="-lrt"],AC_CHECK_LIB(aio,aio_read,[AIOLIB="-laio"],[]))
 513         dnl Enable AIO if the library and headers are found
 514         AS_IF([test "x$AIOLIB" != "x" -a "x$have_aio_header" = "xyes"],[
 515           AC_MSG_NOTICE([Native POSIX AIO support detected.])
 516           squid_opt_use_aio="yes"
 517         ],[
 518           dnl Windows does things differently. We provide wrappers.
 519           dnl TODO: Windows really needs its own DiskIO module or its Overlaped IO
 520           AS_IF([test "$squid_host_os" = "mingw"],[
 521             squid_opt_use_aio="yes"
 522             AC_MSG_NOTICE([Windows being built. Maybe-enable POSIX AIO.])
 523           ],[
 524             squid_opt_use_aio="no"
 525             AC_MSG_NOTICE([Native POSIX AIO support not detected. AIO automatically disabled.])
 526           ])
 527         ])
 528       ],[
 529         AC_MSG_NOTICE([POSIX AIO support manually disabled.])
 530         squid_opt_use_aio="no"
 531       ])
 532       dnl Use the POSIX AIO pieces if we actually need them.
 533       AS_IF([test "x$squid_opt_use_aio" = "xyes"],[
 534         DISK_MODULES="$DISK_MODULES AIO"
 535         AC_DEFINE([HAVE_DISKIO_MODULE_AIO],1,[POSIX AIO Disk I/O module is built])
 536         AS_IF([test "$squid_host_os" = "mingw"],[
 537           ENABLE_WIN32_AIO=1
 538           AC_MSG_NOTICE([Replacing AIO DiskIO module with: Windows overlapped I/O support])
 539         ],[
 540           AC_MSG_NOTICE([Enabling AIO DiskIO module])
 541         ])
 542       ],[
 543         AC_MSG_NOTICE([AIO DiskIO Module disabled. Missing POSIX AIO support.])
 544         squid_disk_module_candidates_AIO=no
 545       ])
 546     ],
 547
 548     [Blocking],[
 549       AC_MSG_NOTICE([Enabling Blocking DiskIO module])
 550       DISK_MODULES="$DISK_MODULES Blocking"
 551       AC_DEFINE([HAVE_DISKIO_MODULE_BLOCKING],1,[Blocking Disk I/O module is built])
 552     ],
 553
 554     [DiskDaemon],[
 555       AS_IF([test "$squid_host_os" = "mingw"],[
 556         AC_MSG_NOTICE([DiskDaemon not supported on MinGW])
 557         squid_disk_module_candidates_DiskDaemon=no
 558       ],[
 559         AC_MSG_NOTICE([Enabling DiskDaemon DiskIO module])
 560         DISK_MODULES="$DISK_MODULES DiskDaemon"
 561         AC_DEFINE([HAVE_DISKIO_MODULE_DISKDAEMON],1,[DiskDaemon Disk I/O module is built])
 562       ])
 563     ],
 564
 565     [DiskThreads],[
 566       squid_opt_use_diskthreads="yes"
 567       LIBPTHREADS=
 568       SQUID_STATE_SAVE([diskthreads_state],[SQUID_CFLAGS SQUID_CXXFLAGS])
 569       AS_IF([test "x$with_pthreads" != "xno"],[
 570         dnl TODO: this needs to be extended to handle more systems and better
 571         dnl REF: http://www.openldap.org/lists/openldap-bugs/200006/msg00070.html
 572         dnl REF: http://autoconf-archive.cryp.to/acx_pthread.html
 573         AS_CASE(["$squid_host_os"],
 574           [mingw],[
 575             ENABLE_WIN32_AIOPS=1
 576             AC_MSG_NOTICE([Windows threads support automatically enabled])
 577           ],
 578
 579           [freebsd],[
 580             AS_IF([test `echo "$squid_host_os_version" | tr -d .` -lt 70],[
 581               AC_MSG_NOTICE(pthread library requires FreeBSD 7 or later)
 582               squid_opt_use_diskthreads="no"
 583             ],[
 584               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT"
 585               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT"
 586               AS_IF([test "x$GCC" = "xyes" -a "x$PRESET_LDFLAGS" = "x"],[LDFLAGS="$LDFLAGS -pthread"])
 587             ])
 588           ],
 589
 590           [openbsd],[
 591             AS_IF([test `echo "$squid_host_os_version" | tr -d .` -lt 52],[
 592               AC_MSG_NOTICE(pthread library requires OpenBSD 5.2 or later)
 593               squid_opt_use_diskthreads="no"
 594             ],[
 595               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT"
 596               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT"
 597               LDFLAGS="$LDFLAGS -lpthread"
 598             ])
 599           ],
 600
 601           [solaris],[
 602             AS_IF([test "x$GCC" = "xyes"],[
 603               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT -pthreads"
 604               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT -pthreads"
 605               AC_CHECK_LIB(pthread, pthread_create ,[LIBPTHREADS="-lpthread"], [
 606                 AC_MSG_NOTICE(pthread library required but cannot be found.)
 607                 squid_opt_use_diskthreads="no"
 608                ])
 609             ],[
 610               dnl test for -lpthread first. libc version is a stub apparently on Solaris.
 611               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT -lpthread"
 612               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT -lpthread"
 613               AC_SEARCH_LIBS([pthread_create],[pthread thread],[
 614                 LIBPTHREADS="" #in LIBS
 615               ],[
 616                 AC_MSG_NOTICE(pthread library required but cannot be found.)
 617                 squid_opt_use_diskthreads="no"
 618               ])
 619             ])
 620           ],
 621
 622           [
 623             SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT"
 624             SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT"
 625             AC_CHECK_LIB(pthread, pthread_create ,[LIBPTHREADS="-lpthread"], [
 626               AC_MSG_NOTICE(pthread library required but cannot be found.)
 627               squid_opt_use_diskthreads="no"
 628             ])
 629           ]
 630         )
 631       ],[
 632         AC_MSG_NOTICE([Native pthreads support manually disabled.])
 633         squid_opt_use_diskthreads="no"
 634       ])
 635       AS_IF([test "x$squid_opt_use_diskthreads" = "xyes"],[
 636         AC_MSG_NOTICE([Enabling DiskThreads DiskIO module])
 637         DISK_MODULES="$DISK_MODULES DiskThreads"
 638         AC_DEFINE([HAVE_DISKIO_MODULE_DISKTHREADS],1,[DiskThreads Disk I/O module is built])
 639       ],[
 640         AC_MSG_NOTICE([Native pthreads support disabled. DiskThreads module automaticaly disabled.])
 641         SQUID_STATE_ROLLBACK([diskthreads_state])
 642         squid_disk_module_candidates_DiskThreads=no
 643       ])
 644     ],
 645
 646     [IpcIo],[
 647       AS_IF([test "x$ac_cv_search_shm_open" = "xno"],[
 648         AC_MSG_NOTICE([DiskIO IpcIo module requires shared memory support])
 649         squid_disk_module_candidates_IpcIo=no
 650       ],[
 651         AC_MSG_NOTICE([Enabling IpcIo DiskIO module])
 652         DISK_MODULES="$DISK_MODULES IpcIo"
 653         AC_DEFINE([HAVE_DISKIO_MODULE_IPCIO],1,[IpcIo Disk I/O module is built])
 654       ])
 655     ],
 656
 657     [Mmapped],[
 658       dnl TODO: use availability of sys/mman.h and/or mmap to define
 659       dnl  OR support windows mmap functions
 660       AS_IF([test "x$squid_host_os" = "xmingw"],[
 661         AC_MSG_NOTICE([Mmapped DiskIO is not available on Mingw])
 662         squid_disk_module_candidates_Mmapped=no
 663       ],[
 664         AC_MSG_NOTICE([Enabling Mmapped DiskIO module])
 665         DISK_MODULES="$DISK_MODULES Mmapped"
 666         AC_DEFINE([HAVE_DISKIO_MODULE_MMAPPED],1,[Mmapped Disk I/O module is built])
 667       ])
 668     ],
 669
 670     [
 671       AC_MSG_NOTICE([Enabling $module DiskIO module])
 672       DISK_LIBS="$DISK_LIBS lib${module}.la"
 673       DISK_MODULES="$DISK_MODULES ${module}"
 674     ])
 675 done
 676 AC_MSG_NOTICE([IO Modules built: $DISK_MODULES])
 677 AC_SUBST(DISK_MODULES)
 678 AC_SUBST(DISK_LIBS)
 679 AM_CONDITIONAL(ENABLE_DISKIO_AIO, test "x$squid_disk_module_candidates_AIO" = "xyes")
 680 AC_SUBST(AIOLIB)
 681 AM_CONDITIONAL(ENABLE_WIN32_AIO, test "x$squid_disk_module_candidates_AIO" = "xyes" -a "x$ENABLE_WIN32_AIO" = "x1")
 682 AM_CONDITIONAL(ENABLE_DISKIO_BLOCKING, test "x$squid_disk_module_candidates_Blocking" = "xyes")
 683 AM_CONDITIONAL(ENABLE_DISKIO_DISKDAEMON, test "x$squid_disk_module_candidates_DiskDaemon" = "xyes")
 684 AM_CONDITIONAL(ENABLE_DISKIO_DISKTHREADS, test "x$squid_disk_module_candidates_DiskThreads" = "xyes")
 685 AC_SUBST(LIBPTHREADS)
 686 AM_CONDITIONAL(ENABLE_WIN32_AIOPS, test "x$squid_disk_module_candidates_DiskThreads" = "xyes" -a "x$ENABLE_WIN32_AIOPS" = "x1")
 687 AM_CONDITIONAL(ENABLE_DISKIO_IPCIO, test "x$squid_disk_module_candidates_IpcIo" = "xyes")
 688 AM_CONDITIONAL(ENABLE_DISKIO_MMAPPED, test "x$squid_disk_module_candidates_Mmapped" = "xyes")
 689
 690 dnl Check what Storage formats are wanted.
 691 dnl This version will error out with a message saying why if a required DiskIO is missing.
 692 AC_ARG_ENABLE([storeio],
 693   AS_HELP_STRING([--enable-storeio="list of modules"],
 694                  [Build support for the list of store I/O modules.
 695                   The default is only to build the "ufs" module.
 696                   See src/fs for a list of available modules, or
 697                   Programmers Guide section <not yet written>
 698                   for details on how to build your custom store module]), [
 699   AS_CASE(["$enableval"],
 700     [yes],[],
 701     [no|none],[enable_storeio="no"],
 702     [
 703       enable_storeio="yes"
 704       # ufs is really always needed as it has low-level routines
 705       # if it is a dupe it will be cleaned-up later
 706       squid_storeio_module_candidates="$enableval ufs"
 707   ])
 708 ])
 709 AS_IF([test "x${enable_storeio:=yes}" = "xyes"],[
 710   SQUID_LOOK_FOR_MODULES([$srcdir/src/fs],[squid_storeio_module_candidates])
 711 ])
 712 SQUID_CLEANUP_MODULES_LIST([squid_storeio_module_candidates])
 713 SQUID_CHECK_EXISTING_MODULES([$srcdir/src/fs],[squid_storeio_module_candidates])
 714 AC_MSG_NOTICE([Store modules built: ${squid_storeio_module_candidates:-none}])
 715
 716 for fs in ${squid_storeio_module_candidates:-none}; do
 717   AS_CASE([$fs],
 718     [diskd],[
 719       AS_IF([test "x$squid_disk_module_candidates_Blocking" != "xyes" -a \
 720         "x$squid_disk_module_candidates_DiskDaemon" != "xyes"],[
 721         AC_MSG_ERROR([Storage diskd module requires DiskIO module: Blocking or DiskDaemon])
 722       ])
 723     ],
 724     [aufs],[
 725       AS_IF([test "x$squid_disk_module_candidates_Blocking" != "xyes" -a \
 726         "x$squid_disk_module_candidates_DiskThreads" != "xyes"],[
 727         AC_MSG_ERROR([Storage module aufs requires DiskIO module: Blocking or DiskThreads])
 728       ])
 729     ],
 730     [rock],[
 731       AS_IF([test "x$squid_disk_module_candidates_IpcIo" != "xyes" -a \
 732         "x$squid_disk_module_candidates_Blocking" != "xyes"],[
 733          AC_MSG_ERROR([Storage module Rock requires DiskIO module: Blocking or IpcIo])
 734       ])
 735       squid_do_build_rock=true
 736     ],
 737     [ufs],[
 738       AS_IF([test "x$squid_disk_module_candidates_Blocking" != "xyes"],[
 739         AC_MSG_ERROR([Storage module ufs requires DiskIO module: Blocking])
 740       ])
 741       squid_do_build_ufs=true
 742     ]
 743   )
 744 done
 745
 746 AM_CONDITIONAL(ENABLE_FS_UFS, test "x$squid_do_build_ufs" = "xtrue")
 747 AM_CONDITIONAL(ENABLE_FS_ROCK, test "x$squid_do_build_rock" = "xtrue")
 748 dnl hack: need to define those even if not used in the build system to
 749 dnl make sure that global FS objects are linked to the squid binary.
 750 AH_TEMPLATE(HAVE_FS_UFS, "Define to 1 if ufs filesystem module is build")
 751 AH_TEMPLATE(HAVE_FS_AUFS, "Define to 1 if aufs filesystem module is build")
 752 AH_TEMPLATE(HAVE_FS_DISKD, "Define to 1 if diskd filesystem module is build")
 753 AH_TEMPLATE(HAVE_FS_ROCK, "Define to 1 if rock filesystem module is build")
 754
 755
 756 dnl got final squid_storeio_module_candidates, build library lists
 757 dnl This list will not be needed when each fs library has its own Makefile
 758 STORE_LIBS_TO_BUILD=
 759 dnl File system libraries to link executables with.
 760 dnl These are the same as STORE_LIBS_TO_BUILD, but with a path
 761 STORE_LIBS_TO_ADD=
 762 for fs in $squid_storeio_module_candidates; do
 763     STORE_LIBS_TO_BUILD="$STORE_LIBS_TO_BUILD lib${fs}.la"
 764     STORE_LIBS_TO_ADD="$STORE_LIBS_TO_ADD fs/lib${fs}.la"
 765     SQUID_TOUPPER_VAR_CONTENTS([fs])
 766     AC_DEFINE_UNQUOTED(HAVE_FS_${fs}, 1)
 767 done
 768
 769 AC_SUBST(STORE_LIBS_TO_BUILD)
 770 AC_SUBST(STORE_LIBS_TO_ADD)
 771 AC_SUBST(STORE_TESTS)
 772
 773
 774 dnl At lest one removal policy is always needed.
 775 dnl 'lru' removal policy is currently hard-coded by name for tests
 776 dnl so we must set it as default.
 777 REPL_POLICIES="lru"
 778 AC_ARG_ENABLE(removal-policies,
 779   AS_HELP_STRING([--enable-removal-policies="list of policies"],
 780                  [Build support for the list of removal policies.
 781                   The default is only to build the "lru" module.
 782                   See src/repl for a list of available modules, or
 783                   Programmers Guide section 9.9 for details on how
 784                   to build your custom policy]), [
 785   AS_CASE(["$enableval"],
 786     [yes],[ SQUID_LOOK_FOR_MODULES([$srcdir/src/repl],[REPL_POLICIES]) ],
 787     [no],[],
 788     [ REPL_POLICIES="$enableval" ]
 789   )
 790 ])
 791 SQUID_CLEANUP_MODULES_LIST([REPL_POLICIES])
 792 SQUID_CHECK_EXISTING_MODULES([$srcdir/src/repl],[REPL_POLICIES])
 793 AC_MSG_NOTICE([Removal policies to build: $REPL_POLICIES])
 794 REPL_OBJS="repl/lib`echo \"$REPL_POLICIES\" | sed -e 's% %.a repl/lib%g'`.a"
 795 REPL_LIBS=`echo "$REPL_OBJS" | sed -e 's%repl/%%g'`
 796 AC_SUBST(REPL_POLICIES)
 797 AC_SUBST(REPL_OBJS)
 798 AC_SUBST(REPL_LIBS)
 799
 800 AM_CONDITIONAL(ENABLE_PINGER, false)
 801 AC_ARG_ENABLE(icmp,
 802   AS_HELP_STRING([--enable-icmp],[Enable ICMP pinging and Network Measurement]),[
 803   AS_IF([test "x$enableval" = "xyes"],[
 804     AC_MSG_NOTICE([ICMP enabled])
 805     AC_DEFINE(USE_ICMP,1,[Define to use Squid ICMP and Network Measurement features (highly recommended!)])
 806     AM_CONDITIONAL(ENABLE_PINGER, true)
 807   ])
 808 ])
 809
 810 AM_CONDITIONAL(ENABLE_DELAY_POOLS, false)
 811 AC_ARG_ENABLE(delay-pools,
 812   AS_HELP_STRING([--enable-delay-pools],[Enable delay pools to limit bandwidth usage]),[
 813   AS_IF([test "x$enableval" = "xyes"],[
 814     AC_MSG_NOTICE([Delay pools enabled])
 815     AC_DEFINE([USE_DELAY_POOLS],1,[Traffic management via "delay pools".])
 816     AM_CONDITIONAL(ENABLE_DELAY_POOLS, true)
 817   ])
 818 ])
 819
 820 dnl disable generic/common adaptation support by default
 821 squid_opt_use_adaptation=no
 822
 823 AH_TEMPLATE([USE_SQUID_ESI],[whether to enable ESI processing])
 824 AC_ARG_ENABLE(esi,[
 825   AS_HELP_STRING([--enable-esi],
 826                  [Enable ESI for accelerators. ESI requires expat or xml2 library.
 827                   Enabling ESI will cause squid reverse proxies to be capable
 828                   of the Edge Acceleration Specification (www.esi.org).])
 829 ],[
 830   SQUID_DEFINE_BOOL(USE_SQUID_ESI,$enable_esi)
 831 ])
 832 AC_MSG_NOTICE([Enable ESI processor: ${enable_esi:=no (auto)}])
 833
 834 # ESI support libraries: expat
 835 SQUID_AUTO_LIB(expat,[ESI expat library],[LIBEXPAT])
 836 SQUID_CHECK_LIB_WORKS(expat,[
 837   SQUID_STATE_SAVE(squid_expat_state)
 838   PKG_CHECK_MODULES([LIBEXPAT],[expat],[:],[:])
 839   CPPFLAGS="$LIBEXPAT_CFLAGS $CPPFLAGS"
 840   AC_CHECK_HEADERS(expat.h)
 841   SQUID_STATE_ROLLBACK(squid_expat_state)
 842 ])
 843
 844 # ESI support libraries: xml2
 845 AH_TEMPLATE(HAVE_LIBXML2,[Define to 1 if you have the xml2 library])
 846 SQUID_AUTO_LIB(xml2,[ESI xml2 library],[LIBXML2])
 847 AS_IF([test "x$enable_esi" = "xyes" -a "x$with_xml2" != "xno"],[
 848   SQUID_STATE_SAVE([squid_libxml2_save])
 849   PKG_CHECK_MODULES([LIBXML2],[libxml-2.0],[],[
 850     AC_CHECK_LIB([xml2],[main],[LIBXML2_LIBS="$LIBXML2_PATH -lxml2"])
 851   ])
 852   CPPFLAGS="$LIBXML2_CFLAGS $CPPFLAGS"
 853   AC_CHECK_HEADERS(libxml/parser.h libxml/HTMLparser.h libxml/HTMLtree.h)
 854   SQUID_STATE_ROLLBACK([squid_libxml2_save])
 855
 856   AS_IF([test "x$LIBXML2_LIBS" != "x"],[
 857     CPPFLAGS="$LIBXML2_CFLAGS $CPPFLAGS"
 858     LIBXML2_LIBS="$LIBXML2_PATH $LIBXML2_LIBS"
 859     AC_DEFINE(HAVE_LIBXML2,1,[Define to 1 if you have the xml2 library])
 860   ],[test "x$with_xml2" = "xyes"],[
 861     AC_MSG_ERROR([Required library xml2 not found])
 862   ],[
 863     AC_MSG_NOTICE([Library xml2 not found.])
 864   ])
 865 ])
 866 AM_CONDITIONAL(ENABLE_LIBXML2,[test "x$LIBXML2_LIBS" != "x"])
 867 AC_SUBST(LIBXML2_LIBS)
 868
 869 AS_IF([test "x$enable_esi" = "xyes" -a "x$LIBXML2_LIBS" = "x" -a "x$LIBEXPAT_LIBS" = "x"],[
 870   AC_MSG_ERROR([ESI processor requires libxml2 or libexpat])
 871 ])
 872 AM_CONDITIONAL(ENABLE_ESI,[test "x$enable_esi" = "xyes"])
 873
 874 AC_ARG_ENABLE(icap-client,
 875   AS_HELP_STRING([--disable-icap-client],[Disable the ICAP client.]),[
 876   SQUID_YESNO([$enableval],[--enable-icap-client])
 877 ])
 878 SQUID_DEFINE_BOOL(ICAP_CLIENT,${enable_icap_client:=yes}, [Enable ICAP client features in Squid])
 879 AS_IF(test "x$enable_icap_client" != "xno", squid_opt_use_adaptation="yes")
 880 AM_CONDITIONAL(ENABLE_ICAP_CLIENT, test "x$enable_icap_client" != "xno")
 881
 882 AC_ARG_ENABLE(ecap,
 883   AS_HELP_STRING([--enable-ecap],[support loadable content adaptation modules]),[
 884   SQUID_YESNO([$enableval],[--enable-ecap])],[
 885   enable_ecap="no"
 886 ])
 887 dnl Perform configuration consistency checks for eCAP
 888 AS_IF([test "x$enable_ecap" != "xno"],[
 889   AS_IF([test "x$enable_shared" != "xyes"],[
 890     AC_MSG_ERROR([eCAP support requires loadable modules. Please do not use --disable-shared with --enable-ecap.])
 891   ])
 892
 893   AS_IF([test -n "$PKG_CONFIG"],[
 894     dnl eCAP support requires libecap.
 895     dnl This Squid supports libecap v1.0.x.
 896     dnl Use EXT_ prefix to distinguish external libecap (that we check for
 897     dnl here) from our own convenience ecap library in Makefiles.
 898     PKG_CHECK_MODULES([EXT_LIBECAP],[libecap >= 1.0 libecap < 1.1])
 899   ],[
 900     AC_MSG_NOTICE([eCAP support requires pkg-config to verify the correct library version. Trouble may follow.])
 901   ])
 902
 903   SQUID_STATE_SAVE(squid_ecap_state)
 904   AC_MSG_CHECKING([whether -lecap will link])
 905   CXXFLAGS="$CXXFLAGS $EXT_LIBECAP_CFLAGS"
 906   LIBS="$LIBS $EXT_LIBECAP_LIBS"
 907   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <libecap/common/names.h>]],[[
 908     const libecap::Name test("test", libecap::Name::NextId());
 909   ]])],[
 910     AC_MSG_RESULT(yes)
 911     squid_opt_use_adaptation=yes
 912   ],[
 913     AC_MSG_RESULT(no)
 914     AS_IF([test "x$enable_ecap" = "xyes"],[
 915       AC_MSG_ERROR([eCAP library will not link.
 916                   You may need to rebuild libecap using the same version of GCC as Squid.
 917                   There have been breaking ABI changes in the libstdc++ STL with GCC 5.])
 918     ],[
 919       AC_MSG_NOTICE([eCAP library will not link.
 920                   You may need to rebuild libecap using the same version of GCC as Squid.
 921                   There have been breaking ABI changes in the libstdc++ STL with GCC 5.])
 922       enable_ecap="no"
 923     ])
 924   ])
 925   SQUID_STATE_ROLLBACK(squid_ecap_state)
 926 ])
 927 SQUID_DEFINE_BOOL(USE_ECAP,${enable_ecap:=no},[Whether to use eCAP support])
 928 AM_CONDITIONAL(ENABLE_ECAP, test "x$enable_ecap" = "xyes")
 929
 930 dnl enable adaptation if requested by specific adaptation mechanisms
 931 ADAPTATION_LIBS=""
 932 AS_IF([test "x$squid_opt_use_adaptation" = "xyes"],[ADAPTATION_LIBS="adaptation/libadaptation.la"])
 933 SQUID_DEFINE_BOOL(USE_ADAPTATION,${squid_opt_use_adaptation:=no}, [common adaptation support])
 934 AM_CONDITIONAL(ENABLE_ADAPTATION, test "x$squid_opt_use_adaptation" = "xyes")
 935 AC_SUBST(ADAPTATION_LIBS)
 936
 937 AS_IF([test "x$squid_host_os" = "xmingw"],[enable_wccp=no])
 938 AC_ARG_ENABLE(wccp,
 939   AS_HELP_STRING([--disable-wccp],[Disable Web Cache Coordination Protocol]),[
 940   SQUID_YESNO([$enableval],[--enable-wccp])
 941 ])
 942 SQUID_DEFINE_BOOL(USE_WCCP, ${enable_wccp:=yes}, [Define to enable WCCP])
 943 AC_MSG_NOTICE([Web Cache Coordination Protocol enabled: $enable_wccp])
 944
 945 AS_IF([test "x$squid_host_os" = "xmingw"],[enable_wccpv2=no])
 946 AC_ARG_ENABLE(wccpv2,
 947   AS_HELP_STRING([--disable-wccpv2],
 948                  [Disable Web Cache Coordination V2 Protocol]), [
 949   SQUID_YESNO([$enableval],[--enable-wccpv2])
 950 ])
 951 SQUID_DEFINE_BOOL(USE_WCCPv2,${enable_wccpv2:=yes},
 952             [Define to enable WCCP V2])
 953 AC_MSG_NOTICE([Web Cache Coordination V2 Protocol enabled: $enable_wccpv2])
 954
 955 AC_ARG_ENABLE(snmp,
 956   AS_HELP_STRING([--disable-snmp],[Disable SNMP monitoring support]), [
 957   SQUID_YESNO([$enableval],[--enable-snmp])
 958 ])
 959 SQUID_DEFINE_BOOL(SQUID_SNMP,${enable_snmp:=yes},
 960    [Define to enable SNMP monitoring of Squid])
 961 AM_CONDITIONAL(ENABLE_SNMP, [test "x$enable_snmp" = "xyes"])
 962 AS_IF([test "x$enable_snmp" = "xyes"],[SNMPLIB="../lib/snmplib/libsnmplib.la"])
 963 AC_MSG_NOTICE([SNMP support enabled: $enable_snmp])
 964 AC_SUBST(SNMPLIB)
 965
 966 AC_ARG_ENABLE(eui,
 967   AS_HELP_STRING([--disable-eui],
 968                  [Disable use of ARP / MAC/ EUI (ether address)]), [
 969   SQUID_YESNO([$enableval],[--enable-eui])
 970 ])
 971 AS_IF([test "x${enable_eui:=yes}" = "xyes"],[
 972   SQUID_STATE_SAVE(LIBEUI)
 973   # GLIBC 2.30 deprecates sysctl.h. Test with the same flags that (may) break includes later.
 974   CFLAGS=$SQUID_CFLAGS
 975   CXXFLAGS=$SQUID_CXXFLAGS
 976   AS_CASE(["$squid_host_os"],
 977     [linux|solaris|freebsd|openbsd|netbsd|cygwin],[:],
 978     [mingw],[EUILIB="-liphlpapi"],
 979     [AC_MSG_WARN([EUI support probably will not work on host $host.])]
 980   )
 981   # iphlpapi.h check delayed after winsock2.h
 982   AC_CHECK_HEADERS( \
 983     windows.h \
 984     sys/sockio.h \
 985     sys/param.h,
 986   [], [], [[
 987 #if HAVE_WINDOWS_H
 988 include <windows.h>
 989 #endif
 990 ]]
 991   )
 992   AC_CHECK_HEADERS( \
 993     net/if_arp.h \
 994     net/route.h,
 995   [], [], [[
 996 #include <sys/types.h>
 997 #include <sys/socket.h>
 998 ]])
 999
1000   # OpenBSD, FreeBSD and NetBSD requires sys/param.h to be included before sysctl.h and net/if_dl.h
1001   AC_CHECK_HEADERS( \
1002     net/if_dl.h \
1003     sys/sysctl.h,
1004   [], [], [[
1005 #if HAVE_SYS_PARAM_H
1006 #include <sys/param.h>
1007 #endif
1008   ]])
1009   SQUID_STATE_ROLLBACK(LIBEUI)
1010 ])
1011 AC_SUBST(EUILIB)
1012 AC_MSG_NOTICE([EUI (MAC address) controls enabled: $enable_eui])
1013 SQUID_DEFINE_BOOL(USE_SQUID_EUI,$enable_eui,
1014    [Define this to include code which lets you use ethernet addresses. This code uses API initially defined in 4.4-BSD.])
1015 AM_CONDITIONAL(ENABLE_EUI, [test "x$enable_eui" = "xyes" ])
1016
1017
1018 AC_ARG_ENABLE(htcp,
1019   AS_HELP_STRING([--disable-htcp],[Disable HTCP protocol support]), [
1020   SQUID_YESNO([$enableval],[--enable-htcp])
1021 ])
1022 SQUID_DEFINE_BOOL(USE_HTCP,${enable_htcp:=yes},
1023    [Define this to include code for the Hypertext Cache Protocol (HTCP)])
1024 AM_CONDITIONAL(ENABLE_HTCP, [test "x$enable_htcp" = "xyes"])
1025 AC_MSG_NOTICE([HTCP support enabled: $enable_htcp])
1026
1027 # Cryptograhic libraries
1028 SQUID_AUTO_LIB(nettle,[Nettle crypto],[LIBNETTLE])
1029 SQUID_CHECK_LIB_WORKS(nettle,[
1030   SQUID_STATE_SAVE(squid_nettle_state)
1031   PKG_CHECK_MODULES([LIBNETTLE],[nettle >= 3.4],[
1032     CPPFLAGS="$LIBNETTLE_CFLAGS $CPPFLAGS"
1033     AC_CHECK_HEADERS(nettle/base64.h nettle/md5.h)
1034   ],[:])
1035   SQUID_STATE_ROLLBACK(squid_nettle_state)
1036 ])
1037
1038 dnl Check for libcrypt
1039 CRYPTLIB=
1040 dnl Some of our helpers use crypt(3) which may be in libc, or in
1041 dnl libcrypt (eg FreeBSD)
1042 AC_CHECK_LIB(crypt, crypt, [CRYPTLIB="-lcrypt"])
1043 dnl Solaris10 provides MD5 natively through libmd5
1044 AC_CHECK_LIB(md5, MD5Init, [CRYPTLIB="$CRYPTLIB -lmd5"])
1045 AC_SUBST(CRYPTLIB)
1046
1047 SQUID_AUTO_LIB(gnutls,[GnuTLS crypto],[LIBGNUTLS])
1048 SQUID_CHECK_LIB_WORKS(gnutls,[
1049   SQUID_STATE_SAVE(squid_gnutls_state)
1050   PKG_CHECK_MODULES([LIBGNUTLS],[gnutls >= 3.4.0],[
1051     CPPFLAGS="$LIBGNUTLS_CFLAGS $CPPFLAGS"
1052     AC_CHECK_HEADERS(gnutls/gnutls.h gnutls/x509.h gnutls/abstract.h)
1053   ],[:])
1054   SQUID_STATE_ROLLBACK(squid_gnutls_state)
1055 ])
1056
1057 SSLLIB=""
1058 dnl User may specify OpenSSL is needed from a non-standard location
1059 SQUID_OPTIONAL_LIB(openssl,[OpenSSL],[LIBOPENSSL])
1060 AH_TEMPLATE(USE_OPENSSL,[OpenSSL support is available])
1061 ## OpenSSL is default disable due to licensing issues on some OS
1062 AS_IF([test "x$with_openssl" = "xyes"],[
1063   CPPFLAGS="$LIBOPENSSL_CFLAGS $CPPFLAGS"
1064   AC_CHECK_HEADERS( \
1065     openssl/asn1.h \
1066     openssl/bio.h \
1067     openssl/bn.h \
1068     openssl/crypto.h \
1069     openssl/decoder.h \
1070     openssl/dh.h \
1071     openssl/err.h \
1072     openssl/evp.h \
1073     openssl/lhash.h \
1074     openssl/md5.h \
1075     openssl/opensslv.h \
1076     openssl/rsa.h \
1077     openssl/ssl.h \
1078     openssl/x509.h \
1079     openssl/x509v3.h \
1080     openssl/engine.h \
1081     openssl/txt_db.h \
1082     openssl/pem.h \
1083   )
1084
1085   # User may have provided a custom location for OpenSSL. Otherwise...
1086   SQUID_STATE_SAVE(squid_openssl_state)
1087   LIBS="$LIBS $LIBOPENSSL_PATH"
1088
1089   # auto-detect using pkg-config
1090   PKG_CHECK_MODULES([LIBOPENSSL],[openssl],,[
1091     ## For some OS pkg-config is broken or unavailable.
1092     ## Detect libraries the hard way.
1093
1094     # Windows MinGW has some special libraries ...
1095     AS_IF([test "x$squid_host_os" = "xmingw"],[
1096       LIBOPENSSL_LIBS='-lssleay32 -leay32 -lgdi32 $LIBOPENSSL_LIBS'
1097       AC_MSG_NOTICE([Windows OpenSSL library support: yes -lssleay32 -leay32 -lgdi32])
1098     ])
1099
1100     AC_CHECK_LIB(crypto,[CRYPTO_new_ex_data],[LIBOPENSSL_LIBS="-lcrypto $LIBOPENSSL_LIBS"],[
1101       AC_MSG_ERROR([library 'crypto' is required for OpenSSL])
1102     ],$LIBOPENSSL_LIBS)
1103     AC_CHECK_LIB(ssl,[SSL_CTX_new],[LIBOPENSSL_LIBS="-lssl $LIBOPENSSL_LIBS"],[
1104       AC_MSG_ERROR([library 'ssl' is required for OpenSSL])
1105     ],$LIBOPENSSL_LIBS)
1106   ])
1107
1108   SQUID_STATE_ROLLBACK(squid_openssl_state) #de-pollute LIBS
1109
1110   AS_IF([test "x$LIBOPENSSL_LIBS" != "x"],[
1111     CXXFLAGS="$LIBOPENSSL_CFLAGS $CXXFLAGS"
1112     SSLLIB="$LIBOPENSSL_PATH $LIBOPENSSL_LIBS $SSLLIB"
1113     AC_DEFINE(USE_OPENSSL,1,[OpenSSL support is available])
1114
1115     # check for API functions
1116     SQUID_CHECK_LIBCRYPTO_API
1117     SQUID_CHECK_LIBSSL_API
1118     SQUID_CHECK_OPENSSL_TLS_METHODS
1119     SQUID_STATE_SAVE(check_SSL_CTX_get0_certificate)
1120     LIBS="$LIBS $SSLLIB"
1121     AC_CHECK_LIB(ssl, SSL_CTX_get0_certificate, [
1122       AC_DEFINE(HAVE_SSL_CTX_GET0_CERTIFICATE, 1, [SSL_CTX_get0_certificate is available])
1123       ], [
1124           missing_SSL_CTX_get0_certificate=yes
1125       ])
1126     SQUID_STATE_ROLLBACK(check_SSL_CTX_get0_certificate)
1127
1128     # check for other specific broken implementations
1129     AS_IF([test "x$missing_SSL_CTX_get0_certificate" = "xyes"],SQUID_CHECK_OPENSSL_GETCERTIFICATE_WORKS)
1130     SQUID_CHECK_OPENSSL_CONST_SSL_METHOD
1131     SQUID_CHECK_OPENSSL_CONST_CRYPTO_EX_DATA
1132     SQUID_CHECK_OPENSSL_CONST_SSL_SESSION_CB_ARG
1133     SQUID_CHECK_OPENSSL_CONST_X509_GET0_SIGNATURE_ARGS
1134     SQUID_CHECK_OPENSSL_TXTDB
1135   ])
1136   AS_IF([test "x$SSLLIB" = "x"],[AC_MSG_ERROR([Required OpenSSL library not found])])
1137 ])
1138 AC_MSG_NOTICE([OpenSSL library support: ${with_openssl:=no} ${LIBOPENSSL_PATH} ${LIBOPENSSL_LIBS}])
1139 AM_CONDITIONAL(ENABLE_SSL,[ test "x$with_openssl" = "xyes" ])
1140 AC_SUBST(SSLLIB)
1141
1142 # Kerberos support libraries: MIT
1143 SQUID_AUTO_LIB(mit-krb5,[MIT Kerberos],[LIB_KRB5])
1144 AH_TEMPLATE(USE_APPLE_KRB5,[Apple Kerberos support is available])
1145 AH_TEMPLATE(USE_SOLARIS_KRB5,[Solaris Kerberos support is available])
1146 SQUID_CHECK_LIB_WORKS(mit-krb5,[
1147   SQUID_STATE_SAVE(squid_mit_krb5_save)
1148   AS_IF([test "x$squid_host_os" = "xsolaris"],[
1149     # pkg-config not available for Solaris krb5 implementation
1150     SQUID_CHECK_SOLARIS_KRB5
1151   ],[
1152     PKG_CHECK_MODULES([LIBMIT_KRB5],[mit-krb5 mit-krb5-gssapi],[
1153       AS_IF([test "x$squid_host_os" = "xdarwin"],[
1154         AC_DEFINE(USE_APPLE_KRB5,1,[Apple Kerberos support is available])
1155         AC_CHECK_LIB(resolv,[main],[LIBMIT_KRB5_LIBS="$LIBMIT_KRB5_LIBS -lresolv"],[
1156           AC_MSG_ERROR([library 'resolv' is required for Apple Kerberos])
1157         ])
1158       ])
1159       CPPFLAGS="$LIBMIT_KRB5_CFLAGS $CPPFLAGS"
1160       LIBS="$LIBMIT_KRB5_PATH $LIBMIT_KRB5_LIBS $LIBS"
1161       AC_CHECK_HEADERS(gssapi.h gssapi/gssapi.h gssapi/gssapi_krb5.h)
1162       AC_CHECK_HEADERS(gssapi/gssapi_ext.h gssapi/gssapi_generic.h)
1163       AC_CHECK_HEADERS(krb5.h com_err.h et/com_err.h)
1164       AC_CHECK_HEADERS(profile.h)
1165       SQUID_CHECK_KRB5_FUNCS
1166     ],[:])
1167   ])
1168   SQUID_STATE_ROLLBACK(squid_mit_krb5_save)
1169 ])
1170
1171 # Kerberos support libraries: Heimdal
1172 SQUID_AUTO_LIB(heimdal-krb5,[Heimdal Kerberos],[LIBHEIMDAL_KRB5])
1173 SQUID_CHECK_LIB_WORKS(heimdal-krb5,[
1174   AS_IF([test "x$LIBMIT_KRB5_LIBS" = "x"],[
1175     SQUID_STATE_SAVE(squid_heimdal_krb5_save)
1176     PKG_CHECK_MODULES([LIBHEIMDAL_KRB5],[heimdal-krb5 heimdal-gssapi],[
1177       CPPFLAGS="$LIBHEIMDAL_KRB5_CFLAGS $CPPFLAGS"
1178       AC_CHECK_HEADERS(gssapi.h gssapi/gssapi.h gssapi/gssapi_krb5.h)
1179       AC_CHECK_HEADERS(krb5.h com_err.h et/com_err.h)
1180
1181       LIBS="$LIBHEIMDAL_KRB5_PATH $LIBHEIMDAL_KRB5_LIBS $LIBS"
1182       SQUID_CHECK_KRB5_HEIMDAL_BROKEN_KRB5_H
1183       SQUID_CHECK_KRB5_FUNCS
1184     ],[:])
1185     SQUID_STATE_ROLLBACK(squid_heimdal_krb5_save)
1186   ])
1187 ])
1188
1189 # Kerberos support libraries: GNU GSS
1190 SQUID_AUTO_LIB(gss,[GNU gss],[LIBGSS])
1191 SQUID_CHECK_LIB_WORKS(gss,[
1192   AS_IF([test "x$LIBMIT_KRB5_LIBS" = "x" -a "x$LIBHEIMDAL_KRB5_LIBS" = "x"],[
1193     SQUID_STATE_SAVE(squid_gss_save)
1194     PKG_CHECK_MODULES([LIBGSS],[gss],[
1195       CPPFLAGS="$LIBGSS_CFLAGS $CPPFLAGS"
1196       AC_CHECK_HEADERS(gss.h)
1197       LIBS="$LIBGSS_PATH $LIBS"
1198       SQUID_CHECK_WORKING_GSSAPI
1199       SQUID_DEFINE_BOOL(HAVE_GSSAPI,$squid_cv_working_gssapi,[GSSAPI support])
1200       SQUID_CHECK_SPNEGO_SUPPORT
1201       SQUID_DEFINE_BOOL(HAVE_SPNEGO,$squid_cv_have_spnego,[SPNEGO support])
1202       SQUID_CHECK_WORKING_KRB5
1203       SQUID_DEFINE_BOOL(HAVE_KRB5,$squid_cv_working_krb5,[KRB5 support])
1204     ],[:])
1205     SQUID_STATE_ROLLBACK(squid_gss_save)
1206   ])
1207 ])
1208
1209 SQUID_AUTO_LIB(ldap,[LDAP],[LIBLDAP])
1210 SQUID_CHECK_LIB_WORKS(ldap,[
1211   dnl On MinGW OpenLDAP is not available, so LDAP helpers can be linked
1212   dnl only with Windows LDAP libraries using -lwldap32
1213   AS_IF([test "$squid_host_os" = "mingw"],[
1214     LIBLDAP_LIBS="-lwldap32"
1215   ],[
1216     SQUID_STATE_SAVE(squid_ldap_state)
1217     LIBS="$LIBLDAP_PATH $LIBPTHREADS $LIBS"
1218     PKG_CHECK_MODULES([LIBLDAP],[ldap],[],[
1219       AC_CHECK_LIB(lber, ber_init, [LIBLBER="-llber"])
1220       AC_CHECK_LIB(ldap, ldap_init, [LIBLDAP_LIBS="-lldap $LIBLBER"])
1221       dnl if no ldap lib found check for mozilla version
1222       AS_IF([test "x$ac_cv_lib_ldap_ldap_init" != "xyes"],[
1223         SQUID_STATE_SAVE(squid_ldap_mozilla)
1224         LIBS="$LIBLDAP_PATH $LIBPTHREADS"
1225         AC_CHECK_LIB(ldap60, ldap_init, [LIBLDAP_LIBS="-lldap60 $LIBLBER"])
1226         LIBS="$LIBLDAP_PATH $LIBLDAP_LIBS $LIBPTHREADS"
1227         AC_CHECK_LIB(prldap60, prldap_init, [LIBLDAP_LIBS="-lprldap60 $LIBLDAP_LIBS"])
1228         LIBS="$LIBLDAP_PATH $LIBLDAP_LIBS $LIBPTHREADS"
1229         AC_CHECK_LIB(ssldap60, ldapssl_init, [LIBLDAP_LIBS="-lssldap60 $LIBLDAP_LIBS"])
1230         SQUID_STATE_ROLLBACK(squid_ldap_mozilla)
1231       ])
1232     ])
1233     AC_CHECK_HEADERS(ldap.h lber.h)
1234     AC_CHECK_HEADERS(mozldap/ldap.h)
1235     SQUID_CHECK_LDAP_API
1236   ])
1237 ])
1238
1239 SQUID_AUTO_LIB(systemd,[systemd API for start-up notification],[LIBSYSTEMD])
1240 SQUID_CHECK_LIB_WORKS(systemd,[
1241   SQUID_STATE_SAVE(squid_systemd_state)
1242   LIBS="$LIBS $LIBSYSTEMD_PATH"
1243   PKG_CHECK_MODULES(LIBSYSTEMD,[libsystemd >= 209],[
1244     AC_CHECK_HEADERS(systemd/sd-daemon.h)
1245   ],[:])
1246   SQUID_STATE_ROLLBACK(squid_systemd_state)
1247 ])
1248
1249 AC_ARG_ENABLE(forw-via-db,
1250   AS_HELP_STRING([--enable-forw-via-db],[Enable Forw/Via database]), [
1251   SQUID_YESNO([$enableval],[--enable-forw-via-db])
1252 ])
1253 SQUID_DEFINE_BOOL(USE_FORW_VIA_DB,${enable_forw_via_db:=no},
1254                       [Enable Forw/Via database])
1255 AC_MSG_NOTICE([Forw/Via database enabled: $enable_forw_via_db])
1256
1257 AC_ARG_ENABLE(cache-digests,
1258   AS_HELP_STRING([--enable-cache-digests],
1259    [Use Cache Digests. See https://wiki.squid-cache.org/SquidFaq/CacheDigests]),[
1260   SQUID_YESNO([$enableval],[--enable-cache-digests])
1261 ])
1262 SQUID_DEFINE_BOOL(USE_CACHE_DIGESTS,${enable_cache_digests:=no},
1263   [Use Cache Digests for locating objects in neighbor caches.])
1264 AC_MSG_NOTICE([Cache Digests enabled: $enable_cache_digests])
1265
1266
1267 ################################
1268 # check for netio plugin stuff #
1269 ################################
1270 dnl order of these options handling is relevant in case the user
1271 dnl supplies more than one --enable option. Options handled later
1272 dnl override those handled earlier for io loop method manual override
1273 AC_ARG_ENABLE(select,
1274   AS_HELP_STRING([--disable-select],[Disable select(2) support.]),[
1275   SQUID_YESNO([$enableval],[--enable-select])
1276   AS_IF([test "x$enableval" = "xyes"],[squid_opt_io_loop_engine="select"])
1277 ])
1278 AC_MSG_NOTICE([enabling select syscall for net I/O: ${enable_select:=auto}])
1279
1280 AC_ARG_ENABLE(poll,
1281   AS_HELP_STRING([--disable-poll],[Disable poll(2) support.]),[
1282   SQUID_YESNO([$enableval],[--enable-poll])
1283   AS_IF([test "x$enableval" = "xyes"],[squid_opt_io_loop_engine="poll"])
1284 ])
1285 AC_MSG_NOTICE([enabling poll syscall for net I/O: ${enable_poll:=auto}])
1286
1287 AC_ARG_ENABLE(kqueue,
1288   AS_HELP_STRING([--disable-kqueue],
1289                  [Disable kqueue(2) support.]), [
1290   SQUID_YESNO([$enableval],[--enable-kqueue])
1291 ])
1292 AS_IF([test "x${enable_kqueue:=auto}" != "xno"],[
1293   AC_CHECK_HEADERS([sys/event.h],[],[
1294     AS_IF([test "x${enable_kqueue}" = "xyes"],[
1295       AC_MSG_ERROR([kqueue support requires sys/event.h header file.])
1296     ])
1297   ])
1298   AC_CHECK_FUNCS(kqueue,[],[
1299     AS_IF([test "x${enable_kqueue}" = "xyes"],[
1300       AC_MSG_ERROR([kqueue support missing in libc library.])
1301     ])
1302   ])
1303   AS_IF([test "x$ac_cv_func_kqueue" = "xyes" -a "x$ac_cv_header_sys_event_h" = "xyes"],[
1304     squid_opt_io_loop_engine="kqueue"
1305   ],[
1306     enable_kqueue="no"
1307   ])
1308 ])
1309 AC_MSG_NOTICE([enabling kqueue for net I/O: ${enable_kqueue:=auto}])
1310
1311 dnl Enable epoll()
1312 AC_ARG_ENABLE(epoll,
1313   AS_HELP_STRING([--disable-epoll],[Disable Linux epoll(2) support.]),
1314 [
1315   SQUID_YESNO([$enableval],[--enable-epoll])
1316 AS_IF([test "x$enableval" = "xyes"],[squid_opt_io_loop_engine="epoll"])
1317 ])
1318 AC_MSG_NOTICE([enabling epoll syscall for net I/O: ${enable_epoll:=auto}])
1319
1320 # auto-detect and verify epoll header and library present and working
1321 # logic mapping and loop method selection are performed later
1322 AS_IF([test "x$enable_epoll" != "xno"],[
1323   # check if libs are needed to support epoll
1324   SQUID_STATE_SAVE(squid_epoll_state)
1325   AC_SEARCH_LIBS(epoll_ctl,[epoll])
1326   AS_IF([test "x$ac_cv_search_epoll_ctl" = "xno"],[enable_epoll=no],
1327     [test "x$ac_cv_search_epoll_ctl" = "xnone required"],[EPOLL_LIBS=""],
1328     [EPOLL_LIBS=$ac_cv_search_epoll_ctl]
1329   )
1330   AC_SUBST(EPOLL_LIBS)
1331   SQUID_STATE_ROLLBACK(squid_epoll_state) #de-pollute LIBS
1332
1333   # epoll requires sys/epoll.h
1334   AC_CHECK_HEADERS([sys/epoll.h])
1335
1336   dnl Verify that epoll really works
1337   AS_IF([test "x$ac_cv_search_epoll_ctl" != "xno"], SQUID_CHECK_EPOLL)
1338
1339   AS_IF([test "x$enable_epoll" = "xyes" -a "x$squid_cv_epoll_works" = "xno"],[
1340     AC_MSG_ERROR([Epoll does not work. Force-enabling it is not going to help.])
1341   ])
1342 ])
1343
1344 dnl Enable /dev/poll
1345 AC_ARG_ENABLE(devpoll,
1346   AS_HELP_STRING([--disable-devpoll],[Disable Solaris /dev/poll support.]),[
1347   SQUID_YESNO([$enableval],[--enable-devpoll])
1348   AS_IF([test "x$enableval" = "xyes"],[squid_opt_io_loop_engine="devpoll"])
1349 ])
1350 AC_MSG_NOTICE([enabling /dev/poll for net I/O: ${enable_devpoll:=auto}])
1351
1352 ## auto-detect and verify devpoll header and library present and working
1353 AS_IF([test "x$enable_devpoll" != "xno"],[
1354   # /dev/poll requires ioctl() and write()
1355   AC_CHECK_FUNCS(ioctl)
1356   AC_CHECK_FUNCS(write)
1357
1358   # /dev/poll requires sys/devpoll.h
1359   AC_CHECK_HEADERS([sys/devpoll.h],,[
1360     AS_IF([test "x$enable_devpoll" = "xyes"],[
1361       AC_MSG_ERROR([--enable-devpoll specified but /dev/poll headers not found])
1362     ])
1363     enable_devpoll=no
1364   ])
1365
1366   # Verify that /dev/poll really works
1367   AS_IF([test "x$enable_devpoll" != "xno"], SQUID_CHECK_DEVPOLL)
1368
1369   AS_IF([test "x$enable_devpoll" = "xyes" -a "x$squid_cv_devpoll_works" = "xno"],[
1370     AC_MSG_ERROR([/dev/poll does not work. Force-enabling it is not going to help.])
1371   ])
1372 ])
1373
1374 AC_ARG_ENABLE(http-violations,
1375   AS_HELP_STRING([--disable-http-violations],
1376                  [This allows you to remove code which is known to
1377                   violate the HTTP protocol specification.]), [
1378   SQUID_YESNO([$enableval],[--enable-http-violations])
1379 ])
1380 SQUID_DEFINE_BOOL(USE_HTTP_VIOLATIONS, ${enable_http_violations:=yes},
1381   [Define to enable code which volates the HTTP standard specification])
1382 AC_MSG_NOTICE([HTTP violations support enabled: $enable_http_violations])
1383
1384 # IPFW Transparent Proxy
1385 AC_ARG_ENABLE(ipfw-transparent,
1386   AS_HELP_STRING([--enable-ipfw-transparent],
1387                  [Enable Transparent Proxy support for systems
1388                   using FreeBSD IPFW-style firewalling.]), [
1389   SQUID_YESNO([$enableval],[--enable-ipfw-transparent])
1390 ])
1391 SQUID_DEFINE_BOOL(IPFW_TRANSPARENT,${enable_ipfw_transparent:=no},
1392   [Enable support for Transparent Proxy on systems using FreeBSD IPFW-style firewalling.])
1393 AC_MSG_NOTICE([FreeBSD IPFW-based transparent proxying enabled: $enable_ipfw_transparent])
1394
1395 # IP-Filter Transparent Proxy
1396 AC_ARG_ENABLE(ipf-transparent,
1397   AS_HELP_STRING([--enable-ipf-transparent],
1398      [Enable Transparent Proxy support using IPFilter-style firewalling]), [
1399   SQUID_YESNO([$enableval],[--enable-ipf-transparent])
1400 ])
1401 #will be AC_DEFINEd later, after checking for appropriate infrastructure
1402 #IPF currently broken. Default-disabled for now.
1403 AC_MSG_NOTICE([IPF-based transparent proxying requested: ${enable_ipf_transparent:=no}])
1404
1405 dnl Enable PF Transparent Proxy
1406 AC_ARG_ENABLE(pf-transparent,
1407   AS_HELP_STRING([--enable-pf-transparent],
1408     [Enable Transparent Proxy support for systems using PF network address redirection.]), [
1409   SQUID_YESNO([$enableval],[--enable-pf-transparent])
1410 ])
1411 #will be AC_DEFINEd later, after checking for appropriate infrastructure
1412 AC_MSG_NOTICE([PF-based transparent proxying requested: ${enable_pf_transparent:=no}])
1413
1414 dnl Enable /dev/pf support for older PF Transparent Proxy systems (OpenBSD 4.x and older)
1415 AC_ARG_WITH(nat-devpf,
1416   AS_HELP_STRING([--with-nat-devpf],
1417     [Enable /dev/pf support for NAT on older OpenBSD and FreeBSD kernels.]), [
1418   SQUID_YESNO([$withval],[--with-nat-devpf])
1419 ])
1420 #will be AC_DEFINEd later, after checking for appropriate infrastructure
1421 AC_MSG_NOTICE([NAT lookups via /dev/pf: ${with_nat_devpf:=no}])
1422
1423 # Linux Netfilter Transparent Proxy
1424 AC_ARG_ENABLE(linux-netfilter,
1425   AS_HELP_STRING([--enable-linux-netfilter],
1426                  [Enable Transparent Proxy support for Linux (Netfilter)]), [
1427   SQUID_YESNO([$enableval],[--enable-linux-netfilter])
1428 ])
1429 AC_MSG_NOTICE([Linux Netfilter support requested: ${enable_linux_netfilter:=auto}])
1430 #will be AC_DEFINEd later, after checking for appropriate infrastructure
1431
1432
1433 dnl Look for libnetfilter_conntrack options (needed for QOS netfilter marking)
1434 SQUID_AUTO_LIB(netfilter-conntrack,[Netfilter conntrack],[LIBNETFILTER_CONNTRACK])
1435 SQUID_CHECK_LIB_WORKS(netfilter-conntrack,[
1436   SQUID_STATE_SAVE(squid_netfilter_conntrack_state)
1437   PKG_CHECK_MODULES([LIBNETFILTER_CONNTRACK],[libnetfilter_conntrack],[:],[:])
1438   CPPFLAGS="$LIBNETFILTER_CONNTRACK_CFLAGS $CPPFLAGS"
1439   LIBS="$LIBNETFILTER_CONNTRACK_PATH $LIBNETFILTER_CONNTRACK_LIBS $LIBS"
1440   AC_CHECK_HEADERS([ \
1441     libnetfilter_conntrack/libnetfilter_conntrack.h \
1442     libnetfilter_conntrack/libnetfilter_conntrack_tcp.h \
1443   ])
1444   SQUID_STATE_ROLLBACK(squid_netfilter_conntrack_state)
1445 ])
1446
1447 dnl Enable Large file support
1448 buildmodel=""
1449
1450 AC_ARG_WITH(large-files,
1451   AS_HELP_STRING([--with-large-files],[Enable support for large files (logs etc).]), [
1452   SQUID_YESNO([$withval],[--with-large-files])
1453   squid_opt_enable_large_files=$withval
1454 ])
1455
1456 dnl UNIX Build environment
1457 dnl AS_HELP_STRING is not suited here because it cannot to specify newlines
1458 AC_ARG_WITH(build-environment,
1459  AS_HELP_STRING([--with-build-environment=model],
1460      [The build environment to use. Normally one of
1461       POSIX_V6_ILP32_OFF32 (32 bits),
1462       POSIX_V6_ILP32_OFFBIG (32 bits with large file support),
1463       POSIX_V6_LP64_OFF64 (64 bits),
1464       POSIX_V6_LPBIG_OFFBIG (large pointers and files),
1465       XBS5_ILP32_OFF32 i(legacy, 32 bits),
1466       XBS5_ILP32_OFFBIG (legacy, 32 bits with large file support),
1467       XBS5_LP64_OFF64 (legacy, 64 bits),
1468       XBS5_LPBIG_OFFBIG (legacy, large pointers and files)
1469       or default (The default for your OS)]), [
1470   AS_CASE(["$withval"],
1471     [yes|no],[AC_MSG_FAILURE([--with-build-environment expects a build environment string as used by getconf])],
1472     [buildmodel="$withval"]
1473   )
1474 ])
1475
1476 #hack. Let's early-detect sizeof(long)
1477 AC_CHECK_SIZEOF(long)
1478
1479 AS_IF([test "x$squid_opt_enable_large_files" = "xyes" -a "x$buildmodel" = "x"],[
1480   for model in POSIX_V6_LPBIG_OFFBIG XBS5_LPBIG_OFFBIG POSIX_V6_LP64_OFF64 XBS5_LP64_OFF64 POSIX_V6_ILP32_OFFBIG XBS5_ILP32_OFFBIG; do
1481     AS_IF([test "`getconf _$model 2>/dev/null || true`" = 1 -o "`getconf $model 2>/dev/null || true`"],[
1482       buildmodel=$model
1483       break
1484     ])
1485   done
1486   AS_IF([test "x$buildmodel" = "x"],[
1487     AC_MSG_WARN([No suitable build environment found for large files. Trying to use _FILE_OFFSET_BITS=64])
1488   ])
1489 ])
1490 AS_IF([test "x$buildmodel" = "xdefault" -o "x$buildmodel" = "x"],[
1491   # define _FILE_OFFSET_BITS if requested and needed
1492   AS_IF([test "x$squid_opt_enable_large_files" = "xyes" -a $ac_cv_sizeof_long -le 4],[
1493     AC_MSG_NOTICE([Enabling -D_FILE_OFFSET_BITS=64])
1494     CFLAGS="-D_FILE_OFFSET_BITS=64 $CFLAGS"
1495     CXXFLAGS="-D_FILE_OFFSET_BITS=64 $CXXFLAGS"
1496   ])
1497 ],[
1498   AC_MSG_NOTICE([Using $buildmodel build environment])
1499   AS_IF([ ! test "`getconf _$buildmodel 2>/dev/null || true`" = 1 -o "`getconf $buildmodel 2>/dev/null || true`"],[
1500     AC_MSG_ERROR([Build environment $buildmodel not known to getconf.])
1501   ])
1502   CFLAGS="`getconf ${buildmodel}_CFLAGS` $CFLAGS"
1503   CXXFLAGS="`getconf ${buildmodel}_CFLAGS` $CXXFLAGS"
1504   LIBS="`getconf ${buildmodel}_LIBS` $LIBS"
1505   LDFLAGS="`getconf ${buildmodel}_LDFLAGS` $LDFLAGS"
1506
1507   AS_IF([test "x$squid_host_os" = "xsolaris"],[
1508 # On Solaris getconf returns for CFLAGS -xarch=generic64, -Xa and -Usun options, and
1509 # for LDFLAGS -xarch=generic64, but:
1510 #   "-Xa" is supported only by Sun cc, so we need to remove it when using gcc
1511 #   For gcc "-xarch=generic64" must be replaced with "-m64"
1512 #   The 'sun' define is needed by ipfilter includes, so we must remove "-Usun"
1513     AS_IF([test "x$GCC" = "xyes"],[
1514       AC_MSG_NOTICE([Removing -Xa for gcc/g++ on $host])
1515       CFLAGS="`echo $CFLAGS | sed -e 's/-Xa//'`"
1516       CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-Xa//'`"
1517       AC_MSG_NOTICE([Replacing -xarch=generic64 with -m64 for gcc/g++ on $host])
1518       CFLAGS="`echo $CFLAGS | sed -e 's/-xarch=generic64/-m64/'`"
1519       CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-xarch=generic64/-m64/'`"
1520       LDFLAGS="`echo $LDFLAGS | sed -e 's/-xarch=generic64//'`"
1521     ])
1522     AC_MSG_NOTICE([Removing -Usun on $host])
1523     CFLAGS="`echo $CFLAGS | sed -e 's/-Usun//'`"
1524     CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-Usun//'`"
1525   ])
1526 ])
1527
1528 AC_ARG_ENABLE(follow-x-forwarded-for,
1529   AS_HELP_STRING([--disable-follow-x-forwarded-for],
1530                  [Do not follow the X-Forwarded-For
1531                  HTTP header to try to find the IP address of the
1532                  original or indirect client when a request has
1533                  been forwarded through other proxies.]), [
1534   SQUID_YESNO([$enableval],[--enable-follow-x-forwarded-for])
1535 ])
1536 AC_MSG_NOTICE([Support for X-Forwarded-For enabled: ${enable_follow_x_forwarded_for:=yes}])
1537 SQUID_DEFINE_BOOL(FOLLOW_X_FORWARDED_FOR,$enable_follow_x_forwarded_for,
1538   [Enable following X-Forwarded-For headers])
1539
1540 AC_ARG_ENABLE(ident-lookups,
1541   AS_HELP_STRING([--disable-ident-lookups],
1542                  [Remove code that supports performing Ident (RFC 931) lookups.]), [
1543   SQUID_YESNO([$enableval],[--enable-ident-lookups])
1544 ])
1545 AC_MSG_NOTICE([Support for Ident lookups enabled: ${enable_ident_lookups:=yes}])
1546 SQUID_DEFINE_BOOL(USE_IDENT,$enable_ident_lookups,[Support for Ident (RFC 931) lookups])
1547
1548 dnl Select Default hosts file location
1549 AC_ARG_ENABLE(default-hostsfile,
1550   AS_HELP_STRING([--enable-default-hostsfile=path],
1551                  [Select default location for hosts file.
1552                   See hosts_file directive in squid.conf for details]), [
1553   # TODO: handle the "yes" case cleanly
1554   AS_CASE(["$enableval"],
1555     [no|none],[squid_opt_default_hosts="none"],
1556     [
1557       squid_opt_default_hosts=$enableval
1558       AS_IF([ ! test -f "$enableval"],[
1559         AC_MSG_WARN([Unable to find file $enableval. I hope you know what you are doing.])
1560       ])
1561     ])
1562 ])
1563 AC_MSG_NOTICE([Default hosts file set to: ${squid_opt_default_hosts:=/etc/hosts}])
1564 DEFAULT_HOSTS=$squid_opt_default_hosts
1565 AC_SUBST(DEFAULT_HOSTS)
1566
1567 # Select auth schemes modules to build
1568 AC_ARG_ENABLE(auth,
1569   AS_HELP_STRING([--disable-auth],
1570                  [Do not support authentication. When supported, the list of schemes
1571                   and helpers to be enabled is defined elsewhere]), [
1572   SQUID_YESNO([$enableval],[--enable-auth])
1573 ])
1574 AC_MSG_NOTICE([Authentication support enabled: ${enable_auth:=yes}])
1575 SQUID_DEFINE_BOOL(USE_AUTH,$enable_auth,[Enable support for authentication])
1576 AM_CONDITIONAL(ENABLE_AUTH, test "x$enable_auth" != "xno")
1577 AUTH_MODULES=""
1578 require_smblib="no"
1579 require_sspi="no"
1580
1581 AC_ARG_ENABLE(auth-basic,
1582   AS_HELP_STRING([--enable-auth-basic="list of helpers"],
1583      [Enable the basic authentication scheme, and build the specified helpers.
1584       Not providing an explicit list of helpers will attempt build of
1585       all possible helpers. Default is to do so.
1586       To disable the basic authentication scheme, use --disable-auth-basic.
1587       To enable but build no helpers, specify "none".
1588       To see available helpers, see the src/auth/basic/ directory. ]),[
1589 #nothing to do really
1590 ])
1591 m4_include([src/auth/basic/helpers.m4])
1592
1593 AC_ARG_ENABLE(auth-digest,
1594   AS_HELP_STRING([--enable-auth-digest="list of helpers"],
1595      [Enable the Digest authentication scheme, and build the specified helpers.
1596       Not providing an explicit list of helpers will attempt build of
1597       all possible helpers. Default is to do so.
1598       To disable the Digest authentication scheme, use --disable-auth-digest.
1599       To enable but build no helpers, specify "none".
1600       To see available helpers, see the src/auth/digest/ directory. ]),[
1601 #nothing to do, really
1602 ])
1603 m4_include([src/auth/digest/helpers.m4])
1604
1605 AC_ARG_ENABLE(auth-negotiate,
1606   AS_HELP_STRING([--enable-auth-negotiate="list of helpers"],
1607      [Enable the Negotiate authentication scheme, and build the specified
1608       helpers.
1609       Not providing an explicit list of helpers will attempt build of
1610       all possible helpers. Default is to do so.
1611       To disable the Negotiate authentication scheme,
1612       use --disable-auth-negotiate.
1613       To enable but build no helpers, specify "none".
1614       To see available helpers, see the src/auth/negotiate/ directory. ]),[
1615 #nothing to do, really
1616 ])
1617 m4_include([src/auth/negotiate/helpers.m4])
1618
1619 AC_ARG_ENABLE(auth-ntlm,
1620   AS_HELP_STRING([--enable-auth-ntlm="list of helpers"],
1621      [Enable the NTLM authentication scheme, and build the specified helpers.
1622       Not providing an explicit list of helpers will attempt build of
1623       all possible helpers. Default is to do so.
1624       To disable the NTLM authentication scheme, use --disable-auth-ntlm.
1625       To enable but build no helpers, specify "none".
1626       To see available helpers, see the src/auth/ntlm/ directory. ]),[
1627 ])
1628 m4_include([src/auth/ntlm/helpers.m4])
1629
1630 dnl Authentication libraries to build
1631 dnl This list will not be needed when each auth library has its own Makefile
1632 dnl this is to be placed AFTER each auth module's handler
1633 AUTH_LIBS_TO_BUILD=
1634 for module in $AUTH_MODULES; do
1635     AUTH_LIBS_TO_BUILD="$AUTH_LIBS_TO_BUILD ${module}/lib${module}.la"
1636 done
1637 AC_SUBST(AUTH_MODULES)
1638 AC_SUBST(AUTH_LIBS_TO_BUILD)
1639 AM_CONDITIONAL(ENABLE_SMBLIB, test "x$require_smblib" = "xyes")
1640 AM_CONDITIONAL(ENABLE_SSPI, test "x$require_sspi" = "xyes")
1641
1642 dnl Select logging daemon helpers to build
1643 AC_ARG_ENABLE(log-daemon-helpers,
1644   AS_HELP_STRING([--enable-log-daemon-helpers="list of helpers"],
1645                  [This option selects which logging daemon helpers to
1646                   build and install as part of the normal build process
1647                   For a list of available helpers see the src/log/
1648                   directory.]),[
1649 #nothing to do, really
1650 ])
1651 m4_include([src/log/helpers.m4])
1652
1653 AC_ARG_ENABLE(external-acl-helpers,
1654   AS_HELP_STRING([--enable-external-acl-helpers="list of helpers"],
1655                  [Enable external_acl helpers support and the helpers themselves.
1656                   Default is to build all buildable helpers and enable support.
1657                   To disable support, use --disable-external-acl-helpers.
1658                   To build no helpers, specify "none".
1659                   To see available helpers, see the src/acl/external/
1660                   directory]), [
1661 #nothing to do, really
1662 ])
1663 m4_include([src/acl/external/helpers.m4])
1664
1665 dnl Select url_rewrite helpers to build
1666 AC_ARG_ENABLE(url-rewrite-helpers,
1667   AS_HELP_STRING([--enable-url-rewrite-helpers="list of helpers"],
1668                  [This option selects which url_rewrite helpers to
1669                   build and install as part of the normal build
1670                   process. The default is to attempt the build of all possible
1671                   helpers. Use --disable-url-rewrite-helpers to build none.
1672                   For a list of available helpers see the
1673                   src/http/url_rewriters/ directory.]),[
1674 ])
1675 m4_include([src/http/url_rewriters/helpers.m4])
1676
1677 dnl Select security helpers to build
1678 AC_ARG_ENABLE(security-cert-validators,
1679   AS_HELP_STRING([--enable-security-cert-validators="list of helpers"],
1680                  [This option selects which security certificate validator
1681                   helpers to build and install as part of the normal build
1682                   process. The default is to attempt the build of all possible
1683                   helpers. Use --disable-security-cert-validators to
1684                   build none. For a list of available helpers see the
1685                   src/security/cert_validators/ directory.]),[
1686 ])
1687 m4_include([src/security/cert_validators/helpers.m4])
1688
1689 AC_ARG_ENABLE(security-cert-generators,
1690   AS_HELP_STRING([--enable-security-cert-generators="list of helpers"],
1691                  [This option selects which security certificate validator
1692                   helpers to build and install as part of the normal build
1693                   process. The default is to attempt the build of all possible
1694                   helpers. Use --disable-security-cert-genrators to
1695                   build none. For a list of available helpers see the
1696                   src/security/cert_generators/ directory.]),[
1697 ])
1698 m4_include([src/security/cert_generators/helpers.m4])
1699
1700 dnl Select storeid_rewrite helpers to build
1701 AC_ARG_ENABLE(storeid-rewrite-helpers,
1702   AS_HELP_STRING([--enable-storeid-rewrite-helpers="list of helpers"],
1703                  [This option selects which Store-ID rewrite helpers to
1704                   build and install as part of the normal build
1705                   process. The default is to attempt the build of all possible
1706                   helpers. Use --disable-storeid-rewrite-helpers to build none.
1707                   For a list of available helpers see the
1708                   src/store/id_rewriters/ directory.]),[
1709 ])
1710 m4_include([src/store/id_rewriters/helpers.m4])
1711
1712 AC_ARG_WITH(valgrind-debug,
1713   AS_HELP_STRING([--with-valgrind-debug],
1714                  [Include debug instrumentation for use with valgrind]),
1715 [
1716   SQUID_YESNO([$withval],[--with-valgrind-debug])
1717   AS_IF([test "x$withval" != "xno"],[
1718     AC_CHECK_HEADERS(valgrind/memcheck.h,[],[
1719       AC_MSG_ERROR([Valgrind support requested, needed headers not found.])
1720     ])
1721   ])
1722 ])
1723 SQUID_DEFINE_BOOL(WITH_VALGRIND,${with_valgrind_debug:=no},
1724                   [Valgrind memory debugger support])
1725 AC_MSG_NOTICE([Valgrind debug support enabled: $with_valgrind_debug])
1726
1727 dnl Enable WIN32 Service compile mode
1728 AC_ARG_ENABLE(win32-service,
1729   AS_HELP_STRING([--enable-win32-service],
1730                  [Compile Squid as a WIN32 Service.
1731                   Works only on MS-Windows platforms]), [
1732   SQUID_YESNO([$enableval],[--enable-win32-service])
1733 ])
1734 SQUID_DEFINE_BOOL(USE_WIN32_SERVICE,${enable_win32_service:=no},
1735    [Enable code supporting MS Windows service mode])
1736 AC_MSG_NOTICE([MS Windows service mode enabled: $enable_win32_service])
1737
1738
1739 # Disable "unlinkd" code
1740 AC_ARG_ENABLE(unlinkd,
1741   AS_HELP_STRING([--disable-unlinkd],[Do not use unlinkd]), [
1742   SQUID_YESNO([$enableval],[--enable-unlinkd])
1743 ])
1744 SQUID_DEFINE_BOOL(USE_UNLINKD,${enable_unlinkd:=yes},
1745                       [Enable useage of unlinkd])
1746 AM_CONDITIONAL(ENABLE_UNLINKD,test "x$enable_unlinkd" = "xyes")
1747 AC_MSG_NOTICE([unlinkd enabled: $enable_unlinkd])
1748
1749 # Enable backtraces on fatal errors
1750 AC_ARG_ENABLE(stacktraces,
1751   AS_HELP_STRING([--enable-stacktraces],
1752                  [Enable automatic call backtrace on fatal errors]), [
1753   SQUID_YESNO([$enableval],[--enable-stacktraces])
1754 ])
1755 SQUID_DEFINE_BOOL(PRINT_STACK_TRACE,${enable_stacktraces:=no},
1756                       [Print stack traces on fatal errors])
1757 AC_MSG_NOTICE([Automatically print stack trace on fatal errors: $enable_stacktraces])
1758
1759 # Enable X-Accelerator-Vary for Vary support within an accelerator setup
1760 AC_ARG_ENABLE(x-accelerator-vary,
1761   AS_HELP_STRING([--enable-x-accelerator-vary],
1762                  [Enable support for the X-Accelerator-Vary
1763                   HTTP header. Can be used to indicate
1764                   variance within an accelerator setup.
1765                   Typically used together with other code
1766                   that adds custom HTTP headers to the requests.]), [
1767   SQUID_YESNO([$enableval],[--enable-x-accelerator-vary])
1768 ])
1769 SQUID_DEFINE_BOOL(X_ACCELERATOR_VARY,${enable_x_accelerator_vary:=no},
1770                       [Enable support for the X-Accelerator-Vary HTTP header])
1771 AC_MSG_NOTICE([X-Accelerator-Vary support enabled: $enable_x_accelerator_vary])
1772
1773 SQUID_AUTO_LIB(cppunit,[cppunit test framework],[LIBCPPUNIT])
1774 SQUID_CHECK_LIB_WORKS(cppunit,[
1775   PKG_CHECK_MODULES([LIBCPPUNIT],[cppunit],[
1776     squid_cv_cppunit_version="`pkg-config --modversion cppunit`"
1777     AC_MSG_NOTICE([using system installed cppunit version $squid_cv_cppunit_version])
1778     AS_UNSET(squid_cv_cppunit_version)
1779
1780     SQUID_STATE_SAVE(squid_cppunit_state)
1781     CXXFLAGS="${CXXFLAGS} ${LIBCPPUNIT_CFLAGS}"
1782     LIBS="${LIBS} ${LIBCPPUNIT_LIBS}"
1783     AC_CHECK_HEADERS(cppunit/extensions/HelperMacros.h)
1784     SQUID_STATE_ROLLBACK(squid_cppunit_state)
1785   ],[
1786     AC_MSG_WARN([cppunit does not appear to be installed. Squid does not require this, but code testing with 'make check' will fail.])
1787   ])
1788 ])
1789
1790 dnl Check for headers
1791 AC_CHECK_HEADERS( \
1792   arpa/inet.h \
1793   arpa/nameser.h \
1794   assert.h \
1795   bstring.h \
1796   crypt.h \
1797   ctype.h \
1798   direct.h \
1799   dirent.h \
1800   errno.h \
1801   execinfo.h \
1802   fcntl.h \
1803   fnmatch.h \
1804   getopt.h \
1805   glob.h \
1806   gnumalloc.h \
1807   grp.h \
1808   ipl.h \
1809   libc.h \
1810   limits.h \
1811   linux/posix_types.h \
1812   linux/types.h \
1813   malloc.h \
1814   math.h \
1815   memory.h \
1816   mount.h \
1817   netdb.h \
1818   netinet/in.h \
1819   netinet/in_systm.h \
1820   netinet/tcp.h \
1821   paths.h \
1822   poll.h \
1823   priv.h \
1824   pwd.h \
1825   regex.h \
1826   sched.h \
1827   siginfo.h \
1828   signal.h \
1829   stdarg.h \
1830   stddef.h \
1831   stdio.h \
1832   stdlib.h \
1833   string.h \
1834   strings.h \
1835   sys/bitypes.h \
1836   sys/file.h \
1837   sys/ioctl.h \
1838   sys/ipc.cc \
1839   sys/param.h \
1840   sys/prctl.h \
1841   sys/procctl.h \
1842   sys/md5.h \
1843   sys/mman.h \
1844   sys/msg.h \
1845   sys/resource.h \
1846   sys/select.h \
1847   sys/shm.h \
1848   sys/socket.h \
1849   sys/stat.h \
1850   syscall.h \
1851   sys/syscall.h \
1852   sys/time.h \
1853   sys/types.h \
1854   sys/uio.h \
1855   sys/un.h \
1856   sys/vfs.h \
1857   sys/wait.h \
1858   syslog.h \
1859   time.h \
1860   unistd.h \
1861   utime.h \
1862   varargs.h \
1863   byteswap.h \
1864   glib.h \
1865   stdint.h \
1866   inttypes.h \
1867   wchar.h
1868 )
1869
1870 AC_CHECK_HEADERS( \
1871   linux/netfilter_ipv4.h \
1872   linux/netfilter_ipv6/ip6_tables.h \
1873 ,,,
1874 SQUID_DEFAULT_INCLUDES
1875 #if HAVE_LIMITS_H
1876 #include <limits.h>
1877 #endif
1878 /* Netfilter ip(6)tables v1.4.0 has broken headers */
1879 #if HAVE_NETINET_IN_H
1880 #include <netinet/in.h>
1881 #endif
1882 )
1883
1884 dnl *BSD do not include the dependencies for all their net/ and netinet/ files
1885 dnl We must include a few basic type headers for them to work.
1886 AC_CHECK_HEADERS( \
1887   net/if.h \
1888   netinet/if_ether.h\
1889   netinet/icmp6.h \
1890   netinet/in.h \
1891   netinet/ip.h \
1892   netinet/ip6.h \
1893   netinet/ip_icmp.h \
1894   netinet/ipl.h \
1895   net/pf/pfvar.h \
1896   net/pfvar.h \
1897   sys/mount.h\
1898   resolv.h \
1899 ,,,
1900 SQUID_BSDNET_INCLUDES)
1901
1902 AC_C_CONST
1903 AC_C_BIGENDIAN
1904
1905 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[
1906 #if HAVE_TIME_H
1907 #include <time.h>
1908 #endif
1909 ])
1910
1911 AC_CHECK_TYPE(struct rusage,AC_DEFINE(HAVE_STRUCT_RUSAGE,1,[The system provides struct rusage]),,[
1912 #if HAVE_SYS_TIME_H
1913 #include <sys/time.h>
1914 #endif
1915 #if HAVE_SYS_RESOURCE_H
1916 #include <sys/resource.h>
1917 #endif
1918 ])
1919
1920 AC_CHECK_MEMBERS([struct iphdr.ip_hl],,,[
1921 #if HAVE_SYS_TYPES_H
1922 #include <sys/types.h>
1923 #endif
1924 #include <netinet/in.h>
1925 #include <netinet/in_systm.h>
1926 #include <netinet/ip.h>
1927 #if defined (__linux__) || defined (__CYGWIN__)
1928 #define ip_hl ihl
1929 #endif
1930 #ifndef __linux__
1931 #ifndef __CYGWIN__
1932 #define iphdr ip
1933 #endif
1934 #endif])
1935
1936 dnl Check for typedefs
1937 AC_CHECK_SIZEOF(void *)
1938
1939 # check for a bunch of types
1940 AC_TYPE_INT8_T
1941 AC_TYPE_UINT8_T
1942 AC_TYPE_INT16_T
1943 AC_TYPE_UINT16_T
1944 AC_TYPE_INT32_T
1945 AC_TYPE_UINT32_T
1946 AC_TYPE_INT64_T
1947 AC_TYPE_UINT64_T
1948 AC_TYPE_PID_T
1949 AC_TYPE_SIZE_T
1950 AC_TYPE_SSIZE_T
1951 AC_TYPE_OFF_T
1952 AC_TYPE_UID_T
1953 AC_CHECK_TYPE([bool])
1954 #need the defines for PRId64
1955 AC_CHECK_SIZEOF(int64_t)
1956 AC_CHECK_SIZEOF(long)
1957 #need the define for overflow checks
1958 AC_CHECK_SIZEOF(off_t)
1959 AC_CHECK_SIZEOF(size_t)
1960
1961 dnl On Solaris 9 x86, gcc may includes a "fixed" set of old system include files
1962 dnl that is incompatible with the updated Solaris header files.
1963 dnl For this reason, we must check if pad128_t and upad128_t are defined.
1964 AC_CHECK_TYPE(pad128_t,
1965   AC_DEFINE(HAVE_PAD128_T,1,[pad128_t is defined in system headers]),
1966   ,SQUID_DEFAULT_INCLUDES)
1967
1968 AC_CHECK_TYPE(upad128_t,
1969   AC_DEFINE(HAVE_UPAD128_T,1,[upad128_t is defined in system headers]),
1970   ,SQUID_DEFAULT_INCLUDES)
1971
1972 AC_CHECK_TYPE(mode_t, AC_DEFINE(HAVE_MODE_T,1,[mode_t is defined by the system headers]),,SQUID_DEFAULT_INCLUDES)
1973 AC_CHECK_TYPE(fd_mask,  AC_DEFINE(HAVE_FD_MASK,1,[fd_mask is defined by the system headers]),,SQUID_DEFAULT_INCLUDES)
1974
1975 AC_CHECK_TYPE(socklen_t,AC_DEFINE(HAVE_SOCKLEN_T,1,[socklen_t is defined by the system headers]),,[
1976 #include <sys/types.h>
1977 #include <sys/socket.h>
1978 #include <stdlib.h>
1979 #include <stddef.h>
1980 ])
1981
1982 AC_CHECK_TYPE(mtyp_t,AC_DEFINE(HAVE_MTYP_T,1,
1983    [mtyp_t is defined by the system headers]),,[#include <sys/types.h>
1984 #include <sys/ipc.h>
1985 #include <sys/msg.h>])
1986
1987 AC_CHECK_TYPE(cpu_set_t,
1988    AC_DEFINE(HAVE_CPU_SET_T,1,[cpu_set_t is defined by the system headers]),,[
1989 #if HAVE_SCHED_H
1990 #include <sched.h>
1991 #endif
1992 ])
1993
1994 dnl Check for special functions
1995 AC_FUNC_ALLOCA
1996
1997 SQUID_AUTO_LIB(cap,[Linux capabilities],[LIBCAP])
1998 SQUID_CHECK_LIB_WORKS(cap,[
1999   SQUID_STATE_SAVE(squid_libcap_state)
2000   PKG_CHECK_MODULES([LIBCAP],[libcap >= 2.09],[:],[:])
2001   CPPFLAGS="$LIBCAP_CFLAGS $CPPFLAGS"
2002   LIBS="$LIBCAP_PATH $LIBCAP_LIBS $LIBS"
2003   SQUID_CHECK_FUNCTIONAL_LIBCAP2
2004   AC_MSG_NOTICE([libcap headers are ok: $squid_cv_sys_capability_works])
2005   AS_IF([test "x$squid_cv_sys_capability_works" = "xno"],[LIBCAP_LIBS=""])
2006   SQUID_STATE_ROLLBACK(squid_libcap_state)
2007 ])
2008
2009 dnl Check for needed libraries
2010 AC_SEARCH_LIBS([gethostbyname],[nsl resolv bind])
2011 AC_SEARCH_LIBS([res_init],[resolv])
2012 AC_SEARCH_LIBS([__res_search],[resolv])
2013 AC_SEARCH_LIBS([bind],[socket])
2014 AC_SEARCH_LIBS([opcom_stack_trace],[opcom_stack])
2015 AC_SEARCH_LIBS([yp_match], [nsl nss_nis nss_nisplus])
2016
2017 # check that we have unix sockets
2018 SQUID_CHECK_UNIX_SOCKET
2019 SQUID_DEFINE_BOOL(HAVE_UNIXSOCKET,$squid_cv_unixsocket,[System supports unix sockets])
2020
2021 AC_CHECK_LIB(gnumalloc, malloc)
2022 AS_IF([test "x$ac_cv_lib_gnumalloc_malloc" = "xyes"],[
2023   AC_MSG_NOTICE([Disabling extended malloc functions when using bundled gnumalloc])
2024   ac_cv_func_mallocblksize=no
2025   ac_cv_func_mallopt=no
2026 ],[
2027   AS_CASE(["$squid_host_os"],
2028     [solaris],[AC_MSG_NOTICE([skipping libmalloc check for $host])],
2029     [freebsd],[AC_MSG_NOTICE([skipping libmalloc check for $host])],
2030     [AC_CHECK_LIB(malloc, main)]
2031   )
2032 ])
2033
2034 AS_IF([test "$squid_host_os" = "mingw"],[
2035   AC_MSG_NOTICE([Use MSVCRT for math functions.])
2036 ],[
2037   dnl log() are only used in old C code for now.
2038   AC_LANG_PUSH([C])
2039   AC_SEARCH_LIBS([log],[m])
2040   AC_LANG_POP([C])
2041 ])
2042
2043 dnl --with-maxfd present for compatibility with Squid-2.
2044 dnl undocumented in ./configure --help  to encourage using the Squid-3 directive
2045 AC_ARG_WITH(maxfd,,[
2046   AS_CASE([$withval],
2047     [@<:@0-9@:>@*],[
2048       squid_filedescriptors_num=$withval
2049       AC_MSG_NOTICE([forcing default of $squid_filedescriptors_num filedescriptors (user-forced)])
2050     ],
2051     [AC_MSG_ERROR(--with-maxfd expects a numeric argument)]
2052   )
2053 ])
2054
2055 AC_ARG_WITH(filedescriptors,
2056   AS_HELP_STRING([--with-filedescriptors=NUMBER],
2057     [Force squid to support NUMBER filedescriptors]),[
2058   AS_CASE([$withval],
2059     [@<:@0-9@:>@*],[
2060       squid_filedescriptors_num=$withval
2061       AC_MSG_NOTICE([forcing default of $squid_filedescriptors_num filedescriptors (user-forced)])],
2062     [AC_MSG_ERROR([--with-filedescriptors expects a numeric argument])]
2063   )
2064 ])
2065
2066 SQUID_CHECK_DEFAULT_FD_SETSIZE
2067 SQUID_CHECK_MAXFD
2068
2069
2070 dnl Enable IPv6 support
2071 AC_MSG_CHECKING([whether to enable IPv6])
2072 AC_ARG_ENABLE(ipv6,
2073   AS_HELP_STRING([--disable-ipv6],[Disable IPv6 support. The default is to probe system capabilities on startup.]), [
2074   SQUID_YESNO([$enableval],[--enable-ipv6])
2075 ])
2076 AC_MSG_RESULT(${enable_ipv6:=yes})
2077 SQUID_DEFINE_BOOL(USE_IPV6,$enable_ipv6,[Enable support for IPv6 ])
2078
2079 AS_IF([test "x$enable_ipv6" = "xyes"],[SQUID_CHECK_SIN6_LEN_IN_SAI])
2080 SQUID_CHECK_SS_LEN_IN_SOCKADDR_STORAGE
2081 SQUID_CHECK_SIN_LEN_IN_SOCKADDR_IN
2082
2083 dnl System-specific library modifications
2084 AH_TEMPLATE(GETTIMEOFDAY_NO_TZP,[Whether gettimeofday takes only one argument])
2085 AS_CASE(["$host"],
2086   [*-pc-sco3.2*],[
2087     # -lintl is needed on SCO version 3.2v4.2 for strftime()
2088     # Robert Side <rside@aiinc.bc.ca>
2089     # Mon, 18 Jan 1999 17:48:00 GMT
2090     AC_CHECK_LIB(intl, strftime)
2091   ],
2092
2093   [i386-*-solaris2.*],[
2094     AS_IF([test "x$GCC" = "xyes"],[
2095       AC_MSG_NOTICE([Removing -O for gcc on $host])
2096       CFLAGS="`echo $CFLAGS | sed -e 's/-O[[0-9g]]*//'`"
2097     ])
2098   ],
2099
2100   [*-sgi-irix*],[
2101     AC_MSG_NOTICE([Removing -lsocket for IRIX...])
2102     LIBS=`echo $LIBS | sed -e s/-lsocket//`
2103     AC_MSG_NOTICE([Removing -lnsl for IRIX...])
2104     LIBS=`echo $LIBS | sed -e s/-lnsl//`
2105     ac_cv_lib_nsl_main=no
2106   ],
2107
2108   [*-ibm-aix*],[
2109     SQUID_CC_REQUIRE_ARGUMENT([ac_cv_require_rtti],[-rtti],[[
2110 #include <assert.h>
2111 #ifndef NULL
2112 #define NULL 0
2113 #endif
2114 class Foo{
2115 public:virtual ~Foo(){}
2116 };
2117 class Bar:public Foo{
2118 public:Bar():Foo(){}
2119 };
2120       ]],[[
2121 Foo * myFoo=new Bar();
2122 Bar * myBar=dynamic_cast<Bar *>(myFoo);
2123 assert(myBar != NULL);
2124       ]])
2125     AS_IF([test "$ac_cv_require_rtti" = "yes"],[
2126       SQUID_CFLAGS="-rtti $SQUID_CFLAGS"
2127       SQUID_CXXFLAGS="-rtti $SQUID_CXXFLAGS"
2128     ])
2129
2130     AC_LANG_PUSH([C])
2131     SQUID_CC_REQUIRE_ARGUMENT([ac_cv_require_qcpluscmt],[-qcpluscmt],[[]],[[//c++ cmt]])
2132     AC_LANG_POP([C])
2133     AS_IF([test "$ac_cv_require_qcpluscmt" = "yes"],[
2134       SQUID_CFLAGS="-qcpluscmt $SQUID_CFLAGS"
2135     ])
2136   ],
2137
2138   [*-*-solaris2.[[0-4]]],[AC_DEFINE(GETTIMEOFDAY_NO_TZP,1)],
2139
2140   [*-sony-newsos[[56]]*],[AC_DEFINE(GETTIMEOFDAY_NO_TZP,1)]
2141 )
2142
2143 dnl This has to be before AC_CHECK_FUNCS
2144 # Disable poll() on certain platforms. Override by setting ac_cv_func_poll
2145 # when running configure.
2146 AS_IF([test "x$ac_cv_func_poll" = "x"],[
2147   AS_CASE(["$host"],
2148     [*-hp-hpux*.*],[
2149       # Duane Wessels
2150       AC_MSG_NOTICE([disabling poll for $host...])
2151       ac_cv_func_poll='no'
2152     ],
2153
2154     [*-linux-*],[
2155       # Henrik Nordstrom (hno@squid-cache.org) 19980817
2156       # poll is problematic on Linux.  We disable it
2157       # by default until Linux gets it right.
2158       rev=`uname -r | awk -F. '{printf "%03d%03d",$1,$2}'`
2159       AS_IF([test $rev -lt 002002],[
2160           AC_MSG_NOTICE([disabling poll for $host < 2.2...])
2161           ac_cv_func_poll='no'
2162       ])
2163     ],
2164
2165     [powerpc-ibm-aix4.1.*],[
2166       # Mike Laster (mlaster@metavillage.com) 19981021
2167       AC_MSG_NOTICE([disabling poll for $host...])
2168       ac_cv_func_poll='no'
2169     ]
2170   )
2171 ])
2172
2173 dnl Check for library functions
2174 AC_CHECK_FUNCS(\
2175         backtrace_symbols_fd \
2176         bcopy \
2177         eui64_aton \
2178         fchmod \
2179         getdtablesize \
2180         getpagesize \
2181         getpass \
2182         getrusage \
2183         getspnam \
2184         gettimeofday \
2185         glob \
2186         mallocblksize \
2187         mallopt \
2188         memcpy \
2189         memmove \
2190         memrchr \
2191         memset \
2192         mkstemp \
2193         mktime \
2194         mstats \
2195         poll \
2196         prctl \
2197         procctl \
2198         pthread_attr_setschedparam \
2199         pthread_attr_setscope \
2200         pthread_setschedparam \
2201         pthread_sigmask \
2202         putenv \
2203         regcomp \
2204         regexec \
2205         regfree \
2206         res_init \
2207         __res_init \
2208         rint \
2209         sched_getaffinity \
2210         sched_setaffinity \
2211         select \
2212         seteuid \
2213         setgroups \
2214         setpflags \
2215         setpgrp \
2216         setsid \
2217         setresuid \
2218         sigaction \
2219         snprintf \
2220         socketpair \
2221         sysconf \
2222         syslog \
2223         timegm \
2224         vsnprintf \
2225 )
2226 dnl ... and some we provide local replacements for
2227 AC_REPLACE_FUNCS(\
2228         initgroups \
2229         psignal \
2230         strerror \
2231         strtoll \
2232         tempnam \
2233 )
2234
2235 # Magic which checks whether we are forcing a type of comm loop we
2236 # are actually going to (ab)use.
2237 # Mostly ripped from squid-commloops, thanks to adrian and benno
2238
2239 AS_IF([test "x$squid_opt_io_loop_engine" != "x"],
2240   AC_MSG_NOTICE([choosing user-specified net I/O API $squid_opt_io_loop_engine]),
2241   [test "x$enable_epoll" != "xno" -a "x$squid_cv_epoll_works" = "xyes"],
2242   squid_opt_io_loop_engine="epoll",
2243   [test "x$enable_kqueue" != "xno"],
2244   squid_opt_io_loop_engine="kqueue",
2245   [test "x$enable_devpoll" != "xno"],
2246   squid_opt_io_loop_engine="devpoll",
2247   [test "x$enable_poll" != "xno" -a "x$ac_cv_func_poll" = "xyes"],
2248   squid_opt_io_loop_engine="poll",
2249   [test "x$enable_select" != "xno" -a "x$ac_cv_func_select" = "xyes"],
2250   squid_opt_io_loop_engine="select",
2251   [
2252     AC_MSG_WARN([Eep!  Cannot find epoll, kqueue, /dev/poll, poll or select!])
2253     AC_MSG_WARN([Will try select and hope for the best.])
2254     squid_opt_io_loop_engine="select"
2255   ]
2256 )
2257
2258 AC_MSG_NOTICE([Using ${squid_opt_io_loop_engine} for the IO loop.])
2259
2260 AM_CONDITIONAL(ENABLE_POLL, test "x$squid_opt_io_loop_engine" = "xpoll")
2261 AM_CONDITIONAL(ENABLE_EPOLL, test "x$squid_opt_io_loop_engine" = "xepoll")
2262 AM_CONDITIONAL(ENABLE_SELECT, test "x$squid_opt_io_loop_engine" = "xselect")
2263 AM_CONDITIONAL(ENABLE_KQUEUE, test "x$squid_opt_io_loop_engine" = "xkqueue")
2264 AM_CONDITIONAL(ENABLE_DEVPOLL, test "x$squid_opt_io_loop_engine" = "xdevpoll")
2265
2266 AS_CASE([$squid_opt_io_loop_engine],
2267   [epoll],[AC_DEFINE(USE_EPOLL,1,[Use epoll() for the IO loop])],
2268   [devpoll],[AC_DEFINE(USE_DEVPOLL,1,[Use /dev/poll for the IO loop])],
2269   [poll],[AC_DEFINE(USE_POLL,1,[Use poll() for the IO loop])],
2270   [kqueue],[AC_DEFINE(USE_KQUEUE,1,[Use kqueue() for the IO loop])],
2271   [select],[AC_DEFINE(USE_SELECT,1,[Use select() for the IO loop])],
2272 )
2273
2274 AS_IF([test "x$ac_cv_func_sched_getaffinity" = "xyes" -a "x$ac_cv_func_sched_setaffinity" = "xyes"],[
2275   AC_DEFINE(HAVE_CPU_AFFINITY,1,[Support setting CPU affinity for workers])
2276 ])
2277
2278 AC_CHECK_HEADERS(mswsock.h)
2279 AC_MSG_CHECKING([for constant CMSG_SPACE])
2280 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
2281   #if HAVE_SYS_SOCKET_H
2282   #include <sys/socket.h>
2283   #endif
2284   #if HAVE_MSWSOCK_H
2285   #include <mswsock.h>
2286   #endif
2287
2288   int a[CMSG_SPACE(int)];
2289 ]])], [
2290   AC_MSG_RESULT(yes)
2291   AC_DEFINE(HAVE_CONSTANT_CMSG_SPACE, 1, [Define to 1 if CMSG_SPACE is constant])
2292 ], [
2293   AC_MSG_RESULT(no)
2294 ])
2295
2296 AC_CHECK_TYPE(struct cmsghdr,AC_DEFINE(HAVE_CMSGHDR,1,[The system provides struct cmsghdr]),,[
2297   #if HAVE_SYS_SOCKET_H
2298   #include <sys/socket.h>
2299   #endif
2300   #if HAVE_MSWSOCK_H
2301   #include <mswsock.h>
2302   #endif
2303   #if HAVE_WINSOCK2_H
2304   #include <winsock2.h>
2305   #endif
2306 ])
2307
2308 AC_CHECK_TYPE(struct iovec,AC_DEFINE(HAVE_IOVEC,1,[The system provides struct iovec]),,[
2309   #if HAVE_SYS_SOCKET_H
2310   #include <sys/socket.h>
2311   #endif
2312   #if HAVE_WINSOCK2_H
2313   #include <winsock2.h>
2314   #endif
2315   #if HAVE_SYS_UIO_H
2316   #include <sys/uio.h>
2317   #endif
2318 ])
2319
2320 AC_CHECK_TYPE(struct msghdr,AC_DEFINE(HAVE_MSGHDR,1,[The system provides struct msghdr]),,[
2321   #if HAVE_SYS_SOCKET_H
2322   #include <sys/socket.h>
2323   #endif
2324   #if HAVE_MSWSOCK_H
2325   #include <mswsock.h>
2326   #endif
2327   #if HAVE_WINSOCK2_H
2328   #include <winsock2.h>
2329   #endif
2330 ])
2331
2332 AC_CHECK_TYPE(struct sockaddr_un,AC_DEFINE(HAVE_SOCKADDR_UN,1,[The system provides sockaddr_un]),,[
2333   #if HAVE_SYS_UN_H
2334   #include <sys/un.h>
2335   #endif
2336   #if HAVE_SYS_SOCKET_H
2337   #include <sys/socket.h>
2338   #endif
2339   #if HAVE_WINSOCK2_H
2340   #include <winsock2.h>
2341   #endif
2342 ])
2343
2344 dnl IP-Filter support requires ipf header files. These aren't
2345 dnl installed by default, so we need to check for them
2346 AS_IF([test "x$enable_ipf_transparent" != "xno"],[
2347   SQUID_CHECK_BROKEN_SOLARIS_IPFILTER
2348   AC_MSG_CHECKING(for availability of IP-Filter header files)
2349   # hold on to your hats...
2350   AS_IF(
2351   [test "x$ac_cv_header_ip_compat_h" = "xyes" -o \
2352     "x$ac_cv_header_ip_fil_compat_h" = "xyes" -o \
2353     "x$ac_cv_header_netinet_ip_compat_h" = "xyes" -o \
2354     "x$ac_cv_header_netinet_ip_fil_compat_h" = "xyes"],
2355   [have_ipfilter_compat_header="yes"])
2356
2357   AS_IF(
2358   [test "x$have_ipfilter_compat_header" = "xyes" -a \
2359     "x$ac_cv_header_ip_fil_h" = "xyes" -a \
2360     "x$ac_cv_header_ip_nat_h" = "xyes"],[enable_ipf_transparent="yes"],
2361
2362   [test "x$have_ipfilter_compat_header" = "xyes" -a \
2363     "x$ac_cv_header_netinet_ip_fil_h" = "xyes" -a \
2364     "x$ac_cv_header_netinet_ip_nat_h" = "xyes"],[enable_ipf_transparent="yes"],
2365   [enable_ipf_transparent="no"])
2366
2367   AC_MSG_RESULT($IPF_TRANSPARENT)
2368
2369 ## On Solaris Ipfilter includes expect that SOLARIS2 is defined with the
2370 ## Solaris minor version (8, 9, 10, ...)
2371   AS_IF([test "x$enable_ipf_transparent" = "xyes" -a "x$squid_host_os" = "xsolaris"],[
2372     solrev=`uname -r | sh -c 'IFS=. read j n x; echo $n'`
2373     CFLAGS="-DSOLARIS2=$solrev $CFLAGS"
2374     CXXFLAGS="-DSOLARIS2=$solrev $CXXFLAGS"
2375   ])
2376 ])
2377 AC_MSG_NOTICE([IPF-based transparent proxying enabled: $enable_ipf_transparent])
2378 SQUID_DEFINE_BOOL(IPF_TRANSPARENT,$enable_ipf_transparent,
2379     [Enable support for IPF-style transparent proxying])
2380
2381 dnl PF /dev/pf support requires a header file.
2382 AS_IF([test "x$with_nat_devpf" != "xno"],[
2383   AS_IF([test "x$ac_cv_header_net_pfvar_h" = "xyes" -o \
2384     "x$ac_cv_header_net_pf_pfvar_h" = "xyes"],[
2385     AS_IF([test "x$with_nat_devpf" = "xauto"],[with_nat_devpf="no"])
2386   ],[
2387     AS_IF([test "x$with_nat_devpf" = "xyes"],[
2388       AC_MSG_ERROR([PF /dev/pf based NAT requested but needed header not found])
2389     ])
2390     with_nat_devpf="no"
2391   ])
2392 ])
2393 SQUID_DEFINE_BOOL(PF_TRANSPARENT,${enable_pf_transparent:=no},
2394   [Enable support for PF-style transparent proxying])
2395 SQUID_DEFINE_BOOL(USE_NAT_DEVPF,${with_nat_devpf:=no},
2396   [Enable support for /dev/pf NAT lookups])
2397
2398 AS_IF([test "x$enable_linux_netfilter" != "xno"],[
2399   AS_IF([test "x$ac_cv_header_linux_netfilter_ipv4_h" = "xyes"],[
2400     AS_IF([test "x$enable_linux_netfilter" = "xauto"],[enable_linux_netfilter=yes])
2401   ],[
2402     AS_IF([test "x$enable_linux_netfilter" = "xauto"],[
2403       enable_linux_netfilter=no
2404     ],[
2405       AC_MSG_ERROR([Linux Netfilter support requested but needed headers not found])
2406     ])
2407   ])
2408 ])
2409 SQUID_DEFINE_BOOL(LINUX_NETFILTER,$enable_linux_netfilter,
2410   [Enable support for Transparent Proxy on Linux via Netfilter])
2411
2412 dnl Netfilter TPROXY depends on libcap but the NAT parts can still work.
2413 AC_MSG_NOTICE([Support for Netfilter-based interception proxy requested: $enable_linux_netfilter])
2414 AS_IF([test "x$enable_linux_netfilter" = "xyes" -a "x$with_cap" != "xyes"],[
2415   AC_MSG_WARN([Missing needed capabilities (libcap 2.09+) for TPROXY])
2416   AC_MSG_WARN([Linux Transparent Proxy (version 4+) support WILL NOT be enabled])
2417   AC_MSG_WARN([Reduced support to NAT Interception Proxy])
2418   # AC_DEFINEd later
2419 ])
2420 AS_IF([test "x$with_netfilter_conntrack" = "xyes" -a "x$with_cap" != "xyes"],[
2421   AC_MSG_WARN([Missing needed capabilities (libcap 2.09+) for netfilter mark support])
2422   AC_MSG_WARN([Linux netfilter marking support WILL NOT be enabled])
2423   with_netfilter_conntrack=no
2424 ])
2425 AC_MSG_NOTICE([Linux Netfilter Conntrack support enabled: ${with_netfilter_conntrack}])
2426
2427
2428 AC_ARG_ENABLE(zph-qos,
2429   AS_HELP_STRING([--disable-zph-qos],[Disable ZPH QOS support]), [
2430   SQUID_YESNO([$enableval],[--enable-zph-qos])
2431 ])
2432 SQUID_DEFINE_BOOL(USE_QOS_TOS,${enable_zph_qos:=yes},
2433           [Enable Zero Penalty Hit QOS. When set, Squid will alter the
2434            TOS field of HIT responses to help policing network traffic])
2435 AC_MSG_NOTICE([ZPH QOS enabled: $enable_zph_qos])
2436 AS_IF([test "x$enable_zph_qos" = "xyes"],[
2437   AC_MSG_NOTICE([QOS netfilter mark preservation enabled: $with_netfilter_conntrack])
2438   SQUID_DEFINE_BOOL(USE_LIBNETFILTERCONNTRACK,${with_netfilter_conntrack:=no},
2439     [Enable support for QOS netfilter mark preservation])
2440 ])
2441
2442 AC_CHECK_LIB(regex, regexec, [REGEXLIB="-lregex"],[REGEXLIB=''])
2443 AC_SUBST(REGEXLIB)
2444
2445 SQUID_DETECT_UDP_SND_BUFSIZE
2446 SQUID_DETECT_UDP_RECV_BUFSIZE
2447 SQUID_DETECT_TCP_SND_BUFSIZE
2448 SQUID_DETECT_TCP_RECV_BUFSIZE
2449
2450 SQUID_CHECK_NEED_SYS_ERRLIST
2451 SQUID_CHECK_MAXPATHLEN
2452
2453 SQUID_CHECK_LIBRESOLV_DNS_TTL_HACK
2454 SQUID_CHECK_RESOLVER_FIELDS
2455
2456 AC_CHECK_HEADERS(sys/statvfs.h)
2457 AS_IF([test "x$ac_cv_header_sys_statvfs_h" = "xyes"],[SQUID_CHECK_WORKING_STATVFS])
2458 AS_IF([test "x$ac_cv_func_statvfs" != "xyes"],[
2459   AC_CHECK_HEADERS(sys/param.h sys/mount.h sys/vfs.h sys/statfs.h)
2460   AC_CHECK_FUNCS(statfs)
2461   SQUID_CHECK_F_FRSIZE_IN_STATFS
2462 ])
2463
2464 dnl Squid will not usually attempt to translate templates when building
2465 AC_ARG_ENABLE(translation,
2466  AS_HELP_STRING([--enable-translation],[Generate the localized error page templates and manuals.
2467                  Which can also be downloaded from http://www.squid-cache.org/Versions/langpack/.]), [
2468   SQUID_YESNO([$enableval],[--enable-translation])
2469 ])
2470 AS_IF([test "x${enable_translation:=no}" = "xyes"],[
2471   AX_WITH_PROG([PO2HTML],[po2html])
2472   AX_WITH_PROG([PO2TEXT],[po2txt])
2473 ],[
2474   PO2HTML="off"
2475   PO2TEXT="off"
2476 ])
2477 AC_SUBST(PO2HTML)
2478 AC_SUBST(PO2TEXT)
2479 AM_CONDITIONAL(ENABLE_TRANSLATION, test "x${enable_translation:=no}" = "xyes")
2480
2481 dnl Squid now has limited locale handling ...
2482 dnl on error pages
2483 AC_ARG_ENABLE(auto-locale,
2484  AS_HELP_STRING([--disable-auto-locale],[This prevents Squid providing localized error pages based on the
2485                  clients request headers.
2486                  When disabled Squid requires explicit language configuration.]), [
2487   SQUID_YESNO([$enableval],[--enable-auto-locale])
2488 ])
2489 AC_MSG_NOTICE([Multi-Language support enabled: ${enable_auto_locale:=yes}])
2490 SQUID_DEFINE_BOOL(USE_ERR_LOCALES,$enable_auto_locale,
2491    [Use multi-language support on error pages])
2492
2493
2494 dnl Need the debugging version of malloc if available
2495 XTRA_OBJS=''
2496 AS_IF([test "x$ac_cv_lib_malloc_main" = "xyes"],[
2497   AS_IF([test -r /usr/lib/debug/malloc.o],[XTRA_OBJS="$XTRA_OBJS /usr/lib/debug/malloc.o"])
2498   AS_IF([test -r /usr/lib/debug/mallocmap.o],[XTRA_OBJS="$XTRA_OBJS /usr/lib/debug/mallocmap.o"]);
2499 ])
2500 AC_SUBST(XTRA_OBJS)
2501
2502 AS_IF([test "x$XTRA_LIBS" = "x"],[
2503   XTRA_LIBS="$LIBS"
2504   dnl minor cleanup
2505   XTRA_LIBS=`echo $XTRA_LIBS | sed -e "s/  */ /g"`
2506   LIBS=''
2507 ])
2508 AC_SUBST(XTRA_LIBS)
2509
2510 AC_SUBST(SQUID_CFLAGS)
2511 AC_SUBST(SQUID_CXXFLAGS)
2512
2513 # Prerequisite: CXXFLAGS have been finalized.
2514 AC_ARG_VAR([BUILDCXXFLAGS],[C++ compiler flags for building compile-time tools. e.g. cf_gen])
2515 AS_IF([test "x$BUILDCXXFLAGS" = "x"],[
2516   # if we are NOT cross-compiling, use the default build flags for cf_gen and friends
2517   # otherwise rely on the user-provided value
2518   AS_IF([test "x$squid_cv_check_marchnative" = "xyes"],[
2519     # always valid for the Build compiler.
2520     BUILDCXXFLAGS="-march=native"
2521   ])
2522   BUILDCXXFLAGS="$BUILDCXXFLAGS $CXXFLAGS"
2523 ])
2524 AC_SUBST(BUILDCXXFLAGS)
2525
2526 AC_MSG_NOTICE([BUILD LIBRARIES: $LIBS])
2527 AC_MSG_NOTICE([BUILD EXTRA LIBRARIES: $XTRA_LIBS])
2528 AC_MSG_NOTICE([BUILD OBJECTS: $OBJS])
2529 AC_MSG_NOTICE([BUILD EXTRA OBJECTS: $XTRA_OBJS])
2530 AC_MSG_NOTICE([BUILD C FLAGS: $CFLAGS])
2531 AC_MSG_NOTICE([BUILD EXTRA C FLAGS: $SQUID_CFLAGS])
2532 AC_MSG_NOTICE([BUILD C++ FLAGS: $CXXFLAGS])
2533 AC_MSG_NOTICE([BUILD EXTRA C++ FLAGS: $SQUID_CXXFLAGS])
2534 AC_MSG_NOTICE([BUILD Tools C++ FLAGS: $BUILDCXXFLAGS])
2535
2536 dnl Clean up after OSF/1 core dump bug
2537 rm -f core
2538
2539 AC_CONFIG_FILES([
2540         Makefile
2541         compat/Makefile
2542         contrib/Makefile
2543         doc/Makefile
2544         doc/manuals/Makefile
2545         doc/release-notes/Makefile
2546         errors/Makefile
2547         icons/Makefile
2548         lib/Makefile
2549         lib/libTrie/Makefile
2550         lib/libTrie/test/Makefile
2551         lib/ntlmauth/Makefile
2552         lib/rfcnb/Makefile
2553         lib/smblib/Makefile
2554         lib/snmplib/Makefile
2555         lib/sspi/Makefile
2556         scripts/Makefile
2557         src/Makefile
2558         src/acl/Makefile
2559         src/acl/external/Makefile
2560         src/acl/external/AD_group/Makefile
2561         src/acl/external/delayer/Makefile
2562         src/acl/external/eDirectory_userip/Makefile
2563         src/acl/external/file_userip/Makefile
2564         src/acl/external/kerberos_ldap_group/Makefile
2565         src/acl/external/kerberos_sid_group/Makefile
2566         src/acl/external/LDAP_group/Makefile
2567         src/acl/external/LM_group/Makefile
2568         src/acl/external/session/Makefile
2569         src/acl/external/SQL_session/Makefile
2570         src/acl/external/unix_group/Makefile
2571         src/acl/external/wbinfo_group/Makefile
2572         src/acl/external/time_quota/Makefile
2573         src/adaptation/Makefile
2574         src/adaptation/icap/Makefile
2575         src/adaptation/ecap/Makefile
2576         src/anyp/Makefile
2577         src/auth/Makefile
2578         src/auth/basic/Makefile
2579         src/auth/basic/DB/Makefile
2580         src/auth/basic/fake/Makefile
2581         src/auth/basic/getpwnam/Makefile
2582         src/auth/basic/LDAP/Makefile
2583         src/auth/basic/NCSA/Makefile
2584         src/auth/basic/NIS/Makefile
2585         src/auth/basic/PAM/Makefile
2586         src/auth/basic/POP3/Makefile
2587         src/auth/basic/RADIUS/Makefile
2588         src/auth/basic/SASL/Makefile
2589         src/auth/basic/SMB/Makefile
2590         src/auth/basic/SMB_LM/Makefile
2591         src/auth/basic/SSPI/Makefile
2592         src/auth/digest/Makefile
2593         src/auth/digest/eDirectory/Makefile
2594         src/auth/digest/file/Makefile
2595         src/auth/digest/LDAP/Makefile
2596         src/auth/negotiate/Makefile
2597         src/auth/negotiate/kerberos/Makefile
2598         src/auth/negotiate/SSPI/Makefile
2599         src/auth/negotiate/wrapper/Makefile
2600         src/auth/ntlm/Makefile
2601         src/auth/ntlm/fake/Makefile
2602         src/auth/ntlm/SMB_LM/Makefile
2603         src/auth/ntlm/SSPI/Makefile
2604         src/base/Makefile
2605         src/clients/Makefile
2606         src/comm/Makefile
2607         src/debug/Makefile
2608         src/dns/Makefile
2609         src/DiskIO/Makefile
2610         src/DiskIO/AIO/Makefile
2611         src/DiskIO/Blocking/Makefile
2612         src/DiskIO/DiskDaemon/Makefile
2613         src/DiskIO/DiskThreads/Makefile
2614         src/DiskIO/IpcIo/Makefile
2615         src/DiskIO/Mmapped/Makefile
2616         src/error/Makefile
2617         src/esi/Makefile
2618         src/eui/Makefile
2619         src/format/Makefile
2620         src/fs/Makefile
2621         src/ftp/Makefile
2622         src/helper/Makefile
2623         src/html/Makefile
2624         src/http/Makefile
2625         src/http/one/Makefile
2626         src/http/url_rewriters/Makefile
2627         src/http/url_rewriters/fake/Makefile
2628         src/http/url_rewriters/LFS/Makefile
2629         src/icmp/Makefile
2630         src/ident/Makefile
2631         src/ip/Makefile
2632         src/ipc/Makefile
2633         src/log/Makefile
2634         src/log/DB/Makefile
2635         src/log/file/Makefile
2636         src/mem/Makefile
2637         src/mgr/Makefile
2638         src/parser/Makefile
2639         src/proxyp/Makefile
2640         src/repl/Makefile
2641         src/sbuf/Makefile
2642         src/security/Makefile
2643         src/security/cert_generators/Makefile
2644         src/security/cert_generators/file/Makefile
2645         src/security/cert_validators/Makefile
2646         src/security/cert_validators/fake/Makefile
2647         src/servers/Makefile
2648         src/snmp/Makefile
2649         src/ssl/Makefile
2650         src/store/Makefile
2651         src/store/id_rewriters/Makefile
2652         src/store/id_rewriters/file/Makefile
2653         src/time/Makefile
2654         test-suite/Makefile
2655         tools/Makefile
2656         tools/apparmor/Makefile
2657         tools/helper-mux/Makefile
2658         tools/systemd/Makefile
2659         tools/sysvinit/Makefile
2660 ])
2661
2662 # must configure libltdl subdir unconditionally for "make distcheck" to work
2663 #AC_CONFIG_SUBDIRS(libltdl)
2664
2665 AC_OUTPUT