gas/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl
   3 dnl And be careful when changing it!  If you must add tests with square
   4 dnl brackets, be sure changequote invocations surround it.
   5 dnl
   6 dnl
   7 AC_PREREQ(2.5)dnl v2.5 needed for --bindir et al
   8 AC_INIT(as.h)dnl
   9 dnl
  10 user_bfd_gas=
  11 AC_ARG_ENABLE(bfd-assembler,
  12 [  --enable-bfd-assembler  use BFD back end for writing object files],
  13 [case "${enableval}" in
  14   yes) need_bfd=yes user_bfd_gas=yes ;;
  15   no)  user_bfd_gas=no ;;
  16   *)   AC_MSG_ERROR(bad value ${enableval} given for bfd-assembler option) ;;
  17 esac])dnl
  18 AC_ARG_ENABLE(targets,
  19 [    targets            alternative target configurations besides the primary],
  20 [case "${enableval}" in
  21   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
  22             ;;
  23   no)       enable_targets= ;;
  24   *)        enable_targets=$enableval ;;
  25 esac])dnl
  26 AC_ARG_ENABLE(shared,
  27 [  --enable-shared         build shared BFD library],
  28 [case "${enableval}" in
  29   yes) shared=true shared_bfd=true shared_opcodes=true ;;
  30   no)  shared=false ;;
  31   *bfd*opcodes*) shared=true shared_bfd=true shared_opcodes=true ;;
  32   *opcodes*bfd*) shared=true shared_bfd=true shared_opcodes=true ;;
  33   *bfd*) shared=true shared_bfd=true ;;
  34   *opcodes*) shared=true shared_opcodes=true ;;
  35   *) shared=false ;;
  36 esac])dnl
  37
  38 # Generate a header file -- gets more post-processing by Makefile later.
  39 AC_CONFIG_HEADER(conf)
  40
  41 dnl For recursion to work right, this must be an absolute pathname.
  42 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  43 AC_CANONICAL_SYSTEM
  44 AC_ARG_PROGRAM
  45
  46 te_file=generic
  47
  48 canon_targets=""
  49 if test -n "$enable_targets" ; then
  50   for t in `echo $enable_targets | sed 's/,/ /g'`; do
  51     result=`$ac_config_sub $t 2>/dev/null`
  52     if test -n "$result" ; then
  53       canon_targets="$canon_targets $result"
  54 #    else
  55 #      # Permit "all", etc.  We don't support it yet though.
  56 #      canon_targets="$canon_targets $t"
  57     fi
  58   done
  59   GAS_UNIQ(canon_targets)
  60 fi
  61
  62 emulations=""
  63
  64 for this_target in $target $canon_targets ; do
  65
  66     eval `echo $this_target | sed 's/^\(.*\)-\(.*\)-\(.*\)$/cpu=\1 vendor=\2 os=\3/'`
  67
  68     # check for architecture variants
  69     case ${cpu} in
  70       armeb)            cpu_type=arm endian=big ;;
  71       arm*)             cpu_type=arm endian=little ;;
  72       hppa*)            cpu_type=hppa ;;
  73 changequote(,)dnl
  74       i[456]86)         cpu_type=i386 ;;
  75       m680[012346]0)    cpu_type=m68k ;;
  76       m68008)           cpu_type=m68k ;;
  77       m683??)           cpu_type=m68k ;;
  78 changequote([,])dnl
  79       m8*)              cpu_type=m88k ;;
  80       mips*el)          cpu_type=mips endian=little;;
  81       mips*)            cpu_type=mips endian=big ;;
  82       powerpcle*)       cpu_type=ppc endian=little ;;
  83       powerpc*)         cpu_type=ppc endian=big ;;
  84       rs6000*)          cpu_type=ppc ;;
  85       sparc64)          cpu_type=sparc want_sparc_v9=true ;;
  86       sparc*)           cpu_type=sparc ;;
  87       *)                cpu_type=${cpu} ;;
  88     esac
  89
  90     if test ${this_target} = $target ; then
  91       target_cpu_type=${cpu_type}
  92     elif test ${target_cpu_type} != ${cpu_type} ; then
  93       continue
  94     fi
  95
  96     targ=${cpu_type}
  97     generic_target=${cpu_type}-$vendor-$os
  98     dev=no
  99     bfd_gas=no
 100     em=generic
 101
 102     # assign object format
 103     case ${generic_target} in
 104       a29k-*-coff)          fmt=coff targ=ebmon29k ;;
 105       a29k-amd-udi)         fmt=coff targ=ebmon29k ;;
 106       a29k-amd-ebmon)       fmt=coff targ=ebmon29k ;;
 107       a29k-nyu-sym1)        fmt=coff targ=ebmon29k ;;
 108       a29k-*-vxworks*)      fmt=coff ;;
 109
 110       alpha-*-*vms*)        fmt=evax ;;
 111       alpha-*-netware*)     fmt=ecoff ;;
 112       alpha-*-osf*)         fmt=ecoff ;;
 113       alpha-*-linuxecoff*)  fmt=ecoff ;;
 114       alpha-*-linux*)       fmt=elf em=linux ;;
 115
 116 # start-sanitize-arc
 117       arc-*-elf*)           fmt=elf bfd_gas=yes ;;
 118 # end-sanitize-arc
 119
 120       arm-*-riscix*)        fmt=aout targ=arm-lit em=riscix ;;
 121       arm-*-aout)           fmt=aout
 122                             case "$endian" in
 123                               big)      targ=arm-big ;;
 124                               *)        targ=arm-lit ;;
 125                             esac
 126                             ;;
 127       arm-*-coff)           fmt=coff ;;
 128       arm-*-riscix*)        fmt=aout ;;
 129       arm-*-pe)             fmt=coff targ=armcoff em=pe ;;
 130
 131 # start-sanitize-d10v
 132       d10v-*-*)             fmt=elf bfd_gas=yes ;;
 133 # end-sanitize-d10v
 134
 135       hppa-*-*elf*)         fmt=elf em=hppa ;;
 136       hppa-*-lites*)        fmt=elf em=hppa ;;
 137       hppa-*-osf*)          fmt=som em=hppa ;;
 138       hppa-*-hpux*)         fmt=som em=hppa ;;
 139       hppa-*-bsd*)          fmt=som em=hppa ;;
 140       hppa-*-hiux*)         fmt=som em=hppa ;;
 141
 142       h8300-*-coff)         fmt=coff ;;
 143
 144       i386-ibm-aix*)        fmt=coff targ=i386coff
 145                              em=i386aix ;;
 146       i386-*-bsd*)          fmt=aout em=386bsd ;;
 147       i386-*-netbsd0.8)     fmt=aout em=386bsd ;;
 148       i386-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes;;
 149       i386-*-linux*aout* | i386-*-linuxoldld)   fmt=aout em=linux ;;
 150       i386-*-linux*coff*)   fmt=coff em=linux
 151                              targ=i386coff ;;
 152       i386-*-linux*)        fmt=elf em=linux ;;
 153       i386-*-lynxos*)       fmt=coff targ=i386coff
 154                              em=lynx ;;
 155       i386-*-sysv4* | i386-*-solaris* | i386-*-elf | i386-*-freebsdelf*)
 156                             fmt=elf ;;
 157       i386-*-sco*elf*)      fmt=elf targ=sco5 ;;
 158       i386-*-coff | i386-*-sysv* | i386-*-sco* | i386-*-isc*)
 159                             fmt=coff targ=i386coff ;;
 160       i386-*-vsta)          fmt=aout ;;
 161       i386-*-go32)          fmt=coff targ=i386coff ;;
 162       i386-*-rtems*)        fmt=coff targ=i386coff ;;
 163       i386-*-gnu*)          fmt=elf ;;
 164       i386-*-mach*)
 165                             fmt=aout em=mach bfd_gas=yes ;;
 166       i386-*-msdos*)        fmt=aout ;;
 167       i386-*-moss*)         fmt=elf ;;
 168       i386-*-pe)            fmt=coff targ=i386coff em=pe ;;
 169       i386-*-cygwin32)      fmt=coff targ=i386coff em=pe ;;
 170       i386-*-*nt)           fmt=coff targ=i386coff em=pe ;;
 171       i960-*-bout)          fmt=bout ;;
 172       i960-*-coff)          fmt=coff em=ic960 targ=ic960coff ;;
 173       i960-*-rtems*)        fmt=coff em=ic960 targ=ic960coff ;;
 174       i960-*-nindy*)        fmt=bout ;;
 175       i960-*-vxworks4*)     fmt=bout ;;
 176       i960-*-vxworks5.0)    fmt=bout ;;
 177       i960-*-vxworks5.*)    fmt=coff em=ic960 targ=ic960coff ;;
 178       i960-*-vxworks*)      fmt=bout ;;
 179
 180       m68k-*-vxworks* | m68k-ericsson-ose | m68k-*-sunos*)
 181                             fmt=aout em=sun3 ;;
 182       m68k-motorola-sysv*)  fmt=coff targ=m68kcoff em=delta ;;
 183       m68k-bull-sysv3*)     fmt=coff targ=m68kcoff em=dpx2 ;;
 184       m68k-apollo-*)        fmt=coff targ=apollo em=apollo ;;
 185       m68k-*-sysv4 | m68k-*-elf) # must be before -sysv*
 186                             fmt=elf ;;
 187       m68k-*-coff | m68k-*-sysv* | m68k-*-rtems*)
 188                             fmt=coff targ=m68kcoff ;;
 189       m68k-*-hpux*)         fmt=hp300 em=hp300 ;;
 190       m68k-*-linux*aout*)   fmt=aout em=linux ;;
 191       m68k-*-linux*)        fmt=elf em=linux ;;
 192       m68k-*-lynxos*)       fmt=coff targ=m68kcoff
 193                              em=lynx ;;
 194       m68k-*-netbsd*)       fmt=aout em=nbsd bfd_gas=yes ;;
 195       m68k-apple-aux*)      fmt=coff targ=m68kcoff em=aux ;;
 196       m68k-*-psos*)         fmt=elf em=psos;;
 197
 198       m88k-motorola-sysv3*) fmt=coff targ=m88kcoff em=delt88 ;;
 199       m88k-*-coff*)         fmt=coff targ=m88kcoff ;;
 200
 201       # don't change em like *-*-bsd does
 202       mips-dec-netbsd*)     fmt=elf targ=mips-lit endian=little ;;
 203       mips-dec-bsd*)        fmt=aout targ=mips-lit ;;
 204       mips-sony-bsd*)       fmt=ecoff targ=mips-big ;;
 205       mips-*-bsd*)          AC_MSG_ERROR(Unknown vendor for mips-bsd configuration.) ;;
 206       mips-*-ultrix*)       fmt=ecoff targ=mips-lit endian=little ;;
 207       mips-*-osf*)          fmt=ecoff targ=mips-lit endian=little ;;
 208       mips-*-ecoff*)        fmt=ecoff
 209                             case "$endian" in
 210                             big) targ=mips-big ;;
 211                             *)   targ=mips-lit ;;
 212                             esac
 213                             ;;
 214       mips-*-ecoff*)        fmt=ecoff targ=mips-big ;;
 215       mips-*-gnu*)          fmt=aout
 216                             case "$endian" in
 217                             big) targ=mips-big ;;
 218                             *)   targ=mips-lit ;;
 219                             esac
 220                             ;;
 221       mips-*-irix6*)        fmt=elf targ=mips-big ;;
 222       mips-*-irix5*)        fmt=elf targ=mips-big ;;
 223       mips-*-irix*)         fmt=ecoff targ=mips-big ;;
 224       mips-*-riscos*)       fmt=ecoff targ=mips-big ;;
 225       mips-*-sysv*)         fmt=ecoff targ=mips-big ;;
 226       mips-*-elf* | mips-*-rtems*)
 227                             fmt=elf
 228                             case "$endian" in
 229                             big) targ=mips-big ;;
 230                             *)   targ=mips-lit ;;
 231                             esac
 232                             ;;
 233       ppc-*-pe | ppc-*-cygwin32 | ppc-*-winnt*)
 234                             fmt=coff em=pe
 235                             case "$endian" in
 236                             big) targ=ppc-big ;;
 237                             *)   targ=ppc-lit ;;
 238                             esac
 239                             ;;
 240       ppc-*-aix*)           fmt=coff ;;
 241       ppc-*-elf* | ppc-*-eabi* | ppc-*-sysv4*)
 242                             fmt=elf
 243                             case "$endian" in
 244                             big)  targ=ppc-big ;;
 245                             *)    targ=ppc-lit ;;
 246                             esac
 247                             ;;
 248       ppc-*-linux*)         fmt=elf
 249                             case "$endian" in
 250                             big)  targ=ppc-big ;;
 251                             *)    AC_MSG_ERROR(Linux must be configured big endian) ;;
 252                             esac
 253                             ;;
 254       ppc-*-solaris*)       fmt=elf
 255                             case "$endian" in
 256                             big)  AC_MSG_ERROR(Solaris must be configured little endian) ;;
 257                             *)    targ=ppc-sol ;;
 258                             esac
 259                             ;;
 260       ppc-*-rtems*)
 261                             fmt=elf
 262                             case "$endian" in
 263                             big)  targ=ppc-big ;;
 264                             *)    targ=ppc-lit ;;
 265                             esac
 266                             ;;
 267       ppc-*-macos* | ppc-*-mpw*)
 268                             fmt=coff em=macos ;;
 269       ppc-*-netware*)       fmt=elf em=ppcnw ;;
 270
 271       sh-*-elf*)            fmt=elf ;;
 272       sh-*-coff*)           fmt=coff ;;
 273
 274       ns32k-pc532-mach* | ns32k-pc532-ux*)    fmt=aout em=pc532mach ;;
 275       ns32k-pc532-netbsd* | ns32k-pc532-lites*)  fmt=aout em=nbsd532 ;;
 276
 277       sparc-*-rtems*)       fmt=aout ;;
 278       sparc-*-sunos4*)      fmt=aout em=sun3 ;;
 279       sparc-*-aout | sparc*-*-vxworks*)
 280                             fmt=aout em=sparcaout ;;
 281       sparc-*-coff)         fmt=coff ;;
 282       sparc-*-lynxos*)      fmt=coff em=lynx ;;
 283       sparc-fujitsu-none)   fmt=aout ;;
 284       sparc-*-elf | sparc-*-sysv4* | sparc-*-solaris*)
 285                             fmt=elf ;;
 286       sparc-*-netbsd*)      fmt=aout em=nbsd bfd_gas=yes ;;
 287
 288       v850-*-*)             fmt=elf bfd_gas=yes ;;
 289
 290       vax-*-bsd* | vax-*-ultrix*)
 291                             fmt=aout ;;
 292       vax-*-vms)            fmt=vms ;;
 293
 294       z8k-*-coff | z8k-*-sim)
 295                             fmt=coff ;;
 296
 297       w65-*-*)              fmt=coff ;;
 298
 299       *-*-aout | *-*-scout)
 300                             fmt=aout ;;
 301       *-*-nindy*)
 302                             fmt=bout ;;
 303       *-*-bsd*)
 304                             fmt=aout em=sun3 ;;
 305       *-*-generic)          fmt=generic ;;
 306       *-*-xray | *-*-hms)   fmt=coff ;;
 307       *-*-sim)              fmt=coff ;;
 308       *-*-elf | *-*-sysv4* | *-*-solaris*)
 309                             AC_MSG_WARN(GAS support for ${generic_target} is incomplete.)
 310                             fmt=elf dev=yes ;;
 311       *-*-vxworks)          fmt=aout ;;
 312       *-*-netware)          fmt=elf ;;
 313     esac
 314
 315     case ${cpu_type}-${fmt} in
 316       alpha-*)  bfd_gas=yes ;;
 317       arm-*)    bfd_gas=yes ;;
 318     # not yet
 319     # i386-aout)        bfd_gas=preferred ;;
 320       mips-*)   bfd_gas=yes ;;
 321       ns32k-*)  bfd_gas=yes ;;
 322       ppc-*)    bfd_gas=yes ;;
 323       sparc-*)  bfd_gas=yes ;;
 324       *-elf)    bfd_gas=yes ;;
 325       *-ecoff)  bfd_gas=yes ;;
 326       *-som)    bfd_gas=yes ;;
 327       *)                ;;
 328     esac
 329
 330 # Other random stuff.
 331
 332     # do we need the opcodes library?
 333     case ${cpu_type} in
 334       vax | i386)
 335         ;;
 336       *)
 337         need_opcodes=yes
 338         if test "${shared_opcodes}" = "true"; then
 339           # A shared libopcodes must be linked against libbfd.
 340           need_bfd=yes
 341         fi
 342         ;;
 343     esac
 344
 345     test -n "$want_sparc_v9" && AC_DEFINE(SPARC_V9)
 346
 347     case ${cpu}-${vendor}-${os} in
 348       sparc64-*-elf*) AC_DEFINE(SPARC_ARCH64) ;;
 349     esac
 350
 351     case ${cpu_type} in
 352       m68k)
 353         case ${extra_objects} in
 354         *m68k-parse.o*) ;;
 355         *) extra_objects="$extra_objects m68k-parse.o" ;;
 356         esac
 357         ;;
 358     esac
 359
 360 # See if we really can support this configuration with the emulation code.
 361
 362     if test $this_target = $target ; then
 363       primary_bfd_gas=$bfd_gas
 364       obj_format=$fmt
 365       gas_target=$targ
 366       te_file=$em
 367
 368       if test $bfd_gas = no ; then
 369         # Can't support other configurations this way.
 370         break
 371       fi
 372     elif test $bfd_gas = no ; then
 373       # Can't support this configuration.
 374       break
 375     fi
 376
 377 # From target name and format, produce a list of supported emulations.
 378
 379     case ${generic_target}-${fmt} in
 380       mips-*-irix5*-*)  emulation="mipsbelf mipslelf mipself mipsbecoff mipslecoff mipsecoff" ;;
 381       mips-*-*-ecoff)   case "$endian" in
 382                         big)    emulation="mipsbecoff mipslecoff mipsecoff" ;;
 383                         *)      emulation="mipslecoff mipsbecoff mipsecoff" ;;
 384                         esac ;;
 385       mips-*-*-elf)     case "$endian" in
 386                         big)    emulation="mipsbelf mipslelf mipself" ;;
 387                         *)      emulation="mipslelf mipsbelf mipself" ;;
 388                         esac ;;
 389     esac
 390
 391     emulations="$emulations $emulation"
 392
 393 done
 394
 395 # Assign floating point type.  Most processors with FP support
 396 # IEEE FP.  On those that don't support FP at all, usually IEEE
 397 # is emulated.
 398 case ${target_cpu} in
 399   vax | tahoe ) atof=${target_cpu} ;;
 400   *)            atof=ieee ;;
 401 esac
 402
 403 case "${obj_format}" in
 404   "") AC_MSG_ERROR(GAS does not know what format to use for target ${target}) ;;
 405 esac
 406
 407 dnl
 408 dnl Make sure the desired support files exist.
 409 dnl
 410
 411 if test ! -r ${srcdir}/config/tc-${target_cpu_type}.c; then
 412   AC_MSG_ERROR(GAS does not support target CPU ${target_cpu_type})
 413 fi
 414
 415 if test ! -r ${srcdir}/config/obj-${obj_format}.c; then
 416   AC_MSG_ERROR(GAS does not have support for object file format ${obj_format})
 417 fi
 418
 419 # and target makefile frag
 420
 421 target_frag=${srcdir}/config/${gas_target}.mt
 422 if test ! -r ${target_frag}; then
 423   target_frag=/dev/null # ick! but subst_file can't be conditionalized
 424 fi
 425 AC_SUBST_FILE(target_frag)
 426
 427 case ${user_bfd_gas}-${primary_bfd_gas} in
 428   yes-yes | no-no)
 429     # We didn't override user's choice.
 430     ;;
 431   no-yes)
 432     AC_MSG_WARN(Use of BFD is required for ${target}; overriding config options.)
 433     ;;
 434   no-preferred)
 435     primary_bfd_gas=no
 436     ;;
 437   *-preferred)
 438     primary_bfd_gas=yes
 439     ;;
 440   yes-*)
 441     primary_bfd_gas=yes
 442     ;;
 443   -*)
 444     # User specified nothing.
 445     ;;
 446 esac
 447
 448 # Some COFF configurations want these random other flags set.
 449 case ${obj_format} in
 450   coff)
 451     case ${target_cpu_type} in
 452       i386) AC_DEFINE(I386COFF) ;;
 453       m68k) AC_DEFINE(M68KCOFF) ;;
 454       m88k) AC_DEFINE(M88KCOFF) ;;
 455     esac
 456     ;;
 457 esac
 458
 459 # Getting this done right is going to be a bitch.  Each configuration specified
 460 # with --enable-targets=... should be checked for environment, format, cpu, and
 461 # bfd_gas setting.
 462 #
 463 # For each configuration, the necessary object file support code must be linked
 464 # in.  This might be only one, it might be up to four.  The necessary emulation
 465 # code needs to be provided, too.
 466 #
 467 # And then there's "--enable-targets=all"....
 468 #
 469 # For now, just always do it for MIPS ELF or ECOFF configurations.  Sigh.
 470
 471 formats="${obj_format}"
 472 emfiles=""
 473 EMULATIONS=""
 474 GAS_UNIQ(emulations)
 475 for em in . $emulations ; do
 476   case $em in
 477     .)  continue ;;
 478     mipsbelf | mipslelf)
 479         fmt=elf   file=mipself ;;
 480     mipsbecoff | mipslecoff)
 481         fmt=ecoff file=mipsecoff ;;
 482   esac
 483   formats="$formats $fmt"
 484   emfiles="$emfiles e-$file.o"
 485   EMULATIONS="$EMULATIONS &$em,"
 486 done
 487 GAS_UNIQ(formats)
 488 GAS_UNIQ(emfiles)
 489 if test `set . $formats ; shift ; echo $#` -gt 1 ; then
 490   for fmt in $formats ; do
 491     case $fmt in
 492       aout)     AC_DEFINE(OBJ_MAYBE_AOUT)    ;;
 493       bout)     AC_DEFINE(OBJ_MAYBE_BOUT)    ;;
 494       coff)     AC_DEFINE(OBJ_MAYBE_COFF)    ;;
 495       ecoff)    AC_DEFINE(OBJ_MAYBE_ECOFF)   ;;
 496       elf)      AC_DEFINE(OBJ_MAYBE_ELF)     ;;
 497       generic)  AC_DEFINE(OBJ_MAYBE_GENERIC) ;;
 498       hp300)    AC_DEFINE(OBJ_MAYBE_HP300)   ;;
 499       ieee)     AC_DEFINE(OBJ_MAYBE_IEEE)    ;;
 500       som)      AC_DEFINE(OBJ_MAYBE_SOM)     ;;
 501       vms)      AC_DEFINE(OBJ_MAYBE_VMS)     ;;
 502     esac
 503     extra_objects="$extra_objects obj-$fmt.o"
 504   done
 505   obj_format=multi
 506 fi
 507 if test `set . $emfiles ; shift ; echo $#` -gt 0 ; then
 508   te_file=multi
 509   extra_objects="$extra_objects $emfiles"
 510   DEFAULT_EMULATION=`set . $emulations ; echo $2`
 511   AC_DEFINE(USE_EMULATIONS)
 512 fi
 513 AC_SUBST(extra_objects)
 514 AC_DEFINE_UNQUOTED(EMULATIONS, $EMULATIONS)
 515 AC_DEFINE_UNQUOTED(DEFAULT_EMULATION, "$DEFAULT_EMULATION")
 516
 517 files="config/tc-${target_cpu_type}.c config/tc-${target_cpu_type}.h \
 518         config/obj-${obj_format}.h config/obj-${obj_format}.c \
 519         config/te-${te_file}.h config/atof-${atof}.c \
 520         $extra_files"
 521 links="targ-cpu.c targ-cpu.h obj-format.h obj-format.c targ-env.h atof-targ.c \
 522         $extra_links"
 523
 524 case ${primary_bfd_gas}-${target_cpu_type}-${obj_format} in
 525   yes-*-coff)   need_bfd=yes ;;
 526   no-*-coff)    need_bfd=yes
 527                 AC_DEFINE(MANY_SEGMENTS) ;;
 528 esac
 529
 530 reject_dev_configs=yes
 531
 532 case ${reject_dev_configs}-${dev} in
 533   yes-yes) # Oops.
 534     AC_MSG_ERROR(GAS does not support the ${generic_target} configuration.)
 535     ;;
 536 esac
 537
 538 AC_SUBST(target_cpu_type)
 539 AC_SUBST(obj_format)
 540 AC_SUBST(atof)
 541 dnl AC_SUBST(emulation)
 542
 543 AC_LINK_FILES($files, $links)
 544
 545 case "${primary_bfd_gas}" in
 546   yes)  AC_DEFINE(BFD_ASSEMBLER)
 547         need_bfd=yes ;;
 548 esac
 549
 550 # do we need the opcodes library?
 551 case "${need_opcodes}" in
 552 yes)
 553   OPCODES_DEP=../opcodes/libopcodes.a
 554   OPCODES_LIB='-L../opcodes -lopcodes'
 555
 556   # We need to handle some special cases for shared libraries.
 557   case "${host}" in
 558   *-*-sunos*)
 559     # On SunOS, we must link against the name we are going to install,
 560     # not -lbfd, since SunOS does not support SONAME.
 561     if test "${shared_opcodes}" = "true"; then
 562       OPCODES_LIB='-L../opcodes -l`echo opcodes | sed '"'"'$(program_transform_name)'"'"'`'
 563     fi
 564     ;;
 565   alpha*-*-osf*)
 566     # On Alpha OSF/1, the native linker searches all the -L
 567     # directories for any LIB.so files, and only then searches for any
 568     # LIB.a files.  That means that if there is an installed
 569     # libbfd.so, but this build is not done with --enable-shared, the
 570     # link will wind up being against the install libbfd.so rather
 571     # than the newly built libbfd.  To avoid this, we must explicitly
 572     # link against libbfd.a when --enable-shared is not used.
 573     if test "${shared_opcodes}" != "true"; then
 574       OPCODES_LIB='../opcodes/libopcodes.a'
 575     fi
 576     ;;
 577   esac
 578   ;;
 579 esac
 580 AC_SUBST(OPCODES_DEP)
 581 AC_SUBST(OPCODES_LIB)
 582
 583 case "${need_bfd}" in
 584 yes)
 585   BFDDEP=../bfd/libbfd.a
 586   BFDLIB='-L../bfd -lbfd'
 587   ALL_OBJ_DEPS="$ALL_OBJ_DEPS ../bfd/bfd.h"
 588
 589   # We need to handle some special cases for shared libraries
 590   case "${host}" in
 591   *-*-sunos*)
 592     # On SunOS, we must link against the name we are going to install,
 593     # not -lbfd, since SunOS does not support SONAME.
 594     if test "${shared_bfd}" = "true"; then
 595       BFDLIB='-L../bfd -l`echo bfd | sed '"'"'$(program_transform_name)'"'"'`'
 596     fi
 597     ;;
 598   alpha*-*-osf*)
 599     # On Alpha OSF/1, the native linker searches all the -L
 600     # directories for any LIB.so files, and only then searches for any
 601     # LIB.a files.  That means that if there is an installed
 602     # libbfd.so, but this build is not done with --enable-shared, the
 603     # link will wind up being against the install libbfd.so rather
 604     # than the newly built libbfd.  To avoid this, we must explicitly
 605     # link against libbfd.a when --enable-shared is not used.
 606     if test "${shared_bfd}" != "true"; then
 607       BFDLIB='../bfd/libbfd.a'
 608     fi
 609     ;;
 610   esac
 611   ;;
 612 esac
 613 AC_SUBST(BFDDEP)
 614 AC_SUBST(BFDLIB)
 615 AC_SUBST(ALL_OBJ_DEPS)
 616
 617 AC_DEFINE_UNQUOTED(TARGET_ALIAS,        "${target_alias}")
 618 AC_DEFINE_UNQUOTED(TARGET_CANONICAL,    "${target}")
 619 AC_DEFINE_UNQUOTED(TARGET_CPU,          "${target_cpu}")
 620 AC_DEFINE_UNQUOTED(TARGET_VENDOR,       "${target_vendor}")
 621 AC_DEFINE_UNQUOTED(TARGET_OS,           "${target_os}")
 622
 623 AC_PROG_CC
 624 AC_PROG_INSTALL
 625
 626 AC_CHECK_HEADERS(string.h stdlib.h memory.h strings.h unistd.h stdarg.h varargs.h errno.h sys/types.h)
 627
 628 # Put this here so that autoconf's "cross-compiling" message doesn't confuse
 629 # people who are not cross-compiling but are compiling cross-assemblers.
 630 AC_MSG_CHECKING(whether compiling a cross-assembler)
 631 if test "${host}" = "${target}"; then
 632   cross_gas=no
 633 else
 634   cross_gas=yes
 635   AC_DEFINE(CROSS_COMPILE)
 636 fi
 637 AC_MSG_RESULT($cross_gas)
 638
 639 dnl ansidecl.h will deal with const
 640 dnl AC_CONST
 641 AC_FUNC_ALLOCA
 642 AC_C_INLINE
 643
 644 # VMS doesn't have unlink.
 645 AC_CHECK_FUNCS(unlink remove, break)
 646
 647 # Some systems don't have sbrk().
 648 AC_CHECK_FUNCS(sbrk)
 649
 650 # Some non-ANSI preprocessors botch requoting inside strings.  That's bad
 651 # enough, but on some of those systems, the assert macro relies on requoting
 652 # working properly!
 653 GAS_WORKING_ASSERT
 654
 655 # On some systems, the system header files may not declare malloc, realloc,
 656 # and free.  There are places where gas needs these functions to have been
 657 # declared -- such as when taking their addresses.
 658 gas_test_headers="
 659 #ifdef HAVE_MEMORY_H
 660 #include <memory.h>
 661 #endif
 662 #ifdef HAVE_STRING_H
 663 #include <string.h>
 664 #else
 665 #ifdef HAVE_STRINGS_H
 666 #include <strings.h>
 667 #endif
 668 #endif
 669 #ifdef HAVE_STDLIB_H
 670 #include <stdlib.h>
 671 #endif
 672 #ifdef HAVE_UNISTD_H
 673 #include <unistd.h>
 674 #endif
 675 "
 676 GAS_CHECK_DECL_NEEDED(strstr, f, char *(*f)(), $gas_test_headers)
 677 GAS_CHECK_DECL_NEEDED(malloc, f, char *(*f)(), $gas_test_headers)
 678 GAS_CHECK_DECL_NEEDED(free, f, void (*f)(), $gas_test_headers)
 679 GAS_CHECK_DECL_NEEDED(sbrk, f, char *(*f)(), $gas_test_headers)
 680
 681 # Does errno.h declare errno, or do we have to add a separate declaration
 682 # for it?
 683 GAS_CHECK_DECL_NEEDED(errno, f, int f, [
 684 #ifdef HAVE_ERRNO_H
 685 #include <errno.h>
 686 #endif
 687 ])
 688
 689 HLDFLAGS=
 690 HLDENV=
 691 RPATH_ENVVAR=LD_LIBRARY_PATH
 692 # If we have shared libraries, try to set rpath reasonably.
 693 if test "${shared}" = "true"; then
 694   case "${host}" in
 695   *-*-hpux*)
 696     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 697     RPATH_ENVVAR=SHLIB_PATH
 698     ;;
 699   *-*-irix5* | *-*-irix6*)
 700     HLDFLAGS='-Wl,-rpath,$(libdir)'
 701     ;;
 702   *-*-linux*aout*)
 703     ;;
 704   *-*-linux*)
 705     HLDFLAGS='-Wl,-rpath,$(libdir)'
 706     ;;
 707   *-*-solaris*)
 708     HLDFLAGS='-R $(libdir)'
 709     ;;
 710   *-*-sysv4*)
 711     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 712     ;;
 713   esac
 714 fi
 715
 716 # On SunOS, if the linker supports the -rpath option, use it to
 717 # prevent ../bfd and ../opcodes from being included in the run time
 718 # search path.
 719 case "${host}" in
 720   *-*-sunos*)
 721     echo 'main () { }' > conftest.c
 722     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 723     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 724       :
 725     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 726       :
 727     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 728       :
 729     elif test "${shared}" = "true"; then
 730       HLDFLAGS='-Wl,-rpath=$(libdir)'
 731     else
 732       HLDFLAGS='-Wl,-rpath='
 733     fi
 734     rm -f conftest.t conftest.c conftest
 735     ;;
 736 esac
 737 AC_SUBST(HLDFLAGS)
 738 AC_SUBST(HLDENV)
 739 AC_SUBST(RPATH_ENVVAR)
 740
 741 dnl This must come last.
 742 AC_OUTPUT(Makefile doc/Makefile .gdbinit:gdbinit.in)