configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2020 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/gcc-plugin.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo"
 167
 168 # these tools are built using the target libraries, and are intended to
 169 # run only in the target environment
 170 #
 171 # note: any program that *uses* libraries that are in the "target_libraries"
 172 # list belongs in this list.
 173 #
 174 target_tools="target-rda"
 175
 176 ################################################################################
 177
 178 ## All tools belong in one of the four categories, and are assigned above
 179 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 180 ## is important because configure will choke if they ever get through.
 181 ## ${configdirs} is directories we build using the host tools.
 182 ## ${target_configdirs} is directories we build using the target tools.
 183 configdirs=`echo ${host_libs} ${host_tools}`
 184 target_configdirs=`echo ${target_libraries} ${target_tools}`
 185 build_configdirs=`echo ${build_libs} ${build_tools}`
 186
 187 m4_divert_text([PARSE_ARGS],
 188 [case $srcdir in
 189   *" "*)
 190 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 191     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 192 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 193     ;;
 194 esac
 195 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 196 ])
 197
 198 ################################################################################
 199
 200 srcname="gnu development package"
 201
 202 # This gets set non-empty for some net releases of packages.
 203 appdirs=""
 204
 205 # Define is_cross_compiler to save on calls to 'test'.
 206 is_cross_compiler=
 207 if test x"${host}" = x"${target}" ; then
 208   is_cross_compiler=no
 209 else
 210   is_cross_compiler=yes
 211 fi
 212
 213 # Find the build and target subdir names.
 214 GCC_TOPLEV_SUBDIRS
 215 # Be sure to cover against remnants of an in-tree build.
 216 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 217   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 218 Use a pristine source tree when building in a separate tree])
 219 fi
 220
 221 # Skipdirs are removed silently.
 222 skipdirs=
 223 # Noconfigdirs are removed loudly.
 224 noconfigdirs=""
 225
 226 use_gnu_ld=
 227 # Make sure we don't let GNU ld be added if we didn't want it.
 228 if test x$with_gnu_ld = xno ; then
 229   use_gnu_ld=no
 230   noconfigdirs="$noconfigdirs ld gold"
 231 fi
 232
 233 use_gnu_as=
 234 # Make sure we don't let GNU as be added if we didn't want it.
 235 if test x$with_gnu_as = xno ; then
 236   use_gnu_as=no
 237   noconfigdirs="$noconfigdirs gas"
 238 fi
 239
 240 use_included_zlib=
 241 AC_ARG_WITH(system-zlib,
 242 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 243 # Make sure we don't let ZLIB be added if we didn't want it.
 244 if test x$with_system_zlib = xyes ; then
 245   use_included_zlib=no
 246   noconfigdirs="$noconfigdirs zlib"
 247 fi
 248
 249 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 250 # is provided.
 251 if test x$with_system_readline = xyes ; then
 252   noconfigdirs="$noconfigdirs readline"
 253 fi
 254
 255 # some tools are so dependent upon X11 that if we're not building with X,
 256 # it's not even worth trying to configure, much less build, that tool.
 257
 258 case ${with_x} in
 259   yes | "") ;; # the default value for this tree is that X11 is available
 260   no)
 261     skipdirs="${skipdirs} tk itcl libgui"
 262     # We won't be able to build gdbtk without X.
 263     enable_gdbtk=no
 264     ;;
 265   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 266 esac
 267
 268 # Some are only suitable for cross toolchains.
 269 # Remove these if host=target.
 270 cross_only="target-libgloss target-newlib target-opcodes"
 271
 272 case $is_cross_compiler in
 273   no) skipdirs="${skipdirs} ${cross_only}" ;;
 274 esac
 275
 276 # If both --with-headers and --with-libs are specified, default to
 277 # --without-newlib.
 278 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 279    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 280   if test x"${with_newlib}" = x ; then
 281     with_newlib=no
 282   fi
 283 fi
 284
 285 # Recognize --with-newlib/--without-newlib.
 286 case ${with_newlib} in
 287   no) skipdirs="${skipdirs} target-newlib" ;;
 288   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 289 esac
 290
 291 AC_ARG_ENABLE(as-accelerator-for,
 292 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 293                 [build as offload target compiler.
 294                 Specify offload host triple by ARG])])
 295
 296 AC_ARG_ENABLE(offload-targets,
 297 [AS_HELP_STRING([--enable-offload-targets=LIST],
 298                 [enable offloading to devices from comma-separated LIST of
 299                 TARGET[=DIR]. Use optional path to find offload target compiler
 300                 during the build])],
 301 [
 302   if test x"$enable_offload_targets" = x; then
 303     AC_MSG_ERROR([no offload targets specified])
 304   fi
 305 ], [enable_offload_targets=])
 306
 307 # Handle --enable-gold, --enable-ld.
 308 # --disable-gold [--enable-ld]
 309 #     Build only ld.  Default option.
 310 # --enable-gold [--enable-ld]
 311 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 312 #     as "ld.bfd" and "ld".
 313 # --enable-gold=default [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 315 #     install ld as "ld.bfd".
 316 # --enable-gold[=default] --disable-ld
 317 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 318 # --enable-gold --enable-ld=default
 319 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 320 #     and ld.bfd).
 321 #     In other words, ld is default
 322 # --enable-gold=default --enable-ld=default
 323 #     Error.
 324
 325 default_ld=
 326 AC_ARG_ENABLE(gold,
 327 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 328                 [build gold @<:@ARG={default,yes,no}@:>@])],
 329 ENABLE_GOLD=$enableval,
 330 ENABLE_GOLD=no)
 331 case "${ENABLE_GOLD}" in
 332   yes|default)
 333     # Check for ELF target.
 334     is_elf=no
 335     case "${target}" in
 336       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 337       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 338       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 339       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 340         case "${target}" in
 341           *-*-linux*aout* | *-*-linux*oldld*)
 342             ;;
 343           *)
 344             is_elf=yes
 345             ;;
 346         esac
 347     esac
 348
 349     if test "$is_elf" = "yes"; then
 350       # Check for target supported by gold.
 351       case "${target}" in
 352         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 353         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 354           configdirs="$configdirs gold"
 355           if test x${ENABLE_GOLD} = xdefault; then
 356             default_ld=gold
 357           fi
 358           ENABLE_GOLD=yes
 359           ;;
 360       esac
 361     fi
 362     ;;
 363   no)
 364     ;;
 365   *)
 366     AC_MSG_ERROR([invalid --enable-gold argument])
 367     ;;
 368 esac
 369
 370 AC_ARG_ENABLE(ld,
 371 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 372                 [build ld @<:@ARG={default,yes,no}@:>@])],
 373 ENABLE_LD=$enableval,
 374 ENABLE_LD=yes)
 375
 376 case "${ENABLE_LD}" in
 377   default)
 378     if test x${default_ld} != x; then
 379       AC_MSG_ERROR([either gold or ld can be the default ld])
 380     fi
 381     ;;
 382   yes)
 383     ;;
 384   no)
 385     if test x${ENABLE_GOLD} != xyes; then
 386       AC_MSG_WARN([neither ld nor gold are enabled])
 387     fi
 388     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 389     ;;
 390   *)
 391     AC_MSG_ERROR([invalid --enable-ld argument])
 392     ;;
 393 esac
 394
 395 # PR gas/19109
 396 # Decide the default method for compressing debug sections.
 397 # Provide a configure time option to override our default.
 398 AC_ARG_ENABLE(compressed_debug_sections,
 399 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 400                 [Enable compressed debug sections for gas, gold or ld by
 401                  default])],
 402 [
 403   if test x"$enable_compressed_debug_sections" = xyes; then
 404     AC_MSG_ERROR([no program with compressed debug sections specified])
 405   fi
 406 ], [enable_compressed_debug_sections=])
 407
 408 # Configure extra directories which are host specific
 409
 410 case "${host}" in
 411   *-cygwin*)
 412     configdirs="$configdirs libtermcap" ;;
 413 esac
 414
 415 # A target can indicate whether a language isn't supported for some reason.
 416 # Only spaces may be used in this macro; not newlines or tabs.
 417 unsupported_languages=
 418
 419 # Remove more programs from consideration, based on the host or
 420 # target this usually means that a port of the program doesn't
 421 # exist yet.
 422
 423 case "${host}" in
 424   i[[3456789]]86-*-msdosdjgpp*)
 425     noconfigdirs="$noconfigdirs tcl tk itcl"
 426     ;;
 427 esac
 428
 429
 430 AC_ARG_ENABLE(libquadmath,
 431 AS_HELP_STRING([--disable-libquadmath],
 432   [do not build libquadmath directory]),
 433 ENABLE_LIBQUADMATH=$enableval,
 434 ENABLE_LIBQUADMATH=yes)
 435 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 436   noconfigdirs="$noconfigdirs target-libquadmath"
 437 fi
 438
 439
 440 AC_ARG_ENABLE(libquadmath-support,
 441 AS_HELP_STRING([--disable-libquadmath-support],
 442   [disable libquadmath support for Fortran]),
 443 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 444 ENABLE_LIBQUADMATH_SUPPORT=yes)
 445 enable_libquadmath_support=
 446 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 447   enable_libquadmath_support=no
 448 fi
 449
 450
 451 AC_ARG_ENABLE(libada,
 452 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 453 ENABLE_LIBADA=$enableval,
 454 ENABLE_LIBADA=yes)
 455 if test "${ENABLE_LIBADA}" != "yes" ; then
 456   noconfigdirs="$noconfigdirs gnattools"
 457 fi
 458
 459 AC_ARG_ENABLE(libssp,
 460 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 461 ENABLE_LIBSSP=$enableval,
 462 ENABLE_LIBSSP=yes)
 463
 464 AC_ARG_ENABLE(libstdcxx,
 465 AS_HELP_STRING([--disable-libstdcxx],
 466   [do not build libstdc++-v3 directory]),
 467 ENABLE_LIBSTDCXX=$enableval,
 468 ENABLE_LIBSTDCXX=default)
 469 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 470   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 471 fi]
 472
 473 # If this is accelerator compiler and its target is intelmic we enable
 474 # target liboffloadmic by default.  If this is compiler with offloading
 475 # for intelmic we enable host liboffloadmic by default.  Otherwise
 476 # liboffloadmic is disabled by default.
 477 AC_ARG_ENABLE([liboffloadmic],
 478 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 479                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 480 [case "$enableval" in
 481   no | host | target)
 482     enable_liboffloadmic=$enableval ;;
 483   *)
 484     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 485 esac],
 486 [if test x"$enable_as_accelerator_for" != x; then
 487   case "${target}" in
 488     *-intelmic-* | *-intelmicemul-*)
 489       enable_liboffloadmic=target
 490       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 491       ;;
 492     *)
 493       enable_liboffloadmic=no
 494       ;;
 495   esac
 496 else
 497   case "${enable_offload_targets}" in
 498     *-intelmic-* | *-intelmicemul-*)
 499       enable_liboffloadmic=host
 500       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 501       ;;
 502     *)
 503       enable_liboffloadmic=no
 504       ;;
 505     esac
 506 fi])
 507 AC_SUBST(extra_liboffloadmic_configure_flags)
 508
 509 # Enable libgomp by default on hosted POSIX systems, and a few others.
 510 if test x$enable_libgomp = x ; then
 511     case "${target}" in
 512     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 513         ;;
 514     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 515         ;;
 516     *-*-solaris2* | *-*-hpux11*)
 517         ;;
 518     *-*-darwin* | *-*-aix*)
 519         ;;
 520     nvptx*-*-*)
 521         ;;
 522     *)
 523         noconfigdirs="$noconfigdirs target-libgomp"
 524         ;;
 525     esac
 526 fi
 527
 528 # Disable libatomic on unsupported systems.
 529 if test -d ${srcdir}/libatomic; then
 530     if test x$enable_libatomic = x; then
 531         AC_MSG_CHECKING([for libatomic support])
 532         if (srcdir=${srcdir}/libatomic; \
 533                 . ${srcdir}/configure.tgt; \
 534                 test -n "$UNSUPPORTED")
 535         then
 536             AC_MSG_RESULT([no])
 537             noconfigdirs="$noconfigdirs target-libatomic"
 538         else
 539             AC_MSG_RESULT([yes])
 540         fi
 541     fi
 542 fi
 543
 544 # Disable liboffloadmic on unsupported systems.
 545 if test -d ${srcdir}/liboffloadmic; then
 546     if test x$enable_liboffloadmic != xno; then
 547         AC_MSG_CHECKING([for liboffloadmic support])
 548         if (srcdir=${srcdir}/liboffloadmic; \
 549                 . ${srcdir}/configure.tgt; \
 550                 test -n "$UNSUPPORTED")
 551         then
 552             AC_MSG_RESULT([no])
 553             noconfigdirs="$noconfigdirs target-liboffloadmic"
 554         else
 555             AC_MSG_RESULT([yes])
 556         fi
 557     fi
 558 fi
 559
 560 # Disable libitm on unsupported systems.
 561 if test -d ${srcdir}/libitm; then
 562     if test x$enable_libitm = x; then
 563         AC_MSG_CHECKING([for libitm support])
 564         if (srcdir=${srcdir}/libitm; \
 565                 . ${srcdir}/configure.tgt; \
 566                 test -n "$UNSUPPORTED")
 567         then
 568             AC_MSG_RESULT([no])
 569             noconfigdirs="$noconfigdirs target-libitm"
 570         else
 571             AC_MSG_RESULT([yes])
 572         fi
 573     fi
 574 fi
 575
 576 # Disable libsanitizer on unsupported systems.
 577 if test -d ${srcdir}/libsanitizer; then
 578     if test x$enable_libsanitizer = x; then
 579         AC_MSG_CHECKING([for libsanitizer support])
 580         if (srcdir=${srcdir}/libsanitizer; \
 581                 . ${srcdir}/configure.tgt; \
 582                 test -n "$UNSUPPORTED")
 583         then
 584             AC_MSG_RESULT([no])
 585             noconfigdirs="$noconfigdirs target-libsanitizer"
 586         else
 587             AC_MSG_RESULT([yes])
 588         fi
 589     fi
 590 fi
 591
 592 # Disable libvtv on unsupported systems.
 593 if test -d ${srcdir}/libvtv; then
 594     if test x$enable_libvtv = x; then
 595         AC_MSG_CHECKING([for libvtv support])
 596         if (srcdir=${srcdir}/libvtv; \
 597                 . ${srcdir}/configure.tgt; \
 598                 test "$VTV_SUPPORTED" != "yes")
 599         then
 600             AC_MSG_RESULT([no])
 601             noconfigdirs="$noconfigdirs target-libvtv"
 602         else
 603             AC_MSG_RESULT([yes])
 604         fi
 605     fi
 606 fi
 607
 608
 609 # Disable libhsail-rt on unsupported systems.
 610 if test -d ${srcdir}/libhsail-rt; then
 611     if test x$enable_libhsail_rt = x; then
 612         AC_MSG_CHECKING([for libhsail-rt support])
 613         if (srcdir=${srcdir}/libhsail-rt; \
 614                 . ${srcdir}/configure.tgt; \
 615                 test -n "$UNSUPPORTED")
 616         then
 617             AC_MSG_RESULT([no])
 618             unsupported_languages="$unsupported_languages brig"
 619             # This implicitly disables also target-libhsail-rt as it won't
 620             # get added to the build without BRIG FE.
 621         else
 622             AC_MSG_RESULT([yes])
 623         fi
 624     fi
 625 fi
 626
 627
 628 # Disable libquadmath for some systems.
 629 case "${target}" in
 630   avr-*-*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633   # libquadmath is unused on AIX and libquadmath build process use of
 634   # LD_LIBRARY_PATH can break AIX bootstrap.
 635   powerpc-*-aix* | rs6000-*-aix*)
 636     noconfigdirs="$noconfigdirs target-libquadmath"
 637     ;;
 638 esac
 639
 640 # Disable libssp for some systems.
 641 case "${target}" in
 642   avr-*-*)
 643     # No hosted I/O support.
 644     noconfigdirs="$noconfigdirs target-libssp"
 645     ;;
 646   powerpc-*-aix* | rs6000-*-aix*)
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649   rl78-*-*)
 650     # libssp uses a misaligned load to trigger a fault, but the RL78
 651     # doesn't fault for those - instead, it gives a build-time error
 652     # for explicit misaligned loads.
 653     noconfigdirs="$noconfigdirs target-libssp"
 654     ;;
 655   visium-*-*)
 656     # No hosted I/O support.
 657     noconfigdirs="$noconfigdirs target-libssp"
 658     ;;
 659 esac
 660
 661 # Disable libstdc++-v3 for some systems.
 662 # Allow user to override this if they pass --enable-libstdc++-v3
 663 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 664   case "${target}" in
 665     *-*-vxworks*)
 666       # VxWorks uses the Dinkumware C++ library.
 667       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 668       ;;
 669     arm*-wince-pe*)
 670       # the C++ libraries don't build on top of CE's C libraries
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     avr-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676     ft32-*-*)
 677       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 678       ;;
 679   esac
 680 fi
 681
 682 # Disable Fortran for some systems.
 683 case "${target}" in
 684   mmix-*-*)
 685     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 686     unsupported_languages="$unsupported_languages fortran"
 687     ;;
 688 esac
 689
 690 # Disable libffi for some systems.
 691 case "${target}" in
 692   powerpc-*-darwin*)
 693     ;;
 694   i[[3456789]]86-*-darwin*)
 695     ;;
 696   x86_64-*-darwin[[912]]*)
 697     ;;
 698   *-*-darwin*)
 699     noconfigdirs="$noconfigdirs target-libffi"
 700     ;;
 701   *-*-netware*)
 702     noconfigdirs="$noconfigdirs target-libffi"
 703     ;;
 704   *-*-phoenix*)
 705     noconfigdirs="$noconfigdirs target-libffi"
 706     ;;
 707   *-*-rtems*)
 708     noconfigdirs="$noconfigdirs target-libffi"
 709     ;;
 710   *-*-tpf*)
 711     noconfigdirs="$noconfigdirs target-libffi"
 712     ;;
 713   *-*-uclinux*)
 714     noconfigdirs="$noconfigdirs target-libffi"
 715     ;;
 716   *-*-vxworks*)
 717     noconfigdirs="$noconfigdirs target-libffi"
 718     ;;
 719   aarch64*-*-freebsd*)
 720     noconfigdirs="$noconfigdirs target-libffi"
 721     ;;
 722   alpha*-*-*vms*)
 723     noconfigdirs="$noconfigdirs target-libffi"
 724     ;;
 725   arm*-*-freebsd*)
 726     noconfigdirs="$noconfigdirs target-libffi"
 727     ;;
 728   arm-wince-pe)
 729     noconfigdirs="$noconfigdirs target-libffi"
 730     ;;
 731   arm*-*-symbianelf*)
 732     noconfigdirs="$noconfigdirs target-libffi"
 733     ;;
 734   cris-*-* | crisv32-*-*)
 735     case "${target}" in
 736       *-*-linux*)
 737         ;;
 738       *) # See PR46792 regarding target-libffi.
 739         noconfigdirs="$noconfigdirs target-libffi";;
 740     esac
 741     ;;
 742   hppa*64*-*-hpux*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   hppa*-hp-hpux11*)
 746     ;;
 747   hppa*-*-hpux*)
 748     noconfigdirs="$noconfigdirs target-libffi"
 749     ;;
 750   ia64*-*-*vms*)
 751     noconfigdirs="$noconfigdirs target-libffi"
 752     ;;
 753   i[[3456789]]86-w64-mingw*)
 754     noconfigdirs="$noconfigdirs target-libffi"
 755     ;;
 756   i[[3456789]]86-*-mingw*)
 757     noconfigdirs="$noconfigdirs target-libffi"
 758     ;;
 759   x86_64-*-mingw*)
 760     noconfigdirs="$noconfigdirs target-libffi"
 761     ;;
 762   mmix-*-*)
 763     noconfigdirs="$noconfigdirs target-libffi"
 764     ;;
 765   powerpc-*-aix*)
 766     ;;
 767   rs6000-*-aix*)
 768     ;;
 769   ft32-*-*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-lynxos*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775 esac
 776
 777 # Disable the go frontend on systems where it is known to not work. Please keep
 778 # this in sync with contrib/config-list.mk.
 779 case "${target}" in
 780 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 781     unsupported_languages="$unsupported_languages go"
 782     ;;
 783 esac
 784
 785 # Only allow gdbserver on some systems.
 786 if test -d ${srcdir}/gdbserver; then
 787     if test x$enable_gdbserver = x; then
 788         AC_MSG_CHECKING([for gdbserver support])
 789         if (srcdir=${srcdir}/gdbserver; \
 790                 . ${srcdir}/configure.srv; \
 791                 test -n "$UNSUPPORTED")
 792         then
 793             AC_MSG_RESULT([no])
 794             noconfigdirs="$noconfigdirs gdbserver"
 795         else
 796             AC_MSG_RESULT([yes])
 797         fi
 798     fi
 799 fi
 800
 801 # Disable libgo for some systems where it is known to not work.
 802 # For testing, you can easily override this with --enable-libgo.
 803 if test x$enable_libgo = x; then
 804     case "${target}" in
 805     *-*-darwin*)
 806         # PR 46986
 807         noconfigdirs="$noconfigdirs target-libgo"
 808         ;;
 809     *-*-cygwin* | *-*-mingw*)
 810         noconfigdirs="$noconfigdirs target-libgo"
 811         ;;
 812     esac
 813 fi
 814
 815 # Default libgloss CPU subdirectory.
 816 libgloss_dir="$target_cpu"
 817
 818 case "${target}" in
 819   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 820     libgloss_dir=wince
 821     ;;
 822   aarch64*-*-* )
 823     libgloss_dir=aarch64
 824     ;;
 825   arm*-*-*)
 826     libgloss_dir=arm
 827     ;;
 828   cris-*-* | crisv32-*-*)
 829     libgloss_dir=cris
 830     ;;
 831   hppa*-*-*)
 832     libgloss_dir=pa
 833     ;;
 834   i[[3456789]]86-*-*)
 835     libgloss_dir=i386
 836     ;;
 837   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 838     libgloss_dir=m68hc11
 839     ;;
 840   m68*-*-* | fido-*-*)
 841     libgloss_dir=m68k
 842     ;;
 843   mips*-*-*)
 844     libgloss_dir=mips
 845     ;;
 846   powerpc*-*-*)
 847     libgloss_dir=rs6000
 848     ;;
 849   sparc*-*-*)
 850     libgloss_dir=sparc
 851     ;;
 852 esac
 853
 854 # Disable newlib and libgloss for various target OSes.
 855 case "${target}" in
 856   alpha*-dec-osf*)
 857     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 858     ;;
 859   i[[3456789]]86-*-linux*)
 860     # This section makes it possible to build newlib natively on linux.
 861     # If we are using a cross compiler then don't configure newlib.
 862     if test x${is_cross_compiler} != xno ; then
 863       noconfigdirs="$noconfigdirs target-newlib"
 864     fi
 865     noconfigdirs="$noconfigdirs target-libgloss"
 866     # If we are not using a cross compiler, do configure newlib.
 867     # Note however, that newlib will only be configured in this situation
 868     # if the --with-newlib option has been given, because otherwise
 869     # 'target-newlib' will appear in skipdirs.
 870     ;;
 871   i[[3456789]]86-*-rdos*)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   sparc-*-sunos4*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-aix*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-beos*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-chorusos)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-dragonfly*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-freebsd*)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898   *-*-lynxos*)
 899     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 900     ;;
 901   *-*-mingw*)
 902     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 903     ;;
 904   *-*-netbsd*)
 905     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 906     ;;
 907   *-*-netware*)
 908     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 909     ;;
 910   *-*-tpf*)
 911     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 912     ;;
 913   *-*-uclinux*)
 914     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 915     ;;
 916   *-*-vxworks*)
 917     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 918     ;;
 919 esac
 920
 921 case "${target}" in
 922   *-*-chorusos)
 923     ;;
 924   aarch64-*-darwin*)
 925     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 926     noconfigdirs="$noconfigdirs sim target-rda"
 927     ;;
 928   arm-*-darwin*)
 929     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 930     noconfigdirs="$noconfigdirs sim target-rda"
 931     ;;
 932   powerpc-*-darwin*)
 933     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 934     noconfigdirs="$noconfigdirs sim target-rda"
 935     ;;
 936   i[[3456789]]86-*-darwin*)
 937     noconfigdirs="$noconfigdirs ld gprof"
 938     noconfigdirs="$noconfigdirs sim target-rda"
 939     ;;
 940   x86_64-*-darwin[[912]]*)
 941     noconfigdirs="$noconfigdirs ld gas gprof"
 942     noconfigdirs="$noconfigdirs sim target-rda"
 943     ;;
 944   *-*-darwin*)
 945     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 946     noconfigdirs="$noconfigdirs sim target-rda"
 947     ;;
 948   *-*-dragonfly*)
 949     ;;
 950   *-*-freebsd*)
 951     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 952         && test -f /usr/local/include/gmp.h; then
 953       with_gmp=/usr/local
 954     fi
 955     ;;
 956   *-*-kaos*)
 957     # Remove unsupported stuff on all kaOS configurations.
 958     noconfigdirs="$noconfigdirs target-libgloss"
 959     ;;
 960   *-*-netbsd*)
 961     ;;
 962   *-*-netware*)
 963     ;;
 964   *-*-phoenix*)
 965     noconfigdirs="$noconfigdirs target-libgloss"
 966     ;;
 967   *-*-rtems*)
 968     noconfigdirs="$noconfigdirs target-libgloss"
 969     ;;
 970     # The tpf target doesn't support gdb yet.
 971   *-*-tpf*)
 972     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 973     ;;
 974   *-*-uclinux*)
 975     noconfigdirs="$noconfigdirs target-rda"
 976     ;;
 977   *-*-vxworks*)
 978     ;;
 979   alpha*-dec-osf*)
 980     # ld works, but does not support shared libraries.
 981     # gas doesn't generate exception information.
 982     noconfigdirs="$noconfigdirs gas ld"
 983     ;;
 984   alpha*-*-*vms*)
 985     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 986     ;;
 987   alpha*-*-*)
 988     # newlib is not 64 bit ready
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 992     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 993     ;;
 994   arc*-*-*)
 995     noconfigdirs="$noconfigdirs sim"
 996     ;;
 997   arm-*-pe*)
 998     noconfigdirs="$noconfigdirs target-libgloss"
 999     ;;
