configure.ac

   1 ## Copyright (C) 1996-2020 The Squid Software Foundation and contributors
   2 ##
   3 ## Squid software is distributed under GPLv2+ license and includes
   4 ## contributions from numerous individuals and organizations.
   5 ## Please see the COPYING and CONTRIBUTORS files for details.
   6 ##
   7
   8 AC_INIT([Squid Web Proxy],[6.0.0-VCS],[http://bugs.squid-cache.org/],[squid])
   9 AC_PREREQ(2.61)
  10 AC_CONFIG_HEADERS([include/autoconf.h])
  11 AC_CONFIG_AUX_DIR(cfgaux)
  12 AC_CONFIG_SRCDIR([src/main.cc])
  13 AM_INIT_AUTOMAKE([tar-ustar nostdinc subdir-objects dist-xz])
  14 AC_REVISION($Revision$)dnl
  15 AC_PREFIX_DEFAULT(/usr/local/squid)
  16 AM_MAINTAINER_MODE
  17
  18 m4_include([acinclude/ax_with_prog.m4])
  19 m4_include([acinclude/init.m4])
  20 m4_include([acinclude/squid-util.m4])
  21 m4_include([acinclude/compiler-flags.m4])
  22 m4_include([acinclude/os-deps.m4])
  23 m4_include([acinclude/krb5.m4])
  24 m4_include([acinclude/pam.m4])
  25 m4_include([acinclude/pkg.m4])
  26 m4_include([acinclude/tdb.m4])
  27 m4_include([acinclude/lib-checks.m4])
  28 m4_include([acinclude/ax_cxx_compile_stdcxx_11.m4])
  29 m4_include([acinclude/ax_cxx_0x_types.m4])
  30
  31 PRESET_CFLAGS="$CFLAGS"
  32 PRESET_CXXFLAGS="$CXXFLAGS"
  33 PRESET_LDFLAGS="$LDFLAGS"
  34
  35 dnl Set default LDFLAGS
  36 if test "x$LDFLAGS" = "x" ; then
  37   LDFLAGS="-g"
  38 fi
  39
  40 # Check for GNU cc
  41 AC_PROG_CC
  42 AM_PROG_CC_C_O
  43 AC_PROG_CXX
  44 AC_LANG([C++])
  45 AC_CANONICAL_HOST
  46
  47 # Clang 3.2 on some CPUs requires -march-native to detect correctly.
  48 # GCC 4.3+ can also produce faster executables when its used.
  49 # But building inside a virtual machine environment has been found to
  50 # cause random Illegal Instruction errors due to mis-detection of CPU.
  51 AC_ARG_ENABLE(arch-native,
  52   AS_HELP_STRING([--disable-arch-native],[Some compilers offer CPU-specific
  53                  optimizations with the -march=native parameter.
  54                  This flag disables the optimization. The default is to
  55                  auto-detect compiler support and use where available.]), [
  56   SQUID_YESNO([$enableval],
  57     [Unrecognized argument to --disable-arch-native: $enableval])
  58 ])
  59 AC_MSG_NOTICE([CPU arch native optimization enabled: ${enable_arch_native:=auto}])
  60 if test "x${enable_arch_native}" != "xno"; then
  61   SQUID_CC_CHECK_ARGUMENT([squid_cv_check_marchnative],[-march=native])
  62 fi
  63
  64 # might be cross-compiling.
  65 # NP: BUILDCXXFLAGS defined at the end of configure after CXXFLAGS fully known.
  66 AC_ARG_VAR([BUILDCXX],[path to compiler for building compile-time tools. e.g. cf_gen])
  67 if test "x$HOSTCXX" != "x" -a "x$BUILDCXX" = "x"; then
  68   AC_MSG_WARN([Cross-compiling with HOSTCXX is deprecated. Uses BUILDCXX instead.])
  69   BUILDCXX="$HOSTCXX"
  70 fi
  71 if test "x$BUILDCXX" = "x"; then
  72   BUILDCXX="$CXX"
  73   if test "x$squid_cv_check_marchnative" = "xyes"; then
  74     CXXFLAGS="$CXXFLAGS -march=native"
  75   fi
  76 fi
  77 AC_SUBST(BUILDCXX)
  78
  79 AC_MSG_CHECKING([simplified host os])
  80 simple_host_os=`echo $host_os|sed 's/[0-9].*//g;s/-.*//g'`
  81 squid_host_os_version=`echo $host_os|tr -d "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ-"`
  82 if test -n "$squid_host_os_version"; then
  83         squid_host_os="`echo $simple_host_os| sed s/$squid_host_os_version//g`"
  84 else
  85         squid_host_os="$simple_host_os"
  86 fi
  87 AC_MSG_RESULT($squid_host_os (version $squid_host_os_version))
  88 # on windows squid_host_os is either mingw or cygwin, version is 32
  89
  90 # this needs to be before any test is run, to have more standard
  91 # functions available on some Unix sysems (e.g. Solaris)
  92 if test "x$squid_host_os" = "solaris" -a "x$GCC" != "x" ; then
  93         AC_USE_SYSTEM_EXTENSIONS
  94 fi
  95
  96 # If the user did not specify a C++ version.
  97 user_cxx=`echo "$PRESET_CXXFLAGS" | grep -o -E "\-std="`
  98 if test "x$user_cxx" = "x"; then
  99   # Check for C++11 compiler support
 100   AX_CXX_COMPILE_STDCXX_11([noext],[mandatory])
 101 fi
 102
 103 # test for programs
 104 AC_PROG_RANLIB
 105 AC_PROG_CPP
 106 AC_PROG_INSTALL
 107 AC_PROG_LN_S
 108 AC_PROG_EGREP
 109
 110 AC_PATH_PROG(SH, sh, /bin/sh)
 111 AC_PATH_PROG(FALSE, false, /usr/bin/false)
 112 AC_PATH_PROG(TRUE, true, /usr/bin/true)
 113 AC_PATH_PROG(MV, mv, $FALSE)
 114 AC_PATH_PROG(MKDIR, mkdir, $FALSE)
 115 AC_PATH_PROG(LN, ln, cp)
 116 AC_PATH_PROG(CHMOD, chmod, $FALSE)
 117 AC_PATH_PROG(TR, tr, $FALSE)
 118 AC_PATH_PROG(RM, rm, $FALSE)
 119 dnl Libtool 2.2.6 requires: rm -f
 120 RM="$RM -f"
 121
 122 PKG_PROG_PKG_CONFIG
 123
 124 AC_PATH_PROG(PERL, perl, none)
 125 if test "x$ac_cv_path_PERL" = "xnone"; then
 126   AC_MSG_FAILURE([Perl is required to compile Squid. Please install Perl and then re-run configure ])
 127 fi
 128 AC_PATH_PROG(POD2MAN, pod2man, $FALSE)
 129 AM_CONDITIONAL(ENABLE_POD2MAN_DOC, test "x${ac_cv_path_POD2MAN}" != "x$FALSE")
 130
 131 dnl set $(AR) if not provided by the build environment
 132 if test "x$AR" = "x"; then
 133   AC_PATH_PROG(AR, ar, $FALSE)
 134 fi
 135 AR_R="$AR r"
 136 AC_SUBST(AR_R)
 137
 138 AC_PATH_PROG(LINUXDOC, linuxdoc, $FALSE)
 139 AM_CONDITIONAL(ENABLE_RELEASE_DOCS, test "x${ac_cv_path_LINUXDOC}" != "x$FALSE")
 140
 141 # pre-define DEFAULT_PREFIX, some modules need it.
 142 if test "${prefix}" = "NONE" ; then
 143   squid_prefix=$ac_default_prefix
 144 else
 145   squid_prefix=$prefix
 146 fi
 147 AC_DEFINE_UNQUOTED(DEFAULT_PREFIX,[$squid_prefix],[The install prefix])
 148
 149 AC_ARG_ENABLE(strict-error-checking,
 150   AS_HELP_STRING([--disable-strict-error-checking],[By default squid is compiled
 151                  with all possible static compiler error-checks enabled.
 152                  This flag disables the behavior]), [
 153   SQUID_YESNO([$enableval],
 154     [Unrecognized argument to --disable-strict-error-checking: $enableval])
 155 ])
 156 AC_MSG_NOTICE([strict error checking enabled: ${enable_strict_error_checking:=yes}])
 157
 158 AC_MSG_CHECKING(whether to use loadable modules)
 159 AC_ARG_ENABLE(loadable-modules,
 160   AS_HELP_STRING([--disable-loadable-modules],[do not support loadable modules]) , [
 161   SQUID_YESNO([$enableval],
 162     [Unrecognized argument to --disable-loadable-modules: $enableval])
 163 ])
 164 AM_CONDITIONAL(ENABLE_LOADABLE_MODULES, test "x${enable_loadable_modules:=yes}" = "xyes")
 165 AC_MSG_RESULT([$enable_loadable_modules])
 166
 167 if test "x$enable_loadable_modules" = "xyes";
 168 then
 169   AC_DEFINE(USE_LOADABLE_MODULES, 1, [Support Loadable Modules])
 170   AC_ENABLE_SHARED
 171 else
 172   AC_DISABLE_SHARED
 173 fi
 174
 175 # LT_INIT requires libtool v2, might as well state it loud
 176 LT_PREREQ([2.2])
 177 LT_INIT([dlopen],[disable-shared])
 178 if ! test "${ac_top_build_prefix}" = "";
 179 then
 180         # LTDL v3-v7 macros assume the autoconf 2.62 variable top_build_prefix is defined
 181         # But from autoconf 2.64 its called ac_top_build_prefix and not automatically added to the Makefile
 182         # This fixes Linux LTDLv3-v7, and BSD LTDL v2.2
 183         top_build_prefix=${ac_top_build_prefix}
 184         AC_SUBST(top_build_prefix)
 185 fi
 186 LTDL_INIT
 187
 188 dnl LibTool environment is now prepared for setup. Check that it is usable and initialize.
 189 LT_LIB_DLLOAD
 190
 191 # Do we need these unconditionally for "make distcheck" to work?
 192 AC_SUBST(INCLTDL)
 193 AC_SUBST(LIBLTDL)
 194
 195 if test "x$enable_loadable_modules" = "xyes";
 196 then
 197   # Why is this needed? Should not LT_INIT (or LT_LIB_DLLOAD) from libtool do that?
 198   LIBADD_DL=${lt_cv_dlopen_libs}
 199   AC_SUBST([LIBADD_DL])
 200 fi
 201
 202 SQUID_CC_GUESS_VARIANT
 203 SQUID_CC_GUESS_OPTIONS
 204
 205 dnl find out the exe extension for this platform.
 206 dnl If it is not empty, use it for CGI as well.
 207 AC_EXEEXT
 208 AC_OBJEXT
 209
 210 if test "x$EXEEXT" = "x" ; then
 211   CGIEXT=".cgi"
 212 else
 213   # automake automatically adds .exe when installing binaries
 214   CGIEXT=""
 215 fi
 216 AC_SUBST(CGIEXT)
 217
 218 AM_CONDITIONAL(ENABLE_WIN32SPECIFIC,[test "x$squid_host_os" = "xmingw"])
 219 AM_CONDITIONAL(ENABLE_WIN32_IPC,[test "x$squid_host_os" = "xmingw"])
 220
 221 case "$squid_host_os" in
 222 mingw)
 223   AC_PATH_PROG(WIN32_PSAPI, psapi.dll, none)
 224   CFLAGS="$CFLAGS -mthreads"
 225   CXXFLAGS="$CXXFLAGS -mthreads -static-libgcc -static-libstdc++"
 226   if test "x$ac_cv_path_WIN32_PSAPI" = "xnone"; then
 227     AC_MSG_NOTICE([PSAPI.DLL is recommended to run Squid on Windows NT Platform])
 228     AC_MSG_NOTICE([Please see PSAPI.DLL section on doc/win32-relnotes.html.])
 229   else
 230     AC_DEFINE(HAVE_WIN32_PSAPI,1,[Define if you have PSAPI.DLL on Windows systems])
 231     LIBS="$LIBS -lpsapi"
 232   fi
 233   MINGW_LIBS="-lmingwex"
 234   AC_SUBST(MINGW_LIBS)
 235   ;;
 236 freebsd)
 237     # FreeBSD places local libraries and packages in /usr/local
 238     CFLAGS="$CFLAGS -I/usr/local/include"
 239     CXXFLAGS="$CXXFLAGS -I/usr/local/include"
 240     LDFLAGS="$LDFLAGS -L/usr/local/lib -Wl,-R/usr/local/lib"
 241     ;;
 242 *)
 243     ;;
 244 esac
 245
 246 dnl Substitutions
 247 AC_DEFINE_UNQUOTED(CONFIG_HOST_TYPE, "$host",[Host type from configure])
 248
 249 AC_DEFINE_UNQUOTED(SQUID_CONFIGURE_OPTIONS, "$ac_configure_args",
 250                        [configure command line used to configure Squid])
 251
 252 CACHE_EFFECTIVE_USER="nobody"
 253 AC_ARG_WITH(default-user,
 254   AS_HELP_STRING([--with-default-user=USER],[System user account for squid permissions. Default: nobody]),
 255  [ CACHE_EFFECTIVE_USER="$withval" ]
 256 )
 257 AC_SUBST(CACHE_EFFECTIVE_USER)
 258
 259 DEFAULT_LOG_DIR="$localstatedir/logs"
 260 AC_ARG_WITH(logdir,
 261   AS_HELP_STRING([--with-logdir=PATH],
 262     [Default location for squid logs. default: PREFIX/var/logs]), [
 263 case $withval in
 264   yes|no)
 265     AC_MSG_ERROR( --with-logdir requires a directory PATH. --with-logdir=PATH )
 266     ;;
 267   *)
 268     DEFAULT_LOG_DIR="$withval"
 269     ;;
 270 esac
 271  ]
 272 )
 273 AC_SUBST(DEFAULT_LOG_DIR)
 274
 275 DEFAULT_PID_FILE="$localstatedir/run/@SERVICE_NAME@.pid"
 276 AC_ARG_WITH(pidfile,
 277   AS_HELP_STRING([--with-pidfile=PATH],
 278     [Default location for squid pid file. Default: PREFIX/var/run/squid.pid]), [
 279 case $withval in
 280  yes|no)
 281    AC_MSG_ERROR( --with-pidfile requires a file PATH. --with-pidfile=PATH )
 282    ;;
 283  *)
 284    DEFAULT_PID_FILE="$withval"
 285    ;;
 286  esac
 287 ])
 288 AC_SUBST(DEFAULT_PID_FILE)
 289
 290 DEFAULT_SWAP_DIR="$localstatedir/cache/squid"
 291 AC_ARG_WITH(swapdir,
 292   AS_HELP_STRING([--with-swapdir=PATH],
 293     [Default location for squid cache directories. Default: PREFIX/var/cache/squid]), [
 294 case $withval in
 295  yes|no)
 296    AC_MSG_ERROR( --with-swapdir requires a directory PATH. --with-swapdir=PATH )
 297    ;;
 298  *)
 299    DEFAULT_SWAP_DIR="$withval"
 300    ;;
 301  esac
 302 ])
 303 AC_SUBST(DEFAULT_SWAP_DIR)
 304
 305 dnl Set Default CFLAGS
 306 if test "x$PRESET_CFLAGS" = "x"; then
 307   if test "$squid_cv_compiler" = "gcc"; then
 308     case "$host" in
 309       *-sun-sunos*)
 310         # sunos has too many warnings for this to be useful
 311         # motorola too
 312         ;;
 313       *m88k*)
 314         # Motorola cc/ld does not like -02 but is ok on -O
 315         CFLAGS=`echo $CFLAGS | sed -e 's/-O[0-9]/-O/'`
 316         ;;
 317       *)
 318         CFLAGS="$squid_cv_cc_option_wall $CFLAGS"
 319         ;;
 320     esac
 321   else
 322     case "$host" in
 323       *mips-sgi-irix6.*)
 324         # suggested by Rafael Seidl <rafaels@cthulhu.engr.sgi.com>
 325         CFLAGS="$squid_cv_cc_option_optimize -OPT:Olimit=0:space=OFF \
 326                 -woff 1009,1014,1110,1116,1183,1185,1188,1204,1230,1233,1355 \
 327                 -Wl,-woff,85,-woff,84,-woff,134 \
 328                 -nostdinc -I/usr/include -D_BSD_SIGNALS $CFLAGS"
 329         CXXFLAGS="$squid_cv_cc_option_optimize -OPT:Olimit=0:space=OFF \
 330                   -woff 1009,1014,1110,1116,1183,1185,1188,1204,1230,1233,1355 \
 331                   -Wl,-woff,85,-woff,84,-woff,134 \
 332                   -nostdinc -I/usr/include -D_BSD_SIGNALS $CXXFLAGS"
 333           ;;
 334         *)
 335           ;;
 336     esac
 337   fi
 338 fi
 339
 340 dnl set squid required flags
 341 if test "$squid_cv_compiler" = "gcc"; then
 342   case "$squid_host_os" in
 343   mingw)
 344 dnl Guido Serassio (serassio@squid-cache.org) 20070811
 345 dnl Using the latest MinGW (gcc 3.4.5 + mingw-runtime 3.13) cannot build with
 346 dnl -Werror -Wmissing-prototypes -Wmissing-declarations
 347 dnl TODO: check if the problem will be present in any other newer MinGW release.
 348     SQUID_CFLAGS="$squid_cv_cc_option_wall -Wpointer-arith -Wwrite-strings -Wcomments -Wshadow"
 349     ;;
 350   *)
 351     SQUID_CFLAGS="$squid_cv_cc_option_wall -Wpointer-arith -Wwrite-strings -Wmissing-prototypes -Wmissing-declarations -Wcomments -Wshadow"
 352     ;;
 353   esac
 354   SQUID_CXXFLAGS="$squid_cv_cc_option_wall -Wpointer-arith -Wwrite-strings -Wcomments -Wshadow -Woverloaded-virtual"
 355 else
 356   SQUID_CFLAGS=
 357   SQUID_CXXFLAGS=
 358 fi
 359
 360 dnl CentOS (and RHEL) still define ntohs() using deprecated C++ features
 361 SQUID_CC_REQUIRE_ARGUMENT([ac_cv_require_wno_deprecated_register],[-Werror -Wno-deprecated-register],[[#include <arpa/inet.h>]],[[int fox=ntohs(1);]])
 362
 363 if test "x$enable_strict_error_checking" != "xno"; then
 364   SQUID_CFLAGS="$SQUID_CFLAGS $squid_cv_cc_option_werror"
 365   SQUID_CXXFLAGS="$SQUID_CXXFLAGS $squid_cv_cxx_option_werror"
 366 fi
 367
 368 if test "x$ac_cv_require_wno_deprecated_register" = "xyes"; then
 369   SQUID_CXXFLAGS="$SQUID_CXXFLAGS -Wno-deprecated-register"
 370 fi
 371
 372 # squid_cv_cc_arg_pipe is set by SQUID_CC_GUESS_OPTIONS
 373 SQUID_CXXFLAGS="$SQUID_CXXFLAGS $squid_cv_cc_arg_pipe"
 374 SQUID_CFLAGS="$SQUID_CFLAGS $squid_cv_cc_arg_pipe"
 375
 376 # possibly include some build info tag into squid -v
 377 SQUID_EMBED_BUILD_INFO
 378
 379 AC_ARG_ENABLE(optimizations,
 380   AS_HELP_STRING([--disable-optimizations],
 381                  [Do not compile Squid with compiler optimizations enabled.
 382                   Optimization is good for production builds, but not
 383                   good for debugging. During development, use
 384                   --disable-optimizations to reduce compilation times
 385                   and allow easier debugging.]), [
 386 if test "x$enableval" = "xno" ; then
 387   AC_MSG_NOTICE([Disabling compiler optimizations (-O flag)])
 388   CFLAGS="`echo $CFLAGS | sed -e 's/-O[[0-9g]]*//'`"
 389   CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-O[[0-9g]]*//'`"
 390 fi
 391 ])
 392
 393 AC_ARG_ENABLE(debug-cbdata,
 394   AS_HELP_STRING([--enable-debug-cbdata],
 395       [Provide some debug information in cbdata]), [
 396 SQUID_YESNO([$enableval],
 397     [unrecognized argument to --enable-debug-cbdata: $enableval])
 398 ])
 399 SQUID_DEFINE_BOOL(USE_CBDATA_DEBUG,${enable_debug_cbdata:=no},
 400     [Enable support for cbdata debug information])
 401 AC_MSG_NOTICE([cbdata debugging enabled: $enable_debug_cbdata])
 402
 403
 404 dnl Nasty hack to get autoconf 2.64 on Linux to run.
 405 dnl all other uses of RUN_IFELSE are wrapped inside CACHE_CHECK which breaks on 2.64
 406 AC_RUN_IFELSE([AC_LANG_SOURCE([[ int main(int argc, char **argv) { return 0; } ]])],[],[],[:])
 407
 408 AH_TEMPLATE(XMALLOC_STATISTICS,[Define to have malloc statistics])
 409 AC_ARG_ENABLE(xmalloc-statistics,
 410   AS_HELP_STRING([--enable-xmalloc-statistics],
 411                  [Show malloc statistics in status page]), [
 412 SQUID_YESNO([$enableval],
 413     [unrecognized argument to --enable-xmalloc-statistics: $enableval])
 414 ])
 415 SQUID_DEFINE_BOOL(XMALLOC_STATISTICS,${enable_xmalloc_statistics:=no},
 416     [Show malloc statistics in status page])
 417 AC_MSG_NOTICE([xmalloc stats display: $enable_xmalloc_statistics])
 418
 419 squid_opt_aufs_threads=""
 420 AC_ARG_WITH(aufs-threads,
 421   AS_HELP_STRING([--with-aufs-threads=N_THREADS],
 422    [Tune the number of worker threads for the aufs object store.]), [
 423 case $withval in
 424   [[0-9]]*)
 425     squid_opt_aufs_threads=$withval
 426     ;;
 427   *)
 428     AC_MSG_ERROR(--with-aufs-threads expects a numeric argument)
 429     ;;
 430   esac
 431 ])
 432 if test "x$squid_opt_aufs_threads" != "x"; then
 433     AC_MSG_NOTICE([With $squid_opt_aufs_threads aufs threads])
 434     AC_DEFINE_UNQUOTED(AUFS_IO_THREADS,$squid_opt_aufs_threads,
 435                  [Defines how many threads aufs uses for I/O])
 436 fi
 437
 438 ## TODO check if this is necessary, LT_INIT does these checks
 439 SQUID_AUTO_LIB(dl,[dynamic linking],[LIBDL])
 440 if test "x$with_dl" != "xno"; then
 441   CXXFLAGS="$LIBDL_CFLAGS $CXXFLAGS"
 442   LDFLAGS="$LIBDL_PATH $LDFLAGS"
 443   AC_CHECK_LIB(dl, dlopen)
 444 fi
 445
 446 ## check for atomics library before anything that might need it
 447 # AC_SEARCH_LIBS pollutes LIBS
 448 SQUID_STATE_SAVE(LIBATOMIC)
 449 AC_SEARCH_LIBS([__atomic_load_8],[atomic],[
 450   test "$ac_res" = "none required" || ATOMICLIB=$ac_res],[])
 451 SQUID_STATE_ROLLBACK(LIBATOMIC)
 452 AC_SUBST(ATOMICLIB)
 453
 454 AC_SEARCH_LIBS([shm_open], [rt])
 455 if test "x$ac_cv_search_shm_open" != "xno" ; then
 456   AC_DEFINE(HAVE_SHM,1,[Support shared memory features])
 457 fi
 458
 459 AC_MSG_CHECKING([for DiskIO modules to be enabled])
 460 squid_disk_module_candidates=""
 461 squid_opt_enable_diskio="auto"  #values: no, yes, "auto"(=yes+detect modules)
 462 AC_ARG_ENABLE(disk-io,
 463   AS_HELP_STRING([--enable-disk-io="list of modules"],
 464     [Build support for the list of disk I/O modules.
 465      Set without a value or omitted, all available modules will be built.
 466      See src/DiskIO for a list of available modules, or
 467      Programmers Guide section on DiskIO
 468      for details on how to build your custom disk module]), [
 469 case $enableval in
 470   yes)
 471     ${TRUE}
 472     #do nothing, "auto" is ok
 473     ;;
 474   no)
 475     squid_opt_enable_diskio="no"
 476     ;;
 477   *)
 478     squid_opt_enable_diskio="yes"
 479     squid_disk_module_candidates=" `echo $enableval| sed -e 's/,/ /g;s/  */ /g'` "
 480     SQUID_CLEANUP_MODULES_LIST([squid_disk_module_candidates])
 481     ;;
 482   esac
 483 ])
 484
 485 # if requested to autodetect, find out what we have
 486 if test "x$squid_opt_enable_diskio" = "xauto"; then
 487     squid_opt_enable_diskio="yes"
 488     SQUID_LOOK_FOR_MODULES([$srcdir/src/DiskIO],[squid_disk_module_candidates])
 489     if test "x$ac_cv_search_shm_open" = "xno" ; then
 490         # disable IpcIo
 491         squid_disk_module_candidates=`echo $squid_disk_module_candidates|sed 's/IpcIo//'`
 492     fi
 493 fi
 494
 495 AC_MSG_RESULT([${squid_disk_module_candidates:-none}])
 496 SQUID_CHECK_EXISTING_MODULES([$srcdir/src/DiskIO],[squid_disk_module_candidates])
 497 SQUID_DEFINE_BOOL(USE_DISKIO,$squid_opt_enable_diskio,
 498     [DiskIO modules are expected to be available.])
 499
 500
 501
 502 dnl Some autoconf.h defines we might enable later...
 503 AC_ARG_WITH(pthreads,AS_HELP_STRING([--without-pthreads],[Disable POSIX Threads]))
 504 AC_ARG_WITH(aio, AS_HELP_STRING([--without-aio],[Do not use POSIX AIO. Default: auto-detect]))
 505 ENABLE_WIN32_AIOPS=0
 506 squid_opt_use_aio=
 507 squid_opt_use_diskthreads=
 508 AIOLIB=
 509
 510 dnl Setup the module paths etc.
 511 DISK_LIBS=
 512 DISK_MODULES=
 513 AH_TEMPLATE(HAVE_DISKIO_MODULE_AIO, [Whether POSIX AIO Disk I/O module is built])
 514 AH_TEMPLATE(HAVE_DISKIO_MODULE_BLOCKING, [Whether Blocking Disk I/O module is built])
 515 AH_TEMPLATE(HAVE_DISKIO_MODULE_DISKDAEMON, [Whether DiskDaemon Disk I/O module is built])
 516 AH_TEMPLATE(HAVE_DISKIO_MODULE_DISKTHREADS, [Whether DiskThreads Disk I/O module is built])
 517 AH_TEMPLATE(HAVE_DISKIO_MODULE_IPCIO, [Whether IpcIo Disk I/O module is built])
 518 AH_TEMPLATE(HAVE_DISKIO_MODULE_MMAPPED, [Whether Mmapped Disk I/O module is built])
 519 for module in $squid_disk_module_candidates none; do
 520   # maybe not needed
 521   if test "x$module" = "xnone"; then
 522     continue
 523   fi
 524   if ! test -d "$srcdir/src/DiskIO/$module"; then
 525     AC_MSG_ERROR(disk-io $module does not exist)
 526   fi
 527   case "$module" in
 528
 529     AIO)
 530       dnl Check for POSIX AIO availability
 531       squid_opt_use_aio="yes"
 532       AIOLIB=
 533       if test "x$with_aio" != "xno"; then
 534         have_aio_header=no
 535         AC_CHECK_HEADERS(aio.h,[have_aio_header=yes])
 536         dnl On some systems POSIX AIO functions are in librt
 537         dnl On some systems POSIX AIO functions are in libaio
 538         AC_CHECK_LIB(rt,aio_read,[AIOLIB="-lrt"],AC_CHECK_LIB(aio,aio_read,[AIOLIB="-laio"],[]))
 539         dnl Enable AIO if the library and headers are found
 540         if test "x$AIOLIB" != "x" && test "x$have_aio_header" = "xyes"; then
 541           AC_MSG_NOTICE([Native POSIX AIO support detected.])
 542           squid_opt_use_aio="yes"
 543         else
 544           dnl Windows does things differently. We provide wrappers.
 545           dnl TODO: Windows really needs its own DiskIO module or its Overlaped IO
 546           case "$squid_host_os" in
 547             mingw)
 548               squid_opt_use_aio="yes"
 549               AC_MSG_NOTICE([Windows being built. Maybe-enable POSIX AIO.])
 550               ;;
 551             *)
 552               AC_MSG_NOTICE([Native POSIX AIO support not detected. AIO automatically disabled.])
 553               squid_opt_use_aio="no"
 554               ;;
 555           esac
 556         fi
 557       else
 558         AC_MSG_NOTICE([POSIX AIO support manually disabled.])
 559         squid_opt_use_aio="no"
 560       fi
 561       dnl Use the POSIX AIO pieces if we actually need them.
 562       if test "x$squid_opt_use_aio" = "xyes" ; then
 563         DISK_MODULES="$DISK_MODULES AIO"
 564         AC_DEFINE([HAVE_DISKIO_MODULE_AIO],1,[POSIX AIO Disk I/O module is built])
 565         case "$squid_host_os" in
 566           mingw)
 567             ENABLE_WIN32_AIO=1
 568             AC_MSG_NOTICE([Replacing AIO DiskIO module with: Windows overlapped I/O support])
 569             ;;
 570           *)
 571             AC_MSG_NOTICE([Enabling AIO DiskIO module])
 572             ;;
 573         esac
 574       else
 575         AC_MSG_NOTICE([AIO DiskIO Module disabled. Missing POSIX AIO support.])
 576         squid_disk_module_candidates_AIO=no
 577       fi
 578       ;;
 579
 580     Blocking)
 581       AC_MSG_NOTICE([Enabling Blocking DiskIO module])
 582       DISK_MODULES="$DISK_MODULES Blocking"
 583       AC_DEFINE([HAVE_DISKIO_MODULE_BLOCKING],1,[Blocking Disk I/O module is built])
 584       ;;
 585
 586     DiskDaemon)
 587       case "$squid_host_os" in
 588         mingw)
 589           AC_MSG_NOTICE(["DiskDaemon not supported on MinGW"])
 590           squid_disk_module_candidates_DiskDaemon=no
 591           ;;
 592         *)
 593           AC_MSG_NOTICE([Enabling DiskDaemon DiskIO module])
 594           DISK_MODULES="$DISK_MODULES DiskDaemon"
 595           AC_DEFINE([HAVE_DISKIO_MODULE_DISKDAEMON],1,[DiskDaemon Disk I/O module is built])
 596           ;;
 597         esac
 598       ;;
 599
 600     DiskThreads)
 601       squid_opt_use_diskthreads="yes"
 602       LIBPTHREADS=
 603       SQUID_STATE_SAVE([diskthreads_state],[SQUID_CFLAGS SQUID_CXXFLAGS])
 604       if test "x$with_pthreads" != "xno"; then
 605       dnl TODO: this needs to be extended to handle more systems and better
 606       dnl REF: http://www.openldap.org/lists/openldap-bugs/200006/msg00070.html
 607       dnl REF: http://autoconf-archive.cryp.to/acx_pthread.html
 608         case "$squid_host_os" in
 609           mingw)
 610             ENABLE_WIN32_AIOPS=1
 611             AC_MSG_NOTICE([Windows threads support automatically enabled])
 612             ;;
 613           freebsd)
 614             if test `echo "$squid_host_os_version" | tr -d .` -lt 70 ; then
 615                 AC_MSG_NOTICE(pthread library requires FreeBSD 7 or later)
 616                 squid_opt_use_diskthreads="no"
 617             else
 618               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT"
 619               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT"
 620               if test "x$GCC" = "xyes" -a "x$PRESET_LDFLAGS" = "x" ; then
 621                 LDFLAGS="$LDFLAGS -pthread"
 622               fi
 623             fi
 624             ;;
 625           openbsd)
 626             if test `echo "$squid_host_os_version" | tr -d .` -lt 52 ; then
 627                 AC_MSG_NOTICE(pthread library requires OpenBSD 5.2 or later)
 628                 squid_opt_use_diskthreads="no"
 629             else
 630               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT"
 631               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT"
 632               LDFLAGS="$LDFLAGS -lpthread"
 633             fi
 634             ;;
 635           solaris)
 636             if test "x$GCC" = "xyes" ; then
 637               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT -pthreads"
 638               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT -pthreads"
 639               AC_CHECK_LIB(pthread, pthread_create ,[LIBPTHREADS="-lpthread"], [
 640                 AC_MSG_NOTICE(pthread library required but cannot be found.)
 641                 squid_opt_use_diskthreads="no"
 642                ])
 643             else
 644               dnl test for -lpthread first. libc version is a stub apparently on Solaris.
 645               SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT -lpthread"
 646               SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT -lpthread"
 647               AC_SEARCH_LIBS([pthread_create],[pthread thread],[
 648                 LIBPTHREADS="" #in LIBS
 649               ],[
 650                 AC_MSG_NOTICE(pthread library required but cannot be found.)
 651                 squid_opt_use_diskthreads="no"
 652               ])
 653             fi
 654             ;;
 655           *)
 656             SQUID_CFLAGS="$SQUID_CFLAGS -D_REENTRANT"
 657             SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_REENTRANT"
 658             AC_CHECK_LIB(pthread, pthread_create ,[LIBPTHREADS="-lpthread"], [
 659               AC_MSG_NOTICE(pthread library required but cannot be found.)
 660               squid_opt_use_diskthreads="no"
 661             ])
 662             ;;
 663           esac
 664         else
 665           AC_MSG_NOTICE([Native pthreads support manually disabled.])
 666           squid_opt_use_diskthreads="no"
 667         fi
 668         if test "x$squid_opt_use_diskthreads" = "xyes" ; then
 669           AC_MSG_NOTICE([Enabling DiskThreads DiskIO module])
 670           DISK_MODULES="$DISK_MODULES DiskThreads"
 671           AC_DEFINE([HAVE_DISKIO_MODULE_DISKTHREADS],1,[DiskThreads Disk I/O module is built])
 672         else
 673           AC_MSG_NOTICE([Native pthreads support disabled. DiskThreads module automaticaly disabled.])
 674           SQUID_STATE_ROLLBACK([diskthreads_state])
 675           squid_disk_module_candidates_DiskThreads=no
 676         fi
 677       ;;
 678
 679     IpcIo)
 680       if test "x$ac_cv_search_shm_open" = "xno" ; then
 681         AC_MSG_NOTICE([DiskIO IpcIo module requires shared memory support])
 682         squid_disk_module_candidates_IpcIo=no
 683       else
 684         AC_MSG_NOTICE([Enabling IpcIo DiskIO module])
 685         DISK_MODULES="$DISK_MODULES IpcIo"
 686         AC_DEFINE([HAVE_DISKIO_MODULE_IPCIO],1,[IpcIo Disk I/O module is built])
 687       fi
 688       ;;
 689
 690     Mmapped)
 691       dnl TODO: use availability of sys/mman.h and/or mmap to define
 692       dnl  OR support windows mmap functions
 693       if test "x$squid_host_os" = "xmingw" ; then
 694         AC_MSG_NOTICE([Mmapped DiskIO is not available on Mingw])
 695         squid_disk_module_candidates_Mmapped=no
 696       else
 697         AC_MSG_NOTICE([Enabling Mmapped DiskIO module])
 698         DISK_MODULES="$DISK_MODULES Mmapped"
 699         AC_DEFINE([HAVE_DISKIO_MODULE_MMAPPED],1,[Mmapped Disk I/O module is built])
 700       fi
 701       ;;
 702
 703     *)
 704       AC_MSG_NOTICE([Enabling $module DiskIO module])
 705       DISK_LIBS="$DISK_LIBS lib${module}.la"
 706       DISK_MODULES="$DISK_MODULES ${module}"
 707       ;;
 708     esac
 709 done
 710 AC_MSG_NOTICE([IO Modules built: $DISK_MODULES])
 711 AC_SUBST(DISK_MODULES)
 712 AC_SUBST(DISK_LIBS)
 713 AM_CONDITIONAL(ENABLE_DISKIO_AIO, test "x$squid_disk_module_candidates_AIO" = "xyes")
 714 AC_SUBST(AIOLIB)
 715 AM_CONDITIONAL(ENABLE_WIN32_AIO, test "x$squid_disk_module_candidates_AIO" = "xyes" -a "x$ENABLE_WIN32_AIO" = "x1")
 716 AM_CONDITIONAL(ENABLE_DISKIO_BLOCKING, test "x$squid_disk_module_candidates_Blocking" = "xyes")
 717 AM_CONDITIONAL(ENABLE_DISKIO_DISKDAEMON, test "x$squid_disk_module_candidates_DiskDaemon" = "xyes")
 718 AM_CONDITIONAL(ENABLE_DISKIO_DISKTHREADS, test "x$squid_disk_module_candidates_DiskThreads" = "xyes")
 719 AC_SUBST(LIBPTHREADS)
 720 AM_CONDITIONAL(ENABLE_WIN32_AIOPS, test "x$squid_disk_module_candidates_DiskThreads" = "xyes" -a "x$ENABLE_WIN32_AIOPS" = "x1")
 721 AM_CONDITIONAL(ENABLE_DISKIO_IPCIO, test "x$squid_disk_module_candidates_IpcIo" = "xyes")
 722 AM_CONDITIONAL(ENABLE_DISKIO_MMAPPED, test "x$squid_disk_module_candidates_Mmapped" = "xyes")
 723
 724 dnl Check what Storage formats are wanted.
 725 dnl This version will error out with a message saying why if a required DiskIO is missing.
 726 squid_opt_enable_storeio=auto
 727 AC_ARG_ENABLE([storeio],
 728   AS_HELP_STRING([--enable-storeio="list of modules"],
 729                  [Build support for the list of store I/O modules.
 730                   The default is only to build the "ufs" module.
 731                   See src/fs for a list of available modules, or
 732                   Programmers Guide section <not yet written>
 733                   for details on how to build your custom store module]), [
 734 case $enableval in
 735   yes)
 736     squid_opt_enable_storeio=auto
 737     ;;
 738   no)
 739     squid_opt_enable_storeio=no
 740     ;;
 741   *)
 742     squid_opt_enable_storeio=yes
 743     squid_storeio_module_candidates="`echo $enableval| sed -e 's/,/ /g;s/  */ /g'`"
 744     # ufs is really always needed as it has low-level routines
 745     # if it is a dupe it will be cleaned-up later
 746     squid_storeio_module_candidates="$squid_storeio_module_candidates ufs"
 747     ;;
 748   esac
 749 ])
 750 if test "x$squid_opt_enable_storeio" = "xauto"; then
 751   squid_opt_enable_storeio=yes
 752   AC_MSG_CHECKING([for available StoreIO modules])
 753   SQUID_LOOK_FOR_MODULES([$srcdir/src/fs],[squid_storeio_module_candidates])
 754   AC_MSG_RESULT([$squid_storeio_module_candidates])
 755 fi
 756
 757 SQUID_CLEANUP_MODULES_LIST([squid_storeio_module_candidates])
 758 SQUID_CHECK_EXISTING_MODULES([$srcdir/src/fs],[squid_storeio_module_candidates])
 759 AC_MSG_NOTICE([Store modules built: $squid_storeio_module_candidates])
 760
 761 for fs in $squid_storeio_module_candidates none; do
 762   case "$fs" in
 763     diskd)
 764       if test "x$squid_disk_module_candidates_Blocking" != "xyes" -a \
 765         "$squid_disk_module_candidates_DiskDaemon" != "yes" ; then
 766         AC_MSG_ERROR([Storage diskd module requires DiskIO module: Blocking or DiskDaemon])
 767       fi
 768       ;;
 769     aufs)
 770       if test "x$squid_disk_module_candidates_Blocking" != "xyes" -a \
 771         "$squid_disk_module_candidates_DiskThreads" != "yes" ; then
 772         AC_MSG_ERROR([Storage module aufs requires DiskIO module: Blocking or DiskThreads])
 773       fi
 774       ;;
 775     rock)
 776       if test "x$squid_disk_module_candidates_IpcIo" != "xyes" -a \
 777         "x$squid_disk_module_candidates_Blocking" != "xyes"; then
 778          AC_MSG_ERROR([Storage module Rock requires DiskIO module: Blocking or IpcIo])
 779       fi
 780       squid_do_build_rock=true
 781       ;;
 782     ufs)
 783       if test "x$squid_disk_module_candidates_Blocking" != "xyes"; then
 784         AC_MSG_ERROR([Storage module ufs requires DiskIO module: Blocking])
 785       fi
 786       squid_do_build_ufs=true
 787       ;;
 788     esac
 789 done
 790
 791 AM_CONDITIONAL(ENABLE_FS_UFS, test "x$squid_do_build_ufs" = "xtrue")
 792 AM_CONDITIONAL(ENABLE_FS_ROCK, test "x$squid_do_build_rock" = "xtrue")
 793 dnl hack: need to define those even if not used in the build system to
 794 dnl make sure that global FS objects are linked to the squid binary.
 795 AH_TEMPLATE(HAVE_FS_UFS, "Define to 1 if ufs filesystem module is build")
 796 AH_TEMPLATE(HAVE_FS_AUFS, "Define to 1 if aufs filesystem module is build")
 797 AH_TEMPLATE(HAVE_FS_DISKD, "Define to 1 if diskd filesystem module is build")
 798 AH_TEMPLATE(HAVE_FS_ROCK, "Define to 1 if rock filesystem module is build")
 799
 800
 801 dnl got final squid_storeio_module_candidates, build library lists
 802 dnl This list will not be needed when each fs library has its own Makefile
 803 STORE_LIBS_TO_BUILD=
 804 dnl File system libraries to link executables with.
 805 dnl These are the same as STORE_LIBS_TO_BUILD, but with a path
 806 STORE_LIBS_TO_ADD=
 807 for fs in $squid_storeio_module_candidates; do
 808     STORE_LIBS_TO_BUILD="$STORE_LIBS_TO_BUILD lib${fs}.la"
 809     STORE_LIBS_TO_ADD="$STORE_LIBS_TO_ADD fs/lib${fs}.la"
 810     SQUID_TOUPPER_VAR_CONTENTS([fs])
 811     AC_DEFINE_UNQUOTED(HAVE_FS_${fs}, 1)
 812 done
 813
 814 AC_SUBST(STORE_LIBS_TO_BUILD)
 815 AC_SUBST(STORE_LIBS_TO_ADD)
 816 AC_SUBST(STORE_TESTS)
 817
 818
 819 dnl At lest one removal policy is always needed.
 820 dnl 'lru' removal policy is currently hard-coded by name for tests
 821 dnl so we must set it as default.
 822 REPL_POLICIES="lru"
 823 AC_ARG_ENABLE(removal-policies,
 824   AS_HELP_STRING([--enable-removal-policies="list of policies"],
 825                  [Build support for the list of removal policies.
 826                   The default is only to build the "lru" module.
 827                   See src/repl for a list of available modules, or
 828                   Programmers Guide section 9.9 for details on how
 829                   to build your custom policy]), [
 830 case $enableval in
 831   yes)
 832     SQUID_LOOK_FOR_MODULES([$srcdir/src/repl],[REPL_POLICIES])
 833     ;;
 834   no)
 835     ;;
 836   *)
 837     REPL_POLICIES="`echo $enableval| sed -e 's/,/ /g;s/  */ /g'`"
 838     ;;
 839   esac
 840 ])
 841 if test "x$REPL_POLICIES" != "x" ; then
 842     SQUID_CHECK_EXISTING_MODULES([$srcdir/src/repl],[REPL_POLICIES])
 843     AC_MSG_NOTICE([Removal policies to build: $REPL_POLICIES])
 844     REPL_OBJS="repl/lib`echo $REPL_POLICIES|sed -e 's% %.a repl/lib%g'`.a"
 845     REPL_LIBS="`echo $REPL_OBJS|sed -e 's%repl/%%g'`"
 846 fi
 847 AC_SUBST(REPL_POLICIES)
 848 AC_SUBST(REPL_OBJS)
 849 AC_SUBST(REPL_LIBS)
 850
 851 AM_CONDITIONAL(ENABLE_PINGER, false)
 852 AC_ARG_ENABLE(icmp,
 853   AS_HELP_STRING([--enable-icmp],[Enable ICMP pinging and Network Measurement]),
 854 [ if test "x$enableval" = "xyes" ; then
 855     AC_MSG_NOTICE([ICMP enabled])
 856     AC_DEFINE(USE_ICMP,1,[Define to use Squid ICMP and Network Measurement features (highly recommended!)])
 857     AM_CONDITIONAL(ENABLE_PINGER, true)
 858   fi
 859 ])
 860
 861 AM_CONDITIONAL(ENABLE_DELAY_POOLS, false)
 862 AC_ARG_ENABLE(delay-pools,
 863   AS_HELP_STRING([--enable-delay-pools],[Enable delay pools to limit bandwidth usage]),
 864 [ if test "x$enableval" = "xyes" ; then
 865     AC_MSG_NOTICE([Delay pools enabled])
 866     AC_DEFINE([USE_DELAY_POOLS],1,[Traffic management via "delay pools".])
 867     AM_CONDITIONAL(ENABLE_DELAY_POOLS, true)
 868   fi
 869 ])
 870
 871 dnl disable generic/common adaptation support by default
 872 squid_opt_use_adaptation=no
 873
 874 squid_opt_use_esi=auto
 875 AH_TEMPLATE([USE_SQUID_ESI],[Define to enable the ESI processor])
 876 AC_ARG_ENABLE(esi,
 877   AS_HELP_STRING([--disable-esi],
 878                  [Disable ESI for accelerators. ESI requires expat or libxml2.
 879                   Enabling ESI will cause squid reverse proxies to be capable
 880                   of the Edge Acceleration Specification (www.esi.org).]),
 881                  [squid_opt_use_esi=$enableval],[])
 882 HAVE_LIBEXPAT=0
 883 EXPATLIB=
 884 HAVE_LIBXML2=0
 885 XMLLIB=
 886
 887 # ESI support libraries: expat
 888 SQUID_AUTO_LIB(expat,[ESI expat],[LIBEXPAT])
 889 if test "x$squid_opt_use_esi" != "xno" -a "x$with_expat" != "xno" ; then
 890   AC_CHECK_LIB([expat], [main], [EXPATLIB="-lexpat"; HAVE_LIBEXPAT=1])
 891   AC_CHECK_HEADERS([expat.h])
 892   AC_DEFINE_UNQUOTED(HAVE_LIBEXPAT, $HAVE_LIBEXPAT, [Define to 1 if you have the expat library])
 893   AS_IF(test "x$HAVE_LIBEXPAT" = "x1",[
 894     squid_opt_use_esi=yes
 895   ],[
 896     AS_IF(test "x$with_expat" = "xyes",[
 897       AC_MSG_ERROR([Required library expat not found.])
 898     ],[
 899       AC_MSG_NOTICE([Library expat not found.])
 900     ])
 901   ])
 902 fi
 903
 904 # TODO: remove this 'lib' prefix to match coding standard
 905 SQUID_AUTO_LIB(libxml2,[ESI libxml2],[LIBXML2])
 906 if test "x$squid_opt_use_esi" != "xno" -a "x$with_libxml2" != "xno" ; then
 907   SQUID_STATE_SAVE([squid_libxml2_save])
 908   PKG_CHECK_MODULES([LIBXML2],[libxml-2.0],[],[
 909     AC_CHECK_LIB([xml2], [main], [LIBXML2_LIBS="$LIBXML2_LIBS -lxml2"])
 910     dnl Find the main header and include path...
 911     AC_CACHE_CHECK([location of libxml2 include files], [ac_cv_libxml2_include], [
 912       AC_CHECK_HEADERS([libxml/parser.h], [], [
 913         AC_MSG_NOTICE([Testing in /usr/include/libxml2])
 914         SAVED_CPPFLAGS="$CPPFLAGS"
 915         CPPFLAGS="-I/usr/include/libxml2 $CPPFLAGS"
 916         unset ac_cv_header_libxml_parser_h
 917         AC_CHECK_HEADERS([libxml/parser.h], [LIBXML2_CFLAGS="$LIBXML2_CFLAGS -I/usr/include/libxml2"], [
 918           AC_MSG_NOTICE([Testing in /usr/local/include/libxml2])
 919           CPPFLAGS="-I/usr/local/include/libxml2 $SAVED_CPPFLAGS"
 920           unset ac_cv_header_libxml_parser_h
 921           AC_CHECK_HEADERS([libxml/parser.h], [LIBXML2_CFLAGS="$LIBXML2_CFLAGS -I/usr/local/include/libxml2"], [
 922             AC_MSG_NOTICE([Failed to find libxml2 header file libxml/parser.h])
 923           ])
 924         ])
 925         CPPFLAGS="$SAVED_CPPFLAGS"
 926       ])
 927     ])
 928   ])
 929   CPPFLAGS="$CPPFLAGS $LIBXML2_CFLAGS"
 930   dnl Now that we know where to look find the headers...
 931   AC_CHECK_HEADERS(libxml/parser.h libxml/HTMLparser.h libxml/HTMLtree.h)
 932   SQUID_STATE_ROLLBACK([squid_libxml2_save])
 933
 934   if test "x$LIBXML2_LIBS" != "x"; then
 935     HAVE_LIBXML2=1
 936     squid_opt_use_esi=yes
 937     SQUID_CXXFLAGS="$SQUID_CXXFLAGS $LIBXML2_CFLAGS"
 938     CPPFLAGS="$CPPFLAGS $LIBXML2_CFLAGS"
 939     XMLLIB="$LIBXML2_LIBS"
 940     AC_DEFINE_UNQUOTED(HAVE_LIBXML2, $HAVE_LIBXML2, [Define to 1 if you have the libxml2 library])
 941   elif test "x$with_libxml2" = "xyes"; then
 942     AC_MSG_ERROR([Required library libxml2 not found])
 943   else
 944     AC_MSG_NOTICE([Library libxml2 not found.])
 945   fi
 946 fi
 947
 948 AS_IF([test "x$squid_opt_use_esi" = "xyes"],[
 949   AS_IF(test "x$HAVE_LIBXML2" = "x0" -a "x$HAVE_LIBEXPAT" = "x0",[
 950     AC_MSG_ERROR([ESI processor requires libxml2 or libexpat])
 951   ])
 952   AC_MSG_NOTICE([Enabling ESI processor: $EXPATLIB $XMLLIB])
 953   AC_DEFINE(USE_SQUID_ESI,1,[Compile the ESI processor])
 954 ],[
 955   AS_IF(test "x$squid_opt_use_esi" = "xno",[
 956     AC_MSG_NOTICE([Disabling ESI processor.])
 957   ],[
 958     AC_MSG_NOTICE([Disabling ESI processor. libxml2 and libexpat not found.])
 959   ])
 960 ])
 961 AM_CONDITIONAL(ENABLE_ESI, test "x$squid_opt_use_esi" = "xyes")
 962 AM_CONDITIONAL(ENABLE_LIBEXPAT, test "x$HAVE_LIBEXPAT" = "x1")
 963 AC_SUBST(EXPATLIB)
 964 AM_CONDITIONAL(ENABLE_LIBXML2, test "x$HAVE_LIBXML2" = "x1")
 965 AC_SUBST(XMLLIB)
 966
 967 # icap argument handling
 968 AC_ARG_ENABLE(icap-client,
 969   AS_HELP_STRING([--disable-icap-client],[Disable the ICAP client.]),[
 970   SQUID_YESNO([$enableval],[Unrecognized argument to --disable-icap-client: $enableval])
 971 ])
 972 SQUID_DEFINE_BOOL(ICAP_CLIENT,${enable_icap_client:=yes}, [Enable ICAP client features in Squid])
 973 AS_IF(test "x$enable_icap_client" != "xno", squid_opt_use_adaptation="yes")
 974 AM_CONDITIONAL(ENABLE_ICAP_CLIENT, test "x$enable_icap_client" != "xno")
 975
 976 squid_opt_use_ecap=1
 977 AC_MSG_CHECKING(whether to support eCAP)
 978 AC_ARG_ENABLE(ecap,
 979   AS_HELP_STRING([--enable-ecap],[support loadable content adaptation modules]), [
 980     case "${enableval}" in
 981        yes|no) squid_opt_use_ecap=$enableval ;;
 982        *) AC_MSG_ERROR(bad value ${enableval} for --enable-ecap) ;;
 983     esac
 984 AC_MSG_RESULT([$squid_opt_use_ecap, explicitly])
 985     ], [
 986         squid_opt_use_ecap=no;
 987         AC_MSG_RESULT([$squid_opt_use_ecap, implicitly])
 988     ]
 989 )
 990
 991 dnl Perform configuration consistency checks for eCAP
 992 if test "x$squid_opt_use_ecap" != "xno";
 993 then
 994   dnl eCAP support requires loadable modules, which are enabled by default
 995   if test "x$enable_loadable_modules" != "xyes"
 996   then
 997     AC_MSG_ERROR([eCAP support requires loadable modules. Please do not use --disable-loadable-modules with --enable-ecap.])
 998   fi
 999
