gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 dnl v2.5 needed for --bindir et al
   8 AC_PREREQ(2.13)
   9 AC_INIT(as.h)
  10
  11 AC_CANONICAL_SYSTEM
  12
  13 AM_INIT_AUTOMAKE(gas, 2.9.5)
  14
  15 AM_PROG_LIBTOOL
  16
  17 user_bfd_gas=
  18 AC_ARG_ENABLE(bfd-assembler,
  19 [  --enable-bfd-assembler  use BFD back end for writing object files],
  20 [case "${enableval}" in
  21   yes) need_bfd=yes user_bfd_gas=yes ;;
  22   no)  user_bfd_gas=no ;;
  23   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  24 esac])dnl
  25 AC_ARG_ENABLE(targets,
  26 [    targets            alternative target configurations besides the primary],
  27 [case "${enableval}" in
  28   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  29             ;;
  30   no)       enable_targets= ;;
  31   *)        enable_targets=$enableval ;;
  32 esac])dnl
  33 AC_ARG_ENABLE(commonbfdlib,
  34 [  --enable-commonbfdlib   build shared BFD/opcodes/libiberty library],
  35 [case "${enableval}" in
  36   yes) commonbfdlib=true ;;
  37   no)  commonbfdlib=false ;;
  38   *)   AC_MSG_ERROR([bad value ${enableval} for BFD commonbfdlib option]) ;;
  39 esac])dnl
  40
  41 using_cgen=no
  42
  43 # Generate a header file
  44 AM_CONFIG_HEADER(config.h:config.in)
  45
  46 # If we are on a DOS filesystem, we must use gdb.ini rather than
  47 # .gdbinit.
  48 GDBINIT=".gdbinit"
  49 case "${host}" in
  50   *-*-msdos* | *-*-go32* | *-*-mingw32* | *-*-cygwin* | *-*-windows*)
  51     GDBINIT="gdb.ini"
  52     ;;
  53 esac
  54 AC_SUBST(GDBINIT)
  55
  56 te_file=generic
  57
  58 # Makefile target for installing gas in $(tooldir)/bin.
  59 install_tooldir=install-exec-tooldir
  60
  61 canon_targets=""
  62 all_targets=no
  63 if test -n "$enable_targets" ; then
  64   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  65     if test $t = "all"; then
  66       all_targets=yes
  67       continue
  68     fi
  69     result=`$ac_config_sub $t 2>/dev/null`
  70     if test -n "$result" ; then
  71       canon_targets="$canon_targets $result"
  72 #    else
  73 #      # Permit "all", etc.  We don't support it yet though.
  74 #      canon_targets="$canon_targets $t"
  75     fi
  76   done
  77   GAS_UNIQ(canon_targets)
  78 fi
  79
  80 emulations=""
  81
  82 for this_target in $target $canon_targets ; do
  83
  84 changequote(,)dnl
  85     eval `echo $this_target | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  86 changequote([,])dnl
  87
  88     # check for architecture variants
  89     arch=
  90     endian=
  91     case ${cpu} in
  92       alpha*)           cpu_type=alpha ;;
  93       armeb)            cpu_type=arm endian=big ;;
  94       arm*)             cpu_type=arm endian=little ;;
  95       armb*)            cpu_type=arm endian=little ;;
  96       armv*l)           cpu_type=arm endian=little ;;
  97       armv*b)           cpu_type=arm endian=big ;;
  98       strongarm*)       cpu_type=arm endian=little ;;
  99       thumb*)           cpu_type=arm endian=little ;;
 100       hppa*)            cpu_type=hppa ;;
 101 changequote(,)dnl
 102       i[456]86)         cpu_type=i386 ;;
 103       m680[012346]0)    cpu_type=m68k ;;
 104 changequote([,])dnl
 105       m68008)           cpu_type=m68k ;;
 106       m683??)           cpu_type=m68k ;;
 107       m5200)            cpu_type=m68k ;;
 108       m8*)              cpu_type=m88k ;;
 109       mips*el)          cpu_type=mips endian=little ;;
 110       mips*)            cpu_type=mips endian=big ;;
 111       pjl*)             cpu_type=pj endian=little ;;
 112       pj*)              cpu_type=pj endian=big ;;
 113       powerpcle*)       cpu_type=ppc endian=little ;;
 114       powerpc*)         cpu_type=ppc endian=big ;;
 115       rs6000*)          cpu_type=ppc ;;
 116       sparclite*)       cpu_type=sparc arch=sparclite ;;
 117       sparclet*)        cpu_type=sparc arch=sparclet ;;
 118       sparc64*)         cpu_type=sparc arch=v9-64 ;;
 119       sparc86x*)        cpu_type=sparc arch=sparc86x  ;;
 120       sparc*)           cpu_type=sparc arch=sparclite ;; # ??? See tc-sparc.c.
 121       v850*)            cpu_type=v850 ;;
 122       *)                cpu_type=${cpu} ;;
 123     esac
 124
 125     if test ${this_target} = $target ; then
 126       target_cpu_type=${cpu_type}
 127     elif test ${target_cpu_type} != ${cpu_type} ; then
 128       continue
 129     fi
 130
 131     generic_target=${cpu_type}-$vendor-$os
 132     dev=no
 133     bfd_gas=no
 134     em=generic
 135
 136     # assign object format
 137     case ${generic_target} in
 138       a29k-*-coff)          fmt=coff ;;
 139       a29k-amd-udi)         fmt=coff ;;
 140       a29k-amd-ebmon)       fmt=coff ;;
 141       a29k-nyu-sym1)        fmt=coff ;;
 142       a29k-*-vxworks*)      fmt=coff ;;
 143
 144       alpha*-*-*vms*)       fmt=evax ;;
 145       alpha*-*-netware*)    fmt=ecoff ;;
 146       alpha*-*-openbsd*)    fmt=ecoff ;;
 147       alpha*-*-osf*)        fmt=ecoff ;;
 148       alpha*-*-linuxecoff*) fmt=ecoff ;;
 149       alpha*-*-linux-gnu*)  fmt=elf em=linux ;;
 150       alpha*-*-netbsd*)     fmt=elf em=nbsd ;;
 151
 152       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 153
 154       arm-*-aout)                       fmt=aout ;;
 155       arm-*-coff | thumb-*-coff)        fmt=coff ;;
 156       arm-*-elf | thumb-*-elf)          fmt=elf ;;
 157       arm*-*-conix*)                    fmt=elf ;;
 158       arm-*-linux*aout*)                fmt=aout em=linux ;;
 159       arm*-*-linux-gnu*)                fmt=elf  em=linux ;;
 160       arm-*-netbsd*)                    fmt=aout em=nbsd bfd_gas=yes ;;
 161       arm-*-oabi | thumb-*-oabi)        fmt=elf ;;
 162       arm-epoc-pe | thumb-epoc-pe)      fmt=coff em=epoc-pe ;;
 163       arm-*-wince)          fmt=coff em=wince-pe bfd_gas=yes;;
 164       arm-*-pe | thumb-*-pe)            fmt=coff em=pe ;;
 165       arm-*-riscix*)                    fmt=aout em=riscix ;;
 166
 167       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 168       d30v-*-*)             fmt=elf bfd_gas=yes ;;
 169
 170
 171       fr30-*-*)             fmt=elf bfd_gas=yes ;;
 172
 173       hppa-*-*elf*)         fmt=elf em=hppa ;;
 174       hppa-*-linux-gnu*)    fmt=elf em=hppa ;;
 175       hppa-*-lites*)        fmt=elf em=hppa ;;
 176       hppa-*-osf*)          fmt=som em=hppa ;;
 177       hppa-*-rtems*)        fmt=elf em=hppa ;;
 178       hppa-*-hpux*)         fmt=som em=hppa ;;
 179       hppa-*-mpeix*)        fmt=som em=hppa ;;
 180       hppa-*-bsd*)          fmt=som em=hppa ;;
 181       hppa-*-hiux*)         fmt=som em=hppa ;;
 182
 183       h8300-*-coff)         fmt=coff ;;
 184
 185       i370-*-elf* | i370-*-linux*) fmt=elf ;;
 186       i386-ibm-aix*)        fmt=coff em=i386aix ;;
 187       i386-sequent-bsd*)    fmt=aout em=dynix bfd_gas=yes ;;
 188       i386-*-beospe*)       fmt=coff em=pe bfd_gas=yes ;;
 189       i386-*-beoself* | i386-*-beos*) fmt=elf bfd_gas=yes ;;
 190       i386-*-bsd*)          fmt=aout em=386bsd ;;
 191       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 192       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 193       i386-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes;;
 194       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 195       i386-*-linux*coff*)   fmt=coff em=linux ;;
 196       i386-*-linux-gnu*)    fmt=elf em=linux bfd_gas=yes ;;
 197       i386-*-lynxos*)       fmt=coff em=lynx ;;
 198       i386-*-sysv4* | i386-*-solaris* | i386-*-elf)
 199                             fmt=elf bfd_gas=yes ;;
 200       i386-*-freebsdaout* | i386-*-freebsd[12].* | i386-*-freebsd[12])
 201                             fmt=aout em=386bsd ;;
 202       i386-*-freebsd*)      fmt=elf bfd_gas=yes ;;
 203       i386-*-coff | i386-*-sysv* | i386-*-sco3.2v5*coff | i386-*-isc*)
 204                           fmt=coff ;;
 205       i386-*-sco3.2v5*)      fmt=elf
 206                             if test ${this_target} = $target; then
 207                                 AC_DEFINE(SCO_ELF, 1,
 208                                     [Define if defaulting to ELF on SCO 5.])
 209                             fi
 210                             ;;
 211       i386-*-sco3.2*)       fmt=coff ;;
 212       i386-*-vsta)          fmt=aout ;;
 213       i386-*-msdosdjgpp* | i386-*-go32* | i386-go32-rtems*)
 214                             fmt=coff em=go32;;
 215       i386-*-rtemself*)     fmt=elf ;;
 216       i386-*-rtems*)        fmt=coff ;;
 217       i386-*-gnu*)          fmt=elf ;;
 218       i386-*-mach*)
 219                             fmt=aout em=mach bfd_gas=yes ;;
 220       i386-*-msdos*)        fmt=aout ;;
 221       i386-*-moss*)         fmt=elf ;;
 222       i386-*-pe)            fmt=coff em=pe ;;
 223       i386-*-cygwin*)       fmt=coff em=pe bfd_gas=yes ;;
 224       i386-*-interix*)      fmt=coff em=interix bfd_gas=yes ;;
 225       i386-*-mingw32*)      fmt=coff em=pe bfd_gas=yes ;;
 226       i386-*-*nt*)          fmt=coff em=pe ;;
 227       i386-*-vxworks*)      fmt=aout ;;
 228       i960-*-bout)          fmt=bout ;;
 229       i960-*-coff)          fmt=coff em=ic960 ;;
 230       i960-*-rtems*)        fmt=coff em=ic960 ;;
 231       i960-*-nindy*)        fmt=bout ;;
 232       i960-*-vxworks4*)     fmt=bout ;;
 233       i960-*-vxworks5.0)    fmt=bout ;;
 234       i960-*-vxworks5.*)    fmt=coff em=ic960 ;;
 235       i960-*-vxworks*)      fmt=bout ;;
 236       i960-*-elf*)          fmt=elf ;;
 237
 238       m32r-*-*)             fmt=elf bfd_gas=yes ;;
 239
 240       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 241                             fmt=aout em=sun3 ;;
 242       m68k-motorola-sysv*)  fmt=coff em=delta ;;
 243       m68k-bull-sysv3*)     fmt=coff em=dpx2 ;;
 244       m68k-apollo-*)        fmt=coff em=apollo ;;
 245       m68k-*-sysv4*) # must be before -sysv*
 246                             fmt=elf em=svr4 ;;
 247       m68k-*-elf*)          fmt=elf ;;
 248       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 249                             fmt=coff ;;
 250       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 251       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 252       m68k-*-linux-gnu*)    fmt=elf em=linux ;;
 253       m68k-*-gnu*)          fmt=elf ;;
 254       m68k-*-lynxos*)       fmt=coff em=lynx ;;
 255       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 256       m68k-*-openbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 257       m68k-apple-aux*)      fmt=coff em=aux ;;
 258       m68k-*-psos*)         fmt=elf em=psos;;
 259
 260       m88k-motorola-sysv3*) fmt=coff em=delt88 ;;
 261       m88k-*-coff*)         fmt=coff ;;
 262
 263       mcore-*-elf)          fmt=elf bfd_gas=yes ;;
 264       mcore-*-pe)           fmt=coff em=pe bfd_gas=yes ;;
 265
 266       # don't change em like *-*-bsd does
 267       mips-dec-netbsd*)     fmt=elf endian=little ;;
 268       mips-dec-openbsd*)    fmt=elf endian=little ;;
 269       mips-dec-bsd*)        fmt=aout endian=little ;;
 270       mips-sony-bsd*)       fmt=ecoff ;;
 271       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 272       mips-*-ultrix*)       fmt=ecoff endian=little ;;
 273       mips-*-osf*)          fmt=ecoff endian=little ;;
 274       mips-*-ecoff*)        fmt=ecoff ;;
 275       mips-*-ecoff*)        fmt=ecoff ;;
 276       mips-*-pe*)           fmt=coff endian=little em=pe ;;
 277       mips-*-irix6*)        fmt=elf ;;
 278       mips-*-irix5*)        fmt=elf ;;
 279       mips-*-irix*)         fmt=ecoff ;;
 280       mips-*-lnews*)        fmt=ecoff em=lnews ;;
 281       mips-*-riscos*)       fmt=ecoff ;;
 282       mips-*-sysv*)         fmt=ecoff ;;
 283       mips-*-elf* | mips-*-rtems* | mips-*-linux-gnu* | mips-*-gnu* | mips-*-openbsd*)
 284                             fmt=elf ;;
 285       mips-*-vxworks*)      fmt=elf
 286                             AC_DEFINE(MIPS_STABS_ELF, 1,
 287                                 [Use ELF stabs for MIPS, not ECOFF stabs])
 288                             ;;
 289       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 290       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 291       pj*)                  fmt=elf ;;
 292       ppc-*-pe | ppc-*-cygwin* | ppc-*-winnt*)
 293                             fmt=coff em=pe ;;
 294       ppc-*-aix*)           fmt=coff ;;
 295       ppc-*-beos*)          fmt=coff ;;
 296       ppc-*-*bsd* | ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 297                             fmt=elf ;;
 298       ppc-*-linux-gnu*)     fmt=elf
 299                             case "$endian" in
 300                             big)  ;;
 301                             *)    AC_MSG_ERROR(GNU/Linux must be configured big endian) ;;
 302                             esac
 303                             ;;
 304       ppc-*-solaris*)       fmt=elf
 305                             if test ${this_target} = $target; then
 306                                 AC_DEFINE(TARGET_SOLARIS_COMMENT, 1,
 307                                 [Define if default target is PowerPC Solaris.])
 308                             fi
 309                             if test x${endian} = xbig; then
 310                                 AC_MSG_ERROR(Solaris must be configured little endian)
 311                             fi
 312                             ;;
 313       ppc-*-rtems*)         fmt=elf ;;
 314       ppc-*-macos* | ppc-*-mpw*)
 315                             fmt=coff em=macos ;;
 316       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 317       ppc-*-vxworks*)       fmt=elf ;;
 318
 319       sh-*-elf*)            fmt=elf ;;
 320       sh-*-coff*)           fmt=coff ;;
 321       sh-*-pe*)             fmt=coff em=pe bfd_gas=yes;;
 322       sh-*-rtemself*)       fmt=elf ;;
 323       sh-*-rtems*)          fmt=coff ;;
 324
 325       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 326       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 327       ns32k-pc532-openbsd*) fmt=aout em=nbsd532 ;;
 328
 329       sparc-*-rtems*)       fmt=aout ;;
 330       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 331       sparc-*-aout | sparc*-*-vxworks*)
 332                             fmt=aout em=sparcaout ;;
 333       sparc-*-coff)         fmt=coff ;;
 334       sparc-*-linux*aout*)  fmt=aout em=linux ;;
 335       sparc-*-linux-gnu*)   fmt=elf em=linux ;;
 336       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 337       sparc-fujitsu-none)   fmt=aout ;;
 338       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 339                             fmt=elf ;;
 340       sparc-*-netbsd*)      fmt=aout em=nbsd ;;
 341       sparc-*-openbsd*)     fmt=aout em=nbsd ;;
 342
 343       strongarm-*-coff)     fmt=coff ;;
 344       strongarm-*-elf)      fmt=elf ;;
 345
 346       tic30-*-*aout*)       fmt=aout bfd_gas=yes ;;
 347       tic30-*-*coff*)       fmt=coff bfd_gas=yes ;;
 348       tic80-*-*)            fmt=coff ;;
 349
 350       v850-*-*)             fmt=elf bfd_gas=yes ;;
 351       v850e-*-*)            fmt=elf bfd_gas=yes ;;
 352       v850ea-*-*)           fmt=elf bfd_gas=yes ;;
 353
 354       vax-*-bsd* | vax-*-ultrix*)
 355                             fmt=aout ;;
 356       vax-*-vms)            fmt=vms ;;
 357
 358
 359       z8k-*-coff | z8k-*-sim)
 360                             fmt=coff ;;
 361
 362       w65-*-*)              fmt=coff ;;
 363
 364       *-*-aout | *-*-scout)
 365                             fmt=aout ;;
 366       *-*-nindy*)
 367                             fmt=bout ;;
 368       *-*-bsd*)
 369                             fmt=aout em=sun3 ;;
 370       *-*-generic)          fmt=generic ;;
 371       *-*-xray | *-*-hms)   fmt=coff ;;
 372       *-*-sim)              fmt=coff ;;
 373       *-*-elf | *-*-sysv4* | *-*-solaris*)
 374                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 375                             fmt=elf dev=yes ;;
 376       *-*-vxworks)          fmt=aout ;;
 377       *-*-netware)          fmt=elf ;;
 378     esac
 379
 380     if test ${this_target} = $target ; then
 381       endian_def=
 382       if test x${endian} = xbig; then
 383         endian_def=1
 384       elif test x${endian} = xlittle; then
 385         endian_def=0
 386       fi
 387       if test x${endian_def} != x; then
 388         AC_DEFINE_UNQUOTED(TARGET_BYTES_BIG_ENDIAN, $endian_def,
 389                            [Define as 1 if big endian.])
 390       fi
 391     fi
 392
 393     case ${cpu_type}-${fmt} in
 394       alpha*-*) bfd_gas=yes ;;
 395       arm-*)    bfd_gas=yes ;;
 396     # not yet
 397     # i386-aout)        bfd_gas=preferred ;;
 398       mips-*)   bfd_gas=yes ;;
 399       ns32k-*)  bfd_gas=yes ;;
 400       ppc-*)    bfd_gas=yes ;;
 401       sparc-*)  bfd_gas=yes ;;
 402       strongarm-*)      bfd_gas=yes ;;
 403       *-elf)    bfd_gas=yes ;;
 404       *-ecoff)  bfd_gas=yes ;;
 405       *-som)    bfd_gas=yes ;;
 406     #enable bfd for coff and aout to allow testing if a bfd target is
 407     #the primary target, but not for coff or aout as the primary target
 408       i386-coff)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 409       i386-aout)        if test x${primary_bfd_gas} = xyes; then bfd_gas=yes; fi ;;
 410       *)                ;;
 411     esac
 412
 413 # Other random stuff.
 414
 415     # Do we need the opcodes library?
 416     case ${cpu_type} in
 417       vax | i386 | tic30)
 418         ;;
 419
 420       *)
 421         need_opcodes=yes
 422
 423         case "${enable_shared}" in
 424         yes) shared_opcodes=true ;;
 425         *opcodes*) shared_opcodes=true ;;
 426         *) shared_opcodes=false ;;
 427         esac
 428         if test "${shared_opcodes}" = "true"; then
 429           # A shared libopcodes must be linked against libbfd.
 430           need_bfd=yes
 431         fi
 432         ;;
 433     esac
 434
 435     # Any other special object files needed ?
 436     case ${cpu_type} in
 437       fr30 | m32r)
 438         using_cgen=yes
 439         ;;
 440
 441       m68k)
 442         case ${extra_objects} in
 443         *m68k-parse.o*) ;;
 444         *) extra_objects="$extra_objects m68k-parse.o" ;;
 445         esac
 446         ;;
 447
 448       mips)
 449         echo ${extra_objects} | grep -s "itbl-parse.o"
 450         if test $? -ne 0 ; then
 451           extra_objects="$extra_objects itbl-parse.o"
 452         fi
 453
 454         echo ${extra_objects} | grep -s "itbl-lex.o"
 455         if test $? -ne 0 ; then
 456           extra_objects="$extra_objects itbl-lex.o"
 457         fi
 458
 459         echo ${extra_objects} | grep -s "itbl-ops.o"
 460         if test $? -ne 0 ; then
 461           extra_objects="$extra_objects itbl-ops.o"
 462         fi
 463         ;;
 464
 465       sparc)
 466         if test $this_target = $target ; then
 467           AC_DEFINE_UNQUOTED(DEFAULT_ARCH, "${arch}", [Default architecture.])
 468         fi
 469         ;;
 470       *)
 471         ;;
 472     esac
 473
 474     if test $using_cgen = yes ; then
 475         case "x${extra_objects}" in
 476         *cgen.o*) ;;
 477         *) extra_objects="$extra_objects cgen.o" ;;
 478         esac
 479     fi
 480
 481 # See if we really can support this configuration with the emulation code.
 482
 483     if test $this_target = $target ; then
 484       primary_bfd_gas=$bfd_gas
 485       obj_format=$fmt
 486       te_file=$em
 487
 488       if test $bfd_gas = no ; then
 489         # Can't support other configurations this way.
 490         break
 491       fi
 492     elif test $bfd_gas = no ; then
 493       # Can't support this configuration.
 494       break
 495     fi
 496
 497 # From target name and format, produce a list of supported emulations.
 498
 499     case ${generic_target}-${fmt} in
 500       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 501       mips-*-linux-gnu*-*) case "$endian" in
 502                         big)    emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 503                         *)      emulation="mipslelf mipsbelf mipself mipslecoff mipsbecoff mipsecoff" ;;
 504                         esac ;;
 505       mips-*-lnews*-ecoff) ;;
 506       mips-*-*-ecoff)   case "$endian" in
 507                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 508                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 509                         esac ;;
 510       mips-*-*-elf)     case "$endian" in
 511                         big)    emulation="mipsbelf mipslelf mipself" ;;
 512                         *)      emulation="mipslelf mipsbelf mipself" ;;
 513                         esac ;;
 514       # Uncommenting the next line will turn on support for i386 AOUT
 515       # for the default linux configuration
 516       # i386-*-linux*-elf) emulation="i386elf i386aout" ;;
 517       #
 518       i386-*-aout)      emulation="i386aout" ;;
 519       i386-*-coff)      emulation="i386coff" ;;
 520       i386-*-elf)       emulation="i386elf" ;;
 521     esac
 522
 523     emulations="$emulations $emulation"
 524
 525 done
 526
 527 # Turn on all targets if possible
 528 if test ${all_targets} = "yes"; then
 529   case ${target_cpu_type} in
 530   i386)
 531     case ${obj_format} in
 532     aout)
 533       emulations="$emulations i386coff i386elf"
 534       ;;
 535     coff)
 536       emulations="$emulations i386aout i386elf"
 537     ;;
 538     elf)
 539       emulations="$emulations i386aout i386coff"
 540       ;;
 541     esac
 542   ;;
 543   esac
 544 fi
 545
 546 # Assign floating point type.  Most processors with FP support
 547 # IEEE FP.  On those that don't support FP at all, usually IEEE
 548 # is emulated.
 549 case ${target_cpu} in
 550   vax | tahoe ) atof=${target_cpu} ;;
 551   *)            atof=ieee ;;
 552 esac
 553
 554 case "${obj_format}" in
 555   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 556 esac
 557
 558 # Unfortunately the cpu in cpu-opc.h file isn't always $(TARGET_CPU).
 559 cgen_cpu_prefix=""
 560 if test $using_cgen = yes ; then
 561   case ${target_cpu} in
 562     *) cgen_cpu_prefix=${target_cpu} ;;
 563   esac
 564   AC_SUBST(cgen_cpu_prefix)
 565   AC_DEFINE(USING_CGEN, 1, [Using cgen code?])
 566 fi
 567
 568 dnl
 569 dnl Make sure the desired support files exist.
 570 dnl
 571
 572 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 573   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 574 fi
 575
 576 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 577   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 578 fi
 579
 580 case ${user_bfd_gas}-${primary_bfd_gas} in
 581   yes-yes | no-no)
 582     # We didn't override user's choice.
 583     ;;
 584   no-yes)
 585     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 586     ;;
 587   no-preferred)
 588     primary_bfd_gas=no
 589     ;;
 590   *-preferred)
 591     primary_bfd_gas=yes
 592     ;;
 593   yes-*)
 594     primary_bfd_gas=yes
 595     ;;
 596   -*)
 597     # User specified nothing.
 598     ;;
 599 esac
 600
 601 # Some COFF configurations want these random other flags set.
 602 case ${obj_format} in
 603   coff)
 604     case ${target_cpu_type} in
 605       i386) AC_DEFINE(I386COFF, 1, [Using i386 COFF?]) ;;
 606       m68k) AC_DEFINE(M68KCOFF, 1, [Using m68k COFF?]) ;;
 607       m88k) AC_DEFINE(M88KCOFF, 1, [Using m88k COFF?]) ;;
 608     esac
 609     ;;
 610 esac
 611
 612 # Getting this done right is going to be a bitch.  Each configuration specified
 613 # with --enable-targets=... should be checked for environment, format, cpu, and
 614 # bfd_gas setting.
 615 #
 616 # For each configuration, the necessary object file support code must be linked
 617 # in.  This might be only one, it might be up to four.  The necessary emulation
 618 # code needs to be provided, too.
 619 #
 620 # And then there's "--enable-targets=all"....
 621 #
 622 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 623
 624 formats="${obj_format}"
 625 emfiles=""
 626 EMULATIONS=""
 627 GAS_UNIQ(emulations)
 628 for em in . $emulations ; do
 629   case $em in
 630     .)  continue ;;
 631     mipsbelf | mipslelf)
 632         fmt=elf   file=mipself ;;
 633     mipsbecoff | mipslecoff)
 634         fmt=ecoff file=mipsecoff ;;
 635     i386aout)
 636         fmt=aout  file=i386aout ;;
 637     i386coff)
 638         fmt=coff  file=i386coff ;;
 639     i386elf)
 640         fmt=elf   file=i386elf ;;
 641   esac
 642   formats="$formats $fmt"
 643   emfiles="$emfiles e-$file.o"
 644   EMULATIONS="$EMULATIONS &$em,"
 645 done
 646 GAS_UNIQ(formats)
 647 GAS_UNIQ(emfiles)
 648 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 649   for fmt in $formats ; do
 650     case $fmt in
 651       aout)     AC_DEFINE(OBJ_MAYBE_AOUT, 1,    [a.out support?])   ;;
 652       bout)     AC_DEFINE(OBJ_MAYBE_BOUT, 1,    [b.out support?])   ;;
 653       coff)     AC_DEFINE(OBJ_MAYBE_COFF, 1,    [COFF support?])    ;;
 654       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF, 1,   [ECOFF support?])   ;;
 655       elf)      AC_DEFINE(OBJ_MAYBE_ELF, 1,     [ELF support?])     ;;
 656       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC, 1, [generic support?]) ;;
 657       hp300)    AC_DEFINE(OBJ_MAYBE_HP300, 1,   [HP300 support?])   ;;
 658       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE, 1,    [IEEE support?])    ;;
 659       som)      AC_DEFINE(OBJ_MAYBE_SOM, 1,     [SOM support?])     ;;
 660       vms)      AC_DEFINE(OBJ_MAYBE_VMS, 1,     [VMS support?])     ;;
 661     esac
 662     extra_objects="$extra_objects obj-$fmt.o"
 663   done
 664   obj_format=multi
 665 fi
 666 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 667   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 668   # e-mips* has more than one emulation per file, e-i386* has just one at the
 669   # moment.  If only one emulation is specified, then don't define
 670   # USE_EMULATIONS or include any of the e-files as they will only be bloat.
 671   case "${obj_format}${emfiles}" in
 672     multi* | *mips*)
 673       extra_objects="$extra_objects $emfiles"
 674       AC_DEFINE(USE_EMULATIONS, 1, [Use emulation support?]) ;;
 675   esac
 676 fi
 677 AC_SUBST(extra_objects)
 678 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS, [Supported emulations.])
 679 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION",
 680                    [Default emulation.])
 681
 682 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 683   yes-*-coff)   need_bfd=yes ;;
 684   no-*-coff)    need_bfd=yes
 685                 AC_DEFINE(MANY_SEGMENTS, 1, [old COFF support?]) ;;
 686 esac
 687
 688 reject_dev_configs=yes
 689
 690 case ${reject_dev_configs}-${dev} in
 691   yes-yes) # Oops.
 692     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 693     ;;
 694 esac
 695
 696 AC_SUBST(target_cpu_type)
 697 AC_SUBST(obj_format)
 698 AC_SUBST(te_file)
 699 AC_SUBST(install_tooldir)
 700 AC_SUBST(atof)
 701 dnl AC_SUBST(emulation)
 702
 703 case "${primary_bfd_gas}" in
 704   yes)  AC_DEFINE(BFD_ASSEMBLER, 1, [Use BFD interface?])
 705         need_bfd=yes ;;
 706 esac
 707
 708 # do we need the opcodes library?
 709 case "${need_opcodes}" in
 710 yes)
 711   OPCODES_LIB=../opcodes/libopcodes.la
 712   ;;
 713 esac
 714
 715 case "${need_bfd}" in
 716 yes)
 717   BFDLIB=../bfd/libbfd.la
 718   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 719   ;;
 720 esac
 721
 722 AC_SUBST(BFDLIB)
 723 AC_SUBST(OPCODES_LIB)
 724
 725 AC_SUBST(ALL_OBJ_DEPS)
 726
 727 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}", [Target alias.])
 728 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}",       [Canonical target.])
 729 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}",   [Target CPU.])
 730 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}", [Target vendor.])
 731 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}",    [Target OS.])
 732
 733 AC_PROG_CC
 734
 735 AC_PROG_YACC
 736 AM_PROG_LEX
 737
 738 ALL_LINGUAS=
 739 CY_GNU_GETTEXT
 740
 741 AM_MAINTAINER_MODE
 742 AC_EXEEXT
 743
 744 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 745
 746 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 747 # people who are not cross-compiling but are compiling cross-assemblers.
 748 AC_MSG_CHECKING(whether compiling a cross-assembler)
 749 if test "${host}" = "${target}"; then
 750   cross_gas=no
 751 else
 752   cross_gas=yes
 753   AC_DEFINE(CROSS_COMPILE, 1, [Compiling cross-assembler?])
 754 fi
 755 AC_MSG_RESULT($cross_gas)
 756
 757 dnl ansidecl.h will deal with const
 758 dnl AC_CONST
 759 AC_FUNC_ALLOCA
 760 AC_C_INLINE
 761
 762 # VMS doesn't have unlink.
 763 AC_CHECK_FUNCS(unlink remove, break)
 764
 765 # Some systems don't have sbrk().
 766 AC_CHECK_FUNCS(sbrk)
 767
 768 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 769 # enough, but on some of those systems, the assert macro relies on requoting
 770 # working properly!
 771 GAS_WORKING_ASSERT
 772
 773 # On some systems, the system header files may not declare malloc, realloc,
 774 # and free.  There are places where gas needs these functions to have been
 775 # declared -- such as when taking their addresses.
 776 gas_test_headers="
 777 #ifdef HAVE_MEMORY_H
 778 #include <memory.h>
 779 #endif
 780 #ifdef HAVE_STRING_H
 781 #include <string.h>
 782 #else
 783 #ifdef HAVE_STRINGS_H
 784 #include <strings.h>
 785 #endif
 786 #endif
 787 #ifdef HAVE_STDLIB_H
 788 #include <stdlib.h>
 789 #endif
 790 #ifdef HAVE_UNISTD_H
 791 #include <unistd.h>
 792 #endif
 793 "
 794 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 795 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 796 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 797 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 798 GAS_CHECK_DECL_NEEDED(environ, f, char **f, $gas_test_headers)
 799
 800 # Does errno.h declare errno, or do we have to add a separate declaration
 801 # for it?
 802 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 803 #ifdef HAVE_ERRNO_H
 804 #include <errno.h>
 805 #endif
 806 ])
 807
 808 dnl This must come last.
 809
 810 dnl We used to make symlinks to files in the source directory, but now
 811 dnl we just use the right name for .c files, and create .h files in
 812 dnl the build directory which include the right .h file.  Make sure
 813 dnl the old symlinks don't exist, so that a reconfigure in an existing
 814 dnl directory behaves reasonably.
 815
 816 AC_OUTPUT(Makefile doc/Makefile ${GDBINIT}:gdbinit.in po/Makefile.in:po/Make-in,
 817 [rm -f targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c itbl-cpu.h
 818  echo '#include "tc-'"${target_cpu_type}"'.h"' > targ-cpu.h
 819  echo '#include "obj-'"${obj_format}"'.h"' > obj-format.h
 820  echo '#include "te-'"${te_file}"'.h"' > targ-env.h
 821  echo '#include "itbl-'"${target_cpu_type}"'.h"' > itbl-cpu.h
 822  if test "x$cgen_cpu_prefix" != x ; then
 823    echo '#include "opcodes/'"${cgen_cpu_prefix}"'-desc.h"' > cgen-desc.h
 824  fi
 825
 826  sed -e '/POTFILES =/r po/POTFILES' po/Makefile.in > po/Makefile],
 827 [target_cpu_type=${target_cpu_type}
 828  cgen_cpu_prefix=${cgen_cpu_prefix}
 829  obj_format=${obj_format}
 830  te_file=${te_file}])