configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_PREREQ(2.64)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libhsail-rt \
 155                 target-libatomic \
 156                 target-libitm \
 157                 target-libstdc++-v3 \
 158                 target-libsanitizer \
 159                 target-libvtv \
 160                 target-libssp \
 161                 target-libquadmath \
 162                 target-libgfortran \
 163                 target-libffi \
 164                 target-libobjc \
 165                 target-libada \
 166                 target-libgo \
 167                 target-libphobos"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Disable libhsail-rt on unsupported systems.
 605 if test -d ${srcdir}/libhsail-rt; then
 606     if test x$enable_libhsail_rt = x; then
 607         AC_MSG_CHECKING([for libhsail-rt support])
 608         if (srcdir=${srcdir}/libhsail-rt; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test -n "$UNSUPPORTED")
 611         then
 612             AC_MSG_RESULT([no])
 613             unsupported_languages="$unsupported_languages brig"
 614             # This implicitly disables also target-libhsail-rt as it won't
 615             # get added to the build without BRIG FE.
 616         else
 617             AC_MSG_RESULT([yes])
 618         fi
 619     fi
 620 fi
 621
 622
 623 # Disable libquadmath for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     noconfigdirs="$noconfigdirs target-libquadmath"
 627     ;;
 628   # libquadmath is unused on AIX and libquadmath build process use of
 629   # LD_LIBRARY_PATH can break AIX bootstrap.
 630   powerpc-*-aix* | rs6000-*-aix*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633 esac
 634
 635 # Disable libssp for some systems.
 636 case "${target}" in
 637   avr-*-*)
 638     # No hosted I/O support.
 639     noconfigdirs="$noconfigdirs target-libssp"
 640     ;;
 641   powerpc-*-aix* | rs6000-*-aix*)
 642     noconfigdirs="$noconfigdirs target-libssp"
 643     ;;
 644   rl78-*-*)
 645     # libssp uses a misaligned load to trigger a fault, but the RL78
 646     # doesn't fault for those - instead, it gives a build-time error
 647     # for explicit misaligned loads.
 648     noconfigdirs="$noconfigdirs target-libssp"
 649     ;;
 650   visium-*-*)
 651     # No hosted I/O support.
 652     noconfigdirs="$noconfigdirs target-libssp"
 653     ;;
 654 esac
 655
 656 # Disable libstdc++-v3 for some systems.
 657 # Allow user to override this if they pass --enable-libstdc++-v3
 658 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 659   case "${target}" in
 660     *-*-vxworks*)
 661       # VxWorks uses the Dinkumware C++ library.
 662       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 663       ;;
 664     arm*-wince-pe*)
 665       # the C++ libraries don't build on top of CE's C libraries
 666       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 667       ;;
 668     avr-*-*)
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     ft32-*-*)
 672       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 673       ;;
 674   esac
 675 fi
 676
 677 # Disable Fortran for some systems.
 678 case "${target}" in
 679   mmix-*-*)
 680     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 681     unsupported_languages="$unsupported_languages fortran"
 682     ;;
 683 esac
 684
 685 # Disable libffi for some systems.
 686 case "${target}" in
 687   powerpc-*-darwin*)
 688     ;;
 689   i[[3456789]]86-*-darwin*)
 690     ;;
 691   x86_64-*-darwin[[912]]*)
 692     ;;
 693   *-*-darwin*)
 694     noconfigdirs="$noconfigdirs target-libffi"
 695     ;;
 696   *-*-netware*)
 697     noconfigdirs="$noconfigdirs target-libffi"
 698     ;;
 699   *-*-phoenix*)
 700     noconfigdirs="$noconfigdirs target-libffi"
 701     ;;
 702   *-*-rtems*)
 703     noconfigdirs="$noconfigdirs target-libffi"
 704     ;;
 705   *-*-tpf*)
 706     noconfigdirs="$noconfigdirs target-libffi"
 707     ;;
 708   *-*-uclinux*)
 709     noconfigdirs="$noconfigdirs target-libffi"
 710     ;;
 711   *-*-vxworks*)
 712     noconfigdirs="$noconfigdirs target-libffi"
 713     ;;
 714   aarch64*-*-freebsd*)
 715     noconfigdirs="$noconfigdirs target-libffi"
 716     ;;
 717   alpha*-*-*vms*)
 718     noconfigdirs="$noconfigdirs target-libffi"
 719     ;;
 720   arm*-*-freebsd*)
 721     noconfigdirs="$noconfigdirs target-libffi"
 722     ;;
 723   arm-wince-pe)
 724     noconfigdirs="$noconfigdirs target-libffi"
 725     ;;
 726   arm*-*-symbianelf*)
 727     noconfigdirs="$noconfigdirs target-libffi"
 728     ;;
 729   cris-*-* | crisv32-*-*)
 730     case "${target}" in
 731       *-*-linux*)
 732         ;;
 733       *) # See PR46792 regarding target-libffi.
 734         noconfigdirs="$noconfigdirs target-libffi";;
 735     esac
 736     ;;
 737   hppa*64*-*-hpux*)
 738     noconfigdirs="$noconfigdirs target-libffi"
 739     ;;
 740   hppa*-hp-hpux11*)
 741     ;;
 742   hppa*-*-hpux*)
 743     noconfigdirs="$noconfigdirs target-libffi"
 744     ;;
 745   ia64*-*-*vms*)
 746     noconfigdirs="$noconfigdirs target-libffi"
 747     ;;
 748   i[[3456789]]86-w64-mingw*)
 749     noconfigdirs="$noconfigdirs target-libffi"
 750     ;;
 751   i[[3456789]]86-*-mingw*)
 752     noconfigdirs="$noconfigdirs target-libffi"
 753     ;;
 754   x86_64-*-mingw*)
 755     noconfigdirs="$noconfigdirs target-libffi"
 756     ;;
 757   mmix-*-*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   powerpc-*-aix*)
 761     ;;
 762   rs6000-*-aix*)
 763     ;;
 764   ft32-*-*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   *-*-lynxos*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770 esac
 771
 772 # Disable the go frontend on systems where it is known to not work. Please keep
 773 # this in sync with contrib/config-list.mk.
 774 case "${target}" in
 775 *-*-darwin* | *-*-cygwin* | *-*-mingw*)
 776     unsupported_languages="$unsupported_languages go"
 777     ;;
 778 esac
 779
 780 # Disable libgo for some systems where it is known to not work.
 781 # For testing, you can easily override this with --enable-libgo.
 782 if test x$enable_libgo = x; then
 783     case "${target}" in
 784     *-*-darwin*)
 785         # PR 46986
 786         noconfigdirs="$noconfigdirs target-libgo"
 787         ;;
 788     *-*-cygwin* | *-*-mingw*)
 789         noconfigdirs="$noconfigdirs target-libgo"
 790         ;;
 791     esac
 792 fi
 793
 794 # Default libgloss CPU subdirectory.
 795 libgloss_dir="$target_cpu"
 796
 797 case "${target}" in
 798   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 799     libgloss_dir=wince
 800     ;;
 801   aarch64*-*-* )
 802     libgloss_dir=aarch64
 803     ;;
 804   arm*-*-*)
 805     libgloss_dir=arm
 806     ;;
 807   cris-*-* | crisv32-*-*)
 808     libgloss_dir=cris
 809     ;;
 810   hppa*-*-*)
 811     libgloss_dir=pa
 812     ;;
 813   i[[3456789]]86-*-*)
 814     libgloss_dir=i386
 815     ;;
 816   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 817     libgloss_dir=m68hc11
 818     ;;
 819   m68*-*-* | fido-*-*)
 820     libgloss_dir=m68k
 821     ;;
 822   mips*-*-*)
 823     libgloss_dir=mips
 824     ;;
 825   powerpc*-*-*)
 826     libgloss_dir=rs6000
 827     ;;
 828   sparc*-*-*)
 829     libgloss_dir=sparc
 830     ;;
 831 esac
 832
 833 # Disable newlib and libgloss for various target OSes.
 834 case "${target}" in
 835   alpha*-dec-osf*)
 836     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 837     ;;
 838   i[[3456789]]86-*-linux*)
 839     # This section makes it possible to build newlib natively on linux.
 840     # If we are using a cross compiler then don't configure newlib.
 841     if test x${is_cross_compiler} != xno ; then
 842       noconfigdirs="$noconfigdirs target-newlib"
 843     fi
 844     noconfigdirs="$noconfigdirs target-libgloss"
 845     # If we are not using a cross compiler, do configure newlib.
 846     # Note however, that newlib will only be configured in this situation
 847     # if the --with-newlib option has been given, because otherwise
 848     # 'target-newlib' will appear in skipdirs.
 849     ;;
 850   i[[3456789]]86-*-rdos*)
 851     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 852     ;;
 853   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 854     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 855     ;;
 856   sparc-*-sunos4*)
 857     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 858     ;;
 859   *-*-aix*)
 860     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 861     ;;
 862   *-*-beos*)
 863     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 864     ;;
 865   *-*-chorusos)
 866     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 867     ;;
 868   *-*-dragonfly*)
 869     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 870     ;;
 871   *-*-freebsd*)
 872     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 873     ;;
 874   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 875     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 876     ;;
 877   *-*-lynxos*)
 878     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 879     ;;
 880   *-*-mingw*)
 881     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 882     ;;
 883   *-*-netbsd*)
 884     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 885     ;;
 886   *-*-netware*)
 887     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 888     ;;
 889   *-*-tpf*)
 890     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 891     ;;
 892   *-*-uclinux*)
 893     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 894     ;;
 895   *-*-vxworks*)
 896     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 897     ;;
 898 esac
 899
 900 case "${target}" in
 901   *-*-chorusos)
 902     ;;
 903   aarch64-*-darwin*)
 904     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 905     noconfigdirs="$noconfigdirs sim target-rda"
 906     ;;
 907   arm-*-darwin*)
 908     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 909     noconfigdirs="$noconfigdirs sim target-rda"
 910     ;;
 911   powerpc-*-darwin*)
 912     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 913     noconfigdirs="$noconfigdirs sim target-rda"
 914     ;;
 915   i[[3456789]]86-*-darwin*)
 916     noconfigdirs="$noconfigdirs ld gprof"
 917     noconfigdirs="$noconfigdirs sim target-rda"
 918     ;;
 919   x86_64-*-darwin[[912]]*)
 920     noconfigdirs="$noconfigdirs ld gas gprof"
 921     noconfigdirs="$noconfigdirs sim target-rda"
 922     ;;
 923   *-*-darwin*)
 924     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 925     noconfigdirs="$noconfigdirs sim target-rda"
 926     ;;
 927   *-*-dragonfly*)
 928     ;;
 929   *-*-freebsd*)
 930     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
 931         && test -f /usr/local/include/gmp.h; then
 932       with_gmp=/usr/local
 933     fi
 934     ;;
 935   *-*-kaos*)
 936     # Remove unsupported stuff on all kaOS configurations.
 937     noconfigdirs="$noconfigdirs target-libgloss"
 938     ;;
 939   *-*-netbsd*)
 940     ;;
 941   *-*-netware*)
 942     ;;
 943   *-*-phoenix*)
 944     noconfigdirs="$noconfigdirs target-libgloss"
 945     ;;
 946   *-*-rtems*)
 947     noconfigdirs="$noconfigdirs target-libgloss"
 948     ;;
 949     # The tpf target doesn't support gdb yet.
 950   *-*-tpf*)
 951     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
 952     ;;
 953   *-*-uclinux*)
 954     noconfigdirs="$noconfigdirs target-rda"
 955     ;;
 956   *-*-vxworks*)
 957     ;;
 958   alpha*-dec-osf*)
 959     # ld works, but does not support shared libraries.
 960     # gas doesn't generate exception information.
 961     noconfigdirs="$noconfigdirs gas ld"
 962     ;;
 963   alpha*-*-*vms*)
 964     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
 965     ;;
 966   alpha*-*-*)
 967     # newlib is not 64 bit ready
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 971     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
 972     ;;
 973   arc*-*-*)
 974     noconfigdirs="$noconfigdirs sim"
 975     ;;
 976   arm-*-pe*)
 977     noconfigdirs="$noconfigdirs target-libgloss"
 978     ;;
 979   arm-*-riscix*)
 980     noconfigdirs="$noconfigdirs ld target-libgloss"
 981     ;;
 982   avr-*-*)
 983     if test x${with_avrlibc} != xno; then
 984       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 985     fi
 986     ;;
 987   c4x-*-* | tic4x-*-*)
 988     noconfigdirs="$noconfigdirs target-libgloss"
 989     ;;
 990   tic54x-*-*)
 991     noconfigdirs="$noconfigdirs target-libgloss gdb"
 992     ;;
 993   d10v-*-*)
 994     noconfigdirs="$noconfigdirs target-libgloss"
 995     ;;
 996   d30v-*-*)
 997     noconfigdirs="$noconfigdirs gdb"
 998     ;;
 999   fr30-*-elf*)
