gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-*vms*)        fmt=evax ;;
 111       alpha-*-netware*)     fmt=ecoff ;;
 112       alpha-*-osf*)         fmt=ecoff ;;
 113       alpha-*-linuxecoff*)  fmt=ecoff ;;
 114       alpha-*-linux*)       fmt=elf em=linux ;;
 115
 116 # start-sanitize-arc
 117       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 118 # end-sanitize-arc
 119
 120       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 121       arm-*-aout)           fmt=aout
 122                             case "$endian" in
 123                               big)      targ=arm-big ;;
 124                               *)        targ=arm-lit ;;
 125                             esac
 126                             ;;
 127       arm-*-coff)           fmt=coff ;;
 128       arm-*-riscix*)        fmt=aout ;;
 129       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 130
 131 # start-sanitize-d10v
 132       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 133 # end-sanitize-d10v
 134
 135       hppa-*-*elf*)         fmt=elf em=hppa ;;
 136       hppa-*-lites*)        fmt=elf em=hppa ;;
 137       hppa-*-osf*)          fmt=som em=hppa ;;
 138       hppa-*-hpux*)         fmt=som em=hppa ;;
 139       hppa-*-bsd*)          fmt=som em=hppa ;;
 140       hppa-*-hiux*)         fmt=som em=hppa ;;
 141
 142       h8300-*-coff)         fmt=coff ;;
 143
 144       i386-ibm-aix*)        fmt=coff targ=i386coff
 145                              em=i386aix ;;
 146       i386-*-bsd*)          fmt=aout em=386bsd ;;
 147       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 148       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 149       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 150       i386-*-linux*coff*)   fmt=coff em=linux
 151                              targ=i386coff ;;
 152       i386-*-linux*)        fmt=elf em=linux ;;
 153       i386-*-lynxos*)       fmt=coff targ=i386coff
 154                              em=lynx ;;
 155       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 156                             fmt=elf ;;
 157       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 158       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 159                             fmt=coff targ=i386coff ;;
 160       i386-*-vsta)          fmt=aout ;;
 161       i386-*-go32)          fmt=coff targ=i386coff ;;
 162       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 163       i386-*-gnu*)          fmt=elf ;;
 164       i386-*-mach*)
 165                             fmt=aout em=mach bfd_gas=yes ;;
 166       i386-*-msdos*)        fmt=aout ;;
 167       i386-*-moss*)         fmt=elf ;;
 168       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 169       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 170       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 171       i960-*-bout)          fmt=bout ;;
 172       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 173       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 174       i960-*-nindy*)        fmt=bout ;;
 175       i960-*-vxworks4*)     fmt=bout ;;
 176       i960-*-vxworks5.0)    fmt=bout ;;
 177       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 178       i960-*-vxworks*)      fmt=bout ;;
 179
 180       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 181                             fmt=aout em=sun3 ;;
 182       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 183       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 184       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 185       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 186                             fmt=elf ;;
 187       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 188                             fmt=coff targ=m68kcoff ;;
 189       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 190       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 191       m68k-*-linux*)        fmt=elf em=linux ;;
 192       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 193                              em=lynx ;;
 194       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 195       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 196       m68k-*-psos*)         fmt=elf em=psos;;
 197
 198       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 199       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 200
 201       # don't change em like *-*-bsd does
 202       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 203       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 204       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 205       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 206       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 207       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 208       mips-*-ecoff*)        fmt=ecoff
 209                             case "$endian" in
 210                             big) targ=mips-big ;;
 211                             *)   targ=mips-lit ;;
 212                             esac
 213                             ;;
 214       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 215       mips-*-gnu*)          fmt=aout
 216                             case "$endian" in
 217                             big) targ=mips-big ;;
 218                             *)   targ=mips-lit ;;
 219                             esac
 220                             ;;
 221       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 222       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 223       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 224       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 225       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 226       mips-*-elf* | mips-*-rtems*)
 227                             fmt=elf
 228                             case "$endian" in
 229                             big) targ=mips-big ;;
 230                             *)   targ=mips-lit ;;
 231                             esac
 232                             ;;
 233       mn10200-*-*)          fmt=elf bfd_gas=yes ;;
 234       mn10300-*-*)          fmt=elf bfd_gas=yes ;;
 235       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 236                             fmt=coff em=pe
 237                             case "$endian" in
 238                             big) targ=ppc-big ;;
 239                             *)   targ=ppc-lit ;;
 240                             esac
 241                             ;;
 242       ppc-*-aix*)           fmt=coff ;;
 243       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 244                             fmt=elf
 245                             case "$endian" in
 246                             big)  targ=ppc-big ;;
 247                             *)    targ=ppc-lit ;;
 248                             esac
 249                             ;;
 250       ppc-*-linux*)         fmt=elf
 251                             case "$endian" in
 252                             big)  targ=ppc-big ;;
 253                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 254                             esac
 255                             ;;
 256       ppc-*-solaris*)       fmt=elf
 257                             case "$endian" in
 258                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 259                             *)    targ=ppc-sol ;;
 260                             esac
 261                             ;;
 262       ppc-*-rtems*)
 263                             fmt=elf
 264                             case "$endian" in
 265                             big)  targ=ppc-big ;;
 266                             *)    targ=ppc-lit ;;
 267                             esac
 268                             ;;
 269       ppc-*-macos* | ppc-*-mpw*)
 270                             fmt=coff em=macos ;;
 271       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 272
 273       sh-*-elf*)            fmt=elf ;;
 274       sh-*-coff*)           fmt=coff ;;
 275
 276       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 277       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 278
 279       sparc-*-rtems*)       fmt=aout ;;
 280       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 281       sparc-*-aout | sparc*-*-vxworks*)
 282                             fmt=aout em=sparcaout ;;
 283       sparc-*-coff)         fmt=coff ;;
 284       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 285       sparc-fujitsu-none)   fmt=aout ;;
 286       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 287                             fmt=elf ;;
 288       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 289
 290       v850-*-*)             fmt=elf bfd_gas=yes ;;
 291
 292       vax-*-bsd* | vax-*-ultrix*)
 293                             fmt=aout ;;
 294       vax-*-vms)            fmt=vms ;;
 295
 296       z8k-*-coff | z8k-*-sim)
 297                             fmt=coff ;;
 298
 299       w65-*-*)              fmt=coff ;;
 300
 301       *-*-aout | *-*-scout)
 302                             fmt=aout ;;
 303       *-*-nindy*)
 304                             fmt=bout ;;
 305       *-*-bsd*)
 306                             fmt=aout em=sun3 ;;
 307       *-*-generic)          fmt=generic ;;
 308       *-*-xray | *-*-hms)   fmt=coff ;;
 309       *-*-sim)              fmt=coff ;;
 310       *-*-elf | *-*-sysv4* | *-*-solaris*)
 311                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 312                             fmt=elf dev=yes ;;
 313       *-*-vxworks)          fmt=aout ;;
 314       *-*-netware)          fmt=elf ;;
 315     esac
 316
 317     case ${cpu_type}-${fmt} in
 318       alpha-*)  bfd_gas=yes ;;
 319       arm-*)    bfd_gas=yes ;;
 320     # not yet
 321     # i386-aout)        bfd_gas=preferred ;;
 322       mips-*)   bfd_gas=yes ;;
 323       ns32k-*)  bfd_gas=yes ;;
 324       ppc-*)    bfd_gas=yes ;;
 325       sparc-*)  bfd_gas=yes ;;
 326       *-elf)    bfd_gas=yes ;;
 327       *-ecoff)  bfd_gas=yes ;;
 328       *-som)    bfd_gas=yes ;;
 329       *)                ;;
 330     esac
 331
 332 # Other random stuff.
 333
 334     # do we need the opcodes library?
 335     case ${cpu_type} in
 336       vax | i386)
 337         ;;
 338       *)
 339         need_opcodes=yes
 340         if test "${shared_opcodes}" = "true"; then
 341           # A shared libopcodes must be linked against libbfd.
 342           need_bfd=yes
 343         fi
 344         ;;
 345     esac
 346
 347     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 348
 349     case ${cpu}-${vendor}-${os} in
 350       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 351     esac
 352
 353     case ${cpu_type} in
 354       m68k)
 355         case ${extra_objects} in
 356         *m68k-parse.o*) ;;
 357         *) extra_objects="$extra_objects m68k-parse.o" ;;
 358         esac
 359         ;;
 360     esac
 361
 362 # See if we really can support this configuration with the emulation code.
 363
 364     if test $this_target = $target ; then
 365       primary_bfd_gas=$bfd_gas
 366       obj_format=$fmt
 367       gas_target=$targ
 368       te_file=$em
 369
 370       if test $bfd_gas = no ; then
 371         # Can't support other configurations this way.
 372         break
 373       fi
 374     elif test $bfd_gas = no ; then
 375       # Can't support this configuration.
 376       break
 377     fi
 378
 379 # From target name and format, produce a list of supported emulations.
 380
 381     case ${generic_target}-${fmt} in
 382       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 383       mips-*-*-ecoff)   case "$endian" in
 384                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 385                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 386                         esac ;;
 387       mips-*-*-elf)     case "$endian" in
 388                         big)    emulation="mipsbelf mipslelf mipself" ;;
 389                         *)      emulation="mipslelf mipsbelf mipself" ;;
 390                         esac ;;
 391     esac
 392
 393     emulations="$emulations $emulation"
 394
 395 done
 396
 397 # Assign floating point type.  Most processors with FP support
 398 # IEEE FP.  On those that don't support FP at all, usually IEEE
 399 # is emulated.
 400 case ${target_cpu} in
 401   vax | tahoe ) atof=${target_cpu} ;;
 402   *)            atof=ieee ;;
 403 esac
 404
 405 case "${obj_format}" in
 406   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 407 esac
 408
 409 dnl
 410 dnl Make sure the desired support files exist.
 411 dnl
 412
 413 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 414   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 415 fi
 416
 417 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 418   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 419 fi
 420
 421 # and target makefile frag
 422
 423 target_frag=${srcdir}/config/${gas_target}.mt
 424 if test ! -r ${target_frag}; then
 425   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 426 fi
 427 AC_SUBST_FILE(target_frag)
 428
 429 case ${user_bfd_gas}-${primary_bfd_gas} in
 430   yes-yes | no-no)
 431     # We didn't override user's choice.
 432     ;;
 433   no-yes)
 434     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 435     ;;
 436   no-preferred)
 437     primary_bfd_gas=no
 438     ;;
 439   *-preferred)
 440     primary_bfd_gas=yes
 441     ;;
 442   yes-*)
 443     primary_bfd_gas=yes
 444     ;;
 445   -*)
 446     # User specified nothing.
 447     ;;
 448 esac
 449
 450 # Some COFF configurations want these random other flags set.
 451 case ${obj_format} in
 452   coff)
 453     case ${target_cpu_type} in
 454       i386) AC_DEFINE(I386COFF) ;;
 455       m68k) AC_DEFINE(M68KCOFF) ;;
 456       m88k) AC_DEFINE(M88KCOFF) ;;
 457     esac
 458     ;;
 459 esac
 460
 461 # Getting this done right is going to be a bitch.  Each configuration specified
 462 # with --enable-targets=... should be checked for environment, format, cpu, and
 463 # bfd_gas setting.
 464 #
 465 # For each configuration, the necessary object file support code must be linked
 466 # in.  This might be only one, it might be up to four.  The necessary emulation
 467 # code needs to be provided, too.
 468 #
 469 # And then there's "--enable-targets=all"....
 470 #
 471 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 472
 473 formats="${obj_format}"
 474 emfiles=""
 475 EMULATIONS=""
 476 GAS_UNIQ(emulations)
 477 for em in . $emulations ; do
 478   case $em in
 479     .)  continue ;;
 480     mipsbelf | mipslelf)
 481         fmt=elf   file=mipself ;;
 482     mipsbecoff | mipslecoff)
 483         fmt=ecoff file=mipsecoff ;;
 484   esac
 485   formats="$formats $fmt"
 486   emfiles="$emfiles e-$file.o"
 487   EMULATIONS="$EMULATIONS &$em,"
 488 done
 489 GAS_UNIQ(formats)
 490 GAS_UNIQ(emfiles)
 491 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 492   for fmt in $formats ; do
 493     case $fmt in
 494       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 495       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 496       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 497       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 498       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 499       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 500       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 501       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 502       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 503       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 504     esac
 505     extra_objects="$extra_objects obj-$fmt.o"
 506   done
 507   obj_format=multi
 508 fi
 509 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 510   te_file=multi
 511   extra_objects="$extra_objects $emfiles"
 512   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 513   AC_DEFINE(USE_EMULATIONS)
 514 fi
 515 AC_SUBST(extra_objects)
 516 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 517 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 518
 519 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 520         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 521         config/te-${te_file}.h config/atof-${atof}.c \
 522         $extra_files"
 523 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 524         $extra_links"
 525
 526 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 527   yes-*-coff)   need_bfd=yes ;;
 528   no-*-coff)    need_bfd=yes
 529                 AC_DEFINE(MANY_SEGMENTS) ;;
 530 esac
 531
 532 reject_dev_configs=yes
 533
 534 case ${reject_dev_configs}-${dev} in
 535   yes-yes) # Oops.
 536     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 537     ;;
 538 esac
 539
 540 AC_SUBST(target_cpu_type)
 541 AC_SUBST(obj_format)
 542 AC_SUBST(atof)
 543 dnl AC_SUBST(emulation)
 544
 545 AC_LINK_FILES($files, $links)
 546
 547 case "${primary_bfd_gas}" in
 548   yes)  AC_DEFINE(BFD_ASSEMBLER)
 549         need_bfd=yes ;;
 550 esac
 551
 552 # do we need the opcodes library?
 553 case "${need_opcodes}" in
 554 yes)
 555   OPCODES_DEP=../opcodes/libopcodes.a
 556   OPCODES_LIB='-L../opcodes -lopcodes'
 557
 558   # We need to handle some special cases for shared libraries.
 559   case "${host}" in
 560   *-*-sunos*)
 561     # On SunOS, we must link against the name we are going to install,
 562     # not -lbfd, since SunOS does not support SONAME.
 563     if test "${shared_opcodes}" = "true"; then
 564       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 565     fi
 566     ;;
 567   alpha*-*-osf*)
 568     # On Alpha OSF/1, the native linker searches all the -L
 569     # directories for any LIB.so files, and only then searches for any
 570     # LIB.a files.  That means that if there is an installed
 571     # libbfd.so, but this build is not done with --enable-shared, the
 572     # link will wind up being against the install libbfd.so rather
 573     # than the newly built libbfd.  To avoid this, we must explicitly
 574     # link against libbfd.a when --enable-shared is not used.
 575     if test "${shared_opcodes}" != "true"; then
 576       OPCODES_LIB='../opcodes/libopcodes.a'
 577     fi
 578     ;;
 579   esac
 580   ;;
 581 esac
 582 AC_SUBST(OPCODES_DEP)
 583 AC_SUBST(OPCODES_LIB)
 584
 585 case "${need_bfd}" in
 586 yes)
 587   BFDDEP=../bfd/libbfd.a
 588   BFDLIB='-L../bfd -lbfd'
 589   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 590
 591   # We need to handle some special cases for shared libraries
 592   case "${host}" in
 593   *-*-sunos*)
 594     # On SunOS, we must link against the name we are going to install,
 595     # not -lbfd, since SunOS does not support SONAME.
 596     if test "${shared_bfd}" = "true"; then
 597       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 598     fi
 599     ;;
 600   alpha*-*-osf*)
 601     # On Alpha OSF/1, the native linker searches all the -L
 602     # directories for any LIB.so files, and only then searches for any
 603     # LIB.a files.  That means that if there is an installed
 604     # libbfd.so, but this build is not done with --enable-shared, the
 605     # link will wind up being against the install libbfd.so rather
 606     # than the newly built libbfd.  To avoid this, we must explicitly
 607     # link against libbfd.a when --enable-shared is not used.
 608     if test "${shared_bfd}" != "true"; then
 609       BFDLIB='../bfd/libbfd.a'
 610     fi
 611     ;;
 612   esac
 613   ;;
 614 esac
 615 AC_SUBST(BFDDEP)
 616 AC_SUBST(BFDLIB)
 617 AC_SUBST(ALL_OBJ_DEPS)
 618
 619 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 620 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 621 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 622 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 623 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 624
 625 AC_PROG_CC
 626 AC_PROG_INSTALL
 627
 628 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 629
 630 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 631 # people who are not cross-compiling but are compiling cross-assemblers.
 632 AC_MSG_CHECKING(whether compiling a cross-assembler)
 633 if test "${host}" = "${target}"; then
 634   cross_gas=no
 635 else
 636   cross_gas=yes
 637   AC_DEFINE(CROSS_COMPILE)
 638 fi
 639 AC_MSG_RESULT($cross_gas)
 640
 641 dnl ansidecl.h will deal with const
 642 dnl AC_CONST
 643 AC_FUNC_ALLOCA
 644 AC_C_INLINE
 645
 646 # VMS doesn't have unlink.
 647 AC_CHECK_FUNCS(unlink remove, break)
 648
 649 # Some systems don't have sbrk().
 650 AC_CHECK_FUNCS(sbrk)
 651
 652 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 653 # enough, but on some of those systems, the assert macro relies on requoting
 654 # working properly!
 655 GAS_WORKING_ASSERT
 656
 657 # On some systems, the system header files may not declare malloc, realloc,
 658 # and free.  There are places where gas needs these functions to have been
 659 # declared -- such as when taking their addresses.
 660 gas_test_headers="
 661 #ifdef HAVE_MEMORY_H
 662 #include <memory.h>
 663 #endif
 664 #ifdef HAVE_STRING_H
 665 #include <string.h>
 666 #else
 667 #ifdef HAVE_STRINGS_H
 668 #include <strings.h>
 669 #endif
 670 #endif
 671 #ifdef HAVE_STDLIB_H
 672 #include <stdlib.h>
 673 #endif
 674 #ifdef HAVE_UNISTD_H
 675 #include <unistd.h>
 676 #endif
 677 "
 678 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 679 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 680 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 681 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 682
 683 # Does errno.h declare errno, or do we have to add a separate declaration
 684 # for it?
 685 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 686 #ifdef HAVE_ERRNO_H
 687 #include <errno.h>
 688 #endif
 689 ])
 690
 691 HLDFLAGS=
 692 HLDENV=
 693 RPATH_ENVVAR=LD_LIBRARY_PATH
 694 # If we have shared libraries, try to set rpath reasonably.
 695 if test "${shared}" = "true"; then
 696   case "${host}" in
 697   *-*-hpux*)
 698     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 699     RPATH_ENVVAR=SHLIB_PATH
 700     ;;
 701   *-*-irix5* | *-*-irix6*)
 702     HLDFLAGS='-Wl,-rpath,$(libdir)'
 703     ;;
 704   *-*-linux*aout*)
 705     ;;
 706   *-*-linux*)
 707     HLDFLAGS='-Wl,-rpath,$(libdir)'
 708     ;;
 709   *-*-solaris*)
 710     HLDFLAGS='-R $(libdir)'
 711     ;;
 712   *-*-sysv4*)
 713     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 714     ;;
 715   esac
 716 fi
 717
 718 # On SunOS, if the linker supports the -rpath option, use it to
 719 # prevent ../bfd and ../opcodes from being included in the run time
 720 # search path.
 721 case "${host}" in
 722   *-*-sunos*)
 723     echo 'main () { }' > conftest.c
 724     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 725     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 726       :
 727     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 728       :
 729     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 730       :
 731     elif test "${shared}" = "true"; then
 732       HLDFLAGS='-Wl,-rpath=$(libdir)'
 733     else
 734       HLDFLAGS='-Wl,-rpath='
 735     fi
 736     rm -f conftest.t conftest.c conftest
 737     ;;
 738 esac
 739 AC_SUBST(HLDFLAGS)
 740 AC_SUBST(HLDENV)
 741 AC_SUBST(RPATH_ENVVAR)
 742
 743 dnl This must come last.
 744 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)