1000   if test -n "$PKG_CONFIG"; then
1001     dnl eCAP support requires libecap.
1002     dnl This Squid supports libecap v1.0.x.
1003     dnl Use EXT_ prefix to distinguish external libecap (that we check for
1004     dnl here) from our own convenience ecap library in Makefiles.
1005     PKG_CHECK_MODULES([EXT_LIBECAP],[libecap >= 1.0 libecap < 1.1])
1006   else
1007     AC_MSG_NOTICE([eCAP support requires pkg-config to verify the correct library version. Trouble may follow.])
1008   fi
1009
1010   SQUID_STATE_SAVE(squid_ecap_state)
1011   AC_MSG_CHECKING([whether -lecap will link])
1012   CXXFLAGS="$CXXFLAGS $EXT_LIBECAP_CFLAGS"
1013   LIBS="$LIBS $EXT_LIBECAP_LIBS"
1014   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <libecap/common/names.h>]],[[
1015     const libecap::Name test("test", libecap::Name::NextId());
1016   ]])],[
1017     AC_MSG_RESULT(yes)
1018     squid_opt_use_adaptation=yes
1019   ],[
1020     AC_MSG_RESULT(no)
1021     AS_IF(
1022       test "x$squid_opt_use_ecap" = "xyes", AC_MSG_ERROR([eCAP library will not link.
1023                   You may need to rebuild libecap using the same version of GCC as Squid.
1024                   There have been breaking ABI changes in the libstdc++ STL with GCC 5.]),
1025
1026     [AC_MSG_NOTICE([eCAP library will not link.
1027                   You may need to rebuild libecap using the same version of GCC as Squid.
1028                   There have been breaking ABI changes in the libstdc++ STL with GCC 5.])
1029       squid_opt_use_ecap="no"
1030     ])
1031   ])
1032   SQUID_STATE_ROLLBACK(squid_ecap_state)
1033 fi
1034 SQUID_DEFINE_BOOL(USE_ECAP,${squid_opt_use_ecap:=no},[Whether to use eCAP support])
1035 AM_CONDITIONAL(ENABLE_ECAP, test "x$squid_opt_use_ecap" = "xyes")
1036
1037 dnl enable adaptation if requested by specific adaptation mechanisms
1038 ADAPTATION_LIBS=""
1039 if test "x$squid_opt_use_adaptation" = "xyes"; then
1040     ADAPTATION_LIBS="adaptation/libadaptation.la"
1041 fi
1042 SQUID_DEFINE_BOOL(USE_ADAPTATION,${squid_opt_use_adaptation:=no}, [common adaptation support])
1043 AM_CONDITIONAL(ENABLE_ADAPTATION, test "x$squid_opt_use_adaptation" = "xyes")
1044 AC_SUBST(ADAPTATION_LIBS)
1045
1046 test "x$squid_host_os" = "xmingw" && enable_wccp=no
1047 AC_ARG_ENABLE(wccp,
1048   AS_HELP_STRING([--disable-wccp],[Disable Web Cache Coordination Protocol]), [
1049 SQUID_YESNO([$enableval],[unrecognized argument to --disable-wccp: $enableval])
1050 ])
1051 SQUID_DEFINE_BOOL(USE_WCCP, ${enable_wccp:=yes}, [Define to enable WCCP])
1052 AC_MSG_NOTICE([Web Cache Coordination Protocol enabled: $enable_wccp])
1053
1054 test "x$squid_host_os" = "xmingw" && enable_wccpv2=no
1055 AC_ARG_ENABLE(wccpv2,
1056   AS_HELP_STRING([--disable-wccpv2],
1057                  [Disable Web Cache Coordination V2 Protocol]), [
1058 SQUID_YESNO([$enableval],
1059             [unrecognized argument to --disable-wccpv2: $enableval])
1060 ])
1061 SQUID_DEFINE_BOOL(USE_WCCPv2,${enable_wccpv2:=yes},
1062             [Define to enable WCCP V2])
1063 AC_MSG_NOTICE([Web Cache Coordination V2 Protocol enabled: $enable_wccpv2])
1064
1065 AC_ARG_ENABLE(kill-parent-hack,
1066   AS_HELP_STRING([--enable-kill-parent-hack],[Kill parent on shutdown]), [
1067 SQUID_YESNO([$enableval],
1068             [unrecognized argument to --enable-kill-parent-hack: $enableval])
1069 ])
1070 SQUID_DEFINE_BOOL(KILL_PARENT_OPT,${enable_kill_parent_hack:=no},
1071                    [A dangerous feature which causes Squid to kill its parent
1072                     process (presumably the RunCache script) upon receipt
1073                     of SIGTERM or SIGINT. Deprecated, Use with caution.])
1074 AC_MSG_NOTICE([Kill parent on shutdown hack enabled: $enable_kill_parent_hack])
1075
1076 AC_ARG_ENABLE(snmp,
1077   AS_HELP_STRING([--disable-snmp],[Disable SNMP monitoring support]), [
1078   SQUID_YESNO([$enableval],
1079               [unrecognized argument to --disable-snmp: $enableval])
1080 ])
1081 SQUID_DEFINE_BOOL(SQUID_SNMP,${enable_snmp:=yes},
1082    [Define to enable SNMP monitoring of Squid])
1083 AM_CONDITIONAL(ENABLE_SNMP, [test "x$enable_snmp" = "xyes"])
1084 if test "x$enable_snmp" = "xyes"; then
1085     SNMPLIB='../lib/snmplib/libsnmplib.la'
1086 fi
1087 AC_MSG_NOTICE([SNMP support enabled: $enable_snmp])
1088 AC_SUBST(SNMPLIB)
1089
1090 AC_ARG_ENABLE(cachemgr-hostname,
1091   AS_HELP_STRING([--enable-cachemgr-hostname=hostname],
1092                  [Make cachemgr.cgi default to this host.
1093                   If unspecified, uses the name of the build-host]), [
1094   case $enableval in
1095   yes)
1096     AC_DEFINE(CACHEMGR_HOSTNAME,[getfullhostname()],
1097     [If you are upset that the cachemgr.cgi form comes up with the hostname field blank, then define this to getfullhostname()])
1098     AC_MSG_NOTICE([Cachemgr default hostname == host where cachemgr runs])
1099     ;;
1100   no)
1101     : # Nothing to do..
1102    ;;
1103   *)
1104     AC_DEFINE_UNQUOTED(CACHEMGR_HOSTNAME,"${enableval}")
1105     AC_MSG_NOTICE([Cachemgr default hostname set to ${enableval}])
1106     ;;
1107   esac
1108 ])
1109
1110 AC_ARG_ENABLE(eui,
1111   AS_HELP_STRING([--disable-eui],
1112                  [Disable use of ARP / MAC/ EUI (ether address)]), [
1113 SQUID_YESNO([$enableval],[--disable-eui expects no arguments])
1114 ])
1115 if test "x${enable_eui:=yes}" = "xyes" ; then
1116   SQUID_STATE_SAVE(LIBEUI)
1117   # GLIBC 2.30 deprecates sysctl.h. Test with the same flags that (may) break includes later.
1118   CFLAGS=$SQUID_CFLAGS
1119   CXXFLAGS=$SQUID_CXXFLAGS
1120   case "$squid_host_os" in
1121     linux|solaris|freebsd|openbsd|netbsd|cygwin)
1122       ${TRUE}
1123       ;;
1124     mingw)
1125       EUILIB="-liphlpapi"
1126       ;;
1127     *)
1128       AC_MSG_WARN([EUI support probably will not work on host $host.])
1129       ;;
1130   esac
1131   # iphlpapi.h check delayed after winsock2.h
1132   AC_CHECK_HEADERS( \
1133     windows.h \
1134     sys/sockio.h \
1135     sys/param.h,
1136   [], [], [[
1137 #if HAVE_WINDOWS_H
1138 include <windows.h>
1139 #endif
1140 ]]
1141   )
1142   AC_CHECK_HEADERS( \
1143     net/if_arp.h \
1144     net/route.h,
1145   [], [], [[
1146 #include <sys/types.h>
1147 #include <sys/socket.h>
1148 ]])
1149
1150   # OpenBSD, FreeBSD and NetBSD requires sys/param.h to be included before sysctl.h and net/if_dl.h
1151   AC_CHECK_HEADERS( \
1152     net/if_dl.h \
1153     sys/sysctl.h,
1154   [], [], [[
1155 #if HAVE_SYS_PARAM_H
1156 #include <sys/param.h>
1157 #endif
1158   ]])
1159   SQUID_STATE_ROLLBACK(LIBEUI)
1160 fi
1161 AC_SUBST(EUILIB)
1162 AC_MSG_NOTICE([EUI (MAC address) controls enabled: $enable_eui])
1163 SQUID_DEFINE_BOOL(USE_SQUID_EUI,$enable_eui,
1164    [Define this to include code which lets you use ethernet addresses. This code uses API initially defined in 4.4-BSD.])
1165 AM_CONDITIONAL(ENABLE_EUI, [test "x$enable_eui" = "xyes" ])
1166
1167
1168 AC_ARG_ENABLE(htcp,
1169   AS_HELP_STRING([--disable-htcp],[Disable HTCP protocol support]), [
1170 SQUID_YESNO([$enableval],
1171             [unrecognized argument to --disable-htcp: $enableval])
1172 ])
1173 SQUID_DEFINE_BOOL(USE_HTCP,${enable_htcp:=yes},
1174    [Define this to include code for the Hypertext Cache Protocol (HTCP)])
1175 AM_CONDITIONAL(ENABLE_HTCP, [test "x$enable_htcp" = "xyes"])
1176 AC_MSG_NOTICE([HTCP support enabled: $enable_htcp])
1177
1178 # Cryptograhic libraries
1179 SQUID_AUTO_LIB(nettle,[Nettle crypto],[LIBNETTLE])
1180 if test "x$with_nettle" != "xno" ; then
1181   CPPFLAGS="$LIBNETTLE_CFLAGS $CPPFLAGS"
1182   AC_CHECK_LIB(nettle, nettle_md5_init,[
1183     NETTLELIB="$LIBNETTLE_PATH -lnettle"
1184     AC_CHECK_HEADERS(nettle/md5.h)
1185   ],[with_nettle=no])
1186   if test "x$with_nettle" != "xno" ; then
1187     # Base64 uses the nettle 3.4 API
1188     # which matters on 64-bit systems
1189     AC_CHECK_HEADERS(nettle/base64.h)
1190     AC_MSG_CHECKING([for Nettle 3.4 API compatibility])
1191     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1192 #     include <cstddef>
1193 #     include <cstdint>
1194 #     include <nettle/base64.h>
1195     ]],[[
1196       char inData[10]; inData[0] = '\0';
1197       size_t srcLen = 0;
1198       struct base64_decode_ctx ctx;
1199       base64_decode_init(&ctx);
1200       uint8_t outData[10];
1201       size_t dstLen = 0;
1202       if (!base64_decode_update(&ctx, &dstLen, outData, srcLen, inData) ||
1203               !base64_decode_final(&ctx)) {
1204           return 1;
1205       }
1206     ]])],[AC_MSG_RESULT(yes)
1207       AC_DEFINE(HAVE_NETTLE34_BASE64,1,[set to 1 if Nettle 3.4 API will link])
1208     ],[AC_MSG_RESULT(no)])
1209   fi
1210 fi
1211 AC_MSG_NOTICE([Using Nettle cryptographic library: ${with_nettle:=yes}])
1212 AC_SUBST(NETTLELIB)
1213
1214 dnl Check for libcrypt
1215 CRYPTLIB=
1216 dnl Some of our helpers use crypt(3) which may be in libc, or in
1217 dnl libcrypt (eg FreeBSD)
1218 AC_CHECK_LIB(crypt, crypt, [CRYPTLIB="-lcrypt"])
1219 dnl Solaris10 provides MD5 natively through libmd5
1220 AC_CHECK_LIB(md5, MD5Init, [CRYPTLIB="$CRYPTLIB -lmd5"])
1221 AC_SUBST(CRYPTLIB)
1222
1223 SSLLIB=""
1224
1225 SQUID_AUTO_LIB(gnutls,[GnuTLS crypto],[LIBGNUTLS])
1226 AH_TEMPLATE(USE_GNUTLS,[GnuTLS support is available])
1227 if test "x$with_gnutls" != "xno"; then
1228   SQUID_STATE_SAVE(squid_gnutls_state)
1229
1230   # User may have provided a custom location for GnuTLS. Otherwise...
1231   CPPFLAGS="$LIBGNUTLS_CFLAGS $CPPFLAGS"
1232   LIBS="$LIBS $LIBGNUTLS_PATH"
1233
1234   # auto-detect using pkg-config
1235   PKG_CHECK_MODULES([LIBGNUTLS],[gnutls >= 3.4.0],[
1236     CPPFLAGS="$CPPFLAGS $LIBGNUTLS_CFLAGS"
1237     ],[
1238     ## find the package without pkg-config
1239     ## check that the library is actually new enough.
1240     ## by testing for a 3.4.0+ function which we use
1241     AC_CHECK_LIB(gnutls,gnutls_pcert_export_x509,[LIBGNUTLS_LIBS="-lgnutls"])
1242   ])
1243   AC_CHECK_HEADERS(gnutls/gnutls.h gnutls/x509.h gnutls/abstract.h)
1244
1245   SQUID_STATE_ROLLBACK(squid_gnutls_state) #de-pollute LIBS
1246
1247   if test "x$with_gnutls" = "xyes" -a "x$LIBGNUTLS_LIBS" = "x"; then
1248     AC_MSG_ERROR([Required GnuTLS library not found])
1249   fi
1250   if test "x$LIBGNUTLS_LIBS" != "x" ; then
1251     CXXFLAGS="$LIBGNUTLS_CFLAGS $CXXFLAGS"
1252     SSLLIB="$LIBGNUTLS_PATH $LIBGNUTLS_LIBS $SSLLIB"
1253     AC_DEFINE(USE_GNUTLS,1,[GnuTLS support is available])
1254   else
1255     with_gnutls=no
1256   fi
1257 fi
1258 AC_MSG_NOTICE([GnuTLS library support: ${with_gnutls:=auto} ${LIBGNUTLS_PATH} ${LIBGNUTLS_LIBS}])
1259
1260 dnl User may specify OpenSSL is needed from a non-standard location
1261 SQUID_OPTIONAL_LIB(openssl,[OpenSSL],[LIBOPENSSL])
1262 AH_TEMPLATE(USE_OPENSSL,[OpenSSL support is available])
1263 ## OpenSSL is default disable due to licensing issues on some OS
1264 if test "x$with_openssl" = "xyes"; then
1265   CPPFLAGS="$LIBOPENSSL_CFLAGS $CPPFLAGS"
1266   AC_CHECK_HEADERS( \
1267     openssl/asn1.h \
1268     openssl/bio.h \
1269     openssl/bn.h \
1270     openssl/crypto.h \
1271     openssl/dh.h \
1272     openssl/err.h \
1273     openssl/evp.h \
1274     openssl/lhash.h \
1275     openssl/md5.h \
1276     openssl/opensslv.h \
1277     openssl/rsa.h \
1278     openssl/ssl.h \
1279     openssl/x509.h \
1280     openssl/x509v3.h \
1281     openssl/engine.h \
1282     openssl/txt_db.h \
1283   )
1284
1285   # User may have provided a custom location for OpenSSL. Otherwise...
1286   SQUID_STATE_SAVE(squid_openssl_state)
1287   LIBS="$LIBS $LIBOPENSSL_PATH"
1288
1289   # auto-detect using pkg-config
1290   PKG_CHECK_MODULES([LIBOPENSSL],[openssl],,[
1291     ## For some OS pkg-config is broken or unavailable.
1292     ## Detect libraries the hard way.
1293
1294     # Windows MinGW has some special libraries ...
1295     if test "x$squid_host_os" = "xmingw" ; then
1296       LIBOPENSSL_LIBS='-lssleay32 -leay32 -lgdi32 $LIBOPENSSL_LIBS'
1297       AC_MSG_NOTICE([Windows OpenSSL library support: yes -lssleay32 -leay32 -lgdi32])
1298     fi
1299
1300     AC_CHECK_LIB(crypto,[CRYPTO_new_ex_data],[LIBOPENSSL_LIBS="-lcrypto $LIBOPENSSL_LIBS"],[
1301       AC_MSG_ERROR([library 'crypto' is required for OpenSSL])
1302     ],$LIBOPENSSL_LIBS)
1303     AC_CHECK_LIB(ssl,[SSL_CTX_new],[LIBOPENSSL_LIBS="-lssl $LIBOPENSSL_LIBS"],[
1304       AC_MSG_ERROR([library 'ssl' is required for OpenSSL])
1305     ],$LIBOPENSSL_LIBS)
1306   ])
1307
1308   # This is a workaround for RedHat 9 brain damage..
1309   if test -d /usr/kerberos/include -a -f /usr/include/openssl/kssl.h; then
1310     AC_MSG_NOTICE([OpenSSL depends on Kerberos])
1311     LIBOPENSSL_LIBS="-L/usr/kerberos/lib $LIBOPENSSL_LIBS"
1312     CPPFLAGS="$CPPFLAGS -I/usr/kerberos/include"
1313   fi
1314   SQUID_STATE_ROLLBACK(squid_openssl_state) #de-pollute LIBS
1315
1316   if test "x$LIBOPENSSL_LIBS" != "x"; then
1317     CXXFLAGS="$LIBOPENSSL_CFLAGS $CXXFLAGS"
1318     SSLLIB="$LIBOPENSSL_PATH $LIBOPENSSL_LIBS $SSLLIB"
1319     AC_DEFINE(USE_OPENSSL,1,[OpenSSL support is available])
1320
1321     # check for API functions
1322     SQUID_CHECK_LIBCRYPTO_API
1323     SQUID_CHECK_LIBSSL_API
1324     SQUID_CHECK_OPENSSL_TLS_METHODS
1325     SQUID_STATE_SAVE(check_SSL_CTX_get0_certificate)
1326     LIBS="$LIBS $SSLLIB"
1327     AC_CHECK_LIB(ssl, SSL_CTX_get0_certificate, [
1328       AC_DEFINE(HAVE_SSL_CTX_GET0_CERTIFICATE, 1, [SSL_CTX_get0_certificate is available])
1329       ], [
1330           missing_SSL_CTX_get0_certificate=yes
1331       ])
1332     SQUID_STATE_ROLLBACK(check_SSL_CTX_get0_certificate)
1333
1334     # check for other specific broken implementations
1335     if test "x$missing_SSL_CTX_get0_certificate" = "xyes"; then
1336       SQUID_CHECK_OPENSSL_GETCERTIFICATE_WORKS
1337     fi
1338     SQUID_CHECK_OPENSSL_CONST_SSL_METHOD
1339     SQUID_CHECK_OPENSSL_CONST_CRYPTO_EX_DATA
1340     SQUID_CHECK_OPENSSL_CONST_SSL_SESSION_CB_ARG
1341     SQUID_CHECK_OPENSSL_CONST_X509_GET0_SIGNATURE_ARGS
1342     SQUID_CHECK_OPENSSL_TXTDB
1343     SQUID_CHECK_OPENSSL_HELLO_OVERWRITE_HACK
1344   fi
1345   if test "x$SSLLIB" = "x"; then
1346     AC_MSG_ERROR([Required OpenSSL library not found])
1347   fi
1348 fi
1349 AC_MSG_NOTICE([OpenSSL library support: ${with_openssl:=no} ${LIBOPENSSL_PATH} ${LIBOPENSSL_LIBS}])
1350 AM_CONDITIONAL(ENABLE_SSL,[ test "x$with_openssl" = "xyes" ])
1351 AC_SUBST(SSLLIB)
1352
1353 dnl User may specify MIT Kerberos is needed from a non-standard location
1354 SQUID_AUTO_LIB(mit-krb5,[MIT Kerberos],[LIB_KRB5])
1355 AH_TEMPLATE(USE_APPLE_KRB5,[Apple Kerberos support is available])
1356 AH_TEMPLATE(USE_MIT_KRB5,[MIT Kerberos support is available])
1357 AH_TEMPLATE(USE_SOLARIS_KRB5,[Solaris Kerberos support is available])
1358
1359 ## find out if pkg-config or krb5-config will work
1360 if test "x$with_mit_krb5" != "xno"; then
1361   CXXFLAGS="$LIB_KRB5_CFLAGS $CXXFLAGS"
1362   krb5confpath="$with_mit_krb5/bin"
1363   # find installed libs via pkg-config or krb5-config
1364   squid_pc_krb5_name=
1365   PKG_CHECK_EXISTS(mit-krb5-gssapi mit-krb5, [squid_pc_krb5_name="mit-krb5-gssapi mit-krb5"],[
1366     PKG_CHECK_EXISTS(gssapi-krb5 krb5, [squid_pc_krb5_name="gssapi-krb5 krb5"])
1367   ])
1368   if test "x$squid_pc_krb5_name" = "x" -a "$cross_compiling" = "no"; then
1369     # Look for krb5-config (unless cross-compiling)
1370     AC_PATH_PROG(krb5_config,krb5-config,no,$krb5confpath)
1371     if test "x$ac_cv_path_krb5_config" != "xno" ; then
1372       krb5confpath="`dirname $ac_cv_path_krb5_config`"
1373       ac_heimdal="`$ac_cv_path_krb5_config --version 2>/dev/null | grep -c -i heimdal`"
1374       ac_solaris="`$ac_cv_path_krb5_config --version 2>/dev/null | grep -c -i solaris`"
1375       ac_apple="`$ac_cv_path_krb5_config --vendor 2>/dev/null | grep -c -i apple`"
1376       if test $ac_solaris -gt 0 ; then
1377         with_solaris_krb5=yes
1378       elif test $ac_apple -gt 0 ; then
1379         with_apple_krb5=yes
1380       elif test $ac_heimdal -gt 0; then
1381         with_mit_krb5=no
1382         if test "x$with_mit_krb5" = "xyes"; then
1383           AC_MSG_ERROR([Could not find pkg-config or krb5-config for MIT Kerberos])
1384         fi
1385       fi
1386     else
1387       if test "x$with_mit_krb5" = "xyes"; then
1388         AC_MSG_ERROR([Could not find krb5-config in path])
1389       else
1390         with_mit_krb5=no
1391       fi
1392     fi
1393   fi
1394 fi
1395
1396 # detect MIT Kerberos dependencies (except on Solaris)
1397 if test "x$with_mit_krb5" != "xno" -a "x$with_solaris_krb5" != "xyes"; then
1398   SQUID_STATE_SAVE([squid_krb5_save])
1399   LIBS="$LIBS $LIB_KRB5_PATH"
1400
1401   # auto-detect using pkg-config
1402   PKG_CHECK_MODULES([LIB_KRB5], $squid_pc_krb5_name,,[
1403     # look for krb5-config (unless cross-compiling)
1404     if test "$cross_compiling" = "no"; then
1405       if test "x$krb5confpath" = "x" ; then
1406         AC_PATH_PROG(krb5_config,krb5-config,no)
1407         if test "x$ac_cv_path_krb5_config" != "xno" ; then
1408           ac_krb5_config="$ac_cv_path_krb5_config"
1409         fi
1410       else
1411         ac_krb5_config="$krb5confpath/krb5-config"
1412       fi
1413     fi
1414     if test "x$ac_krb5_config" != "x" && test -x "$ac_krb5_config"; then
1415       # Get libs, etc
1416       AC_MSG_NOTICE([Use krb5-config to get CXXFLAGS and LIBS])
1417       LIB_KRB5_CFLAGS="`$ac_krb5_config --cflags krb5 2>/dev/null`"
1418       LIB_KRB5_LIBS="`$ac_krb5_config --libs krb5 2>/dev/null`"
1419       LIB_KRB5_CFLAGS="`$ac_krb5_config --cflags gssapi 2>/dev/null` $LIB_KRB5_CFLAGS"
1420       LIB_KRB5_LIBS="`$ac_krb5_config --libs gssapi 2>/dev/null` $LIB_KRB5_LIBS"
1421     else
1422       ## For some OS pkg-config is broken or unavailable.
1423       ## Detect libraries the hard way.
1424
1425       SQUID_STATE_SAVE([squid_mit_save])
1426       missing_required=
1427       AC_MSG_NOTICE([Try to find Kerberos libraries in given path])
1428       AC_CHECK_LIB(com_err, [main], [LIB_KRB5_LIBS="-lcom_err $LIB_KRB5_LIBS"],[
1429         AC_MSG_WARN([library 'com_err' is required for MIT Kerberos])
1430         missing_required=yes
1431       ])
1432       LIBS=$LIB_KRB5_LIBS
1433       AC_CHECK_LIB(k5crypto, [main], [LIB_KRB5_LIBS="-lk5crypto $LIB_KRB5_LIBS"],[
1434         AC_MSG_WARN([library 'k5crypto' is required for MIT Kerberos])
1435         missing_required=yes
1436       ])
1437       LIBS=$LIB_KRB5_LIBS
1438       AC_CHECK_LIB(krb5, [main], [LIB_KRB5_LIBS="-lkrb5 $LIB_KRB5_LIBS"],[
1439         AC_MSG_WARN([library 'krb5' is required for MIT Kerberos])
1440         missing_required=yes
1441       ])
1442       LIBS=$LIB_KRB5_LIBS
1443       AC_CHECK_LIB(gssapi_krb5, [main], [LIB_KRB5_LIBS="-lgssapi_krb5 $LIB_KRB5_LIBS"],[
1444         AC_MSG_WARN([library 'gssapi_krb5' is required for MIT Kerberos])
1445         missing_required=yes
1446       ])
1447       SQUID_STATE_ROLLBACK([squid_mit_save])
1448       if test "x$missing_required" = "xyes"; then
1449         LIB_KRB5_LIBS=""
1450       fi
1451     fi
1452   ])
1453
1454   if test "x$LIB_KRB5_LIBS" != "x"; then
1455     if test "x$with_apple_krb5" = "xyes" ; then
1456       AC_DEFINE(USE_APPLE_KRB5,1,[Apple Kerberos support is available])
1457       KRB5_FLAVOUR="Apple"
1458     else
1459       AC_DEFINE(USE_MIT_KRB5,1,[MIT Kerberos support is available])
1460       KRB5_FLAVOUR="MIT"
1461     fi
1462     KRB5LIBS="$LIB_KRB5_PATH $LIB_KRB5_LIBS $KRB5LIBS"
1463     KRB5INCS="$LIB_KRB5_CFLAGS"
1464
1465     # check for other specific broken implementations
1466     CXXFLAGS="$CXXFLAGS $KRB5INCS"
1467     LIBS="$LIBS $KRB5LIBS"
1468
1469     AC_MSG_NOTICE([Try to find Kerberos headers in given path])
1470     AC_CHECK_HEADERS(gssapi.h gssapi/gssapi.h gssapi/gssapi_krb5.h)
1471     AC_CHECK_HEADERS(gssapi/gssapi_generic.h)
1472     AC_CHECK_HEADERS(krb5.h com_err.h et/com_err.h)
1473     AC_CHECK_HEADERS(profile.h)
1474
1475     SQUID_CHECK_KRB5_FUNCS
1476   fi
1477   if test "x$with_mit_krb5" = "xyes" -a "x$KRB5LIBS" = "x"; then
1478     AC_MSG_ERROR([Required Kerberos library not found])
1479   elif test "x$KRB5LIBS" = "x"; then
1480     with_mit_krb5=no
1481     with_apple_krb5=no
1482   fi
1483   SQUID_STATE_ROLLBACK([squid_krb5_save])
1484 fi
1485
1486 # detect Solaris Kerberos dependencies
1487 if test "x$with_solaris_krb5" = "xyes" -a "x$KRB5LIBS" = "x"; then
1488   SQUID_STATE_SAVE([squid_krb5_save])
1489   LIBS="$LIBS $LIB_KRB5_PATH"
1490
1491   # no pkg-config for solaris native Kerberos
1492   # look for krb5-config (unless cross-compiling)
1493   if test "$cross_compiling" = "no"; then
1494     if test "x$krb5confpath" = "x" ; then
1495       AC_PATH_PROG(krb5_config,krb5-config,no)
1496       if test "x$ac_cv_path_krb5_config" != "xno" ; then
1497         ac_krb5_config="$ac_cv_path_krb5_config"
1498       fi
1499     else
1500       ac_krb5_config="$krb5confpath/krb5-config"
1501     fi
1502   fi
1503   if test "x$ac_krb5_config" != "x" && test -x "$ac_krb5_config"; then
1504     # Get libs, etc
1505     AC_MSG_NOTICE([Use krb5-config to get CXXFLAGS and LIBS])
1506     LIB_KRB5_CFLAGS="`$ac_krb5_config --cflags krb5 2>/dev/null`"
1507     LIB_KRB5_LIBS="`$ac_krb5_config --libs krb5 2>/dev/null`"
1508     # Solaris 10 Update 11 patches the krb5-config tool to produce stderr messages on stdout.
1509     SOLARIS_BROKEN_KRB5CONFIG_GSSAPI="`$ac_krb5_config --libs gssapi 2>/dev/null | grep "krb5-config"`"
1510     if test "x$SOLARIS_BROKEN_KRB5CONFIG_GSSAPI" = "x"; then
1511       LIB_KRB5_CFLAGS="`$ac_krb5_config --cflags gssapi 2>/dev/null` $LIB_KRB5_CFLAGS"
1512       LIB_KRB5_LIBS="`$ac_krb5_config --libs gssapi 2>/dev/null` $LIB_KRB5_LIBS"
1513     fi
1514   else
1515     ## For some OS pkg-config is broken or unavailable.
1516     ## Detect libraries the hard way.
1517
1518     CXXFLAGS="-I/usr/include/kerberosv5 $CXXFLAGS"
1519
1520     SQUID_STATE_SAVE([squid_solaris_save])
1521     missing_required=
1522     AC_MSG_NOTICE([Try to find Kerberos libraries in given path])
1523     AC_CHECK_LIB(krb5, [main], [LIB_KRB5_LIBS="-lkrb5 $LIB_KRB5_LIBS"],[
1524       AC_MSG_WARN([library 'krb5' is required for Solaris Kerberos])
1525         missing_required=yes
1526     ])
1527     LIBS=$LIB_KRB5_LIBS
1528     AC_CHECK_LIB(gss, [main], [LIB_KRB5_LIBS="-lgss $LIB_KRB5_LIBS"],[
1529       AC_MSG_WARN([library 'gss' is required for Solaris Kerberos])
1530         missing_required=yes
1531     ])
1532     SQUID_STATE_ROLLBACK([squid_solaris_save])
1533     if test "x$missing_required" = "xyes"; then
1534       LIB_KRB5_LIBS=""
1535     fi
1536   fi
1537
1538   if test "x$LIB_KRB5_LIBS" != "x"; then
1539     KRB5LIBS="$LIB_KRB5_PATH $LIB_KRB5_LIBS $KRB5LIBS"
1540     KRB5INCS="$LIB_KRB5_CFLAGS"
1541     AC_DEFINE(USE_SOLARIS_KRB5,1,[Solaris Kerberos support is available])
1542     KRB5_FLAVOUR="Solaris"
1543
1544     # check for other specific broken implementations
1545     CXXFLAGS="$CXXFLAGS $KRB5INCS"
1546     LIBS="$LIBS $KRB5LIBS"
1547
1548     AC_MSG_NOTICE([Try to find Kerberos headers in given path])
1549     AC_CHECK_HEADERS(gssapi/gssapi.h gssapi/gssapi_ext.h)
1550     AC_CHECK_HEADERS(krb5.h com_err.h)
1551
1552     SQUID_CHECK_KRB5_SOLARIS_BROKEN_KRB5_H
1553     if test "x$squid_cv_broken_krb5_h" = "xyes"; then
1554       AC_DEFINE(HAVE_BROKEN_SOLARIS_KRB5_H, 1, [Define to 1 if Solaris krb5.h is broken for C++])
1555       AC_MSG_WARN([You have a broken Solaris <krb5.h> system include.])
1556       AC_MSG_WARN([Please see http://bugs.opensolaris.org/bugdatabase/view_bug.do?bug_id=6837512])
1557       AC_MSG_WARN([If you need Kerberos support you will have to patch])
1558       AC_MSG_WARN([your system. See contrib/solaris/solaris-krb5-include.patch])
1559     fi
1560     SQUID_CHECK_KRB5_FUNCS
1561   fi
1562   if test "x$with_mit_krb5" = "xyes" -a "x$KRB5LIBS" = "x"; then
1563     # Error only if Solaris flavour was detected while looking for required MIT Kerberos
1564     AC_MSG_ERROR([Required Kerberos library not found])
1565   elif test "x$KRB5LIBS" = "x"; then
1566     with_solaris_krb5=no
1567     with_mit_krb5=no
1568   fi
1569   SQUID_STATE_ROLLBACK([squid_krb5_save])
1570 fi
1571
1572 dnl User may specify Heimdal Kerberos is needed from a non-standard location
1573 SQUID_AUTO_LIB(heimdal-krb5,[Heimdal Kerberos],[LIB_KRB5])
1574 AH_TEMPLATE(USE_HEIMDAL_KRB5,[Heimdal Kerberos support is available])
1575 if test "x$with_heimdal_krb5" != "xno" -a "x$KRB5LIBS" = "x"; then
1576   CXXFLAGS="$LIB_KRB5_CFLAGS $CXXFLAGS"
1577   krb5confpath="$with_heimdal_krb5/bin"
1578   # find installed libs via pkg-config or krb5-config
1579   PKG_CHECK_EXISTS(heimdal-krb5, [squid_pc_krb5_name="heimdal-krb5"])
1580   if test "x$squid_pc_krb5_name" = "x"; then
1581     PKG_CHECK_EXISTS(heimdal-gssapi, [squid_pc_krb5_name="heimdal-gssapi"])
1582   fi
1583   if test "x$squid_pc_krb5_name" = "x" -a "$cross_compiling" = "no"; then
1584     # Look for krb5-config (unless cross-compiling)
1585     AC_PATH_PROG(krb5_config,krb5-config,no,$krb5confpath)
1586     if test "x$ac_cv_path_krb5_config" != "xno" ; then
1587       krb5confpath="`dirname $ac_cv_path_krb5_config`"
1588       ac_heimdal="`$ac_cv_path_krb5_config --version 2>/dev/null | grep -c -i heimdal`"
1589       if test "x$with_heimdal_krb5" = "xyes" -a $ac_heimdal = 0; then
1590         AC_MSG_ERROR([Could not find pkg-config or krb5-config for Heimdal Kerberos])
1591       fi
1592     else
1593       if test "x$with_heimdal_krb5" = "xyes"; then
1594         AC_MSG_ERROR([Could not find krb5-config in path])
1595       else
1596         AC_MSG_WARN([Could not find krb5-config in path])
1597         with_heimdal_krb5=no
1598       fi
1599     fi
1600   fi
1601 fi
1602 if test "x$with_heimdal_krb5" != "xno" -a "x$KRB5LIBS" = "x"; then
1603   SQUID_STATE_SAVE([squid_krb5_save])
1604   LIBS="$LIBS $LIB_KRB5_PATH"
1605
1606   # auto-detect using pkg-config
1607   PKG_CHECK_MODULES([LIB_KRB5], $squid_pc_krb5_name,,[
1608     # look for krb5-config (unless cross-compiling)
1609     if test "$cross_compiling" = "no"; then
1610       if test "x$krb5confpath" = "x" ; then
1611         AC_PATH_PROG(krb5_config,krb5-config,no)
1612         if test "x$ac_cv_path_krb5_config" != "xno" ; then
1613           ac_krb5_config="$ac_cv_path_krb5_config"
1614         fi
1615       else
1616         ac_krb5_config="$krb5confpath/krb5-config"
1617       fi
1618     fi
1619     if test "x$ac_krb5_config" != "x" -a -x "$ac_krb5_config"; then
1620       # Get libs, etc
1621       AC_MSG_NOTICE([Use krb5-config to get CXXFLAGS and LIBS])
1622       LIB_KRB5_CFLAGS="`$ac_krb5_config --cflags krb5 2>/dev/null`"
1623       LIB_KRB5_LIBS="`$ac_krb5_config --libs krb5 2>/dev/null`"
1624       LIB_KRB5_CFLAGS="`$ac_krb5_config --cflags gssapi 2>/dev/null` $LIB_KRB5_CFLAGS"
1625       LIB_KRB5_LIBS="`$ac_krb5_config --libs gssapi 2>/dev/null` $LIB_KRB5_LIBS"
1626     else
1627       ## For some OS pkg-config is broken or unavailable.
1628       ## Detect libraries the hard way.
1629       SQUID_STATE_SAVE([squid_heimdal_save])
1630       missing_required=
1631       AC_MSG_NOTICE([Try to find Kerberos libraries in given path])
1632       AC_CHECK_LIB(resolv, [main], [LIB_KRB5_LIBS="-lresolv $LIB_KRB5_LIBS"],[
1633         AC_MSG_WARN([library 'resolv' is required for Heimdal Kerberos])
1634         missing_required=yes
1635       ])
1636       LIBS=$LIB_KRB5_LIBS
1637       AC_CHECK_LIB(crypt, [main], [LIB_KRB5_LIBS="-lcrypt $LIB_KRB5_LIBS"],[
1638         AC_MSG_WARN([library 'crypt' is required for Heimdal Kerberos])
1639         missing_required=yes
1640       ])
1641       LIBS=$LIB_KRB5_LIBS
1642       AC_CHECK_LIB(roken, [main], [LIB_KRB5_LIBS="-lroken $LIB_KRB5_LIBS"],[
1643         AC_MSG_WARN([library 'roken' is required for Heimdal Kerberos])
1644         missing_required=yes
1645       ])
1646       LIBS=$LIB_KRB5_LIBS
1647       AC_CHECK_LIB(heimbase, [main], [LIB_KRB5_LIBS="-lheimbase $LIB_KRB5_LIBS"],[
1648         AC_MSG_WARN([library 'heimbase' may be required for Heimdal Kerberos])
1649       ])
1650       LIBS=$LIB_KRB5_LIBS
1651       AC_CHECK_LIB(wind, [main], [LIB_KRB5_LIBS="-lwind $LIB_KRB5_LIBS"],[
1652         AC_MSG_WARN([library 'wind' may be required for Heimdal Kerberos])
1653       ])
1654       LIBS=$LIB_KRB5_LIBS
1655       AC_CHECK_LIB(crypto, [main], [LIB_KRB5_LIBS="-lcrypto $LIB_KRB5_LIBS"],[
1656         AC_MSG_WARN([library 'crypto' is required for Heimdal Kerberos])
1657         missing_required=yes
1658       ])
1659       LIBS=$LIB_KRB5_LIBS
1660       AC_CHECK_LIB(com_err, [main], [LIB_KRB5_LIBS="-lcom_err $LIB_KRB5_LIBS"],[
1661         AC_MSG_WARN([library 'com_err' is required for Heimdal Kerberos])
1662         missing_required=yes
1663       ])
1664       LIBS=$LIB_KRB5_LIBS
1665       AC_CHECK_LIB(hx509, [main], [LIB_KRB5_LIBS="-lhx509 $LIB_KRB5_LIBS"],[
1666         AC_MSG_WARN([library 'hx509' may be required for Heimdal Kerberos])
1667       ])
1668       LIBS=$LIB_KRB5_LIBS
1669       AC_CHECK_LIB(asn1, [main], [LIB_KRB5_LIBS="-lasn1 $LIB_KRB5_LIBS"],[
1670         AC_MSG_WARN([library 'asn1' is required for Heimdal Kerberos])
1671         missing_required=yes
1672       ])
1673       LIBS=$LIB_KRB5_LIBS
1674       AC_CHECK_LIB(krb5, [main], [LIB_KRB5_LIBS="-lkrb5 $LIB_KRB5_LIBS"],[
1675         AC_MSG_WARN([library 'krb5' is required for Heimdal Kerberos])
1676         missing_required=yes
1677       ])
1678       LIBS=$LIB_KRB5_LIBS
1679       AC_CHECK_LIB(heimntlm, [main], [LIB_KRB5_LIBS="-lheimntlm $LIB_KRB5_LIBS"],[
1680         AC_MSG_WARN([library 'heimntlm' may be required for Heimdal Kerberos])
1681       ])
1682       LIBS=$LIB_KRB5_LIBS
1683       AC_CHECK_LIB(gssapi, [main], [LIB_KRB5_LIBS="-lgssapi $LIB_KRB5_LIBS"],[
1684         AC_MSG_WARN([library 'gssapi' is required for Heimdal Kerberos])
1685         missing_required=yes
1686       ])
1687       SQUID_STATE_ROLLBACK([squid_heimdal_save])
1688       if test "x$missing_required" = "xyes"; then
1689         LIB_KRB5_LIBS=""
1690       fi
1691     fi
1692   ])
1693   if test "x$LIB_KRB5_LIBS" != "x"; then
1694     KRB5LIBS="$LIB_KRB5_PATH $LIB_KRB5_LIBS $KRB5LIBS"
1695     KRB5INCS="$LIB_KRB5_CFLAGS"
1696     AC_DEFINE(USE_HEIMDAL_KRB5,1,[Heimdal Kerberos support is available])
1697     KRB5_FLAVOUR="Heimdal"
1698
1699     # check for other specific broken implementations
1700     CXXFLAGS="$CXXFLAGS $KRB5INCS"
1701     LIBS="$LIBS $KRB5LIBS"
1702
1703     AC_MSG_NOTICE([Try to find Kerberos headers in given path])
1704     AC_CHECK_HEADERS(gssapi.h gssapi/gssapi.h gssapi/gssapi_krb5.h)
1705     AC_CHECK_HEADERS(krb5.h com_err.h et/com_err.h)
1706
1707     SQUID_CHECK_KRB5_HEIMDAL_BROKEN_KRB5_H
1708     if test "x$squid_cv_broken_heimdal_krb5_h" = "xyes"; then
1709       AC_DEFINE(HAVE_BROKEN_HEIMDAL_KRB5_H, 1, [Define to 1 if Heimdal krb5.h is broken for C++])
1710     fi
1711     SQUID_CHECK_KRB5_FUNCS
1712   fi
1713   if test "x$KRB5LIBS" = "x"; then
1714     if test "x$with_heimdal_krb5" = "xyes"; then
1715       AC_MSG_ERROR([Required Heimdal Kerberos library not found])
1716     else
1717       AC_MSG_WARN([Heimdal Kerberos library not found])
1718     fi
1719   fi
1720   SQUID_STATE_ROLLBACK([squid_krb5_save])
1721 fi
1722
1723 dnl User may specify GNU gss is needed from a non-standard location
1724 SQUID_AUTO_LIB(gnugss,[GNU gss],[LIB_KRB5])
1725 AH_TEMPLATE(USE_GNUGSS,[GNU gss support is available])
1726 if test "x$with_gnugss" != "xno" -a "x$KRB5LIBS" = "x"; then
1727   CXXFLAGS="$LIB_KRB5_CFLAGS $CXXFLAGS"
1728   krb5confpath=
1729   SQUID_STATE_SAVE([squid_krb5_save])
1730   LIBS="$LIBS $LIB_KRB5_PATH"
1731
1732   # auto-detect using pkg-config
1733   PKG_CHECK_MODULES([LIB_KRB5],[gss],,[
1734     ## For some OS pkg-config is broken or unavailable.
1735     ## Detect libraries the hard way.
1736
1737     AC_MSG_NOTICE([Try to find Kerberos libraries in given path])
1738     AC_CHECK_LIB(gss, [main], [LIB_KRB5_LIBS="-lgss $LIB_KRB5_LIBS"],[
1739       AC_MSG_WARN([library 'com_err' is required for GNU Kerberos])
1740     ])
1741   ])
1742
1743   if test "x$LIB_KRB5_LIBS" != "x"; then
1744     KRB5LIBS="$LIB_KRB5_PATH $LIB_KRB5_LIBS $KRB5LIBS"
1745     KRB5INCS="$LIB_KRB5_CFLAGS"
1746     AC_DEFINE(USE_GNUGSS,1,[GNU Kerberos support is available])
1747     KRB5_FLAVOUR="GNU GSS"
1748
1749     # check for other specific broken implementations
1750     CXXFLAGS="$CXXFLAGS $KRB5INCS"
1751     LIBS="$LIBS $KRB5LIBS"
1752
1753     AC_MSG_NOTICE([Try to find Kerbeors headers in given path])
1754     AC_CHECK_HEADERS(gss.h)
1755
1756     SQUID_CHECK_WORKING_GSSAPI
1757     SQUID_DEFINE_BOOL(HAVE_GSSAPI,$squid_cv_working_gssapi,[GSSAPI support])
1758
1759     SQUID_CHECK_SPNEGO_SUPPORT
1760     SQUID_DEFINE_BOOL(HAVE_SPNEGO,$squid_cv_have_spnego,[SPNEGO support])
1761
1762     SQUID_CHECK_WORKING_KRB5
1763     SQUID_DEFINE_BOOL(HAVE_KRB5,$squid_cv_working_krb5,[KRB5 support])
1764   fi
1765   if test "x$KRB5LIBS" = "x"; then
1766     if test "x$with_gnugss" = "xyes"; then
1767       AC_MSG_ERROR([Required GNU GSS Kerberos library not found])
1768     else
1769       AC_MSG_WARN([GNU GSS Kerberos library not found])
1770     fi
1771   fi
1772   SQUID_STATE_ROLLBACK([squid_krb5_save])
1773 fi
1774
1775 if test "x$KRB5LIBS" != "x"; then
1776   with_krb5=yes
1777 fi
1778 AC_MSG_NOTICE([$KRB5_FLAVOUR Kerberos library support: ${with_krb5:=no} ${LIB_KRB5_PATH} ${LIB_KRB5_LIBS}])
1779 AC_SUBST(KRB5INCS)
1780 AC_SUBST(KRB5LIBS)
1781
1782 dnl On MinGW OpenLDAP is not available, so LDAP helpers can be linked
1783 dnl only with Windows LDAP libraries using -lwldap32
1784 case "$squid_host_os" in
1785         mingw)
1786                 LDAPLIB="-lwldap32"
1787                 LBERLIB=""
1788                 ;;
1789         *)
1790                 AC_CHECK_LIB(ldap, ldap_init, [LDAPLIB="-lldap"])
1791                 dnl LDAP helpers need to know if -llber is needed or not
1792                 AC_CHECK_LIB(lber, ber_init, [LBERLIB="-llber"])
1793                 dnl if no ldap lib found check for mozilla version
1794                 if test "x$ac_cv_lib_ldap_ldap_init" != x""yes; then
1795                         oLIBS=$LIBS
1796                         LIBS="$LIBPTHREADS"
1797                         AC_CHECK_LIB(ldap60, ldap_init, [LDAPLIB="-lldap60"])
1798                         LIBS="$LDAPLIB $LIBPTHREADS"
1799                         AC_CHECK_LIB(prldap60, prldap_init, [LDAPLIB="-lprldap60 $LDAPLIB"])
1800                         LIBS="$LDAPLIB $LIBPTHREADS"
1801                         AC_CHECK_LIB(ssldap60, ldapssl_init, [LDAPLIB="-lssldap60 $LDAPLIB"])
1802                         LIBS=$oLIBS
1803                 fi
1804
1805                 AC_CHECK_HEADERS(ldap.h lber.h)
1806                 AC_CHECK_HEADERS(mozldap/ldap.h)
1807
1808                 dnl
1809                 dnl Check for LDAP_OPT_DEBUG_LEVEL
1810                 dnl
1811                 AC_MSG_CHECKING([for LDAP_OPT_DEBUG_LEVEL])
1812                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1813 #                   include <ldap.h>
1814                 ]],[[
1815                     int i=LDAP_OPT_DEBUG_LEVEL
1816                 ]])],
1817                 [ AC_MSG_RESULT(yes) ],
1818                 [ AC_MSG_RESULT(no) ])
1819
1820                 dnl
1821                 dnl Check for working ldap
1822                 dnl
1823                 oLIBS=$LIBS
1824                 LIBS="$LDAPLIB $LBERLIB $LIBPTHREADS"
1825                 AC_MSG_CHECKING([for working ldap])
1826                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1827 #                   define  LDAP_DEPRECATED 1
1828 #                   if HAVE_LDAP_H
1829 #                   include <ldap.h>
1830 #                   elif HAVE_MOZLDAP_LDAP_H
1831 #                   include <mozldap/ldap.h>
1832 #                   endif
1833                     int
1834                     main(void)
1835                     {
1836                         char host[]="";
1837                         int port;
1838
1839                         ldap_init((const char *)&host, port);
1840
1841                         return 0;
1842                     }
1843                 ]])],
1844                 [ AC_DEFINE(HAVE_LDAP, 1, [LDAP support])
1845                   AC_MSG_RESULT(yes) ],
1846                 [ AC_MSG_RESULT(no) ],
1847                 [ AC_MSG_RESULT(cross-compiler cant tell) ])
1848                 LIBS=$oLIBS
1849
1850                 dnl
1851                 dnl Check for ldap vendor
1852                 dnl
1853                 AC_MSG_CHECKING([for OpenLDAP])
1854                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1855 #                   if HAVE_LDAP_H
1856 #                   include <ldap.h>
1857 #                   endif
1858 #                   include <string.h>
1859                     int
1860                     main(void)
1861                     {
1862                         return strcmp(LDAP_VENDOR_NAME,"OpenLDAP");
1863                     }
1864                 ]])],
1865                 [ AC_DEFINE(HAVE_OPENLDAP, 1, [OpenLDAP support])
1866                   AC_MSG_RESULT(yes) ],
1867                 [ AC_MSG_RESULT(no) ],
1868                 [ AC_MSG_RESULT(cross-compiler cant tell) ])
1869
1870                 AC_MSG_CHECKING([for Sun LDAP SDK])
1871                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1872 #                   if HAVE_LDAP_H
1873 #                   include <ldap.h>
1874 #                   endif
1875 #                   include <string.h>
1876                     int
1877                     main(void)
1878                     {
1879                         return strcmp(LDAP_VENDOR_NAME,"Sun Microsystems Inc.");
1880                     }
1881                 ]])],
1882                 [ AC_DEFINE(HAVE_SUN_LDAP_SDK, 1, [Sun LDAP SDK support])
1883                   AC_MSG_RESULT(yes) ],
1884                 [ AC_MSG_RESULT(no) ],
1885                 [ AC_MSG_RESULT(cross-compiler cant tell) ])
1886
1887                 AC_MSG_CHECKING([for Mozilla LDAP SDK])
1888                 AC_RUN_IFELSE([AC_LANG_SOURCE([[
1889 #                   if HAVE_LDAP_H
1890 #                   include <ldap.h>
1891 #                   elif HAVE_MOZLDAP_LDAP_H
1892 #                   include <mozldap/ldap.h>
1893 #                   endif
1894 #                   include <string.h>
1895                     int
1896                     main(void)
1897                     {
1898                         return strcmp(LDAP_VENDOR_NAME,"mozilla.org");
1899                     }
1900                 ]])],
1901                 [ AC_DEFINE(HAVE_MOZILLA_LDAP_SDK, 1, [Mozilla LDAP SDK support])
1902                   AC_MSG_RESULT(yes) ],
1903                 [ AC_MSG_RESULT(no)],
1904                 [ AC_MSG_RESULT(cross-compiler cant tell) ])
1905
1906                 dnl
1907                 dnl Check for LDAP_REBINDPROC_CALLBACK
1908                 dnl
1909                 AC_MSG_CHECKING([for LDAP_REBINDPROC_CALLBACK])
1910                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1911 #                   if HAVE_LDAP_H
1912 #                   include <ldap.h>
1913 #                   elif HAVE_MOZLDAP_LDAP_H
1914 #                   include <mozldap/ldap.h>
1915 #                   endif
1916                 ]],[[
1917                     LDAP_REBINDPROC_CALLBACK ldap_rebind;
1918                 ]])],
1919                 [ AC_DEFINE(HAVE_LDAP_REBINDPROC_CALLBACK,1,[Define to 1 if you have LDAP_REBINDPROC_CALLBACK])
1920                   AC_MSG_RESULT(yes) ],
1921                 [ AC_MSG_RESULT(no) ])
1922
1923                 dnl
1924                 dnl Check for LDAP_REBIND_PROC
1925                 dnl
1926                 AC_MSG_CHECKING([for LDAP_REBIND_PROC])
1927                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1928 #                   if HAVE_LDAP_H
1929 #                   include <ldap.h>
1930 #                   elif HAVE_MOZLDAP_LDAP_H
1931 #                   include <mozldap/ldap.h>
1932 #                   endif
1933                 ]],[[
1934                     LDAP_REBIND_PROC ldap_rebind;
1935                 ]])],
1936                 [ AC_DEFINE(HAVE_LDAP_REBIND_PROC,1,[Define to 1 if you have LDAP_REBIND_PROC])
1937                   AC_MSG_RESULT(yes) ],
1938                 [ AC_MSG_RESULT(no) ])
1939
1940                 dnl
1941                 dnl Check for LDAP_REBIND_FUNCTION
1942                 dnl
1943                 AC_MSG_CHECKING([for LDAP_REBIND_FUNCTION])
1944                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1945 #                   define LDAP_REFERRALS
1946 #                   if HAVE_LDAP_H
1947 #                   include <ldap.h>
1948 #                   elif HAVE_MOZLDAP_LDAP_H
1949 #                   include <mozldap/ldap.h>
1950 #                   endif
1951                 ]],[[
1952                     LDAP_REBIND_FUNCTION ldap_rebind;
1953                 ]])],
1954                 [ AC_DEFINE(HAVE_LDAP_REBIND_FUNCTION,1,[Define to 1 if you have LDAP_REBIND_FUNCTION])
1955                   AC_MSG_RESULT(yes) ],
1956                 [ AC_MSG_RESULT(no) ])
1957
1958                 dnl
1959                 dnl Check for LDAP_SCOPE_DEFAULT
1960                 dnl
1961                 AC_MSG_CHECKING([for LDAP_SCOPE_DEFAULT])
1962                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1963 #                   if HAVE_LDAP_H
1964 #                   include <ldap.h>
1965 #                   elif HAVE_MOZLDAP_LDAP_H
1966 #                   include <mozldap/ldap.h>
1967 #                   endif
1968                 ]],[[
1969                     int i=LDAP_SCOPE_DEFAULT;
1970                 ]])],
1971                 [ AC_DEFINE(HAVE_LDAP_SCOPE_DEFAULT,1,[Define to 1 if you have LDAP_SCOPE_DEFAULT])
1972                   AC_MSG_RESULT(yes) ],
1973                 [ AC_MSG_RESULT(no) ])
1974
1975                 dnl
1976                 dnl Check for ldap_url_desc.lud_scheme
1977                 dnl
1978                 AC_CHECK_MEMBER(struct ldap_url_desc.lud_scheme,
1979                   AC_DEFINE(HAVE_LDAP_URL_LUD_SCHEME,1,
1980                     [Define to 1 if you have LDAPURLDesc.lud_scheme]),,[#include <ldap.h>])
1981
1982                 dnl
1983                 dnl Check for ldapssl_client_init
1984                 dnl
1985                 AC_CHECK_LIB(ldap,ldapssl_client_init,
1986                   AC_DEFINE(HAVE_LDAPSSL_CLIENT_INIT,1,[Define to 1 if you have ldapssl_client_init]),)
1987
1988                 dnl
1989                 dnl Check for ldap_url_desc2str
1990                 dnl
1991                 AC_CHECK_LIB(ldap,ldap_url_desc2str,
1992                   AC_DEFINE(HAVE_LDAP_URL_DESC2STR,1,[Define to 1 if you have ldap_url_desc2str]),)
1993
1994                 dnl
1995                 dnl Check for ldap_url_parse
1996                 dnl
1997                 AC_CHECK_LIB(ldap,ldap_url_parse,
1998                   AC_DEFINE(HAVE_LDAP_URL_PARSE,1,[Define to 1 if you have ldap_url_parse]),)
1999
2000                 dnl
2001                 dnl Check for ldap_start_tls_s
2002                 dnl
2003                 AC_CHECK_LIB(ldap,ldap_start_tls_s,
2004                   AC_DEFINE(HAVE_LDAP_START_TLS_S,1,[Define to 1 if you have ldap_start_tls_s]),)
2005                 ;;
2006 esac
2007
2008 AC_SUBST(LDAPLIB)
2009 AC_SUBST(LBERLIB)
2010
2011 SQUID_AUTO_LIB(systemd,[systemd API for start-up notification],[SYSTEMD])
2012 AH_TEMPLATE(USE_SYSTEMD,[systemd support is available])
2013 if test "x$with_systemd" != "xno" -a "x$squid_host_os" = "xlinux"; then
2014   SQUID_STATE_SAVE(squid_systemd_state)
2015
2016   # User may have provided a custom location for systemd. Otherwise...
2017   LIBS="$LIBS $SYSTEMD_PATH"
2018
2019   # auto-detect using pkg-config
2020   PKG_CHECK_MODULES(SYSTEMD,[libsystemd],,[
2021     # systemd < 209
2022     PKG_CHECK_MODULES(SYSTEMD,[libsystemd-daemon],,[:])
2023   ])
2024
2025   AC_CHECK_HEADERS(systemd/sd-daemon.h)
2026
2027   SQUID_STATE_ROLLBACK(squid_systemd_state) #de-pollute LIBS
2028
2029   if test "x$with_systemd" = "xyes" -a "x$SYSTEMD_LIBS" = "x"; then
2030     AC_MSG_ERROR([Required systemd library not found])
2031   fi
2032   if test "x$SYSTEMD_LIBS" != "x" ; then
2033     CXXFLAGS="$SYSTEMD_CFLAGS $CXXFLAGS"
2034     LDFLAGS="$SYSTEMD_PATH $SYSTEMD_LIBS $LDFLAGS"
2035     AC_DEFINE(USE_SYSTEMD,1,[systemd support is available])
2036   else
2037     with_systemd=no
2038   fi
2039 fi
2040 AC_MSG_NOTICE([systemd library support: ${with_systemd:=auto} ${SYSTEMD_PATH} ${SYSTEMD_LIBS}])
2041
2042 AC_ARG_ENABLE(forw-via-db,
2043   AS_HELP_STRING([--enable-forw-via-db],[Enable Forw/Via database]), [
2044   SQUID_YESNO([$enableval],[unrecognized argument to --enable-forw-via-db: $enableval])
2045 ])
2046 SQUID_DEFINE_BOOL(USE_FORW_VIA_DB,${enable_forw_via_db:=no},
2047                       [Enable Forw/Via database])
2048 AC_MSG_NOTICE([Forw/Via database enabled: $enable_forw_via_db])
2049
2050 AC_ARG_ENABLE(cache-digests,
2051   AS_HELP_STRING([--enable-cache-digests],
2052    [Use Cache Digests. See http://wiki.squid-cache.org/SquidFaq/CacheDigests]),
2053 [
2054  SQUID_YESNO($enableval,
2055    [unrecognized argument to --enable-cache-digests: $enableval])
2056 ])
2057 SQUID_DEFINE_BOOL(USE_CACHE_DIGESTS,${enable_cache_digests:=no},
2058   [Use Cache Digests for locating objects in neighbor caches.])
2059 AC_MSG_NOTICE([Cache Digests enabled: $enable_cache_digests])
2060
2061
2062 ################################
2063 # check for netio plugin stuff #
2064 ################################
2065 dnl order of these options handling is relevant in case the user
2066 dnl supplies more than one --enable option. Options handled later
2067 dnl override those handled earlier for io loop method manual override
2068 AC_ARG_ENABLE(select,
2069   AS_HELP_STRING([--disable-select],[Disable select(2) support.]),
2070 [
2071 SQUID_YESNO($enableval,[--disable-select takes no extra argument])
2072 if test "x$enableval" = "xyes"; then
2073   if test "x$squid_host_os" = "xmingw"; then
2074     squid_opt_io_loop_engine="select_win32"
2075   else
2076     squid_opt_io_loop_engine="select"
2077   fi
2078 fi
2079 ])
2080 AC_MSG_NOTICE([enabling select syscall for net I/O: ${enable_select:=auto}])
2081
2082 AC_ARG_ENABLE(poll,
2083   AS_HELP_STRING([--disable-poll],[Disable poll(2) support.]),
2084 [
2085 SQUID_YESNO($enableval,[--disable-poll takes no extra argument])
2086 test "x$enableval" = "xyes" && squid_opt_io_loop_engine="poll"
2087 ])
2088 AC_MSG_NOTICE([enabling poll syscall for net I/O: ${enable_poll:=auto}])
2089
2090 AC_ARG_ENABLE(kqueue,
2091   AS_HELP_STRING([--disable-kqueue],
2092                  [Disable kqueue(2) support.]), [
2093 SQUID_YESNO($enableval,[--enable-kqueue takes no extra argument])
2094 ])
2095 if test "x${enable_kqueue:=auto}" != "xno" ; then
2096   AC_CHECK_HEADERS([sys/event.h],[],[
2097     if test "x${enable_kqueue}" = "xyes" ; then
2098       AC_MSG_ERROR([kqueue support requires sys/event.h header file.])
2099     fi
2100   ])
2101   AC_CHECK_FUNCS(kqueue,[],[
2102     if test "x${enable_kqueue}" = "xyes" ; then
2103       AC_MSG_ERROR([kqueue support missing in libc library.])
2104     fi
2105   ])
2106   if test "x$ac_cv_func_kqueue" = "xyes" -a "x$ac_cv_header_sys_event_h" = "xyes" ; then
2107     squid_opt_io_loop_engine="kqueue"
2108   else
2109     enable_kqueue="no"
2110   fi
2111 fi
2112 AC_MSG_NOTICE([enabling kqueue for net I/O: ${enable_kqueue:=auto}])
2113
2114 dnl Enable epoll()
2115 AC_ARG_ENABLE(epoll,
2116   AS_HELP_STRING([--disable-epoll],[Disable Linux epoll(2) support.]),
2117 [
2118 SQUID_YESNO($enableval,[--disable-epoll takes no extra argument])
2119 test "x$enableval" = "xyes" && squid_opt_io_loop_engine="epoll"
2120 ])
2121 AC_MSG_NOTICE([enabling epoll syscall for net I/O: ${enable_epoll:=auto}])
2122
2123 # auto-detect and verify epoll header and library present and working
2124 # logic mapping and loop method selection are performed later
2125 if test "x$enable_epoll" != "xno" ; then
2126
2127   # check if libs are needed to support epoll
2128   # note: this code block seems quite generic. Could it be extracted
2129   #   into a squid specific configure function?
2130   SQUID_STATE_SAVE(squid_epoll_state)
2131   AC_SEARCH_LIBS(epoll_ctl,[epoll])
2132   if test "x$ac_cv_search_epoll_ctl" = "xno" ; then
2133     enable_epoll=no #disable. Needed code not found
2134   elif test "x$ac_cv_search_epoll_ctl" = "xnone required" ; then
2135     EPOLL_LIBS=""
2136   else
2137     EPOLL_LIBS=$ac_cv_search_epoll_ctl
2138   fi
2139   AC_SUBST(EPOLL_LIBS)
2140   SQUID_STATE_ROLLBACK(squid_epoll_state) #de-pollute LIBS
2141
2142   # epoll requires sys/epoll.h
2143   AC_CHECK_HEADERS([sys/epoll.h])
2144
2145   dnl Verify that epoll really works
2146   if test "x$ac_cv_search_epoll_ctl" != 'xno' ; then
2147     SQUID_CHECK_EPOLL
2148   fi
2149
2150   if test "x$enable_epoll" = "xyes" -a "x$squid_cv_epoll_works" = "xno" ; then
2151     AC_MSG_ERROR([Epoll does not work. Force-enabling it is not going to help.])
2152   fi
2153 fi
2154
2155 dnl Enable /dev/poll
2156 AC_ARG_ENABLE(devpoll,
2157   AS_HELP_STRING([--disable-devpoll],[Disable Solaris /dev/poll support.]),
2158 [
2159 SQUID_YESNO($enableval,[--disable-devpoll takes no extra argument])
2160 test "x$enableval" = "xyes" && squid_opt_io_loop_engine="devpoll"
2161 ])
2162 AC_MSG_NOTICE([enabling /dev/poll for net I/O: ${enable_devpoll:=auto}])
2163
2164 ## auto-detect and verify devpoll header and library present and working
2165 if test "x$enable_devpoll" != "xno"; then
2166
2167   # /dev/poll requires ioctl() and write()
2168   AC_CHECK_FUNCS(ioctl)
2169   AC_CHECK_FUNCS(write)
2170
2171   # /dev/poll requires sys/devpoll.h
2172   AC_CHECK_HEADERS([sys/devpoll.h],,[
2173         if test "x$enable_devpoll" = "xyes"; then
2174             AC_MSG_ERROR([--enable-devpoll specified but /dev/poll headers not found])
2175         fi
2176         enable_devpoll=no])
2177
2178   # Verify that /dev/poll really works
2179   if test "x$enable_devpoll" != 'xno' ; then
2180     SQUID_CHECK_DEVPOLL
2181   fi
2182
2183   if test "x$enable_devpoll" = "xyes" -a "x$squid_cv_devpoll_works" = "xno" ; then
2184     AC_MSG_ERROR([/dev/poll does not work. Force-enabling it is not going to help.])
2185   fi
2186 fi
2187
2188
2189 AC_ARG_ENABLE(http-violations,
2190   AS_HELP_STRING([--disable-http-violations],
2191                  [This allows you to remove code which is known to
2192                   violate the HTTP protocol specification.]), [
2193   SQUID_YESNO([$enableval],
2194          [unrecognized argument to --disable-http-violations: $enableval])
2195 ])
2196 SQUID_DEFINE_BOOL(USE_HTTP_VIOLATIONS, ${enable_http_violations:=yes},
2197   [Define to enable code which volates the HTTP standard specification])
2198 AC_MSG_NOTICE([HTTP violations support enabled: $enable_http_violations])
2199
2200 # IPFW Transparent Proxy
2201 AC_ARG_ENABLE(ipfw-transparent,
2202   AS_HELP_STRING([--enable-ipfw-transparent],
2203                  [Enable Transparent Proxy support for systems
2204                   using FreeBSD IPFW-style firewalling.]), [
2205   SQUID_YESNO([$enableval],
2206       [unrecognized argument to --enable-ipfw-transparent: $enableval])
2207 ])
2208 SQUID_DEFINE_BOOL(IPFW_TRANSPARENT,${enable_ipfw_transparent:=no},
2209   [Enable support for Transparent Proxy on systems using FreeBSD IPFW-style firewalling.])
2210 AC_MSG_NOTICE([FreeBSD IPFW-based transparent proxying enabled: $enable_ipfw_transparent])
2211
2212 # IP-Filter Transparent Proxy
2213 AC_ARG_ENABLE(ipf-transparent,
2214   AS_HELP_STRING([--enable-ipf-transparent],
2215      [Enable Transparent Proxy support using IPFilter-style firewalling]), [
2216   SQUID_YESNO([$enableval],
2217       [unrecognized argument to --enable-ipf-transparent: $enableval])
2218 ])
2219 #will be AC_DEFINEd later, after checking for appropriate infrastructure
2220 #IPF currently broken. Default-disabled for now.
2221 AC_MSG_NOTICE([IPF-based transparent proxying requested: ${enable_ipf_transparent:=no}])
2222
2223 dnl Enable PF Transparent Proxy
2224 AC_ARG_ENABLE(pf-transparent,
2225   AS_HELP_STRING([--enable-pf-transparent],
2226     [Enable Transparent Proxy support for systems using PF network address redirection.]), [
2227   SQUID_YESNO([$enableval],
2228               [unrecognized argument to --enable-pf-transparent: $enableval])
2229 ])
2230 #will be AC_DEFINEd later, after checking for appropriate infrastructure
2231 AC_MSG_NOTICE([PF-based transparent proxying requested: ${enable_pf_transparent:=no}])
2232
2233 dnl Enable /dev/pf support for older PF Transparent Proxy systems (OpenBSD 4.x and older)
2234 AC_ARG_WITH(nat-devpf,
2235   AS_HELP_STRING([--with-nat-devpf],
2236     [Enable /dev/pf support for NAT on older OpenBSD and FreeBSD kernels.]), [
2237   SQUID_YESNO([$enableval],
2238               [unrecognized argument to --with-nat-devpf: $enableval])
2239 ])
2240 #will be AC_DEFINEd later, after checking for appropriate infrastructure
2241 AC_MSG_NOTICE([NAT lookups via /dev/pf: ${with_nat_devpf:=no}])
2242
2243 # Linux Netfilter Transparent Proxy
2244 AC_ARG_ENABLE(linux-netfilter,
2245   AS_HELP_STRING([--enable-linux-netfilter],
2246                  [Enable Transparent Proxy support for Linux (Netfilter)]), [
2247   SQUID_YESNO([$enableval],
2248               [unrecognized argument to --enable-linux-netfilter: $enableval])
2249 ])
2250 AC_MSG_NOTICE([Linux Netfilter support requested: ${enable_linux_netfilter:=auto}])
2251 #will be AC_DEFINEd later, after checking for appropriate infrastructure
2252
2253
2254 dnl Look for libnetfilter_conntrack options (needed for QOS netfilter marking)
2255 SQUID_AUTO_LIB(netfilter-conntrack,[Netfilter conntrack],[LIBNETFILTER_CONNTRACK])
2256 AC_MSG_NOTICE([Linux Netfilter Conntrack support requested: ${with_netfilter_conntrack:=auto}])
2257 if test "x$with_netfilter_conntrack" != "xno"; then
2258     LDFLAGS="$LIBNETFILTER_CONNTRACK_PATH $LDFLAGS"
2259     CPPFLAGS="$LIBNETFILTER_CONNTRACK_CFLAGS $CPPFLAGS"
2260     AC_SEARCH_LIBS([nfct_query], [netfilter_conntrack],,[
2261         if test x"$with_netfilter_conntrack" = "xyes"; then
2262             AC_MSG_ERROR([--with-netfilter-conntrack specified but libnetfilter-conntrack library not found])
2263         fi
2264         with_netfilter_conntrack=no])
2265     AC_CHECK_HEADERS([libnetfilter_conntrack/libnetfilter_conntrack.h \
2266         libnetfilter_conntrack/libnetfilter_conntrack_tcp.h],,[
2267         if test x"$with_netfilter_conntrack" = "xyes"; then
2268             AC_MSG_ERROR([--with-netfilter-conntrack specified but libnetfilter-conntrack headers not found])
2269         fi
2270         with_netfilter_conntrack=no])
2271   # If nothing is broken; enable the libraries usage.
2272   if test "x$with_netfilter_conntrack" != "xno"; then
2273     with_netfilter_conntrack=yes
2274   fi
2275 fi
2276
2277
2278 dnl Enable Large file support
2279 buildmodel=""
2280 squid_opt_enable_large_files=no
2281
2282 AC_ARG_WITH(large-files,
2283   AS_HELP_STRING([--with-large-files],[Enable support for large files (logs etc).]), [
2284   if test "x$withval" = "xyes"; then
2285     squid_opt_enable_large_files=yes
2286   fi
2287 ])
2288
2289 dnl UNIX Build environment
2290 dnl AS_HELP_STRING is not suited here because it cannot to specify newlines
2291 AC_ARG_WITH(build-environment,
2292  AS_HELP_STRING([--with-build-environment=model],
2293      [The build environment to use. Normally one of
2294       POSIX_V6_ILP32_OFF32 (32 bits),
2295       POSIX_V6_ILP32_OFFBIG (32 bits with large file support),
2296       POSIX_V6_LP64_OFF64 (64 bits),
2297       POSIX_V6_LPBIG_OFFBIG (large pointers and files),
2298       XBS5_ILP32_OFF32 i(legacy, 32 bits),
2299       XBS5_ILP32_OFFBIG (legacy, 32 bits with large file support),
2300       XBS5_LP64_OFF64 (legacy, 64 bits),
2301       XBS5_LPBIG_OFFBIG (legacy, large pointers and files)
2302       or default (The default for your OS)]), [
2303 case "$withval" in
2304   yes|no)
2305     AC_MSG_FAILURE([--with-build-environment expects a build environment string as used by getconf])
2306     ;;
2307   *)
2308     buildmodel="$withval"
2309     ;;
2310 esac
2311 ])
2312
2313 #hack. Let's early-detect sizeof(long)
2314 AC_CHECK_SIZEOF(long)
2315
2316 if test "x$squid_opt_enable_large_files" = "xyes" -a "x$buildmodel" = "x"; then
2317   for model in POSIX_V6_LPBIG_OFFBIG XBS5_LPBIG_OFFBIG POSIX_V6_LP64_OFF64 XBS5_LP64_OFF64 POSIX_V6_ILP32_OFFBIG XBS5_ILP32_OFFBIG; do
2318     if test "`getconf _$model 2>/dev/null || true`" = 1 || test "`getconf $model 2>/dev/null || true`" ; then
2319       buildmodel=$model
2320       break
2321     fi
2322   done
2323   if test "x$buildmodel" = "x"; then
2324     AC_MSG_WARN([No suitable build environment found for large files. Trying to use _FILE_OFFSET_BITS=64])
2325   fi
2326 fi
2327 if test "x$buildmodel" = "xdefault" -o "x$buildmodel" = "x"; then
2328   # define _FILE_OFFSET_BITS if requested and needed
2329   if test "x$squid_opt_enable_large_files" = "xyes" -a $ac_cv_sizeof_long -le 4 ; then
2330     AC_MSG_NOTICE([Enabling -D_FILE_OFFSET_BITS=64])
2331     CFLAGS="-D_FILE_OFFSET_BITS=64 $CFLAGS"
2332     CXXFLAGS="-D_FILE_OFFSET_BITS=64 $CXXFLAGS"
2333   fi
2334 else
2335   AC_MSG_NOTICE([Using $buildmodel build environment])
2336   if test "`getconf _$buildmodel 2>/dev/null || true`" = 1 || test "`getconf $buildmodel 2>/dev/null || true`" ; then
2337     : # All fine
2338   else
2339     AC_MSG_ERROR(Build environment $buildmodel not known to getconf.)
2340   fi
2341   CFLAGS="`getconf ${buildmodel}_CFLAGS` $CFLAGS"
2342   CXXFLAGS="`getconf ${buildmodel}_CFLAGS` $CXXFLAGS"
2343   LIBS="`getconf ${buildmodel}_LIBS` $LIBS"
2344   LDFLAGS="`getconf ${buildmodel}_LDFLAGS` $LDFLAGS"
2345   if test "x$squid_host_os" = "xsolaris" ; then
2346
2347 # On Solaris getconf returns for CFLAGS -xarch=generic64, -Xa and -Usun options, and
2348 # for LDFLAGS -xarch=generic64, but:
2349 #   "-Xa" is supported only by Sun cc, so we need to remove it when using gcc
2350 #   For gcc "-xarch=generic64" must be replaced with "-m64"
2351 #   The 'sun' define is needed by ipfilter includes, so we must remove "-Usun"
2352     if test "x$GCC" = "xyes"; then
2353       AC_MSG_NOTICE([Removing -Xa for gcc/g++ on $host])
2354       CFLAGS="`echo $CFLAGS | sed -e 's/-Xa//'`"
2355       CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-Xa//'`"
2356       AC_MSG_NOTICE([Replacing -xarch=generic64 with -m64 for gcc/g++ on $host])
2357       CFLAGS="`echo $CFLAGS | sed -e 's/-xarch=generic64/-m64/'`"
2358       CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-xarch=generic64/-m64/'`"
2359       LDFLAGS="`echo $LDFLAGS | sed -e 's/-xarch=generic64//'`"
2360     fi
2361     AC_MSG_NOTICE([Removing -Usun on $host])
2362     CFLAGS="`echo $CFLAGS | sed -e 's/-Usun//'`"
2363     CXXFLAGS="`echo $CXXFLAGS | sed -e 's/-Usun//'`"
2364   fi
2365 fi
2366
2367 dnl Enable Leak Finding Functions
2368 AC_ARG_ENABLE(leakfinder,
2369   AS_HELP_STRING([--enable-leakfinder],
2370     [Enable Leak Finding code. Enabling this alone does nothing;
2371      you also have to modify the source code to use the leak
2372      finding functions. Probably Useful for hackers only.]), [
2373   SQUID_YESNO([$enableval],
2374      [unrecognized argument to --enable-leakfinder: $enableval])
2375 ])
2376 AC_MSG_NOTICE([Leak Finder enabled: ${enable_leakfinder:=no}])
2377 SQUID_DEFINE_BOOL(USE_LEAKFINDER,$enable_leakfinder,
2378   [Enable code for assisting in finding memory leaks. Not for the faint of heart])
2379 AM_CONDITIONAL(ENABLE_LEAKFINDER, [test "x$enable_leakfinder" = "xyes"])
2380
2381
2382 AC_ARG_ENABLE(follow-x-forwarded-for,
2383   AS_HELP_STRING([--enable-follow-x-forwarded-for],
2384                  [Enable support for following the X-Forwarded-For
2385                  HTTP header to try to find the IP address of the
2386                  original or indirect client when a request has
2387                  been forwarded through other proxies.]), [
2388   SQUID_YESNO([$enableval],
2389     [unrecognized argument to --enable-follow-x-forwarded-for: $enableval])
2390 ])
2391 AC_MSG_NOTICE([Support for X-Forwarded-For enabled: ${enable_follow_x_forwarded_for:=yes}])
2392 SQUID_DEFINE_BOOL(FOLLOW_X_FORWARDED_FOR,$enable_follow_x_forwarded_for,
2393   [Enable following X-Forwarded-For headers])
2394
2395 AC_ARG_ENABLE(ident-lookups,
2396   AS_HELP_STRING([--disable-ident-lookups],
2397                  [Remove code that supports performing Ident (RFC 931) lookups.]), [
2398   SQUID_YESNO([$enableval],[unrecognized argument to --disable-ident-lookups: $enableval])
2399 ])
2400 AC_MSG_NOTICE([Support for Ident lookups enabled: ${enable_ident_lookups:=yes}])
2401 SQUID_DEFINE_BOOL(USE_IDENT,$enable_ident_lookups,[Support for Ident (RFC 931) lookups])
2402
2403 dnl Select Default hosts file location
2404 AC_ARG_ENABLE(default-hostsfile,
2405   AS_HELP_STRING([--enable-default-hostsfile=path],
2406                  [Select default location for hosts file.
2407                   See hosts_file directive in squid.conf for details]), [
2408 if test "x$enableval" != "xnone" -a "x$enableval" != "xno" ; then
2409   if test \! -f "$enableval"; then
2410     AC_MSG_WARN([Unable to find file $enableval. I hope you know what you are doing.])
2411   fi
2412   squid_opt_default_hosts=$enableval
2413 else
2414   squid_opt_default_hosts="none"
2415 fi
2416 ])
2417 AC_MSG_NOTICE([Default hosts file set to: ${squid_opt_default_hosts:=/etc/hosts}])
2418 DEFAULT_HOSTS=$squid_opt_default_hosts
2419 AC_SUBST(DEFAULT_HOSTS)
2420
2421 # Select auth schemes modules to build
2422 AC_ARG_ENABLE(auth,
2423   AS_HELP_STRING([--enable-auth],
2424                  [Build global support for authentication. The list of schemes
2425                   and helpers to be enabled is defined elsewhere]), [
2426 SQUID_YESNO([$enableval],
2427             [unrecognized argument to --enable-auth: $enableval])
2428 ])
2429 AC_MSG_NOTICE([Authentication support enabled: ${enable_auth:=yes}])
2430 SQUID_DEFINE_BOOL(USE_AUTH,$enable_auth,[Enable support for authentication])
2431 AM_CONDITIONAL(ENABLE_AUTH, test "x$enable_auth" != "xno")
2432 AUTH_MODULES=""
2433 require_smblib="no"
2434
2435 AC_ARG_ENABLE(auth-basic,
2436   AS_HELP_STRING([--enable-auth-basic="list of helpers"],
2437      [Enable the basic authentication scheme, and build the specified helpers.
2438       Not providing an explicit list of helpers will attempt build of
2439       all possible helpers. Default is to do so.
2440       To disable the basic authentication scheme, use --disable-auth-basic.
2441       To enable but build no helpers, specify "none".
2442       To see available helpers, see the src/auth/basic/ directory. ]),[
2443 #nothing to do really
2444 ])
2445 m4_include([src/auth/basic/helpers.m4])
2446
2447 AC_ARG_ENABLE(auth-digest,
2448   AS_HELP_STRING([--enable-auth-digest="list of helpers"],
2449      [Enable the Digest authentication scheme, and build the specified helpers.
2450       Not providing an explicit list of helpers will attempt build of
2451       all possible helpers. Default is to do so.
2452       To disable the Digest authentication scheme, use --disable-auth-digest.
2453       To enable but build no helpers, specify "none".
2454       To see available helpers, see the src/auth/digest/ directory. ]),[
2455 #nothing to do, really
2456 ])
2457 m4_include([src/auth/digest/helpers.m4])
2458
2459 AC_ARG_ENABLE(auth-negotiate,
2460   AS_HELP_STRING([--enable-auth-negotiate="list of helpers"],
2461      [Enable the Negotiate authentication scheme, and build the specified
2462       helpers.
2463       Not providing an explicit list of helpers will attempt build of
2464       all possible helpers. Default is to do so.
2465       To disable the Negotiate authentication scheme,
2466       use --disable-auth-negotiate.
2467       To enable but build no helpers, specify "none".
2468       To see available helpers, see the src/auth/negotiate/ directory. ]),[
2469 #nothing to do, really
2470 ])
2471 m4_include([src/auth/negotiate/helpers.m4])
2472
2473 AC_ARG_ENABLE(auth-ntlm,
2474   AS_HELP_STRING([--enable-auth-ntlm="list of helpers"],
2475      [Enable the NTLM authentication scheme, and build the specified helpers.
2476       Not providing an explicit list of helpers will attempt build of
2477       all possible helpers. Default is to do so.
2478       To disable the NTLM authentication scheme, use --disable-auth-ntlm.
2479       To enable but build no helpers, specify "none".
2480       To see available helpers, see the src/auth/ntlm/ directory. ]),[
2481 ])
2482 m4_include([src/auth/ntlm/helpers.m4])
2483
2484 dnl Authentication libraries to build
2485 dnl This list will not be needed when each auth library has its own Makefile
2486 dnl this is to be placed AFTER each auth module's handler
2487 AUTH_LIBS_TO_BUILD=
2488 for module in $AUTH_MODULES; do
2489     AUTH_LIBS_TO_BUILD="$AUTH_LIBS_TO_BUILD ${module}/lib${module}.la"
2490 done
2491 AC_SUBST(AUTH_MODULES)
2492 AC_SUBST(AUTH_LIBS_TO_BUILD)
2493 AM_CONDITIONAL(ENABLE_SMBLIB, test "x$require_smblib" = "xyes")
2494
2495 dnl Select logging daemon helpers to build
2496 AC_ARG_ENABLE(log-daemon-helpers,
2497   AS_HELP_STRING([--enable-log-daemon-helpers="list of helpers"],
2498                  [This option selects which logging daemon helpers to
2499                   build and install as part of the normal build process
2500                   For a list of available helpers see the src/log/
2501                   directory.]),[
2502 #nothing to do, really
2503 ])
2504 m4_include([src/log/helpers.m4])
2505
2506 AC_ARG_ENABLE(external-acl-helpers,
2507   AS_HELP_STRING([--enable-external-acl-helpers="list of helpers"],
2508                  [Enable external_acl helpers support and the helpers themselves.
2509                   Default is to build all buildable helpers and enable support.
2510                   To disable support, use --disable-external-acl-helpers.
2511                   To build no helpers, specify "none".
2512                   To see available helpers, see the src/acl/external/
2513                   directory]), [
2514 #nothing to do, really
2515 ])
2516 m4_include([src/acl/external/helpers.m4])
2517
2518 dnl Select url_rewrite helpers to build
2519 AC_ARG_ENABLE(url-rewrite-helpers,
2520   AS_HELP_STRING([--enable-url-rewrite-helpers="list of helpers"],
2521                  [This option selects which url_rewrite helpers to
2522                   build and install as part of the normal build
2523                   process. The default is to attempt the build of all possible
2524                   helpers. Use --disable-url-rewrite-helpers to build none.
2525                   For a list of available helpers see the
2526                   src/http/url_rewriters/ directory.]),[
2527 ])
2528 m4_include([src/http/url_rewriters/helpers.m4])
2529
2530 dnl Select security helpers to build
2531 AC_ARG_ENABLE(security-cert-validators,
2532   AS_HELP_STRING([--enable-security-cert-validators="list of helpers"],
2533                  [This option selects which security certificate validator
2534                   helpers to build and install as part of the normal build
2535                   process. The default is to attempt the build of all possible
2536                   helpers. Use --disable-security-cert-validators to
2537                   build none. For a list of available helpers see the
2538                   src/security/cert_validators/ directory.]),[
2539 ])
2540 m4_include([src/security/cert_validators/helpers.m4])
2541
2542 AC_ARG_ENABLE(security-cert-generators,
2543   AS_HELP_STRING([--enable-security-cert-generators="list of helpers"],
2544                  [This option selects which security certificate validator
2545                   helpers to build and install as part of the normal build
2546                   process. The default is to attempt the build of all possible
2547                   helpers. Use --disable-security-cert-genrators to
2548                   build none. For a list of available helpers see the
2549                   src/security/cert_generators/ directory.]),[
2550 ])
2551 m4_include([src/security/cert_generators/helpers.m4])
2552
2553 dnl Select storeid_rewrite helpers to build
2554 AC_ARG_ENABLE(storeid-rewrite-helpers,
2555   AS_HELP_STRING([--enable-storeid-rewrite-helpers="list of helpers"],
2556                  [This option selects which Store-ID rewrite helpers to
2557                   build and install as part of the normal build
2558                   process. The default is to attempt the build of all possible
2559                   helpers. Use --disable-storeid-rewrite-helpers to build none.
2560                   For a list of available helpers see the
2561                   src/store/id_rewriters/ directory.]),[
2562 ])
2563 m4_include([src/store/id_rewriters/helpers.m4])
2564
2565 AC_ARG_WITH(valgrind-debug,
2566   AS_HELP_STRING([--with-valgrind-debug],
2567                  [Include debug instrumentation for use with valgrind]),
2568 [
2569   SQUID_YESNO([$withval],
2570             [unrecognized argument to --with-valgrind-debug: $withval])
2571   if test "x$withval" != "xno" ; then
2572     AC_CHECK_HEADERS(valgrind/memcheck.h,[],[
2573       AC_MSG_ERROR([Valgrind support requested, needed headers not found.])
2574     ])
2575   fi
2576 ])
2577 SQUID_DEFINE_BOOL(WITH_VALGRIND,${with_valgrind_debug:=no},
2578                   [Valgrind memory debugger support])
2579 AC_MSG_NOTICE([Valgrind debug support enabled: $with_valgrind_debug])
2580
2581 dnl Enable WIN32 Service compile mode
2582 AC_ARG_ENABLE(win32-service,
2583   AS_HELP_STRING([--enable-win32-service],
2584                  [Compile Squid as a WIN32 Service.
2585                   Works only on MS-Windows platforms]), [
2586 SQUID_YESNO([$enableval],
2587             [unrecognized argument to --enable-win32-service: $enableval])
2588 ])
2589 SQUID_DEFINE_BOOL(USE_WIN32_SERVICE,${enable_win32_service:=no},
2590    [Enable code supporting MS Windows service mode])
2591 AC_MSG_NOTICE([MS Windows service mode enabled: $enable_win32_service])
2592
2593
2594 # Disable "unlinkd" code
2595 AC_ARG_ENABLE(unlinkd,
2596   AS_HELP_STRING([--disable-unlinkd],[Do not use unlinkd]), [
2597 SQUID_YESNO([$enableval],
2598             [unrecognized argument to --disable-unlinkd: $enableval])
2599 ])
2600 SQUID_DEFINE_BOOL(USE_UNLINKD,${enable_unlinkd:=yes},
2601                       [Enable useage of unlinkd])
2602 AM_CONDITIONAL(ENABLE_UNLINKD,test "x$enable_unlinkd" = "xyes")
2603 AC_MSG_NOTICE([unlinkd enabled: $enable_unlinkd])
2604
2605 # Enable backtraces on fatal errors
2606 AC_ARG_ENABLE(stacktraces,
2607   AS_HELP_STRING([--enable-stacktraces],
2608                  [Enable automatic call backtrace on fatal errors]), [
2609 SQUID_YESNO([$enableval],
2610             [unrecognized argument to --enable-stacktraces: $enableval])
2611 ])
2612 SQUID_DEFINE_BOOL(PRINT_STACK_TRACE,${enable_stacktraces:=no},
2613                       [Print stack traces on fatal errors])
2614 AC_MSG_NOTICE([Automatically print stack trace on fatal errors: $enable_stacktraces])
2615
2616
2617 # CPU Profiling options handling
2618 AC_ARG_ENABLE(cpu-profiling,
2619   AS_HELP_STRING([--enable-cpu-profiling],
2620                  [Enable instrumentation to try and understand how CPU power
2621                  is spent by squid, by enabling specific probes in selected
2622                  functions.
2623                  New probes can only be added by modifying the source code.
2624                  It is meant to help developers in optimizing performance
2625                  of Squid internal functions.
2626                  If you are not developer you should not enable this,
2627                  as it slows squid down somewhat.
2628                  See lib/Profiler.c for more details.]), [
2629 SQUID_YESNO([$enableval],
2630             [unrecognized argument to --enable-cpu-profiling: $enableval])
2631 ])
2632 # Default OFF. This is a debug feature. Only check and enable if forced ON.
2633 if test "x$enable_cpu_profiling" = "xyes"; then
2634   SQUID_CHECK_FUNCTIONAL_CPU_PROFILER
2635   if test "x$squid_cv_cpu_profiler_works" = "xno"; then
2636     AC_MSG_ERROR([CPU profiling will not be functional in this build.])
2637   fi
2638 fi
2639 SQUID_DEFINE_BOOL(USE_XPROF_STATS,${enable_cpu_profiling:=no},
2640                       [Define to enable CPU profiling within Squid])
2641 AM_CONDITIONAL(ENABLE_XPROF_STATS,
2642                test "x$enable_cpu_profiling" = "xyes")
2643 AC_MSG_NOTICE([CPU profiling enabled: $enable_cpu_profiling])
2644
2645 # Enable X-Accelerator-Vary for Vary support within an accelerator setup
2646 AC_ARG_ENABLE(x-accelerator-vary,
2647   AS_HELP_STRING([--enable-x-accelerator-vary],
2648                  [Enable support for the X-Accelerator-Vary
2649                   HTTP header. Can be used to indicate
2650                   variance within an accelerator setup.
2651                   Typically used together with other code
2652                   that adds custom HTTP headers to the requests.]), [
2653 SQUID_YESNO([$enableval],
2654             [unrecognized argument to --enable-x-accelerator-vary: $enableval])
2655 ])
2656 SQUID_DEFINE_BOOL(X_ACCELERATOR_VARY,${enable_x_accelerator_vary:=no},
2657                       [Enable support for the X-Accelerator-Vary HTTP header])
2658 AC_MSG_NOTICE([X-Accelerator-Vary support enabled: $enable_x_accelerator_vary])
2659
2660 SQUID_AUTO_LIB(cppunit,[cppunit test framework],[LIBCPPUNIT])
2661 AS_IF([test "x$with_cppunit" != "xno"],[
2662   LIBCPPUNIT_LIBS="$LIBCPPUNIT_PATH -lcppunit"
2663   PKG_CHECK_MODULES([LIBCPPUNIT],[cppunit],[
2664     squid_cv_cppunit_version="`pkg-config cppunit --version`"
2665     AC_MSG_NOTICE([using system installed cppunit version $squid_cv_cppunit_version])
2666     AS_UNSET(squid_cv_cppunit_version)
2667
2668     SQUID_STATE_SAVE(squid_cppunit_state)
2669     CXXFLAGS="${CXXFLAGS} ${LIBCPPUNIT_CFLAGS}"
2670     LIBS="${LIBS} ${LIBCPPUNIT_LIBS}"
2671     AC_CHECK_HEADERS(cppunit/extensions/HelperMacros.h)
2672     SQUID_STATE_ROLLBACK(squid_cppunit_state)
2673   ],[
2674     AC_MSG_WARN([cppunit does not appear to be installed. Squid does not require this, but code testing with 'make check' will fail.])
2675   ])
2676 ])
2677
2678 # Force some compilers to use ANSI features
2679 #
2680 case "$host" in
2681   *-hp-hpux*)
2682     if test "x$ac_cv_prog_CC" = "xcc" ; then
2683       AC_MSG_NOTICE([adding '-Ae' to cc args for $host])
2684       CC="cc -Ae";
2685       ac_cv_prog_CC="$CC"
2686     fi
2687     ;;
2688 esac
2689
2690
2691 dnl automake handles this AC_PATH_PROG(MAKEDEPEND, makedepend, $TRUE)
2692
2693 case "$host" in
2694   *hpux*)
2695     AC_MSG_NOTICE([Disabling ranlib for HP-UX...])
2696     RANLIB=":"
2697     ;;
2698 esac
2699
2700 dnl Check for headers
2701 AC_HEADER_DIRENT
2702 AC_HEADER_STDC
2703
2704 AC_CHECK_HEADERS( \
2705   arpa/inet.h \
2706   arpa/nameser.h \
2707   assert.h \
2708   bstring.h \
2709   crypt.h \
2710   ctype.h \
2711   direct.h \
2712   errno.h \
2713   execinfo.h \
2714   fcntl.h \
2715   fnmatch.h \
2716   getopt.h \
2717   glob.h \
2718   gnumalloc.h \
2719   grp.h \
2720   ipl.h \
2721   lber.h \
2722   ldap.h \
2723   libc.h \
2724   limits.h \
2725   linux/posix_types.h \
2726   linux/types.h \
2727   malloc.h \
2728   math.h \
2729   memory.h \
2730   mount.h \
2731   netdb.h \
2732   netinet/in.h \
2733   netinet/in_systm.h \
2734   netinet/tcp.h \
2735   paths.h \
2736   poll.h \
2737   pwd.h \
2738   regex.h \
2739   sched.h \
2740   siginfo.h \
2741   signal.h \
2742   stdarg.h \
2743   stddef.h \
2744   stdio.h \
2745   stdlib.h \
2746   string.h \
2747   strings.h \
2748   sys/bitypes.h \
2749   sys/file.h \
2750   sys/ioctl.h \
2751   sys/ipc.cc \
2752   sys/param.h \
2753   sys/prctl.h \
2754   sys/md5.h \
2755   sys/mman.h \
2756   sys/msg.h \
2757   sys/resource.h \
2758   sys/select.h \
2759   sys/shm.h \
2760   sys/socket.h \
2761   sys/stat.h \
2762   syscall.h \
2763   sys/syscall.h \
2764   sys/time.h \
2765   sys/types.h \
2766   sys/uio.h \
2767   sys/un.h \
2768   sys/vfs.h \
2769   sys/wait.h \
2770   syslog.h \
2771   time.h \
2772   unistd.h \
2773   utime.h \
2774   varargs.h \
2775   byteswap.h \
2776   glib.h \
2777   stdint.h \
2778   inttypes.h \
2779   wchar.h
2780 )
2781
2782 AC_CHECK_HEADERS( \
2783   linux/netfilter_ipv4.h \
2784   linux/netfilter_ipv6/ip6_tables.h \
2785 ,,,
2786 SQUID_DEFAULT_INCLUDES
2787 #if HAVE_LIMITS_H
2788 #include <limits.h>
2789 #endif
2790 /* Netfilter ip(6)tables v1.4.0 has broken headers */
2791 #if HAVE_NETINET_IN_H
2792 #include <netinet/in.h>
2793 #endif
2794 )
2795
2796 dnl *BSD do not include the dependencies for all their net/ and netinet/ files
2797 dnl We must include a few basic type headers for them to work.
2798 AC_CHECK_HEADERS( \
2799   net/if.h \
2800   netinet/if_ether.h\
2801   netinet/icmp6.h \
2802   netinet/in.h \
2803   netinet/ip.h \
2804   netinet/ip6.h \
2805   netinet/ip_icmp.h \
2806   netinet/ipl.h \
2807   net/pf/pfvar.h \
2808   net/pfvar.h \
2809   sys/mount.h\
2810   resolv.h \
2811 ,,,
2812 SQUID_BSDNET_INCLUDES)
2813
2814 AC_C_CONST
2815 AC_C_BIGENDIAN
2816
2817 AC_STRUCT_TM
2818 AC_CHECK_MEMBERS([struct tm.tm_gmtoff],,,[
2819 #if TM_IN_SYS_TIME
2820 #if HAVE_SYS_TIME_H
2821 #include <sys/time.h>
2822 #endif
2823 #elif HAVE_TIME_H
2824 #include <time.h>
2825 #endif
2826 ])
2827
2828 dnl Override rusage() detect on MinGW because is emulated in source code
2829 case "$squid_host_os" in
2830   mingw)
2831     AC_DEFINE(HAVE_STRUCT_RUSAGE)
2832     ac_cv_func_getrusage='yes'
2833     AC_MSG_NOTICE([Using own rusage on Windows.])
2834     ;;
2835   *)
2836     AC_CHECK_TYPE(struct rusage,AC_DEFINE(HAVE_STRUCT_RUSAGE,1,[The system provides struct rusage]),,[
2837 #if HAVE_SYS_TIME_H
2838 #include <sys/time.h>
2839 #endif
2840 #if HAVE_SYS_RESOURCE_H
2841 #include <sys/resource.h>
2842 #endif])
2843     ;;
2844 esac
2845
2846 AC_CHECK_MEMBERS([struct iphdr.ip_hl],,,[
2847 #if HAVE_SYS_TYPES_H
2848 #include <sys/types.h>
2849 #endif
2850 #include <netinet/in.h>
2851 #include <netinet/in_systm.h>
2852 #include <netinet/ip.h>
2853 #if defined (__linux__) || defined (__CYGWIN__)
2854 #define ip_hl ihl
2855 #endif
2856 #ifndef __linux__
2857 #ifndef __CYGWIN__
2858 #define iphdr ip
2859 #endif
2860 #endif])
2861
2862 dnl Check for typedefs
2863 AC_CHECK_SIZEOF(void *)
2864
2865 # check for a bunch of types
2866 AC_TYPE_INT8_T
2867 AC_TYPE_UINT8_T
2868 AC_TYPE_INT16_T
2869 AC_TYPE_UINT16_T
2870 AC_TYPE_INT32_T
2871 AC_TYPE_UINT32_T
2872 AC_TYPE_INT64_T
2873 AC_TYPE_UINT64_T
2874 AC_TYPE_PID_T
2875 AC_TYPE_SIZE_T
2876 AC_TYPE_SSIZE_T
2877 AC_TYPE_OFF_T
2878 AC_TYPE_UID_T
2879 AC_CHECK_TYPE([bool])
2880 #need the defines for PRId64
2881 AC_CHECK_SIZEOF(int64_t)
2882 AC_CHECK_SIZEOF(long)
2883 #need the defines for PRIuSIZE
2884 AC_CHECK_SIZEOF(size_t)
2885 #need the define for overflow checks
2886 AC_CHECK_SIZEOF(off_t)
2887 AC_CHECK_SIZEOF(size_t)
2888
2889 dnl Some C++11 types we try to use
2890 AX_CXX_TYPE_NULLPTR
2891 AX_CXX_TYPE_UNIQUE_PTR
2892 AX_CXX_TYPE_UNIFORM_DISTRIBUTIONS
2893 SQUID_CXX_STD_UNDERLYING_TYPE
2894
2895 dnl On Solaris 9 x86, gcc may includes a "fixed" set of old system include files
2896 dnl that is incompatible with the updated Solaris header files.
2897 dnl For this reason, we must check if pad128_t and upad128_t are defined.
2898 AC_CHECK_TYPE(pad128_t,
2899   AC_DEFINE(HAVE_PAD128_T,1,[pad128_t is defined in system headers]),
2900   ,SQUID_DEFAULT_INCLUDES)
2901
2902 AC_CHECK_TYPE(upad128_t,
2903   AC_DEFINE(HAVE_UPAD128_T,1,[upad128_t is defined in system headers]),
2904   ,SQUID_DEFAULT_INCLUDES)
2905
2906 AC_CHECK_TYPE(mode_t, AC_DEFINE(HAVE_MODE_T,1,[mode_t is defined by the system headers]),,SQUID_DEFAULT_INCLUDES)
2907 AC_CHECK_TYPE(fd_mask,  AC_DEFINE(HAVE_FD_MASK,1,[fd_mask is defined by the system headers]),,SQUID_DEFAULT_INCLUDES)
2908
2909 AC_CHECK_TYPE(socklen_t,AC_DEFINE(HAVE_SOCKLEN_T,1,[socklen_t is defined by the system headers]),,[
2910 #include <sys/types.h>
2911 #include <sys/socket.h>
2912 #if STDC_HEADERS
2913 #include <stdlib.h>
2914 #include <stddef.h>
2915 #endif])
2916
2917 AC_CHECK_TYPE(mtyp_t,AC_DEFINE(HAVE_MTYP_T,1,
2918    [mtyp_t is defined by the system headers]),,[#include <sys/types.h>
2919 #include <sys/ipc.h>
2920 #include <sys/msg.h>])
2921
2922 AC_CHECK_TYPE(cpu_set_t,
2923    AC_DEFINE(HAVE_CPU_SET_T,1,[cpu_set_t is defined by the system headers]),,[
2924 #if HAVE_SCHED_H
2925 #include <sched.h>
2926 #endif
2927 ])
2928
2929 # check for compiler support of %zu printf macro
2930 AH_TEMPLATE(PRIuSIZE,[Compiler supports %zu printf macro])
2931 AC_MSG_CHECKING([for compiler %zu support])
2932 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2933 #include <stdio.h>
2934   ]],[[size_t n=1;printf("%zu",n);]])],[
2935     AC_DEFINE(PRIuSIZE,"zu")
2936     AC_MSG_RESULT(yes)
2937   ],[AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
2938
2939
2940 dnl Check for special functions
2941 AC_FUNC_ALLOCA
2942
2943
2944 # TODO: remove this 'lib' prefix to match coding standard
2945 SQUID_AUTO_LIB(libcap,[Linux capabilities],[LIBCAP])
2946 if test "x$with_libcap" != "xno"; then
2947   CXXFLAGS="$LIBCAP_CFLAGS $CXXFLAGS"
2948   LDFLAGS="$LIBCAP_PATH $LDFLAGS"
2949   # cap_clear_flag is the most recent libcap function we require
2950   AC_CHECK_HEADERS(sys/capability.h)
2951   AC_CHECK_LIB(cap, cap_clear_flag)
2952   SQUID_CHECK_FUNCTIONAL_LIBCAP2
2953
2954   # if it can't be supported..
2955   if test "x$ac_cv_header_sys_capability_h" = "xno" -o \
2956      "x$ac_cv_lib_cap_cap_clear_flag" = "xno"; then
2957     # and it was forced on: error
2958     if test "x$with_libcap" = "xyes" ; then
2959       AC_MSG_ERROR([libcap forced enabled but not available or not usable, requires libcap-2.09 or later])
2960     else
2961       # with_libcap is "auto"; it can't be supported. Disable.
2962       with_libcap=no
2963     fi
2964   else
2965     # header and lib are ok, we support
2966     with_libcap=yes
2967   fi
2968
2969 fi
2970
2971 SQUID_DEFINE_BOOL(USE_LIBCAP,$with_libcap,
2972    [use libcap to set capabilities required for TPROXY])
2973 AC_MSG_NOTICE([libcap support enabled: $with_libcap])
2974 SQUID_DEFINE_BOOL(LIBCAP_BROKEN,${squid_cv_sys_capability_works:=no},
2975    [libcap2 headers are broken and clashing with glibc])
2976 AC_MSG_NOTICE([libcap2 headers are ok: $squid_cv_sys_capability_works])
2977
2978
2979 dnl Check for needed libraries
2980 AC_SEARCH_LIBS([gethostbyname],[nsl resolv bind])
2981 AC_SEARCH_LIBS([res_init],[resolv])
2982 AC_SEARCH_LIBS([__res_search],[resolv])
2983 AC_SEARCH_LIBS([bind],[socket])
2984 AC_SEARCH_LIBS([opcom_stack_trace],[opcom_stack])
2985 AC_SEARCH_LIBS([strlcpy], [bsd])
2986 AC_SEARCH_LIBS([yp_match], [nsl nss_nis nss_nisplus])
2987 dnl Check for Winsock only on MinGW, on Cygwin we must use emulated BSD socket API
2988 if test "x$squid_host_os" = "xmingw" ; then
2989   SQUID_CHECK_WINSOCK_LIB
2990   AC_CHECK_HEADERS( \
2991     windows.h \
2992     ws2tcpip.h \
2993     iphlpapi.h ,,,[
2994 #if HAVE_WINSOCK2_H
2995 #include <winsock2.h>
2996 #endif
2997 #if HAVE_WINDOWS_H
2998 #include <windows.h>
2999 #endif
3000 #if HAVE_WS2TCPIP_H
3001 #include <ws2tcpip.h>
3002 #endif
3003 ])
3004 fi
3005
3006 # check that we have unix sockets
3007 SQUID_CHECK_UNIX_SOCKET
3008 SQUID_DEFINE_BOOL(HAVE_UNIXSOCKET,$squid_cv_unixsocket,[System supports unix sockets])
3009
3010 AC_CHECK_LIB(gnumalloc, malloc)
3011 if test "x$ac_cv_lib_gnumalloc_malloc" = "xyes"; then
3012   AC_MSG_NOTICE([Disabling extended malloc functions when using bundled gnumalloc])
3013   ac_cv_func_mallocblksize=no
3014   ac_cv_func_mallopt=no
3015 else
3016   case "$squid_host_os" in
3017     solaris)
3018       AC_MSG_NOTICE([skipping libmalloc check for $host])
3019       ;;
3020     freebsd)
3021       AC_MSG_NOTICE([skipping libmalloc check for $host])
3022       ;;
3023     *)
3024       #used later. FIXME
3025       AC_CHECK_LIB(malloc, main)
3026       ;;
3027   esac
3028 fi
3029
3030 case "$squid_host_os" in
3031   mingw)
3032     AC_MSG_NOTICE([Use MSVCRT for math functions.])
3033     ;;
3034   *)
3035     dnl rint() and log() are only used in old C code for now.
3036     AC_LANG_PUSH([C])
3037     AC_SEARCH_LIBS([rint],[m])
3038     AC_SEARCH_LIBS([log],[m])
3039     AC_LANG_POP([C])
3040     ;;
3041 esac
3042
3043 dnl --with-maxfd present for compatibility with Squid-2.
3044 dnl undocumented in ./configure --help  to encourage using the Squid-3 directive
3045 AC_ARG_WITH(maxfd,,
3046 [
3047   case ${withval} in
3048     [[0-9]]*)
3049       squid_filedescriptors_num=$withval
3050       AC_MSG_NOTICE([forcing default of $squid_filedescriptors_num filedescriptors (user-forced)])
3051       ;;
3052     *)
3053       AC_MSG_ERROR(--with-maxfd expects a numeric argument)
3054       ;;
3055     esac
3056 ])
3057
3058 AC_ARG_WITH(filedescriptors,
3059   AS_HELP_STRING([--with-filedescriptors=NUMBER],
3060                  [Force squid to support NUMBER filedescriptors]),
3061 [
3062   case ${withval} in
3063     [[0-9]]*)
3064       squid_filedescriptors_num=$withval
3065       AC_MSG_NOTICE([forcing default of $squid_filedescriptors_num filedescriptors (user-forced)])
3066       ;;
3067     *)
3068       AC_MSG_ERROR(--with-filedescriptors expects a numeric argument)
3069       ;;
3070     esac
3071 ])
3072
3073 SQUID_CHECK_DEFAULT_FD_SETSIZE
3074 SQUID_CHECK_MAXFD
3075
3076
3077 dnl Enable IPv6 support
3078 AC_MSG_CHECKING([whether to enable IPv6])
3079 AC_ARG_ENABLE(ipv6,
3080   AS_HELP_STRING([--disable-ipv6],[Disable IPv6 support. The default is to probe system capabilities on startup.]), [
3081 SQUID_YESNO([$enableval],[unrecognized argument to --disable-ipv6: $enableval])
3082 ])
3083 AC_MSG_RESULT(${enable_ipv6:=yes})
3084 SQUID_DEFINE_BOOL(USE_IPV6,$enable_ipv6,[Enable support for IPv6 ])
3085
3086 if test "x$enable_ipv6" = "xyes" ; then
3087   SQUID_CHECK_SIN6_LEN_IN_SAI
3088 fi
3089 SQUID_CHECK_SS_LEN_IN_SOCKADDR_STORAGE
3090 SQUID_CHECK_SIN_LEN_IN_SOCKADDR_IN
3091
3092
3093 dnl -lintl is needed on SCO version 3.2v4.2 for strftime()
3094 dnl Robert Side <rside@aiinc.bc.ca>
3095 dnl Mon, 18 Jan 1999 17:48:00 GMT
3096 case "$host" in
3097         *-pc-sco3.2*)
3098                 AC_CHECK_LIB(intl, strftime)
3099                 ;;
3100 esac
3101
3102 dnl System-specific library modifications
3103 dnl
3104 case "$host" in
3105   i386-*-solaris2.*)
3106     if test "x$GCC" = "xyes"; then
3107       AC_MSG_NOTICE([Removing -O for gcc on $host])
3108       CFLAGS="`echo $CFLAGS | sed -e 's/-O[[0-9g]]*//'`"
3109     fi
3110   ;;
3111
3112   *-sgi-irix*)
3113     AC_MSG_NOTICE([Removing -lsocket for IRIX...])
3114     LIBS=`echo $LIBS | sed -e s/-lsocket//`
3115     AC_MSG_NOTICE([Removing -lnsl for IRIX...])
3116     LIBS=`echo $LIBS | sed -e s/-lnsl//`
3117     ac_cv_lib_nsl_main=no
3118     AC_MSG_NOTICE([Removing -lbsd for IRIX...])
3119     LIBS=`echo $LIBS | sed -e s/-lbsd//`
3120   ;;
3121 dnl From: c0032033@ws.rz.tu-bs.de (Joerg Schumacher)
3122 dnl Date: Thu, 17 Oct 1996 04:09:30 +0200
3123 dnl Please change your configure script.  AIX doesn't need -lbsd.
3124   *-ibm-aix*)
3125     AC_MSG_NOTICE([Removing -lbsd for AIX...])
3126     LIBS=`echo $LIBS | sed -e s/-lbsd//`
3127
3128     SQUID_CC_REQUIRE_ARGUMENT([ac_cv_require_rtti],[-rtti],[[
3129 #include <assert.h>
3130 #ifndef NULL
3131 #define NULL 0
3132 #endif
3133 class Foo{
3134 public:virtual ~Foo(){}
3135 };
3136 class Bar:public Foo{
3137 public:Bar():Foo(){}
3138 };
3139       ]],[[
3140 Foo * myFoo=new Bar();
3141 Bar * myBar=dynamic_cast<Bar *>(myFoo);
3142 assert(myBar != NULL);
3143       ]])
3144     if test "$ac_cv_require_rtti" = "yes"; then
3145       SQUID_CFLAGS="-rtti $SQUID_CFLAGS"
3146       SQUID_CXXFLAGS="-rtti $SQUID_CXXFLAGS"
3147     fi
3148
3149     AC_LANG_PUSH([C])
3150     SQUID_CC_REQUIRE_ARGUMENT([ac_cv_require_qcpluscmt],[-qcpluscmt],[[]],[[//c++ cmt]])
3151     AC_LANG_POP([C])
3152     if test "$ac_cv_require_qcpluscmt" = "yes"; then
3153       SQUID_CFLAGS="-qcpluscmt $SQUID_CFLAGS"
3154     fi
3155     ;;
3156
3157     *m88k*)
3158       SQUID_CFLAGS="$SQUID_CFLAGS -D_SQUID_MOTOROLA_"
3159       SQUID_CXXFLAGS="$SQUID_CXXFLAGS -D_SQUID_MOTOROLA_"
3160       AC_DEFINE(GETTIMEOFDAY_NO_TZP,1,
3161         [If gettimeofday is known to take only one argument])
3162     ;;
3163     [*-*-solaris2.[0-4]])
3164       AC_DEFINE(GETTIMEOFDAY_NO_TZP,1)
3165     ;;
3166     [*-sony-newsos[56]*])
3167       AC_DEFINE(GETTIMEOFDAY_NO_TZP,1)
3168     ;;
3169   esac
3170
3171 dnl This has to be before AC_CHECK_FUNCS
3172 # Disable poll() on certain platforms. Override by setting ac_cv_func_poll
3173 # when running configure.
3174 if test "x$ac_cv_func_poll" = "x" ; then
3175   case "$host" in
3176     [*-hp-hpux*.*])
3177       # Duane Wessels
3178       AC_MSG_NOTICE([disabling poll for $host...])
3179       ac_cv_func_poll='no'
3180       ;;
3181     [*-linux-*])
3182       # Henrik Nordstrom (hno@squid-cache.org) 19980817
3183       # poll is problematic on Linux.  We disable it
3184       # by default until Linux gets it right.
3185       rev=`uname -r | awk -F. '{printf "%03d%03d",$1,$2}'`
3186       if test $rev -lt 002002; then
3187           AC_MSG_NOTICE([disabling poll for $host < 2.2...])
3188           ac_cv_func_poll='no'
3189       fi
3190       ;;
3191     [powerpc-ibm-aix4.1.*])
3192       # Mike Laster (mlaster@metavillage.com) 19981021
3193       AC_MSG_NOTICE([disabling poll for $host...])
3194       ac_cv_func_poll='no'
3195       ;;
3196     [*-pc-sco3.2*])
3197       # Robert Side <rside@aiinc.bc.ca>
3198       # Mon, 18 Jan 1999 17:48:00 GMT
3199       AC_MSG_NOTICE([disabling poll for $host...])
3200       ac_cv_func_poll='no'
3201       ;;
3202   esac
3203 fi
3204
3205 dnl Check for library functions
3206 AC_CHECK_FUNCS(\
3207         backtrace_symbols_fd \
3208         bcopy \
3209         eui64_aton \
3210         fchmod \
3211         getdtablesize \
3212         getpagesize \
3213         getpass \
3214         getrusage \
3215         getspnam \
3216         gettimeofday \
3217         glob \
3218         mallocblksize \
3219         mallopt \
3220         memcpy \
3221         memmove \
3222         memrchr \
3223         memset \
3224         mkstemp \
3225         mktime \
3226         mstats \
3227         poll \
3228         prctl \
3229         pthread_attr_setschedparam \
3230         pthread_attr_setscope \
3231         pthread_setschedparam \
3232         pthread_sigmask \
3233         putenv \
3234         regcomp \
3235         regexec \
3236         regfree \
3237         res_init \
3238         __res_init \
3239         rint \
3240         sched_getaffinity \
3241         sched_setaffinity \
3242         select \
3243         seteuid \
3244         setgroups \
3245         setpgrp \
3246         setsid \
3247         sigaction \
3248         snprintf \
3249         socketpair \
3250         sysconf \
3251         syslog \
3252         timegm \
3253         vsnprintf \
3254 )
3255 dnl ... and some we provide local replacements for
3256 AC_REPLACE_FUNCS(\
3257         initgroups \
3258         psignal \
3259         strerror \
3260         strtoll \
3261         tempnam \
3262 )
3263
3264 AC_CHECK_DECLS([getaddrinfo,getnameinfo,inet_ntop,inet_pton,InetNtopA,InetPtonA],,,[
3265 /*
3266  * BSD requires sys/types.h, sys/socket.h, netinet/in.h, netdb.h, arpa/inet.h
3267  * Linux requires sys/types.h, sys/socket.h, arpa/inet.h
3268  * Windows requires sys/socket.h, winsock2.h, ws2tcpip.h
3269  */
3270 #if HAVE_SYS_TYPES_H
3271 #include <sys/types.h>
3272 #endif
3273 #if HAVE_NETINET_IN_H
3274 #include <netinet/in.h>
3275 #endif
3276 #if HAVE_SYS_SOCKET_H
3277 #include <sys/socket.h>
3278 #endif
3279 #if HAVE_NETDB_H
3280 #include <netdb.h>
3281 #endif
3282 #if HAVE_ARPA_INET_H
3283 #include <arpa/inet.h>
3284 #endif
3285 #if HAVE_WINSOCK2_H
3286 #include <winsock2.h>
3287 #endif
3288 #if HAVE_WS2TCPIP_H
3289 #include <ws2tcpip.h>
3290 #endif
3291 ])
3292
3293 # Magic which checks whether we are forcing a type of comm loop we
3294 # are actually going to (ab)use.
3295 # Mostly ripped from squid-commloops, thanks to adrian and benno
3296
3297 if test "x$squid_opt_io_loop_engine" != "x"; then
3298         AC_MSG_NOTICE([choosing user-specified net I/O API $squid_opt_io_loop_engine])
3299 elif test "x$enable_epoll" != "xno" -a "x$squid_cv_epoll_works" = "xyes" ; then
3300   squid_opt_io_loop_engine="epoll"
3301 elif test "x$enable_kqueue" != "xno" ; then
3302   squid_opt_io_loop_engine="kqueue"
3303 elif test "x$enable_devpoll" != "xno" ; then
3304   squid_opt_io_loop_engine="devpoll"
3305 elif test "x$enable_poll" != "xno" -a "x$ac_cv_func_poll" = "xyes" ; then
3306   squid_opt_io_loop_engine="poll"
3307 elif test "x$enable_select" != "xno" -a "x$ac_cv_func_select" = "xyes"; then
3308   squid_opt_io_loop_engine="select"
3309 elif test "x$enable_select" != "xno" -a "x$squid_host_os" = "xmingw"; then
3310   squid_opt_io_loop_engine="select_win32"
3311 else
3312   AC_MSG_WARN([Eep!  Cannot find epoll, kqueue, /dev/poll, poll or select!])
3313   AC_MSG_WARN([Will try select and hope for the best.])
3314   squid_opt_io_loop_engine="select"
3315 fi
3316
3317 AC_MSG_NOTICE([Using ${squid_opt_io_loop_engine} for the IO loop.])
3318
3319 AM_CONDITIONAL(ENABLE_POLL, test "x$squid_opt_io_loop_engine" = "xpoll")
3320 AM_CONDITIONAL(ENABLE_EPOLL, test "x$squid_opt_io_loop_engine" = "xepoll")
3321 AM_CONDITIONAL(ENABLE_SELECT, test "x$squid_opt_io_loop_engine" = "xselect")
3322 AM_CONDITIONAL(ENABLE_SELECT_WIN32, test "x$squid_opt_io_loop_engine" = "xselect_win32")
3323 AM_CONDITIONAL(ENABLE_KQUEUE, test "x$squid_opt_io_loop_engine" = "xkqueue")
3324 AM_CONDITIONAL(ENABLE_DEVPOLL, test "x$squid_opt_io_loop_engine" = "xdevpoll")
3325
3326 case $squid_opt_io_loop_engine in
3327   epoll) AC_DEFINE(USE_EPOLL,1,[Use epoll() for the IO loop]) ;;
3328   devpoll) AC_DEFINE(USE_DEVPOLL,1,[Use /dev/poll for the IO loop]) ;;
3329   poll) AC_DEFINE(USE_POLL,1,[Use poll() for the IO loop]) ;;
3330   kqueue) AC_DEFINE(USE_KQUEUE,1,[Use kqueue() for the IO loop]) ;;
3331   select_win32) AC_DEFINE(USE_SELECT_WIN32,1,[Use Winsock select() for the IO loop]) ;;
3332   select) AC_DEFINE(USE_SELECT,1,[Use select() for the IO loop]) ;;
3333 esac
3334
3335 if test "x$ac_cv_func_sched_getaffinity" = "xyes" -a "x$ac_cv_func_sched_setaffinity" = "xyes" ; then
3336   AC_DEFINE(HAVE_CPU_AFFINITY,1,[Support setting CPU affinity for workers])
3337 fi
3338
3339 SQUID_CHECK_SETRESUID_WORKS
3340 if test "x$squid_cv_resuid_works" = "xyes" ; then
3341   AC_DEFINE(HAVE_SETRESUID,1,[Yay! Another Linux brokenness. Knowing that setresuid() exists is not enough, because RedHat 5.0 declares setresuid() but does not implement it.])
3342 fi
3343
3344 AC_CHECK_HEADERS(mswsock.h)
3345 AC_MSG_CHECKING([for constant CMSG_SPACE])
3346 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
3347   #if HAVE_SYS_SOCKET_H
3348   #include <sys/socket.h>
3349   #endif
3350   #if HAVE_MSWSOCK_H
3351   #include <mswsock.h>
3352   #endif
3353
3354   int a[CMSG_SPACE(int)];
3355 ]])], [
3356   AC_MSG_RESULT(yes)
3357   AC_DEFINE(HAVE_CONSTANT_CMSG_SPACE, 1, [Define to 1 if CMSG_SPACE is constant])
3358 ], [
3359   AC_MSG_RESULT(no)
3360 ])
3361
3362 AC_CHECK_TYPE(struct cmsghdr,AC_DEFINE(HAVE_CMSGHDR,1,[The system provides struct cmsghdr]),,[
3363   #if HAVE_SYS_SOCKET_H
3364   #include <sys/socket.h>
3365   #endif
3366   #if HAVE_MSWSOCK_H
3367   #include <mswsock.h>
3368   #endif
3369   #if HAVE_WINSOCK2_H
3370   #include <winsock2.h>
3371   #endif
3372 ])
3373
3374 AC_CHECK_TYPE(struct iovec,AC_DEFINE(HAVE_IOVEC,1,[The system provides struct iovec]),,[
3375   #if HAVE_SYS_SOCKET_H
3376   #include <sys/socket.h>
3377   #endif
3378   #if HAVE_WINSOCK2_H
3379   #include <winsock2.h>
3380   #endif
3381   #if HAVE_SYS_UIO_H
3382   #include <sys/uio.h>
3383   #endif
3384 ])
3385
3386 AC_CHECK_TYPE(struct msghdr,AC_DEFINE(HAVE_MSGHDR,1,[The system provides struct msghdr]),,[
3387   #if HAVE_SYS_SOCKET_H
3388   #include <sys/socket.h>
3389   #endif
3390   #if HAVE_MSWSOCK_H
3391   #include <mswsock.h>
3392   #endif
3393   #if HAVE_WINSOCK2_H
3394   #include <winsock2.h>
3395   #endif
3396 ])
3397
3398 AC_CHECK_TYPE(struct sockaddr_un,AC_DEFINE(HAVE_SOCKADDR_UN,1,[The system provides sockaddr_un]),,[
3399   #if HAVE_SYS_UN_H
3400   #include <sys/un.h>
3401   #endif
3402   #if HAVE_SYS_SOCKET_H
3403   #include <sys/socket.h>
3404   #endif
3405   #if HAVE_WINSOCK2_H
3406   #include <winsock2.h>
3407   #endif
3408 ])
3409
3410 SQUID_CHECK_FUNC_STRNSTR
3411
3412 dnl IP-Filter support requires ipf header files. These aren't
3413 dnl installed by default, so we need to check for them
3414 if test "x$enable_ipf_transparent" != "xno" ; then
3415     SQUID_CHECK_BROKEN_SOLARIS_IPFILTER
3416     AC_MSG_CHECKING(for availability of IP-Filter header files)
3417     # hold on to your hats...
3418     if test "x$ac_cv_header_ip_compat_h" = "xyes" -o \
3419         "x$ac_cv_header_ip_fil_compat_h" = "xyes" -o \
3420         "x$ac_cv_header_netinet_ip_compat_h" = "xyes" -o \
3421         "x$ac_cv_header_netinet_ip_fil_compat_h" = "xyes" ; then
3422         have_ipfilter_compat_header="yes"
3423     fi
3424     if test "x$have_ipfilter_compat_header" = "xyes" -a \
3425        "x$ac_cv_header_ip_fil_h" = "xyes" -a \
3426        "x$ac_cv_header_ip_nat_h" = "xyes" ; then
3427         enable_ipf_transparent="yes"
3428     elif test "x$have_ipfilter_compat_header" = "xyes" -a \
3429          "x$ac_cv_header_netinet_ip_fil_h" = "xyes" -a \
3430          "x$ac_cv_header_netinet_ip_nat_h" = "xyes" ; then
3431         enable_ipf_transparent="yes"
3432     else
3433         enable_ipf_transparent="no"
3434     fi
3435     AC_MSG_RESULT($IPF_TRANSPARENT)
3436
3437 ## On Solaris Ipfilter includes expect that SOLARIS2 is defined with the
3438 ## Solaris minor version (8, 9, 10, ...)
3439   if test "x$enable_ipf_transparent" = "xyes" -a "x$squid_host_os" = "xsolaris" ; then
3440     solrev=`uname -r | sh -c 'IFS=. read j n x; echo $n'`
3441     CFLAGS="-DSOLARIS2=$solrev $CFLAGS"
3442     CXXFLAGS="-DSOLARIS2=$solrev $CXXFLAGS"
3443   fi
3444
3445 fi
3446 AC_MSG_NOTICE([IPF-based transparent proxying enabled: $enable_ipf_transparent])
3447 SQUID_DEFINE_BOOL(IPF_TRANSPARENT,$enable_ipf_transparent,
3448     [Enable support for IPF-style transparent proxying])
3449
3450 dnl PF /dev/pf support requires a header file.
3451 if test "x$with_nat_devpf" != "xno" ; then
3452   if test "x$ac_cv_header_net_pfvar_h" = "xyes" -o \
3453     "x$ac_cv_header_net_pf_pfvar_h" = "xyes"; then
3454     if test "x$with_nat_devpf" = "xauto" ; then
3455       with_nat_devpf="no"
3456     fi
3457   else
3458     if test "x$with_nat_devpf" = "xyes" ; then
3459       AC_MSG_ERROR([PF /dev/pf based NAT requested but needed header not found])
3460     fi
3461     with_nat_devpf="no"
3462   fi
3463 fi
3464 SQUID_DEFINE_BOOL(PF_TRANSPARENT,${enable_pf_transparent:=no},
3465   [Enable support for PF-style transparent proxying])
3466 SQUID_DEFINE_BOOL(USE_NAT_DEVPF,${with_nat_devpf:=no},
3467   [Enable support for /dev/pf NAT lookups])
3468
3469 if test "x$enable_linux_netfilter" != "xno" ; then
3470   if test "x$ac_cv_header_linux_netfilter_ipv4_h" = "xyes"; then
3471     if test "x$enable_linux_netfilter" = "xauto" ; then
3472       enable_linux_netfilter=yes
3473     fi
3474   else
3475     if test "x$enable_linux_netfilter" = "xauto" ; then
3476       enable_linux_netfilter=no
3477     else
3478       AC_MSG_ERROR([Linux Netfilter support requested but needed headers not found])
3479     fi
3480   fi
3481 fi
3482 SQUID_DEFINE_BOOL(LINUX_NETFILTER,$enable_linux_netfilter,
3483   [Enable support for Transparent Proxy on Linux via Netfilter])
3484
3485 dnl Netfilter TPROXY depends on libcap but the NAT parts can still work.
3486 AC_MSG_NOTICE([Support for Netfilter-based interception proxy requested: $enable_linux_netfilter])
3487 if test "x$enable_linux_netfilter" = "xyes" -a "x$with_libcap" != "xyes" ; then
3488     AC_MSG_WARN([Missing needed capabilities (libcap 2.09+) for TPROXY])
3489     AC_MSG_WARN([Linux Transparent Proxy (version 4+) support WILL NOT be enabled])
3490     AC_MSG_WARN([Reduced support to NAT Interception Proxy])
3491     # AC_DEFINEd later
3492 fi
3493 if test "x$with_netfilter_conntrack" = "xyes" -a "x$with_libcap" != "xyes" ; then
3494     AC_MSG_WARN([Missing needed capabilities (libcap 2.09+) for netfilter mark support])
3495     AC_MSG_WARN([Linux netfilter marking support WILL NOT be enabled])
3496     with_netfilter_conntrack=no
3497 fi
3498 AC_MSG_NOTICE([Linux Netfilter Conntrack support enabled: ${with_netfilter_conntrack}])
3499
3500
3501 AC_ARG_ENABLE(zph-qos,
3502   AS_HELP_STRING([--enable-zph-qos],[Enable ZPH QOS support]), [
3503 SQUID_YESNO([$enableval],
3504             [unrecognized argument to --enable-zph-qos: $enableval])
3505 ])
3506 SQUID_DEFINE_BOOL(USE_QOS_TOS,${enable_zph_qos:=yes},
3507           [Enable Zero Penalty Hit QOS. When set, Squid will alter the
3508            TOS field of HIT responses to help policing network traffic])
3509 AC_MSG_NOTICE([ZPH QOS enabled: $enable_zph_qos])
3510 if test x"$enable_zph_qos" = "xyes" ; then
3511         AC_MSG_NOTICE([QOS netfilter mark preservation enabled: $with_netfilter_conntrack])
3512         SQUID_DEFINE_BOOL(USE_LIBNETFILTERCONNTRACK,${with_netfilter_conntrack:=no},
3513                       [Enable support for QOS netfilter mark preservation])
3514 fi
3515
3516
3517 AC_CHECK_LIB(regex, regexec, [REGEXLIB="-lregex"],[REGEXLIB=''])
3518 AC_ARG_ENABLE(gnuregex,
3519   AS_HELP_STRING([--enable-gnuregex],
3520                  [Compile GNUregex.  Unless you have reason to use
3521                  this option, you should not enable it.
3522                  This library file is usually only required on Windows and
3523                  very old Unix boxes which do not have their own regex
3524                  library built in.]), [
3525 SQUID_YESNO([$enableval],[unrecognized argument to --enable-gnuregex: $enableval])
3526 ])
3527 # force-enable on old solaris and nextstep
3528 if test "x${enable_gnuregex:=auto}" = "xauto" ; then
3529     case "$host" in
3530     *-sun-solaris2.[[0-4]])
3531           enable_gnuregex="yes"
3532           ;;
3533     *-next-nextstep*)
3534           enable_gnuregex="yes"
3535           ;;
3536     esac
3537 fi
3538
3539 # try detecting if it is needed
3540 if test "x$enable_gnuregex" = "xauto" ; then
3541   SQUID_CHECK_REGEX_WORKS
3542   if test "x$squid_cv_regex_works" = "xyes" ; then
3543     enable_gnuregex=no
3544   else
3545     enable_gnuregex=yes
3546   fi
3547 fi
3548 AC_MSG_CHECKING(if GNUregex needs to be compiled)
3549 AC_MSG_RESULT($enable_gnuregex)
3550 if test "x$enable_gnuregex" = "xyes"; then
3551   # for some reason (force-enable, test..) gnuregex was found as needed. Override any system lib
3552   REGEXLIB=""
3553 fi
3554 #if no reason was found to enable gnuregex, disable it
3555 if test "x$enable_gnuregex" = "xauto" ; then
3556   enable_gnuregex=no
3557 fi
3558 SQUID_DEFINE_BOOL(USE_GNUREGEX,$enable_gnuregex,[Define if we should use GNU regex])
3559 AC_SUBST(REGEXLIB)
3560
3561 SQUID_DETECT_UDP_SND_BUFSIZE
3562 SQUID_DETECT_UDP_RECV_BUFSIZE
3563 SQUID_DETECT_TCP_SND_BUFSIZE
3564 SQUID_DETECT_TCP_RECV_BUFSIZE
3565
3566 SQUID_CHECK_RECV_ARG_TYPE
3567 SQUID_CHECK_NEED_SYS_ERRLIST
3568 SQUID_CHECK_MAXPATHLEN
3569
3570 SQUID_CHECK_LIBRESOLV_DNS_TTL_HACK
3571 SQUID_CHECK_RESOLVER_FIELDS
3572
3573 AC_CHECK_HEADERS(sys/statvfs.h)
3574 if test "x$ac_cv_header_sys_statvfs_h" = "xyes" ; then
3575   SQUID_CHECK_WORKING_STATVFS
3576 fi
3577 if test "x$ac_cv_func_statvfs" != "xyes" ; then
3578   AC_CHECK_HEADERS(sys/param.h sys/mount.h sys/vfs.h sys/statfs.h)
3579   AC_CHECK_FUNCS(statfs)
3580   SQUID_CHECK_F_FRSIZE_IN_STATFS
3581 fi
3582
3583 dnl Squid will not usually attempt to translate templates when building
3584 AC_ARG_ENABLE(translation,
3585  AS_HELP_STRING([--enable-translation],[Generate the localized error page templates and manuals.
3586                  Which can also be downloaded from http://www.squid-cache.org/Versions/langpack/.]), [
3587   SQUID_YESNO([$enableval],
3588      [unrecognized argument to --enable-translation: $enableval])
3589 ])
3590 if test "x${enable_translation:=no}" = "xyes" ; then
3591   AX_WITH_PROG([PO2HTML],[po2html])
3592   AX_WITH_PROG([PO2TEXT],[po2txt])
3593 else
3594   PO2HTML="off"
3595   PO2TEXT="off"
3596 fi
3597 AC_SUBST(PO2HTML)
3598 AC_SUBST(PO2TEXT)
3599
3600 dnl Squid now has limited locale handling ...
3601 dnl on error pages
3602 AC_ARG_ENABLE(auto-locale,
3603  AS_HELP_STRING([--disable-auto-locale],[This prevents Squid providing localized error pages based on the
3604                  clients request headers.
3605                  When disabled Squid requires explicit language configuration.]), [
3606 SQUID_YESNO([$enableval],
3607     [unrecognized argument to --disable-auto-locale: $enableval])
3608 ])
3609 AC_MSG_NOTICE([Multi-Language support enabled: ${enable_auto_locale:=yes}])
3610 SQUID_DEFINE_BOOL(USE_ERR_LOCALES,$enable_auto_locale,
3611    [Use multi-language support on error pages])
3612
3613
3614 dnl Need the debugging version of malloc if available
3615 XTRA_OBJS=''
3616 if test "x$ac_cv_lib_malloc_main" = "xyes" ; then
3617         if test -r /usr/lib/debug/malloc.o ; then
3618                 XTRA_OBJS="$XTRA_OBJS /usr/lib/debug/malloc.o"
3619         fi
3620         if test -r /usr/lib/debug/mallocmap.o ; then
3621                 XTRA_OBJS="$XTRA_OBJS /usr/lib/debug/mallocmap.o"
3622         fi
3623 fi
3624 AC_SUBST(XTRA_OBJS)
3625
3626 if test "x$XTRA_LIBS" = "x"; then
3627         XTRA_LIBS="$LIBS"
3628         dnl minor cleanup
3629         XTRA_LIBS=`echo $XTRA_LIBS | sed -e "s/  */ /g"`
3630         LIBS=''
3631 fi
3632 AC_SUBST(XTRA_LIBS)
3633
3634 AC_SUBST(SQUID_CFLAGS)
3635 AC_SUBST(SQUID_CXXFLAGS)
3636
3637 AC_ARG_VAR([BUILDCXXFLAGS],[C++ compiler flags for building compile-time tools. e.g. cf_gen])
3638 if test "x$BUILDCXXFLAGS" = "x"; then
3639   # if we are NOT cross-compiling, use the default build flags for cf_gen and friends
3640   # otherwise rely on the user-provided value
3641   if test "x$squid_cv_check_marchnative" = "xyes"; then
3642     # always valid for the Build compiler.
3643     BUILDCXXFLAGS="-march=native"
3644   fi
3645   BUILDCXXFLAGS="$BUILDCXXFLAGS $CXXFLAGS"
3646 fi
3647 AC_SUBST(BUILDCXXFLAGS)
3648
3649 AC_MSG_NOTICE([BUILD LIBRARIES: $LIBS])
3650 AC_MSG_NOTICE([BUILD EXTRA LIBRARIES: $XTRA_LIBS])
3651 AC_MSG_NOTICE([BUILD OBJECTS: $OBJS])
3652 AC_MSG_NOTICE([BUILD EXTRA OBJECTS: $XTRA_OBJS])
3653 AC_MSG_NOTICE([BUILD C FLAGS: $CFLAGS])
3654 AC_MSG_NOTICE([BUILD EXTRA C FLAGS: $SQUID_CFLAGS])
3655 AC_MSG_NOTICE([BUILD C++ FLAGS: $CXXFLAGS])
3656 AC_MSG_NOTICE([BUILD EXTRA C++ FLAGS: $SQUID_CXXFLAGS])
3657 AC_MSG_NOTICE([BUILD Tools C++ FLAGS: $BUILDCXXFLAGS])
3658
3659 dnl Clean up after OSF/1 core dump bug
3660 rm -f core
3661
3662 AC_CONFIG_FILES([
3663         Makefile
3664         compat/Makefile
3665         contrib/Makefile
3666         doc/Makefile
3667         doc/manuals/Makefile
3668         doc/release-notes/Makefile
3669         errors/Makefile
3670         icons/Makefile
3671         lib/Makefile
3672         lib/libTrie/Makefile
3673         lib/libTrie/test/Makefile
3674         lib/ntlmauth/Makefile
3675         lib/profiler/Makefile
3676         lib/rfcnb/Makefile
3677         lib/smblib/Makefile
3678         lib/snmplib/Makefile
3679         scripts/Makefile
3680         src/Makefile
3681         src/acl/Makefile
3682         src/acl/external/Makefile
3683         src/acl/external/AD_group/Makefile
3684         src/acl/external/delayer/Makefile
3685         src/acl/external/eDirectory_userip/Makefile
3686         src/acl/external/file_userip/Makefile
3687         src/acl/external/kerberos_ldap_group/Makefile
3688         src/acl/external/kerberos_sid_group/Makefile
3689         src/acl/external/LDAP_group/Makefile
3690         src/acl/external/LM_group/Makefile
3691         src/acl/external/session/Makefile
3692         src/acl/external/SQL_session/Makefile
3693         src/acl/external/unix_group/Makefile
3694         src/acl/external/wbinfo_group/Makefile
3695         src/acl/external/time_quota/Makefile
3696         src/adaptation/Makefile
3697         src/adaptation/icap/Makefile
3698         src/adaptation/ecap/Makefile
3699         src/anyp/Makefile
3700         src/auth/Makefile
3701         src/auth/basic/Makefile
3702         src/auth/basic/DB/Makefile
3703         src/auth/basic/fake/Makefile
3704         src/auth/basic/getpwnam/Makefile
3705         src/auth/basic/LDAP/Makefile
3706         src/auth/basic/NCSA/Makefile
3707         src/auth/basic/NIS/Makefile
3708         src/auth/basic/PAM/Makefile
3709         src/auth/basic/POP3/Makefile
3710         src/auth/basic/RADIUS/Makefile
3711         src/auth/basic/SASL/Makefile
3712         src/auth/basic/SMB/Makefile
3713         src/auth/basic/SMB_LM/Makefile
3714         src/auth/basic/SSPI/Makefile
3715         src/auth/digest/Makefile
3716         src/auth/digest/eDirectory/Makefile
3717         src/auth/digest/file/Makefile
3718         src/auth/digest/LDAP/Makefile
3719         src/auth/negotiate/Makefile
3720         src/auth/negotiate/kerberos/Makefile
3721         src/auth/negotiate/SSPI/Makefile
3722         src/auth/negotiate/wrapper/Makefile
3723         src/auth/ntlm/Makefile
3724         src/auth/ntlm/fake/Makefile
3725         src/auth/ntlm/SMB_LM/Makefile
3726         src/auth/ntlm/SSPI/Makefile
3727         src/base/Makefile
3728         src/clients/Makefile
3729         src/comm/Makefile
3730         src/dns/Makefile
3731         src/DiskIO/Makefile
3732         src/DiskIO/AIO/Makefile
3733         src/DiskIO/Blocking/Makefile
3734         src/DiskIO/DiskDaemon/Makefile
3735         src/DiskIO/DiskThreads/Makefile
3736         src/DiskIO/IpcIo/Makefile
3737         src/DiskIO/Mmapped/Makefile
3738         src/esi/Makefile
3739         src/eui/Makefile
3740         src/format/Makefile
3741         src/fs/Makefile
3742         src/ftp/Makefile
3743         src/helper/Makefile
3744         src/http/Makefile
3745         src/http/one/Makefile
3746         src/http/url_rewriters/Makefile
3747         src/http/url_rewriters/fake/Makefile
3748         src/http/url_rewriters/LFS/Makefile
3749         src/icmp/Makefile
3750         src/ident/Makefile
3751         src/ip/Makefile
3752         src/ipc/Makefile
3753         src/log/Makefile
3754         src/log/DB/Makefile
3755         src/log/file/Makefile
3756         src/mem/Makefile
3757         src/mgr/Makefile
3758         src/parser/Makefile
3759         src/proxyp/Makefile
3760         src/repl/Makefile
3761         src/sbuf/Makefile
3762         src/security/Makefile
3763         src/security/cert_generators/Makefile
3764         src/security/cert_generators/file/Makefile
3765         src/security/cert_validators/Makefile
3766         src/security/cert_validators/fake/Makefile
3767         src/servers/Makefile
3768         src/snmp/Makefile
3769         src/ssl/Makefile
3770         src/store/Makefile
3771         src/store/id_rewriters/Makefile
3772         src/store/id_rewriters/file/Makefile
3773         test-suite/Makefile
3774         tools/Makefile
3775         tools/apparmor/Makefile
3776         tools/helper-mux/Makefile
3777         tools/purge/Makefile
3778         tools/squidclient/Makefile
3779         tools/systemd/Makefile
3780         tools/sysvinit/Makefile
3781 ])
3782
3783 # must configure libltdl subdir unconditionally for "make distcheck" to work
3784 #AC_CONFIG_SUBDIRS(libltdl)
3785
3786 AC_OUTPUT