gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2021 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 m4_include(../config/debuginfod.m4)
  22
  23 AC_INIT
  24 AC_CONFIG_SRCDIR([main.c])
  25 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36
  37 # Set build, build_cpu, build_vendor and build_os.
  38 AC_CANONICAL_BUILD
  39
  40 # Set host, host_cpu, host_vendor, and host_os.
  41 AC_CANONICAL_HOST
  42
  43 # Set target, target_cpu, target_vendor, and target_os.
  44 AC_CANONICAL_TARGET
  45
  46 ACX_NONCANONICAL_TARGET
  47
  48 AC_ARG_PROGRAM
  49
  50 # We require a C++11 compiler.  Check if one is available, and if
  51 # necessary, set CXX_DIALECT to some -std=xxx switch.
  52 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  53
  54 # Dependency checking.
  55 ZW_CREATE_DEPDIR
  56 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  57
  58 dnl List of object files and targets accumulated by configure.
  59
  60 CONFIG_OBS=
  61 CONFIG_DEPS=
  62 CONFIG_SRCS=
  63 ENABLE_CFLAGS=
  64
  65 CONFIG_ALL=
  66 CONFIG_CLEAN=
  67 CONFIG_INSTALL=
  68 CONFIG_UNINSTALL=
  69
  70 dnl Set up for gettext.
  71 ZW_GNU_GETTEXT_SISTER_DIR
  72
  73 localedir='${datadir}/locale'
  74 AC_SUBST(localedir)
  75
  76 if test x"$USE_NLS" = xyes; then
  77    CONFIG_ALL="$CONFIG_ALL all-po"
  78    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  79    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  80    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  81 fi
  82
  83 PACKAGE=gdb
  84 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  85 AC_SUBST(PACKAGE)
  86
  87 # We never need to detect it in this sub-configure.
  88 # But preserve it for config.status --recheck.
  89 AC_ARG_VAR(MAKEINFO,
  90   [Parent configure detects if it is of sufficient version.])
  91 AC_ARG_VAR(MAKEINFOFLAGS,
  92   [Parameters for MAKEINFO.])
  93
  94 MAKEINFO_EXTRA_FLAGS=""
  95 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  96   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  97   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  98     gdb_cv_have_makeinfo_click=yes
  99   else
 100     gdb_cv_have_makeinfo_click=no
 101   fi])
 102 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 103   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 104 fi
 105 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 106
 107 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 108     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 109     [${libdir}/debug])
 110
 111 # We can't pass paths as command line arguments.
 112 # Mingw32 tries to be clever and will convert the paths for us.
 113 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 114 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 115 # This breaks GDB's relocatable path conversions since paths passed in
 116 # config.h would not get so translated, the path prefixes no longer match.
 117 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 118
 119 # GDB's datadir relocation
 120
 121 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 122     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 123     [${datadir}/gdb])
 124
 125 AC_ARG_WITH(relocated-sources,
 126 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 127 [reloc_srcdir="${withval}"
 128  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 129               [Relocated directory for source files. ])
 130 ])
 131
 132 AC_MSG_CHECKING([for default auto-load directory])
 133 AC_ARG_WITH(auto-load-dir,
 134 AS_HELP_STRING([--with-auto-load-dir=PATH],
 135   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 136   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 137 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 138 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 139               [Directories from which to load auto-loaded scripts.])
 140 AC_MSG_RESULT([$with_auto_load_dir])
 141
 142 AC_MSG_CHECKING([for default auto-load safe-path])
 143 AC_ARG_WITH(auto-load-safe-path,
 144 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 145   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 146 AS_HELP_STRING([--without-auto-load-safe-path],
 147                [do not restrict auto-loaded files locations]),
 148     [if test "$with_auto_load_safe_path" = "no"; then
 149      with_auto_load_safe_path="/"
 150      fi],
 151 [with_auto_load_safe_path="$with_auto_load_dir"])
 152 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 153 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 154               [Directories safe to hold auto-loaded files.])
 155 AC_MSG_RESULT([$with_auto_load_safe_path])
 156
 157 # Enable shared libraries.
 158 AC_ARG_ENABLE(shared,
 159 AS_HELP_STRING([--enable-shared], [build shared libraries [default=yes]]),,
 160   enable_shared=yes)
 161
 162 # If we have shared libraries, try to set RPATH_ENVVAR reasonably,
 163 # such that we can find the shared libraries in the build tree.
 164 if test $enable_shared = no; then
 165   # The variable `RPATH_ENVVAR' itself is not likely to be used on any
 166   # platform.
 167   RPATH_ENVVAR=RPATH_ENVVAR
 168 else
 169   # The variable `LD_LIBRARY_PATH' is used on most platforms.
 170   RPATH_ENVVAR=LD_LIBRARY_PATH
 171   # The following exceptions are taken from Libtool 1.4.3.
 172   case $host_os in
 173     aix*)
 174       if test $host_cpu != ia64; then
 175         RPATH_ENVVAR=LIBPATH
 176       fi ;;
 177     darwin* | rhapsody*)
 178       RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
 179   esac
 180 fi
 181 AC_SUBST(RPATH_ENVVAR)
 182
 183 # Check whether to support alternative target configurations
 184 AC_ARG_ENABLE(targets,
 185 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 186 [case "${enableval}" in
 187   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
 188             ;;
 189   no)       enable_targets= ;;
 190   *)        enable_targets=$enableval ;;
 191 esac])
 192
 193 # Check whether to enable 64-bit support on 32-bit hosts
 194 AC_ARG_ENABLE(64-bit-bfd,
 195 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 196 [case "${enableval}" in
 197   yes)  want64=true  ;;
 198   no)   want64=false ;;
 199   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 200 esac],[want64=false])dnl
 201
 202 # Provide defaults for some variables set by the per-host and per-target
 203 # configuration.
 204 gdb_host_obs=posix-hdep.o
 205
 206 if test "${target}" = "${host}"; then
 207   gdb_native=yes
 208 else
 209   gdb_native=no
 210 fi
 211
 212 . $srcdir/configure.host
 213
 214 # Accumulate some settings from configure.tgt over all enabled targets
 215
 216 TARGET_OBS=
 217 all_targets=
 218 HAVE_NATIVE_GCORE_TARGET=
 219
 220 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 221 do
 222   if test "$targ_alias" = "all"; then
 223     all_targets=true
 224   else
 225     # Canonicalize the secondary target names.
 226     result=`$ac_config_sub $targ_alias 2>/dev/null`
 227     if test -n "$result"; then
 228         targ=$result
 229     else
 230         targ=$targ_alias
 231     fi
 232
 233     . ${srcdir}/configure.tgt
 234
 235     AS_IF([test -z "${gdb_target_obs}"],
 236       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 237
 238     # Target-specific object files
 239     for i in ${gdb_target_obs}; do
 240         case " $TARGET_OBS " in
 241         *" ${i} "*) ;;
 242         *)
 243           TARGET_OBS="$TARGET_OBS ${i}"
 244           ;;
 245         esac
 246     done
 247
 248     # Check whether this target needs 64-bit CORE_ADDR
 249     if test x${want64} = xfalse; then
 250       . ${srcdir}/../bfd/config.bfd
 251     fi
 252
 253     # Check whether this target is native and supports gcore.
 254     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 255        && $gdb_have_gcore; then
 256       HAVE_NATIVE_GCORE_TARGET=1
 257     fi
 258   fi
 259 done
 260
 261 if test x${all_targets} = xtrue; then
 262
 263   # We want all 64-bit targets if we either:
 264   #  - run on a 64-bit host  or
 265   #  - already require 64-bit support for some other target  or
 266   #  - the --enable-64-bit-bfd option was supplied
 267   # Otherwise we only support all 32-bit targets.
 268   #
 269   # NOTE: This test must be in sync with the corresponding
 270   #       tests in BFD!
 271
 272   if test x${want64} = xfalse; then
 273     AC_CHECK_SIZEOF(long)
 274     if test "x${ac_cv_sizeof_long}" = "x8"; then
 275       want64=true
 276     fi
 277   fi
 278   if test x${want64} = xtrue; then
 279     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 280   else
 281     TARGET_OBS='$(ALL_TARGET_OBS)'
 282   fi
 283 fi
 284
 285 AC_SUBST(TARGET_OBS)
 286 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 287
 288 # For other settings, only the main target counts.
 289 gdb_sim=
 290 gdb_osabi=
 291 targ=$target; . ${srcdir}/configure.tgt
 292
 293 # Fetch the default architecture and default target vector from BFD.
 294 targ=$target; . $srcdir/../bfd/config.bfd
 295
 296 # We only want the first architecture, so strip off the others if
 297 # there is more than one.
 298 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 299
 300 if test "x$targ_archs" != x; then
 301   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 302     [Define to BFD's default architecture. ])
 303 fi
 304 if test "x$targ_defvec" != x; then
 305   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 306     [Define to BFD's default target vector. ])
 307 fi
 308
 309 # Enable MI.
 310 AC_ARG_ENABLE(gdbmi,
 311 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 312   [case $enableval in
 313     yes | no)
 314       ;;
 315     *)
 316       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 317   esac],
 318   [enable_gdbmi=yes])
 319 if test x"$enable_gdbmi" = xyes; then
 320   if test -d "$srcdir/mi"; then
 321     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 322     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 323     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 324     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 325   fi
 326 fi
 327
 328 # Enable TUI.
 329 AC_ARG_ENABLE(tui,
 330 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 331   [case $enableval in
 332     yes | no | auto)
 333       ;;
 334     *)
 335       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 336   esac],enable_tui=auto)
 337
 338 # Enable gdbtk.
 339 AC_ARG_ENABLE(gdbtk,
 340 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 341   [case $enableval in
 342     yes | no)
 343       ;;
 344     *)
 345       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 346   esac],
 347   [if test -d "$srcdir/gdbtk"; then
 348     enable_gdbtk=yes
 349   else
 350     enable_gdbtk=no
 351   fi])
 352 # We unconditionally disable gdbtk tests on selected platforms.
 353 case $host_os in
 354   go32* | windows*)
 355     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 356     enable_gdbtk=no ;;
 357 esac
 358
 359 # Handle optional debuginfod support
 360 AC_DEBUGINFOD
 361
 362 # Libunwind support for ia64.
 363 AC_ARG_WITH(libunwind-ia64,
 364 AS_HELP_STRING([--with-libunwind-ia64],
 365                [use libunwind frame unwinding for ia64 targets]),,
 366             [with_libunwind_ia64=auto])
 367
 368 # Backward compatibility option.
 369 if test "${with_libunwind+set}" = set; then
 370   if test x"$with_libunwind_ia64" != xauto; then
 371     AC_MSG_ERROR(
 372       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 373   fi
 374   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 375   with_libunwind_ia64="$with_libunwind"
 376 fi
 377
 378 case "$with_libunwind_ia64" in
 379   yes | no)
 380     ;;
 381   auto)
 382     AC_CHECK_HEADERS(libunwind-ia64.h)
 383     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 384     ;;
 385   *)
 386     AC_MSG_ERROR(
 387       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 388     ;;
 389 esac
 390
 391 if test x"$with_libunwind_ia64" = xyes; then
 392   AC_CHECK_HEADERS(libunwind-ia64.h)
 393   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 394     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 395   fi
 396   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 397   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 398   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 399 fi
 400
 401 opt_curses=no
 402 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 403
 404 prefer_curses=no
 405 if test "$opt_curses" = "yes"; then
 406   prefer_curses=yes
 407 fi
 408
 409 # Profiling support.
 410 AC_ARG_ENABLE(profiling,
 411 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 412   [case $enableval in
 413     yes | no)
 414       ;;
 415     *)
 416       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 417   esac],
 418  [enable_profiling=no])
 419
 420 AC_CHECK_FUNCS(monstartup _mcleanup)
 421 AC_CACHE_CHECK(
 422   [for _etext],
 423   [ac_cv_var__etext],
 424   [AC_LINK_IFELSE(
 425      [AC_LANG_PROGRAM(
 426         [#include <stdlib.h>
 427          extern char _etext;],
 428         [free (&_etext);]
 429       )],
 430      [ac_cv_var__etext=yes],
 431      [ac_cv_var__etext=no]
 432    )]
 433 )
 434 if test "$ac_cv_var__etext" = yes; then
 435   AC_DEFINE(HAVE__ETEXT, 1,
 436             [Define to 1 if your system has the _etext variable. ])
 437 fi
 438 AC_CACHE_CHECK(
 439   [for etext],
 440   [ac_cv_var_etext],
 441   [AC_LINK_IFELSE(
 442      [AC_LANG_PROGRAM(
 443         [#include <stdlib.h>
 444          extern char etext;],
 445         [free (&etext);]
 446       )],
 447      [ac_cv_var_etext=yes],
 448      [ac_cv_var_etext=no]
 449    )]
 450 )
 451 if test "$ac_cv_var_etext" = yes; then
 452   AC_DEFINE(HAVE_ETEXT, 1,
 453             [Define to 1 if your system has the etext variable. ])
 454 fi
 455 if test "$enable_profiling" = yes ; then
 456   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 457     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 458   fi
 459   PROFILE_CFLAGS=-pg
 460   OLD_CFLAGS="$CFLAGS"
 461   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 462
 463   AC_CACHE_CHECK(
 464     [whether $CC supports -pg],
 465     [ac_cv_cc_supports_pg],
 466     [AC_COMPILE_IFELSE(
 467        [AC_LANG_PROGRAM([], [int x;])],
 468        [ac_cv_cc_supports_pg=yes],
 469        [ac_cv_cc_supports_pg=no]
 470      )]
 471   )
 472
 473   if test "$ac_cv_cc_supports_pg" = no; then
 474     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 475   fi
 476
 477   CFLAGS="$OLD_CFLAGS"
 478 fi
 479
 480 CODESIGN_CERT=
 481 AC_ARG_ENABLE([codesign],
 482   AS_HELP_STRING([--enable-codesign=CERT],
 483                  [sign gdb with 'codesign -s CERT']),
 484   [CODESIGN_CERT=$enableval])
 485 AC_SUBST([CODESIGN_CERT])
 486
 487 ACX_PKGVERSION([GDB])
 488 ACX_BUGURL([https://www.gnu.org/software/gdb/bugs/])
 489 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 490 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 491
 492 # --------------------- #
 493 # Checks for programs.  #
 494 # --------------------- #
 495
 496 AC_PROG_AWK
 497 AC_PROG_INSTALL
 498 AC_PROG_LN_S
 499 AC_PROG_RANLIB
 500 AC_PROG_YACC
 501
 502 AC_CHECK_TOOL(AR, ar)
 503 AC_CHECK_TOOL(DLLTOOL, dlltool)
 504 AC_CHECK_TOOL(WINDRES, windres)
 505
 506 case $host_os in
 507   gnu*)
 508     # Needed for GNU Hurd hosts.
 509     AC_CHECK_TOOL(MIG, mig)
 510     if test x"$MIG" = x; then
 511       AC_MSG_ERROR([MIG not found but required for $host hosts])
 512     fi
 513     ;;
 514 esac
 515
 516 # ---------------------- #
 517 # Checks for libraries.  #
 518 # ---------------------- #
 519
 520 # We might need to link with -lm; most simulators need it.
 521 AC_CHECK_LIB(m, main)
 522
 523 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 524 AC_SEARCH_LIBS(gethostbyname, nsl)
 525
 526 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 527 AC_SEARCH_LIBS(socketpair, socket)
 528
 529 # Link in zlib if we can.  This allows us to read compressed debug sections.
 530 AM_ZLIB
 531
 532 AM_ICONV
 533
 534 # GDB may fork/exec the iconv program to get the list of supported character
 535 # sets.  Allow the user to specify where to find it.
 536 # There are several factors affecting the choice of option name:
 537 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 538 #   the build-time location of libiconv files.
 539 # - The program we need to find is iconv, which comes with glibc.  The user
 540 #   doesn't necessarily have libiconv installed.  Therefore naming this
 541 #   --with-libiconv-foo feels wrong.
 542 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 543 #   defined to work on directories not files (though it really doesn't know
 544 #   the difference).
 545 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 546 #   with --with-libiconv-prefix.
 547 # Putting these together is why the option name is --with-iconv-bin.
 548
 549 AC_ARG_WITH(iconv-bin,
 550 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 551 [iconv_bin="${withval}"
 552  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 553                     [Path of directory of iconv program.])
 554  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 555 ])
 556
 557 # For the TUI, we need enhanced curses functionality.
 558 if test x"$enable_tui" != xno; then
 559   prefer_curses=yes
 560 fi
 561
 562 curses_found=no
 563 if test x"$prefer_curses" = xyes; then
 564   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 565   # curses library because the latter might not provide all the
 566   # functionality we need.  However, this leads to problems on systems
 567   # where the linker searches /usr/local/lib, but the compiler doesn't
 568   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 569   # default installation of ncurses on alpha*-dec-osf* will lead to such
 570   # a situation.
 571   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 572
 573   if test "$ac_cv_search_waddstr" != no; then
 574     curses_found=yes
 575   fi
 576 fi
 577
 578 # Check whether we should enable the TUI, but only do so if we really
 579 # can.
 580 if test x"$enable_tui" != xno; then
 581   if test -d "$srcdir/tui"; then
 582     if test "$curses_found" != no; then
 583       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 584       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 585       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 586       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 587     else
 588       if test x"$enable_tui" = xyes; then
 589         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 590       else
 591         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 592       fi
 593     fi
 594   fi
 595 fi
 596
 597 # Since GDB uses Readline, we need termcap functionality.  In many
 598 # cases this will be provided by the curses library, but some systems
 599 # have a separate termcap library, or no curses library at all.
 600
 601 case $host_os in
 602   cygwin*)
 603     if test -d "$srcdir/libtermcap"; then
 604       LIBS="../libtermcap/libtermcap.a $LIBS"
 605       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 606     fi ;;
 607   go32* | *djgpp*)
 608     ac_cv_search_tgetent="none required"
 609     ;;
 610 esac
 611
 612 # These are the libraries checked by Readline.
 613 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 614
 615 if test "$ac_cv_search_tgetent" = no; then
 616   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 617 fi
 618
 619 AC_ARG_WITH([system-readline],
 620   [AS_HELP_STRING([--with-system-readline],
 621                   [use installed readline library])])
 622
 623 if test "$with_system_readline" = yes; then
 624   AC_CACHE_CHECK(
 625     [whether system readline is new enough],
 626     [gdb_cv_readline_ok],
 627     [AC_COMPILE_IFELSE(
 628        [AC_LANG_PROGRAM(
 629           [#include <stdio.h>
 630            #include <readline/readline.h>],
 631           [#if RL_VERSION_MAJOR < 7
 632            # error "readline version 7 required"
 633            #endif]
 634         )],
 635        [gdb_cv_readline_ok=yes],
 636        [gdb_cv_readline_ok=no]
 637      )]
 638   )
 639   if test "$gdb_cv_readline_ok" != yes; then
 640     AC_MSG_ERROR([system readline is not new enough])
 641   fi
 642
 643   READLINE=-lreadline
 644   READLINE_DEPS=
 645   READLINE_CFLAGS=
 646   READLINE_TEXI_INCFLAG=
 647 else
 648   READLINE='$(READLINE_DIR)/libreadline.a'
 649   READLINE_DEPS='$(READLINE)'
 650   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 651   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 652 fi
 653 AC_SUBST(READLINE)
 654 AC_SUBST(READLINE_DEPS)
 655 AC_SUBST(READLINE_CFLAGS)
 656 AC_SUBST(READLINE_TEXI_INCFLAG)
 657
 658 # Generate jit-reader.h
 659
 660 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 661 TARGET_PTR=
 662
 663 AC_CHECK_SIZEOF(unsigned long long)
 664 AC_CHECK_SIZEOF(unsigned long)
 665 AC_CHECK_SIZEOF(unsigned __int128)
 666
 667 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 668   TARGET_PTR="unsigned long"
 669 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 670   TARGET_PTR="unsigned long long"
 671 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 672   TARGET_PTR="unsigned __int128"
 673 else
 674   TARGET_PTR="unsigned long"
 675 fi
 676
 677 AC_SUBST(TARGET_PTR)
 678 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 679
 680 AC_SEARCH_LIBS(dlopen, dl)
 681
 682 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 683                 [directory to load the JIT readers from],
 684                 [${libdir}/gdb])
 685
 686 AC_ARG_WITH(expat,
 687   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 688   [], [with_expat=auto])
 689 AC_MSG_CHECKING([whether to use expat])
 690 AC_MSG_RESULT([$with_expat])
 691
 692 if test "${with_expat}" = no; then
 693   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 694   HAVE_LIBEXPAT=no
 695 else
 696   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 697                         [XML_Parser p = XML_ParserCreate (0);])
 698   if test "$HAVE_LIBEXPAT" != yes; then
 699     if test "$with_expat" = yes; then
 700       AC_MSG_ERROR([expat is missing or unusable])
 701     else
 702       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 703     fi
 704   else
 705     save_LIBS=$LIBS
 706     LIBS="$LIBS $LIBEXPAT"
 707     AC_CHECK_FUNCS(XML_StopParser)
 708     LIBS=$save_LIBS
 709   fi
 710 fi
 711
 712 # Verify that we have a usable GMP library.
 713 AC_LIB_HAVE_LINKFLAGS([gmp], [], [#include <gmp.h>],
 714                       [mpz_t n;
 715                        mpz_init (n);])
 716 if test "$HAVE_LIBGMP" != yes; then
 717   AC_MSG_ERROR([GMP is missing or unusable])
 718 fi
 719
 720 AC_ARG_WITH(mpfr,
 721   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 722   [], [with_mpfr=auto])
 723 AC_MSG_CHECKING([whether to use MPFR])
 724 AC_MSG_RESULT([$with_mpfr])
 725
 726 if test "${with_mpfr}" = no; then
 727   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 728   HAVE_LIBMPFR=no
 729 else
 730   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 731                         [mpfr_exp_t exp; mpfr_t x;
 732                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 733   if test "$HAVE_LIBMPFR" != yes; then
 734     if test "$with_mpfr" = yes; then
 735       AC_MSG_ERROR([MPFR is missing or unusable])
 736     else
 737       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 738     fi
 739   fi
 740 fi
 741
 742 # --------------------- #
 743 # Check for libpython.  #
 744 # --------------------- #
 745
 746 dnl Utility to simplify finding libpython.
 747 dnl $1 = the shell variable to assign the result to
 748 dnl      If libpython is found we store $version here.
 749 dnl $2 = additional flags to add to CPPFLAGS
 750 dnl $3 = additional flags to add to LIBS
 751
 752 AC_DEFUN([AC_TRY_LIBPYTHON],
 753 [
 754   define([have_libpython_var],$1)
 755   new_CPPFLAGS=$2
 756   new_LIBS=$3
 757   AC_MSG_CHECKING([for python])
 758   save_CPPFLAGS=$CPPFLAGS
 759   save_LIBS=$LIBS
 760   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 761   LIBS="$new_LIBS $LIBS"
 762   found_usable_python=no
 763   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 764                                  [[Py_Initialize ();]])],
 765                  [have_libpython_var=yes
 766                   found_usable_python=yes
 767                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 768                   PYTHON_LIBS=$new_LIBS])
 769   CPPFLAGS=$save_CPPFLAGS
 770   LIBS=$save_LIBS
 771   AC_MSG_RESULT([${found_usable_python}])
 772 ])
 773
 774 dnl There are several different values for --with-python:
 775 dnl
 776 dnl no -   Don't include python support.
 777 dnl yes -  Include python support, error if it's missing.
 778 dnl        If we find python in $PATH, use it to fetch configure options,
 779 dnl        otherwise assume the compiler can find it with no help from us.
 780 dnl        Python 2.7 and 2.6 are tried in turn.
 781 dnl auto - Same as "yes", but if python is missing from the system,
 782 dnl        fall back to "no".
 783 dnl /path/to/python/exec-prefix -
 784 dnl        Use the python located in this directory.
 785 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 786 dnl        the compilation parameters.  Otherwise use
 787 dnl        -I/path/to/python/exec-prefix/include,
 788 dnl        -L/path/to/python/exec-prefix/lib.
 789 dnl        Python 2.7 and 2.6 are tried in turn.
 790 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 791 dnl        but is deprecated.
 792 dnl /path/to/python/executable -
 793 dnl        Run python-config.py with this version of python to fetch the
 794 dnl        compilation parameters.
 795 dnl        NOTE: This needn't be the real python executable.
 796 dnl        In a cross-compilation scenario (build != host), this could be
 797 dnl        a shell script that provides what python-config.py provides for
 798 dnl        --ldflags, --includes, --exec-prefix.
 799 dnl python-executable -
 800 dnl        Find python-executable in $PATH, and then handle the same as
 801 dnl        /path/to/python/executable.
 802 dnl
 803 dnl If a python program is specified, it is used to run python-config.py and
 804 dnl is passed --ldflags, --includes, --exec-prefix.
 805
 806 AC_ARG_WITH(python,
 807   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 808   [], [with_python=auto])
 809 AC_MSG_CHECKING([whether to use python])
 810 AC_MSG_RESULT([$with_python])
 811
 812 if test "${with_python}" = no; then
 813   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 814   have_libpython=no
 815 else
 816   case "${with_python}" in
 817   [[\\/]]* | ?:[[\\/]]*)
 818     if test -d "${with_python}"; then
 819       # Assume the python binary is ${with_python}/bin/python.
 820       python_prog="${with_python}/bin/python"
 821       python_prefix=
 822       # If python does not exit ${with_python}/bin, then try in
 823       # ${with_python}.  On Windows/MinGW, this is where the Python
 824       # executable is.
 825       if test ! -x "${python_prog}"; then
 826         python_prog="${with_python}/python"
 827         python_prefix=
 828       fi
 829       if test ! -x "${python_prog}"; then
 830         # Fall back to gdb 7.0/7.1 behaviour.
 831         python_prog=missing
 832         python_prefix=${with_python}
 833       fi
 834     elif test -x "${with_python}"; then
 835       # While we can't run python compiled for $host (unless host == build),
 836       # the user could write a script that provides the needed information,
 837       # so we support that.
 838       python_prog=${with_python}
 839       python_prefix=
 840     else
 841       AC_MSG_ERROR(invalid value for --with-python)
 842     fi
 843     ;;
 844   */*)
 845     # Disallow --with-python=foo/bar.
 846     AC_MSG_ERROR(invalid value for --with-python)
 847     ;;
 848   *)
 849     # The user has either specified auto, yes, or the name of the python
 850     # program assumed to be in $PATH.
 851     python_prefix=
 852     case "${with_python}" in
 853     yes | auto)
 854       if test "${build}" = "${host}"; then
 855         AC_PATH_PROG(python_prog_path, python, missing)
 856         if test "${python_prog_path}" = missing; then
 857           python_prog=missing
 858         else
 859           python_prog=${python_prog_path}
 860         fi
 861       else
 862         # Not much we can do except assume the cross-compiler will find the
 863         # right files.
 864         python_prog=missing
 865       fi
 866       ;;
 867     *)
 868       # While we can't run python compiled for $host (unless host == build),
 869       # the user could write a script that provides the needed information,
 870       # so we support that.
 871       python_prog="${with_python}"
 872       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 873       if test "${python_prog_path}" = missing; then
 874         AC_MSG_ERROR(unable to find python program ${python_prog})
 875       fi
 876       ;;
 877     esac
 878   esac
 879
 880   if test "${python_prog}" != missing; then
 881     # We have a python program to use, but it may be too old.
 882     # Don't flag an error for --with-python=auto (the default).
 883     have_python_config=yes
 884     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 885     if test $? != 0; then
 886       have_python_config=failed
 887       if test "${with_python}" != auto; then
 888         AC_MSG_ERROR(failure running python-config --includes)
 889       fi
 890     fi
 891     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 892     if test $? != 0; then
 893       have_python_config=failed
 894       if test "${with_python}" != auto; then
 895         AC_MSG_ERROR(failure running python-config --ldflags)
 896       fi
 897     fi
 898     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 899     if test $? != 0; then
 900       have_python_config=failed
 901       if test "${with_python}" != auto; then
 902         AC_MSG_ERROR(failure running python-config --exec-prefix)
 903       fi
 904     fi
 905   else
 906     # We do not have a python executable we can use to determine where
 907     # to find the Python headers and libs.  We cannot guess the include
 908     # path from the python_prefix either, because that include path
 909     # depends on the Python version.  So, there is nothing much we can
 910     # do except assume that the compiler will be able to find those files.
 911     python_includes=
 912     python_libs=
 913     have_python_config=no
 914   fi
 915
 916   # If we have python-config, only try the configuration it provides.
 917   # Otherwise fallback on the old way of trying different versions of
 918   # python in turn.
 919
 920   have_libpython=no
 921   if test "${have_python_config}" = yes; then
 922     AC_TRY_LIBPYTHON(have_libpython,
 923                      ${python_includes}, ${python_libs})
 924   elif test "${have_python_config}" != failed; then
 925     if test "${have_libpython}" = no; then
 926       AC_TRY_LIBPYTHON(have_libpython,
 927                        ${python_includes}, "-lpython2.7 ${python_libs}")
 928     fi
 929     if test "${have_libpython}" = no; then
 930       AC_TRY_LIBPYTHON(have_libpython,
 931                        ${python_includes}, "-lpython2.6 ${python_libs}")
 932     fi
 933   fi
 934
 935   if test "${have_libpython}" = no; then
 936     case "${with_python}" in
 937     yes)
 938       AC_MSG_ERROR([python is missing or unusable])
 939       ;;
 940     auto)
 941       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 942       ;;
 943     *)
 944       AC_MSG_ERROR([no usable python found at ${with_python}])
 945       ;;
 946     esac
 947   else
 948     if test -n "${python_prefix}"; then
 949       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 950                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 951       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 952     fi
 953   fi
 954 fi
 955
 956 dnl Use --with-python-libdir to control where GDB looks for the Python
 957 dnl libraries.
 958 dnl
 959 dnl If this is not given then the default will be based on the value
 960 dnl passed to --with-python, which is in the python_prefix variable.
 961 dnl If the --with-python option wasn't given then the default value in
 962 dnl python_prefix is based on running the 'gdb/python/python-config
 963 dnl --exec-prefix' script.
 964 AC_ARG_WITH(python-libdir,
 965   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 966   [],[
 967     # If no python libdir is specified then select one based on
 968     # python's prefix path.
 969     if test -n "${python_prefix}"; then
 970       with_python_libdir=${python_prefix}/lib
 971     fi
 972   ])
 973
 974 if test "${have_libpython}" != no; then
 975   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 976   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 977   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 978   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 979   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 980   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 981
 982   if test -n "${with_python_libdir}"; then
 983     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 984                        [Directory containing Python's standard libraries from --with-python-libdir.])
 985     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 986   fi
 987
 988   # Flags needed to compile Python code (taken from python-config --cflags).
 989   # We cannot call python-config directly because it will output whatever was
 990   # used when compiling the Python interpreter itself, including flags which
 991   # would make the python-related objects be compiled differently from the
 992   # rest of GDB (e.g., -O2 and -fPIC).
 993   if test "${GCC}" = yes; then
 994     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 995     # Python headers recommend -DNDEBUG, but it's unclear if that just
 996     # refers to building Python itself.  In release mode, though, it
 997     # doesn't hurt for the Python code in gdb to follow.
 998     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 999   fi
1000
1001   if test "x${tentative_python_cflags}" != x; then
1002     AC_MSG_CHECKING(compiler flags for python code)
1003     for flag in ${tentative_python_cflags}; do
1004       # Check that the compiler accepts it
1005       saved_CFLAGS="$CFLAGS"
1006       CFLAGS="$CFLAGS $flag"
1007       AC_COMPILE_IFELSE(
1008         [AC_LANG_PROGRAM([], [])],
1009         [PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag"],
1010         []
1011       )
1012       CFLAGS="$saved_CFLAGS"
1013     done
1014     AC_MSG_RESULT(${PYTHON_CFLAGS})
1015   fi
1016
1017   # On x64 Windows, Python's include headers, and pyconfig.h in
1018   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
1019   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
1020   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
1021   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
1022   # The issue was reported to the Python community, but still isn't
1023   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
1024
1025   case "$gdb_host" in
1026     mingw64)
1027            if test "${GCC}" = yes; then
1028              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1029            fi
1030            ;;
1031   esac
1032 else
1033   # Even if Python support is not compiled in, we need to have this file
1034   # included so that the "python" command, et.al., still exists.
1035   CONFIG_OBS="$CONFIG_OBS python/python.o"
1036   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1037 fi
1038
1039 # Work around Python http://bugs.python.org/issue10112.  See also
1040 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1041 # no effect.  Note that the only test after this that uses Python is
1042 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1043 # run without -export-dynamic too.
1044 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1045
1046 AC_SUBST(PYTHON_CFLAGS)
1047 AC_SUBST(PYTHON_CPPFLAGS)
1048 AC_SUBST(PYTHON_LIBS)
1049 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1050
1051 # -------------------- #
1052 # Check for libguile.  #
1053 # -------------------- #
1054
1055 dnl Utility to simplify finding libguile.
1056 dnl $1 = pkg-config-program
1057 dnl $2 = space-separate list of guile versions to try
1058 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1059 dnl $4 = the shell variable to assign the result to
1060 dnl      If libguile is found we store "yes" here.
1061
1062 AC_DEFUN([AC_TRY_LIBGUILE],
1063 [
1064   pkg_config=$1
1065   guile_version_list=$2
1066   flag_errors=$3
1067   define([have_libguile_var],$4)
1068   found_usable_guile=checking
1069   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1070   for guile_version in ${guile_version_list}; do
1071     ${pkg_config} --exists ${guile_version} 2>/dev/null
1072     if test $? != 0; then
1073       continue
1074     fi
1075     dnl pkg-config says the package exists, so if we get an error now,
1076     dnl that's bad.
1077     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1078     if test $? != 0; then
1079       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1080     fi
1081     new_LIBS=`${pkg_config} --libs ${guile_version}`
1082     if test $? != 0; then
1083       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1084     fi
1085     dnl If we get this far, great.
1086     found_usable_guile=${guile_version}
1087     break
1088   done
1089   if test "${found_usable_guile}" = "checking"; then
1090     if test "${flag_errors}" = "yes"; then
1091       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1092     else
1093       found_usable_guile=no
1094     fi
1095   fi
1096   dnl One final sanity check.
1097   dnl The user could have said --with-guile=python-2.7.
1098   if test "${found_usable_guile}" != no; then
1099     save_CPPFLAGS=$CPPFLAGS
1100     save_LIBS=$LIBS
1101     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1102     LIBS="$LIBS $new_LIBS"
1103     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1104                                    [[scm_init_guile ();]])],
1105                    [have_libguile_var=yes
1106                     GUILE_CPPFLAGS=$new_CPPFLAGS
1107                     GUILE_LIBS=$new_LIBS],
1108                    [found_usable_guile=no])
1109     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1110     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1111       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1112                 [Define if Guile supports manual finalization.])
1113     )
1114     CPPFLAGS=$save_CPPFLAGS
1115     LIBS=$save_LIBS
1116     if test "${found_usable_guile}" = no; then
1117       if test "${flag_errors}" = yes; then
1118         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1119       fi
1120     fi
1121   fi
1122   AC_MSG_RESULT([${found_usable_guile}])
1123 ])
1124
1125 dnl There are several different values for --with-guile:
1126 dnl
1127 dnl no -   Don't include guile support.
1128 dnl yes -  Include guile support, error if it's missing.
1129 dnl        The pkg-config program must be in $PATH.
1130 dnl auto - Same as "yes", but if guile is missing from the system,
1131 dnl        fall back to "no".
1132 dnl guile-version [guile-version-choice-2 ...] -
1133 dnl        A space-separated list of guile package versions to try.
1134 dnl        These are passed to pkg-config as-is.
1135 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1136 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1137 dnl /path/to/pkg-config -
1138 dnl        Use this pkg-config program.
1139 dnl        NOTE: This needn't be the "real" pkg-config program.
1140 dnl        It could be a shell script.  It is invoked as:
1141 dnl        pkg-config --exists $version
1142 dnl        pkg-config --cflags $version
1143 dnl        pkg-config --libs $version
1144 dnl        pkg-config --variable guild $version
1145 dnl        The script will be called with $version having each value in
1146 dnl        $try_guile_versions until --exists indicates success.
1147
1148 AC_ARG_WITH(guile,
1149   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1150   [], [with_guile=auto])
1151 AC_MSG_CHECKING([whether to use guile])
1152 AC_MSG_RESULT([$with_guile])
1153
1154 dnl We check guile with pkg-config.
1155 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1156
1157 try_guile_versions="guile-3.0 guile-2.2 guile-2.0"
1158 have_libguile=no
1159 case "${with_guile}" in
1160 no)
1161   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1162   ;;
1163 auto)
1164   if test "${pkg_config_prog_path}" = "missing"; then
1165     AC_MSG_WARN([pkg-config not found, guile support disabled])
1166   else
1167     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1168   fi
1169   ;;
1170 yes)
1171   if test "${pkg_config_prog_path}" = "missing"; then
1172     AC_MSG_ERROR([pkg-config not found])
1173   fi
1174   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1175   ;;
1176 [[\\/]]* | ?:[[\\/]]*)
1177   if test -x "${with_guile}"; then
1178     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1179   else
1180     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1181   fi
1182   ;;
1183 "" | */*)
1184   # Disallow --with=guile="" and --with-guile=foo/bar.
1185   AC_MSG_ERROR([invalid value for --with-guile])
1186   ;;
1187 *)
1188   # A space separate list of guile versions to try, in order.
1189   if test "${pkg_config_prog_path}" = "missing"; then
1190     AC_MSG_ERROR([pkg-config not found])
1191   fi
1192   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1193   ;;
1194 esac
1195
1196 if test "${have_libguile}" != no; then
1197   dnl Get the name of the 'guild' program.
1198   case "${with_guile}" in
1199   [[\\/]]* | ?:[[\\/]]*)
1200     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1201     ;;
1202   *)
1203     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1204     ;;
1205   esac
1206
1207   dnl Make sure guild can handle this host.
1208   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1209   dnl If not, disable guile support.
1210   if test "$ac_cv_guild_ok" = no; then
1211     have_libguile=no
1212     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1213   fi
1214 fi
1215
1216 if test "${have_libguile}" != no; then
1217   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1218   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1219   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1220   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1221   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1222   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1223
1224   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1225   save_LIBS="$LIBS"
1226   save_CPPFLAGS="$CPPFLAGS"
1227   LIBS="$GUILE_LIBS"
1228   CPPFLAGS="$GUILE_CPPFLAGS"
1229   AC_CHECK_FUNCS([scm_new_smob])
1230   LIBS="$save_LIBS"
1231   CPPFLAGS="$save_CPPFLAGS"
1232 else
1233   # Even if Guile support is not compiled in, we need to have these files
1234   # included.
1235   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1236   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1237 fi
1238 AC_SUBST(GUILE_CPPFLAGS)
1239 AC_SUBST(GUILE_LIBS)
1240 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1241
1242 # ---------------------------- #
1243 # Check for source highlight.  #
1244 # ---------------------------- #
1245
1246 SRCHIGH_LIBS=
1247 SRCHIGH_CFLAGS=
1248
1249 AC_ARG_ENABLE(source-highlight,
1250   AS_HELP_STRING([--enable-source-highlight],
1251     [enable source-highlight for source listings]),
1252   [case "${enableval}" in
1253   yes)  enable_source_highlight=yes ;;
1254   no)   enable_source_highlight=no  ;;
1255   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1256 esac],
1257 [enable_source_highlight=auto])
1258
1259 if test "${enable_source_highlight}" != "no"; then
1260   AC_MSG_CHECKING([for the source-highlight library])
1261   if test "${pkg_config_prog_path}" = "missing"; then
1262     AC_MSG_RESULT([no - pkg-config not found])
1263     if test "${enable_source_highlight}" = "yes"; then
1264       AC_MSG_ERROR([pkg-config was not found in your system])
1265     fi
1266   else
1267     if ${pkg_config_prog_path} --exists source-highlight; then
1268       case "$LDFLAGS" in
1269         *static-libstdc*)
1270           AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1271 either use --disable-source-highlight or dnl
1272 --without-static-standard-libraries])
1273           ;;
1274       esac
1275
1276       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1277       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1278       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1279                 [Define to 1 if the source-highlight library is available])
1280       AC_MSG_RESULT([yes])
1281     else
1282       AC_MSG_RESULT([no])
1283       if test "${enable_source_highlight}" = "yes"; then
1284         AC_MSG_ERROR([source-highlight was not found in your system])
1285       fi
1286     fi
1287   fi
1288 fi
1289 AC_SUBST(SRCHIGH_LIBS)
1290 AC_SUBST(SRCHIGH_CFLAGS)
1291
1292 # ------------------------- #
1293 # Checks for header files.  #
1294 # ------------------------- #
1295
1296 AC_HEADER_STDC
1297 # elf_hp.h is for HP/UX 64-bit shared library support.
1298 AC_CHECK_HEADERS([nlist.h machine/reg.h \
1299                   thread_db.h \
1300                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1301                   sys/procctl.h sys/resource.h sys/ptrace.h ptrace.h \
1302                   sys/reg.h sys/debugreg.h \
1303                   termios.h elf_hp.h])
1304 AC_CHECK_HEADERS(sys/user.h, [], [],
1305 [#if HAVE_SYS_PARAM_H
1306 # include <sys/param.h>
1307 #endif
1308 ])
1309
1310 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1311 AC_CHECK_HEADERS(term.h, [], [],
1312 [#if HAVE_CURSES_H
1313 # include <curses.h>
1314 #endif
1315 ])
1316
1317 AC_CHECK_HEADERS([sys/socket.h])
1318 AC_CHECK_HEADERS([ws2tcpip.h])
1319
1320 # ------------------------- #
1321 # Checks for declarations.  #
1322 # ------------------------- #
1323
1324 libiberty_INIT
1325
1326 AC_CHECK_DECLS([snprintf])
1327 AM_LC_MESSAGES
1328
1329 # ------------------ #
1330 # Checks for types.  #
1331 # ------------------ #
1332
1333 AC_CHECK_TYPES(socklen_t, [], [],
1334 [#include <sys/types.h>
1335 #if HAVE_SYS_SOCKET_H
1336 # include <sys/socket.h>
1337 #elif HAVE_WS2TCPIP_H
1338 # include <ws2tcpip.h>
1339 #endif
1340 ])
1341
1342 # ------------------------------------- #
1343 # Checks for compiler characteristics.  #
1344 # ------------------------------------- #
1345
1346 AC_C_CONST
1347 AC_C_INLINE
1348 AC_C_BIGENDIAN
1349
1350 # ------------------------------ #
1351 # Checks for library functions.  #
1352 # ------------------------------ #
1353
1354 AC_CHECK_FUNCS([getuid getgid \
1355                 pipe pread pread64 pwrite resize_term \
1356                 getpgid setsid \
1357                 sigaction sigsetmask socketpair \
1358                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1359                 setrlimit getrlimit posix_madvise waitpid \
1360                 use_default_colors])
1361 AM_LANGINFO_CODESET
1362 GDB_AC_COMMON
1363
1364 # Check the return and argument types of ptrace.
1365 GDB_AC_PTRACE
1366
1367 dnl AC_FUNC_SETPGRP does not work when cross compiling
1368 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1369 if test "$cross_compiling" = no; then
1370   AC_FUNC_SETPGRP
1371 else
1372   AC_CACHE_CHECK(
1373     [whether setpgrp takes no argument],
1374     [ac_cv_func_setpgrp_void],
1375     [AC_COMPILE_IFELSE(
1376        [AC_LANG_PROGRAM(
1377           [#include <unistd.h>],
1378           [if (setpgrp(1,1) == -1)
1379              exit (0);
1380            else
1381              exit (1);]
1382         )],
1383        [ac_cv_func_setpgrp_void=no],
1384        [ac_cv_func_setpgrp_void=yes]
1385      )]
1386   )
1387 if test "$ac_cv_func_setpgrp_void" = yes; then
1388   AC_DEFINE(SETPGRP_VOID, 1)
1389 fi
1390 fi
1391
1392 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1393 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1394 [#include <sys/param.h>
1395 #include <sys/proc.h>
1396 ])
1397
1398 # See if <sys/lwp.h> defines `struct lwp`.
1399 AC_CACHE_CHECK(
1400   [for struct lwp],
1401   [gdb_cv_struct_lwp],
1402   [AC_COMPILE_IFELSE(
1403      [AC_LANG_PROGRAM(
1404         [#include <sys/param.h>
1405          #define _KMEMUSER
1406          #include <sys/lwp.h>],
1407         [struct lwp l;]
1408       )],
1409      [gdb_cv_struct_lwp=yes],
1410      [gdb_cv_struct_lwp=no]
1411    )]
1412 )
1413 if test "$gdb_cv_struct_lwp" = yes; then
1414   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1415             [Define to 1 if your system has struct lwp.])
1416 fi
1417
1418 # See if <machine/reg.h> degines `struct reg'.
1419 AC_CACHE_CHECK(
1420   [for struct reg in machine/reg.h],
1421   [gdb_cv_struct_reg],
1422   [AC_COMPILE_IFELSE(
1423      [AC_LANG_PROGRAM(
1424         [#include <sys/types.h>
1425          #include <machine/reg.h>],
1426         [struct reg r;]
1427       )],
1428      [gdb_cv_struct_reg=yes],
1429      [gdb_cv_struct_reg=no]
1430    )]
1431 )
1432 if test "$gdb_cv_struct_reg" = yes; then
1433   AC_DEFINE(HAVE_STRUCT_REG, 1,
1434             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1435 fi
1436
1437 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1438 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1439 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1440                  [#include <sys/types.h>
1441 #include <machine/reg.h>])
1442
1443 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1444 AC_MSG_CHECKING(for PTRACE_GETREGS)
1445 AC_CACHE_VAL(
1446   [gdb_cv_have_ptrace_getregs],
1447   [AC_COMPILE_IFELSE(
1448     [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
1449     [gdb_cv_have_ptrace_getregs=yes],
1450     [gdb_cv_have_ptrace_getregs=no]
1451    )]
1452 )
1453 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1454 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1455   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1456   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1457 fi
1458
1459 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1460 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1461 AC_CACHE_VAL(
1462   [gdb_cv_have_ptrace_getfpxregs],
1463   [AC_COMPILE_IFELSE(
1464      [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
1465      [gdb_cv_have_ptrace_getfpxregs=yes],
1466      [gdb_cv_have_ptrace_getfpxregs=no]
1467    )]
1468 )
1469 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1470 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1471   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1472   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1473 fi
1474
1475 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1476 AC_MSG_CHECKING(for PT_GETDBREGS)
1477 AC_CACHE_VAL(
1478   [gdb_cv_have_pt_getdbregs],
1479   [AC_COMPILE_IFELSE(
1480      [AC_LANG_PROGRAM(
1481         [#include <sys/types.h>
1482          #include <sys/ptrace.h>],
1483         [PT_GETDBREGS;]
1484       )],
1485      [gdb_cv_have_pt_getdbregs=yes],
1486      [gdb_cv_have_pt_getdbregs=no]
1487    )]
1488 )
1489 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1490 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1491   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1492   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1493 fi
1494
1495 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1496 AC_MSG_CHECKING(for PT_GETXMMREGS)
1497 AC_CACHE_VAL(
1498   [gdb_cv_have_pt_getxmmregs],
1499   [AC_COMPILE_IFELSE(
1500      [AC_LANG_PROGRAM(
1501         [#include <sys/types.h>
1502          #include <sys/ptrace.h>],
1503         [PT_GETXMMREGS;]
1504       )],
1505      [gdb_cv_have_pt_getxmmregs=yes],
1506      [gdb_cv_have_pt_getxmmregs=no]
1507    )]
1508 )
1509 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1510 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1511   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1512   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1513 fi
1514
1515 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1516 # Older FreeBSD versions don't have the pl_tdname member of
1517 # `struct ptrace_lwpinfo'.
1518 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1519                  [#include <sys/ptrace.h>])
1520
1521 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1522 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1523 # FreeBSD 10.3.
1524 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1525                  [#include <sys/ptrace.h>])
1526
1527 # Check if the compiler supports the `long long' type.
1528
1529 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1530                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1531 [[extern long long foo;]],
1532 [[switch (foo & 2) { case 0: return 1; }]])],
1533                                   gdb_cv_c_long_long=yes,
1534                                   gdb_cv_c_long_long=no)])
1535 if test "$gdb_cv_c_long_long" != yes; then
1536   # libdecnumber requires long long.
1537   AC_MSG_ERROR([Compiler must support long long for GDB.])
1538 fi
1539
1540 # Check if the compiler and runtime support printing long longs.
1541
1542 AC_CACHE_CHECK([for long long support in printf],
1543                gdb_cv_printf_has_long_long,
1544                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1545 [[char buf[32];
1546   long long l = 0;
1547   l = (l << 16) + 0x0123;
1548   l = (l << 16) + 0x4567;
1549   l = (l << 16) + 0x89ab;
1550   l = (l << 16) + 0xcdef;
1551   sprintf (buf, "0x%016llx", l);
1552   return (strcmp ("0x0123456789abcdef", buf));]])],
1553                               gdb_cv_printf_has_long_long=yes,
1554                               gdb_cv_printf_has_long_long=no,
1555                               gdb_cv_printf_has_long_long=no)])
1556 if test "$gdb_cv_printf_has_long_long" = yes; then
1557   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1558             [Define to 1 if the "%ll" format works to print long longs.])
1559 fi
1560
1561 # Check if the compiler and runtime support printing decfloats.
1562
1563 AC_CACHE_CHECK([for decfloat support in printf],
1564                gdb_cv_printf_has_decfloat,
1565                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1566 [[char buf[64];
1567   _Decimal32 d32 = 1.2345df;
1568   _Decimal64 d64 = 1.2345dd;
1569   _Decimal128 d128 = 1.2345dl;
1570   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1571   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1572                               gdb_cv_printf_has_decfloat=yes,
1573                               gdb_cv_printf_has_decfloat=no,
1574                               gdb_cv_printf_has_decfloat=no)])
1575 if test "$gdb_cv_printf_has_decfloat" = yes; then
1576   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1577             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1578 fi
1579
1580 # Check if the compiler supports the `long double' type.  We can't use
1581 # AC_C_LONG_DOUBLE because that one does additional checks on the
1582 # constants defined in <float.h> that fail on some systems,
1583 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1584
1585 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1586                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1587                                   gdb_cv_c_long_double=yes,
1588                                   gdb_cv_c_long_double=no)])
1589 if test "$gdb_cv_c_long_double" = yes; then
1590   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1591            [Define to 1 if the compiler supports long double.])
1592 fi
1593
1594 # Check if the compiler and runtime support printing long doubles.
1595
1596 AC_CACHE_CHECK([for long double support in printf],
1597                gdb_cv_printf_has_long_double,
1598                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1599 [[char buf[16];
1600   long double f = 3.141592653;
1601   sprintf (buf, "%Lg", f);
1602   return (strncmp ("3.14159", buf, 7));]])],
1603                               gdb_cv_printf_has_long_double=yes,
1604                               gdb_cv_printf_has_long_double=no,
1605                               gdb_cv_printf_has_long_double=no)])
1606 if test "$gdb_cv_printf_has_long_double" = yes; then
1607   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1608             [Define to 1 if the "%Lg" format works to print long doubles.])
1609 fi
1610
1611 # Check if the compiler and runtime support scanning long doubles.
1612
1613 AC_CACHE_CHECK([for long double support in scanf],
1614                gdb_cv_scanf_has_long_double,
1615                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1616 [[#include <stdio.h>]],
1617 [[char *buf = "3.141592653";
1618   long double f = 0;
1619   sscanf (buf, "%Lg", &f);
1620   return !(f > 3.14159 && f < 3.14160);]])],
1621                               gdb_cv_scanf_has_long_double=yes,
1622                               gdb_cv_scanf_has_long_double=no,
1623                               gdb_cv_scanf_has_long_double=no)])
1624 if test "$gdb_cv_scanf_has_long_double" = yes; then
1625   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1626             [Define to 1 if the "%Lg" format works to scan long doubles.])
1627 fi
1628
1629 case ${host_os} in
1630 aix*)
1631   AC_CACHE_CHECK(
1632     [for -bbigtoc option], [gdb_cv_bigtoc],
1633     [SAVE_LDFLAGS=$LDFLAGS
1634
1635      case $GCC in
1636        yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1637        *) gdb_cv_bigtoc=-bbigtoc ;;
1638      esac
1639
1640      LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1641      AC_LINK_IFELSE(
1642        [AC_LANG_PROGRAM([], [int i;])],
1643        [],
1644        [gdb_cv_bigtoc=]
1645      )
1646      LDFLAGS="${SAVE_LDFLAGS}"]
1647   )
1648   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1649   ;;
1650 esac
1651
1652 AC_MSG_CHECKING(for the dynamic export flag)
1653 dynamic_list=false
1654 if test "${gdb_native}" = yes; then
1655    # The dynamically loaded libthread_db needs access to symbols in the gdb
1656    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1657    # may not be supported there.
1658    old_LDFLAGS="$LDFLAGS"
1659    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1660    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1661    LDFLAGS="$LDFLAGS $RDYNAMIC"
1662    if test "${have_libpython}" = no; then
1663      AC_LINK_IFELSE(
1664        [AC_LANG_PROGRAM([], [])],
1665        [dynamic_list=true],
1666        []
1667      )
1668    else
1669      # Workaround http://bugs.python.org/issue4434 where static
1670      # libpythonX.Y.a would get its symbols required for
1671      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1672      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1673
1674      # Note the workaround for Python
1675      # http://bugs.python.org/issue10112 earlier has removed
1676      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1677      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1678      # always pass.
1679      old_CFLAGS="$CFLAGS"
1680      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1681      old_LIBS="$LIBS"
1682      LIBS="$LIBS $PYTHON_LIBS"
1683      old_CPPFLAGS="$CPPFLAGS"
1684      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1685      AC_RUN_IFELSE(
1686        [AC_LANG_PROGRAM(
1687          [#include "Python.h"],
1688          [int err;
1689           Py_Initialize ();
1690           err = PyRun_SimpleString ("import ctypes\n");
1691           Py_Finalize ();
1692           return err == 0 ? 0 : 1;])],
1693        [dynamic_list=true], [], [true])
1694      LIBS="$old_LIBS"
1695      CFLAGS="$old_CFLAGS"
1696      CPPFLAGS="$old_CPPFLAGS"
1697    fi
1698    LDFLAGS="$old_LDFLAGS"
1699 fi
1700 if $dynamic_list; then
1701   found="-Wl,--dynamic-list"
1702   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1703 else
1704   found="-rdynamic"
1705   RDYNAMIC="-rdynamic"
1706 fi
1707 AC_SUBST(RDYNAMIC)
1708 AC_MSG_RESULT($found)
1709
1710 dnl For certain native configurations, we need to check whether thread
1711 dnl support can be built in or not.
1712 dnl
1713 dnl Note that we only want this if we are both native (host == target),
1714 dnl and not doing a canadian cross build (build == host).
1715
1716 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1717    case ${host_os} in
1718    aix*)
1719       AC_MSG_CHECKING(for AiX thread debugging library)
1720       AC_CACHE_VAL(
1721         [gdb_cv_have_aix_thread_debug],
1722         [AC_COMPILE_IFELSE(
1723            [AC_LANG_PROGRAM(
1724               [#include <sys/pthdebug.h>],
1725               [#ifndef PTHDB_VERSION_3
1726                #error
1727                #endif]
1728             )],
1729            [gdb_cv_have_aix_thread_debug=yes],
1730            [gdb_cv_have_aix_thread_debug=no]
1731          )]
1732       )
1733       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1734       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1735          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1736          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1737          LIBS="$LIBS -lpthdebug"
1738
1739          # Older versions of AIX do not provide the declaration for
1740          # the getthrds function (it appears that it was introduced
1741          # with AIX 6.x).
1742          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1743       fi
1744       ;;
1745    esac
1746    AC_SUBST(CONFIG_LDFLAGS)
1747 fi
1748
1749 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1750 dnl other error codes.
1751 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1752   AC_CACHE_CHECK(
1753     [whether <thread_db.h> has TD_NOTALLOC],
1754     [gdb_cv_thread_db_h_has_td_notalloc],
1755     [AC_COMPILE_IFELSE(
1756        [AC_LANG_PROGRAM(
1757           [#include <thread_db.h>],
1758           [int i = TD_NOTALLOC;]
1759         )],
1760        [gdb_cv_thread_db_h_has_td_notalloc=yes],
1761        [gdb_cv_thread_db_h_has_td_notalloc=no]
1762      )]
1763   )
1764
1765   AC_CACHE_CHECK(
1766     [whether <thread_db.h> has TD_VERSION],
1767     [gdb_cv_thread_db_h_has_td_version],
1768     [AC_COMPILE_IFELSE(
1769        [AC_LANG_PROGRAM(
1770           [#include <thread_db.h>],
1771           [int i = TD_VERSION;]
1772         )],
1773        [gdb_cv_thread_db_h_has_td_version=yes],
1774        [gdb_cv_thread_db_h_has_td_version=no]
1775      )]
1776   )
1777
1778   AC_CACHE_CHECK(
1779     [whether <thread_db.h> has TD_NOTLS],
1780     [gdb_cv_thread_db_h_has_td_notls],
1781     [AC_COMPILE_IFELSE(
1782        [AC_LANG_PROGRAM(
1783           [#include <thread_db.h>],
1784           [int i = TD_NOTLS;]
1785         )],
1786        [gdb_cv_thread_db_h_has_td_notls=yes],
1787        [gdb_cv_thread_db_h_has_td_notls=no]
1788      )]
1789   )
1790 fi
1791 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1792   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1793             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1794 fi
1795 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1796   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1797             [Define if <thread_db.h> has the TD_VERSION error code.])
1798 fi
1799 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1800   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1801             [Define if <thread_db.h> has the TD_NOTLS error code.])
1802 fi
1803
1804 dnl Set the host's .gdbinit filename.
1805 case $host_os in
1806   go32* | *djgpp*)
1807     gdbinit=gdb.ini
1808     ;;
1809   *)
1810     gdbinit=.gdbinit
1811     ;;
1812 esac
1813 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1814
1815 dnl Set the host's .gdbearlyinit filename
1816 AC_DEFINE_UNQUOTED(GDBEARLYINIT,".gdbearlyinit",[The .gdbearlyinit filename.])
1817
1818 dnl Handle optional features that can be enabled.
1819
1820 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1821 # except that the argument to --with-sysroot is optional.
1822 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1823 if test "x$with_sysroot" = xyes; then
1824   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1825 fi
1826 AC_ARG_WITH(sysroot,
1827   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1828                  [search for usr/lib et al within DIR]),
1829   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1830 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1831               [search for usr/lib et al within DIR])
1832 AC_SUBST(TARGET_SYSTEM_ROOT)
1833 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1834
1835 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1836     [automatically load a system-wide gdbinit file],
1837     [])
1838 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1839     [automatically load system-wide gdbinit files from this directory],
1840     [])
1841
1842 AM_GDB_WARNINGS
1843 AM_GDB_UBSAN
1844
1845 # In the Cygwin environment, we need some additional flags.
1846 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1847 [AC_EGREP_CPP(^lose$, [
1848 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1849 lose
1850 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1851
1852
1853 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1854 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1855 case ${host} in
1856   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1857   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1858   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1859   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1860 esac
1861 AC_SUBST(SER_HARDWIRE)
1862
1863 # libreadline needs libuser32.a in a cygwin environment
1864 WIN32LIBS=
1865 if test x"$gdb_cv_os_cygwin" = xyes; then
1866     WIN32LIBS="-luser32"
1867     case "${target}" in
1868         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1869         ;;
1870     esac
1871 fi
1872
1873 # The ser-tcp.c module requires sockets.
1874 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1875 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1876
1877 # Add ELF support to GDB, but only if BFD includes ELF support.
1878 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1879                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1880 if test "$gdb_cv_var_elf" = yes; then
1881   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o \
1882                 gcore-elf.o elf-none-tdep.o"
1883   AC_DEFINE(HAVE_ELF, 1,
1884             [Define if ELF support should be included.])
1885   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1886   if test "$plugins" = "yes"; then
1887     AC_SEARCH_LIBS(dlopen, dl)
1888   fi
1889 fi
1890
1891 # Add macho support to GDB, but only if BFD includes it.
1892 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1893                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1894 if test "$gdb_cv_var_macho" = yes; then
1895   CONFIG_OBS="$CONFIG_OBS machoread.o"
1896 fi
1897
1898 # Add any host-specific objects to GDB.
1899 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1900
1901 # If building on ELF, look for lzma support for embedded compressed debug info.
1902 if test "$gdb_cv_var_elf" = yes; then
1903   AC_ARG_WITH(lzma,
1904     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1905     [], [with_lzma=auto])
1906   AC_MSG_CHECKING([whether to use lzma])
1907   AC_MSG_RESULT([$with_lzma])
1908
1909   if test "${with_lzma}" != no; then
1910     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1911                           [lzma_index_iter iter;
1912                            lzma_index_iter_init (&iter, 0);
1913                            lzma_mf_is_supported (LZMA_MF_HC3);])
1914     if test "$HAVE_LIBLZMA" != yes; then
1915       if test "$with_lzma" = yes; then
1916         AC_MSG_ERROR([missing liblzma for --with-lzma])
1917       fi
1918     fi
1919   fi
1920 fi
1921
1922 LIBGUI="../libgui/src/libgui.a"
1923 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1924 AC_SUBST(LIBGUI)
1925 AC_SUBST(GUI_CFLAGS_X)
1926
1927 WIN32LDAPP=
1928 AC_SUBST(WIN32LIBS)
1929 AC_SUBST(WIN32LDAPP)
1930
1931 case "${host}" in
1932 *-*-cygwin* | *-*-mingw* )
1933     configdir="win"
1934     ;;
1935 *)
1936     configdir="unix"
1937     ;;
1938 esac
1939
1940 GDBTKLIBS=
1941 if test "${enable_gdbtk}" = "yes"; then
1942
1943     # Gdbtk must have an absolute path to srcdir in order to run
1944     # properly when not installed.
1945     here=`pwd`
1946     cd ${srcdir}
1947     GDBTK_SRC_DIR=`pwd`
1948     cd $here
1949
1950     SC_PATH_TCLCONFIG
1951
1952     # If $no_tk is nonempty, then we can't do Tk, and there is no
1953     # point to doing Tcl.
1954     SC_PATH_TKCONFIG
1955
1956     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1957         SC_LOAD_TCLCONFIG
1958
1959         # Check for in-tree tcl
1960         here=`pwd`
1961         cd ${srcdir}/..
1962         topdir=`pwd`
1963         cd ${here}
1964
1965         intree="no"
1966         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1967           intree="yes"
1968         fi
1969
1970         # Find Tcl private headers
1971         if test x"${intree}" = xno; then
1972           CY_AC_TCL_PRIVATE_HEADERS
1973           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1974           TCL_LIBRARY="${TCL_LIB_SPEC}"
1975           TCL_DEPS=""
1976         else
1977           # If building tcl in the same src tree, private headers
1978           # are not needed, but we need to be sure to use the right
1979           # headers library
1980           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1981           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1982           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1983         fi
1984         AC_SUBST(TCL_INCLUDE)
1985         AC_SUBST(TCL_LIBRARY)
1986         AC_SUBST(TCL_DEPS)
1987
1988         SC_LOAD_TKCONFIG
1989
1990         # Check for in-tree Tk
1991         intree="no"
1992         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1993           intree="yes"
1994         fi
1995
1996         # Find Tk private headers
1997         if test x"${intree}" = xno; then
1998           CY_AC_TK_PRIVATE_HEADERS
1999           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2000           TK_LIBRARY=${TK_LIB_SPEC}
2001           TK_DEPS=""
2002         else
2003           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2004           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2005           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2006         fi
2007         AC_SUBST(TK_INCLUDE)
2008         AC_SUBST(TK_LIBRARY)
2009         AC_SUBST(TK_DEPS)
2010         AC_SUBST(TK_XINCLUDES)
2011
2012         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2013
2014         # Include some libraries that Tcl and Tk want.
2015         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2016         # Yes, the ordering seems wrong here.  But it isn't.
2017         # TK_LIBS is the list of libraries that need to be linked
2018         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2019         # were in LIBS then any link tests after this point would
2020         # try to include things like `$(LIBGUI)', which wouldn't work.
2021         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2022
2023         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2024         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2025         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2026         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2027         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2028         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2029         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2030
2031         if test x"$gdb_cv_os_cygwin" = xyes; then
2032           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2033           WIN32LDAPP="-Wl,--subsystem,console"
2034           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2035         fi
2036
2037         AC_CONFIG_SUBDIRS(gdbtk)
2038     fi
2039 fi
2040
2041 AC_SUBST(X_CFLAGS)
2042 AC_SUBST(X_LDFLAGS)
2043 AC_SUBST(X_LIBS)
2044 AC_SUBST(GDBTKLIBS)
2045 AC_SUBST(GDBTK_CFLAGS)
2046 AC_SUBST(GDBTK_SRC_DIR)
2047
2048 AC_PATH_X
2049
2050 # Unlike the sim directory, whether a simulator is linked is controlled by
2051 # presence of a gdb_sim definition in the target configure.tgt entry.
2052 # This code just checks for a few cases where we'd like to ignore those
2053 # definitions, even when they're present in the '.mt' file.  These cases
2054 # are when --disable-sim is specified, or if the simulator directory is
2055 # not part of the source tree.
2056 #
2057 AC_ARG_ENABLE(sim,
2058 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2059 [echo "enable_sim = $enable_sim";
2060  echo "enableval = ${enableval}";
2061  case "${enableval}" in
2062   yes) ignore_sim=false ;;
2063   no)  ignore_sim=true ;;
2064   *)   ignore_sim=false ;;
2065  esac],
2066 [ignore_sim=false])
2067
2068 if test ! -d "${srcdir}/../sim"; then
2069   ignore_sim=true
2070 fi
2071
2072 SIM=
2073 SIM_OBS=
2074 if test "${ignore_sim}" = "false"; then
2075   if test x"${gdb_sim}" != x ; then
2076     SIM="${gdb_sim}"
2077     SIM_OBS="remote-sim.o"
2078     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2079
2080     # Some tdep code should only be compiled in when the ppc sim is
2081     # built.  PR sim/13418.
2082     case $target in
2083       powerpc*-*-*)
2084         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2085         ;;
2086     esac
2087   fi
2088 fi
2089 AC_SUBST(SIM)
2090 AC_SUBST(SIM_OBS)
2091
2092 AC_SUBST(ENABLE_CFLAGS)
2093 AC_SUBST(PROFILE_CFLAGS)
2094
2095 AC_SUBST(CONFIG_OBS)
2096 AC_SUBST(CONFIG_DEPS)
2097 AC_SUBST(CONFIG_SRCS)
2098 AC_SUBST(CONFIG_ALL)
2099 AC_SUBST(CONFIG_CLEAN)
2100 AC_SUBST(CONFIG_INSTALL)
2101 AC_SUBST(CONFIG_UNINSTALL)
2102
2103 # List of host floatformats.
2104 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2105 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2106 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2107
2108 # target_subdir is used by the testsuite to find the target libraries.
2109 target_subdir=
2110 if test "${host}" != "${target}"; then
2111     target_subdir="${target_alias}/"
2112 fi
2113 AC_SUBST(target_subdir)
2114
2115 # Import nat definitions.
2116 nat_makefile_frag=/dev/null
2117 if test "${gdb_native}" = "yes"; then
2118   . ${srcdir}/configure.nat
2119   nativefile=$NAT_FILE
2120 fi
2121
2122 AC_SUBST(NAT_FILE)
2123 AC_SUBST(NATDEPFILES)
2124 AC_SUBST(NAT_CDEPS)
2125 AC_SUBST(LOADLIBES)
2126 AC_SUBST(MH_CFLAGS)
2127 AC_SUBST(XM_CLIBS)
2128 AC_SUBST(NAT_GENERATED_FILES)
2129 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2130 AC_SUBST_FILE(nat_makefile_frag)
2131
2132 if test x"${gdb_osabi}" != x ; then
2133     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2134                        [Define to the default OS ABI for this configuration.])
2135 fi
2136
2137 # Check for babeltrace and babeltrace-ctf
2138 AC_ARG_WITH(babeltrace,
2139   AS_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2140   [], [with_babeltrace=auto])
2141 AC_MSG_CHECKING([whether to use babeltrace])
2142 AC_MSG_RESULT([$with_babeltrace])
2143
2144 if test "x$with_babeltrace" = "xno"; then
2145   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2146 else
2147   # Append -Werror to CFLAGS so that configure can catch the warning
2148   # "assignment from incompatible pointer type", which is related to
2149   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2150   # in GDB, while babeltrace 1.0.3 is broken.
2151   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2152   # safe to save and restore CFLAGS here.
2153   saved_CFLAGS=$CFLAGS
2154   CFLAGS="$CFLAGS -Werror"
2155   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2156                         [#include <babeltrace/babeltrace.h>
2157                          #include <babeltrace/ctf/events.h>
2158                          #include <babeltrace/ctf/iterator.h>],
2159                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2160                         struct bt_ctf_event *event = NULL;
2161                         const struct bt_definition *scope;
2162
2163                         pos->type = BT_SEEK_BEGIN;
2164                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2165                         scope = bt_ctf_get_top_level_scope (event,
2166                                                            BT_STREAM_EVENT_HEADER);
2167                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2168                         ])
2169   CFLAGS=$saved_CFLAGS
2170
2171   if test "$HAVE_LIBBABELTRACE" != yes; then
2172      if test "$with_babeltrace" = yes; then
2173        AC_MSG_ERROR([babeltrace is missing or unusable])
2174      else
2175        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2176      fi
2177   fi
2178 fi
2179
2180 # Check for xxhash
2181 AC_ARG_WITH(xxhash,
2182   AS_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2183   [], [with_xxhash=auto])
2184
2185 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
2186 if test x${enable_static} = xno; then
2187   LIBCTF="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
2188   CTF_DEPS="../libctf/.libs/libctf.so"
2189 else
2190   LIBCTF="../libctf/.libs/libctf.a"
2191   CTF_DEPS="$LIBCTF"
2192 fi
2193 if test "${enable_libctf}" = yes; then
2194   AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
2195 else
2196   LIBCTF=
2197   CTF_DEPS=
2198 fi
2199 AC_SUBST(enable_libctf)
2200 AC_SUBST(LIBCTF)
2201 AC_SUBST(CTF_DEPS)
2202
2203 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2204 # empty version.
2205
2206 if test "x$with_xxhash" != "xno"; then
2207   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2208                         [#include <xxhash.h>],
2209                         [XXH32("foo", 3, 0);
2210                         ])
2211   if test "$HAVE_LIBXXHASH" != yes; then
2212     if test "$with_xxhash" = yes; then
2213       AC_MSG_ERROR([xxhash is missing or unusable])
2214     fi
2215   fi
2216   if test "x$with_xxhash" = "xauto"; then
2217     with_xxhash="$HAVE_LIBXXHASH"
2218   fi
2219 fi
2220
2221 AC_MSG_CHECKING([whether to use xxhash])
2222 AC_MSG_RESULT([$with_xxhash])
2223
2224 NM_H=
2225 rm -f nm.h
2226 if test "${nativefile}" != ""; then
2227     case "${nativefile}" in
2228       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2229       * ) GDB_NM_FILE="${nativefile}"
2230     esac
2231     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2232                     [GDB_NM_FILE=$GDB_NM_FILE])
2233     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2234     NM_H=nm.h
2235 fi
2236 AC_SUBST(GDB_NM_FILE)
2237 AC_SUBST(NM_H)
2238
2239 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2240 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2241 if test "x$USE_MAINTAINER_MODE" = xyes; then
2242   if test "${XSLTPROC}" = missing; then
2243     AC_MSG_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2244   fi
2245 fi
2246 AC_SUBST(XSLTPROC)
2247
2248 dnl Check for exe extension set on certain hosts (e.g. Win32)
2249 AC_EXEEXT
2250
2251 dnl  Detect the character set used by this host.
2252 dnl  At the moment, we just assume it's UTF-8.
2253 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2254           [Define to be a string naming the default host character set.])
2255
2256 GDB_AC_SELFTEST([
2257   CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)"
2258   CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)"
2259 ])
2260
2261 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2262 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2263 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2264 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2265 # Transform the name of some programs for the testsuite/lib/pdtrace
2266 # test tool.
2267 GDB_AC_TRANSFORM(strip, STRIP_TRANSFORM_NAME)
2268 GDB_AC_TRANSFORM(readelf, READELF_TRANSFORM_NAME)
2269 GDB_AC_TRANSFORM(as, GAS_TRANSFORM_NAME)
2270 GDB_AC_TRANSFORM(nm, NM_TRANSFORM_NAME)
2271 AC_CONFIG_FILES([testsuite/lib/pdtrace], [chmod +x testsuite/lib/pdtrace])
2272 AC_CONFIG_FILES([testsuite/Makefile])
2273
2274 AC_OUTPUT