1000   arm-*-riscix*)
1001     noconfigdirs="$noconfigdirs ld target-libgloss"
1002     ;;
1003   avr-*-*)
1004     if test x${with_avrlibc} != xno; then
1005       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1006     fi
1007     ;;
1008   c4x-*-* | tic4x-*-*)
1009     noconfigdirs="$noconfigdirs target-libgloss"
1010     ;;
1011   tic54x-*-*)
1012     noconfigdirs="$noconfigdirs target-libgloss gdb"
1013     ;;
1014   d10v-*-*)
1015     noconfigdirs="$noconfigdirs target-libgloss"
1016     ;;
1017   d30v-*-*)
1018     noconfigdirs="$noconfigdirs gdb"
1019     ;;
1020   fr30-*-elf*)
1021     noconfigdirs="$noconfigdirs gdb"
1022     ;;
1023   ft32-*-*)
1024     noconfigdirs="$noconfigdirs target-rda gprof"
1025     ;;
1026   moxie-*-*)
1027     noconfigdirs="$noconfigdirs"
1028     ;;
1029   h8300*-*-*)
1030     noconfigdirs="$noconfigdirs target-libgloss"
1031     ;;
1032   h8500-*-*)
1033     noconfigdirs="$noconfigdirs target-libgloss"
1034     ;;
1035   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1036     ;;
1037   hppa*64*-*-hpux*)
1038     noconfigdirs="$noconfigdirs gdb"
1039     ;;
1040   hppa*-*-hpux11*)
1041     noconfigdirs="$noconfigdirs gdb ld"
1042     ;;
1043   hppa*64*-*-linux*)
1044     ;;
1045   hppa*-*-linux*)
1046     ;;
1047   hppa*-*-*elf* | \
1048   hppa*-*-lites* | \
1049   hppa*-*-openbsd* | \
1050   hppa*64*-*-*)
1051     ;;
1052   hppa*-*-pro*)
1053     ;;
1054   hppa*-*-*)
1055     noconfigdirs="$noconfigdirs ld"
1056     ;;
1057   i960-*-*)
1058     noconfigdirs="$noconfigdirs gdb"
1059     ;;
1060   ia64*-*-elf*)
1061     # No gdb support yet.
1062     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1063     ;;
1064   ia64*-**-hpux*)
1065     # No ld support yet.
1066     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1067     ;;
1068   ia64*-*-*vms*)
1069     # No ld support yet.
1070     noconfigdirs="$noconfigdirs libgui itcl ld"
1071     ;;
1072   i[[3456789]]86-w64-mingw*)
1073     ;;
1074   i[[3456789]]86-*-mingw*)
1075     target_configdirs="$target_configdirs target-winsup"
1076     ;;
1077   *-*-cygwin*)
1078     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1079     noconfigdirs="$noconfigdirs target-libgloss"
1080     # always build newlib if winsup directory is present.
1081     if test -d "$srcdir/winsup/cygwin"; then
1082       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1083     elif test -d "$srcdir/newlib"; then
1084       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1085     fi
1086     ;;
1087   i[[3456789]]86-*-pe)
1088     noconfigdirs="$noconfigdirs target-libgloss"
1089     ;;
1090   i[[3456789]]86-*-sco3.2v5*)
1091     # The linker does not yet know about weak symbols in COFF,
1092     # and is not configured to handle mixed ELF and COFF.
1093     noconfigdirs="$noconfigdirs ld target-libgloss"
1094     ;;
1095   i[[3456789]]86-*-sco*)
1096     noconfigdirs="$noconfigdirs gprof target-libgloss"
1097     ;;
1098   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1099     noconfigdirs="$noconfigdirs target-libgloss"
1100     ;;
1101   i[[3456789]]86-*-sysv4*)
1102     noconfigdirs="$noconfigdirs target-libgloss"
1103     ;;
1104   i[[3456789]]86-*-beos*)
1105     noconfigdirs="$noconfigdirs gdb"
1106     ;;
1107   i[[3456789]]86-*-rdos*)
1108     noconfigdirs="$noconfigdirs gdb"
1109     ;;
1110   mmix-*-*)
1111     noconfigdirs="$noconfigdirs gdb"
1112     ;;
1113   mt-*-*)
1114     noconfigdirs="$noconfigdirs sim"
1115     ;;
1116   nfp-*-*)
1117     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1118     noconfigdirs="$noconfigdirs $target_libraries"
1119     ;;
1120   pdp11-*-*)
1121     noconfigdirs="$noconfigdirs gdb gprof"
1122     ;;
1123   powerpc-*-aix*)
1124     # copied from rs6000-*-* entry
1125     noconfigdirs="$noconfigdirs gprof"
1126     ;;
1127   powerpc*-*-winnt* | powerpc*-*-pe*)
1128     target_configdirs="$target_configdirs target-winsup"
1129     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1130     # always build newlib.
1131     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1132     ;;
1133     # This is temporary until we can link against shared libraries
1134   powerpcle-*-solaris*)
1135     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1136     ;;
1137   powerpc-*-beos*)
1138     noconfigdirs="$noconfigdirs gdb"
1139     ;;
1140   rs6000-*-lynxos*)
1141     noconfigdirs="$noconfigdirs gprof"
1142     ;;
1143   rs6000-*-aix*)
1144     noconfigdirs="$noconfigdirs gprof"
1145     ;;
1146   rs6000-*-*)
1147     noconfigdirs="$noconfigdirs gprof"
1148     ;;
1149   m68k-apollo-*)
1150     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1151     ;;
1152   microblaze*)
1153     noconfigdirs="$noconfigdirs gprof"
1154     ;;
1155   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1156     if test x$with_newlib = xyes; then
1157       noconfigdirs="$noconfigdirs gprof"
1158     fi
1159     ;;
1160   mips*-*-irix5*)
1161     noconfigdirs="$noconfigdirs gprof target-libgloss"
1162     ;;
1163   mips*-*-irix6*)
1164     noconfigdirs="$noconfigdirs gprof target-libgloss"
1165     ;;
1166   mips*-*-bsd*)
1167     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1168     ;;
1169   mips*-*-linux*)
1170     ;;
1171   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1172   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1173     noconfigdirs="$noconfigdirs ld gas gprof"
1174     ;;
1175   mips*-*-*)
1176     noconfigdirs="$noconfigdirs gprof"
1177     ;;
1178   nvptx*-*-*)
1179     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1180     ;;
1181   sh-*-*)
1182     case "${target}" in
1183       sh*-*-elf)
1184          ;;
1185       *)
1186          noconfigdirs="$noconfigdirs target-libgloss" ;;
1187     esac
1188     ;;
1189   sparc-*-sunos4*)
1190     if test x${is_cross_compiler} = xno ; then
1191            use_gnu_ld=no
1192     fi
1193     ;;
1194   tic6x-*-*)
1195     noconfigdirs="$noconfigdirs sim"
1196     ;;
1197   tilepro*-*-* | tilegx*-*-*)
1198     noconfigdirs="$noconfigdirs sim"
1199     ;;
1200   v810-*-*)
1201     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1202     ;;
1203   vax-*-*)
1204     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1205     ;;
1206   wasm32-*-*)
1207     noconfigdirs="$noconfigdirs ld"
1208     ;;
1209 esac
1210
1211 # If we aren't building newlib, then don't build libgloss, since libgloss
1212 # depends upon some newlib header files.
1213 case "${noconfigdirs}" in
1214   *target-libgloss*) ;;
1215   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1216 esac
1217
1218 # Work in distributions that contain no compiler tools, like Autoconf.
1219 host_makefile_frag=/dev/null
1220 if test -d ${srcdir}/config ; then
1221 case "${host}" in
1222   i[[3456789]]86-*-msdosdjgpp*)
1223     host_makefile_frag="config/mh-djgpp"
1224     ;;
1225   *-cygwin*)
1226     ACX_CHECK_CYGWIN_CAT_WORKS
1227     host_makefile_frag="config/mh-cygwin"
1228     ;;
1229   *-mingw*)
1230     host_makefile_frag="config/mh-mingw"
1231     ;;
1232   alpha*-linux*)
1233     host_makefile_frag="config/mh-alpha-linux"
1234     ;;
1235   hppa*-hp-hpux10*)
1236     host_makefile_frag="config/mh-pa-hpux10"
1237     ;;
1238   hppa*-hp-hpux*)
1239     host_makefile_frag="config/mh-pa"
1240     ;;
1241   hppa*-*)
1242     host_makefile_frag="config/mh-pa"
1243     ;;
1244   *-*-darwin*)
1245     host_makefile_frag="config/mh-darwin"
1246     ;;
1247   powerpc-*-aix*)
1248     host_makefile_frag="config/mh-ppc-aix"
1249     ;;
1250   rs6000-*-aix*)
1251     host_makefile_frag="config/mh-ppc-aix"
1252     ;;
1253 esac
1254 fi
1255
1256 if test "${build}" != "${host}" ; then
1257   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1258   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1259   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1260   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1261   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1262   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1263   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1264   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1265   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1266   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1267   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1268   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1269 else
1270   AR_FOR_BUILD="\$(AR)"
1271   AS_FOR_BUILD="\$(AS)"
1272   CC_FOR_BUILD="\$(CC)"
1273   CXX_FOR_BUILD="\$(CXX)"
1274   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1275   GOC_FOR_BUILD="\$(GOC)"
1276   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1277   LD_FOR_BUILD="\$(LD)"
1278   NM_FOR_BUILD="\$(NM)"
1279   RANLIB_FOR_BUILD="\$(RANLIB)"
1280   WINDRES_FOR_BUILD="\$(WINDRES)"
1281   WINDMC_FOR_BUILD="\$(WINDMC)"
1282 fi
1283
1284 AC_PROG_CC
1285 AC_PROG_CXX
1286
1287 # We must set the default linker to the linker used by gcc for the correct
1288 # operation of libtool.  If LD is not defined and we are using gcc, try to
1289 # set the LD default to the ld used by gcc.
1290 if test -z "$LD"; then
1291   if test "$GCC" = yes; then
1292     case $build in
1293     *-*-mingw*)
1294       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1295     *)
1296       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1297     esac
1298     case $gcc_prog_ld in
1299     # Accept absolute paths.
1300     [[\\/]* | [A-Za-z]:[\\/]*)]
1301       LD="$gcc_prog_ld" ;;
1302     esac
1303   fi
1304 fi
1305
1306 # Check whether -static-libstdc++ -static-libgcc is supported.
1307 have_static_libs=no
1308 if test "$GCC" = yes; then
1309   saved_LDFLAGS="$LDFLAGS"
1310
1311   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1312   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1313   AC_LANG_PUSH(C++)
1314   AC_LINK_IFELSE([AC_LANG_SOURCE([
1315 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1316 #error -static-libstdc++ not implemented
1317 #endif
1318 int main() {}])],
1319     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1320     [AC_MSG_RESULT([no])])
1321   AC_LANG_POP(C++)
1322
1323   LDFLAGS="$saved_LDFLAGS"
1324 fi
1325
1326 ACX_PROG_GNAT
1327 ACX_PROG_CMP_IGNORE_INITIAL
1328
1329 AC_ARG_ENABLE([bootstrap],
1330 [AS_HELP_STRING([--enable-bootstrap],
1331                 [enable bootstrapping @<:@yes if native build@:>@])],,
1332 enable_bootstrap=default)
1333
1334 # Issue errors and warnings for invalid/strange bootstrap combinations.
1335 if test -r $srcdir/gcc/configure; then
1336   have_compiler=yes
1337 else
1338   have_compiler=no
1339 fi
1340
1341 case "$have_compiler:$host:$target:$enable_bootstrap" in
1342   *:*:*:no) ;;
1343
1344   # Default behavior.  Enable bootstrap if we have a compiler
1345   # and we are in a native configuration.
1346   yes:$build:$build:default)
1347     enable_bootstrap=yes ;;
1348
1349   *:*:*:default)
1350     enable_bootstrap=no ;;
1351
1352   # We have a compiler and we are in a native configuration, bootstrap is ok
1353   yes:$build:$build:yes)
1354     ;;
1355
1356   # Other configurations, but we have a compiler.  Assume the user knows
1357   # what he's doing.
1358   yes:*:*:yes)
1359     AC_MSG_WARN([trying to bootstrap a cross compiler])
1360     ;;
1361
1362   # No compiler: if they passed --enable-bootstrap explicitly, fail
1363   no:*:*:yes)
1364     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1365
1366   # Fail if wrong command line
1367   *)
1368     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1369     ;;
1370 esac
1371
1372 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1373 # C++98 compiler can still start the bootstrap.
1374 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1375   CXX="$CXX -std=gnu++98"
1376 fi
1377
1378 AC_ARG_ENABLE([pgo-build],
1379 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1380                 [enable the PGO build])],
1381 [enable_pgo_build=$enableval],
1382 [enable_pgo_build=no])
1383
1384 # Issue errors and warnings for invalid/strange PGO build combinations.
1385 case "$have_compiler:$host:$target:$enable_pgo_build" in
1386   *:*:*:no) ;;
1387
1388   # Allow the PGO build only if we aren't building a compiler and
1389   # we are in a native configuration.
1390   no:$build:$build:yes | no:$build:$build:lto) ;;
1391
1392   # Disallow the PGO bootstrap if we are building a compiler.
1393   yes:*:*:yes | yes:*:*:lto)
1394     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1395
1396   *)
1397     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1398     ;;
1399 esac
1400
1401 if test "$enable_pgo_build" != "no"; then
1402   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1403   old_CFLAGS="$CFLAGS"
1404   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1405   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1406   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1407                     [PGO_BUILD_GEN_CFLAGS=])
1408   CFLAGS="$old_CFLAGS"
1409   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1410     AC_MSG_RESULT([yes])
1411     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1412   else
1413     AC_MSG_RESULT([no])
1414     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1415   fi
1416
1417   if test "$enable_pgo_build" = "lto"; then
1418     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1419     old_CFLAGS="$CFLAGS"
1420     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1421     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1422     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1423                       [PGO_BUILD_LTO_CFLAGS=])
1424     CFLAGS="$old_CFLAGS"
1425     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1426       AC_MSG_RESULT([yes])
1427     else
1428       AC_MSG_RESULT([no])
1429       AC_MSG_WARN([LTO is disabled for the PGO build])
1430     fi
1431   fi
1432 fi
1433 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1434 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1435 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1436
1437 # Used for setting $lt_cv_objdir
1438 _LT_CHECK_OBJDIR
1439
1440 # Check for GMP, MPFR and MPC
1441 gmplibs="-lmpc -lmpfr -lgmp"
1442 gmpinc=
1443 have_gmp=no
1444
1445 # Specify a location for mpc
1446 # check for this first so it ends up on the link line before mpfr.
1447 AC_ARG_WITH(mpc,
1448 [AS_HELP_STRING([--with-mpc=PATH],
1449                 [specify prefix directory for installed MPC package.
1450                  Equivalent to --with-mpc-include=PATH/include
1451                  plus --with-mpc-lib=PATH/lib])])
1452 AC_ARG_WITH(mpc-include,
1453 [AS_HELP_STRING([--with-mpc-include=PATH],
1454                 [specify directory for installed MPC include files])])
1455 AC_ARG_WITH(mpc-lib,
1456 [AS_HELP_STRING([--with-mpc-lib=PATH],
1457                 [specify directory for the installed MPC library])])
1458
1459 if test "x$with_mpc" != x; then
1460   gmplibs="-L$with_mpc/lib $gmplibs"
1461   gmpinc="-I$with_mpc/include $gmpinc"
1462 fi
1463 if test "x$with_mpc_include" != x; then
1464   gmpinc="-I$with_mpc_include $gmpinc"
1465 fi
1466 if test "x$with_mpc_lib" != x; then
1467   gmplibs="-L$with_mpc_lib $gmplibs"
1468 fi
1469 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1470   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1471   gmpinc='-I$$s/mpc/src '"$gmpinc"
1472   # Do not test the mpc version.  Assume that it is sufficient, since
1473   # it is in the source tree, and the library has not been built yet
1474   # but it would be included on the link line in the version check below
1475   # hence making the test fail.
1476   have_gmp=yes
1477 fi
1478
1479 # Specify a location for mpfr
1480 # check for this first so it ends up on the link line before gmp.
1481 AC_ARG_WITH(mpfr-dir,
1482 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1483 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1484 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1485
1486 AC_ARG_WITH(mpfr,
1487 [AS_HELP_STRING([--with-mpfr=PATH],
1488                 [specify prefix directory for installed MPFR package.
1489                  Equivalent to --with-mpfr-include=PATH/include
1490                  plus --with-mpfr-lib=PATH/lib])])
1491 AC_ARG_WITH(mpfr-include,
1492 [AS_HELP_STRING([--with-mpfr-include=PATH],
1493                 [specify directory for installed MPFR include files])])
1494 AC_ARG_WITH(mpfr-lib,
1495 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1496                 [specify directory for the installed MPFR library])])
1497
1498 if test "x$with_mpfr" != x; then
1499   gmplibs="-L$with_mpfr/lib $gmplibs"
1500   gmpinc="-I$with_mpfr/include $gmpinc"
1501 fi
1502 if test "x$with_mpfr_include" != x; then
1503   gmpinc="-I$with_mpfr_include $gmpinc"
1504 fi
1505 if test "x$with_mpfr_lib" != x; then
1506   gmplibs="-L$with_mpfr_lib $gmplibs"
1507 fi
1508 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1509   # MPFR v3.1.0 moved the sources into a src sub-directory.
1510   if ! test -d ${srcdir}/mpfr/src; then
1511     AC_MSG_ERROR([dnl
1512 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1513   fi
1514   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1515   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1516   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1517   # Do not test the mpfr version.  Assume that it is sufficient, since
1518   # it is in the source tree, and the library has not been built yet
1519   # but it would be included on the link line in the version check below
1520   # hence making the test fail.
1521   have_gmp=yes
1522 fi
1523
1524 # Specify a location for gmp
1525 AC_ARG_WITH(gmp-dir,
1526 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1527 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1528 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1529
1530 AC_ARG_WITH(gmp,
1531 [AS_HELP_STRING([--with-gmp=PATH],
1532                 [specify prefix directory for the installed GMP package.
1533                  Equivalent to --with-gmp-include=PATH/include
1534                  plus --with-gmp-lib=PATH/lib])])
1535 AC_ARG_WITH(gmp-include,
1536 [AS_HELP_STRING([--with-gmp-include=PATH],
1537                 [specify directory for installed GMP include files])])
1538 AC_ARG_WITH(gmp-lib,
1539 [AS_HELP_STRING([--with-gmp-lib=PATH],
1540                 [specify directory for the installed GMP library])])
1541
1542
1543 if test "x$with_gmp" != x; then
1544   gmplibs="-L$with_gmp/lib $gmplibs"
1545   gmpinc="-I$with_gmp/include $gmpinc"
1546 fi
1547 if test "x$with_gmp_include" != x; then
1548   gmpinc="-I$with_gmp_include $gmpinc"
1549 fi
1550 if test "x$with_gmp_lib" != x; then
1551   gmplibs="-L$with_gmp_lib $gmplibs"
1552 fi
1553 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1554   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1555   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1556   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1557   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1558   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1559   # Do not test the gmp version.  Assume that it is sufficient, since
1560   # it is in the source tree, and the library has not been built yet
1561   # but it would be included on the link line in the version check below
1562   # hence making the test fail.
1563   have_gmp=yes
1564 fi
1565
1566 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1567   have_gmp=yes
1568   saved_CFLAGS="$CFLAGS"
1569   CFLAGS="$CFLAGS $gmpinc"
1570   # Check for the recommended and required versions of GMP.
1571   AC_MSG_CHECKING([for the correct version of gmp.h])
1572   AC_TRY_COMPILE([#include "gmp.h"],[
1573   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1574   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1575   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1576   choke me
1577   #endif
1578   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1579   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1580   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1581   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1582   choke me
1583   #endif
1584   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1585    [AC_MSG_RESULT([no]); have_gmp=no])
1586
1587   # If we have GMP, check the MPFR version.
1588   if test x"$have_gmp" = xyes; then
1589     # Check for the recommended and required versions of MPFR.
1590     AC_MSG_CHECKING([for the correct version of mpfr.h])
1591     AC_TRY_COMPILE([#include <gmp.h>
1592     #include <mpfr.h>],[
1593     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1594     choke me
1595     #endif
1596     ], [AC_TRY_COMPILE([#include <gmp.h>
1597     #include <mpfr.h>],[
1598     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1599     choke me
1600     #endif
1601     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1602      [AC_MSG_RESULT([no]); have_gmp=no])
1603   fi
1604
1605   # Check for the MPC header version.
1606   if test x"$have_gmp" = xyes ; then
1607     # Check for the recommended and required versions of MPC.
1608     AC_MSG_CHECKING([for the correct version of mpc.h])
1609     AC_TRY_COMPILE([#include <mpc.h>],[
1610     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1611     choke me
1612     #endif
1613     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1614     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1615     choke me
1616     #endif
1617     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1618      [AC_MSG_RESULT([no]); have_gmp=no])
1619   fi
1620
1621   # Now check the MPFR library.
1622   if test x"$have_gmp" = xyes; then
1623     saved_LIBS="$LIBS"
1624     LIBS="$LIBS $gmplibs"
1625     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1626     AC_TRY_LINK([#include <mpc.h>],[
1627     mpfr_t n;
1628     mpfr_t x;
1629     mpc_t c;
1630     int t;
1631     mpfr_init (n);
1632     mpfr_init (x);
1633     mpfr_atan2 (n, n, x, GMP_RNDN);
1634     mpfr_erfc (n, x, GMP_RNDN);
1635     mpfr_subnormalize (x, t, GMP_RNDN);
1636     mpfr_clear(n);
1637     mpfr_clear(x);
1638     mpc_init2 (c, 53);
1639     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1640     mpc_cosh (c, c, MPC_RNDNN);
1641     mpc_pow (c, c, c, MPC_RNDNN);
1642     mpc_acosh (c, c, MPC_RNDNN);
1643     mpc_clear (c);
1644     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1645     LIBS="$saved_LIBS"
1646   fi
1647
1648   CFLAGS="$saved_CFLAGS"
1649
1650 # The library versions listed in the error message below should match
1651 # the HARD-minimums enforced above.
1652   if test x$have_gmp != xyes; then
1653     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1654 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1655 their locations.  Source code for these libraries can be found at
1656 their respective hosting sites as well as at
1657 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1658 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1659 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1660 make sure that you have installed both the libraries and the header
1661 files.  They may be located in separate packages.])
1662   fi
1663 fi
1664
1665 # Flags needed for both GMP, MPFR and/or MPC.
1666 AC_SUBST(gmplibs)
1667 AC_SUBST(gmpinc)
1668 AC_SUBST(extra_mpfr_configure_flags)
1669 AC_SUBST(extra_mpc_gmp_configure_flags)
1670 AC_SUBST(extra_mpc_mpfr_configure_flags)
1671 AC_SUBST(extra_isl_gmp_configure_flags)
1672
1673 # Libraries to use for stage1 or when not bootstrapping.
1674 AC_ARG_WITH(stage1-libs,
1675 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1676 [if test "$withval" = "no" -o "$withval" = "yes"; then
1677    stage1_libs=
1678  else
1679    stage1_libs=$withval
1680  fi],
1681 [stage1_libs=])
1682 AC_SUBST(stage1_libs)
1683
1684 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1685 # default is yes if gcc is being built; no otherwise.  The reason for
1686 # this default is that gdb is sometimes linked against GNU Source
1687 # Highlight, which is a shared library that uses C++ exceptions.  In
1688 # this case, -static-libstdc++ will cause crashes.
1689 AC_ARG_WITH(static-standard-libraries,
1690 [AS_HELP_STRING([--with-static-standard-libraries],
1691                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1692 [], [with_static_standard_libraries=auto])
1693 if test "$with_static_standard_libraries" = auto; then
1694   with_static_standard_libraries=$have_compiler
1695 fi
1696
1697 # Linker flags to use for stage1 or when not bootstrapping.
1698 AC_ARG_WITH(stage1-ldflags,
1699 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1700 [if test "$withval" = "no" -o "$withval" = "yes"; then
1701    stage1_ldflags=
1702  else
1703    stage1_ldflags=$withval
1704  fi],
1705 [stage1_ldflags=
1706  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1707  # if supported.  But if the user explicitly specified the libraries to use,
1708  # trust that they are doing what they want.
1709  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1710      -a "$have_static_libs" = yes; then
1711    stage1_ldflags="-static-libstdc++ -static-libgcc"
1712  fi])
1713 AC_SUBST(stage1_ldflags)
1714
1715 # Libraries to use for stage2 and later builds.
1716 AC_ARG_WITH(boot-libs,
1717 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1718 [if test "$withval" = "no" -o "$withval" = "yes"; then
1719    poststage1_libs=
1720  else
1721    poststage1_libs=$withval
1722  fi],
1723 [poststage1_libs=])
1724 AC_SUBST(poststage1_libs)
1725
1726 # Linker flags to use for stage2 and later builds.
1727 AC_ARG_WITH(boot-ldflags,
1728 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1729                 [linker flags for stage2 and later])],
1730 [if test "$withval" = "no" -o "$withval" = "yes"; then
1731    poststage1_ldflags=
1732  else
1733    poststage1_ldflags=$withval
1734  fi],
1735 [poststage1_ldflags=
1736  # In stages 2 and 3, default to linking libstdc++ and libgcc
1737  # statically.  But if the user explicitly specified the libraries to
1738  # use, trust that they are doing what they want.
1739  if test "$poststage1_libs" = ""; then
1740    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1741  fi])
1742 AC_SUBST(poststage1_ldflags)
1743
1744 # GCC GRAPHITE dependency isl.
1745 # Basic setup is inlined here, actual checks are in config/isl.m4
1746
1747 AC_ARG_WITH(isl,
1748   [AS_HELP_STRING(
1749    [--with-isl=PATH],
1750    [Specify prefix directory for the installed isl package.
1751     Equivalent to --with-isl-include=PATH/include
1752     plus --with-isl-lib=PATH/lib])])
1753
1754 # Treat --without-isl as a request to disable
1755 # GRAPHITE support and skip all following checks.
1756 if test "x$with_isl" != "xno"; then
1757   # Check for isl
1758   dnl Provide configure switches and initialize islinc & isllibs
1759   dnl with user input.
1760   ISL_INIT_FLAGS
1761   dnl The versions of isl that work for Graphite
1762   ISL_CHECK_VERSION()
1763   dnl Only execute fail-action, if isl has been requested.
1764   ISL_IF_FAILED([
1765     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1766 fi
1767
1768 # If the isl check failed, disable builds of in-tree variant of isl
1769 if test "x$with_isl" = xno ||
1770    test "x$gcc_cv_isl" = xno; then
1771   noconfigdirs="$noconfigdirs isl"
1772   islinc=
1773 fi
1774
1775 AC_SUBST(isllibs)
1776 AC_SUBST(islinc)
1777
1778 # Check for LTO support.
1779 AC_ARG_ENABLE(lto,
1780 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1781 enable_lto=$enableval,
1782 enable_lto=yes; default_enable_lto=yes)
1783
1784 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1785   build_lto_plugin=yes
1786 ],[if test x"$default_enable_lto" = x"yes" ; then
1787     case $target in
1788       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1789       # On other non-ELF platforms, LTO has yet to be validated.
1790       *) enable_lto=no ;;
1791     esac
1792   else
1793   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1794   # It would also be nice to check the binutils support, but we don't
1795   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1796   # warn during gcc/ subconfigure; unless you're bootstrapping with
1797   # -flto it won't be needed until after installation anyway.
1798     case $target in
1799       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1800       *) if test x"$enable_lto" = x"yes"; then
1801         AC_MSG_ERROR([LTO support is not enabled for this target.])
1802         fi
1803       ;;
1804     esac
1805   fi
1806   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1807   # Build it unless LTO was explicitly disabled.
1808   case $target in
1809     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1810     *) ;;
1811   esac
1812 ])
1813
1814 AC_ARG_ENABLE(linker-plugin-configure-flags,
1815   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1816     [additional flags for configuring linker plugins @<:@none@:>@])],
1817   extra_linker_plugin_configure_flags=$enableval,
1818   extra_linker_plugin_configure_flags=)
1819 AC_SUBST(extra_linker_plugin_configure_flags)
1820 AC_ARG_ENABLE(linker-plugin-flags,
1821   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1822     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1823   extra_linker_plugin_flags=$enableval,
1824   extra_linker_plugin_flags=)
1825 AC_SUBST(extra_linker_plugin_flags)
1826
1827 # Enable --enable-host-shared.
1828 # Checked early to determine whether jit is an 'all' language
1829 AC_ARG_ENABLE(host-shared,
1830 [AS_HELP_STRING([--enable-host-shared],
1831                 [build host code as shared libraries])],
1832 [host_shared=$enableval], [host_shared=no])
1833 AC_SUBST(host_shared)
1834
1835 # By default, C and C++ are the only stage 1 languages.
1836 stage1_languages=,c,
1837
1838 # Target libraries that we bootstrap.
1839 bootstrap_target_libs=,target-libgcc,
1840
1841 # Figure out what language subdirectories are present.
1842 # Look if the user specified --enable-languages="..."; if not, use
1843 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1844 # go away some day.
1845 # NB:  embedded tabs in this IF block -- do not untabify
1846 if test -d ${srcdir}/gcc; then
1847   if test x"${enable_languages+set}" != xset; then
1848     if test x"${LANGUAGES+set}" = xset; then
1849       enable_languages="${LANGUAGES}"
1850         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1851     else
1852       enable_languages=default
1853     fi
1854   else
1855     if test x"${enable_languages}" = x ||
1856        test x"${enable_languages}" = xyes;
1857        then
1858       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1859       exit 1
1860     fi
1861   fi
1862   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1863
1864   # 'f95' is the old name for the 'fortran' language. We issue a warning
1865   # and make the substitution.
1866   case ,${enable_languages}, in
1867     *,f95,*)
1868       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1869       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1870       ;;
1871   esac
1872
1873   # If bootstrapping, C++ must be enabled.
1874   case ",$enable_languages,:$enable_bootstrap" in
1875     *,c++,*:*) ;;
1876     *:yes)
1877       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1878         enable_languages="${enable_languages},c++"
1879       else
1880         AC_MSG_ERROR([bootstrapping requires c++ sources])
1881       fi
1882       ;;
1883   esac
1884
1885   # First scan to see if an enabled language requires some other language.
1886   # We assume that a given config-lang.in will list all the language
1887   # front ends it requires, even if some are required indirectly.
1888   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1889     case ${lang_frag} in
1890       ..) ;;
1891       # The odd quoting in the next line works around
1892       # an apparent bug in bash 1.12 on linux.
1893       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1894       *)
1895         # From the config-lang.in, get $language, $lang_requires, and
1896         # $lang_requires_boot_languages.
1897         language=
1898         lang_requires=
1899         lang_requires_boot_languages=
1900         # set srcdir during sourcing lang_frag to the gcc dir.
1901         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1902         # polutes this shell
1903         saved_srcdir=${srcdir}
1904         srcdir=${srcdir}/gcc . ${lang_frag}
1905         srcdir=${saved_srcdir}
1906         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1907           case ,${enable_languages}, in
1908             *,$other,*) ;;
1909             *,default,*) ;;
1910             *,all,*) ;;
1911             *,$language,*)
1912               echo " \`$other' language required by \`$language'; enabling" 1>&2
1913               enable_languages="${enable_languages},${other}"
1914               ;;
1915           esac
1916         done
1917         for other in ${lang_requires_boot_languages} ; do
1918           if test "$other" != "c"; then
1919             case ,${enable_stage1_languages}, in
1920               *,$other,*) ;;
1921               *,default,*) ;;
1922               *,all,*) ;;
1923               *)
1924                 case ,${enable_languages}, in
1925                   *,$language,*)
1926                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1927                     enable_stage1_languages="$enable_stage1_languages,${other}"
1928                     ;;
1929                 esac
1930                 ;;
1931             esac
1932           fi
1933         done
1934         ;;
1935     esac
1936   done
1937
1938   new_enable_languages=,c,
1939
1940   # If LTO is enabled, add the LTO front end.
1941   if test "$enable_lto" = "yes" ; then
1942     case ,${enable_languages}, in
1943       *,lto,*) ;;
1944       *) enable_languages="${enable_languages},lto" ;;
1945     esac
1946     if test "${build_lto_plugin}" = "yes" ; then
1947       configdirs="$configdirs lto-plugin"
1948     fi
1949   fi
1950
1951   # If we're building an offloading compiler, add the LTO front end.
1952   if test x"$enable_as_accelerator_for" != x ; then
1953     case ,${enable_languages}, in
1954       *,lto,*) ;;
1955       *) enable_languages="${enable_languages},lto" ;;
1956     esac
1957   fi
1958
1959   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1960   potential_languages=,c,
1961
1962   enabled_target_libs=
1963   disabled_target_libs=
1964
1965   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1966     case ${lang_frag} in
1967       ..) ;;
1968       # The odd quoting in the next line works around
1969       # an apparent bug in bash 1.12 on linux.
1970       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1971       *)
1972         # From the config-lang.in, get $language, $target_libs,
1973         # $lang_dirs, $boot_language, and $build_by_default
1974         language=
1975         target_libs=
1976         lang_dirs=
1977         subdir_requires=
1978         boot_language=no
1979         build_by_default=yes
1980         # set srcdir during sourcing.  See above about save & restore
1981         saved_srcdir=${srcdir}
1982         srcdir=${srcdir}/gcc . ${lang_frag}
1983         srcdir=${saved_srcdir}
1984         if test x${language} = x; then
1985           echo "${lang_frag} doesn't set \$language." 1>&2
1986           exit 1
1987         fi
1988
1989         if test "$language" = "c++"; then
1990           boot_language=yes
1991         fi
1992
1993         add_this_lang=no
1994         # C is always enabled, so no need to add it again
1995         if test "$language" != "c"; then
1996           case ,${enable_languages}, in
1997             *,${language},*)
1998               # Language was explicitly selected; include it
1999               add_this_lang=yes
2000               ;;
2001             *,all,*)
2002               # All languages are enabled
2003               add_this_lang=all
2004               ;;
2005             *,default,*)
2006               # 'default' was selected, select it if it is a default language
2007               add_this_lang=${build_by_default}
2008               ;;
2009           esac
2010         fi
2011
2012         # Disable languages that need other directories if these aren't available.
2013         for i in $subdir_requires; do
2014           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2015           case ${add_this_lang} in
2016             yes)
2017               # Specifically requested language; tell them.
2018               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2019               ;;
2020             all)
2021               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2022               add_this_lang=unsupported
2023               ;;
2024             *)
2025               # Silently disable.
2026               add_this_lang=unsupported
2027               ;;
2028           esac
2029         done
2030
2031         # Disable Ada if no preexisting GNAT is available.
2032         case ${add_this_lang}:${language}:${have_gnat} in
2033           yes:ada:no)
2034             # Specifically requested language; tell them.
2035             AC_MSG_ERROR([GNAT is required to build $language])
2036             ;;
2037           all:ada:no)
2038             AC_MSG_WARN([GNAT is required to build $language])
2039             add_this_lang=unsupported
2040             ;;
2041           *:ada:no)
2042             # Silently disable.
2043             add_this_lang=unsupported
2044             ;;
2045         esac
2046
2047         # Disable jit if -enable-host-shared not specified
2048         case ${add_this_lang}:${language}:${host_shared} in
2049           yes:jit:no)
2050             # PR jit/64780: explicitly specify --enable-host-shared
2051             AC_MSG_ERROR([
2052 Enabling language "jit" requires --enable-host-shared.
2053
2054 --enable-host-shared typically slows the rest of the compiler down by
2055 a few %, so you must explicitly enable it.
2056
2057 If you want to build both the jit and the regular compiler, it is often
2058 best to do this via two separate configure/builds, in separate
2059 directories, to avoid imposing the performance cost of
2060 --enable-host-shared on the regular compiler.])
2061             ;;
2062           all:jit:no)
2063             AC_MSG_WARN([--enable-host-shared required to build $language])
2064             add_this_lang=unsupported
2065             ;;
2066           *:jit:no)
2067             # Silently disable.
2068             add_this_lang=unsupported
2069             ;;
2070         esac
2071
2072         # Disable a language that is unsupported by the target.
2073         case "${add_this_lang}: $unsupported_languages " in
2074           no:*) ;;
2075           unsupported:*) ;;
2076           *:*" $language "*)
2077             AC_MSG_WARN([${language} not supported for this target])
2078             add_this_lang=unsupported
2079             ;;
2080         esac
2081
2082         case $add_this_lang in
2083           unsupported)
2084             # Remove language-dependent dirs.
2085             disabled_target_libs="$disabled_target_libs $target_libs"
2086             noconfigdirs="$noconfigdirs $lang_dirs"
2087             ;;
2088           no)
2089             # Remove language-dependent dirs; still show language as supported.
2090             disabled_target_libs="$disabled_target_libs $target_libs"
2091             noconfigdirs="$noconfigdirs $lang_dirs"
2092             potential_languages="${potential_languages}${language},"
2093             ;;
2094           all|yes)
2095             new_enable_languages="${new_enable_languages}${language},"
2096             potential_languages="${potential_languages}${language},"
2097             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2098             enabled_target_libs="$enabled_target_libs $target_libs"
2099             case "${boot_language}:,$enable_stage1_languages," in
2100               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2101                 # Add to (comma-separated) list of stage 1 languages.
2102                 case ",$stage1_languages," in
2103                   *,$language,* | ,yes, | ,all,) ;;
2104                   *) stage1_languages="${stage1_languages}${language}," ;;
2105                 esac
2106                 # We need to bootstrap any supporting libraries.
2107                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2108                 ;;
2109             esac
2110             ;;
2111         esac
2112         ;;
2113     esac
2114   done
2115
2116   # Add target libraries which are only needed for disabled languages
2117   # to noconfigdirs.
2118   if test -n "$disabled_target_libs"; then
2119     for dir in $disabled_target_libs; do
2120       case " $enabled_target_libs " in
2121       *" ${dir} "*) ;;
2122       *) noconfigdirs="$noconfigdirs $dir" ;;
2123       esac
2124     done
2125   fi
2126
2127   AC_ARG_ENABLE(stage1-languages,
2128   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2129                   [choose additional languages to build during
2130                   stage1.  Mostly useful for compiler development])],
2131   [case ,${enable_stage1_languages}, in
2132     ,no,|,,)
2133       # Set it to something that will have no effect in the loop below
2134       enable_stage1_languages=c ;;
2135     ,yes,)
2136       enable_stage1_languages=`echo $new_enable_languages | \
2137         sed -e "s/^,//" -e "s/,$//" ` ;;
2138     *,all,*)
2139       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2140         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2141   esac
2142
2143   # Add "good" languages from enable_stage1_languages to stage1_languages,
2144   # while "bad" languages go in missing_languages.  Leave no duplicates.
2145   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2146     case $potential_languages in
2147       *,$i,*)
2148         case $stage1_languages in
2149           *,$i,*) ;;
2150           *) stage1_languages="$stage1_languages$i," ;;
2151         esac ;;
2152       *)
2153         case $missing_languages in
2154           *,$i,*) ;;
2155           *) missing_languages="$missing_languages$i," ;;
2156         esac ;;
2157      esac
2158   done])
2159
2160   # Remove leading/trailing commas that were added for simplicity
2161   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2162   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2163   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2164   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2165
2166   if test "x$missing_languages" != x; then
2167     AC_MSG_ERROR([
2168 The following requested languages could not be built: ${missing_languages}
2169 Supported languages are: ${potential_languages}])
2170   fi
2171   if test "x$new_enable_languages" != "x$enable_languages"; then
2172     echo The following languages will be built: ${new_enable_languages}
2173     enable_languages="$new_enable_languages"
2174   fi
2175
2176   AC_SUBST(stage1_languages)
2177   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2178 fi
2179
2180 # Handle --disable-<component> generically.
2181 for dir in $configdirs $build_configdirs $target_configdirs ; do
2182   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2183   varname=`echo $dirname | sed -e s/+/_/g`
2184   if eval test x\${enable_${varname}} "=" xno ; then
2185     noconfigdirs="$noconfigdirs $dir"
2186   fi
2187 done
2188
2189 # Check for Boehm's garbage collector
2190 AC_ARG_ENABLE(objc-gc,
2191 [AS_HELP_STRING([--enable-objc-gc],
2192                 [enable use of Boehm's garbage collector with the
2193                  GNU Objective-C runtime])])
2194 AC_ARG_WITH([target-bdw-gc],
2195 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2196                 [specify prefix directory for installed bdw-gc package.
2197                  Equivalent to --with-target-bdw-gc-include=PATH/include
2198                  plus --with-target-bdw-gc-lib=PATH/lib])])
2199 AC_ARG_WITH([target-bdw-gc-include],
2200 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2201                 [specify directories for installed bdw-gc include files])])
2202 AC_ARG_WITH([target-bdw-gc-lib],
2203 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2204                 [specify directories for installed bdw-gc library])])
2205
2206 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2207   AC_MSG_CHECKING([for bdw garbage collector])
2208   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2209     dnl no bdw-gw options, assume default locations
2210     AC_MSG_RESULT([using bdw-gc in default locations])
2211   else
2212     dnl bdw-gw options, first error checking, complete checking in libobjc
2213     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2214       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2215     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2216       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2217     else
2218       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2219     fi
2220   fi
2221 esac
2222
2223 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2224 case ,${enable_languages}, in
2225   *,c++,*)
2226     # Disable libitm, libsanitizer if we're not building libstdc++
2227     case "${noconfigdirs}" in
2228       *target-libstdc++-v3*)
2229         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2230         ;;
2231       *) ;;
2232     esac
2233     ;;
2234   *)
2235     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2236     ;;
2237 esac
2238
2239 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2240 # $build_configdirs and $target_configdirs.
2241 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2242
2243 notsupp=""
2244 for dir in . $skipdirs $noconfigdirs ; do
2245   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2246   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2247     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2248     if test -r $srcdir/$dirname/configure ; then
2249       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2250         true
2251       else
2252         notsupp="$notsupp $dir"
2253       fi
2254     fi
2255   fi
2256   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2257     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2258     if test -r $srcdir/$dirname/configure ; then
2259       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2260         true
2261       else
2262         notsupp="$notsupp $dir"
2263       fi
2264     fi
2265   fi
2266   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2267     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2268     if test -r $srcdir/$dirname/configure ; then
2269       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2270         true
2271       else
2272         notsupp="$notsupp $dir"
2273       fi
2274     fi
2275   fi
2276 done
2277
2278 # Quietly strip out all directories which aren't configurable in this tree.
2279 # This relies on all configurable subdirectories being autoconfiscated, which
2280 # is now the case.
2281 build_configdirs_all="$build_configdirs"
2282 build_configdirs=
2283 for i in ${build_configdirs_all} ; do
2284   j=`echo $i | sed -e s/build-//g`
2285   if test -f ${srcdir}/$j/configure ; then
2286     build_configdirs="${build_configdirs} $i"
2287   fi
2288 done
2289
2290 configdirs_all="$configdirs"
2291 configdirs=
2292 for i in ${configdirs_all} ; do
2293   if test -f ${srcdir}/$i/configure ; then
2294     configdirs="${configdirs} $i"
2295   fi
2296 done
2297
2298 target_configdirs_all="$target_configdirs"
2299 target_configdirs=
2300 for i in ${target_configdirs_all} ; do
2301   j=`echo $i | sed -e s/target-//g`
2302   if test -f ${srcdir}/$j/configure ; then
2303     target_configdirs="${target_configdirs} $i"
2304   fi
2305 done
2306
2307 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2308 # so we have to add it after the preceding checks.
2309 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2310 then
2311   case " $configdirs " in
2312     *" libiberty "*)
2313       # If we can build libiberty, we can also build libiberty-linker-plugin.
2314       configdirs="$configdirs libiberty-linker-plugin"
2315       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2316         --with-libiberty=../libiberty-linker-plugin";;
2317     *)
2318       AC_MSG_ERROR([libiberty missing]);;
2319   esac
2320 fi
2321
2322 # Sometimes we have special requirements for the host libiberty.
2323 extra_host_libiberty_configure_flags=
2324 extra_host_zlib_configure_flags=
2325 case " $configdirs " in
2326   *" lto-plugin "* | *" libcc1 "*)
2327     # When these are to be built as shared libraries, the same applies to
2328     # libiberty.
2329     extra_host_libiberty_configure_flags=--enable-shared
2330     ;;
2331   *" bfd "*)
2332     # When bfd is to be built as a shared library, the same applies to
2333     # zlib.
2334     if test "$enable_shared" = "yes"; then
2335       extra_host_zlib_configure_flags=--enable-host-shared
2336     fi
2337     ;;
2338 esac
2339 AC_SUBST(extra_host_libiberty_configure_flags)
2340 AC_SUBST(extra_host_zlib_configure_flags)
2341
2342 # Produce a warning message for the subdirs we can't configure.
2343 # This isn't especially interesting in the Cygnus tree, but in the individual
2344 # FSF releases, it's important to let people know when their machine isn't
2345 # supported by the one or two programs in a package.
2346
2347 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2348   # If $appdirs is non-empty, at least one of those directories must still
2349   # be configured, or we error out.  (E.g., if the gas release supports a
2350   # specified target in some subdirs but not the gas subdir, we shouldn't
2351   # pretend that all is well.)
2352   if test -n "$appdirs" ; then
2353     for dir in $appdirs ; do
2354       if test -r $dir/Makefile.in ; then
2355         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2356           appdirs=""
2357           break
2358         fi
2359         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2360           appdirs=""
2361           break
2362         fi
2363       fi
2364     done
2365     if test -n "$appdirs" ; then
2366       echo "*** This configuration is not supported by this package." 1>&2
2367       exit 1
2368     fi
2369   fi
2370   # Okay, some application will build, or we don't care to check.  Still
2371   # notify of subdirs not getting built.
2372   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2373   echo "    ${notsupp}" 1>&2
2374   echo "    (Any other directories should still work fine.)" 1>&2
2375 fi
2376
2377 case "$host" in
2378   *msdosdjgpp*)
2379     enable_gdbtk=no ;;
2380 esac
2381
2382 # To find our prefix, in gcc_cv_tool_prefix.
2383 ACX_TOOL_DIRS
2384
2385 copy_dirs=
2386
2387 AC_ARG_WITH([build-sysroot],
2388   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2389                   [use sysroot as the system root during the build])],
2390   [if test x"$withval" != x ; then
2391      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2392    fi],
2393   [SYSROOT_CFLAGS_FOR_TARGET=])
2394 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2395
2396 AC_ARG_WITH([debug-prefix-map],
2397   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2398                   [map A to B, C to D ... in debug information])],
2399   [if test x"$withval" != x; then
2400      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2401      for debug_map in $withval; do
2402        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2403      done
2404    fi],
2405   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2406 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2407
2408 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2409 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2410 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2411 # We want to ensure that TARGET libraries (which we know are built with
2412 # gcc) are built with "-O2 -g", so include those options when setting
2413 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2414 if test "x$CFLAGS_FOR_TARGET" = x; then
2415   if test "x${is_cross_compiler}" = xyes; then
2416     CFLAGS_FOR_TARGET="-g -O2"
2417   else
2418     CFLAGS_FOR_TARGET=$CFLAGS
2419     case " $CFLAGS " in
2420       *" -O2 "*) ;;
2421       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2422     esac
2423     case " $CFLAGS " in
2424       *" -g "* | *" -g3 "*) ;;
2425       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2426     esac
2427   fi
2428 fi
2429 AC_SUBST(CFLAGS_FOR_TARGET)
2430
2431 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2432   if test "x${is_cross_compiler}" = xyes; then
2433     CXXFLAGS_FOR_TARGET="-g -O2"
2434   else
2435     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2436     case " $CXXFLAGS " in
2437       *" -O2 "*) ;;
2438       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2439     esac
2440     case " $CXXFLAGS " in
2441       *" -g "* | *" -g3 "*) ;;
2442       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2443     esac
2444   fi
2445 fi
2446 AC_SUBST(CXXFLAGS_FOR_TARGET)
2447
2448 AC_SUBST(LDFLAGS_FOR_TARGET)
2449
2450 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2451 # the named directory are copied to $(tooldir)/sys-include.
2452 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2453   if test x${is_cross_compiler} = xno ; then
2454     echo 1>&2 '***' --with-headers is only supported when cross compiling
2455     exit 1
2456   fi
2457   if test x"${with_headers}" != xyes ; then
2458     x=${gcc_cv_tool_prefix}
2459     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2460   fi
2461 fi
2462
2463 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2464 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2465 # are permitted.
2466 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2467   if test x${is_cross_compiler} = xno ; then
2468     echo 1>&2 '***' --with-libs is only supported when cross compiling
2469     exit 1
2470   fi
2471   if test x"${with_libs}" != xyes ; then
2472     # Copy the libraries in reverse order, so that files in the first named
2473     # library override files in subsequent libraries.
2474     x=${gcc_cv_tool_prefix}
2475     for l in ${with_libs}; do
2476       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2477     done
2478   fi
2479 fi
2480
2481 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2482 #
2483 # This is done by determining whether or not the appropriate directory
2484 # is available, and by checking whether or not specific configurations
2485 # have requested that this magic not happen.
2486 #
2487 # The command line options always override the explicit settings in
2488 # configure.ac, and the settings in configure.ac override this magic.
2489 #
2490 # If the default for a toolchain is to use GNU as and ld, and you don't
2491 # want to do that, then you should use the --without-gnu-as and
2492 # --without-gnu-ld options for the configure script.  Similarly, if
2493 # the default is to use the included zlib and you don't want to do that,
2494 # you should use the --with-system-zlib option for the configure script.
2495
2496 if test x${use_gnu_as} = x &&
2497    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2498   with_gnu_as=yes
2499   extra_host_args="$extra_host_args --with-gnu-as"
2500 fi
2501
2502 if test x${use_gnu_ld} = x &&
2503    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2504   with_gnu_ld=yes
2505   extra_host_args="$extra_host_args --with-gnu-ld"
2506 fi
2507
2508 if test x${use_included_zlib} = x &&
2509    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2510   :
2511 else
2512   with_system_zlib=yes
2513   extra_host_args="$extra_host_args --with-system-zlib"
2514 fi
2515
2516 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2517 # can detect this case.
2518
2519 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2520   with_newlib=yes
2521   extra_host_args="$extra_host_args --with-newlib"
2522 fi
2523
2524 # Handle ${copy_dirs}
2525 set fnord ${copy_dirs}
2526 shift
2527 while test $# != 0 ; do
2528   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2529     :
2530   else
2531     echo Copying $1 to $2
2532
2533     # Use the install script to create the directory and all required
2534     # parent directories.
2535     if test -d $2 ; then
2536       :
2537     else
2538       echo >config.temp
2539       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2540     fi
2541
2542     # Copy the directory, assuming we have tar.
2543     # FIXME: Should we use B in the second tar?  Not all systems support it.
2544     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2545
2546     # It is the responsibility of the user to correctly adjust all
2547     # symlinks.  If somebody can figure out how to handle them correctly
2548     # here, feel free to add the code.
2549
2550     echo $1 > $2/COPIED
2551   fi
2552   shift; shift
2553 done
2554
2555 # Determine a target-dependent exec_prefix that the installed
2556 # gcc will search in.  Keep this list sorted by triplet, with
2557 # the *-*-osname triplets last.
2558 md_exec_prefix=
2559 case "${target}" in
2560   i[[34567]]86-pc-msdosdjgpp*)
2561     md_exec_prefix=/dev/env/DJDIR/bin
2562     ;;
2563   *-*-hpux* | \
2564   *-*-nto-qnx* | \
2565   *-*-solaris2*)
2566     md_exec_prefix=/usr/ccs/bin
2567     ;;
2568 esac
2569
2570 extra_arflags_for_target=
2571 extra_nmflags_for_target=
2572 extra_ranlibflags_for_target=
2573 target_makefile_frag=/dev/null
2574 case "${target}" in
2575   spu-*-*)
2576     target_makefile_frag="config/mt-spu"
2577     ;;
2578   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2579     target_makefile_frag="config/mt-sde"
2580     ;;
2581   mipsisa*-*-elfoabi*)
2582     target_makefile_frag="config/mt-mips-elfoabi"
2583     ;;
2584   mips*-*-*linux* | mips*-*-gnu*)
2585     target_makefile_frag="config/mt-mips-gnu"
2586     ;;
2587   nios2-*-elf*)
2588     target_makefile_frag="config/mt-nios2-elf"
2589     ;;
2590   *-*-linux-android*)
2591     target_makefile_frag="config/mt-android"
2592     ;;
2593   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2594     target_makefile_frag="config/mt-gnu"
2595     ;;
2596   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2597     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2598     # commands to handle both 32-bit and 64-bit objects.  These flags are
2599     # harmless if we're using GNU nm or ar.
2600     extra_arflags_for_target=" -X32_64"
2601     extra_nmflags_for_target=" -B -X32_64"
2602     ;;
2603 esac
2604
2605 alphaieee_frag=/dev/null
2606 case $target in
2607   alpha*-*-*)
2608     # This just makes sure to use the -mieee option to build target libs.
2609     # This should probably be set individually by each library.
2610     alphaieee_frag="config/mt-alphaieee"
2611     ;;
2612 esac
2613
2614 # If --enable-target-optspace always use -Os instead of -O2 to build
2615 # the target libraries, similarly if it is not specified, use -Os
2616 # on selected platforms.
2617 ospace_frag=/dev/null
2618 case "${enable_target_optspace}:${target}" in
2619   yes:*)
2620     ospace_frag="config/mt-ospace"
2621     ;;
2622   :d30v-*)
2623     ospace_frag="config/mt-d30v"
2624     ;;
2625   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2626     ospace_frag="config/mt-ospace"
2627     ;;
2628   no:* | :*)
2629     ;;
2630   *)
2631     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2632     ;;
2633 esac
2634
2635 # Some systems (e.g., one of the i386-aix systems the gas testers are
2636 # using) don't handle "\$" correctly, so don't use it here.
2637 tooldir='${exec_prefix}'/${target_noncanonical}
2638 build_tooldir=${tooldir}
2639
2640 # Create a .gdbinit file which runs the one in srcdir
2641 # and tells GDB to look there for source files.
2642
2643 if test -r ${srcdir}/.gdbinit ; then
2644   case ${srcdir} in
2645     .) ;;
2646     *) cat > ./.gdbinit <<EOF
2647 # ${NO_EDIT}
2648 dir ${srcdir}
2649 dir .
2650 source ${srcdir}/.gdbinit
2651 EOF
2652     ;;
2653   esac
2654 fi
2655
2656 # Make sure that the compiler is able to generate an executable.  If it
2657 # can't, we are probably in trouble.  We don't care whether we can run the
2658 # executable--we might be using a cross compiler--we only care whether it
2659 # can be created.  At this point the main configure script has set CC.
2660 we_are_ok=no
2661 echo "int main () { return 0; }" > conftest.c
2662 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2663 if test $? = 0 ; then
2664   if test -s conftest || test -s conftest.exe ; then
2665     we_are_ok=yes
2666   fi
2667 fi
2668 case $we_are_ok in
2669   no)
2670     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2671     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2672     rm -f conftest*
2673     exit 1
2674     ;;
2675 esac
2676 rm -f conftest*
2677
2678 # Decide which environment variable is used to find dynamic libraries.
2679 case "${host}" in
2680   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2681   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2682   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2683   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2684 esac
2685
2686 # On systems where the dynamic library environment variable is PATH,
2687 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2688 # built executables to PATH.
2689 if test "$RPATH_ENVVAR" = PATH; then
2690   GCC_SHLIB_SUBDIR=/shlib
2691 else
2692   GCC_SHLIB_SUBDIR=
2693 fi
2694
2695 # Adjust the toplevel makefile according to whether bootstrap was selected.
2696 case $enable_bootstrap in
2697   yes)
2698     bootstrap_suffix=bootstrap
2699     BUILD_CONFIG=bootstrap-debug
2700     ;;
2701   no)
2702     bootstrap_suffix=no-bootstrap
2703     BUILD_CONFIG=
2704     ;;
2705 esac
2706
2707 AC_MSG_CHECKING(for default BUILD_CONFIG)
2708
2709 AC_ARG_WITH([build-config],
2710   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2711                   [use config/NAME.mk build configuration])],
2712   [case $with_build_config in
2713    yes) with_build_config= ;;
2714    no) with_build_config= BUILD_CONFIG= ;;
2715    esac])
2716
2717 if test "x${with_build_config}" != x; then
2718   BUILD_CONFIG=$with_build_config
2719 else
2720   case $BUILD_CONFIG in
2721   bootstrap-debug)
2722     if echo "int f (void) { return 0; }" > conftest.c &&
2723        ${CC} -c conftest.c &&
2724        mv conftest.o conftest.o.g0 &&
2725        ${CC} -c -g conftest.c &&
2726        mv conftest.o conftest.o.g &&
2727        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2728       :
2729     else
2730       BUILD_CONFIG=
2731     fi
2732     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2733     ;;
2734   esac
2735 fi
2736 AC_MSG_RESULT($BUILD_CONFIG)
2737 AC_SUBST(BUILD_CONFIG)
2738
2739 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2740 AC_MSG_CHECKING([for --enable-vtable-verify])
2741 AC_ARG_ENABLE(vtable-verify,
2742 [AS_HELP_STRING([--enable-vtable-verify],
2743                 [Enable vtable verification feature])],
2744 [case "$enableval" in
2745  yes) enable_vtable_verify=yes ;;
2746  no)  enable_vtable_verify=no ;;
2747  *)   enable_vtable_verify=no;;
2748  esac],
2749 [enable_vtable_verify=no])
2750 AC_MSG_RESULT($enable_vtable_verify)
2751
2752 # Record target_configdirs and the configure arguments for target and
2753 # build configuration in Makefile.
2754 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2755 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2756 bootstrap_fixincludes=no
2757
2758 # If we are building libgomp, bootstrap it.
2759 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2760   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2761 fi
2762
2763 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2764 # or bootstrap-ubsan, bootstrap it.
2765 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2766   case "$BUILD_CONFIG" in
2767     *bootstrap-asan* | *bootstrap-ubsan* )
2768       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2769       bootstrap_fixincludes=yes
2770       ;;
2771   esac
2772 fi
2773
2774 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2775 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2776    test "$enable_vtable_verify" != no; then
2777   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2778 fi
2779
2780 # Determine whether gdb needs tk/tcl or not.
2781 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2782 # and in that case we want gdb to be built without tk.  Ugh!
2783 # In fact I believe gdb is the *only* package directly dependent on tk,
2784 # so we should be able to put the 'maybe's in unconditionally and
2785 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2786 # 100% sure that that's safe though.
2787
2788 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2789 case "$enable_gdbtk" in
2790   no)
2791     GDB_TK="" ;;
2792   yes)
2793     GDB_TK="${gdb_tk}" ;;
2794   *)
2795     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2796     # distro.  Eventually someone will fix this and move Insight, nee
2797     # gdbtk to a separate directory.
2798     if test -d ${srcdir}/gdb/gdbtk ; then
2799       GDB_TK="${gdb_tk}"
2800     else
2801       GDB_TK=""
2802     fi
2803     ;;
2804 esac
2805 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2806 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2807
2808 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2809 # else does, only include them if one of these is built.  The Makefile
2810 # provides the ordering, so it's enough here to add to the list.
2811 case " ${configdirs} " in
2812   *\ gdb\ *)
2813     configdirs="${configdirs} gnulib gdbsupport"
2814     ;;
2815   *\ gdbserver\ *)
2816     configdirs="${configdirs} gnulib gdbsupport"
2817     ;;
2818 esac
2819
2820 # Strip out unwanted targets.
2821
2822 # While at that, we remove Makefiles if we were started for recursive
2823 # configuration, so that the top-level Makefile reconfigures them,
2824 # like we used to do when configure itself was recursive.
2825
2826 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2827 # but now we're fixing up the Makefile ourselves with the additional
2828 # commands passed to AC_CONFIG_FILES.  Use separate variables
2829 # extrasub-{build,host,target} not because there is any reason to split
2830 # the substitutions up that way, but only to remain below the limit of
2831 # 99 commands in a script, for HP-UX sed.
2832
2833 # Do not nest @if/@endif or @unless/@endunless pairs, because
2834 # configure will not warn you at all.
2835
2836 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2837   yes:yes:*\ gold\ *:*,c++,*) ;;
2838   yes:yes:*\ gold\ *:*)
2839     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2840     ;;
2841 esac
2842
2843 extrasub_build=
2844 for module in ${build_configdirs} ; do
2845   if test -z "${no_recursion}" \
2846      && test -f ${build_subdir}/${module}/Makefile; then
2847     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2848     rm -f ${build_subdir}/${module}/Makefile
2849   fi
2850   extrasub_build="$extrasub_build
2851 /^@if build-$module\$/d
2852 /^@endif build-$module\$/d
2853 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2854 /^@if build-$module-$bootstrap_suffix\$/d
2855 /^@endif build-$module-$bootstrap_suffix\$/d
2856 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2857 done
2858 extrasub_host=
2859 for module in ${configdirs} ; do
2860   if test -z "${no_recursion}"; then
2861     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2862       if test -f ${file}; then
2863         echo 1>&2 "*** removing ${file} to force reconfigure"
2864         rm -f ${file}
2865       fi
2866     done
2867   fi
2868   case ${module},${bootstrap_fixincludes} in
2869     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2870     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2871   esac
2872   extrasub_host="$extrasub_host
2873 /^@if $module\$/d
2874 /^@endif $module\$/d
2875 /^@unless $module\$/,/^@endunless $module\$/d
2876 /^@if $module-$host_bootstrap_suffix\$/d
2877 /^@endif $module-$host_bootstrap_suffix\$/d
2878 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2879 done
2880 extrasub_target=
2881 for module in ${target_configdirs} ; do
2882   if test -z "${no_recursion}" \
2883      && test -f ${target_subdir}/${module}/Makefile; then
2884     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2885     rm -f ${target_subdir}/${module}/Makefile
2886   fi
2887
2888   # We only bootstrap target libraries listed in bootstrap_target_libs.
2889   case $bootstrap_target_libs in
2890     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2891     *) target_bootstrap_suffix=no-bootstrap ;;
2892   esac
2893
2894   extrasub_target="$extrasub_target
2895 /^@if target-$module\$/d
2896 /^@endif target-$module\$/d
2897 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2898 /^@if target-$module-$target_bootstrap_suffix\$/d
2899 /^@endif target-$module-$target_bootstrap_suffix\$/d
2900 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2901 done
2902
2903 # Do the final fixup along with target modules.
2904 extrasub_target="$extrasub_target
2905 /^@if /,/^@endif /d
2906 /^@unless /d
2907 /^@endunless /d"
2908
2909 if test "$enable_pgo_build" != "no"; then
2910   extrasub_build="$extrasub_build
2911 /^@if pgo-build\$/d
2912 /^@endif pgo-build\$/d"
2913 fi
2914
2915 # Create the serialization dependencies.  This uses a temporary file.
2916
2917 AC_ARG_ENABLE([serial-configure],
2918 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2919                 [force sequential configuration of
2920                  sub-packages for the host, target or build
2921                  machine, or all sub-packages])])
2922
2923 case ${enable_serial_configure} in
2924   yes)
2925     enable_serial_build_configure=yes
2926     enable_serial_host_configure=yes
2927     enable_serial_target_configure=yes
2928     ;;
2929 esac
2930
2931 # These force 'configure's to be done one at a time, to avoid problems
2932 # with contention over a shared config.cache.
2933 rm -f serdep.tmp
2934 echo '# serdep.tmp' > serdep.tmp
2935 olditem=
2936 test "x${enable_serial_build_configure}" = xyes &&
2937 for item in ${build_configdirs} ; do
2938   case ${olditem} in
2939     "") ;;
2940     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2941   esac
2942   olditem=${item}
2943 done
2944 olditem=
2945 test "x${enable_serial_host_configure}" = xyes &&
2946 for item in ${configdirs} ; do
2947   case ${olditem} in
2948     "") ;;
2949     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2950   esac
2951   olditem=${item}
2952 done
2953 olditem=
2954 test "x${enable_serial_target_configure}" = xyes &&
2955 for item in ${target_configdirs} ; do
2956   case ${olditem} in
2957     "") ;;
2958     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2959   esac
2960   olditem=${item}
2961 done
2962 serialization_dependencies=serdep.tmp
2963 AC_SUBST_FILE(serialization_dependencies)
2964
2965 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2966 # target, nonopt, and variable assignments.  These are the ones we
2967 # might not want to pass down to subconfigures.  The exception being
2968 # --cache-file=/dev/null, which is used to turn off the use of cache
2969 # files altogether, and which should be passed on to subconfigures.
2970 # Also strip program-prefix, program-suffix, and program-transform-name,
2971 # so that we can pass down a consistent program-transform-name.
2972 baseargs=
2973 tbaseargs=
2974 keep_next=no
2975 skip_next=no
2976 eval "set -- $ac_configure_args"
2977 for ac_arg
2978 do
2979   if test X"$skip_next" = X"yes"; then
2980     skip_next=no
2981     continue
2982   fi
2983   if test X"$keep_next" = X"yes"; then
2984     case $ac_arg in
2985       *\'*)
2986         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2987     esac
2988     baseargs="$baseargs '$ac_arg'"
2989     tbaseargs="$tbaseargs '$ac_arg'"
2990     keep_next=no
2991     continue
2992   fi
2993
2994   # Handle separated arguments.  Based on the logic generated by
2995   # autoconf 2.59.
2996   case $ac_arg in
2997     *=* | --config-cache | -C | -disable-* | --disable-* \
2998       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2999       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3000       | -with-* | --with-* | -without-* | --without-* | --x)
3001       separate_arg=no
3002       ;;
3003     -*)
3004       separate_arg=yes
3005       ;;
3006     *)
3007       separate_arg=no
3008       ;;
3009   esac
3010
3011   skip_targ=no
3012   case $ac_arg in
3013 changequote(,)
3014   --with-* | --without-*)
3015     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3016
3017     case $libopt in
3018     *[-_]include)
3019       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3020       ;;
3021     *[-_]lib)
3022       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3023       ;;
3024     *)
3025       lib=$libopt
3026       ;;
3027     esac
3028 changequote([,])
3029
3030     case $lib in
3031     mpc | mpfr | gmp | isl)
3032       # If we're processing --with-$lib, --with-$lib-include or
3033       # --with-$lib-lib, for one of the libs above, and target is
3034       # different from host, don't pass the current argument to any
3035       # target library's configure.
3036       if test x$is_cross_compiler = xyes; then
3037         skip_targ=yes
3038       fi
3039       ;;
3040     esac
3041     ;;
3042   esac
3043
3044   case "$ac_arg" in
3045     --cache-file=/dev/null | \
3046     -cache-file=/dev/null )
3047       # Handled here to avoid the test to skip args below.
3048       baseargs="$baseargs '$ac_arg'"
3049       tbaseargs="$tbaseargs '$ac_arg'"
3050       # Assert: $separate_arg should always be no.
3051       keep_next=$separate_arg
3052       ;;
3053     --no*)
3054       continue
3055       ;;
3056     --c* | \
3057     --sr* | \
3058     --ho* | \
3059     --bu* | \
3060     --t* | \
3061     --program-* | \
3062     -cache_file* | \
3063     -srcdir* | \
3064     -host* | \
3065     -build* | \
3066     -target* | \
3067     -program-prefix* | \
3068     -program-suffix* | \
3069     -program-transform-name* )
3070       skip_next=$separate_arg
3071       continue
3072       ;;
3073     -*)
3074       # An option.  Add it.
3075       case $ac_arg in
3076         *\'*)
3077           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3078       esac
3079       baseargs="$baseargs '$ac_arg'"
3080       if test X"$skip_targ" = Xno; then
3081         tbaseargs="$tbaseargs '$ac_arg'"
3082       fi
3083       keep_next=$separate_arg
3084       ;;
3085     *)
3086       # Either a variable assignment, or a nonopt (triplet).  Don't
3087       # pass it down; let the Makefile handle this.
3088       continue
3089       ;;
3090   esac
3091 done
3092 # Remove the initial space we just introduced and, as these will be
3093 # expanded by make, quote '$'.
3094 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3095
3096 # Add in --program-transform-name, after --program-prefix and
3097 # --program-suffix have been applied to it.  Autoconf has already
3098 # doubled dollar signs and backslashes in program_transform_name; we want
3099 # the backslashes un-doubled, and then the entire thing wrapped in single
3100 # quotes, because this will be expanded first by make and then by the shell.
3101 # Also, because we want to override the logic in subdir configure scripts to
3102 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3103 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3104 ${program_transform_name}
3105 EOF_SED
3106 gcc_transform_name=`cat conftestsed.out`
3107 rm -f conftestsed.out
3108 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3109 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3110 if test "$silent" = yes; then
3111   baseargs="$baseargs --silent"
3112   tbaseargs="$tbaseargs --silent"
3113 fi
3114 baseargs="$baseargs --disable-option-checking"
3115 tbaseargs="$tbaseargs --disable-option-checking"
3116
3117 # Record and document user additions to sub configure arguments.
3118 AC_ARG_VAR([build_configargs],
3119            [additional configure arguments for build directories])
3120 AC_ARG_VAR([host_configargs],
3121            [additional configure arguments for host directories])
3122 AC_ARG_VAR([target_configargs],
3123            [additional configure arguments for target directories])
3124
3125 # For the build-side libraries, we just need to pretend we're native,
3126 # and not use the same cache file.  Multilibs are neither needed nor
3127 # desired.  We can't even use the same cache file for all build-side
3128 # libraries, as they're compiled differently; some with C, some with
3129 # C++ or with different feature-enabling options.
3130 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3131
3132 # For host modules, accept cache file option, or specification as blank.
3133 case "${cache_file}" in
3134 "") # empty
3135   cache_file_option="" ;;
3136 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3137   cache_file_option="--cache-file=${cache_file}" ;;
3138 *) # relative path
3139   cache_file_option="--cache-file=../${cache_file}" ;;
3140 esac
3141
3142 # Host dirs don't like to share a cache file either, horribly enough.
3143 # This seems to be due to autoconf 2.5x stupidity.
3144 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3145
3146 target_configargs="$target_configargs ${tbaseargs}"
3147
3148 # Passing a --with-cross-host argument lets the target libraries know
3149 # whether they are being built with a cross-compiler or being built
3150 # native.  However, it would be better to use other mechanisms to make the
3151 # sorts of decisions they want to make on this basis.  Please consider
3152 # this option to be deprecated.  FIXME.
3153 if test x${is_cross_compiler} = xyes ; then
3154   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3155 fi
3156
3157 # Special user-friendly check for native x86_64-linux build, if
3158 # multilib is not explicitly enabled.
3159 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3160   x86_64-*linux*:yes:$build:$build:)
3161     # Make sure we have a development environment that handles 32-bit
3162     dev64=no
3163     echo "int main () { return 0; }" > conftest.c
3164     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3165     if test $? = 0 ; then
3166       if test -s conftest || test -s conftest.exe ; then
3167         dev64=yes
3168       fi
3169     fi
3170     rm -f conftest*
3171     if test x${dev64} != xyes ; then
3172       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3173     fi
3174     ;;
3175 esac
3176
3177 # Default to --enable-multilib.
3178 if test x${enable_multilib} = x ; then
3179   target_configargs="--enable-multilib ${target_configargs}"
3180 fi
3181
3182 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3183 # changed from the earlier setting of with_newlib.
3184 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3185   target_configargs="--with-newlib ${target_configargs}"
3186 fi
3187
3188 # Different target subdirs use different values of certain variables
3189 # (notably CXX).  Worse, multilibs use *lots* of different values.
3190 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3191 # it doesn't automatically accept command-line overrides of them.
3192 # This means it's not safe for target subdirs to share a cache file,
3193 # which is disgusting, but there you have it.  Hopefully this can be
3194 # fixed in future.  It's still worthwhile to use a cache file for each
3195 # directory.  I think.
3196
3197 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3198 # We need to pass --target, as newer autoconf's requires consistency
3199 # for target_alias and gcc doesn't manage it consistently.
3200 target_configargs="--cache-file=./config.cache ${target_configargs}"
3201
3202 FLAGS_FOR_TARGET=
3203 case " $target_configdirs " in
3204  *" newlib "*)
3205   case " $target_configargs " in
3206   *" --with-newlib "*)
3207    case "$target" in
3208     *-cygwin*)
3209       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3210       ;;
3211    esac
3212
3213    # If we're not building GCC, don't discard standard headers.
3214    if test -d ${srcdir}/gcc; then
3215      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3216
3217      if test "${build}" != "${host}"; then
3218        # On Canadian crosses, CC_FOR_TARGET will have already been set
3219        # by `configure', so we won't have an opportunity to add -Bgcc/
3220        # to it.  This is right: we don't want to search that directory
3221        # for binaries, but we want the header files in there, so add
3222        # them explicitly.
3223        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3224
3225        # Someone might think of using the pre-installed headers on
3226        # Canadian crosses, in case the installed compiler is not fully
3227        # compatible with the compiler being built.  In this case, it
3228        # would be better to flag an error than risking having
3229        # incompatible object files being constructed.  We can't
3230        # guarantee that an error will be flagged, but let's hope the
3231        # compiler will do it, when presented with incompatible header
3232        # files.
3233      fi
3234    fi
3235
3236    case "${target}-${is_cross_compiler}" in
3237    i[[3456789]]86-*-linux*-no)
3238       # Here host == target, so we don't need to build gcc,
3239       # so we don't want to discard standard headers.
3240       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3241       ;;
3242    *)
3243       # If we're building newlib, use its generic headers last, but search
3244       # for any libc-related directories first (so make it the last -B
3245       # switch).
3246       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3247
3248       # If we're building libgloss, find the startup file, simulator library
3249       # and linker script.
3250       case " $target_configdirs " in
3251         *" libgloss "*)
3252         # Look for startup file, simulator library and maybe linker script.
3253         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3254         # Look for libnosys.a in case the target needs it.
3255         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3256         # Most targets have the linker script in the source directory.
3257         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3258         ;;
3259       esac
3260       ;;
3261    esac
3262    ;;
3263   esac
3264   ;;
3265 esac
3266
3267 case "$target" in
3268   x86_64-*mingw* | *-w64-mingw*)
3269   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3270   # however, use a symlink named 'mingw' in ${prefix} .
3271     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3272     ;;
3273   *-mingw*)
3274   # MinGW can't be handled as Cygwin above since it does not use newlib.
3275     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3276     ;;
3277 esac
3278
3279 # Allow the user to override the flags for
3280 # our build compiler if desired.
3281 if test x"${build}" = x"${host}" ; then
3282   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3283   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3284   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3285 fi
3286
3287 # On Canadian crosses, we'll be searching the right directories for
3288 # the previously-installed cross compiler, so don't bother to add
3289 # flags for directories within the install tree of the compiler
3290 # being built; programs in there won't even run.
3291 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3292   # Search for pre-installed headers if nothing else fits.
3293   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3294 fi
3295
3296 if test "x${use_gnu_ld}" = x &&
3297    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3298   # Arrange for us to find uninstalled linker scripts.
3299   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3300 fi
3301
3302 # Search for other target-specific linker scripts and such.
3303 case "${target}" in
3304   mep*)
3305     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3306     ;;
3307 esac
3308
3309 # Makefile fragments.
3310 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3311 do
3312   eval fragval=\$$frag
3313   if test $fragval != /dev/null; then
3314     eval $frag=${srcdir}/$fragval
3315   fi
3316 done
3317 AC_SUBST_FILE(host_makefile_frag)
3318 AC_SUBST_FILE(target_makefile_frag)
3319 AC_SUBST_FILE(alphaieee_frag)
3320 AC_SUBST_FILE(ospace_frag)
3321
3322 # Miscellanea: directories, flags, etc.
3323 AC_SUBST(RPATH_ENVVAR)
3324 AC_SUBST(GCC_SHLIB_SUBDIR)
3325 AC_SUBST(tooldir)
3326 AC_SUBST(build_tooldir)
3327 AC_SUBST(CONFIGURE_GDB_TK)
3328 AC_SUBST(GDB_TK)
3329 AC_SUBST(INSTALL_GDB_TK)
3330
3331 # Build module lists & subconfigure args.
3332 AC_SUBST(build_configargs)
3333 AC_SUBST(build_configdirs)
3334
3335 # Host module lists & subconfigure args.
3336 AC_SUBST(host_configargs)
3337 AC_SUBST(configdirs)
3338 AC_SUBST(target_configdirs)
3339
3340 # Target module lists & subconfigure args.
3341 AC_SUBST(target_configargs)
3342
3343
3344 # Build tools.
3345 AC_SUBST(AR_FOR_BUILD)
3346 AC_SUBST(AS_FOR_BUILD)
3347 AC_SUBST(CC_FOR_BUILD)
3348 AC_SUBST(CFLAGS_FOR_BUILD)
3349 AC_SUBST(CXXFLAGS_FOR_BUILD)
3350 AC_SUBST(CXX_FOR_BUILD)
3351 AC_SUBST(DLLTOOL_FOR_BUILD)
3352 AC_SUBST(GFORTRAN_FOR_BUILD)
3353 AC_SUBST(GOC_FOR_BUILD)
3354 AC_SUBST(LDFLAGS_FOR_BUILD)
3355 AC_SUBST(LD_FOR_BUILD)
3356 AC_SUBST(NM_FOR_BUILD)
3357 AC_SUBST(RANLIB_FOR_BUILD)
3358 AC_SUBST(WINDMC_FOR_BUILD)
3359 AC_SUBST(WINDRES_FOR_BUILD)
3360
3361 # Generate default definitions for YACC, M4, LEX and other programs that run
3362 # on the build machine.  These are used if the Makefile can't locate these
3363 # programs in objdir.
3364 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3365
3366 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3367 case " $build_configdirs " in
3368   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3369 esac
3370
3371 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3372 case " $build_configdirs " in
3373   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3374 esac
3375
3376 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3377 case " $build_configdirs " in
3378   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3379 esac
3380
3381 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3382 case " $build_configdirs " in
3383   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3384   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3385 esac
3386
3387 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3388 case " $build_configdirs " in
3389   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3390 esac
3391
3392 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3393 case " $build_configdirs " in
3394   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3395   *)
3396 changequote(,)
3397     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3398     # higher, else we use the "missing" dummy.
3399     if ${MAKEINFO} --version \
3400        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3401       :
3402     else
3403       MAKEINFO="$MISSING makeinfo"
3404     fi
3405     ;;
3406 changequote([,])
3407 esac
3408
3409 # FIXME: expect and dejagnu may become build tools?
3410
3411 AC_CHECK_PROGS(EXPECT, expect, expect)
3412 case " $configdirs " in
3413   *" expect "*)
3414     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3415     ;;
3416 esac
3417
3418 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3419 case " $configdirs " in
3420   *" dejagnu "*)
3421     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3422     ;;
3423 esac
3424
3425
3426 # Host tools.
3427 NCN_STRICT_CHECK_TOOLS(AR, ar)
3428 NCN_STRICT_CHECK_TOOLS(AS, as)
3429 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3430 NCN_STRICT_CHECK_TOOLS(LD, ld)
3431 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3432 NCN_STRICT_CHECK_TOOLS(NM, nm)
3433 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3434 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3435 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3436 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3437 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3438 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3439 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3440 AC_SUBST(CC)
3441 AC_SUBST(CXX)
3442 AC_SUBST(CFLAGS)
3443 AC_SUBST(CXXFLAGS)
3444
3445 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3446 AR_PLUGIN_OPTION=
3447 RANLIB_PLUGIN_OPTION=
3448 if test -n "$PLUGIN_OPTION"; then
3449   if $AR --help 2>&1 | grep -q "\--plugin"; then
3450     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3451   fi
3452   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3453     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3454   fi
3455 else
3456   if test "$enable_pgo_build" != "no"; then
3457     AC_MSG_ERROR([AR with --plugin and rc is required for LTO build])
3458   fi
3459 fi
3460 AC_SUBST(AR_PLUGIN_OPTION)
3461 AC_SUBST(RANLIB_PLUGIN_OPTION)
3462
3463 # Target tools.
3464 AC_ARG_WITH([build-time-tools],
3465   [AS_HELP_STRING([--with-build-time-tools=PATH],
3466                   [use given path to find target tools during the build])],
3467   [case x"$withval" in
3468      x/*) ;;
3469      *)
3470        with_build_time_tools=
3471        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3472        ;;
3473    esac],
3474   [with_build_time_tools=])
3475
3476 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3477 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3478 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3479 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3480 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3481
3482 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3483 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3484 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3485 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3486 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3487 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3488 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3489 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3490 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3491 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3492 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3493 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3494 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3495
3496 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3497
3498 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3499 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3500 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3501 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3502 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3503                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3504                 c++)
3505 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3506                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3507                 c++)
3508 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3509 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3510 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3511                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3512 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3513                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3514 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3515 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3516 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3517 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3518 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3519 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3520 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3521 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3522 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3523 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3524
3525 AC_SUBST(FLAGS_FOR_TARGET)
3526 AC_SUBST(RAW_CXX_FOR_TARGET)
3527
3528 # Certain tools may need extra flags.
3529 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3530 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3531 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3532
3533 # When building target libraries, except in a Canadian cross, we use
3534 # the same toolchain as the compiler we just built.
3535 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3536 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3537 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3538 if test $host = $build; then
3539   case " $configdirs " in
3540     *" gcc "*)
3541       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3542       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3543       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3544       ;;
3545   esac
3546 fi
3547
3548 AC_SUBST(COMPILER_AS_FOR_TARGET)
3549 AC_SUBST(COMPILER_LD_FOR_TARGET)
3550 AC_SUBST(COMPILER_NM_FOR_TARGET)
3551
3552 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3553 AC_ARG_ENABLE(maintainer-mode,
3554 [AS_HELP_STRING([--enable-maintainer-mode],
3555                 [enable make rules and dependencies not useful
3556                  (and sometimes confusing) to the casual installer])],
3557       USE_MAINTAINER_MODE=$enableval,
3558       USE_MAINTAINER_MODE=no)
3559 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3560 AC_SUBST(MAINTAINER_MODE_TRUE)
3561 AC_SUBST(MAINTAINER_MODE_FALSE)
3562 if test "$USE_MAINTAINER_MODE" = yes; then
3563   MAINTAINER_MODE_TRUE=
3564   MAINTAINER_MODE_FALSE='#'
3565 else
3566   MAINTAINER_MODE_TRUE='#'
3567   MAINTAINER_MODE_FALSE=
3568 fi
3569 MAINT=$MAINTAINER_MODE_TRUE
3570 AC_SUBST(MAINT)dnl
3571
3572 # ---------------------
3573 # GCC bootstrap support
3574 # ---------------------
3575
3576 # Stage specific cflags for build.
3577 stage1_cflags="-g"
3578 case $build in
3579   vax-*-*)
3580     case ${GCC} in
3581       yes) stage1_cflags="-g -Wa,-J" ;;
3582       *) stage1_cflags="-g -J" ;;
3583     esac ;;
3584 esac
3585
3586 AC_SUBST(stage1_cflags)
3587
3588 # Enable --enable-checking in stage1 of the compiler.
3589 AC_ARG_ENABLE(stage1-checking,
3590 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3591                 [choose additional checking for stage1 of the compiler])],
3592 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3593 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3594   # For --disable-checking or implicit --enable-checking=release, avoid
3595   # setting --enable-checking=gc in the default stage1 checking for LTO
3596   # bootstraps.  See PR62077.
3597   case $BUILD_CONFIG in
3598     *lto*)
3599       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3600     *)
3601       stage1_checking=--enable-checking=yes,types;;
3602   esac
3603   if test "x$enable_checking" = x && \
3604      test -d ${srcdir}/gcc && \
3605      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3606     stage1_checking=--enable-checking=yes,types,extra
3607   fi
3608 else
3609   stage1_checking=--enable-checking=$enable_checking,types
3610 fi])
3611 AC_SUBST(stage1_checking)
3612
3613 # Enable -Werror in bootstrap stage2 and later.
3614 AC_ARG_ENABLE(werror,
3615 [AS_HELP_STRING([--enable-werror],
3616                 [enable -Werror in bootstrap stage2 and later])],
3617 [
3618 case ${enable_werror} in
3619   yes) stage2_werror_flag="--enable-werror-always" ;;
3620   *) stage2_werror_flag="" ;;
3621 esac
3622 ],
3623 [
3624 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3625   case $BUILD_CONFIG in
3626   bootstrap-debug)
3627       stage2_werror_flag="--enable-werror-always" ;;
3628   "")
3629       stage2_werror_flag="--enable-werror-always" ;;
3630   esac
3631 fi
3632 ])
3633
3634 AC_SUBST(stage2_werror_flag)
3635
3636 # Specify what files to not compare during bootstrap.
3637
3638 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3639 case "$target" in
3640   hppa*64*-*-hpux*) ;;
3641   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3642   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3643 esac
3644 AC_SUBST(compare_exclusions)
3645
3646 AC_CONFIG_FILES([Makefile],
3647   [sed "$extrasub_build" Makefile |
3648    sed "$extrasub_host" |
3649    sed "$extrasub_target" > mf$$
3650    mv -f mf$$ Makefile],
3651   [extrasub_build="$extrasub_build"
3652    extrasub_host="$extrasub_host"
3653    extrasub_target="$extrasub_target"])
3654 AC_OUTPUT