gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-*vms*)        fmt=evax ;;
 111       alpha-*-netware*)     fmt=ecoff ;;
 112       alpha-*-osf*)         fmt=ecoff ;;
 113       alpha-*-linuxecoff*)  fmt=ecoff ;;
 114       alpha-*-linux*)       fmt=elf em=linux ;;
 115
 116 # start-sanitize-arc
 117       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 118 # end-sanitize-arc
 119
 120       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 121       arm-*-aout)           fmt=aout
 122                             case "$endian" in
 123                               big)      targ=arm-big ;;
 124                               *)        targ=arm-lit ;;
 125                             esac
 126                             ;;
 127       arm-*-coff)           fmt=coff ;;
 128       arm-*-riscix*)        fmt=aout ;;
 129       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 130
 131 # start-sanitize-d10v
 132       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 133 # end-sanitize-d10v
 134
 135       hppa-*-*elf*)         fmt=elf em=hppa ;;
 136       hppa-*-lites*)        fmt=elf em=hppa ;;
 137       hppa-*-osf*)          fmt=som em=hppa ;;
 138       hppa-*-hpux*)         fmt=som em=hppa ;;
 139       hppa-*-bsd*)          fmt=som em=hppa ;;
 140       hppa-*-hiux*)         fmt=som em=hppa ;;
 141
 142       h8300-*-coff)         fmt=coff ;;
 143
 144       i386-ibm-aix*)        fmt=coff targ=i386coff
 145                              em=i386aix ;;
 146       i386-*-bsd*)          fmt=aout em=386bsd ;;
 147       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 148       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 149       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 150       i386-*-linux*coff*)   fmt=coff em=linux
 151                              targ=i386coff ;;
 152       i386-*-linux*)        fmt=elf em=linux ;;
 153       i386-*-lynxos*)       fmt=coff targ=i386coff
 154                              em=lynx ;;
 155       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 156                             fmt=elf ;;
 157       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 158       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 159                             fmt=coff targ=i386coff ;;
 160       i386-*-vsta)          fmt=aout ;;
 161       i386-*-go32)          fmt=coff targ=i386coff ;;
 162       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 163       i386-*-gnu*)          fmt=elf ;;
 164       i386-*-mach*)
 165                             fmt=aout em=mach bfd_gas=yes ;;
 166       i386-*-msdos*)        fmt=aout ;;
 167       i386-*-moss*)         fmt=elf ;;
 168       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 169       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 170       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 171       i960-*-bout)          fmt=bout ;;
 172       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 173       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 174       i960-*-nindy*)        fmt=bout ;;
 175       i960-*-vxworks4*)     fmt=bout ;;
 176       i960-*-vxworks5.0)    fmt=bout ;;
 177       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 178       i960-*-vxworks*)      fmt=bout ;;
 179
 180       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 181                             fmt=aout em=sun3 ;;
 182       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 183       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 184       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 185       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 186                             fmt=elf ;;
 187       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 188                             fmt=coff targ=m68kcoff ;;
 189       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 190       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 191       m68k-*-linux*)        fmt=elf em=linux ;;
 192       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 193                              em=lynx ;;
 194       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 195       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 196       m68k-*-psos*)         fmt=elf em=psos;;
 197
 198       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 199       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 200
 201       # don't change em like *-*-bsd does
 202       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 203       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 204       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 205       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 206       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 207       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 208       mips-*-ecoff*)        fmt=ecoff
 209                             case "$endian" in
 210                             big) targ=mips-big ;;
 211                             *)   targ=mips-lit ;;
 212                             esac
 213                             ;;
 214       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 215       mips-*-gnu*)          fmt=aout
 216                             case "$endian" in
 217                             big) targ=mips-big ;;
 218                             *)   targ=mips-lit ;;
 219                             esac
 220                             ;;
 221       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 222       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 223       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 224       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 225       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 226       mips-*-elf*)          fmt=elf
 227                             case "$endian" in
 228                             big) targ=mips-big ;;
 229                             *)   targ=mips-lit ;;
 230                             esac
 231                             ;;
 232       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 233                             fmt=coff em=pe
 234                             case "$endian" in
 235                             big) targ=ppc-big ;;
 236                             *)   targ=ppc-lit ;;
 237                             esac
 238                             ;;
 239       ppc-*-aix*)           fmt=coff ;;
 240       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 241                             fmt=elf
 242                             case "$endian" in
 243                             big)  targ=ppc-big ;;
 244                             *)    targ=ppc-lit ;;
 245                             esac
 246                             ;;
 247       ppc-*-linux*)         fmt=elf
 248                             case "$endian" in
 249                             big)  targ=ppc-big ;;
 250                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 251                             esac
 252                             ;;
 253       ppc-*-solaris*)       fmt=elf
 254                             case "$endian" in
 255                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 256                             *)    targ=ppc-sol ;;
 257                             esac
 258                             ;;
 259       ppc-*-rtems*)
 260                             fmt=elf
 261                             case "$endian" in
 262                             big)  targ=ppc-big ;;
 263                             *)    targ=ppc-lit ;;
 264                             esac
 265                             ;;
 266       ppc-*-macos* | ppc-*-mpw*)
 267                             fmt=coff em=macos ;;
 268       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 269
 270       sh-*-coff)            fmt=coff ;;
 271
 272       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 273       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 274
 275       sparc-*-rtems*)       fmt=aout ;;
 276       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 277       sparc-*-aout | sparc*-*-vxworks*)
 278                             fmt=aout ;;
 279       sparc-*-coff)         fmt=coff ;;
 280       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 281       sparc-fujitsu-none)   fmt=aout ;;
 282       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 283                             fmt=elf ;;
 284       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 285
 286       v850-*-*)             fmt=elf bfd_gas=yes ;;
 287
 288       vax-*-bsd* | vax-*-ultrix*)
 289                             fmt=aout ;;
 290       vax-*-vms)            fmt=vms ;;
 291
 292       z8k-*-coff | z8k-*-sim)
 293                             fmt=coff ;;
 294
 295       w65-*-*)              fmt=coff ;;
 296
 297       *-*-aout | *-*-scout)
 298                             fmt=aout ;;
 299       *-*-nindy*)
 300                             fmt=bout ;;
 301       *-*-bsd*)
 302                             fmt=aout em=sun3 ;;
 303       *-*-generic)          fmt=generic ;;
 304       *-*-xray | *-*-hms)   fmt=coff ;;
 305       *-*-sim)              fmt=coff ;;
 306       *-*-elf | *-*-sysv4* | *-*-solaris*)
 307                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 308                             fmt=elf dev=yes ;;
 309       *-*-vxworks)          fmt=aout ;;
 310       *-*-netware)          fmt=elf ;;
 311     esac
 312
 313     case ${cpu_type}-${fmt} in
 314       alpha-*)  bfd_gas=yes ;;
 315       arm-*)    bfd_gas=yes ;;
 316     # not yet
 317     # i386-aout)        bfd_gas=preferred ;;
 318       mips-*)   bfd_gas=yes ;;
 319       ns32k-*)  bfd_gas=yes ;;
 320       ppc-*)    bfd_gas=yes ;;
 321       sparc-*)  bfd_gas=yes ;;
 322       *-elf)    bfd_gas=yes ;;
 323       *-ecoff)  bfd_gas=yes ;;
 324       *-som)    bfd_gas=yes ;;
 325       *)                ;;
 326     esac
 327
 328 # Other random stuff.
 329
 330     # do we need the opcodes library?
 331     case ${cpu_type} in
 332       vax | i386)
 333         ;;
 334       *)
 335         need_opcodes=yes
 336         if test "${shared_opcodes}" = "true"; then
 337           # A shared libopcodes must be linked against libbfd.
 338           need_bfd=yes
 339         fi
 340         ;;
 341     esac
 342
 343     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 344
 345     case ${cpu}-${vendor}-${os} in
 346       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 347     esac
 348
 349     case ${cpu_type} in
 350       m68k)
 351         case ${extra_objects} in
 352         *m68k-parse.o*) ;;
 353         *) extra_objects="$extra_objects m68k-parse.o" ;;
 354         esac
 355         ;;
 356     esac
 357
 358 # See if we really can support this configuration with the emulation code.
 359
 360     if test $this_target = $target ; then
 361       primary_bfd_gas=$bfd_gas
 362       obj_format=$fmt
 363       gas_target=$targ
 364       te_file=$em
 365
 366       if test $bfd_gas = no ; then
 367         # Can't support other configurations this way.
 368         break
 369       fi
 370     elif test $bfd_gas = no ; then
 371       # Can't support this configuration.
 372       break
 373     fi
 374
 375 # From target name and format, produce a list of supported emulations.
 376
 377     case ${generic_target}-${fmt} in
 378       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 379       mips-*-*-ecoff)   case "$endian" in
 380                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 381                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 382                         esac ;;
 383       mips-*-*-elf)     case "$endian" in
 384                         big)    emulation="mipsbelf mipslelf mipself" ;;
 385                         *)      emulation="mipslelf mipsbelf mipself" ;;
 386                         esac ;;
 387     esac
 388
 389     emulations="$emulations $emulation"
 390
 391 done
 392
 393 # Assign floating point type.  Most processors with FP support
 394 # IEEE FP.  On those that don't support FP at all, usually IEEE
 395 # is emulated.
 396 case ${target_cpu} in
 397   vax | tahoe ) atof=${target_cpu} ;;
 398   *)            atof=ieee ;;
 399 esac
 400
 401 case "${obj_format}" in
 402   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 403 esac
 404
 405 dnl
 406 dnl Make sure the desired support files exist.
 407 dnl
 408
 409 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 410   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 411 fi
 412
 413 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 414   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 415 fi
 416
 417 # and target makefile frag
 418
 419 target_frag=${srcdir}/config/${gas_target}.mt
 420 if test ! -r ${target_frag}; then
 421   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 422 fi
 423 AC_SUBST_FILE(target_frag)
 424
 425 case ${user_bfd_gas}-${primary_bfd_gas} in
 426   yes-yes | no-no)
 427     # We didn't override user's choice.
 428     ;;
 429   no-yes)
 430     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 431     ;;
 432   no-preferred)
 433     primary_bfd_gas=no
 434     ;;
 435   *-preferred)
 436     primary_bfd_gas=yes
 437     ;;
 438   yes-*)
 439     primary_bfd_gas=yes
 440     ;;
 441   -*)
 442     # User specified nothing.
 443     ;;
 444 esac
 445
 446 # Some COFF configurations want these random other flags set.
 447 case ${obj_format} in
 448   coff)
 449     case ${target_cpu_type} in
 450       i386) AC_DEFINE(I386COFF) ;;
 451       m68k) AC_DEFINE(M68KCOFF) ;;
 452       m88k) AC_DEFINE(M88KCOFF) ;;
 453     esac
 454     ;;
 455 esac
 456
 457 # Getting this done right is going to be a bitch.  Each configuration specified
 458 # with --enable-targets=... should be checked for environment, format, cpu, and
 459 # bfd_gas setting.
 460 #
 461 # For each configuration, the necessary object file support code must be linked
 462 # in.  This might be only one, it might be up to four.  The necessary emulation
 463 # code needs to be provided, too.
 464 #
 465 # And then there's "--enable-targets=all"....
 466 #
 467 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 468
 469 formats="${obj_format}"
 470 emfiles=""
 471 EMULATIONS=""
 472 GAS_UNIQ(emulations)
 473 for em in . $emulations ; do
 474   case $em in
 475     .)  continue ;;
 476     mipsbelf | mipslelf)
 477         fmt=elf   file=mipself ;;
 478     mipsbecoff | mipslecoff)
 479         fmt=ecoff file=mipsecoff ;;
 480   esac
 481   formats="$formats $fmt"
 482   emfiles="$emfiles e-$file.o"
 483   EMULATIONS="$EMULATIONS &$em,"
 484 done
 485 GAS_UNIQ(formats)
 486 GAS_UNIQ(emfiles)
 487 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 488   for fmt in $formats ; do
 489     case $fmt in
 490       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 491       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 492       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 493       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 494       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 495       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 496       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 497       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 498       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 499       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 500     esac
 501     extra_objects="$extra_objects obj-$fmt.o"
 502   done
 503   obj_format=multi
 504 fi
 505 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 506   te_file=multi
 507   extra_objects="$extra_objects $emfiles"
 508   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 509   AC_DEFINE(USE_EMULATIONS)
 510 fi
 511 AC_SUBST(extra_objects)
 512 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 513 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 514
 515 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 516         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 517         config/te-${te_file}.h config/atof-${atof}.c \
 518         $extra_files"
 519 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 520         $extra_links"
 521
 522 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 523   yes-*-coff)   need_bfd=yes ;;
 524   no-*-coff)    need_bfd=yes
 525                 AC_DEFINE(MANY_SEGMENTS) ;;
 526 esac
 527
 528 reject_dev_configs=yes
 529
 530 case ${reject_dev_configs}-${dev} in
 531   yes-yes) # Oops.
 532     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 533     ;;
 534 esac
 535
 536 AC_SUBST(target_cpu_type)
 537 AC_SUBST(obj_format)
 538 AC_SUBST(atof)
 539 dnl AC_SUBST(emulation)
 540
 541 AC_LINK_FILES($files, $links)
 542
 543 case "${primary_bfd_gas}" in
 544   yes)  AC_DEFINE(BFD_ASSEMBLER)
 545         need_bfd=yes ;;
 546 esac
 547
 548 # do we need the opcodes library?
 549 case "${need_opcodes}" in
 550 yes)
 551   OPCODES_DEP=../opcodes/libopcodes.a
 552   OPCODES_LIB='-L../opcodes -lopcodes'
 553
 554   # We need to handle some special cases for shared libraries.
 555   case "${host}" in
 556   *-*-sunos*)
 557     # On SunOS, we must link against the name we are going to install,
 558     # not -lbfd, since SunOS does not support SONAME.
 559     if test "${shared_opcodes}" = "true"; then
 560       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 561     fi
 562     ;;
 563   alpha*-*-osf*)
 564     # On Alpha OSF/1, the native linker searches all the -L
 565     # directories for any LIB.so files, and only then searches for any
 566     # LIB.a files.  That means that if there is an installed
 567     # libbfd.so, but this build is not done with --enable-shared, the
 568     # link will wind up being against the install libbfd.so rather
 569     # than the newly built libbfd.  To avoid this, we must explicitly
 570     # link against libbfd.a when --enable-shared is not used.
 571     if test "${shared_opcodes}" != "true"; then
 572       OPCODES_LIB='../opcodes/libopcodes.a'
 573     fi
 574     ;;
 575   esac
 576   ;;
 577 esac
 578 AC_SUBST(OPCODES_DEP)
 579 AC_SUBST(OPCODES_LIB)
 580
 581 case "${need_bfd}" in
 582 yes)
 583   BFDDEP=../bfd/libbfd.a
 584   BFDLIB='-L../bfd -lbfd'
 585   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 586
 587   # We need to handle some special cases for shared libraries
 588   case "${host}" in
 589   *-*-sunos*)
 590     # On SunOS, we must link against the name we are going to install,
 591     # not -lbfd, since SunOS does not support SONAME.
 592     if test "${shared_bfd}" = "true"; then
 593       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 594     fi
 595     ;;
 596   alpha*-*-osf*)
 597     # On Alpha OSF/1, the native linker searches all the -L
 598     # directories for any LIB.so files, and only then searches for any
 599     # LIB.a files.  That means that if there is an installed
 600     # libbfd.so, but this build is not done with --enable-shared, the
 601     # link will wind up being against the install libbfd.so rather
 602     # than the newly built libbfd.  To avoid this, we must explicitly
 603     # link against libbfd.a when --enable-shared is not used.
 604     if test "${shared_bfd}" != "true"; then
 605       BFDLIB='../bfd/libbfd.a'
 606     fi
 607     ;;
 608   esac
 609   ;;
 610 esac
 611 AC_SUBST(BFDDEP)
 612 AC_SUBST(BFDLIB)
 613 AC_SUBST(ALL_OBJ_DEPS)
 614
 615 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 616 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 617 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 618 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 619 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 620
 621 AC_PROG_CC
 622 AC_PROG_INSTALL
 623
 624 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 625
 626 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 627 # people who are not cross-compiling but are compiling cross-assemblers.
 628 AC_MSG_CHECKING(whether compiling a cross-assembler)
 629 if test "${host}" = "${target}"; then
 630   cross_gas=no
 631 else
 632   cross_gas=yes
 633   AC_DEFINE(CROSS_COMPILE)
 634 fi
 635 AC_MSG_RESULT($cross_gas)
 636
 637 dnl ansidecl.h will deal with const
 638 dnl AC_CONST
 639 AC_FUNC_ALLOCA
 640 AC_C_INLINE
 641
 642 # VMS doesn't have unlink.
 643 AC_CHECK_FUNCS(unlink remove, break)
 644
 645 # Some systems don't have sbrk().
 646 AC_CHECK_FUNCS(sbrk)
 647
 648 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 649 # enough, but on some of those systems, the assert macro relies on requoting
 650 # working properly!
 651 GAS_WORKING_ASSERT
 652
 653 # On some systems, the system header files may not declare malloc, realloc,
 654 # and free.  There are places where gas needs these functions to have been
 655 # declared -- such as when taking their addresses.
 656 gas_test_headers="
 657 #ifdef HAVE_MEMORY_H
 658 #include <memory.h>
 659 #endif
 660 #ifdef HAVE_STRING_H
 661 #include <string.h>
 662 #else
 663 #ifdef HAVE_STRINGS_H
 664 #include <strings.h>
 665 #endif
 666 #endif
 667 #ifdef HAVE_STDLIB_H
 668 #include <stdlib.h>
 669 #endif
 670 #ifdef HAVE_UNISTD_H
 671 #include <unistd.h>
 672 #endif
 673 "
 674 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 675 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 676 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 677 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 678
 679 # Does errno.h declare errno, or do we have to add a separate declaration
 680 # for it?
 681 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 682 #ifdef HAVE_ERRNO_H
 683 #include <errno.h>
 684 #endif
 685 ])
 686
 687 HLDFLAGS=
 688 RPATH_ENVVAR=LD_LIBRARY_PATH
 689 # If we have shared libraries, try to set rpath reasonably.
 690 if test "${shared}" = "true"; then
 691   case "${host}" in
 692   *-*-hpux*)
 693     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 694     RPATH_ENVVAR=SHLIB_PATH
 695     ;;
 696   *-*-irix5* | *-*-irix6*)
 697     HLDFLAGS='-Wl,-rpath,$(libdir)'
 698     ;;
 699   *-*-linux*aout*)
 700     ;;
 701   *-*-linux*)
 702     HLDFLAGS='-Wl,-rpath,$(libdir)'
 703     ;;
 704   *-*-sysv4* | *-*-solaris*)
 705     HLDFLAGS='-R $(libdir)'
 706     ;;
 707   esac
 708 fi
 709
 710 # On SunOS, if the linker supports the -rpath option, use it to
 711 # prevent ../bfd and ../opcodes from being included in the run time
 712 # search path.
 713 case "${host}" in
 714   *-*-sunos*)
 715     echo 'main () { }' > conftest.c
 716     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 717     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 718       :
 719     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 720       :
 721     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 722       :
 723     elif test "${shared}" = "true"; then
 724       HLDFLAGS='-Wl,-rpath=$(libdir)'
 725     else
 726       HLDFLAGS='-Wl,-rpath='
 727     fi
 728     rm -f conftest.t conftest.c conftest
 729     ;;
 730 esac
 731 AC_SUBST(HLDFLAGS)
 732 AC_SUBST(RPATH_ENVVAR)
 733
 734 dnl This must come last.
 735 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)