configure.ac

   1 #
   2 #  This file is part of systemd.
   3 #
   4 #  Copyright 2010-2012 Lennart Poettering
   5 #  Copyright 2010-2012 Kay Sievers
   6 #
   7 #  systemd is free software; you can redistribute it and/or modify it
   8 #  under the terms of the GNU Lesser General Public License as published by
   9 #  the Free Software Foundation; either version 2.1 of the License, or
  10 #  (at your option) any later version.
  11 #
  12 #  systemd is distributed in the hope that it will be useful, but
  13 #  WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  15 #  Lesser General Public License for more details.
  16 #
  17 #  You should have received a copy of the GNU Lesser General Public License
  18 #  along with systemd; If not, see <http://www.gnu.org/licenses/>.
  19
  20 AC_PREREQ([2.64])
  21
  22 AC_INIT([systemd],
  23         [231],
  24         [http://github.com/systemd/systemd/issues],
  25         [systemd],
  26         [http://www.freedesktop.org/wiki/Software/systemd])
  27
  28 AC_CONFIG_SRCDIR([src/core/main.c])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_HEADERS([config.h])
  31 AC_CONFIG_AUX_DIR([build-aux])
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 AC_SYS_LARGEFILE
  35 AC_PREFIX_DEFAULT([/usr])
  36 AM_MAINTAINER_MODE([enable])
  37 AM_INIT_AUTOMAKE([foreign 1.11 -Wall -Wno-portability silent-rules tar-pax no-dist-gzip dist-xz subdir-objects parallel-tests])
  38 AM_SILENT_RULES([yes])
  39 AC_CANONICAL_HOST
  40 AC_DEFINE_UNQUOTED([CANONICAL_HOST], "$host", [Canonical host string.])
  41
  42 AC_PROG_CC_C99
  43
  44 AX_COMPILER_VENDOR
  45 AS_IF([test "x$ax_cv_c_compiler_vendor" = "xgnu"], [
  46       AC_CHECK_TOOLS([AR], [gcc-ar ar], [:])
  47       AC_CHECK_TOOLS([NM], [gcc-nm nm], [:])
  48       AC_CHECK_TOOLS([RANLIB], [gcc-ranlib ranlib], [:])
  49 ])
  50
  51 LT_PREREQ(2.2)
  52 LT_INIT([disable-static])
  53
  54 AS_IF([test "x$enable_static" = "xyes"], [AC_MSG_ERROR([--enable-static is not supported by systemd])])
  55 AS_IF([test "x$enable_largefile" = "xno"], [AC_MSG_ERROR([--disable-largefile is not supported by systemd])])
  56
  57 SET_ARCH(X86_64, x86_64*)
  58 SET_ARCH(IA32, i*86*)
  59 SET_ARCH(MIPS, mips*)
  60 SET_ARCH(AARCH64, aarch64*)
  61
  62 # i18n stuff for the PolicyKit policy files, heck whether intltool can be found, disable NLS otherwise
  63 AC_CHECK_PROG(intltool_found, [intltool-merge], [yes], [no])
  64 AS_IF([test x"$intltool_found" != xyes],
  65       [AS_IF([test x"$enable_nls" = xyes],
  66              [AC_MSG_ERROR([--enable-nls requested but intltool not found])],
  67              [AS_IF([test x"$enable_nls" != xno],
  68                     [AC_MSG_WARN([*** Disabling NLS support because intltool was not found])
  69                      enable_nls=no])
  70              ])
  71       ])
  72
  73 AM_NLS
  74 AS_IF([test x"$enable_nls" != xno -o "x$enable_polkit" != xno], [
  75     # intltoolize greps for '^(AC|IT)_PROG_INTLTOOL', so it needs to be on its own line
  76 IT_PROG_INTLTOOL([0.40.0])
  77 ])
  78
  79 AS_IF([test -z "$INTLTOOL_POLICY_RULE"], [
  80     # If intltool is not available, provide a dummy rule to fail generation of %.policy files with a meaningful error message
  81     INTLTOOL_POLICY_RULE='%.policy: %.policy.in ; @echo "  ITMRG   " $@ && echo "*** intltool support required to build target $@" && false'
  82     AC_SUBST(INTLTOOL_POLICY_RULE)
  83 ])
  84
  85 GETTEXT_PACKAGE=systemd
  86 AC_SUBST(GETTEXT_PACKAGE)
  87 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [systemd])
  88
  89 AC_PROG_MKDIR_P
  90 AC_PROG_LN_S
  91 AC_PROG_SED
  92 AC_PROG_GREP
  93 AC_PROG_AWK
  94
  95 AC_PATH_PROG([M4], [m4])
  96
  97 AC_PATH_PROG([QUOTAON], [quotaon], [/usr/sbin/quotaon], [$PATH:/usr/sbin:/sbin])
  98 AC_PATH_PROG([QUOTACHECK], [quotacheck], [/usr/sbin/quotacheck], [$PATH:/usr/sbin:/sbin])
  99
 100 AC_PATH_PROG([SETCAP], [setcap], [/usr/sbin/setcap], [$PATH:/usr/sbin:/sbin])
 101
 102 AC_PATH_PROG([KILL], [kill], [/usr/bin/kill], [$PATH:/usr/sbin:/sbin])
 103
 104 AC_PATH_PROG([KMOD], [kmod], [/usr/bin/kmod], [$PATH:/usr/sbin:/sbin])
 105
 106 AC_PATH_PROG([KEXEC], [kexec], [/usr/sbin/kexec], [$PATH:/usr/sbin:/sbin])
 107
 108 AC_PATH_PROG([SULOGIN], [sulogin], [/usr/sbin/sulogin], [$PATH:/usr/sbin:/sbin])
 109
 110 AC_PATH_PROG([MOUNT_PATH], [mount], [/usr/bin/mount], [$PATH:/usr/sbin:/sbin])
 111 AC_PATH_PROG([UMOUNT_PATH], [umount], [/usr/bin/umount], [$PATH:/usr/sbin:/sbin])
 112
 113 AS_IF([! ln --relative --help > /dev/null 2>&1], [AC_MSG_ERROR([*** ln doesn't support --relative ***])])
 114
 115 M4_DEFINES=
 116
 117 AC_CHECK_TOOL(OBJCOPY, objcopy)
 118 AC_CHECK_TOOL(STRINGS, strings)
 119 AC_CHECK_TOOL(GPERF, gperf)
 120 if test -z "$GPERF" ; then
 121         AC_MSG_ERROR([*** gperf not found])
 122 fi
 123
 124 # ------------------------------------------------------------------------------
 125 address_sanitizer_cflags=
 126 address_sanitizer_cppflags=
 127 address_sanitizer_ldflags=
 128 AC_ARG_ENABLE(address-sanitizer, AS_HELP_STRING([--enable-address-sanitizer], [enable -fsanitize=address]))
 129 AS_IF([test "x$enable_address_sanitizer" = "xyes"], [
 130             CC_CHECK_FLAG_APPEND([with_as_cflags], [CFLAGS], [-fsanitize=address])
 131             AS_IF([test -z "$with_as_cflags"],
 132                   [AC_MSG_ERROR([*** -fsanitize=address is not supported])])
 133             address_sanitizer_cflags="$with_as_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 134             address_sanitizer_cppflags="-DVALGRIND=1"
 135             address_sanitizer_ldflags="-Wc,-fsanitize=address"
 136       ])
 137
 138 undefined_sanitizer_cflags=
 139 undefined_sanitizer_cppflags=
 140 undefined_sanitizer_ldflags=
 141 AC_ARG_ENABLE(undefined-sanitizer, AS_HELP_STRING([--enable-undefined-sanitizer], [enable -fsanitize=undefined]))
 142 AS_IF([test "x$enable_undefined_sanitizer" = "xyes"], [
 143             CC_CHECK_FLAG_APPEND([with_us_cflags], [CFLAGS], [-fsanitize=undefined])
 144             AS_IF([test -z "$with_us_cflags"],
 145                   [AC_MSG_ERROR([*** -fsanitize=undefined is not supported])])
 146             undefined_sanitizer_cflags="$with_us_cflags -fno-omit-frame-pointer -DVALGRIND=1"
 147             undefined_sanitizer_cppflags="-DVALGRIND=1"
 148             undefined_sanitizer_ldflags="-Wc,-fsanitize=undefined"
 149       ])
 150
 151 sanitizer_cflags="$address_sanitizer_cflags $undefined_sanitizer_cflags"
 152 sanitizer_cppflags="$address_sanitizer_cppflags $undefined_sanitizer_cppflags"
 153 sanitizer_ldflags="$address_sanitizer_ldflags $undefined_sanitizer_ldflags"
 154
 155 CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 156         -pipe \
 157         -Wall \
 158         -Wextra \
 159         -Wundef \
 160         "-Wformat=2 -Wformat-security -Wformat-nonliteral" \
 161         -Wlogical-op \
 162         -Wmissing-include-dirs \
 163         -Wold-style-definition \
 164         -Wpointer-arith \
 165         -Winit-self \
 166         -Wdeclaration-after-statement \
 167         -Wfloat-equal \
 168         -Wsuggest-attribute=noreturn \
 169         -Werror=missing-prototypes \
 170         -Werror=implicit-function-declaration \
 171         -Werror=missing-declarations \
 172         -Werror=return-type \
 173         -Wstrict-prototypes \
 174         -Wredundant-decls \
 175         -Wmissing-noreturn \
 176         -Wshadow \
 177         -Wendif-labels \
 178         -Wstrict-aliasing=2 \
 179         -Wwrite-strings \
 180         -Wno-unused-parameter \
 181         -Wno-missing-field-initializers \
 182         -Wno-unused-result \
 183         -Wno-format-signedness \
 184         -Werror=overflow \
 185         -Wdate-time \
 186         -Wnested-externs \
 187         -ffast-math \
 188         -fno-common \
 189         -fdiagnostics-show-option \
 190         -fno-strict-aliasing \
 191         -fvisibility=hidden \
 192         -fstack-protector \
 193         -fstack-protector-strong \
 194         -fPIE \
 195         --param=ssp-buffer-size=4])
 196
 197 CC_CHECK_FLAG_APPEND([with_cflags], [CFLAGS], [-Werror=shadow], [
 198 #include <time.h>
 199 #include <inttypes.h>
 200 typedef uint64_t usec_t;
 201 usec_t now(clockid_t clock);
 202 int main(void) {
 203         struct timespec now;
 204         return 0;
 205 }
 206 ])
 207
 208 AS_CASE([$CC], [*clang*],
 209         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 210                -Wno-typedef-redefinition \
 211                -Wno-gnu-variable-sized-type-not-at-end \
 212         ])])
 213
 214 AC_ARG_ENABLE([lto], [AS_HELP_STRING([--disable-lto], [disable -flto])],
 215                      [], [enable_lto=yes])
 216 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 217         [AS_IF([test "x$enable_lto" = "xyes"],
 218                [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [-flto])],
 219                [AC_MSG_RESULT([disabling -flto as requested])])],
 220         [AC_MSG_RESULT([skipping -flto, optimization not enabled])])
 221 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 222
 223 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 224         [CC_CHECK_FLAGS_APPEND([with_cppflags], [CPPFLAGS], [\
 225                -Wp,-D_FORTIFY_SOURCE=2])],
 226         [AC_MSG_RESULT([skipping -D_FORTIFY_SOURCE, optimization not enabled])])
 227 AC_SUBST([OUR_CPPFLAGS], "$with_cppflags $sanitizer_cppflags")
 228
 229 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 230         [CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 231                -Wl,--gc-sections])],
 232         [AC_MSG_RESULT([skipping --gc-sections, optimization not enabled])])
 233 AC_SUBST([OUR_CFLAGS], "$with_ldflags $sanitizer_cflags")
 234
 235 AS_CASE([$CFLAGS], [*-O[[12345sz\ ]]*],
 236         [CC_CHECK_FLAGS_APPEND([with_cflags], [CFLAGS], [\
 237                -ffunction-sections -fdata-sections])],
 238         [AC_MSG_RESULT([skipping -ffunction/data-section, optimization not enabled])])
 239 AC_SUBST([OUR_CFLAGS], "$with_cflags $sanitizer_cflags")
 240
 241 CC_CHECK_FLAGS_APPEND([with_ldflags], [LDFLAGS], [\
 242         -Wl,--as-needed \
 243         -Wl,--no-undefined \
 244         -Wl,-z,relro \
 245         -Wl,-z,now \
 246         -pie \
 247         -Wl,-fuse-ld=gold])
 248 AC_SUBST([OUR_LDFLAGS], "$with_ldflags $sanitizer_ldflags")
 249
 250 AC_CHECK_SIZEOF(pid_t)
 251 AC_CHECK_SIZEOF(uid_t)
 252 AC_CHECK_SIZEOF(gid_t)
 253 AC_CHECK_SIZEOF(time_t)
 254 AC_CHECK_SIZEOF(dev_t)
 255 AC_CHECK_SIZEOF(ino_t)
 256 AC_CHECK_SIZEOF(rlim_t,,[
 257        #include <sys/time.h>
 258        #include <sys/resource.h>
 259 ])
 260
 261 # ------------------------------------------------------------------------------
 262 # we use python to build the man page index
 263 have_python=no
 264 AC_ARG_WITH([python],
 265         [AS_HELP_STRING([--without-python], [Disable building the man page index and systemd-python (default: test)])])
 266
 267 have_lxml=no
 268 AS_IF([test "x$with_python" != "xno"], [
 269         AM_PATH_PYTHON(,, [:])
 270         AS_IF([test "x$PYTHON" != "x:"], [
 271                 AC_MSG_CHECKING([for python lxml module])
 272                 AS_IF(["$PYTHON" -c 'import lxml' 2>/dev/null], [have_lxml=yes])
 273                 AC_MSG_RESULT([$have_lxml])
 274                 AS_IF([test "x$have_lxml" = "xyes"], [have_python=yes],
 275                       [AC_MSG_WARN([*** python support requires python-lxml module installed])])
 276         ])
 277 ])
 278 AS_IF([test "$have_python" != "yes"], [
 279       AS_IF([test "$with_python" = "yes"],
 280             [AC_MSG_ERROR([*** python support requested but python support not found])])
 281       AS_IF([test "$with_python" != "no"],
 282             [AC_MSG_WARN([*** python support not found, some documentation cannot be built])])
 283 ])
 284 AM_CONDITIONAL([HAVE_PYTHON], [test "x$have_python" = "xyes"])
 285
 286 # ------------------------------------------------------------------------------
 287
 288 AC_CHECK_HEADERS([sys/capability.h], [], [AC_MSG_ERROR([*** POSIX caps headers not found])])
 289 AC_CHECK_HEADERS([linux/btrfs.h], [], [])
 290 AC_CHECK_HEADERS([linux/memfd.h], [], [])
 291
 292 # unconditionally pull-in librt with old glibc versions
 293 AC_SEARCH_LIBS([clock_gettime], [rt], [], [])
 294
 295 save_LIBS="$LIBS"
 296 LIBS=
 297 AC_SEARCH_LIBS([cap_init], [cap], [], [AC_MSG_ERROR([*** POSIX caps library not found])])
 298 CAP_LIBS="$LIBS"
 299 LIBS="$save_LIBS"
 300 AC_SUBST(CAP_LIBS)
 301
 302 AC_CHECK_FUNCS([__secure_getenv secure_getenv])
 303 AC_CHECK_DECLS([
 304         memfd_create,
 305         gettid,
 306         pivot_root,
 307         name_to_handle_at,
 308         setns,
 309         getrandom,
 310         renameat2,
 311         kcmp,
 312         keyctl,
 313         LO_FLAGS_PARTSCAN,
 314         copy_file_range],
 315         [], [], [[
 316 #include <sys/types.h>
 317 #include <unistd.h>
 318 #include <sys/mount.h>
 319 #include <fcntl.h>
 320 #include <sched.h>
 321 #include <linux/loop.h>
 322 #include <linux/random.h>
 323 ]])
 324
 325 AC_CHECK_TYPES([char16_t, char32_t, key_serial_t],
 326                [], [], [[
 327 #include <uchar.h>
 328 ]])
 329
 330 AC_CHECK_DECLS([IFLA_INET6_ADDR_GEN_MODE,
 331                 IN6_ADDR_GEN_MODE_STABLE_PRIVACY,
 332                 IFLA_VRF_TABLE,
 333                 IFLA_MACVLAN_FLAGS,
 334                 IFLA_IPVLAN_MODE,
 335                 IFLA_VTI_REMOTE,
 336                 IFLA_PHYS_PORT_ID,
 337                 IFLA_BOND_AD_INFO,
 338                 IFLA_VLAN_PROTOCOL,
 339                 IFLA_VXLAN_REMCSUM_NOPARTIAL,
 340                 IFLA_IPTUN_ENCAP_DPORT,
 341                 IFLA_GRE_ENCAP_DPORT,
 342                 IFLA_BRIDGE_VLAN_INFO,
 343                 IFLA_BRPORT_PROXYARP,
 344                 IFLA_BRPORT_LEARNING_SYNC,
 345                 IFLA_BR_VLAN_DEFAULT_PVID,
 346                 NDA_IFINDEX,
 347                 IFA_FLAGS],
 348 [], [], [[
 349 #include <inttypes.h>
 350 #include <netinet/in.h>
 351 #include <netinet/ether.h>
 352 #include <linux/rtnetlink.h>
 353 #include <net/if.h>
 354 #include <linux/ip.h>
 355 #include <linux/if_tunnel.h>
 356 #include <linux/if_link.h>
 357 #include <linux/if_bridge.h>
 358 #include <linux/if_addr.h>
 359 #include <linux/neighbour.h>
 360 ]])
 361
 362 # This makes sure pkg.m4 is available.
 363 m4_pattern_forbid([^_?PKG_[A-Z_]+$],[*** pkg.m4 missing, please install pkg-config])
 364
 365 # ------------------------------------------------------------------------------
 366 have_dbus=no
 367 AC_ARG_ENABLE(dbus, AS_HELP_STRING([--disable-dbus], [disable usage of dbus-1 in tests]))
 368 AS_IF([test "x$enable_dbus" != "xno"], [
 369         PKG_CHECK_MODULES(DBUS, [dbus-1 >= 1.3.2],
 370                 [AC_DEFINE(HAVE_DBUS, 1, [Define if dbus-1 library is available]) have_dbus=yes],
 371                 [have_dbus=no])
 372         AS_IF([test "x$have_dbus" = "xno" -a "x$enable_dbus" = "xyes"],
 373                 [AC_MSG_ERROR([*** dbus-1 support requested but libraries not found])])])
 374 AM_CONDITIONAL(HAVE_DBUS, [test "$have_dbus" = "yes"])
 375
 376 # ------------------------------------------------------------------------------
 377 have_utmp=yes
 378 AC_ARG_ENABLE([utmp], AS_HELP_STRING([--disable-utmp], [disable utmp/wtmp log handling]),
 379         AS_CASE("x${enableval}",
 380                 [xyes], [have_utmp=yes],
 381                 [xno],  [have_utmp=no],
 382                 AC_MSG_ERROR(bad value ${enableval} for --enable-utmp)))
 383 AS_IF([test "x$have_utmp" = "xyes"], [AC_DEFINE(HAVE_UTMP, 1, [Define if utmp/wtmp support is enabled])])
 384 AM_CONDITIONAL([HAVE_UTMP], [test "x$have_utmp" = "xyes"])
 385
 386 # ------------------------------------------------------------------------------
 387 have_coverage=no
 388 AC_ARG_ENABLE(coverage, AS_HELP_STRING([--enable-coverage], [enable test coverage]))
 389 if test "x$enable_coverage" = "xyes" ; then
 390         AC_CHECK_PROG(lcov_found, [lcov], [yes], [no])
 391         if test "x$lcov_found" = xno ; then
 392                 AC_MSG_ERROR([*** lcov support requested but the program was not found])
 393         else
 394                 lcov_version_major="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 1`"
 395                 lcov_version_minor="`lcov --version | cut -d ' ' -f 4 | cut -d '.' -f 2`"
 396                 if test "$lcov_version_major" -eq 1 -a "$lcov_version_minor" -lt 10; then
 397                         AC_MSG_ERROR([*** lcov version is too old. 1.10 required])
 398                 else
 399                         have_coverage=yes
 400                         CC_CHECK_FLAGS_APPEND([with_coverage_cflags], [CFLAGS], [\
 401                         -fprofile-arcs \
 402                         -ftest-coverage])
 403                         AC_SUBST([OUR_CFLAGS], "$with_cflags $with_coverage_cflags")
 404                 fi
 405         fi
 406 fi
 407 AM_CONDITIONAL(ENABLE_COVERAGE, [test "$have_coverage" = "yes"])
 408
 409 # ------------------------------------------------------------------------------
 410 have_kmod=no
 411 AC_ARG_ENABLE(kmod, AS_HELP_STRING([--disable-kmod], [disable loadable modules support]))
 412 if test "x$enable_kmod" != "xno"; then
 413         PKG_CHECK_EXISTS([ libkmod ], have_kmod=yes, have_kmod=no)
 414         if test "x$have_kmod" = "xyes"; then
 415                 PKG_CHECK_MODULES(KMOD, [ libkmod >= 15 ],
 416                         [AC_DEFINE(HAVE_KMOD, 1, [Define if kmod is available])],
 417                         AC_MSG_ERROR([*** kmod version >= 15 not found]))
 418         fi
 419         if test "x$have_kmod" = xno -a "x$enable_kmod" = xyes; then
 420                 AC_MSG_ERROR([*** kmod support requested, but libraries not found])
 421         fi
 422 fi
 423 AM_CONDITIONAL(HAVE_KMOD, [test "$have_kmod" = "yes"])
 424
 425 # ------------------------------------------------------------------------------
 426 have_xkbcommon=no
 427 AC_ARG_ENABLE(xkbcommon, AS_HELP_STRING([--disable-xkbcommon], [disable xkbcommon keymap support]))
 428 if test "x$enable_xkbcommon" != "xno"; then
 429         PKG_CHECK_MODULES(XKBCOMMON, [ xkbcommon >= 0.3.0 ],
 430                 [AC_DEFINE(HAVE_XKBCOMMON, 1, [Define if libxkbcommon is available]) have_xkbcommon=yes], have_xkbcommon=no)
 431         if test "x$have_xkbcommon" = xno -a "x$enable_xkbcommon" = xyes; then
 432                 AC_MSG_ERROR([*** xkbcommon support requested but libraries not found])
 433         fi
 434 fi
 435 AM_CONDITIONAL(HAVE_XKBCOMMON, [test "$have_xkbcommon" = "yes"])
 436
 437 # ------------------------------------------------------------------------------
 438 have_blkid=no
 439 AC_ARG_ENABLE(blkid, AS_HELP_STRING([--disable-blkid], [disable blkid support]))
 440 if test "x$enable_blkid" != "xno"; then
 441         PKG_CHECK_MODULES(BLKID, [ blkid >= 2.24 ],
 442                 [AC_DEFINE(HAVE_BLKID, 1, [Define if blkid is available]) have_blkid=yes], have_blkid=no)
 443         if test "x$have_blkid" = xno -a "x$enable_blkid" = xyes; then
 444                 AC_MSG_ERROR([*** blkid support requested but libraries not found])
 445         fi
 446 fi
 447 AM_CONDITIONAL(HAVE_BLKID, [test "$have_blkid" = "yes"])
 448
 449 # ------------------------------------------------------------------------------
 450 have_libmount=no
 451 PKG_CHECK_MODULES(MOUNT, [ mount >= 2.27 ],
 452         [AC_DEFINE(HAVE_LIBMOUNT, 1, [Define if libmount is available]) have_libmount=yes], have_libmount=no)
 453 if test "x$have_libmount" = xno; then
 454         AC_MSG_ERROR([*** libmount support required but libraries not found])
 455 fi
 456 AM_CONDITIONAL(HAVE_LIBMOUNT, [test "$have_libmount" = "yes"])
 457
 458 # ------------------------------------------------------------------------------
 459 have_seccomp=no
 460 AC_ARG_ENABLE(seccomp, AS_HELP_STRING([--disable-seccomp], [Disable optional SECCOMP support]))
 461 if test "x$enable_seccomp" != "xno"; then
 462         PKG_CHECK_MODULES(SECCOMP, [libseccomp >= 1.0.0],
 463                [AC_DEFINE(HAVE_SECCOMP, 1, [Define if seccomp is available])
 464                 have_seccomp=yes
 465                 M4_DEFINES="$M4_DEFINES -DHAVE_SECCOMP"],
 466                [have_seccomp=no])
 467         if test "x$have_seccomp" = "xno" -a "x$enable_seccomp" = "xyes"; then
 468                 AC_MSG_ERROR([*** seccomp support requested but libraries not found])
 469         fi
 470 fi
 471 AM_CONDITIONAL(HAVE_SECCOMP, [test "$have_seccomp" = "yes"])
 472
 473 # ------------------------------------------------------------------------------
 474 have_ima=yes
 475 AC_ARG_ENABLE([ima], AS_HELP_STRING([--disable-ima],[Disable optional IMA support]),
 476                 [case "${enableval}" in
 477                         yes) have_ima=yes ;;
 478                         no) have_ima=no ;;
 479                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-ima) ;;
 480                 esac],
 481                 [have_ima=yes])
 482
 483 if test "x${have_ima}" != xno ; then
 484         AC_DEFINE(HAVE_IMA, 1, [Define if IMA is available])
 485 fi
 486
 487 # ------------------------------------------------------------------------------
 488 have_selinux=no
 489 AC_ARG_ENABLE(selinux, AS_HELP_STRING([--disable-selinux], [Disable optional SELINUX support]))
 490 if test "x$enable_selinux" != "xno"; then
 491         PKG_CHECK_MODULES([SELINUX], [libselinux >= 2.1.9],
 492                 [AC_DEFINE(HAVE_SELINUX, 1, [Define if SELinux is available])
 493                  have_selinux=yes
 494                  M4_DEFINES="$M4_DEFINES -DHAVE_SELINUX"],
 495                 [have_selinux=no])
 496         if test "x$have_selinux" = xno -a "x$enable_selinux" = xyes; then
 497                 AC_MSG_ERROR([*** SELinux support requested but libraries not found])
 498         fi
 499 fi
 500 AM_CONDITIONAL(HAVE_SELINUX, [test "$have_selinux" = "yes"])
 501
 502 have_apparmor=no
 503 AC_ARG_ENABLE(apparmor, AS_HELP_STRING([--disable-apparmor], [Disable optional AppArmor support]))
 504 if test "x$enable_apparmor" != "xno"; then
 505         PKG_CHECK_MODULES([APPARMOR], [libapparmor],
 506                 [AC_DEFINE(HAVE_APPARMOR, 1, [Define if AppArmor is available])
 507                  have_apparmor=yes
 508                  M4_DEFINES="$M4_DEFINES -DHAVE_APPARMOR"],
 509                 [have_apparmor=no])
 510         if test "x$have_apparmor" = xno -a "x$enable_apparmor" = xyes; then
 511                 AC_MSG_ERROR([*** AppArmor support requested but libraries not found])
 512         fi
 513 fi
 514 AM_CONDITIONAL(HAVE_APPARMOR, [test "$have_apparmor" = "yes"])
 515
 516 have_adm_group=no
 517 AC_ARG_ENABLE(adm-group, AS_HELP_STRING([--disable-adm-group], [disable adm group]))
 518 AS_IF([test "x$enable_adm_group" != "xno"], [
 519         AC_DEFINE(ENABLE_ADM_GROUP, 1, [Define if the ACL for adm group should be enabled])
 520         have_adm_group=yes
 521         M4_DEFINES="$M4_DEFINES -DENABLE_ADM_GROUP"
 522 ])
 523
 524 have_wheel_group=no
 525 AC_ARG_ENABLE(wheel-group, AS_HELP_STRING([--disable-wheel-group], [disable wheel group]))
 526 AS_IF([test "x$enable_wheel_group" != "xno"], [
 527         AC_DEFINE(ENABLE_WHEEL_GROUP, 1, [Define if the ACL for wheel group should be enabled])
 528         have_wheel_group=yes
 529         M4_DEFINES="$M4_DEFINES -DENABLE_WHEEL_GROUP"
 530 ])
 531
 532
 533 AC_ARG_WITH(debug-shell,
 534         AS_HELP_STRING([--with-debug-shell=PATH],
 535                 [Path to debug shell binary]),
 536         [SUSHELL="$withval"],[
 537         AS_IF([test "x${have_selinux}" != "xno"], [SUSHELL="/sbin/sushell"] , [SUSHELL="/bin/sh"])])
 538
 539 AC_SUBST(SUSHELL)
 540
 541 AC_ARG_WITH([debug-tty],
 542         AS_HELP_STRING([--with-debug-tty=PATH],
 543                 [Specify the tty device for debug shell]),
 544         [DEBUGTTY="$withval"],
 545         [DEBUGTTY=/dev/tty9])
 546
 547 AC_SUBST(DEBUGTTY)
 548
 549 AC_ARG_WITH([certificate-root],
 550         AS_HELP_STRING([--with-certificate-root=PATH],
 551                 [Specify the prefix for TLS certificates [/etc/ssl]]),
 552         [CERTIFICATEROOT="$withval"],
 553         [CERTIFICATEROOT="/etc/ssl"])
 554
 555 AC_SUBST(CERTIFICATEROOT)
 556
 557 AC_ARG_WITH([support-url],
 558         AS_HELP_STRING([--with-support-url=URL],
 559                 [Specify the supoport URL to show in catalog entries included in systemd]),
 560         [SUPPORT_URL="$withval"],
 561         [SUPPORT_URL=http://lists.freedesktop.org/mailman/listinfo/systemd-devel])
 562
 563 AC_SUBST(SUPPORT_URL)
 564
 565 # ------------------------------------------------------------------------------
 566 have_xz=no
 567 AC_ARG_ENABLE(xz, AS_HELP_STRING([--disable-xz], [Disable optional XZ support]))
 568 AS_IF([test "x$enable_xz" != "xno"], [
 569         PKG_CHECK_MODULES(XZ, [ liblzma ],
 570                 [AC_DEFINE(HAVE_XZ, 1, [Define if XZ is available])
 571                  have_xz=yes],
 572                  have_xz=no)
 573         AS_IF([test "x$have_xz" = xno -a "x$enable_xz" = xyes],
 574               [AC_MSG_ERROR([*** XZ support requested but libraries not found])])
 575 ])
 576 AM_CONDITIONAL(HAVE_XZ, [test "$have_xz" = "yes"])
 577
 578 # ------------------------------------------------------------------------------
 579 have_zlib=no
 580 AC_ARG_ENABLE(zlib, AS_HELP_STRING([--disable-zlib], [Disable optional ZLIB support]))
 581 AS_IF([test "x$enable_zlib" != "xno"], [
 582         PKG_CHECK_MODULES(ZLIB, [ zlib ],
 583                 [AC_DEFINE(HAVE_ZLIB, 1, [Define if ZLIB is available])
 584                  have_zlib=yes],
 585                  have_zlib=no)
 586         AS_IF([test "x$have_zlib" = xno -a "x$enable_zlib" = xyes],
 587               [AC_MSG_ERROR([*** ZLIB support requested but libraries not found])])
 588 ])
 589 AM_CONDITIONAL(HAVE_ZLIB, [test "$have_zlib" = "yes"])
 590
 591 # ------------------------------------------------------------------------------
 592 have_bzip2=no
 593 AC_ARG_ENABLE(bzip2, AS_HELP_STRING([--enable-bzip2], [Enable optional BZIP2 support]))
 594 AS_IF([test "x$enable_bzip2" != "xno"], [
 595         AC_CHECK_HEADERS(bzlib.h,
 596                 [AC_DEFINE(HAVE_BZIP2, 1, [Define if BZIP2 is available])
 597                  have_bzip2=yes],
 598                 [AS_IF([test "x$enable_bzip2" = xyes],
 599                        [AC_MSG_ERROR([*** BZIP2 support requested but headers not found])])]
 600         )
 601 ])
 602 AM_CONDITIONAL(HAVE_BZIP2, [test "$have_bzip2" = "yes"])
 603
 604 # ------------------------------------------------------------------------------
 605 have_lz4=no
 606 AC_ARG_ENABLE(lz4, AS_HELP_STRING([--disable-lz4], [Disable optional LZ4 support]))
 607 AS_IF([test "x$enable_lz4" != "xno"], [
 608         PKG_CHECK_MODULES(LZ4, [ liblz4 >= 125 ],
 609                [AC_DEFINE(HAVE_LZ4, 1, [Define in LZ4 is available])
 610                 have_lz4=yes],
 611                 have_lz4=no)
 612         AS_IF([test "x$have_lz4" = xno -a "x$enable_lz4" = xyes],
 613               [AC_MSG_ERROR([*** LZ4 support requested but libraries not found])])
 614 ])
 615 AM_CONDITIONAL(HAVE_LZ4, [test "$have_lz4" = "yes"])
 616
 617 AM_CONDITIONAL(HAVE_COMPRESSION, [test "$have_xz" = "yes" -o "$have_lz4" = "yes"])
 618
 619 # ------------------------------------------------------------------------------
 620 AC_ARG_ENABLE([pam],
 621         AS_HELP_STRING([--disable-pam],[Disable optional PAM support]),
 622                 [case "${enableval}" in
 623                         yes) have_pam=yes ;;
 624                         no) have_pam=no ;;
 625                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-pam) ;;
 626                 esac],
 627                 [have_pam=auto])
 628
 629 if test "x${have_pam}" != xno ; then
 630         AC_CHECK_HEADERS(
 631                 [security/pam_modules.h security/pam_modutil.h security/pam_ext.h],
 632                 [have_pam=yes],
 633                 [if test "x$have_pam" = xyes ; then
 634                         AC_MSG_ERROR([*** PAM headers not found.])
 635                 fi])
 636
 637         AC_CHECK_LIB(
 638                 [pam],
 639                 [pam_syslog],
 640                 [have_pam=yes],
 641                 [if test "x$have_pam" = xyes ; then
 642                         AC_MSG_ERROR([*** libpam not found.])
 643                 fi])
 644
 645         if test "x$have_pam" = xyes ; then
 646                 PAM_LIBS="-lpam -lpam_misc"
 647                 AC_DEFINE(HAVE_PAM, 1, [PAM available])
 648                 M4_DEFINES="$M4_DEFINES -DHAVE_PAM"
 649         else
 650                 have_pam=no
 651         fi
 652 else
 653         PAM_LIBS=
 654 fi
 655 AC_SUBST(PAM_LIBS)
 656 AM_CONDITIONAL([HAVE_PAM], [test "x$have_pam" != xno])
 657
 658 # ------------------------------------------------------------------------------
 659 AC_ARG_ENABLE([acl],
 660         AS_HELP_STRING([--disable-acl],[Disable optional ACL support]),
 661                 [case "${enableval}" in
 662                         yes) have_acl=yes ;;
 663                         no) have_acl=no ;;
 664                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-acl) ;;
 665                 esac],
 666                 [have_acl=auto])
 667
 668 if test "x${have_acl}" != xno ; then
 669         AC_CHECK_HEADERS(
 670                 [sys/acl.h acl/libacl.h],
 671                 [have_acl=yes],
 672                 [if test "x$have_acl" = xyes ; then
 673                         AC_MSG_ERROR([*** ACL headers not found.])
 674                 fi])
 675
 676         AC_CHECK_LIB(
 677                 [acl],
 678                 [acl_get_file],
 679                 [have_acl=yes],
 680                 [if test "x$have_acl" = xyes ; then
 681                         AC_MSG_ERROR([*** libacl not found.])
 682                 fi])
 683
 684         if test "x$have_acl" = xyes ; then
 685                 ACL_LIBS="-lacl"
 686                 AC_DEFINE(HAVE_ACL, 1, [ACL available])
 687                 M4_DEFINES="$M4_DEFINES -DHAVE_ACL"
 688         else
 689                 have_acl=no
 690         fi
 691 else
 692         ACL_LIBS=
 693 fi
 694 AC_SUBST(ACL_LIBS)
 695 AM_CONDITIONAL([HAVE_ACL], [test "x$have_acl" != xno])
 696
 697 # ------------------------------------------------------------------------------
 698 AC_ARG_ENABLE([smack], AS_HELP_STRING([--disable-smack],[Disable optional SMACK support]),
 699                 [case "${enableval}" in
 700                         yes) have_smack=yes ;;
 701                         no) have_smack=no ;;
 702                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-smack) ;;
 703                 esac],
 704                 [have_smack=auto])
 705
 706 if test "x${have_smack}" != xno; then
 707         AC_DEFINE(HAVE_SMACK, 1, [Define if SMACK is available])
 708         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK"
 709         have_smack=yes
 710 fi
 711
 712 AM_CONDITIONAL([HAVE_SMACK], [test "x$have_smack" = "xyes"])
 713
 714 have_smack_run_label=no
 715 AC_ARG_WITH(smack-run-label,
 716 AS_HELP_STRING([--with-smack-run-label=STRING],
 717         [run systemd --system itself with a specific SMACK label]),
 718         [AC_DEFINE_UNQUOTED(SMACK_RUN_LABEL, ["$withval"], [Run systemd itself with SMACK label]) have_smack_run_label=yes],
 719         [])
 720
 721 if test "x${have_smack_run_label}" = xyes; then
 722         M4_DEFINES="$M4_DEFINES -DHAVE_SMACK_RUN_LABEL"
 723 fi
 724
 725 AC_ARG_WITH(smack-default-process-label,
 726 AS_HELP_STRING([--with-smack-default-process-label=STRING],
 727         [default SMACK label for executed processes]),
 728         [AC_DEFINE_UNQUOTED(SMACK_DEFAULT_PROCESS_LABEL, ["$withval"], [Default SMACK label for executed processes])],
 729         [])
 730
 731 # ------------------------------------------------------------------------------
 732 AC_ARG_ENABLE([gcrypt],
 733         AS_HELP_STRING([--disable-gcrypt],[Disable optional GCRYPT support]),
 734                 [case "${enableval}" in
 735                         yes) have_gcrypt=yes ;;
 736                         no) have_gcrypt=no ;;
 737                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-gcrypt) ;;
 738                 esac],
 739                 [have_gcrypt=auto])
 740
 741 if test "x${have_gcrypt}" != xno ; then
 742         m4_define([AM_PATH_LIBGCRYPT_FAIL],
 743                 [{ test "x$have_gcrypt" != xyes || AC_MSG_ERROR([*** GCRYPT/GPG-ERROR headers not found.]); }]
 744         )
 745         m4_ifdef([AM_PATH_LIBGCRYPT], [AM_PATH_LIBGCRYPT(
 746                         [1.4.5],
 747                         [have_gcrypt=yes],
 748                         dnl  If we have the gcrypt m4 macros, but don't have
 749                         dnl  gcrypt, throw an error if gcrypt is explicitly
 750                         dnl  requested.
 751                         [AM_PATH_LIBGCRYPT_FAIL]
 752                 )],
 753                 dnl  If we don't have the gcrypt m4 macros, but build with
 754                 dnl  gcrypt explicitly requested, throw an error.
 755                 [AM_PATH_LIBGCRYPT_FAIL]
 756         )
 757
 758         have_gpg_error=no
 759         m4_ifdef([AM_PATH_GPG_ERROR], [AM_PATH_GPG_ERROR(
 760                         [1.12],
 761                         [have_gpg_error=yes],
 762                         [AM_PATH_LIBGCRYPT_FAIL]
 763                 )],
 764                 [AM_PATH_LIBGCRYPT_FAIL]
 765         )
 766
 767         if test "x$have_gcrypt" = xyes -a "x$have_gpg_error" = xyes ; then
 768                 GCRYPT_LIBS="$LIBGCRYPT_LIBS $GPG_ERROR_LIBS"
 769                 GCRYPT_CFLAGS="$LIBGCRYPT_CFLAGS $GPG_ERROR_CFLAGS"
 770                 AC_DEFINE(HAVE_GCRYPT, 1, [GCRYPT available])
 771         else
 772                 have_gcrypt=no
 773                 have_gpg_error=no
 774         fi
 775 else
 776         GCRYPT_LIBS=
 777         GCRYPT_CFLAGS=
 778 fi
 779 AC_SUBST(GCRYPT_LIBS)
 780 AC_SUBST(GCRYPT_CFLAGS)
 781 AM_CONDITIONAL([HAVE_GCRYPT], [test "x$have_gcrypt" != xno])
 782
 783 # ------------------------------------------------------------------------------
 784 AC_ARG_ENABLE([audit],
 785         AS_HELP_STRING([--disable-audit],[Disable optional AUDIT support]),
 786                 [case "${enableval}" in
 787                         yes) have_audit=yes ;;
 788                         no) have_audit=no ;;
 789                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-audit) ;;
 790                 esac],
 791                 [have_audit=auto])
 792
 793 if test "x${have_audit}" != xno ; then
 794         AC_CHECK_HEADERS(
 795                 [libaudit.h],
 796                 [have_audit=yes],
 797                 [if test "x$have_audit" = xyes ; then
 798                         AC_MSG_ERROR([*** AUDIT headers not found.])
 799                 fi])
 800
 801         AC_CHECK_LIB(
 802                 [audit],
 803                 [audit_open],
 804                 [have_audit=yes],
 805                 [if test "x$have_audit" = xyes ; then
 806                         AC_MSG_ERROR([*** libaudit not found.])
 807                 fi])
 808
 809         if test "x$have_audit" = xyes ; then
 810                 AUDIT_LIBS="-laudit"
 811                 AC_DEFINE(HAVE_AUDIT, 1, [AUDIT available])
 812         else
 813                 have_audit=no
 814         fi
 815 else
 816         AUDIT_LIBS=
 817 fi
 818 AC_SUBST(AUDIT_LIBS)
 819 AM_CONDITIONAL([HAVE_AUDIT], [test "x$have_audit" != xno])
 820
 821 # ------------------------------------------------------------------------------
 822 AC_ARG_ENABLE([elfutils],
 823         AS_HELP_STRING([--disable-elfutils],[Disable optional ELFUTILS support]),
 824                 [case "${enableval}" in
 825                         yes) have_elfutils=yes ;;
 826                         no) have_elfutils=no ;;
 827                         *) AC_MSG_ERROR(bad value ${enableval} for --disable-elfutils) ;;
 828                 esac],
 829                 [have_elfutils=auto])
 830
 831 if test "x${have_elfutils}" != xno ; then
 832         AC_CHECK_HEADERS(
 833                 [elfutils/libdwfl.h],
 834                 [],
 835                 [if test "x$have_elfutils" = xyes ; then
 836                         AC_MSG_ERROR([*** ELFUTILS headers not found.])
 837                 fi])
 838
 839         AC_CHECK_LIB(
 840                 [dw],
 841                 [dwfl_core_file_attach],
 842                 [have_elfutils=yes],
 843                 [if test "x$have_elfutils" = xyes ; then
 844                         AC_MSG_ERROR([*** ELFUTILS >= 158 is required.])
 845                 fi])
 846
 847         if test "x$have_elfutils" = xyes ; then
 848                 ELFUTILS_LIBS="-lelf -ldw"
 849                 AC_DEFINE(HAVE_ELFUTILS, 1, [ELFUTILS available])
 850         else
 851                 have_elfutils=no
 852         fi
 853 else
 854         ELFUTILS_LIBS=
 855 fi
 856 AC_SUBST(ELFUTILS_LIBS)
 857 AM_CONDITIONAL(HAVE_ELFUTILS, [test "$have_elfutils" = "yes"])
 858
 859 # ------------------------------------------------------------------------------
 860 have_libcryptsetup=no
 861 AC_ARG_ENABLE(libcryptsetup, AS_HELP_STRING([--disable-libcryptsetup], [disable libcryptsetup tools]))
 862 if test "x$enable_libcryptsetup" != "xno"; then
 863         PKG_CHECK_MODULES(LIBCRYPTSETUP, [ libcryptsetup >= 1.6.0 ],
 864                 [AC_DEFINE(HAVE_LIBCRYPTSETUP, 1, [Define if libcryptsetup is available]) have_libcryptsetup=yes], have_libcryptsetup=no)
 865         if test "x$have_libcryptsetup" = xno -a "x$enable_libcryptsetup" = xyes; then
 866                 AC_MSG_ERROR([*** libcryptsetup support requested but libraries not found])
 867         fi
 868 fi
 869 AM_CONDITIONAL(HAVE_LIBCRYPTSETUP, [test "$have_libcryptsetup" = "yes"])
 870
 871 # ------------------------------------------------------------------------------
 872 have_qrencode=no
 873 AC_ARG_ENABLE(qrencode, AS_HELP_STRING([--disable-qrencode], [disable qrencode support]))
 874 if test "x$enable_qrencode" != "xno"; then
 875         PKG_CHECK_MODULES(QRENCODE, [ libqrencode ],
 876                 [AC_DEFINE(HAVE_QRENCODE, 1, [Define if qrencode is available]) have_qrencode=yes], have_qrencode=no)
 877         if test "x$have_qrencode" = xno -a "x$enable_qrencode" = xyes; then
 878                 AC_MSG_ERROR([*** qrencode support requested but libraries not found])
 879         fi
 880 fi
 881 AM_CONDITIONAL(HAVE_QRENCODE, [test "$have_qrencode" = "yes"])
 882
 883 # ------------------------------------------------------------------------------
 884 have_gnutls=no
 885 AC_ARG_ENABLE(gnutls, AS_HELP_STRING([--disable-gnutls], [disable gnutls support]))
 886 if test "x$enable_gnutls" != "xno"; then
 887         PKG_CHECK_MODULES(GNUTLS, [gnutls >= 3.1.4],
 888                 [AC_DEFINE(HAVE_GNUTLS, 1, [Define if gnutls is available]) have_gnutls=yes], have_gnutls=no)
 889         if test "x$have_gnutls" = xno -a "x$enable_gnutls" = xyes; then
 890                 AC_MSG_ERROR([*** gnutls support requested but libraries not found])
 891         fi
 892 fi
 893 AM_CONDITIONAL(HAVE_GNUTLS, [test "$have_gnutls" = "yes"])
 894
 895 # ------------------------------------------------------------------------------
 896 have_microhttpd=no
 897 AC_ARG_ENABLE(microhttpd, AS_HELP_STRING([--disable-microhttpd], [disable microhttpd support]))
 898 if test "x$enable_microhttpd" != "xno"; then
 899         PKG_CHECK_MODULES(MICROHTTPD, [libmicrohttpd >= 0.9.33],
 900                 [AC_DEFINE(HAVE_MICROHTTPD, 1, [Define if microhttpd is available])
 901                  have_microhttpd=yes
 902                  M4_DEFINES="$M4_DEFINES -DHAVE_MICROHTTPD"],
 903                 [have_microhttpd=no])
 904         if test "x$have_microhttpd" = xno -a "x$enable_microhttpd" = xyes; then
 905                 AC_MSG_ERROR([*** microhttpd support requested but libraries not found])
 906         fi
 907 fi
 908 AM_CONDITIONAL(HAVE_MICROHTTPD, [test "$have_microhttpd" = "yes"])
 909
 910 # ------------------------------------------------------------------------------
 911 have_libcurl=no
 912 AC_ARG_ENABLE(libcurl, AS_HELP_STRING([--disable-libcurl], [disable libcurl support]))
 913 if test "x$enable_libcurl" != "xno"; then
 914         PKG_CHECK_MODULES(LIBCURL, [libcurl >= 7.32.0],
 915                 [AC_DEFINE(HAVE_LIBCURL, 1, [Define if libcurl is available])
 916                  have_libcurl=yes
 917                  M4_DEFINES="$M4_DEFINES -DHAVE_LIBCURL"],
 918                 [have_libcurl=no])
 919         if test "x$have_libcurl" = xno -a "x$enable_libcurl" = xyes; then
 920                 AC_MSG_ERROR([*** libcurl support requested but libraries not found])
 921         fi
 922 fi
 923 AM_CONDITIONAL(HAVE_LIBCURL, [test "$have_libcurl" = "yes"])
 924
 925 # ------------------------------------------------------------------------------
 926 AM_CONDITIONAL(HAVE_REMOTE, [test "$have_microhttpd" = "yes" -o "$have_libcurl" = "yes"])
 927
 928 # ------------------------------------------------------------------------------
 929 have_libidn=no
 930 AC_ARG_ENABLE(libidn, AS_HELP_STRING([--disable-libidn], [Disable optional LIBIDN support]))
 931 if test "x$enable_libidn" != "xno"; then
 932         PKG_CHECK_MODULES(LIBIDN, [libidn],
 933                [AC_DEFINE(HAVE_LIBIDN, 1, [Define if libidn is available])
 934                 have_libidn=yes
 935                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIDN"],
 936                [have_libidn=no])
 937         if test "x$have_libidn" = "xno" -a "x$enable_libidn" = "xyes"; then
 938                 AC_MSG_ERROR([*** libidn support requested but libraries not found])
 939         fi
 940 fi
 941 AM_CONDITIONAL(HAVE_LIBIDN, [test "$have_libidn" = "yes"])
 942
 943 # ------------------------------------------------------------------------------
 944 have_libiptc=no
 945 AC_ARG_ENABLE(libiptc, AS_HELP_STRING([--disable-libiptc], [Disable optional LIBIPTC support]))
 946 if test "x$enable_libiptc" != "xno"; then
 947         PKG_CHECK_MODULES(LIBIPTC, [libiptc],
 948                [AC_DEFINE(HAVE_LIBIPTC, 1, [Define if libiptc is available])
 949                 have_libiptc=yes
 950                 M4_DEFINES="$M4_DEFINES -DHAVE_LIBIPTC"],
 951                [have_libiptc=no])
 952         if test "x$have_libiptc" = "xno" -a "x$enable_libiptc" = "xyes"; then
 953                 AC_MSG_ERROR([*** libiptc support requested but libraries not found])
 954         fi
 955 fi
 956 AM_CONDITIONAL(HAVE_LIBIPTC, [test "$have_libiptc" = "yes"])
 957
 958 # ------------------------------------------------------------------------------
 959 have_binfmt=no
 960 AC_ARG_ENABLE(binfmt, AS_HELP_STRING([--disable-binfmt], [disable binfmt tool]))
 961 if test "x$enable_binfmt" != "xno"; then
 962         have_binfmt=yes
 963 fi
 964 AM_CONDITIONAL(ENABLE_BINFMT, [test "$have_binfmt" = "yes"])
 965
 966 # ------------------------------------------------------------------------------
 967 have_vconsole=no
 968 AC_ARG_ENABLE(vconsole, AS_HELP_STRING([--disable-vconsole], [disable vconsole tool]))
 969 if test "x$enable_vconsole" != "xno"; then
 970         have_vconsole=yes
 971 fi
 972 AM_CONDITIONAL(ENABLE_VCONSOLE, [test "$have_vconsole" = "yes"])
 973
 974 # ------------------------------------------------------------------------------
 975 have_quotacheck=no
 976 AC_ARG_ENABLE(quotacheck, AS_HELP_STRING([--disable-quotacheck], [disable quotacheck tools]))
 977 if test "x$enable_quotacheck" != "xno"; then
 978         have_quotacheck=yes
 979 fi
 980 AM_CONDITIONAL(ENABLE_QUOTACHECK, [test "$have_quotacheck" = "yes"])
 981
 982 # ------------------------------------------------------------------------------
 983 have_tmpfiles=no
 984 AC_ARG_ENABLE(tmpfiles, AS_HELP_STRING([--disable-tmpfiles], [disable tmpfiles support]))
 985 if test "x$enable_tmpfiles" != "xno"; then
 986         have_tmpfiles=yes
 987 fi
 988 AM_CONDITIONAL(ENABLE_TMPFILES, [test "$have_tmpfiles" = "yes"])
 989
 990 # ------------------------------------------------------------------------------
 991 have_sysusers=no
 992 AC_ARG_ENABLE(sysusers, AS_HELP_STRING([--disable-sysusers], [disable sysusers support]))
 993 if test "x$enable_sysusers" != "xno"; then
 994         have_sysusers=yes
 995 fi
 996 AM_CONDITIONAL(ENABLE_SYSUSERS, [test "$have_sysusers" = "yes"])
 997
 998 # ------------------------------------------------------------------------------
 999 have_firstboot=no
1000 AC_ARG_ENABLE(firstboot, AS_HELP_STRING([--disable-firstboot], [disable firstboot support]))
1001 if test "x$enable_firstboot" != "xno"; then
1002         have_firstboot=yes
1003 fi
1004 AM_CONDITIONAL(ENABLE_FIRSTBOOT, [test "$have_firstboot" = "yes"])
1005
1006 # ------------------------------------------------------------------------------
1007 have_randomseed=no
1008 AC_ARG_ENABLE(randomseed, AS_HELP_STRING([--disable-randomseed], [disable randomseed tools]))
1009 if test "x$enable_randomseed" != "xno"; then
1010         have_randomseed=yes
1011 fi
1012 AM_CONDITIONAL(ENABLE_RANDOMSEED, [test "$have_randomseed" = "yes"])
1013
1014 # ------------------------------------------------------------------------------
1015 have_backlight=no
1016 AC_ARG_ENABLE(backlight, AS_HELP_STRING([--disable-backlight], [disable backlight tools]))
1017 if test "x$enable_backlight" != "xno"; then
1018         have_backlight=yes
1019 fi
1020 AM_CONDITIONAL(ENABLE_BACKLIGHT, [test "$have_backlight" = "yes"])
1021
1022 # ------------------------------------------------------------------------------
1023 have_rfkill=no
1024 AC_ARG_ENABLE(rfkill, AS_HELP_STRING([--disable-rfkill], [disable rfkill tools]))
1025 if test "x$enable_rfkill" != "xno"; then
1026         have_rfkill=yes
1027 fi
1028 AM_CONDITIONAL(ENABLE_RFKILL, [test "$have_rfkill" = "yes"])
1029
1030 # ------------------------------------------------------------------------------
1031 have_logind=no
1032 AC_ARG_ENABLE(logind, AS_HELP_STRING([--disable-logind], [disable login daemon]))
1033 if test "x$enable_logind" != "xno"; then
1034         have_logind=yes
1035 fi
1036 AM_CONDITIONAL(ENABLE_LOGIND, [test "$have_logind" = "yes"])
1037 AS_IF([test "$have_logind" = "yes"], [ AC_DEFINE(HAVE_LOGIND, [1], [Logind support available]) ])
1038
1039 AC_ARG_WITH([kill-user-processes],
1040         [AS_HELP_STRING([--without-kill-user-processes], [Set logind's KillUserProcesses=no by default])])
1041 AS_IF([test "$with_kill_user_processes" != "no"],
1042        [kill_user_processes=true
1043         KILL_USER_PROCESSES=yes],
1044        [kill_user_processes=false
1045         KILL_USER_PROCESSES=no])
1046 AC_DEFINE_UNQUOTED(KILL_USER_PROCESSES, [$kill_user_processes], [Default KillUserProcesses setting])
1047 AC_SUBST(KILL_USER_PROCESSES)
1048
1049 # ------------------------------------------------------------------------------
1050 have_machined=no
1051 AC_ARG_ENABLE(machined, AS_HELP_STRING([--disable-machined], [disable machine daemon]))
1052 if test "x$enable_machined" != "xno"; then
1053         have_machined=yes
1054         AC_DEFINE(HAVE_MACHINED, [1], [systemd-machined is enabled])
1055 fi
1056 AM_CONDITIONAL(ENABLE_MACHINED, [test "$have_machined" = "yes"])
1057
1058 # ------------------------------------------------------------------------------
1059 have_importd=no
1060 AC_ARG_ENABLE(importd, AS_HELP_STRING([--disable-importd], [disable import daemon]))
1061 if test "x$enable_importd" != "xno"; then
1062         have_importd=yes
1063 fi
1064 AM_CONDITIONAL(ENABLE_IMPORTD, [test "$have_importd" = "yes"])
1065 AS_IF([test "$have_importd" = "yes"], [ AC_DEFINE(HAVE_IMPORTD, [1], [Importd support available]) ])
1066
1067 # ------------------------------------------------------------------------------
1068 have_hostnamed=no
1069 AC_ARG_ENABLE(hostnamed, AS_HELP_STRING([--disable-hostnamed], [disable hostname daemon]))
1070 if test "x$enable_hostnamed" != "xno"; then
1071         have_hostnamed=yes
1072 fi
1073 AM_CONDITIONAL(ENABLE_HOSTNAMED, [test "$have_hostnamed" = "yes"])
1074
1075 # ------------------------------------------------------------------------------
1076 have_timedated=no
1077 AC_ARG_ENABLE(timedated, AS_HELP_STRING([--disable-timedated], [disable timedate daemon]))
1078 if test "x$enable_timedated" != "xno"; then
1079         have_timedated=yes
1080 fi
1081 AM_CONDITIONAL(ENABLE_TIMEDATED, [test "$have_timedated" = "yes"])
1082
1083 # ------------------------------------------------------------------------------
1084 have_timesyncd=no
1085 AC_ARG_ENABLE(timesyncd, AS_HELP_STRING([--disable-timesyncd], [disable timesync daemon]))
1086 if test "x$enable_timesyncd" != "xno"; then
1087         have_timesyncd=yes
1088         M4_DEFINES="$M4_DEFINES -DENABLE_TIMESYNCD"
1089 fi
1090 AM_CONDITIONAL(ENABLE_TIMESYNCD, [test "$have_timesyncd" = "yes"])
1091
1092 AC_ARG_WITH(ntp-servers,
1093         AS_HELP_STRING([--with-ntp-servers=NTPSERVERS],
1094                 [Space-separated list of default NTP servers]),
1095         [NTP_SERVERS="$withval"],
1096         [NTP_SERVERS="time1.google.com time2.google.com time3.google.com time4.google.com"
1097         AC_MSG_WARN([*** Using Google NTP servers.
1098                         Do not ship OSes or devices with these default settings.
1099                         See DISTRO_PORTING for details!])])
1100
1101 AC_DEFINE_UNQUOTED(NTP_SERVERS, ["$NTP_SERVERS"], [Default NTP Servers])
1102 AC_SUBST(NTP_SERVERS)
1103
1104 AC_ARG_WITH(time-epoch,
1105         AS_HELP_STRING([--with-time-epoch=SECONDS],
1106                 [Time epoch for time clients]),
1107         [TIME_EPOCH="$withval"],
1108         [TIME_EPOCH="`stat -c %Y ${srcdir}/NEWS 2>/dev/null || echo 0`"])
1109
1110 AC_DEFINE_UNQUOTED(TIME_EPOCH, [$TIME_EPOCH], [Time Epoch])
1111
1112 # ------------------------------------------------------------------------------
1113 AC_ARG_WITH(system-uid-max,
1114         AS_HELP_STRING([--with-system-uid-max=UID]
1115                 [Maximum UID for system users]),
1116         [SYSTEM_UID_MAX="$withval"],
1117         [SYSTEM_UID_MAX="`awk 'BEGIN { uid=999 } /^\s*SYS_UID_MAX\s+/ { uid=$2 } END { print uid }' /etc/login.defs 2>/dev/null || echo 999`"])
1118
1119 AC_DEFINE_UNQUOTED(SYSTEM_UID_MAX, [$SYSTEM_UID_MAX], [Maximum System UID])
1120 AC_SUBST(SYSTEM_UID_MAX)
1121
1122 # ------------------------------------------------------------------------------
1123 AC_ARG_WITH(system-gid-max,
1124         AS_HELP_STRING([--with-system-gid-max=GID]
1125                 [Maximum GID for system groups]),
1126         [SYSTEM_GID_MAX="$withval"],
1127         [SYSTEM_GID_MAX="`awk 'BEGIN { gid=999 } /^\s*SYS_GID_MAX\s+/ { gid=$2 } END { print gid }' /etc/login.defs 2>/dev/null || echo 999`"])
1128
1129 AC_DEFINE_UNQUOTED(SYSTEM_GID_MAX, [$SYSTEM_GID_MAX], [Maximum System GID])
1130 AC_SUBST(SYSTEM_GID_MAX)
1131
1132 # ------------------------------------------------------------------------------
1133 have_localed=no
1134 AC_ARG_ENABLE(localed, AS_HELP_STRING([--disable-localed], [disable locale daemon]))
1135 if test "x$enable_localed" != "xno"; then
1136         have_localed=yes
1137 fi
1138 AM_CONDITIONAL(ENABLE_LOCALED, [test "$have_localed" = "yes"])
1139
1140 # ------------------------------------------------------------------------------
1141 have_coredump=no
1142 AC_ARG_ENABLE(coredump, AS_HELP_STRING([--disable-coredump], [disable coredump hook]))
1143 if test "x$enable_coredump" != "xno"; then
1144         have_coredump=yes
1145         M4_DEFINES="$M4_DEFINES -DENABLE_COREDUMP"
1146 fi
1147 AM_CONDITIONAL(ENABLE_COREDUMP, [test "$have_coredump" = "yes"])
1148
1149 # ------------------------------------------------------------------------------
1150 have_polkit=no
1151 AC_ARG_ENABLE(polkit, AS_HELP_STRING([--disable-polkit], [disable PolicyKit support]))
1152 if test "x$enable_polkit" != "xno"; then
1153         AC_DEFINE(ENABLE_POLKIT, 1, [Define if PolicyKit support is to be enabled])
1154         have_polkit=yes
1155 fi
1156 AM_CONDITIONAL(ENABLE_POLKIT, [test "x$have_polkit" = "xyes"])
1157
1158 # ------------------------------------------------------------------------------
1159 have_resolved=no
1160 AC_ARG_ENABLE(resolved, AS_HELP_STRING([--disable-resolved], [disable resolve daemon]))
1161 AS_IF([test "x$enable_resolved" != "xno"], [
1162         AC_CHECK_LIB([dl], [dlsym], [true], [AC_MSG_ERROR([*** Dynamic linking loader library not found])])
1163
1164         have_resolved=yes
1165         M4_DEFINES="$M4_DEFINES -DENABLE_RESOLVED"
1166         AC_DEFINE(HAVE_RESOLVED, [1], [systemd-resolved is enabled])
1167 ])
1168 AM_CONDITIONAL(ENABLE_RESOLVED, [test "$have_resolved" = "yes"])
1169
1170 AC_ARG_WITH(dns-servers,
1171         AS_HELP_STRING([--with-dns-servers=DNSSERVERS],
1172                 [Space-separated list of default DNS servers]),
1173         [DNS_SERVERS="$withval"],
1174         [DNS_SERVERS="8.8.8.8 8.8.4.4 2001:4860:4860::8888 2001:4860:4860::8844"])
1175
1176 AC_DEFINE_UNQUOTED(DNS_SERVERS, ["$DNS_SERVERS"], [Default DNS Servers])
1177 AC_SUBST(DNS_SERVERS)
1178
1179 AC_ARG_WITH(default-dnssec,
1180         AS_HELP_STRING([--with-default-dnssec=MODE],
1181                [Default DNSSEC mode, defaults to "allow-downgrade"]),
1182         [DEFAULT_DNSSEC_MODE="$withval"],
1183         [DEFAULT_DNSSEC_MODE="allow-downgrade"])
1184
1185 AS_CASE("x${DEFAULT_DNSSEC_MODE}",
1186         [xno], [mode=DNSSEC_NO],
1187         [xyes], [mode=DNSSEC_YES],
1188         [xallow-downgrade], [mode=DNSSEC_ALLOW_DOWNGRADE],
1189         AC_MSG_ERROR(Bad DNSSEC mode ${DEFAULT_DNSSEC_MODE}))
1190 AC_DEFINE_UNQUOTED(DEFAULT_DNSSEC_MODE, [$mode], [Default DNSSEC mode])
1191 AC_SUBST(DEFAULT_DNSSEC_MODE)
1192
1193 # ------------------------------------------------------------------------------
1194 have_networkd=no
1195 AC_ARG_ENABLE(networkd, AS_HELP_STRING([--disable-networkd], [disable networkd]))
1196 AS_IF([test "x$enable_networkd" != "xno"], [
1197         AC_DEFINE(ENABLE_NETWORKD, 1, [Define if networkd support is to be enabled])
1198         have_networkd=yes
1199         M4_DEFINES="$M4_DEFINES -DENABLE_NETWORKD"
1200 ])
1201 AM_CONDITIONAL(ENABLE_NETWORKD, [test "x$have_networkd" = "xyes"])
1202
1203 # ------------------------------------------------------------------------------
1204 have_efi=no
1205 AC_ARG_ENABLE(efi, AS_HELP_STRING([--disable-efi], [disable EFI support]))
1206 if test "x$enable_efi" != "xno"; then
1207         AC_DEFINE(ENABLE_EFI, 1, [Define if EFI support is to be enabled])
1208         have_efi=yes
1209 fi
1210 AM_CONDITIONAL(ENABLE_EFI, [test "x$have_efi" = "xyes"])
1211
1212 # ------------------------------------------------------------------------------
1213 AC_CHECK_TOOL(EFI_CC, gcc)
1214
1215 EFI_ARCH=`echo $host | sed "s/\(-\).*$//"`
1216
1217 AM_COND_IF(ARCH_IA32, [
1218         EFI_ARCH=ia32
1219         EFI_MACHINE_TYPE_NAME=ia32])
1220
1221 AM_COND_IF(ARCH_X86_64, [
1222         EFI_MACHINE_TYPE_NAME=x64])
1223
1224 AM_COND_IF(ARCH_AARCH64, [
1225         EFI_MACHINE_TYPE_NAME=aa64])
1226
1227 AC_SUBST([EFI_ARCH])
1228 AC_SUBST([EFI_MACHINE_TYPE_NAME])
1229
1230 have_gnuefi=no
1231 AC_ARG_ENABLE(gnuefi, AS_HELP_STRING([--enable-gnuefi], [Enable optional gnuefi support]))
1232 AS_IF([test "x$enable_gnuefi" != "xno"], [
1233         AC_CHECK_HEADERS(efi/${EFI_ARCH}/efibind.h,
1234                 [AC_DEFINE(HAVE_GNUEFI, 1, [Define if gnuefi is available])
1235                  have_gnuefi=yes],
1236                 [AS_IF([test "x$enable_gnuefi" = xyes],
1237                        [AC_MSG_ERROR([*** gnuefi support requested but headers not found])])
1238         ])
1239
1240         efiroot=$(echo $(cd /usr/lib/$(${EFI_CC} -print-multi-os-directory); pwd))
1241
1242         EFI_LIB_DIR="$efiroot"
1243         AC_ARG_WITH(efi-libdir,
1244                 AS_HELP_STRING([--with-efi-libdir=PATH], [Path to EFI lib directory]),
1245                 [EFI_LIB_DIR="$withval"], [EFI_LIB_DIR="$efiroot"]
1246         )
1247         AC_SUBST([EFI_LIB_DIR])
1248
1249         have_efi_lds=no
1250         AC_ARG_WITH(efi-ldsdir,
1251                 AS_HELP_STRING([--with-efi-ldsdir=PATH], [Path to EFI lds directory]),
1252                 [EFI_LDS_DIR="$withval" && AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1253                         [have_efi_lds=yes])],
1254                 [AS_FOR([DIR], [EFI_LDS_DIR], ["${EFI_LIB_DIR}/gnuefi" "${EFI_LIB_DIR}"],
1255                         [AS_IF([test -f "${EFI_LDS_DIR}/elf_${EFI_ARCH}_efi.lds"],
1256                                        [have_efi_lds=yes && break])])])
1257         AS_IF([test "x$have_efi_lds" = xyes],
1258               [AC_SUBST([EFI_LDS_DIR])],
1259               [AS_IF([test "x$enable_gnuefi" = xyes],
1260                      [AC_MSG_ERROR([*** gnuefi support requested but files not found])],
1261                      [have_gnuefi=no])])
1262
1263         AC_ARG_WITH(efi-includedir,
1264                 AS_HELP_STRING([--with-efi-includedir=PATH], [Path to EFI include directory]),
1265                 [EFI_INC_DIR="$withval"], [EFI_INC_DIR="/usr/include"]
1266         )
1267         AC_SUBST([EFI_INC_DIR])
1268 ])
1269 AM_CONDITIONAL(HAVE_GNUEFI, [test "x$have_gnuefi" = xyes])
1270
1271 # ------------------------------------------------------------------------------
1272 have_tpm=no
1273 AC_ARG_ENABLE([tpm], AS_HELP_STRING([--enable-tpm],[Enable optional TPM support]),
1274                 [case "${enableval}" in
1275                         yes) have_tpm=yes ;;
1276                         no) have_tpm=no ;;
1277                         *) AC_MSG_ERROR(bad value ${enableval} for --enable-tpm) ;;
1278                 esac],
1279                 [have_tpm=no])
1280
1281 if test "x${have_tpm}" != xno ; then
1282         AC_DEFINE(SD_BOOT_LOG_TPM, 1, [Define if TPM should be used to log events and extend the registers])
1283 fi
1284
1285 AC_ARG_WITH(tpm-pcrindex,
1286         AS_HELP_STRING([--with-tpm-pcrindex=<NUM>],
1287                 [TPM PCR register number to use]),
1288         [SD_TPM_PCR="$withval"],
1289         [SD_TPM_PCR="8"])
1290
1291 AC_DEFINE_UNQUOTED(SD_TPM_PCR, [$SD_TPM_PCR], [TPM PCR register number to use])
1292
1293 # ------------------------------------------------------------------------------
1294 AC_ARG_WITH(rc-local-script-path-start,
1295         AS_HELP_STRING([--with-rc-local-script-path-start=PATH],
1296                 [Path to /etc/rc.local]),
1297         [RC_LOCAL_SCRIPT_PATH_START="$withval"],
1298         [RC_LOCAL_SCRIPT_PATH_START="/etc/rc.local"])
1299
1300 AC_ARG_WITH(rc-local-script-path-stop,
1301         AS_HELP_STRING([--with-rc-local-script-path-stop=PATH],
1302                 [Path to /usr/sbin/halt.local]),
1303         [RC_LOCAL_SCRIPT_PATH_STOP="$withval"],
1304         [RC_LOCAL_SCRIPT_PATH_STOP="/usr/sbin/halt.local"])
1305
1306 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_START, ["$RC_LOCAL_SCRIPT_PATH_START"], [Path of /etc/rc.local script])
1307 AC_DEFINE_UNQUOTED(RC_LOCAL_SCRIPT_PATH_STOP, ["$RC_LOCAL_SCRIPT_PATH_STOP"], [Path of /usr/sbin/halt.local script])
1308
1309 AC_SUBST(RC_LOCAL_SCRIPT_PATH_START)
1310 AC_SUBST(RC_LOCAL_SCRIPT_PATH_STOP)
1311
1312 # ------------------------------------------------------------------------------
1313 AC_ARG_WITH(kbd-loadkeys,
1314         AS_HELP_STRING([--with-kbd-loadkeys=PATH],
1315                 [Path to loadkeys]),
1316         [KBD_LOADKEYS="$withval"],
1317         [KBD_LOADKEYS="/usr/bin/loadkeys"])
1318
1319 AC_ARG_WITH(kbd-setfont,
1320         AS_HELP_STRING([--with-kbd-setfont=PATH],
1321                 [Path to setfont]),
1322         [KBD_SETFONT="$withval"],
1323         [KBD_SETFONT="/usr/bin/setfont"])
1324
1325 AC_DEFINE_UNQUOTED(KBD_LOADKEYS, ["$KBD_LOADKEYS"], [Path of loadkeys])
1326 AC_DEFINE_UNQUOTED(KBD_SETFONT, ["$KBD_SETFONT"], [Path of setfont])
1327
1328 AC_SUBST(KBD_LOADKEYS)
1329 AC_SUBST(KBD_SETFONT)
1330
1331 AC_ARG_WITH(telinit,
1332         AS_HELP_STRING([--with-telinit=PATH],
1333                 [Path to telinit]),
1334         [TELINIT="$withval"],
1335         [TELINIT="/lib/sysvinit/telinit"])
1336
1337 AC_DEFINE_UNQUOTED(TELINIT, ["$TELINIT"], [Path to telinit])
1338
1339 AC_SUBST(TELINIT)
1340
1341 AC_CHECK_HEADERS_ONCE([valgrind/memcheck.h valgrind/valgrind.h])
1342
1343 # ------------------------------------------------------------------------------
1344 have_myhostname=no
1345 AC_ARG_ENABLE(myhostname, AS_HELP_STRING([--disable-myhostname], [disable nss-myhostname support]))
1346 if test "x$enable_myhostname" != "xno"; then
1347         AC_HEADER_STDC
1348         AC_CHECK_HEADERS([arpa/inet.h fcntl.h inttypes.h netdb.h netinet/in.h stdlib.h string.h sys/socket.h sys/time.h unistd.h nss.h sys/ioctl.h sys/auxv.h])
1349
1350         AC_C_CONST
1351         AC_TYPE_SIZE_T
1352         AC_HEADER_TIME
1353
1354         AC_FUNC_SELECT_ARGTYPES
1355         AC_CHECK_FUNCS([gethostbyaddr gethostbyname gettimeofday inet_ntoa memset select socket strcspn strdup strerror strncasecmp strcasecmp strspn])
1356
1357         have_myhostname=yes
1358         AC_DEFINE(HAVE_MYHOSTNAME, [1], [nss-myhostname is enabled])
1359 fi
1360 AM_CONDITIONAL(HAVE_MYHOSTNAME, [test "$have_myhostname" = "yes"])
1361
1362 # ------------------------------------------------------------------------------
1363 AC_ARG_ENABLE(hwdb, [AC_HELP_STRING([--disable-hwdb], [disable hardware database support])],
1364        enable_hwdb=$enableval, enable_hwdb=yes)
1365 AM_CONDITIONAL(ENABLE_HWDB, [test x$enable_hwdb = xyes])
1366
1367 # ------------------------------------------------------------------------------
1368 have_manpages=no
1369 AC_ARG_ENABLE(manpages, AS_HELP_STRING([--disable-manpages], [disable manpages]))
1370 AC_PATH_PROG([XSLTPROC], [xsltproc])
1371 AS_IF([test "x$enable_manpages" != xno], [
1372        have_manpages=yes
1373        AS_IF([test -z "$XSLTPROC"],
1374              AC_MSG_ERROR([*** xsltproc is required for man pages]))
1375 ])
1376 AM_CONDITIONAL(ENABLE_MANPAGES, [test "x$have_manpages" = "xyes"])
1377
1378 # ------------------------------------------------------------------------------
1379 AC_ARG_ENABLE(hibernate,
1380        [AC_HELP_STRING([--disable-hibernate], [disable hibernation support])],
1381        enable_hibernate=$enableval, enable_hibernate=yes)
1382 AM_CONDITIONAL(ENABLE_HIBERNATE, [test x$enable_hibernate = xyes])
1383
1384 # ------------------------------------------------------------------------------
1385 AC_ARG_ENABLE(ldconfig,
1386        [AC_HELP_STRING([--disable-ldconfig], [disable ldconfig])],
1387        enable_ldconfig=$enableval, enable_ldconfig=yes)
1388 AM_CONDITIONAL(ENABLE_LDCONFIG, [test x$enable_ldconfig = xyes])
1389
1390 # ------------------------------------------------------------------------------
1391 # Location of the init scripts as mandated by LSB
1392 SYSTEM_SYSVINIT_PATH=/etc/init.d
1393 SYSTEM_SYSVRCND_PATH=/etc/rc.d
1394
1395 AC_ARG_WITH([sysvinit-path],
1396         [AS_HELP_STRING([--with-sysvinit-path=PATH],
1397                 [Specify the path to where the SysV init scripts are located])],
1398         [SYSTEM_SYSVINIT_PATH="$withval"],
1399         [])
1400
1401 AC_ARG_WITH([sysvrcnd-path],
1402         [AS_HELP_STRING([--with-sysvrcnd-path=PATH],
1403                 [Specify the path to the base directory for the SysV rcN.d directories])],
1404         [SYSTEM_SYSVRCND_PATH="$withval"],
1405         [])
1406
1407 if test "x${SYSTEM_SYSVINIT_PATH}" != "x" -a "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1408         AC_DEFINE(HAVE_SYSV_COMPAT, [], [SysV init scripts and rcN.d links are supported.])
1409         SYSTEM_SYSV_COMPAT="yes"
1410         M4_DEFINES="$M4_DEFINES -DHAVE_SYSV_COMPAT"
1411 elif test "x${SYSTEM_SYSVINIT_PATH}" != "x" -o "x${SYSTEM_SYSVRCND_PATH}" != "x"; then
1412         AC_MSG_ERROR([*** You need both --with-sysvinit-path=PATH and --with-sysvrcnd-path=PATH to enable SysV compatibility support, or both empty to disable it.])
1413 else
1414         SYSTEM_SYSV_COMPAT="no"
1415 fi
1416
1417 AC_SUBST(SYSTEM_SYSVINIT_PATH)
1418 AC_SUBST(SYSTEM_SYSVRCND_PATH)
1419 AC_SUBST(M4_DEFINES)
1420
1421 AM_CONDITIONAL(HAVE_SYSV_COMPAT, test "$SYSTEM_SYSV_COMPAT" = "yes")
1422
1423 AC_ARG_WITH([tty-gid],
1424         [AS_HELP_STRING([--with-tty-gid=GID],
1425                 [Specify the numeric GID of the 'tty' group])],
1426         [TTY_GID="$withval"],
1427         [TTY_GID="5"])
1428
1429 AC_DEFINE_UNQUOTED(TTY_GID, [$TTY_GID], [GID of the 'tty' group])
1430 AC_SUBST(TTY_GID)
1431
1432 AC_ARG_WITH([dbuspolicydir],
1433         AS_HELP_STRING([--with-dbuspolicydir=DIR], [D-Bus policy directory]),
1434         [],
1435         [with_dbuspolicydir=${sysconfdir}/dbus-1/system.d])
1436 AX_NORMALIZE_PATH([with_dbuspolicydir])
1437
1438 AC_ARG_WITH([dbussessionservicedir],
1439         AS_HELP_STRING([--with-dbussessionservicedir=DIR], [D-Bus session service directory]),
1440         [],
1441         [with_dbussessionservicedir=${datadir}/dbus-1/services])
1442 AX_NORMALIZE_PATH([with_dbussessionservicedir])
1443
1444 AC_ARG_WITH([dbussystemservicedir],
1445         AS_HELP_STRING([--with-dbussystemservicedir=DIR], [D-Bus system service directory]),
1446         [],
1447         [with_dbussystemservicedir=${datadir}/dbus-1/system-services])
1448 AX_NORMALIZE_PATH([with_dbussystemservicedir])
1449
1450 AC_ARG_WITH([bashcompletiondir],
1451         AS_HELP_STRING([--with-bashcompletiondir=DIR], [Bash completions directory]),
1452         [],
1453         [AS_IF([$($PKG_CONFIG --exists bash-completion)], [
1454                 with_bashcompletiondir=$($PKG_CONFIG --variable=completionsdir bash-completion)
1455         ] , [
1456                 with_bashcompletiondir=${datadir}/bash-completion/completions
1457         ])])
1458 AM_CONDITIONAL(ENABLE_BASH_COMPLETION, [test "$with_bashcompletiondir" != "no"])
1459 AX_NORMALIZE_PATH([with_bashcompletiondir])
1460
1461 AC_ARG_WITH([zshcompletiondir],
1462         AS_HELP_STRING([--with-zshcompletiondir=DIR], [Zsh completions directory]),
1463         [], [with_zshcompletiondir=${datadir}/zsh/site-functions])
1464 AM_CONDITIONAL(ENABLE_ZSH_COMPLETION, [test "$with_zshcompletiondir" != "no"])
1465 AX_NORMALIZE_PATH([with_zshcompletiondir])
1466
1467 AC_ARG_WITH([rootprefix],
1468         AS_HELP_STRING([--with-rootprefix=DIR], [rootfs directory prefix for config files and kernel modules]),
1469         [], [with_rootprefix=${ac_default_prefix}])
1470 # --with-rootprefix= (empty) should default to "/" but AX_NORMALIZE_PATH
1471 # defaults those to ".", solve that here for now until we can find a suitable
1472 # fix for AX_NORMALIZE_PATH upstream at autoconf-archive.
1473 # See: https://github.com/systemd/systemd/issues/54
1474 if test "x${with_rootprefix}" = "x"; then
1475         with_rootprefix="/"
1476 fi
1477 AX_NORMALIZE_PATH([with_rootprefix])
1478
1479 AC_ARG_WITH([rootlibdir],
1480         AS_HELP_STRING([--with-rootlibdir=DIR], [Root directory for libraries necessary for boot]),
1481         [],
1482         [with_rootlibdir=${libdir}])
1483 AX_NORMALIZE_PATH([with_rootlibdir])
1484
1485 AC_ARG_WITH([pamlibdir],
1486         AS_HELP_STRING([--with-pamlibdir=DIR], [Directory for PAM modules]),
1487         [],
1488         [with_pamlibdir=${with_rootlibdir}/security])
1489 AX_NORMALIZE_PATH([with_pamlibdir])
1490
1491 AC_ARG_WITH([pamconfdir],
1492         AS_HELP_STRING([--with-pamconfdir=DIR], [Directory for PAM configuration]),
1493         [],
1494         [with_pamconfdir=${sysconfdir}/pam.d])
1495 AX_NORMALIZE_PATH([with_pamconfdir])
1496
1497 AC_ARG_ENABLE([split-usr],
1498         AS_HELP_STRING([--enable-split-usr], [Assume that /bin, /sbin aren\'t symlinks into /usr]),
1499         [],
1500         [AS_IF([test "x${ac_default_prefix}" != "x${with_rootprefix}"], [
1501                 enable_split_usr=yes
1502         ], [
1503                 enable_split_usr=no
1504         ])])
1505
1506 AS_IF([test "x${enable_split_usr}" = "xyes"], [
1507         AC_DEFINE(HAVE_SPLIT_USR, 1, [Define if /bin, /sbin aren't symlinks into /usr])
1508 ])
1509 AM_CONDITIONAL(ENABLE_SPLIT_USR, [test "x${enable_split_usr}" = "xyes"])
1510
1511 # work around intltool-update issues during 'make distcheck'
1512 AS_IF([test "x$0" != "x./configure"], [
1513         AC_SUBST([INTLTOOL_UPDATE], [/bin/true])
1514 ])
1515
1516 # QEMU and OVMF UEFI firmware
1517 AS_IF([test x"$cross_compiling" = "xyes"], [], [
1518         AC_PATH_PROG([QEMU], [qemu-system-x86_64])
1519         AC_CHECK_FILE([/usr/share/qemu/bios-ovmf.bin], [QEMU_BIOS=/usr/share/qemu/bios-ovmf.bin],
1520                 [AC_CHECK_FILE([/usr/share/qemu-ovmf/bios.bin], [QEMU_BIOS=/usr/share/qemu-ovmf/bios.bin])])
1521         AC_SUBST([QEMU_BIOS])
1522 ])
1523
1524 AC_ARG_ENABLE(tests,
1525         [AC_HELP_STRING([--disable-tests], [disable tests, or enable extra tests with =unsafe])],
1526         enable_tests=$enableval, enable_tests=yes)
1527 AM_CONDITIONAL(ENABLE_TESTS, [test x$enable_tests = xyes -o x$enable_tests = xunsafe])
1528 AM_CONDITIONAL(ENABLE_UNSAFE_TESTS, [test x$enable_tests = xunsafe])
1529
1530 AC_ARG_ENABLE(debug,
1531         [AC_HELP_STRING([--enable-debug@<:@=LIST@:>@], [enable extra debugging (hashmap,mmap-cache)])],
1532         [if test "x$enableval" = "xyes"; then
1533                 enableval="hashmap,mmap-cache"
1534         fi
1535         saved_ifs="$IFS"
1536         IFS="$IFS$PATH_SEPARATOR,"
1537         for name in $enableval; do
1538                 case $name in
1539                 hashmap)
1540                         enable_debug_hashmap=yes
1541                         ;;
1542                 mmap-cache)
1543                         enable_debug_mmap_cache=yes
1544                         ;;
1545                 esac
1546         done
1547         IFS="$saved_ifs"],[])
1548
1549 enable_debug=""
1550 AS_IF([test x$enable_debug_hashmap = xyes], [
1551         AC_DEFINE(ENABLE_DEBUG_HASHMAP, 1, [Define if hashmap debugging is to be enabled])
1552         enable_debug="hashmap $enable_debug"
1553 ])
1554 AS_IF([test x$enable_debug_mmap_cache = xyes], [
1555         AC_DEFINE(ENABLE_DEBUG_MMAP_CACHE, 1, [Define if mmap cache debugging is to be enabled])
1556         enable_debug="mmap-cache $enable_debug"
1557 ])
1558 test -z "$enable_debug" && enable_debug="none"
1559
1560 AC_SUBST([dbuspolicydir], [$with_dbuspolicydir])
1561 AC_SUBST([dbussessionservicedir], [$with_dbussessionservicedir])
1562 AC_SUBST([dbussystemservicedir], [$with_dbussystemservicedir])
1563 AC_SUBST([bashcompletiondir], [$with_bashcompletiondir])
1564 AC_SUBST([zshcompletiondir], [$with_zshcompletiondir])
1565 AC_SUBST([pamlibdir], [$with_pamlibdir])
1566 AC_SUBST([pamconfdir], [$with_pamconfdir])
1567 AC_SUBST([rootprefix], [$with_rootprefix])
1568 AC_SUBST([rootlibdir], [$with_rootlibdir])
1569
1570 AC_CONFIG_FILES([
1571         Makefile
1572         po/Makefile.in
1573 ])
1574
1575 AC_OUTPUT
1576 AC_MSG_RESULT([
1577         $PACKAGE_NAME $VERSION
1578
1579         libcryptsetup:                     ${have_libcryptsetup}
1580         PAM:                               ${have_pam}
1581         AUDIT:                             ${have_audit}
1582         IMA:                               ${have_ima}
1583         AppArmor:                          ${have_apparmor}
1584         SELinux:                           ${have_selinux}
1585         SECCOMP:                           ${have_seccomp}
1586         SMACK:                             ${have_smack}
1587         ZLIB:                              ${have_zlib}
1588         XZ:                                ${have_xz}
1589         LZ4:                               ${have_lz4}
1590         BZIP2:                             ${have_bzip2}
1591         ACL:                               ${have_acl}
1592         GCRYPT:                            ${have_gcrypt}
1593         QRENCODE:                          ${have_qrencode}
1594         MICROHTTPD:                        ${have_microhttpd}
1595         GNUTLS:                            ${have_gnutls}
1596         libcurl:                           ${have_libcurl}
1597         libidn:                            ${have_libidn}
1598         libiptc:                           ${have_libiptc}
1599         ELFUTILS:                          ${have_elfutils}
1600         binfmt:                            ${have_binfmt}
1601         vconsole:                          ${have_vconsole}
1602         quotacheck:                        ${have_quotacheck}
1603         tmpfiles:                          ${have_tmpfiles}
1604         sysusers:                          ${have_sysusers}
1605         firstboot:                         ${have_firstboot}
1606         randomseed:                        ${have_randomseed}
1607         backlight:                         ${have_backlight}
1608         rfkill:                            ${have_rfkill}
1609         logind:                            ${have_logind}
1610         Default KillUserProcesses setting: ${KILL_USER_PROCESSES}
1611         machined:                          ${have_machined}
1612         importd:                           ${have_importd}
1613         hostnamed:                         ${have_hostnamed}
1614         timedated:                         ${have_timedated}
1615         timesyncd:                         ${have_timesyncd}
1616         Default NTP servers:               ${NTP_SERVERS}
1617         time epoch:                        ${TIME_EPOCH}
1618         localed:                           ${have_localed}
1619         networkd:                          ${have_networkd}
1620         resolved:                          ${have_resolved}
1621         Default DNS servers:               ${DNS_SERVERS}
1622         Default DNSSEC mode:               ${DEFAULT_DNSSEC_MODE}
1623         coredump:                          ${have_coredump}
1624         polkit:                            ${have_polkit}
1625         efi:                               ${have_efi}
1626         gnuefi:                            ${have_gnuefi}
1627         efi arch:                          ${EFI_ARCH}
1628         EFI machine type:                  ${EFI_MACHINE_TYPE_NAME}
1629         EFI CC                             ${EFI_CC}
1630         EFI libdir:                        ${EFI_LIB_DIR}
1631         EFI ldsdir:                        ${EFI_LDS_DIR}
1632         EFI includedir:                    ${EFI_INC_DIR}
1633         kmod:                              ${have_kmod}
1634         xkbcommon:                         ${have_xkbcommon}
1635         blkid:                             ${have_blkid}
1636         libmount:                          ${have_libmount}
1637         dbus:                              ${have_dbus}
1638         nss-myhostname:                    ${have_myhostname}
1639         hwdb:                              ${enable_hwdb}
1640         tpm:                               ${have_tpm}
1641         kdbus:                             ${have_kdbus}
1642         Python:                            ${have_python}
1643         man pages:                         ${have_manpages}
1644         test coverage:                     ${have_coverage}
1645         Split /usr:                        ${enable_split_usr}
1646         SysV compatibility:                ${SYSTEM_SYSV_COMPAT}
1647         utmp/wtmp support:                 ${have_utmp}
1648         ldconfig support:                  ${enable_ldconfig}
1649         hibernate support:                 ${enable_hibernate}
1650         extra debugging:                   ${enable_debug}
1651         tests:                             ${enable_tests}
1652
1653         prefix:                            ${prefix}
1654         rootprefix:                        ${with_rootprefix}
1655         sysconf dir:                       ${sysconfdir}
1656         datarootdir:                       ${datarootdir}
1657         includedir:                        ${includedir}
1658         lib dir:                           ${libdir}
1659         rootlib dir:                       ${with_rootlibdir}
1660         SysV init scripts:                 ${SYSTEM_SYSVINIT_PATH}
1661         SysV rc?.d directories:            ${SYSTEM_SYSVRCND_PATH}
1662         Build Python:                      ${PYTHON}
1663         PAM modules dir:                   ${with_pamlibdir}
1664         PAM configuration dir:             ${with_pamconfdir}
1665         D-Bus policy dir:                  ${with_dbuspolicydir}
1666         D-Bus session dir:                 ${with_dbussessionservicedir}
1667         D-Bus system dir:                  ${with_dbussystemservicedir}
1668         Bash completions dir:              ${with_bashcompletiondir}
1669         Zsh completions dir:               ${with_zshcompletiondir}
1670         Extra start script:                ${RC_LOCAL_SCRIPT_PATH_START}
1671         Extra stop script:                 ${RC_LOCAL_SCRIPT_PATH_STOP}
1672         Adm group:                         ${have_adm_group}
1673         Wheel group:                       ${have_wheel_group}
1674         Debug shell:                       ${SUSHELL} @ ${DEBUGTTY}
1675         TTY GID:                           ${TTY_GID}
1676         Maximum System UID:                ${SYSTEM_UID_MAX}
1677         Maximum System GID:                ${SYSTEM_GID_MAX}
1678         Certificate root:                  ${CERTIFICATEROOT}
1679         Support URL:                       ${SUPPORT_URL}
1680
1681         CFLAGS:   ${OUR_CFLAGS} ${CFLAGS}
1682         CPPFLAGS: ${OUR_CPPFLAGS} ${CPPFLAGS}
1683         LDFLAGS:  ${OUR_LDFLAGS} ${LDFLAGS}
1684 ])