1000     noconfigdirs="$noconfigdirs gdb"
1001     ;;
1002   ft32-*-*)
1003     noconfigdirs="$noconfigdirs target-rda gprof"
1004     ;;
1005   moxie-*-*)
1006     noconfigdirs="$noconfigdirs"
1007     ;;
1008   h8300*-*-*)
1009     noconfigdirs="$noconfigdirs target-libgloss"
1010     ;;
1011   h8500-*-*)
1012     noconfigdirs="$noconfigdirs target-libgloss"
1013     ;;
1014   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1015     ;;
1016   hppa*64*-*-hpux*)
1017     noconfigdirs="$noconfigdirs gdb"
1018     ;;
1019   hppa*-*-hpux11*)
1020     noconfigdirs="$noconfigdirs gdb ld"
1021     ;;
1022   hppa*64*-*-linux*)
1023     ;;
1024   hppa*-*-linux*)
1025     ;;
1026   hppa*-*-*elf* | \
1027   hppa*-*-lites* | \
1028   hppa*-*-openbsd* | \
1029   hppa*64*-*-*)
1030     ;;
1031   hppa*-*-pro*)
1032     ;;
1033   hppa*-*-*)
1034     noconfigdirs="$noconfigdirs ld"
1035     ;;
1036   i960-*-*)
1037     noconfigdirs="$noconfigdirs gdb"
1038     ;;
1039   ia64*-*-elf*)
1040     # No gdb support yet.
1041     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1042     ;;
1043   ia64*-**-hpux*)
1044     # No ld support yet.
1045     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1046     ;;
1047   ia64*-*-*vms*)
1048     # No ld support yet.
1049     noconfigdirs="$noconfigdirs libgui itcl ld"
1050     ;;
1051   i[[3456789]]86-w64-mingw*)
1052     ;;
1053   i[[3456789]]86-*-mingw*)
1054     target_configdirs="$target_configdirs target-winsup"
1055     ;;
1056   *-*-cygwin*)
1057     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1058     noconfigdirs="$noconfigdirs target-libgloss"
1059     # always build newlib if winsup directory is present.
1060     if test -d "$srcdir/winsup/cygwin"; then
1061       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1062     elif test -d "$srcdir/newlib"; then
1063       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1064     fi
1065     ;;
1066   i[[3456789]]86-*-pe)
1067     noconfigdirs="$noconfigdirs target-libgloss"
1068     ;;
1069   i[[3456789]]86-*-sco3.2v5*)
1070     # The linker does not yet know about weak symbols in COFF,
1071     # and is not configured to handle mixed ELF and COFF.
1072     noconfigdirs="$noconfigdirs ld target-libgloss"
1073     ;;
1074   i[[3456789]]86-*-sco*)
1075     noconfigdirs="$noconfigdirs gprof target-libgloss"
1076     ;;
1077   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1078     noconfigdirs="$noconfigdirs target-libgloss"
1079     ;;
1080   i[[3456789]]86-*-sysv4*)
1081     noconfigdirs="$noconfigdirs target-libgloss"
1082     ;;
1083   i[[3456789]]86-*-beos*)
1084     noconfigdirs="$noconfigdirs gdb"
1085     ;;
1086   i[[3456789]]86-*-rdos*)
1087     noconfigdirs="$noconfigdirs gdb"
1088     ;;
1089   mmix-*-*)
1090     noconfigdirs="$noconfigdirs gdb"
1091     ;;
1092   mt-*-*)
1093     noconfigdirs="$noconfigdirs sim"
1094     ;;
1095   nfp-*-*)
1096     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1097     noconfigdirs="$noconfigdirs $target_libraries"
1098     ;;
1099   powerpc-*-aix*)
1100     # copied from rs6000-*-* entry
1101     noconfigdirs="$noconfigdirs gprof"
1102     ;;
1103   powerpc*-*-winnt* | powerpc*-*-pe*)
1104     target_configdirs="$target_configdirs target-winsup"
1105     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1106     # always build newlib.
1107     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1108     ;;
1109     # This is temporary until we can link against shared libraries
1110   powerpcle-*-solaris*)
1111     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1112     ;;
1113   powerpc-*-beos*)
1114     noconfigdirs="$noconfigdirs gdb"
1115     ;;
1116   rs6000-*-lynxos*)
1117     noconfigdirs="$noconfigdirs gprof"
1118     ;;
1119   rs6000-*-aix*)
1120     noconfigdirs="$noconfigdirs gprof"
1121     ;;
1122   rs6000-*-*)
1123     noconfigdirs="$noconfigdirs gprof"
1124     ;;
1125   m68k-apollo-*)
1126     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1127     ;;
1128   microblaze*)
1129     noconfigdirs="$noconfigdirs gprof"
1130     ;;
1131   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1132     if test x$with_newlib = xyes; then
1133       noconfigdirs="$noconfigdirs gprof"
1134     fi
1135     ;;
1136   mips*-*-irix5*)
1137     noconfigdirs="$noconfigdirs gprof target-libgloss"
1138     ;;
1139   mips*-*-irix6*)
1140     noconfigdirs="$noconfigdirs gprof target-libgloss"
1141     ;;
1142   mips*-*-bsd*)
1143     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1144     ;;
1145   mips*-*-linux*)
1146     ;;
1147   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1148   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1149     noconfigdirs="$noconfigdirs ld gas gprof"
1150     ;;
1151   mips*-*-*)
1152     noconfigdirs="$noconfigdirs gprof"
1153     ;;
1154   nvptx*-*-*)
1155     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1156     ;;
1157   sh-*-*)
1158     case "${target}" in
1159       sh*-*-elf)
1160          ;;
1161       *)
1162          noconfigdirs="$noconfigdirs target-libgloss" ;;
1163     esac
1164     ;;
1165   sparc-*-sunos4*)
1166     if test x${is_cross_compiler} = xno ; then
1167            use_gnu_ld=no
1168     fi
1169     ;;
1170   tic6x-*-*)
1171     noconfigdirs="$noconfigdirs sim"
1172     ;;
1173   tilepro*-*-* | tilegx*-*-*)
1174     noconfigdirs="$noconfigdirs sim"
1175     ;;
1176   v810-*-*)
1177     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1178     ;;
1179   vax-*-*)
1180     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1181     ;;
1182   wasm32-*-*)
1183     noconfigdirs="$noconfigdirs ld"
1184     ;;
1185 esac
1186
1187 # If we aren't building newlib, then don't build libgloss, since libgloss
1188 # depends upon some newlib header files.
1189 case "${noconfigdirs}" in
1190   *target-libgloss*) ;;
1191   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1192 esac
1193
1194 # Work in distributions that contain no compiler tools, like Autoconf.
1195 host_makefile_frag=/dev/null
1196 if test -d ${srcdir}/config ; then
1197 case "${host}" in
1198   i[[3456789]]86-*-msdosdjgpp*)
1199     host_makefile_frag="config/mh-djgpp"
1200     ;;
1201   *-cygwin*)
1202     ACX_CHECK_CYGWIN_CAT_WORKS
1203     host_makefile_frag="config/mh-cygwin"
1204     ;;
1205   *-mingw*)
1206     host_makefile_frag="config/mh-mingw"
1207     ;;
1208   alpha*-linux*)
1209     host_makefile_frag="config/mh-alpha-linux"
1210     ;;
1211   hppa*-hp-hpux10*)
1212     host_makefile_frag="config/mh-pa-hpux10"
1213     ;;
1214   hppa*-hp-hpux*)
1215     host_makefile_frag="config/mh-pa"
1216     ;;
1217   hppa*-*)
1218     host_makefile_frag="config/mh-pa"
1219     ;;
1220   *-*-darwin*)
1221     host_makefile_frag="config/mh-darwin"
1222     ;;
1223   powerpc-*-aix*)
1224     host_makefile_frag="config/mh-ppc-aix"
1225     ;;
1226   rs6000-*-aix*)
1227     host_makefile_frag="config/mh-ppc-aix"
1228     ;;
1229 esac
1230 fi
1231
1232 if test "${build}" != "${host}" ; then
1233   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1234   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1235   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1236   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1237   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1238   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1239   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1240   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1241   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1242   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1243   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1244   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1245   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1246 else
1247   AR_FOR_BUILD="\$(AR)"
1248   AS_FOR_BUILD="\$(AS)"
1249   CC_FOR_BUILD="\$(CC)"
1250   CXX_FOR_BUILD="\$(CXX)"
1251   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1252   GOC_FOR_BUILD="\$(GOC)"
1253   GDC_FOR_BUILD="\$(GDC)"
1254   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1255   LD_FOR_BUILD="\$(LD)"
1256   NM_FOR_BUILD="\$(NM)"
1257   RANLIB_FOR_BUILD="\$(RANLIB)"
1258   WINDRES_FOR_BUILD="\$(WINDRES)"
1259   WINDMC_FOR_BUILD="\$(WINDMC)"
1260 fi
1261
1262 AC_PROG_CC
1263 AC_PROG_CXX
1264
1265 # We must set the default linker to the linker used by gcc for the correct
1266 # operation of libtool.  If LD is not defined and we are using gcc, try to
1267 # set the LD default to the ld used by gcc.
1268 if test -z "$LD"; then
1269   if test "$GCC" = yes; then
1270     case $build in
1271     *-*-mingw*)
1272       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1273     *)
1274       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1275     esac
1276     case $gcc_prog_ld in
1277     # Accept absolute paths.
1278     [[\\/]* | [A-Za-z]:[\\/]*)]
1279       LD="$gcc_prog_ld" ;;
1280     esac
1281   fi
1282 fi
1283
1284 # Check whether -static-libstdc++ -static-libgcc is supported.
1285 have_static_libs=no
1286 if test "$GCC" = yes; then
1287   saved_LDFLAGS="$LDFLAGS"
1288
1289   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1290   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1291   AC_LANG_PUSH(C++)
1292   AC_LINK_IFELSE([
1293 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1294 #error -static-libstdc++ not implemented
1295 #endif
1296 int main() {}],
1297     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1298     [AC_MSG_RESULT([no])])
1299   AC_LANG_POP(C++)
1300
1301   LDFLAGS="$saved_LDFLAGS"
1302 fi
1303
1304 ACX_PROG_GNAT
1305 ACX_PROG_CMP_IGNORE_INITIAL
1306
1307 AC_ARG_ENABLE([bootstrap],
1308 [AS_HELP_STRING([--enable-bootstrap],
1309                 [enable bootstrapping @<:@yes if native build@:>@])],,
1310 enable_bootstrap=default)
1311
1312 # Issue errors and warnings for invalid/strange bootstrap combinations.
1313 if test -r $srcdir/gcc/configure; then
1314   have_compiler=yes
1315 else
1316   have_compiler=no
1317 fi
1318
1319 case "$have_compiler:$host:$target:$enable_bootstrap" in
1320   *:*:*:no) ;;
1321
1322   # Default behavior.  Enable bootstrap if we have a compiler
1323   # and we are in a native configuration.
1324   yes:$build:$build:default)
1325     enable_bootstrap=yes ;;
1326
1327   *:*:*:default)
1328     enable_bootstrap=no ;;
1329
1330   # We have a compiler and we are in a native configuration, bootstrap is ok
1331   yes:$build:$build:yes)
1332     ;;
1333
1334   # Other configurations, but we have a compiler.  Assume the user knows
1335   # what he's doing.
1336   yes:*:*:yes)
1337     AC_MSG_WARN([trying to bootstrap a cross compiler])
1338     ;;
1339
1340   # No compiler: if they passed --enable-bootstrap explicitly, fail
1341   no:*:*:yes)
1342     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1343
1344   # Fail if wrong command line
1345   *)
1346     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1347     ;;
1348 esac
1349
1350 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1351 # C++98 compiler can still start the bootstrap.
1352 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1353   CXX="$CXX -std=gnu++98"
1354 fi
1355
1356 # Used for setting $lt_cv_objdir
1357 _LT_CHECK_OBJDIR
1358
1359 # Check for GMP, MPFR and MPC
1360 gmplibs="-lmpc -lmpfr -lgmp"
1361 gmpinc=
1362 have_gmp=no
1363
1364 # Specify a location for mpc
1365 # check for this first so it ends up on the link line before mpfr.
1366 AC_ARG_WITH(mpc,
1367 [AS_HELP_STRING([--with-mpc=PATH],
1368                 [specify prefix directory for installed MPC package.
1369                  Equivalent to --with-mpc-include=PATH/include
1370                  plus --with-mpc-lib=PATH/lib])])
1371 AC_ARG_WITH(mpc-include,
1372 [AS_HELP_STRING([--with-mpc-include=PATH],
1373                 [specify directory for installed MPC include files])])
1374 AC_ARG_WITH(mpc-lib,
1375 [AS_HELP_STRING([--with-mpc-lib=PATH],
1376                 [specify directory for the installed MPC library])])
1377
1378 if test "x$with_mpc" != x; then
1379   gmplibs="-L$with_mpc/lib $gmplibs"
1380   gmpinc="-I$with_mpc/include $gmpinc"
1381 fi
1382 if test "x$with_mpc_include" != x; then
1383   gmpinc="-I$with_mpc_include $gmpinc"
1384 fi
1385 if test "x$with_mpc_lib" != x; then
1386   gmplibs="-L$with_mpc_lib $gmplibs"
1387 fi
1388 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1389   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1390   gmpinc='-I$$s/mpc/src '"$gmpinc"
1391   # Do not test the mpc version.  Assume that it is sufficient, since
1392   # it is in the source tree, and the library has not been built yet
1393   # but it would be included on the link line in the version check below
1394   # hence making the test fail.
1395   have_gmp=yes
1396 fi
1397
1398 # Specify a location for mpfr
1399 # check for this first so it ends up on the link line before gmp.
1400 AC_ARG_WITH(mpfr-dir,
1401 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1402 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1403 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1404
1405 AC_ARG_WITH(mpfr,
1406 [AS_HELP_STRING([--with-mpfr=PATH],
1407                 [specify prefix directory for installed MPFR package.
1408                  Equivalent to --with-mpfr-include=PATH/include
1409                  plus --with-mpfr-lib=PATH/lib])])
1410 AC_ARG_WITH(mpfr-include,
1411 [AS_HELP_STRING([--with-mpfr-include=PATH],
1412                 [specify directory for installed MPFR include files])])
1413 AC_ARG_WITH(mpfr-lib,
1414 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1415                 [specify directory for the installed MPFR library])])
1416
1417 if test "x$with_mpfr" != x; then
1418   gmplibs="-L$with_mpfr/lib $gmplibs"
1419   gmpinc="-I$with_mpfr/include $gmpinc"
1420 fi
1421 if test "x$with_mpfr_include" != x; then
1422   gmpinc="-I$with_mpfr_include $gmpinc"
1423 fi
1424 if test "x$with_mpfr_lib" != x; then
1425   gmplibs="-L$with_mpfr_lib $gmplibs"
1426 fi
1427 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1428   # MPFR v3.1.0 moved the sources into a src sub-directory.
1429   if ! test -d ${srcdir}/mpfr/src; then
1430     AC_MSG_ERROR([dnl
1431 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1432   fi
1433   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1434   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1435   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1436   # Do not test the mpfr version.  Assume that it is sufficient, since
1437   # it is in the source tree, and the library has not been built yet
1438   # but it would be included on the link line in the version check below
1439   # hence making the test fail.
1440   have_gmp=yes
1441 fi
1442
1443 # Specify a location for gmp
1444 AC_ARG_WITH(gmp-dir,
1445 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1446 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1447 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1448
1449 AC_ARG_WITH(gmp,
1450 [AS_HELP_STRING([--with-gmp=PATH],
1451                 [specify prefix directory for the installed GMP package.
1452                  Equivalent to --with-gmp-include=PATH/include
1453                  plus --with-gmp-lib=PATH/lib])])
1454 AC_ARG_WITH(gmp-include,
1455 [AS_HELP_STRING([--with-gmp-include=PATH],
1456                 [specify directory for installed GMP include files])])
1457 AC_ARG_WITH(gmp-lib,
1458 [AS_HELP_STRING([--with-gmp-lib=PATH],
1459                 [specify directory for the installed GMP library])])
1460
1461
1462 if test "x$with_gmp" != x; then
1463   gmplibs="-L$with_gmp/lib $gmplibs"
1464   gmpinc="-I$with_gmp/include $gmpinc"
1465 fi
1466 if test "x$with_gmp_include" != x; then
1467   gmpinc="-I$with_gmp_include $gmpinc"
1468 fi
1469 if test "x$with_gmp_lib" != x; then
1470   gmplibs="-L$with_gmp_lib $gmplibs"
1471 fi
1472 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1473   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1474   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1475   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1476   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1477   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1478   # Do not test the gmp version.  Assume that it is sufficient, since
1479   # it is in the source tree, and the library has not been built yet
1480   # but it would be included on the link line in the version check below
1481   # hence making the test fail.
1482   have_gmp=yes
1483 fi
1484
1485 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1486   have_gmp=yes
1487   saved_CFLAGS="$CFLAGS"
1488   CFLAGS="$CFLAGS $gmpinc"
1489   # Check for the recommended and required versions of GMP.
1490   AC_MSG_CHECKING([for the correct version of gmp.h])
1491   AC_TRY_COMPILE([#include "gmp.h"],[
1492   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1493   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1494   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1495   choke me
1496   #endif
1497   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1498   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1499   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1500   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1501   choke me
1502   #endif
1503   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1504    [AC_MSG_RESULT([no]); have_gmp=no])
1505
1506   # If we have GMP, check the MPFR version.
1507   if test x"$have_gmp" = xyes; then
1508     # Check for the recommended and required versions of MPFR.
1509     AC_MSG_CHECKING([for the correct version of mpfr.h])
1510     AC_TRY_COMPILE([#include <gmp.h>
1511     #include <mpfr.h>],[
1512     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,0)
1513     choke me
1514     #endif
1515     ], [AC_TRY_COMPILE([#include <gmp.h>
1516     #include <mpfr.h>],[
1517     #if MPFR_VERSION < MPFR_VERSION_NUM(2,4,2)
1518     choke me
1519     #endif
1520     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1521      [AC_MSG_RESULT([no]); have_gmp=no])
1522   fi
1523
1524   # Check for the MPC header version.
1525   if test x"$have_gmp" = xyes ; then
1526     # Check for the recommended and required versions of MPC.
1527     AC_MSG_CHECKING([for the correct version of mpc.h])
1528     AC_TRY_COMPILE([#include <mpc.h>],[
1529     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1530     choke me
1531     #endif
1532     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1533     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1534     choke me
1535     #endif
1536     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1537      [AC_MSG_RESULT([no]); have_gmp=no])
1538   fi
1539
1540   # Now check the MPFR library.
1541   if test x"$have_gmp" = xyes; then
1542     saved_LIBS="$LIBS"
1543     LIBS="$LIBS $gmplibs"
1544     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1545     AC_TRY_LINK([#include <mpc.h>],[
1546     mpfr_t n;
1547     mpfr_t x;
1548     mpc_t c;
1549     int t;
1550     mpfr_init (n);
1551     mpfr_init (x);
1552     mpfr_atan2 (n, n, x, GMP_RNDN);
1553     mpfr_erfc (n, x, GMP_RNDN);
1554     mpfr_subnormalize (x, t, GMP_RNDN);
1555     mpfr_clear(n);
1556     mpfr_clear(x);
1557     mpc_init2 (c, 53);
1558     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1559     mpc_cosh (c, c, MPC_RNDNN);
1560     mpc_pow (c, c, c, MPC_RNDNN);
1561     mpc_acosh (c, c, MPC_RNDNN);
1562     mpc_clear (c);
1563     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1564     LIBS="$saved_LIBS"
1565   fi
1566
1567   CFLAGS="$saved_CFLAGS"
1568
1569 # The library versions listed in the error message below should match
1570 # the HARD-minimums enforced above.
1571   if test x$have_gmp != xyes; then
1572     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 2.4.0+ and MPC 0.8.0+.
1573 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1574 their locations.  Source code for these libraries can be found at
1575 their respective hosting sites as well as at
1576 ftp://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1577 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1578 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1579 make sure that you have installed both the libraries and the header
1580 files.  They may be located in separate packages.])
1581   fi
1582 fi
1583
1584 # Flags needed for both GMP, MPFR and/or MPC.
1585 AC_SUBST(gmplibs)
1586 AC_SUBST(gmpinc)
1587 AC_SUBST(extra_mpfr_configure_flags)
1588 AC_SUBST(extra_mpc_gmp_configure_flags)
1589 AC_SUBST(extra_mpc_mpfr_configure_flags)
1590 AC_SUBST(extra_isl_gmp_configure_flags)
1591
1592 # Libraries to use for stage1 or when not bootstrapping.
1593 AC_ARG_WITH(stage1-libs,
1594 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1595 [if test "$withval" = "no" -o "$withval" = "yes"; then
1596    stage1_libs=
1597  else
1598    stage1_libs=$withval
1599  fi],
1600 [stage1_libs=])
1601 AC_SUBST(stage1_libs)
1602
1603 # Linker flags to use for stage1 or when not bootstrapping.
1604 AC_ARG_WITH(stage1-ldflags,
1605 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1606 [if test "$withval" = "no" -o "$withval" = "yes"; then
1607    stage1_ldflags=
1608  else
1609    stage1_ldflags=$withval
1610  fi],
1611 [stage1_ldflags=
1612  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1613  # if supported.  But if the user explicitly specified the libraries to use,
1614  # trust that they are doing what they want.
1615  if test "$stage1_libs" = "" -a "$have_static_libs" = yes; then
1616    stage1_ldflags="-static-libstdc++ -static-libgcc"
1617  fi])
1618 AC_SUBST(stage1_ldflags)
1619
1620 # Libraries to use for stage2 and later builds.
1621 AC_ARG_WITH(boot-libs,
1622 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1623 [if test "$withval" = "no" -o "$withval" = "yes"; then
1624    poststage1_libs=
1625  else
1626    poststage1_libs=$withval
1627  fi],
1628 [poststage1_libs=])
1629 AC_SUBST(poststage1_libs)
1630
1631 # Linker flags to use for stage2 and later builds.
1632 AC_ARG_WITH(boot-ldflags,
1633 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1634                 [linker flags for stage2 and later])],
1635 [if test "$withval" = "no" -o "$withval" = "yes"; then
1636    poststage1_ldflags=
1637  else
1638    poststage1_ldflags=$withval
1639  fi],
1640 [poststage1_ldflags=
1641  # In stages 2 and 3, default to linking libstdc++ and libgcc
1642  # statically.  But if the user explicitly specified the libraries to
1643  # use, trust that they are doing what they want.
1644  if test "$poststage1_libs" = ""; then
1645    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1646  fi])
1647 AC_SUBST(poststage1_ldflags)
1648
1649 # GCC GRAPHITE dependency isl.
1650 # Basic setup is inlined here, actual checks are in config/isl.m4
1651
1652 AC_ARG_WITH(isl,
1653   [AS_HELP_STRING(
1654    [--with-isl=PATH],
1655    [Specify prefix directory for the installed isl package.
1656     Equivalent to --with-isl-include=PATH/include
1657     plus --with-isl-lib=PATH/lib])])
1658
1659 # Treat --without-isl as a request to disable
1660 # GRAPHITE support and skip all following checks.
1661 if test "x$with_isl" != "xno"; then
1662   # Check for isl
1663   dnl Provide configure switches and initialize islinc & isllibs
1664   dnl with user input.
1665   ISL_INIT_FLAGS
1666   dnl The versions of isl that work for Graphite
1667   ISL_CHECK_VERSION()
1668   dnl Only execute fail-action, if isl has been requested.
1669   ISL_IF_FAILED([
1670     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1671 fi
1672
1673 # If the isl check failed, disable builds of in-tree variant of isl
1674 if test "x$with_isl" = xno ||
1675    test "x$gcc_cv_isl" = xno; then
1676   noconfigdirs="$noconfigdirs isl"
1677   islinc=
1678 fi
1679
1680 AC_SUBST(isllibs)
1681 AC_SUBST(islinc)
1682
1683 # Check for LTO support.
1684 AC_ARG_ENABLE(lto,
1685 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1686 enable_lto=$enableval,
1687 enable_lto=yes; default_enable_lto=yes)
1688
1689 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1690   build_lto_plugin=yes
1691 ],[if test x"$default_enable_lto" = x"yes" ; then
1692     case $target in
1693       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1694       # On other non-ELF platforms, LTO has yet to be validated.
1695       *) enable_lto=no ;;
1696     esac
1697   else
1698   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1699   # It would also be nice to check the binutils support, but we don't
1700   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1701   # warn during gcc/ subconfigure; unless you're bootstrapping with
1702   # -flto it won't be needed until after installation anyway.
1703     case $target in
1704       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1705       *) if test x"$enable_lto" = x"yes"; then
1706         AC_MSG_ERROR([LTO support is not enabled for this target.])
1707         fi
1708       ;;
1709     esac
1710   fi
1711   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1712   # Build it unless LTO was explicitly disabled.
1713   case $target in
1714     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1715     *) ;;
1716   esac
1717 ])
1718
1719 AC_ARG_ENABLE(linker-plugin-configure-flags,
1720   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1721     [additional flags for configuring linker plugins @<:@none@:>@])],
1722   extra_linker_plugin_configure_flags=$enableval,
1723   extra_linker_plugin_configure_flags=)
1724 AC_SUBST(extra_linker_plugin_configure_flags)
1725 AC_ARG_ENABLE(linker-plugin-flags,
1726   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1727     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1728   extra_linker_plugin_flags=$enableval,
1729   extra_linker_plugin_flags=)
1730 AC_SUBST(extra_linker_plugin_flags)
1731
1732 # Enable --enable-host-shared.
1733 # Checked early to determine whether jit is an 'all' language
1734 AC_ARG_ENABLE(host-shared,
1735 [AS_HELP_STRING([--enable-host-shared],
1736                 [build host code as shared libraries])],
1737 [host_shared=$enableval], [host_shared=no])
1738 AC_SUBST(host_shared)
1739
1740 # By default, C and C++ are the only stage 1 languages.
1741 stage1_languages=,c,
1742
1743 # Target libraries that we bootstrap.
1744 bootstrap_target_libs=,target-libgcc,
1745
1746 # Figure out what language subdirectories are present.
1747 # Look if the user specified --enable-languages="..."; if not, use
1748 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1749 # go away some day.
1750 # NB:  embedded tabs in this IF block -- do not untabify
1751 if test -d ${srcdir}/gcc; then
1752   if test x"${enable_languages+set}" != xset; then
1753     if test x"${LANGUAGES+set}" = xset; then
1754       enable_languages="${LANGUAGES}"
1755         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1756     else
1757       enable_languages=default
1758     fi
1759   else
1760     if test x"${enable_languages}" = x ||
1761        test x"${enable_languages}" = xyes;
1762        then
1763       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1764       exit 1
1765     fi
1766   fi
1767   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1768
1769   # 'f95' is the old name for the 'fortran' language. We issue a warning
1770   # and make the substitution.
1771   case ,${enable_languages}, in
1772     *,f95,*)
1773       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1774       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1775       ;;
1776   esac
1777
1778   # If bootstrapping, C++ must be enabled.
1779   case ",$enable_languages,:$enable_bootstrap" in
1780     *,c++,*:*) ;;
1781     *:yes)
1782       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1783         enable_languages="${enable_languages},c++"
1784       else
1785         AC_MSG_ERROR([bootstrapping requires c++ sources])
1786       fi
1787       ;;
1788   esac
1789
1790   # First scan to see if an enabled language requires some other language.
1791   # We assume that a given config-lang.in will list all the language
1792   # front ends it requires, even if some are required indirectly.
1793   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1794     case ${lang_frag} in
1795       ..) ;;
1796       # The odd quoting in the next line works around
1797       # an apparent bug in bash 1.12 on linux.
1798       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1799       *)
1800         # From the config-lang.in, get $language, $lang_requires, and
1801         # $lang_requires_boot_languages.
1802         language=
1803         lang_requires=
1804         lang_requires_boot_languages=
1805         # set srcdir during sourcing lang_frag to the gcc dir.
1806         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1807         # polutes this shell
1808         saved_srcdir=${srcdir}
1809         srcdir=${srcdir}/gcc . ${lang_frag}
1810         srcdir=${saved_srcdir}
1811         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1812           case ,${enable_languages}, in
1813             *,$other,*) ;;
1814             *,default,*) ;;
1815             *,all,*) ;;
1816             *,$language,*)
1817               echo " \`$other' language required by \`$language'; enabling" 1>&2
1818               enable_languages="${enable_languages},${other}"
1819               ;;
1820           esac
1821         done
1822         for other in ${lang_requires_boot_languages} ; do
1823           if test "$other" != "c"; then
1824             case ,${enable_stage1_languages}, in
1825               *,$other,*) ;;
1826               *,default,*) ;;
1827               *,all,*) ;;
1828               *)
1829                 case ,${enable_languages}, in
1830                   *,$language,*)
1831                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1832                     enable_stage1_languages="$enable_stage1_languages,${other}"
1833                     ;;
1834                 esac
1835                 ;;
1836             esac
1837           fi
1838         done
1839         ;;
1840     esac
1841   done
1842
1843   new_enable_languages=,c,
1844
1845   # If LTO is enabled, add the LTO front end.
1846   if test "$enable_lto" = "yes" ; then
1847     case ,${enable_languages}, in
1848       *,lto,*) ;;
1849       *) enable_languages="${enable_languages},lto" ;;
1850     esac
1851     if test "${build_lto_plugin}" = "yes" ; then
1852       configdirs="$configdirs lto-plugin"
1853     fi
1854   fi
1855
1856   # If we're building an offloading compiler, add the LTO front end.
1857   if test x"$enable_as_accelerator_for" != x ; then
1858     case ,${enable_languages}, in
1859       *,lto,*) ;;
1860       *) enable_languages="${enable_languages},lto" ;;
1861     esac
1862   fi
1863
1864   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1865   potential_languages=,c,
1866
1867   enabled_target_libs=
1868   disabled_target_libs=
1869
1870   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1871     case ${lang_frag} in
1872       ..) ;;
1873       # The odd quoting in the next line works around
1874       # an apparent bug in bash 1.12 on linux.
1875       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1876       *)
1877         # From the config-lang.in, get $language, $target_libs,
1878         # $lang_dirs, $boot_language, and $build_by_default
1879         language=
1880         target_libs=
1881         lang_dirs=
1882         subdir_requires=
1883         boot_language=no
1884         build_by_default=yes
1885         # set srcdir during sourcing.  See above about save & restore
1886         saved_srcdir=${srcdir}
1887         srcdir=${srcdir}/gcc . ${lang_frag}
1888         srcdir=${saved_srcdir}
1889         if test x${language} = x; then
1890           echo "${lang_frag} doesn't set \$language." 1>&2
1891           exit 1
1892         fi
1893
1894         if test "$language" = "c++"; then
1895           boot_language=yes
1896         fi
1897
1898         add_this_lang=no
1899         # C is always enabled, so no need to add it again
1900         if test "$language" != "c"; then
1901           case ,${enable_languages}, in
1902             *,${language},*)
1903               # Language was explicitly selected; include it
1904               add_this_lang=yes
1905               ;;
1906             *,all,*)
1907               # All languages are enabled
1908               add_this_lang=all
1909               ;;
1910             *,default,*)
1911               # 'default' was selected, select it if it is a default language
1912               add_this_lang=${build_by_default}
1913               ;;
1914           esac
1915         fi
1916
1917         # Disable languages that need other directories if these aren't available.
1918         for i in $subdir_requires; do
1919           test -f "$srcdir/gcc/$i/config-lang.in" && continue
1920           case ${add_this_lang} in
1921             yes)
1922               # Specifically requested language; tell them.
1923               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
1924               ;;
1925             all)
1926               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
1927               add_this_lang=unsupported
1928               ;;
1929             *)
1930               # Silently disable.
1931               add_this_lang=unsupported
1932               ;;
1933           esac
1934         done
1935
1936         # Disable Ada if no preexisting GNAT is available.
1937         case ${add_this_lang}:${language}:${have_gnat} in
1938           yes:ada:no)
1939             # Specifically requested language; tell them.
1940             AC_MSG_ERROR([GNAT is required to build $language])
1941             ;;
1942           all:ada:no)
1943             AC_MSG_WARN([GNAT is required to build $language])
1944             add_this_lang=unsupported
1945             ;;
1946           *:ada:no)
1947             # Silently disable.
1948             add_this_lang=unsupported
1949             ;;
1950         esac
1951
1952         # Disable jit if -enable-host-shared not specified
1953         case ${add_this_lang}:${language}:${host_shared} in
1954           yes:jit:no)
1955             # PR jit/64780: explicitly specify --enable-host-shared
1956             AC_MSG_ERROR([
1957 Enabling language "jit" requires --enable-host-shared.
1958
1959 --enable-host-shared typically slows the rest of the compiler down by
1960 a few %, so you must explicitly enable it.
1961
1962 If you want to build both the jit and the regular compiler, it is often
1963 best to do this via two separate configure/builds, in separate
1964 directories, to avoid imposing the performance cost of
1965 --enable-host-shared on the regular compiler.])
1966             ;;
1967           all:jit:no)
1968             AC_MSG_WARN([--enable-host-shared required to build $language])
1969             add_this_lang=unsupported
1970             ;;
1971           *:jit:no)
1972             # Silently disable.
1973             add_this_lang=unsupported
1974             ;;
1975         esac
1976
1977         # Disable a language that is unsupported by the target.
1978         case "${add_this_lang}: $unsupported_languages " in
1979           no:*) ;;
1980           unsupported:*) ;;
1981           *:*" $language "*)
1982             AC_MSG_WARN([${language} not supported for this target])
1983             add_this_lang=unsupported
1984             ;;
1985         esac
1986
1987         case $add_this_lang in
1988           unsupported)
1989             # Remove language-dependent dirs.
1990             disabled_target_libs="$disabled_target_libs $target_libs"
1991             noconfigdirs="$noconfigdirs $lang_dirs"
1992             ;;
1993           no)
1994             # Remove language-dependent dirs; still show language as supported.
1995             disabled_target_libs="$disabled_target_libs $target_libs"
1996             noconfigdirs="$noconfigdirs $lang_dirs"
1997             potential_languages="${potential_languages}${language},"
1998             ;;
1999           all|yes)
2000             new_enable_languages="${new_enable_languages}${language},"
2001             potential_languages="${potential_languages}${language},"
2002             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2003             enabled_target_libs="$enabled_target_libs $target_libs"
2004             case "${boot_language}:,$enable_stage1_languages," in
2005               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2006                 # Add to (comma-separated) list of stage 1 languages.
2007                 case ",$stage1_languages," in
2008                   *,$language,* | ,yes, | ,all,) ;;
2009                   *) stage1_languages="${stage1_languages}${language}," ;;
2010                 esac
2011                 # We need to bootstrap any supporting libraries.
2012                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2013                 ;;
2014             esac
2015             ;;
2016         esac
2017         ;;
2018     esac
2019   done
2020
2021   # Add target libraries which are only needed for disabled languages
2022   # to noconfigdirs.
2023   if test -n "$disabled_target_libs"; then
2024     for dir in $disabled_target_libs; do
2025       case " $enabled_target_libs " in
2026       *" ${dir} "*) ;;
2027       *) noconfigdirs="$noconfigdirs $dir" ;;
2028       esac
2029     done
2030   fi
2031
2032   AC_ARG_ENABLE(stage1-languages,
2033   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2034                   [choose additional languages to build during
2035                   stage1.  Mostly useful for compiler development])],
2036   [case ,${enable_stage1_languages}, in
2037     ,no,|,,)
2038       # Set it to something that will have no effect in the loop below
2039       enable_stage1_languages=c ;;
2040     ,yes,)
2041       enable_stage1_languages=`echo $new_enable_languages | \
2042         sed -e "s/^,//" -e "s/,$//" ` ;;
2043     *,all,*)
2044       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2045         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2046   esac
2047
2048   # Add "good" languages from enable_stage1_languages to stage1_languages,
2049   # while "bad" languages go in missing_languages.  Leave no duplicates.
2050   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2051     case $potential_languages in
2052       *,$i,*)
2053         case $stage1_languages in
2054           *,$i,*) ;;
2055           *) stage1_languages="$stage1_languages$i," ;;
2056         esac ;;
2057       *)
2058         case $missing_languages in
2059           *,$i,*) ;;
2060           *) missing_languages="$missing_languages$i," ;;
2061         esac ;;
2062      esac
2063   done])
2064
2065   # Remove leading/trailing commas that were added for simplicity
2066   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2067   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2068   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2069   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2070
2071   if test "x$missing_languages" != x; then
2072     AC_MSG_ERROR([
2073 The following requested languages could not be built: ${missing_languages}
2074 Supported languages are: ${potential_languages}])
2075   fi
2076   if test "x$new_enable_languages" != "x$enable_languages"; then
2077     echo The following languages will be built: ${new_enable_languages}
2078     enable_languages="$new_enable_languages"
2079   fi
2080
2081   AC_SUBST(stage1_languages)
2082   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2083 fi
2084
2085 # Handle --disable-<component> generically.
2086 for dir in $configdirs $build_configdirs $target_configdirs ; do
2087   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2088   varname=`echo $dirname | sed -e s/+/_/g`
2089   if eval test x\${enable_${varname}} "=" xno ; then
2090     noconfigdirs="$noconfigdirs $dir"
2091   fi
2092 done
2093
2094 # Check for Boehm's garbage collector
2095 AC_ARG_ENABLE(objc-gc,
2096 [AS_HELP_STRING([--enable-objc-gc],
2097                 [enable use of Boehm's garbage collector with the
2098                  GNU Objective-C runtime])])
2099 AC_ARG_WITH([target-bdw-gc],
2100 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2101                 [specify prefix directory for installed bdw-gc package.
2102                  Equivalent to --with-target-bdw-gc-include=PATH/include
2103                  plus --with-target-bdw-gc-lib=PATH/lib])])
2104 AC_ARG_WITH([target-bdw-gc-include],
2105 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2106                 [specify directories for installed bdw-gc include files])])
2107 AC_ARG_WITH([target-bdw-gc-lib],
2108 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2109                 [specify directories for installed bdw-gc library])])
2110
2111 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2112   AC_MSG_CHECKING([for bdw garbage collector])
2113   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2114     dnl no bdw-gw options, assume default locations
2115     AC_MSG_RESULT([using bdw-gc in default locations])
2116   else
2117     dnl bdw-gw options, first error checking, complete checking in libobjc
2118     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2119       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2120     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2121       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2122     else
2123       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2124     fi
2125   fi
2126 esac
2127
2128 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2129 case ,${enable_languages}, in
2130   *,c++,*)
2131     # Disable libitm, libsanitizer if we're not building libstdc++
2132     case "${noconfigdirs}" in
2133       *target-libstdc++-v3*)
2134         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2135         ;;
2136       *) ;;
2137     esac
2138     ;;
2139   *)
2140     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2141     ;;
2142 esac
2143
2144 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2145 # $build_configdirs and $target_configdirs.
2146 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2147
2148 notsupp=""
2149 for dir in . $skipdirs $noconfigdirs ; do
2150   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2151   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2152     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2153     if test -r $srcdir/$dirname/configure ; then
2154       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2155         true
2156       else
2157         notsupp="$notsupp $dir"
2158       fi
2159     fi
2160   fi
2161   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2162     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2163     if test -r $srcdir/$dirname/configure ; then
2164       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2165         true
2166       else
2167         notsupp="$notsupp $dir"
2168       fi
2169     fi
2170   fi
2171   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2172     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2173     if test -r $srcdir/$dirname/configure ; then
2174       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2175         true
2176       else
2177         notsupp="$notsupp $dir"
2178       fi
2179     fi
2180   fi
2181 done
2182
2183 # Quietly strip out all directories which aren't configurable in this tree.
2184 # This relies on all configurable subdirectories being autoconfiscated, which
2185 # is now the case.
2186 build_configdirs_all="$build_configdirs"
2187 build_configdirs=
2188 for i in ${build_configdirs_all} ; do
2189   j=`echo $i | sed -e s/build-//g`
2190   if test -f ${srcdir}/$j/configure ; then
2191     build_configdirs="${build_configdirs} $i"
2192   fi
2193 done
2194
2195 configdirs_all="$configdirs"
2196 configdirs=
2197 for i in ${configdirs_all} ; do
2198   if test -f ${srcdir}/$i/configure ; then
2199     configdirs="${configdirs} $i"
2200   fi
2201 done
2202
2203 target_configdirs_all="$target_configdirs"
2204 target_configdirs=
2205 for i in ${target_configdirs_all} ; do
2206   j=`echo $i | sed -e s/target-//g`
2207   if test -f ${srcdir}/$j/configure ; then
2208     target_configdirs="${target_configdirs} $i"
2209   fi
2210 done
2211
2212 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2213 # so we have to add it after the preceding checks.
2214 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2215 then
2216   case " $configdirs " in
2217     *" libiberty "*)
2218       # If we can build libiberty, we can also build libiberty-linker-plugin.
2219       configdirs="$configdirs libiberty-linker-plugin"
2220       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2221         --with-libiberty=../libiberty-linker-plugin";;
2222     *)
2223       AC_MSG_ERROR([libiberty missing]);;
2224   esac
2225 fi
2226
2227 # Sometimes we have special requirements for the host libiberty.
2228 extra_host_libiberty_configure_flags=
2229 extra_host_zlib_configure_flags=
2230 case " $configdirs " in
2231   *" lto-plugin "* | *" libcc1 "*)
2232     # When these are to be built as shared libraries, the same applies to
2233     # libiberty.
2234     extra_host_libiberty_configure_flags=--enable-shared
2235     ;;
2236   *" bfd "*)
2237     # When bfd is to be built as a shared library, the same applies to
2238     # zlib.
2239     if test "$enable_shared" = "yes"; then
2240       extra_host_zlib_configure_flags=--enable-host-shared
2241     fi
2242     ;;
2243 esac
2244 AC_SUBST(extra_host_libiberty_configure_flags)
2245 AC_SUBST(extra_host_zlib_configure_flags)
2246
2247 # Produce a warning message for the subdirs we can't configure.
2248 # This isn't especially interesting in the Cygnus tree, but in the individual
2249 # FSF releases, it's important to let people know when their machine isn't
2250 # supported by the one or two programs in a package.
2251
2252 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2253   # If $appdirs is non-empty, at least one of those directories must still
2254   # be configured, or we error out.  (E.g., if the gas release supports a
2255   # specified target in some subdirs but not the gas subdir, we shouldn't
2256   # pretend that all is well.)
2257   if test -n "$appdirs" ; then
2258     for dir in $appdirs ; do
2259       if test -r $dir/Makefile.in ; then
2260         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2261           appdirs=""
2262           break
2263         fi
2264         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2265           appdirs=""
2266           break
2267         fi
2268       fi
2269     done
2270     if test -n "$appdirs" ; then
2271       echo "*** This configuration is not supported by this package." 1>&2
2272       exit 1
2273     fi
2274   fi
2275   # Okay, some application will build, or we don't care to check.  Still
2276   # notify of subdirs not getting built.
2277   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2278   echo "    ${notsupp}" 1>&2
2279   echo "    (Any other directories should still work fine.)" 1>&2
2280 fi
2281
2282 case "$host" in
2283   *msdosdjgpp*)
2284     enable_gdbtk=no ;;
2285 esac
2286
2287 # To find our prefix, in gcc_cv_tool_prefix.
2288 ACX_TOOL_DIRS
2289
2290 copy_dirs=
2291
2292 AC_ARG_WITH([build-sysroot],
2293   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2294                   [use sysroot as the system root during the build])],
2295   [if test x"$withval" != x ; then
2296      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2297    fi],
2298   [SYSROOT_CFLAGS_FOR_TARGET=])
2299 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2300
2301 AC_ARG_WITH([debug-prefix-map],
2302   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2303                   [map A to B, C to D ... in debug information])],
2304   [if test x"$withval" != x; then
2305      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2306      for debug_map in $withval; do
2307        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2308      done
2309    fi],
2310   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2311 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2312
2313 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2314 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2315 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2316 # We want to ensure that TARGET libraries (which we know are built with
2317 # gcc) are built with "-O2 -g", so include those options when setting
2318 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2319 if test "x$CFLAGS_FOR_TARGET" = x; then
2320   if test "x${is_cross_compiler}" = xyes; then
2321     CFLAGS_FOR_TARGET="-g -O2"
2322   else
2323     CFLAGS_FOR_TARGET=$CFLAGS
2324     case " $CFLAGS " in
2325       *" -O2 "*) ;;
2326       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2327     esac
2328     case " $CFLAGS " in
2329       *" -g "* | *" -g3 "*) ;;
2330       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2331     esac
2332   fi
2333 fi
2334 AC_SUBST(CFLAGS_FOR_TARGET)
2335
2336 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2337   if test "x${is_cross_compiler}" = xyes; then
2338     CXXFLAGS_FOR_TARGET="-g -O2"
2339   else
2340     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2341     case " $CXXFLAGS " in
2342       *" -O2 "*) ;;
2343       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2344     esac
2345     case " $CXXFLAGS " in
2346       *" -g "* | *" -g3 "*) ;;
2347       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2348     esac
2349   fi
2350 fi
2351 AC_SUBST(CXXFLAGS_FOR_TARGET)
2352
2353 AC_SUBST(LDFLAGS_FOR_TARGET)
2354
2355 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2356 # the named directory are copied to $(tooldir)/sys-include.
2357 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2358   if test x${is_cross_compiler} = xno ; then
2359     echo 1>&2 '***' --with-headers is only supported when cross compiling
2360     exit 1
2361   fi
2362   if test x"${with_headers}" != xyes ; then
2363     x=${gcc_cv_tool_prefix}
2364     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2365   fi
2366 fi
2367
2368 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2369 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2370 # are permitted.
2371 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2372   if test x${is_cross_compiler} = xno ; then
2373     echo 1>&2 '***' --with-libs is only supported when cross compiling
2374     exit 1
2375   fi
2376   if test x"${with_libs}" != xyes ; then
2377     # Copy the libraries in reverse order, so that files in the first named
2378     # library override files in subsequent libraries.
2379     x=${gcc_cv_tool_prefix}
2380     for l in ${with_libs}; do
2381       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2382     done
2383   fi
2384 fi
2385
2386 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2387 #
2388 # This is done by determining whether or not the appropriate directory
2389 # is available, and by checking whether or not specific configurations
2390 # have requested that this magic not happen.
2391 #
2392 # The command line options always override the explicit settings in
2393 # configure.ac, and the settings in configure.ac override this magic.
2394 #
2395 # If the default for a toolchain is to use GNU as and ld, and you don't
2396 # want to do that, then you should use the --without-gnu-as and
2397 # --without-gnu-ld options for the configure script.  Similarly, if
2398 # the default is to use the included zlib and you don't want to do that,
2399 # you should use the --with-system-zlib option for the configure script.
2400
2401 if test x${use_gnu_as} = x &&
2402    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2403   with_gnu_as=yes
2404   extra_host_args="$extra_host_args --with-gnu-as"
2405 fi
2406
2407 if test x${use_gnu_ld} = x &&
2408    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2409   with_gnu_ld=yes
2410   extra_host_args="$extra_host_args --with-gnu-ld"
2411 fi
2412
2413 if test x${use_included_zlib} = x &&
2414    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2415   :
2416 else
2417   with_system_zlib=yes
2418   extra_host_args="$extra_host_args --with-system-zlib"
2419 fi
2420
2421 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2422 # can detect this case.
2423
2424 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2425   with_newlib=yes
2426   extra_host_args="$extra_host_args --with-newlib"
2427 fi
2428
2429 # Handle ${copy_dirs}
2430 set fnord ${copy_dirs}
2431 shift
2432 while test $# != 0 ; do
2433   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2434     :
2435   else
2436     echo Copying $1 to $2
2437
2438     # Use the install script to create the directory and all required
2439     # parent directories.
2440     if test -d $2 ; then
2441       :
2442     else
2443       echo >config.temp
2444       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2445     fi
2446
2447     # Copy the directory, assuming we have tar.
2448     # FIXME: Should we use B in the second tar?  Not all systems support it.
2449     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2450
2451     # It is the responsibility of the user to correctly adjust all
2452     # symlinks.  If somebody can figure out how to handle them correctly
2453     # here, feel free to add the code.
2454
2455     echo $1 > $2/COPIED
2456   fi
2457   shift; shift
2458 done
2459
2460 # Determine a target-dependent exec_prefix that the installed
2461 # gcc will search in.  Keep this list sorted by triplet, with
2462 # the *-*-osname triplets last.
2463 md_exec_prefix=
2464 case "${target}" in
2465   i[[34567]]86-pc-msdosdjgpp*)
2466     md_exec_prefix=/dev/env/DJDIR/bin
2467     ;;
2468   *-*-hpux* | \
2469   *-*-nto-qnx* | \
2470   *-*-solaris2*)
2471     md_exec_prefix=/usr/ccs/bin
2472     ;;
2473 esac
2474
2475 extra_arflags_for_target=
2476 extra_nmflags_for_target=
2477 extra_ranlibflags_for_target=
2478 target_makefile_frag=/dev/null
2479 case "${target}" in
2480   spu-*-*)
2481     target_makefile_frag="config/mt-spu"
2482     ;;
2483   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2484     target_makefile_frag="config/mt-sde"
2485     ;;
2486   mipsisa*-*-elfoabi*)
2487     target_makefile_frag="config/mt-mips-elfoabi"
2488     ;;
2489   mips*-*-*linux* | mips*-*-gnu*)
2490     target_makefile_frag="config/mt-mips-gnu"
2491     ;;
2492   nios2-*-elf*)
2493     target_makefile_frag="config/mt-nios2-elf"
2494     ;;
2495   *-*-linux-android*)
2496     target_makefile_frag="config/mt-android"
2497     ;;
2498   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2499     target_makefile_frag="config/mt-gnu"
2500     ;;
2501   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2502     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2503     # commands to handle both 32-bit and 64-bit objects.  These flags are
2504     # harmless if we're using GNU nm or ar.
2505     extra_arflags_for_target=" -X32_64"
2506     extra_nmflags_for_target=" -B -X32_64"
2507     ;;
2508 esac
2509
2510 alphaieee_frag=/dev/null
2511 case $target in
2512   alpha*-*-*)
2513     # This just makes sure to use the -mieee option to build target libs.
2514     # This should probably be set individually by each library.
2515     alphaieee_frag="config/mt-alphaieee"
2516     ;;
2517 esac
2518
2519 # If --enable-target-optspace always use -Os instead of -O2 to build
2520 # the target libraries, similarly if it is not specified, use -Os
2521 # on selected platforms.
2522 ospace_frag=/dev/null
2523 case "${enable_target_optspace}:${target}" in
2524   yes:*)
2525     ospace_frag="config/mt-ospace"
2526     ;;
2527   :d30v-*)
2528     ospace_frag="config/mt-d30v"
2529     ;;
2530   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2531     ospace_frag="config/mt-ospace"
2532     ;;
2533   no:* | :*)
2534     ;;
2535   *)
2536     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2537     ;;
2538 esac
2539
2540 # Some systems (e.g., one of the i386-aix systems the gas testers are
2541 # using) don't handle "\$" correctly, so don't use it here.
2542 tooldir='${exec_prefix}'/${target_noncanonical}
2543 build_tooldir=${tooldir}
2544
2545 # Create a .gdbinit file which runs the one in srcdir
2546 # and tells GDB to look there for source files.
2547
2548 if test -r ${srcdir}/.gdbinit ; then
2549   case ${srcdir} in
2550     .) ;;
2551     *) cat > ./.gdbinit <<EOF
2552 # ${NO_EDIT}
2553 dir ${srcdir}
2554 dir .
2555 source ${srcdir}/.gdbinit
2556 EOF
2557     ;;
2558   esac
2559 fi
2560
2561 # Make sure that the compiler is able to generate an executable.  If it
2562 # can't, we are probably in trouble.  We don't care whether we can run the
2563 # executable--we might be using a cross compiler--we only care whether it
2564 # can be created.  At this point the main configure script has set CC.
2565 we_are_ok=no
2566 echo "int main () { return 0; }" > conftest.c
2567 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2568 if test $? = 0 ; then
2569   if test -s conftest || test -s conftest.exe ; then
2570     we_are_ok=yes
2571   fi
2572 fi
2573 case $we_are_ok in
2574   no)
2575     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2576     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2577     rm -f conftest*
2578     exit 1
2579     ;;
2580 esac
2581 rm -f conftest*
2582
2583 # Decide which environment variable is used to find dynamic libraries.
2584 case "${host}" in
2585   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2586   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2587   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2588   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2589 esac
2590
2591 # On systems where the dynamic library environment variable is PATH,
2592 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2593 # built executables to PATH.
2594 if test "$RPATH_ENVVAR" = PATH; then
2595   GCC_SHLIB_SUBDIR=/shlib
2596 else
2597   GCC_SHLIB_SUBDIR=
2598 fi
2599
2600 # Adjust the toplevel makefile according to whether bootstrap was selected.
2601 case $enable_bootstrap in
2602   yes)
2603     bootstrap_suffix=bootstrap
2604     BUILD_CONFIG=bootstrap-debug
2605     ;;
2606   no)
2607     bootstrap_suffix=no-bootstrap
2608     BUILD_CONFIG=
2609     ;;
2610 esac
2611
2612 AC_MSG_CHECKING(for default BUILD_CONFIG)
2613
2614 AC_ARG_WITH([build-config],
2615   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2616                   [use config/NAME.mk build configuration])],
2617   [case $with_build_config in
2618    yes) with_build_config= ;;
2619    no) with_build_config= BUILD_CONFIG= ;;
2620    esac])
2621
2622 if test "x${with_build_config}" != x; then
2623   BUILD_CONFIG=$with_build_config
2624 else
2625   case $BUILD_CONFIG in
2626   bootstrap-debug)
2627     if echo "int f (void) { return 0; }" > conftest.c &&
2628        ${CC} -c conftest.c &&
2629        mv conftest.o conftest.o.g0 &&
2630        ${CC} -c -g conftest.c &&
2631        mv conftest.o conftest.o.g &&
2632        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2633       :
2634     else
2635       BUILD_CONFIG=
2636     fi
2637     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2638     ;;
2639   esac
2640 fi
2641 AC_MSG_RESULT($BUILD_CONFIG)
2642 AC_SUBST(BUILD_CONFIG)
2643
2644 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2645 AC_MSG_CHECKING([for --enable-vtable-verify])
2646 AC_ARG_ENABLE(vtable-verify,
2647 [AS_HELP_STRING([--enable-vtable-verify],
2648                 [Enable vtable verification feature])],
2649 [case "$enableval" in
2650  yes) enable_vtable_verify=yes ;;
2651  no)  enable_vtable_verify=no ;;
2652  *)   enable_vtable_verify=no;;
2653  esac],
2654 [enable_vtable_verify=no])
2655 AC_MSG_RESULT($enable_vtable_verify)
2656
2657 # Record target_configdirs and the configure arguments for target and
2658 # build configuration in Makefile.
2659 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2660 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2661 bootstrap_fixincludes=no
2662
2663 # If we are building libgomp, bootstrap it.
2664 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2665   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2666 fi
2667
2668 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2669 # or bootstrap-ubsan, bootstrap it.
2670 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2671   case "$BUILD_CONFIG" in
2672     *bootstrap-asan* | *bootstrap-ubsan* )
2673       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2674       bootstrap_fixincludes=yes
2675       ;;
2676   esac
2677 fi
2678
2679 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2680 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2681    test "$enable_vtable_verify" != no; then
2682   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2683 fi
2684
2685 # Determine whether gdb needs tk/tcl or not.
2686 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2687 # and in that case we want gdb to be built without tk.  Ugh!
2688 # In fact I believe gdb is the *only* package directly dependent on tk,
2689 # so we should be able to put the 'maybe's in unconditionally and
2690 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2691 # 100% sure that that's safe though.
2692
2693 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2694 case "$enable_gdbtk" in
2695   no)
2696     GDB_TK="" ;;
2697   yes)
2698     GDB_TK="${gdb_tk}" ;;
2699   *)
2700     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2701     # distro.  Eventually someone will fix this and move Insight, nee
2702     # gdbtk to a separate directory.
2703     if test -d ${srcdir}/gdb/gdbtk ; then
2704       GDB_TK="${gdb_tk}"
2705     else
2706       GDB_TK=""
2707     fi
2708     ;;
2709 esac
2710 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2711 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2712
2713 # Strip out unwanted targets.
2714
2715 # While at that, we remove Makefiles if we were started for recursive
2716 # configuration, so that the top-level Makefile reconfigures them,
2717 # like we used to do when configure itself was recursive.
2718
2719 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2720 # but now we're fixing up the Makefile ourselves with the additional
2721 # commands passed to AC_CONFIG_FILES.  Use separate variables
2722 # extrasub-{build,host,target} not because there is any reason to split
2723 # the substitutions up that way, but only to remain below the limit of
2724 # 99 commands in a script, for HP-UX sed.
2725
2726 # Do not nest @if/@endif or @unless/@endunless pairs, because
2727 # configure will not warn you at all.
2728
2729 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2730   yes:yes:*\ gold\ *:*,c++,*) ;;
2731   yes:yes:*\ gold\ *:*)
2732     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2733     ;;
2734 esac
2735
2736 extrasub_build=
2737 for module in ${build_configdirs} ; do
2738   if test -z "${no_recursion}" \
2739      && test -f ${build_subdir}/${module}/Makefile; then
2740     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2741     rm -f ${build_subdir}/${module}/Makefile
2742   fi
2743   extrasub_build="$extrasub_build
2744 /^@if build-$module\$/d
2745 /^@endif build-$module\$/d
2746 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2747 /^@if build-$module-$bootstrap_suffix\$/d
2748 /^@endif build-$module-$bootstrap_suffix\$/d
2749 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2750 done
2751 extrasub_host=
2752 for module in ${configdirs} ; do
2753   if test -z "${no_recursion}"; then
2754     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2755       if test -f ${file}; then
2756         echo 1>&2 "*** removing ${file} to force reconfigure"
2757         rm -f ${file}
2758       fi
2759     done
2760   fi
2761   case ${module},${bootstrap_fixincludes} in
2762     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2763     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2764   esac
2765   extrasub_host="$extrasub_host
2766 /^@if $module\$/d
2767 /^@endif $module\$/d
2768 /^@unless $module\$/,/^@endunless $module\$/d
2769 /^@if $module-$host_bootstrap_suffix\$/d
2770 /^@endif $module-$host_bootstrap_suffix\$/d
2771 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2772 done
2773 extrasub_target=
2774 for module in ${target_configdirs} ; do
2775   if test -z "${no_recursion}" \
2776      && test -f ${target_subdir}/${module}/Makefile; then
2777     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2778     rm -f ${target_subdir}/${module}/Makefile
2779   fi
2780
2781   # We only bootstrap target libraries listed in bootstrap_target_libs.
2782   case $bootstrap_target_libs in
2783     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2784     *) target_bootstrap_suffix=no-bootstrap ;;
2785   esac
2786
2787   extrasub_target="$extrasub_target
2788 /^@if target-$module\$/d
2789 /^@endif target-$module\$/d
2790 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2791 /^@if target-$module-$target_bootstrap_suffix\$/d
2792 /^@endif target-$module-$target_bootstrap_suffix\$/d
2793 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2794 done
2795
2796 # Do the final fixup along with target modules.
2797 extrasub_target="$extrasub_target
2798 /^@if /,/^@endif /d
2799 /^@unless /d
2800 /^@endunless /d"
2801
2802 # Create the serialization dependencies.  This uses a temporary file.
2803
2804 AC_ARG_ENABLE([serial-configure],
2805 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2806                 [force sequential configuration of
2807                  sub-packages for the host, target or build
2808                  machine, or all sub-packages])])
2809
2810 case ${enable_serial_configure} in
2811   yes)
2812     enable_serial_build_configure=yes
2813     enable_serial_host_configure=yes
2814     enable_serial_target_configure=yes
2815     ;;
2816 esac
2817
2818 # These force 'configure's to be done one at a time, to avoid problems
2819 # with contention over a shared config.cache.
2820 rm -f serdep.tmp
2821 echo '# serdep.tmp' > serdep.tmp
2822 olditem=
2823 test "x${enable_serial_build_configure}" = xyes &&
2824 for item in ${build_configdirs} ; do
2825   case ${olditem} in
2826     "") ;;
2827     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2828   esac
2829   olditem=${item}
2830 done
2831 olditem=
2832 test "x${enable_serial_host_configure}" = xyes &&
2833 for item in ${configdirs} ; do
2834   case ${olditem} in
2835     "") ;;
2836     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2837   esac
2838   olditem=${item}
2839 done
2840 olditem=
2841 test "x${enable_serial_target_configure}" = xyes &&
2842 for item in ${target_configdirs} ; do
2843   case ${olditem} in
2844     "") ;;
2845     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2846   esac
2847   olditem=${item}
2848 done
2849 serialization_dependencies=serdep.tmp
2850 AC_SUBST_FILE(serialization_dependencies)
2851
2852 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2853 # target, nonopt, and variable assignments.  These are the ones we
2854 # might not want to pass down to subconfigures.  The exception being
2855 # --cache-file=/dev/null, which is used to turn off the use of cache
2856 # files altogether, and which should be passed on to subconfigures.
2857 # Also strip program-prefix, program-suffix, and program-transform-name,
2858 # so that we can pass down a consistent program-transform-name.
2859 baseargs=
2860 tbaseargs=
2861 keep_next=no
2862 skip_next=no
2863 eval "set -- $ac_configure_args"
2864 for ac_arg
2865 do
2866   if test X"$skip_next" = X"yes"; then
2867     skip_next=no
2868     continue
2869   fi
2870   if test X"$keep_next" = X"yes"; then
2871     case $ac_arg in
2872       *\'*)
2873         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2874     esac
2875     baseargs="$baseargs '$ac_arg'"
2876     tbaseargs="$tbaseargs '$ac_arg'"
2877     keep_next=no
2878     continue
2879   fi
2880
2881   # Handle separated arguments.  Based on the logic generated by
2882   # autoconf 2.59.
2883   case $ac_arg in
2884     *=* | --config-cache | -C | -disable-* | --disable-* \
2885       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
2886       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
2887       | -with-* | --with-* | -without-* | --without-* | --x)
2888       separate_arg=no
2889       ;;
2890     -*)
2891       separate_arg=yes
2892       ;;
2893     *)
2894       separate_arg=no
2895       ;;
2896   esac
2897
2898   skip_targ=no
2899   case $ac_arg in
2900 changequote(,)
2901   --with-* | --without-*)
2902     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
2903
2904     case $libopt in
2905     *[-_]include)
2906       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
2907       ;;
2908     *[-_]lib)
2909       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
2910       ;;
2911     *)
2912       lib=$libopt
2913       ;;
2914     esac
2915 changequote([,])
2916
2917     case $lib in
2918     mpc | mpfr | gmp | isl)
2919       # If we're processing --with-$lib, --with-$lib-include or
2920       # --with-$lib-lib, for one of the libs above, and target is
2921       # different from host, don't pass the current argument to any
2922       # target library's configure.
2923       if test x$is_cross_compiler = xyes; then
2924         skip_targ=yes
2925       fi
2926       ;;
2927     esac
2928     ;;
2929   esac
2930
2931   case "$ac_arg" in
2932     --cache-file=/dev/null | \
2933     -cache-file=/dev/null )
2934       # Handled here to avoid the test to skip args below.
2935       baseargs="$baseargs '$ac_arg'"
2936       tbaseargs="$tbaseargs '$ac_arg'"
2937       # Assert: $separate_arg should always be no.
2938       keep_next=$separate_arg
2939       ;;
2940     --no*)
2941       continue
2942       ;;
2943     --c* | \
2944     --sr* | \
2945     --ho* | \
2946     --bu* | \
2947     --t* | \
2948     --program-* | \
2949     -cache_file* | \
2950     -srcdir* | \
2951     -host* | \
2952     -build* | \
2953     -target* | \
2954     -program-prefix* | \
2955     -program-suffix* | \
2956     -program-transform-name* )
2957       skip_next=$separate_arg
2958       continue
2959       ;;
2960     -*)
2961       # An option.  Add it.
2962       case $ac_arg in
2963         *\'*)
2964           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2965       esac
2966       baseargs="$baseargs '$ac_arg'"
2967       if test X"$skip_targ" = Xno; then
2968         tbaseargs="$tbaseargs '$ac_arg'"
2969       fi
2970       keep_next=$separate_arg
2971       ;;
2972     *)
2973       # Either a variable assignment, or a nonopt (triplet).  Don't
2974       # pass it down; let the Makefile handle this.
2975       continue
2976       ;;
2977   esac
2978 done
2979 # Remove the initial space we just introduced and, as these will be
2980 # expanded by make, quote '$'.
2981 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
2982
2983 # Add in --program-transform-name, after --program-prefix and
2984 # --program-suffix have been applied to it.  Autoconf has already
2985 # doubled dollar signs and backslashes in program_transform_name; we want
2986 # the backslashes un-doubled, and then the entire thing wrapped in single
2987 # quotes, because this will be expanded first by make and then by the shell.
2988 # Also, because we want to override the logic in subdir configure scripts to
2989 # choose program_transform_name, replace any s,x,x, with s,y,y,.
2990 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
2991 ${program_transform_name}
2992 EOF_SED
2993 gcc_transform_name=`cat conftestsed.out`
2994 rm -f conftestsed.out
2995 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
2996 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
2997 if test "$silent" = yes; then
2998   baseargs="$baseargs --silent"
2999   tbaseargs="$tbaseargs --silent"
3000 fi
3001 baseargs="$baseargs --disable-option-checking"
3002 tbaseargs="$tbaseargs --disable-option-checking"
3003
3004 # Record and document user additions to sub configure arguments.
3005 AC_ARG_VAR([build_configargs],
3006            [additional configure arguments for build directories])
3007 AC_ARG_VAR([host_configargs],
3008            [additional configure arguments for host directories])
3009 AC_ARG_VAR([target_configargs],
3010            [additional configure arguments for target directories])
3011
3012 # For the build-side libraries, we just need to pretend we're native,
3013 # and not use the same cache file.  Multilibs are neither needed nor
3014 # desired.  We can't even use the same cache file for all build-side
3015 # libraries, as they're compiled differently; some with C, some with
3016 # C++ or with different feature-enabling options.
3017 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3018
3019 # For host modules, accept cache file option, or specification as blank.
3020 case "${cache_file}" in
3021 "") # empty
3022   cache_file_option="" ;;
3023 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3024   cache_file_option="--cache-file=${cache_file}" ;;
3025 *) # relative path
3026   cache_file_option="--cache-file=../${cache_file}" ;;
3027 esac
3028
3029 # Host dirs don't like to share a cache file either, horribly enough.
3030 # This seems to be due to autoconf 2.5x stupidity.
3031 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3032
3033 target_configargs="$target_configargs ${tbaseargs}"
3034
3035 # Passing a --with-cross-host argument lets the target libraries know
3036 # whether they are being built with a cross-compiler or being built
3037 # native.  However, it would be better to use other mechanisms to make the
3038 # sorts of decisions they want to make on this basis.  Please consider
3039 # this option to be deprecated.  FIXME.
3040 if test x${is_cross_compiler} = xyes ; then
3041   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3042 fi
3043
3044 # Special user-friendly check for native x86_64-linux build, if
3045 # multilib is not explicitly enabled.
3046 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3047   x86_64-*linux*:yes:$build:$build:)
3048     # Make sure we have a development environment that handles 32-bit
3049     dev64=no
3050     echo "int main () { return 0; }" > conftest.c
3051     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3052     if test $? = 0 ; then
3053       if test -s conftest || test -s conftest.exe ; then
3054         dev64=yes
3055       fi
3056     fi
3057     rm -f conftest*
3058     if test x${dev64} != xyes ; then
3059       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3060     fi
3061     ;;
3062 esac
3063
3064 # Default to --enable-multilib.
3065 if test x${enable_multilib} = x ; then
3066   target_configargs="--enable-multilib ${target_configargs}"
3067 fi
3068
3069 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3070 # changed from the earlier setting of with_newlib.
3071 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3072   target_configargs="--with-newlib ${target_configargs}"
3073 fi
3074
3075 # Different target subdirs use different values of certain variables
3076 # (notably CXX).  Worse, multilibs use *lots* of different values.
3077 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3078 # it doesn't automatically accept command-line overrides of them.
3079 # This means it's not safe for target subdirs to share a cache file,
3080 # which is disgusting, but there you have it.  Hopefully this can be
3081 # fixed in future.  It's still worthwhile to use a cache file for each
3082 # directory.  I think.
3083
3084 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3085 # We need to pass --target, as newer autoconf's requires consistency
3086 # for target_alias and gcc doesn't manage it consistently.
3087 target_configargs="--cache-file=./config.cache ${target_configargs}"
3088
3089 FLAGS_FOR_TARGET=
3090 case " $target_configdirs " in
3091  *" newlib "*)
3092   case " $target_configargs " in
3093   *" --with-newlib "*)
3094    case "$target" in
3095     *-cygwin*)
3096       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3097       ;;
3098    esac
3099
3100    # If we're not building GCC, don't discard standard headers.
3101    if test -d ${srcdir}/gcc; then
3102      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3103
3104      if test "${build}" != "${host}"; then
3105        # On Canadian crosses, CC_FOR_TARGET will have already been set
3106        # by `configure', so we won't have an opportunity to add -Bgcc/
3107        # to it.  This is right: we don't want to search that directory
3108        # for binaries, but we want the header files in there, so add
3109        # them explicitly.
3110        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3111
3112        # Someone might think of using the pre-installed headers on
3113        # Canadian crosses, in case the installed compiler is not fully
3114        # compatible with the compiler being built.  In this case, it
3115        # would be better to flag an error than risking having
3116        # incompatible object files being constructed.  We can't
3117        # guarantee that an error will be flagged, but let's hope the
3118        # compiler will do it, when presented with incompatible header
3119        # files.
3120      fi
3121    fi
3122
3123    case "${target}-${is_cross_compiler}" in
3124    i[[3456789]]86-*-linux*-no)
3125       # Here host == target, so we don't need to build gcc,
3126       # so we don't want to discard standard headers.
3127       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3128       ;;
3129    *)
3130       # If we're building newlib, use its generic headers last, but search
3131       # for any libc-related directories first (so make it the last -B
3132       # switch).
3133       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3134
3135       # If we're building libgloss, find the startup file, simulator library
3136       # and linker script.
3137       case " $target_configdirs " in
3138         *" libgloss "*)
3139         # Look for startup file, simulator library and maybe linker script.
3140         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3141         # Look for libnosys.a in case the target needs it.
3142         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3143         # Most targets have the linker script in the source directory.
3144         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3145         ;;
3146       esac
3147       ;;
3148    esac
3149    ;;
3150   esac
3151   ;;
3152 esac
3153
3154 case "$target" in
3155   x86_64-*mingw* | *-w64-mingw*)
3156   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3157   # however, use a symlink named 'mingw' in ${prefix} .
3158     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3159     ;;
3160   *-mingw*)
3161   # MinGW can't be handled as Cygwin above since it does not use newlib.
3162     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3163     ;;
3164 esac
3165
3166 # Allow the user to override the flags for
3167 # our build compiler if desired.
3168 if test x"${build}" = x"${host}" ; then
3169   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3170   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3171   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3172 fi
3173
3174 # On Canadian crosses, we'll be searching the right directories for
3175 # the previously-installed cross compiler, so don't bother to add
3176 # flags for directories within the install tree of the compiler
3177 # being built; programs in there won't even run.
3178 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3179   # Search for pre-installed headers if nothing else fits.
3180   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3181 fi
3182
3183 if test "x${use_gnu_ld}" = x &&
3184    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3185   # Arrange for us to find uninstalled linker scripts.
3186   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3187 fi
3188
3189 # Search for other target-specific linker scripts and such.
3190 case "${target}" in
3191   mep*)
3192     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3193     ;;
3194 esac
3195
3196 # Makefile fragments.
3197 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3198 do
3199   eval fragval=\$$frag
3200   if test $fragval != /dev/null; then
3201     eval $frag=${srcdir}/$fragval
3202   fi
3203 done
3204 AC_SUBST_FILE(host_makefile_frag)
3205 AC_SUBST_FILE(target_makefile_frag)
3206 AC_SUBST_FILE(alphaieee_frag)
3207 AC_SUBST_FILE(ospace_frag)
3208
3209 # Miscellanea: directories, flags, etc.
3210 AC_SUBST(RPATH_ENVVAR)
3211 AC_SUBST(GCC_SHLIB_SUBDIR)
3212 AC_SUBST(tooldir)
3213 AC_SUBST(build_tooldir)
3214 AC_SUBST(CONFIGURE_GDB_TK)
3215 AC_SUBST(GDB_TK)
3216 AC_SUBST(INSTALL_GDB_TK)
3217
3218 # Build module lists & subconfigure args.
3219 AC_SUBST(build_configargs)
3220 AC_SUBST(build_configdirs)
3221
3222 # Host module lists & subconfigure args.
3223 AC_SUBST(host_configargs)
3224 AC_SUBST(configdirs)
3225 AC_SUBST(target_configdirs)
3226
3227 # Target module lists & subconfigure args.
3228 AC_SUBST(target_configargs)
3229
3230
3231 # Build tools.
3232 AC_SUBST(AR_FOR_BUILD)
3233 AC_SUBST(AS_FOR_BUILD)
3234 AC_SUBST(CC_FOR_BUILD)
3235 AC_SUBST(CFLAGS_FOR_BUILD)
3236 AC_SUBST(CXXFLAGS_FOR_BUILD)
3237 AC_SUBST(CXX_FOR_BUILD)
3238 AC_SUBST(DLLTOOL_FOR_BUILD)
3239 AC_SUBST(GFORTRAN_FOR_BUILD)
3240 AC_SUBST(GOC_FOR_BUILD)
3241 AC_SUBST(GDC_FOR_BUILD)
3242 AC_SUBST(LDFLAGS_FOR_BUILD)
3243 AC_SUBST(LD_FOR_BUILD)
3244 AC_SUBST(NM_FOR_BUILD)
3245 AC_SUBST(RANLIB_FOR_BUILD)
3246 AC_SUBST(WINDMC_FOR_BUILD)
3247 AC_SUBST(WINDRES_FOR_BUILD)
3248
3249 # Generate default definitions for YACC, M4, LEX and other programs that run
3250 # on the build machine.  These are used if the Makefile can't locate these
3251 # programs in objdir.
3252 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3253
3254 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3255 case " $build_configdirs " in
3256   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3257 esac
3258
3259 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3260 case " $build_configdirs " in
3261   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3262 esac
3263
3264 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3265 case " $build_configdirs " in
3266   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3267 esac
3268
3269 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3270 case " $build_configdirs " in
3271   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3272   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3273 esac
3274
3275 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3276 case " $build_configdirs " in
3277   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3278 esac
3279
3280 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3281 case " $build_configdirs " in
3282   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3283   *)
3284 changequote(,)
3285     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3286     # higher, else we use the "missing" dummy.
3287     if ${MAKEINFO} --version \
3288        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3289       :
3290     else
3291       MAKEINFO="$MISSING makeinfo"
3292     fi
3293     ;;
3294 changequote([,])
3295 esac
3296
3297 # FIXME: expect and dejagnu may become build tools?
3298
3299 AC_CHECK_PROGS(EXPECT, expect, expect)
3300 case " $configdirs " in
3301   *" expect "*)
3302     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3303     ;;
3304 esac
3305
3306 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3307 case " $configdirs " in
3308   *" dejagnu "*)
3309     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3310     ;;
3311 esac
3312
3313
3314 # Host tools.
3315 NCN_STRICT_CHECK_TOOLS(AR, ar)
3316 NCN_STRICT_CHECK_TOOLS(AS, as)
3317 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3318 NCN_STRICT_CHECK_TOOLS(LD, ld)
3319 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3320 NCN_STRICT_CHECK_TOOLS(NM, nm)
3321 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3322 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3323 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3324 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3325 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3326 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3327 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3328 AC_SUBST(CC)
3329 AC_SUBST(CXX)
3330 AC_SUBST(CFLAGS)
3331 AC_SUBST(CXXFLAGS)
3332
3333 # Target tools.
3334 AC_ARG_WITH([build-time-tools],
3335   [AS_HELP_STRING([--with-build-time-tools=PATH],
3336                   [use given path to find target tools during the build])],
3337   [case x"$withval" in
3338      x/*) ;;
3339      *)
3340        with_build_time_tools=
3341        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3342        ;;
3343    esac],
3344   [with_build_time_tools=])
3345
3346 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3347 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3348 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3349 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3350 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3351 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3352
3353 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3354 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3355 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3356 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3357 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3358 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3359 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3360 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3361 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3362 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3363 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3364 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3365 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3366
3367 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3368
3369 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3370 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3371 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3372 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3373 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3374                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3375                 c++)
3376 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3377                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3378                 c++)
3379 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3380 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3381 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3382                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3383 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3384                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3385 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3386                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3387 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3388 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3389 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3390 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3391 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3392 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3393 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3394 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3395 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3396 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3397
3398 AC_SUBST(FLAGS_FOR_TARGET)
3399 AC_SUBST(RAW_CXX_FOR_TARGET)
3400
3401 # Certain tools may need extra flags.
3402 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3403 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3404 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3405
3406 # When building target libraries, except in a Canadian cross, we use
3407 # the same toolchain as the compiler we just built.
3408 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3409 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3410 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3411 if test $host = $build; then
3412   case " $configdirs " in
3413     *" gcc "*)
3414       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3415       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3416       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3417       ;;
3418   esac
3419 fi
3420
3421 AC_SUBST(COMPILER_AS_FOR_TARGET)
3422 AC_SUBST(COMPILER_LD_FOR_TARGET)
3423 AC_SUBST(COMPILER_NM_FOR_TARGET)
3424
3425 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3426 AC_ARG_ENABLE(maintainer-mode,
3427 [AS_HELP_STRING([--enable-maintainer-mode],
3428                 [enable make rules and dependencies not useful
3429                  (and sometimes confusing) to the casual installer])],
3430       USE_MAINTAINER_MODE=$enableval,
3431       USE_MAINTAINER_MODE=no)
3432 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3433 AC_SUBST(MAINTAINER_MODE_TRUE)
3434 AC_SUBST(MAINTAINER_MODE_FALSE)
3435 if test "$USE_MAINTAINER_MODE" = yes; then
3436   MAINTAINER_MODE_TRUE=
3437   MAINTAINER_MODE_FALSE='#'
3438 else
3439   MAINTAINER_MODE_TRUE='#'
3440   MAINTAINER_MODE_FALSE=
3441 fi
3442 MAINT=$MAINTAINER_MODE_TRUE
3443 AC_SUBST(MAINT)dnl
3444
3445 # ---------------------
3446 # GCC bootstrap support
3447 # ---------------------
3448
3449 # Stage specific cflags for build.
3450 stage1_cflags="-g"
3451 case $build in
3452   vax-*-*)
3453     case ${GCC} in
3454       yes) stage1_cflags="-g -Wa,-J" ;;
3455       *) stage1_cflags="-g -J" ;;
3456     esac ;;
3457 esac
3458
3459 AC_SUBST(stage1_cflags)
3460
3461 # Enable --enable-checking in stage1 of the compiler.
3462 AC_ARG_ENABLE(stage1-checking,
3463 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3464                 [choose additional checking for stage1 of the compiler])],
3465 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3466 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3467   # For --disable-checking or implicit --enable-checking=release, avoid
3468   # setting --enable-checking=gc in the default stage1 checking for LTO
3469   # bootstraps.  See PR62077.
3470   case $BUILD_CONFIG in
3471     *lto*)
3472       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3473     *)
3474       stage1_checking=--enable-checking=yes,types;;
3475   esac
3476   if test "x$enable_checking" = x && \
3477      test -d ${srcdir}/gcc && \
3478      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3479     stage1_checking=--enable-checking=yes,types,extra
3480   fi
3481 else
3482   stage1_checking=--enable-checking=$enable_checking,types
3483 fi])
3484 AC_SUBST(stage1_checking)
3485
3486 # Enable -Werror in bootstrap stage2 and later.
3487 AC_ARG_ENABLE(werror,
3488 [AS_HELP_STRING([--enable-werror],
3489                 [enable -Werror in bootstrap stage2 and later])],
3490 [
3491 case ${enable_werror} in
3492   yes) stage2_werror_flag="--enable-werror-always" ;;
3493   *) stage2_werror_flag="" ;;
3494 esac
3495 ],
3496 [
3497 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3498   case $BUILD_CONFIG in
3499   bootstrap-debug)
3500       stage2_werror_flag="--enable-werror-always" ;;
3501   "")
3502       stage2_werror_flag="--enable-werror-always" ;;
3503   esac
3504 fi
3505 ])
3506
3507 AC_SUBST(stage2_werror_flag)
3508
3509 # Specify what files to not compare during bootstrap.
3510
3511 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3512 case "$target" in
3513   hppa*64*-*-hpux*) ;;
3514   hppa*-*-hpux*) compare_exclusions="gcc/cc*-checksum\$(objext) | */libgcc/lib2funcs* | gcc/ada/*tools/* | gcc/function-tests.o" ;;
3515   powerpc*-ibm-aix*) compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/* | *libgomp*\$(objext)" ;;
3516 esac
3517 AC_SUBST(compare_exclusions)
3518
3519 AC_CONFIG_FILES([Makefile],
3520   [sed "$extrasub_build" Makefile |
3521    sed "$extrasub_host" |
3522    sed "$extrasub_target" > mf$$
3523    mv -f mf$$ Makefile],
3524   [extrasub_build="$extrasub_build"
3525    extrasub_host="$extrasub_host"
3526    extrasub_target="$extrasub_target"])
3527 AC_OUTPUT