gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 m4_include(../config/debuginfod.m4)
  22
  23 AC_INIT
  24 AC_CONFIG_SRCDIR([main.c])
  25 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  26 AM_MAINTAINER_MODE
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_INSTALL_STRIP
  34
  35 AC_CONFIG_AUX_DIR(..)
  36
  37 # Set build, build_cpu, build_vendor and build_os.
  38 AC_CANONICAL_BUILD
  39
  40 # Set host, host_cpu, host_vendor, and host_os.
  41 AC_CANONICAL_HOST
  42
  43 # Set target, target_cpu, target_vendor, and target_os.
  44 AC_CANONICAL_TARGET
  45
  46 AC_ARG_PROGRAM
  47
  48 # We require a C++11 compiler.  Check if one is available, and if
  49 # necessary, set CXX_DIALECT to some -std=xxx switch.
  50 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  51
  52 # Dependency checking.
  53 ZW_CREATE_DEPDIR
  54 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  55
  56 dnl List of object files and targets accumulated by configure.
  57
  58 CONFIG_OBS=
  59 CONFIG_DEPS=
  60 CONFIG_SRCS=
  61 ENABLE_CFLAGS=
  62
  63 CONFIG_ALL=
  64 CONFIG_CLEAN=
  65 CONFIG_INSTALL=
  66 CONFIG_UNINSTALL=
  67
  68 dnl Set up for gettext.
  69 ZW_GNU_GETTEXT_SISTER_DIR
  70
  71 localedir='${datadir}/locale'
  72 AC_SUBST(localedir)
  73
  74 if test x"$USE_NLS" = xyes; then
  75    CONFIG_ALL="$CONFIG_ALL all-po"
  76    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  77    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  78    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  79 fi
  80
  81 PACKAGE=gdb
  82 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  83 AC_SUBST(PACKAGE)
  84
  85 # We never need to detect it in this sub-configure.
  86 # But preserve it for config.status --recheck.
  87 AC_ARG_VAR(MAKEINFO,
  88   [Parent configure detects if it is of sufficient version.])
  89 AC_ARG_VAR(MAKEINFOFLAGS,
  90   [Parameters for MAKEINFO.])
  91
  92 MAKEINFO_EXTRA_FLAGS=""
  93 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  94   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  95   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  96     gdb_cv_have_makeinfo_click=yes
  97   else
  98     gdb_cv_have_makeinfo_click=no
  99   fi])
 100 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
 101   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
 102 fi
 103 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
 104
 105 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 106     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 107     [${libdir}/debug])
 108
 109 # We can't pass paths as command line arguments.
 110 # Mingw32 tries to be clever and will convert the paths for us.
 111 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 112 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 113 # This breaks GDB's relocatable path conversions since paths passed in
 114 # config.h would not get so translated, the path prefixes no longer match.
 115 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 116
 117 # GDB's datadir relocation
 118
 119 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 120     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 121     [${datadir}/gdb])
 122
 123 AC_ARG_WITH(relocated-sources,
 124 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 125 [reloc_srcdir="${withval}"
 126  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 127               [Relocated directory for source files. ])
 128 ])
 129
 130 AC_MSG_CHECKING([for default auto-load directory])
 131 AC_ARG_WITH(auto-load-dir,
 132 AS_HELP_STRING([--with-auto-load-dir=PATH],
 133   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 134   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 135 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 136 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 137               [Directories from which to load auto-loaded scripts.])
 138 AC_MSG_RESULT([$with_auto_load_dir])
 139
 140 AC_MSG_CHECKING([for default auto-load safe-path])
 141 AC_ARG_WITH(auto-load-safe-path,
 142 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 143   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 144 AS_HELP_STRING([--without-auto-load-safe-path],
 145                [do not restrict auto-loaded files locations]),
 146     [if test "$with_auto_load_safe_path" = "no"; then
 147      with_auto_load_safe_path="/"
 148      fi],
 149 [with_auto_load_safe_path="$with_auto_load_dir"])
 150 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 151 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 152               [Directories safe to hold auto-loaded files.])
 153 AC_MSG_RESULT([$with_auto_load_safe_path])
 154
 155 AC_CONFIG_SUBDIRS(testsuite)
 156
 157 # Check whether to support alternative target configurations
 158 AC_ARG_ENABLE(targets,
 159 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 160 [case "${enableval}" in
 161   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
 162             ;;
 163   no)       enable_targets= ;;
 164   *)        enable_targets=$enableval ;;
 165 esac])
 166
 167 # Check whether to enable 64-bit support on 32-bit hosts
 168 AC_ARG_ENABLE(64-bit-bfd,
 169 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 170 [case "${enableval}" in
 171   yes)  want64=true  ;;
 172   no)   want64=false ;;
 173   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 174 esac],[want64=false])dnl
 175
 176 # Provide defaults for some variables set by the per-host and per-target
 177 # configuration.
 178 gdb_host_obs=posix-hdep.o
 179
 180 if test "${target}" = "${host}"; then
 181   gdb_native=yes
 182 else
 183   gdb_native=no
 184 fi
 185
 186 . $srcdir/configure.host
 187
 188 # Accumulate some settings from configure.tgt over all enabled targets
 189
 190 TARGET_OBS=
 191 all_targets=
 192 HAVE_NATIVE_GCORE_TARGET=
 193
 194 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 195 do
 196   if test "$targ_alias" = "all"; then
 197     all_targets=true
 198   else
 199     # Canonicalize the secondary target names.
 200     result=`$ac_config_sub $targ_alias 2>/dev/null`
 201     if test -n "$result"; then
 202         targ=$result
 203     else
 204         targ=$targ_alias
 205     fi
 206
 207     . ${srcdir}/configure.tgt
 208
 209     AS_IF([test -z "${gdb_target_obs}"],
 210       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 211
 212     # Target-specific object files
 213     for i in ${gdb_target_obs}; do
 214         case " $TARGET_OBS " in
 215         *" ${i} "*) ;;
 216         *)
 217           TARGET_OBS="$TARGET_OBS ${i}"
 218           ;;
 219         esac
 220     done
 221
 222     # Check whether this target needs 64-bit CORE_ADDR
 223     if test x${want64} = xfalse; then
 224       . ${srcdir}/../bfd/config.bfd
 225     fi
 226
 227     # Check whether this target is native and supports gcore.
 228     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 229        && $gdb_have_gcore; then
 230       HAVE_NATIVE_GCORE_TARGET=1
 231     fi
 232   fi
 233 done
 234
 235 if test x${all_targets} = xtrue; then
 236
 237   # We want all 64-bit targets if we either:
 238   #  - run on a 64-bit host  or
 239   #  - already require 64-bit support for some other target  or
 240   #  - the --enable-64-bit-bfd option was supplied
 241   # Otherwise we only support all 32-bit targets.
 242   #
 243   # NOTE: This test must be in sync with the corresponding
 244   #       tests in BFD!
 245
 246   if test x${want64} = xfalse; then
 247     AC_CHECK_SIZEOF(long)
 248     if test "x${ac_cv_sizeof_long}" = "x8"; then
 249       want64=true
 250     fi
 251   fi
 252   if test x${want64} = xtrue; then
 253     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 254   else
 255     TARGET_OBS='$(ALL_TARGET_OBS)'
 256   fi
 257 fi
 258
 259 AC_SUBST(TARGET_OBS)
 260 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 261
 262 # For other settings, only the main target counts.
 263 gdb_sim=
 264 gdb_osabi=
 265 targ=$target; . ${srcdir}/configure.tgt
 266
 267 # Fetch the default architecture and default target vector from BFD.
 268 targ=$target; . $srcdir/../bfd/config.bfd
 269
 270 # We only want the first architecture, so strip off the others if
 271 # there is more than one.
 272 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 273
 274 if test "x$targ_archs" != x; then
 275   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 276     [Define to BFD's default architecture. ])
 277 fi
 278 if test "x$targ_defvec" != x; then
 279   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 280     [Define to BFD's default target vector. ])
 281 fi
 282
 283 # Enable MI.
 284 AC_ARG_ENABLE(gdbmi,
 285 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 286   [case $enableval in
 287     yes | no)
 288       ;;
 289     *)
 290       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 291   esac],
 292   [enable_gdbmi=yes])
 293 if test x"$enable_gdbmi" = xyes; then
 294   if test -d "$srcdir/mi"; then
 295     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 296     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 297     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 298     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 299   fi
 300 fi
 301
 302 # Enable TUI.
 303 AC_ARG_ENABLE(tui,
 304 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 305   [case $enableval in
 306     yes | no | auto)
 307       ;;
 308     *)
 309       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 310   esac],enable_tui=auto)
 311
 312 # Enable gdbtk.
 313 AC_ARG_ENABLE(gdbtk,
 314 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 315   [case $enableval in
 316     yes | no)
 317       ;;
 318     *)
 319       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 320   esac],
 321   [if test -d "$srcdir/gdbtk"; then
 322     enable_gdbtk=yes
 323   else
 324     enable_gdbtk=no
 325   fi])
 326 # We unconditionally disable gdbtk tests on selected platforms.
 327 case $host_os in
 328   go32* | windows*)
 329     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 330     enable_gdbtk=no ;;
 331 esac
 332
 333 # Handle optional debuginfod support
 334 AC_DEBUGINFOD
 335
 336 # Libunwind support for ia64.
 337 AC_ARG_WITH(libunwind-ia64,
 338 AS_HELP_STRING([--with-libunwind-ia64],
 339                [use libunwind frame unwinding for ia64 targets]),,
 340             [with_libunwind_ia64=auto])
 341
 342 # Backward compatibility option.
 343 if test "${with_libunwind+set}" = set; then
 344   if test x"$with_libunwind_ia64" != xauto; then
 345     AC_MSG_ERROR(
 346       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 347   fi
 348   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 349   with_libunwind_ia64="$with_libunwind"
 350 fi
 351
 352 case "$with_libunwind_ia64" in
 353   yes | no)
 354     ;;
 355   auto)
 356     AC_CHECK_HEADERS(libunwind-ia64.h)
 357     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 358     ;;
 359   *)
 360     AC_MSG_ERROR(
 361       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 362     ;;
 363 esac
 364
 365 if test x"$with_libunwind_ia64" = xyes; then
 366   AC_CHECK_HEADERS(libunwind-ia64.h)
 367   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 368     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 369   fi
 370   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 371   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 372   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 373 fi
 374
 375 opt_curses=no
 376 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 377
 378 prefer_curses=no
 379 if test "$opt_curses" = "yes"; then
 380   prefer_curses=yes
 381 fi
 382
 383 # Profiling support.
 384 AC_ARG_ENABLE(profiling,
 385 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 386   [case $enableval in
 387     yes | no)
 388       ;;
 389     *)
 390       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 391   esac],
 392  [enable_profiling=no])
 393
 394 AC_CHECK_FUNCS(monstartup _mcleanup)
 395 AC_CACHE_CHECK(
 396   [for _etext],
 397   [ac_cv_var__etext],
 398   [AC_LINK_IFELSE(
 399      [AC_LANG_PROGRAM(
 400         [#include <stdlib.h>
 401          extern char _etext;],
 402         [free (&_etext);]
 403       )],
 404      [ac_cv_var__etext=yes],
 405      [ac_cv_var__etext=no]
 406    )]
 407 )
 408 if test "$ac_cv_var__etext" = yes; then
 409   AC_DEFINE(HAVE__ETEXT, 1,
 410             [Define to 1 if your system has the _etext variable. ])
 411 fi
 412 AC_CACHE_CHECK(
 413   [for etext],
 414   [ac_cv_var_etext],
 415   [AC_LINK_IFELSE(
 416      [AC_LANG_PROGRAM(
 417         [#include <stdlib.h>
 418          extern char etext;],
 419         [free (&etext);]
 420       )],
 421      [ac_cv_var_etext=yes],
 422      [ac_cv_var_etext=no]
 423    )]
 424 )
 425 if test "$ac_cv_var_etext" = yes; then
 426   AC_DEFINE(HAVE_ETEXT, 1,
 427             [Define to 1 if your system has the etext variable. ])
 428 fi
 429 if test "$enable_profiling" = yes ; then
 430   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 431     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 432   fi
 433   PROFILE_CFLAGS=-pg
 434   OLD_CFLAGS="$CFLAGS"
 435   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 436
 437   AC_CACHE_CHECK(
 438     [whether $CC supports -pg],
 439     [ac_cv_cc_supports_pg],
 440     [AC_COMPILE_IFELSE(
 441        [AC_LANG_PROGRAM([], [int x;])],
 442        [ac_cv_cc_supports_pg=yes],
 443        [ac_cv_cc_supports_pg=no]
 444      )]
 445   )
 446
 447   if test "$ac_cv_cc_supports_pg" = no; then
 448     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 449   fi
 450
 451   CFLAGS="$OLD_CFLAGS"
 452 fi
 453
 454 CODESIGN_CERT=
 455 AC_ARG_ENABLE([codesign],
 456   AS_HELP_STRING([--enable-codesign=CERT],
 457                  [sign gdb with 'codesign -s CERT']),
 458   [CODESIGN_CERT=$enableval])
 459 AC_SUBST([CODESIGN_CERT])
 460
 461 ACX_PKGVERSION([GDB])
 462 ACX_BUGURL([https://www.gnu.org/software/gdb/bugs/])
 463 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 464 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 465
 466 # --------------------- #
 467 # Checks for programs.  #
 468 # --------------------- #
 469
 470 AC_PROG_AWK
 471 AC_PROG_INSTALL
 472 AC_PROG_LN_S
 473 AC_PROG_RANLIB
 474 AC_PROG_YACC
 475
 476 AC_CHECK_TOOL(AR, ar)
 477 AC_CHECK_TOOL(DLLTOOL, dlltool)
 478 AC_CHECK_TOOL(WINDRES, windres)
 479
 480 case $host_os in
 481   gnu*)
 482     # Needed for GNU Hurd hosts.
 483     AC_CHECK_TOOL(MIG, mig)
 484     if test x"$MIG" = x; then
 485       AC_MSG_ERROR([MIG not found but required for $host hosts])
 486     fi
 487     ;;
 488 esac
 489
 490 # ---------------------- #
 491 # Checks for libraries.  #
 492 # ---------------------- #
 493
 494 # We might need to link with -lm; most simulators need it.
 495 AC_CHECK_LIB(m, main)
 496
 497 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 498 AC_SEARCH_LIBS(gethostbyname, nsl)
 499
 500 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 501 AC_SEARCH_LIBS(socketpair, socket)
 502
 503 # Link in zlib if we can.  This allows us to read compressed debug sections.
 504 AM_ZLIB
 505
 506 AM_ICONV
 507
 508 # GDB may fork/exec the iconv program to get the list of supported character
 509 # sets.  Allow the user to specify where to find it.
 510 # There are several factors affecting the choice of option name:
 511 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 512 #   the build-time location of libiconv files.
 513 # - The program we need to find is iconv, which comes with glibc.  The user
 514 #   doesn't necessarily have libiconv installed.  Therefore naming this
 515 #   --with-libiconv-foo feels wrong.
 516 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 517 #   defined to work on directories not files (though it really doesn't know
 518 #   the difference).
 519 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 520 #   with --with-libiconv-prefix.
 521 # Putting these together is why the option name is --with-iconv-bin.
 522
 523 AC_ARG_WITH(iconv-bin,
 524 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 525 [iconv_bin="${withval}"
 526  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 527                     [Path of directory of iconv program.])
 528  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 529 ])
 530
 531 # For the TUI, we need enhanced curses functionality.
 532 if test x"$enable_tui" != xno; then
 533   prefer_curses=yes
 534 fi
 535
 536 curses_found=no
 537 if test x"$prefer_curses" = xyes; then
 538   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 539   # curses library because the latter might not provide all the
 540   # functionality we need.  However, this leads to problems on systems
 541   # where the linker searches /usr/local/lib, but the compiler doesn't
 542   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 543   # default installation of ncurses on alpha*-dec-osf* will lead to such
 544   # a situation.
 545   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 546
 547   if test "$ac_cv_search_waddstr" != no; then
 548     curses_found=yes
 549   fi
 550 fi
 551
 552 # Check whether we should enable the TUI, but only do so if we really
 553 # can.
 554 if test x"$enable_tui" != xno; then
 555   if test -d "$srcdir/tui"; then
 556     if test "$curses_found" != no; then
 557       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 558       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 559       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 560       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 561     else
 562       if test x"$enable_tui" = xyes; then
 563         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 564       else
 565         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 566       fi
 567     fi
 568   fi
 569 fi
 570
 571 # Since GDB uses Readline, we need termcap functionality.  In many
 572 # cases this will be provided by the curses library, but some systems
 573 # have a separate termcap library, or no curses library at all.
 574
 575 case $host_os in
 576   cygwin*)
 577     if test -d "$srcdir/libtermcap"; then
 578       LIBS="../libtermcap/libtermcap.a $LIBS"
 579       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 580     fi ;;
 581   go32* | *djgpp*)
 582     ac_cv_search_tgetent="none required"
 583     ;;
 584 esac
 585
 586 # These are the libraries checked by Readline.
 587 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 588
 589 if test "$ac_cv_search_tgetent" = no; then
 590   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 591 fi
 592
 593 AC_ARG_WITH([system-readline],
 594   [AS_HELP_STRING([--with-system-readline],
 595                   [use installed readline library])])
 596
 597 if test "$with_system_readline" = yes; then
 598   AC_CACHE_CHECK(
 599     [whether system readline is new enough],
 600     [gdb_cv_readline_ok],
 601     [AC_COMPILE_IFELSE(
 602        [AC_LANG_PROGRAM(
 603           [#include <stdio.h>
 604            #include <readline/readline.h>],
 605           [#if RL_VERSION_MAJOR < 7
 606            # error "readline version 7 required"
 607            #endif]
 608         )],
 609        [gdb_cv_readline_ok=yes],
 610        [gdb_cv_readline_ok=no]
 611      )]
 612   )
 613   if test "$gdb_cv_readline_ok" != yes; then
 614     AC_MSG_ERROR([system readline is not new enough])
 615   fi
 616
 617   READLINE=-lreadline
 618   READLINE_DEPS=
 619   READLINE_CFLAGS=
 620   READLINE_TEXI_INCFLAG=
 621 else
 622   READLINE='$(READLINE_DIR)/libreadline.a'
 623   READLINE_DEPS='$(READLINE)'
 624   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 625   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 626 fi
 627 AC_SUBST(READLINE)
 628 AC_SUBST(READLINE_DEPS)
 629 AC_SUBST(READLINE_CFLAGS)
 630 AC_SUBST(READLINE_TEXI_INCFLAG)
 631
 632 # Generate jit-reader.h
 633
 634 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 635 TARGET_PTR=
 636
 637 AC_CHECK_SIZEOF(unsigned long long)
 638 AC_CHECK_SIZEOF(unsigned long)
 639 AC_CHECK_SIZEOF(unsigned __int128)
 640
 641 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 642   TARGET_PTR="unsigned long"
 643 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 644   TARGET_PTR="unsigned long long"
 645 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 646   TARGET_PTR="unsigned __int128"
 647 else
 648   TARGET_PTR="unsigned long"
 649 fi
 650
 651 AC_SUBST(TARGET_PTR)
 652 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 653
 654 AC_SEARCH_LIBS(dlopen, dl)
 655
 656 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 657                 [directory to load the JIT readers from],
 658                 [${libdir}/gdb])
 659
 660 AC_ARG_WITH(expat,
 661   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 662   [], [with_expat=auto])
 663 AC_MSG_CHECKING([whether to use expat])
 664 AC_MSG_RESULT([$with_expat])
 665
 666 if test "${with_expat}" = no; then
 667   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 668   HAVE_LIBEXPAT=no
 669 else
 670   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 671                         [XML_Parser p = XML_ParserCreate (0);])
 672   if test "$HAVE_LIBEXPAT" != yes; then
 673     if test "$with_expat" = yes; then
 674       AC_MSG_ERROR([expat is missing or unusable])
 675     else
 676       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 677     fi
 678   else
 679     save_LIBS=$LIBS
 680     LIBS="$LIBS $LIBEXPAT"
 681     AC_CHECK_FUNCS(XML_StopParser)
 682     LIBS=$save_LIBS
 683   fi
 684 fi
 685
 686 # Verify that we have a usable GMP library.
 687 AC_LIB_HAVE_LINKFLAGS([gmp], [], [#include <gmp.h>],
 688                       [mpz_t n;
 689                        mpz_init (n);])
 690 if test "$HAVE_LIBGMP" != yes; then
 691   AC_MSG_ERROR([GMP is missing or unusable])
 692 fi
 693
 694 AC_ARG_WITH(mpfr,
 695   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 696   [], [with_mpfr=auto])
 697 AC_MSG_CHECKING([whether to use MPFR])
 698 AC_MSG_RESULT([$with_mpfr])
 699
 700 if test "${with_mpfr}" = no; then
 701   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 702   HAVE_LIBMPFR=no
 703 else
 704   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 705                         [mpfr_exp_t exp; mpfr_t x;
 706                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 707   if test "$HAVE_LIBMPFR" != yes; then
 708     if test "$with_mpfr" = yes; then
 709       AC_MSG_ERROR([MPFR is missing or unusable])
 710     else
 711       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 712     fi
 713   fi
 714 fi
 715
 716 # --------------------- #
 717 # Check for libpython.  #
 718 # --------------------- #
 719
 720 dnl Utility to simplify finding libpython.
 721 dnl $1 = the shell variable to assign the result to
 722 dnl      If libpython is found we store $version here.
 723 dnl $2 = additional flags to add to CPPFLAGS
 724 dnl $3 = additional flags to add to LIBS
 725
 726 AC_DEFUN([AC_TRY_LIBPYTHON],
 727 [
 728   define([have_libpython_var],$1)
 729   new_CPPFLAGS=$2
 730   new_LIBS=$3
 731   AC_MSG_CHECKING([for python])
 732   save_CPPFLAGS=$CPPFLAGS
 733   save_LIBS=$LIBS
 734   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 735   LIBS="$new_LIBS $LIBS"
 736   found_usable_python=no
 737   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 738                                  [[Py_Initialize ();]])],
 739                  [have_libpython_var=yes
 740                   found_usable_python=yes
 741                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 742                   PYTHON_LIBS=$new_LIBS])
 743   CPPFLAGS=$save_CPPFLAGS
 744   LIBS=$save_LIBS
 745   AC_MSG_RESULT([${found_usable_python}])
 746 ])
 747
 748 dnl There are several different values for --with-python:
 749 dnl
 750 dnl no -   Don't include python support.
 751 dnl yes -  Include python support, error if it's missing.
 752 dnl        If we find python in $PATH, use it to fetch configure options,
 753 dnl        otherwise assume the compiler can find it with no help from us.
 754 dnl        Python 2.7 and 2.6 are tried in turn.
 755 dnl auto - Same as "yes", but if python is missing from the system,
 756 dnl        fall back to "no".
 757 dnl /path/to/python/exec-prefix -
 758 dnl        Use the python located in this directory.
 759 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 760 dnl        the compilation parameters.  Otherwise use
 761 dnl        -I/path/to/python/exec-prefix/include,
 762 dnl        -L/path/to/python/exec-prefix/lib.
 763 dnl        Python 2.7 and 2.6 are tried in turn.
 764 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 765 dnl        but is deprecated.
 766 dnl /path/to/python/executable -
 767 dnl        Run python-config.py with this version of python to fetch the
 768 dnl        compilation parameters.
 769 dnl        NOTE: This needn't be the real python executable.
 770 dnl        In a cross-compilation scenario (build != host), this could be
 771 dnl        a shell script that provides what python-config.py provides for
 772 dnl        --ldflags, --includes, --exec-prefix.
 773 dnl python-executable -
 774 dnl        Find python-executable in $PATH, and then handle the same as
 775 dnl        /path/to/python/executable.
 776 dnl
 777 dnl If a python program is specified, it is used to run python-config.py and
 778 dnl is passed --ldflags, --includes, --exec-prefix.
 779
 780 AC_ARG_WITH(python,
 781   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 782   [], [with_python=auto])
 783 AC_MSG_CHECKING([whether to use python])
 784 AC_MSG_RESULT([$with_python])
 785
 786 if test "${with_python}" = no; then
 787   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 788   have_libpython=no
 789 else
 790   case "${with_python}" in
 791   [[\\/]]* | ?:[[\\/]]*)
 792     if test -d "${with_python}"; then
 793       # Assume the python binary is ${with_python}/bin/python.
 794       python_prog="${with_python}/bin/python"
 795       python_prefix=
 796       # If python does not exit ${with_python}/bin, then try in
 797       # ${with_python}.  On Windows/MinGW, this is where the Python
 798       # executable is.
 799       if test ! -x "${python_prog}"; then
 800         python_prog="${with_python}/python"
 801         python_prefix=
 802       fi
 803       if test ! -x "${python_prog}"; then
 804         # Fall back to gdb 7.0/7.1 behaviour.
 805         python_prog=missing
 806         python_prefix=${with_python}
 807       fi
 808     elif test -x "${with_python}"; then
 809       # While we can't run python compiled for $host (unless host == build),
 810       # the user could write a script that provides the needed information,
 811       # so we support that.
 812       python_prog=${with_python}
 813       python_prefix=
 814     else
 815       AC_MSG_ERROR(invalid value for --with-python)
 816     fi
 817     ;;
 818   */*)
 819     # Disallow --with-python=foo/bar.
 820     AC_MSG_ERROR(invalid value for --with-python)
 821     ;;
 822   *)
 823     # The user has either specified auto, yes, or the name of the python
 824     # program assumed to be in $PATH.
 825     python_prefix=
 826     case "${with_python}" in
 827     yes | auto)
 828       if test "${build}" = "${host}"; then
 829         AC_PATH_PROG(python_prog_path, python, missing)
 830         if test "${python_prog_path}" = missing; then
 831           python_prog=missing
 832         else
 833           python_prog=${python_prog_path}
 834         fi
 835       else
 836         # Not much we can do except assume the cross-compiler will find the
 837         # right files.
 838         python_prog=missing
 839       fi
 840       ;;
 841     *)
 842       # While we can't run python compiled for $host (unless host == build),
 843       # the user could write a script that provides the needed information,
 844       # so we support that.
 845       python_prog="${with_python}"
 846       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 847       if test "${python_prog_path}" = missing; then
 848         AC_MSG_ERROR(unable to find python program ${python_prog})
 849       fi
 850       ;;
 851     esac
 852   esac
 853
 854   if test "${python_prog}" != missing; then
 855     # We have a python program to use, but it may be too old.
 856     # Don't flag an error for --with-python=auto (the default).
 857     have_python_config=yes
 858     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 859     if test $? != 0; then
 860       have_python_config=failed
 861       if test "${with_python}" != auto; then
 862         AC_MSG_ERROR(failure running python-config --includes)
 863       fi
 864     fi
 865     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 866     if test $? != 0; then
 867       have_python_config=failed
 868       if test "${with_python}" != auto; then
 869         AC_MSG_ERROR(failure running python-config --ldflags)
 870       fi
 871     fi
 872     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 873     if test $? != 0; then
 874       have_python_config=failed
 875       if test "${with_python}" != auto; then
 876         AC_MSG_ERROR(failure running python-config --exec-prefix)
 877       fi
 878     fi
 879   else
 880     # We do not have a python executable we can use to determine where
 881     # to find the Python headers and libs.  We cannot guess the include
 882     # path from the python_prefix either, because that include path
 883     # depends on the Python version.  So, there is nothing much we can
 884     # do except assume that the compiler will be able to find those files.
 885     python_includes=
 886     python_libs=
 887     have_python_config=no
 888   fi
 889
 890   # If we have python-config, only try the configuration it provides.
 891   # Otherwise fallback on the old way of trying different versions of
 892   # python in turn.
 893
 894   have_libpython=no
 895   if test "${have_python_config}" = yes; then
 896     AC_TRY_LIBPYTHON(have_libpython,
 897                      ${python_includes}, ${python_libs})
 898   elif test "${have_python_config}" != failed; then
 899     if test "${have_libpython}" = no; then
 900       AC_TRY_LIBPYTHON(have_libpython,
 901                        ${python_includes}, "-lpython2.7 ${python_libs}")
 902     fi
 903     if test "${have_libpython}" = no; then
 904       AC_TRY_LIBPYTHON(have_libpython,
 905                        ${python_includes}, "-lpython2.6 ${python_libs}")
 906     fi
 907   fi
 908
 909   if test "${have_libpython}" = no; then
 910     case "${with_python}" in
 911     yes)
 912       AC_MSG_ERROR([python is missing or unusable])
 913       ;;
 914     auto)
 915       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 916       ;;
 917     *)
 918       AC_MSG_ERROR([no usable python found at ${with_python}])
 919       ;;
 920     esac
 921   else
 922     if test -n "${python_prefix}"; then
 923       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 924                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 925       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 926     fi
 927   fi
 928 fi
 929
 930 dnl Use --with-python-libdir to control where GDB looks for the Python
 931 dnl libraries.
 932 dnl
 933 dnl If this is not given then the default will be based on the value
 934 dnl passed to --with-python, which is in the python_prefix variable.
 935 dnl If the --with-python option wasn't given then the default value in
 936 dnl python_prefix is based on running the 'gdb/python/python-config
 937 dnl --exec-prefix' script.
 938 AC_ARG_WITH(python-libdir,
 939   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 940   [],[
 941     # If no python libdir is specified then select one based on
 942     # python's prefix path.
 943     if test -n "${python_prefix}"; then
 944       with_python_libdir=${python_prefix}/lib
 945     fi
 946   ])
 947
 948 if test "${have_libpython}" != no; then
 949   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 950   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 951   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 952   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 953   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 954   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 955
 956   if test -n "${with_python_libdir}"; then
 957     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 958                        [Directory containing Python's standard libraries from --with-python-libdir.])
 959     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 960   fi
 961
 962   # Flags needed to compile Python code (taken from python-config --cflags).
 963   # We cannot call python-config directly because it will output whatever was
 964   # used when compiling the Python interpreter itself, including flags which
 965   # would make the python-related objects be compiled differently from the
 966   # rest of GDB (e.g., -O2 and -fPIC).
 967   if test "${GCC}" = yes; then
 968     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 969     # Python headers recommend -DNDEBUG, but it's unclear if that just
 970     # refers to building Python itself.  In release mode, though, it
 971     # doesn't hurt for the Python code in gdb to follow.
 972     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 973   fi
 974
 975   if test "x${tentative_python_cflags}" != x; then
 976     AC_MSG_CHECKING(compiler flags for python code)
 977     for flag in ${tentative_python_cflags}; do
 978       # Check that the compiler accepts it
 979       saved_CFLAGS="$CFLAGS"
 980       CFLAGS="$CFLAGS $flag"
 981       AC_COMPILE_IFELSE(
 982         [AC_LANG_PROGRAM([], [])],
 983         [PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag"],
 984         []
 985       )
 986       CFLAGS="$saved_CFLAGS"
 987     done
 988     AC_MSG_RESULT(${PYTHON_CFLAGS})
 989   fi
 990
 991   # On x64 Windows, Python's include headers, and pyconfig.h in
 992   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 993   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 994   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 995   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 996   # The issue was reported to the Python community, but still isn't
 997   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 998
 999   case "$gdb_host" in
1000     mingw64)
1001            if test "${GCC}" = yes; then
1002              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
1003            fi
1004            ;;
1005   esac
1006 else
1007   # Even if Python support is not compiled in, we need to have this file
1008   # included so that the "python" command, et.al., still exists.
1009   CONFIG_OBS="$CONFIG_OBS python/python.o"
1010   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
1011 fi
1012
1013 # Work around Python http://bugs.python.org/issue10112.  See also
1014 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
1015 # no effect.  Note that the only test after this that uses Python is
1016 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
1017 # run without -export-dynamic too.
1018 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
1019
1020 AC_SUBST(PYTHON_CFLAGS)
1021 AC_SUBST(PYTHON_CPPFLAGS)
1022 AC_SUBST(PYTHON_LIBS)
1023 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1024
1025 # -------------------- #
1026 # Check for libguile.  #
1027 # -------------------- #
1028
1029 dnl Utility to simplify finding libguile.
1030 dnl $1 = pkg-config-program
1031 dnl $2 = space-separate list of guile versions to try
1032 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1033 dnl $4 = the shell variable to assign the result to
1034 dnl      If libguile is found we store "yes" here.
1035
1036 AC_DEFUN([AC_TRY_LIBGUILE],
1037 [
1038   pkg_config=$1
1039   guile_version_list=$2
1040   flag_errors=$3
1041   define([have_libguile_var],$4)
1042   found_usable_guile=checking
1043   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1044   for guile_version in ${guile_version_list}; do
1045     ${pkg_config} --exists ${guile_version} 2>/dev/null
1046     if test $? != 0; then
1047       continue
1048     fi
1049     dnl pkg-config says the package exists, so if we get an error now,
1050     dnl that's bad.
1051     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1052     if test $? != 0; then
1053       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1054     fi
1055     new_LIBS=`${pkg_config} --libs ${guile_version}`
1056     if test $? != 0; then
1057       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1058     fi
1059     dnl If we get this far, great.
1060     found_usable_guile=${guile_version}
1061     break
1062   done
1063   if test "${found_usable_guile}" = "checking"; then
1064     if test "${flag_errors}" = "yes"; then
1065       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1066     else
1067       found_usable_guile=no
1068     fi
1069   fi
1070   dnl One final sanity check.
1071   dnl The user could have said --with-guile=python-2.7.
1072   if test "${found_usable_guile}" != no; then
1073     save_CPPFLAGS=$CPPFLAGS
1074     save_LIBS=$LIBS
1075     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1076     LIBS="$LIBS $new_LIBS"
1077     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1078                                    [[scm_init_guile ();]])],
1079                    [have_libguile_var=yes
1080                     GUILE_CPPFLAGS=$new_CPPFLAGS
1081                     GUILE_LIBS=$new_LIBS],
1082                    [found_usable_guile=no])
1083     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1084     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1085       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1086                 [Define if Guile supports manual finalization.])
1087     )
1088     CPPFLAGS=$save_CPPFLAGS
1089     LIBS=$save_LIBS
1090     if test "${found_usable_guile}" = no; then
1091       if test "${flag_errors}" = yes; then
1092         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1093       fi
1094     fi
1095   fi
1096   AC_MSG_RESULT([${found_usable_guile}])
1097 ])
1098
1099 dnl There are several different values for --with-guile:
1100 dnl
1101 dnl no -   Don't include guile support.
1102 dnl yes -  Include guile support, error if it's missing.
1103 dnl        The pkg-config program must be in $PATH.
1104 dnl auto - Same as "yes", but if guile is missing from the system,
1105 dnl        fall back to "no".
1106 dnl guile-version [guile-version-choice-2 ...] -
1107 dnl        A space-separated list of guile package versions to try.
1108 dnl        These are passed to pkg-config as-is.
1109 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1110 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1111 dnl /path/to/pkg-config -
1112 dnl        Use this pkg-config program.
1113 dnl        NOTE: This needn't be the "real" pkg-config program.
1114 dnl        It could be a shell script.  It is invoked as:
1115 dnl        pkg-config --exists $version
1116 dnl        pkg-config --cflags $version
1117 dnl        pkg-config --libs $version
1118 dnl        pkg-config --variable guild $version
1119 dnl        The script will be called with $version having each value in
1120 dnl        $try_guile_versions until --exists indicates success.
1121
1122 AC_ARG_WITH(guile,
1123   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1124   [], [with_guile=auto])
1125 AC_MSG_CHECKING([whether to use guile])
1126 AC_MSG_RESULT([$with_guile])
1127
1128 dnl We check guile with pkg-config.
1129 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1130
1131 try_guile_versions="guile-3.0 guile-2.2 guile-2.0"
1132 have_libguile=no
1133 case "${with_guile}" in
1134 no)
1135   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1136   ;;
1137 auto)
1138   if test "${pkg_config_prog_path}" = "missing"; then
1139     AC_MSG_WARN([pkg-config not found, guile support disabled])
1140   else
1141     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1142   fi
1143   ;;
1144 yes)
1145   if test "${pkg_config_prog_path}" = "missing"; then
1146     AC_MSG_ERROR([pkg-config not found])
1147   fi
1148   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1149   ;;
1150 [[\\/]]* | ?:[[\\/]]*)
1151   if test -x "${with_guile}"; then
1152     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1153   else
1154     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1155   fi
1156   ;;
1157 "" | */*)
1158   # Disallow --with=guile="" and --with-guile=foo/bar.
1159   AC_MSG_ERROR([invalid value for --with-guile])
1160   ;;
1161 *)
1162   # A space separate list of guile versions to try, in order.
1163   if test "${pkg_config_prog_path}" = "missing"; then
1164     AC_MSG_ERROR([pkg-config not found])
1165   fi
1166   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1167   ;;
1168 esac
1169
1170 if test "${have_libguile}" != no; then
1171   dnl Get the name of the 'guild' program.
1172   case "${with_guile}" in
1173   [[\\/]]* | ?:[[\\/]]*)
1174     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1175     ;;
1176   *)
1177     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1178     ;;
1179   esac
1180
1181   dnl Make sure guild can handle this host.
1182   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1183   dnl If not, disable guile support.
1184   if test "$ac_cv_guild_ok" = no; then
1185     have_libguile=no
1186     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1187   fi
1188 fi
1189
1190 if test "${have_libguile}" != no; then
1191   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1192   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1193   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1194   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1195   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1196   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1197
1198   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1199   save_LIBS="$LIBS"
1200   save_CPPFLAGS="$CPPFLAGS"
1201   LIBS="$GUILE_LIBS"
1202   CPPFLAGS="$GUILE_CPPFLAGS"
1203   AC_CHECK_FUNCS([scm_new_smob])
1204   LIBS="$save_LIBS"
1205   CPPFLAGS="$save_CPPFLAGS"
1206 else
1207   # Even if Guile support is not compiled in, we need to have these files
1208   # included.
1209   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1210   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1211 fi
1212 AC_SUBST(GUILE_CPPFLAGS)
1213 AC_SUBST(GUILE_LIBS)
1214 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1215
1216 # ---------------------------- #
1217 # Check for source highlight.  #
1218 # ---------------------------- #
1219
1220 SRCHIGH_LIBS=
1221 SRCHIGH_CFLAGS=
1222
1223 AC_ARG_ENABLE(source-highlight,
1224   AS_HELP_STRING([--enable-source-highlight],
1225     [enable source-highlight for source listings]),
1226   [case "${enableval}" in
1227   yes)  enable_source_highlight=yes ;;
1228   no)   enable_source_highlight=no  ;;
1229   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1230 esac],
1231 [enable_source_highlight=auto])
1232
1233 if test "${enable_source_highlight}" != "no"; then
1234   AC_MSG_CHECKING([for the source-highlight library])
1235   if test "${pkg_config_prog_path}" = "missing"; then
1236     AC_MSG_RESULT([no - pkg-config not found])
1237     if test "${enable_source_highlight}" = "yes"; then
1238       AC_MSG_ERROR([pkg-config was not found in your system])
1239     fi
1240   else
1241     if ${pkg_config_prog_path} --exists source-highlight; then
1242       case "$LDFLAGS" in
1243         *static-libstdc*)
1244           AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1245 either use --disable-source-highlight or dnl
1246 --without-static-standard-libraries])
1247           ;;
1248       esac
1249
1250       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1251       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1252       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1253                 [Define to 1 if the source-highlight library is available])
1254       AC_MSG_RESULT([yes])
1255     else
1256       AC_MSG_RESULT([no])
1257       if test "${enable_source_highlight}" = "yes"; then
1258         AC_MSG_ERROR([source-highlight was not found in your system])
1259       fi
1260     fi
1261   fi
1262 fi
1263 AC_SUBST(SRCHIGH_LIBS)
1264 AC_SUBST(SRCHIGH_CFLAGS)
1265
1266 # ------------------------- #
1267 # Checks for header files.  #
1268 # ------------------------- #
1269
1270 AC_HEADER_STDC
1271 # elf_hp.h is for HP/UX 64-bit shared library support.
1272 AC_CHECK_HEADERS([nlist.h machine/reg.h \
1273                   thread_db.h \
1274                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1275                   sys/resource.h sys/ptrace.h ptrace.h \
1276                   sys/reg.h sys/debugreg.h \
1277                   termios.h elf_hp.h])
1278 AC_CHECK_HEADERS(sys/user.h, [], [],
1279 [#if HAVE_SYS_PARAM_H
1280 # include <sys/param.h>
1281 #endif
1282 ])
1283
1284 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1285 AC_CHECK_HEADERS(term.h, [], [],
1286 [#if HAVE_CURSES_H
1287 # include <curses.h>
1288 #endif
1289 ])
1290
1291 AC_CHECK_HEADERS([sys/socket.h])
1292 AC_CHECK_HEADERS([ws2tcpip.h])
1293
1294 # ------------------------- #
1295 # Checks for declarations.  #
1296 # ------------------------- #
1297
1298 libiberty_INIT
1299
1300 AC_CHECK_DECLS([snprintf])
1301 AM_LC_MESSAGES
1302
1303 # ------------------ #
1304 # Checks for types.  #
1305 # ------------------ #
1306
1307 AC_CHECK_TYPES(socklen_t, [], [],
1308 [#include <sys/types.h>
1309 #if HAVE_SYS_SOCKET_H
1310 # include <sys/socket.h>
1311 #elif HAVE_WS2TCPIP_H
1312 # include <ws2tcpip.h>
1313 #endif
1314 ])
1315
1316 # ------------------------------------- #
1317 # Checks for compiler characteristics.  #
1318 # ------------------------------------- #
1319
1320 AC_C_CONST
1321 AC_C_INLINE
1322 AC_C_BIGENDIAN
1323
1324 # ------------------------------ #
1325 # Checks for library functions.  #
1326 # ------------------------------ #
1327
1328 AC_CHECK_FUNCS([getuid getgid \
1329                 pipe pread pread64 pwrite resize_term \
1330                 getpgid setsid \
1331                 sigaction sigsetmask socketpair \
1332                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1333                 setrlimit getrlimit posix_madvise waitpid \
1334                 use_default_colors])
1335 AM_LANGINFO_CODESET
1336 GDB_AC_COMMON
1337
1338 # Check the return and argument types of ptrace.
1339 GDB_AC_PTRACE
1340
1341 dnl AC_FUNC_SETPGRP does not work when cross compiling
1342 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1343 if test "$cross_compiling" = no; then
1344   AC_FUNC_SETPGRP
1345 else
1346   AC_CACHE_CHECK(
1347     [whether setpgrp takes no argument],
1348     [ac_cv_func_setpgrp_void],
1349     [AC_COMPILE_IFELSE(
1350        [AC_LANG_PROGRAM(
1351           [#include <unistd.h>],
1352           [if (setpgrp(1,1) == -1)
1353              exit (0);
1354            else
1355              exit (1);]
1356         )],
1357        [ac_cv_func_setpgrp_void=no],
1358        [ac_cv_func_setpgrp_void=yes]
1359      )]
1360   )
1361 if test "$ac_cv_func_setpgrp_void" = yes; then
1362   AC_DEFINE(SETPGRP_VOID, 1)
1363 fi
1364 fi
1365
1366 # Assume we'll default to using the included libiberty regex.
1367 gdb_use_included_regex=yes
1368
1369 # However, if the system regex is GNU regex, then default to *not*
1370 # using the included regex.
1371 AC_CACHE_CHECK(
1372   [for GNU regex],
1373   [gdb_cv_have_gnu_regex],
1374   [AC_COMPILE_IFELSE(
1375      [AC_LANG_PROGRAM(
1376         [#include <gnu-versions.h>],
1377         [#define REGEX_INTERFACE_VERSION 1
1378          #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1379          # error "Version mismatch"
1380          #endif]
1381       )],
1382      [gdb_cv_have_gnu_regex=yes],
1383      [gdb_cv_have_gnu_regex=no]
1384    )]
1385 )
1386 if test "$gdb_cv_have_gnu_regex" = yes; then
1387   gdb_use_included_regex=no
1388 fi
1389
1390 AC_ARG_WITH(included-regex,
1391   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1392   gdb_with_regex=$withval,
1393   gdb_with_regex=$gdb_use_included_regex)
1394 if test "$gdb_with_regex" = yes; then
1395   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1396     [Define to 1 if the regex included in libiberty should be used.])
1397 fi
1398
1399 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1400 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1401 [#include <sys/param.h>
1402 #include <sys/proc.h>
1403 ])
1404
1405 # See if <sys/lwp.h> defines `struct lwp`.
1406 AC_CACHE_CHECK(
1407   [for struct lwp],
1408   [gdb_cv_struct_lwp],
1409   [AC_COMPILE_IFELSE(
1410      [AC_LANG_PROGRAM(
1411         [#include <sys/param.h>
1412          #define _KMEMUSER
1413          #include <sys/lwp.h>],
1414         [struct lwp l;]
1415       )],
1416      [gdb_cv_struct_lwp=yes],
1417      [gdb_cv_struct_lwp=no]
1418    )]
1419 )
1420 if test "$gdb_cv_struct_lwp" = yes; then
1421   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1422             [Define to 1 if your system has struct lwp.])
1423 fi
1424
1425 # See if <machine/reg.h> degines `struct reg'.
1426 AC_CACHE_CHECK(
1427   [for struct reg in machine/reg.h],
1428   [gdb_cv_struct_reg],
1429   [AC_COMPILE_IFELSE(
1430      [AC_LANG_PROGRAM(
1431         [#include <sys/types.h>
1432          #include <machine/reg.h>],
1433         [struct reg r;]
1434       )],
1435      [gdb_cv_struct_reg=yes],
1436      [gdb_cv_struct_reg=no]
1437    )]
1438 )
1439 if test "$gdb_cv_struct_reg" = yes; then
1440   AC_DEFINE(HAVE_STRUCT_REG, 1,
1441             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1442 fi
1443
1444 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1445 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1446 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1447                  [#include <sys/types.h>
1448 #include <machine/reg.h>])
1449
1450 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1451 AC_MSG_CHECKING(for PTRACE_GETREGS)
1452 AC_CACHE_VAL(
1453   [gdb_cv_have_ptrace_getregs],
1454   [AC_COMPILE_IFELSE(
1455     [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETREGS;])],
1456     [gdb_cv_have_ptrace_getregs=yes],
1457     [gdb_cv_have_ptrace_getregs=no]
1458    )]
1459 )
1460 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1461 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1462   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1463   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1464 fi
1465
1466 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1467 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1468 AC_CACHE_VAL(
1469   [gdb_cv_have_ptrace_getfpxregs],
1470   [AC_COMPILE_IFELSE(
1471      [AC_LANG_PROGRAM([#include <sys/ptrace.h>], [PTRACE_GETFPXREGS;])],
1472      [gdb_cv_have_ptrace_getfpxregs=yes],
1473      [gdb_cv_have_ptrace_getfpxregs=no]
1474    )]
1475 )
1476 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1477 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1478   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1479   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1480 fi
1481
1482 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1483 AC_MSG_CHECKING(for PT_GETDBREGS)
1484 AC_CACHE_VAL(
1485   [gdb_cv_have_pt_getdbregs],
1486   [AC_COMPILE_IFELSE(
1487      [AC_LANG_PROGRAM(
1488         [#include <sys/types.h>
1489          #include <sys/ptrace.h>],
1490         [PT_GETDBREGS;]
1491       )],
1492      [gdb_cv_have_pt_getdbregs=yes],
1493      [gdb_cv_have_pt_getdbregs=no]
1494    )]
1495 )
1496 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1497 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1498   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1499   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1500 fi
1501
1502 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1503 AC_MSG_CHECKING(for PT_GETXMMREGS)
1504 AC_CACHE_VAL(
1505   [gdb_cv_have_pt_getxmmregs],
1506   [AC_COMPILE_IFELSE(
1507      [AC_LANG_PROGRAM(
1508         [#include <sys/types.h>
1509          #include <sys/ptrace.h>],
1510         [PT_GETXMMREGS;]
1511       )],
1512      [gdb_cv_have_pt_getxmmregs=yes],
1513      [gdb_cv_have_pt_getxmmregs=no]
1514    )]
1515 )
1516 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1517 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1518   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1519   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1520 fi
1521
1522 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1523 # Older FreeBSD versions don't have the pl_tdname member of
1524 # `struct ptrace_lwpinfo'.
1525 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1526                  [#include <sys/ptrace.h>])
1527
1528 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1529 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1530 # FreeBSD 10.3.
1531 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1532                  [#include <sys/ptrace.h>])
1533
1534 # Check if the compiler supports the `long long' type.
1535
1536 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1537                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1538 [[extern long long foo;]],
1539 [[switch (foo & 2) { case 0: return 1; }]])],
1540                                   gdb_cv_c_long_long=yes,
1541                                   gdb_cv_c_long_long=no)])
1542 if test "$gdb_cv_c_long_long" != yes; then
1543   # libdecnumber requires long long.
1544   AC_MSG_ERROR([Compiler must support long long for GDB.])
1545 fi
1546
1547 # Check if the compiler and runtime support printing long longs.
1548
1549 AC_CACHE_CHECK([for long long support in printf],
1550                gdb_cv_printf_has_long_long,
1551                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1552 [[char buf[32];
1553   long long l = 0;
1554   l = (l << 16) + 0x0123;
1555   l = (l << 16) + 0x4567;
1556   l = (l << 16) + 0x89ab;
1557   l = (l << 16) + 0xcdef;
1558   sprintf (buf, "0x%016llx", l);
1559   return (strcmp ("0x0123456789abcdef", buf));]])],
1560                               gdb_cv_printf_has_long_long=yes,
1561                               gdb_cv_printf_has_long_long=no,
1562                               gdb_cv_printf_has_long_long=no)])
1563 if test "$gdb_cv_printf_has_long_long" = yes; then
1564   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1565             [Define to 1 if the "%ll" format works to print long longs.])
1566 fi
1567
1568 # Check if the compiler and runtime support printing decfloats.
1569
1570 AC_CACHE_CHECK([for decfloat support in printf],
1571                gdb_cv_printf_has_decfloat,
1572                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1573 [[char buf[64];
1574   _Decimal32 d32 = 1.2345df;
1575   _Decimal64 d64 = 1.2345dd;
1576   _Decimal128 d128 = 1.2345dl;
1577   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1578   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1579                               gdb_cv_printf_has_decfloat=yes,
1580                               gdb_cv_printf_has_decfloat=no,
1581                               gdb_cv_printf_has_decfloat=no)])
1582 if test "$gdb_cv_printf_has_decfloat" = yes; then
1583   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1584             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1585 fi
1586
1587 # Check if the compiler supports the `long double' type.  We can't use
1588 # AC_C_LONG_DOUBLE because that one does additional checks on the
1589 # constants defined in <float.h> that fail on some systems,
1590 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1591
1592 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1593                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1594                                   gdb_cv_c_long_double=yes,
1595                                   gdb_cv_c_long_double=no)])
1596 if test "$gdb_cv_c_long_double" = yes; then
1597   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1598            [Define to 1 if the compiler supports long double.])
1599 fi
1600
1601 # Check if the compiler and runtime support printing long doubles.
1602
1603 AC_CACHE_CHECK([for long double support in printf],
1604                gdb_cv_printf_has_long_double,
1605                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1606 [[char buf[16];
1607   long double f = 3.141592653;
1608   sprintf (buf, "%Lg", f);
1609   return (strncmp ("3.14159", buf, 7));]])],
1610                               gdb_cv_printf_has_long_double=yes,
1611                               gdb_cv_printf_has_long_double=no,
1612                               gdb_cv_printf_has_long_double=no)])
1613 if test "$gdb_cv_printf_has_long_double" = yes; then
1614   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1615             [Define to 1 if the "%Lg" format works to print long doubles.])
1616 fi
1617
1618 # Check if the compiler and runtime support scanning long doubles.
1619
1620 AC_CACHE_CHECK([for long double support in scanf],
1621                gdb_cv_scanf_has_long_double,
1622                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1623 [[#include <stdio.h>]],
1624 [[char *buf = "3.141592653";
1625   long double f = 0;
1626   sscanf (buf, "%Lg", &f);
1627   return !(f > 3.14159 && f < 3.14160);]])],
1628                               gdb_cv_scanf_has_long_double=yes,
1629                               gdb_cv_scanf_has_long_double=no,
1630                               gdb_cv_scanf_has_long_double=no)])
1631 if test "$gdb_cv_scanf_has_long_double" = yes; then
1632   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1633             [Define to 1 if the "%Lg" format works to scan long doubles.])
1634 fi
1635
1636 case ${host_os} in
1637 aix*)
1638   AC_CACHE_CHECK(
1639     [for -bbigtoc option], [gdb_cv_bigtoc],
1640     [SAVE_LDFLAGS=$LDFLAGS
1641
1642      case $GCC in
1643        yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1644        *) gdb_cv_bigtoc=-bbigtoc ;;
1645      esac
1646
1647      LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1648      AC_LINK_IFELSE(
1649        [AC_LANG_PROGRAM([], [int i;])],
1650        [],
1651        [gdb_cv_bigtoc=]
1652      )
1653      LDFLAGS="${SAVE_LDFLAGS}"]
1654   )
1655   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1656   ;;
1657 esac
1658
1659 AC_MSG_CHECKING(for the dynamic export flag)
1660 dynamic_list=false
1661 if test "${gdb_native}" = yes; then
1662    # The dynamically loaded libthread_db needs access to symbols in the gdb
1663    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1664    # may not be supported there.
1665    old_LDFLAGS="$LDFLAGS"
1666    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1667    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1668    LDFLAGS="$LDFLAGS $RDYNAMIC"
1669    if test "${have_libpython}" = no; then
1670      AC_LINK_IFELSE(
1671        [AC_LANG_PROGRAM([], [])],
1672        [dynamic_list=true],
1673        []
1674      )
1675    else
1676      # Workaround http://bugs.python.org/issue4434 where static
1677      # libpythonX.Y.a would get its symbols required for
1678      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1679      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1680
1681      # Note the workaround for Python
1682      # http://bugs.python.org/issue10112 earlier has removed
1683      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1684      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1685      # always pass.
1686      old_CFLAGS="$CFLAGS"
1687      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1688      old_LIBS="$LIBS"
1689      LIBS="$LIBS $PYTHON_LIBS"
1690      old_CPPFLAGS="$CPPFLAGS"
1691      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1692      AC_RUN_IFELSE(
1693        [AC_LANG_PROGRAM(
1694          [#include "Python.h"],
1695          [int err;
1696           Py_Initialize ();
1697           err = PyRun_SimpleString ("import ctypes\n");
1698           Py_Finalize ();
1699           return err == 0 ? 0 : 1;])],
1700        [dynamic_list=true], [], [true])
1701      LIBS="$old_LIBS"
1702      CFLAGS="$old_CFLAGS"
1703      CPPFLAGS="$old_CPPFLAGS"
1704    fi
1705    LDFLAGS="$old_LDFLAGS"
1706 fi
1707 if $dynamic_list; then
1708   found="-Wl,--dynamic-list"
1709   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1710 else
1711   found="-rdynamic"
1712   RDYNAMIC="-rdynamic"
1713 fi
1714 AC_SUBST(RDYNAMIC)
1715 AC_MSG_RESULT($found)
1716
1717 dnl For certain native configurations, we need to check whether thread
1718 dnl support can be built in or not.
1719 dnl
1720 dnl Note that we only want this if we are both native (host == target),
1721 dnl and not doing a canadian cross build (build == host).
1722
1723 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1724    case ${host_os} in
1725    aix*)
1726       AC_MSG_CHECKING(for AiX thread debugging library)
1727       AC_CACHE_VAL(
1728         [gdb_cv_have_aix_thread_debug],
1729         [AC_COMPILE_IFELSE(
1730            [AC_LANG_PROGRAM(
1731               [#include <sys/pthdebug.h>],
1732               [#ifndef PTHDB_VERSION_3
1733                #error
1734                #endif]
1735             )],
1736            [gdb_cv_have_aix_thread_debug=yes],
1737            [gdb_cv_have_aix_thread_debug=no]
1738          )]
1739       )
1740       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1741       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1742          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1743          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1744          LIBS="$LIBS -lpthdebug"
1745
1746          # Older versions of AIX do not provide the declaration for
1747          # the getthrds function (it appears that it was introduced
1748          # with AIX 6.x).
1749          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1750       fi
1751       ;;
1752    esac
1753    AC_SUBST(CONFIG_LDFLAGS)
1754 fi
1755
1756 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1757 dnl other error codes.
1758 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1759   AC_CACHE_CHECK(
1760     [whether <thread_db.h> has TD_NOTALLOC],
1761     [gdb_cv_thread_db_h_has_td_notalloc],
1762     [AC_COMPILE_IFELSE(
1763        [AC_LANG_PROGRAM(
1764           [#include <thread_db.h>],
1765           [int i = TD_NOTALLOC;]
1766         )],
1767        [gdb_cv_thread_db_h_has_td_notalloc=yes],
1768        [gdb_cv_thread_db_h_has_td_notalloc=no]
1769      )]
1770   )
1771
1772   AC_CACHE_CHECK(
1773     [whether <thread_db.h> has TD_VERSION],
1774     [gdb_cv_thread_db_h_has_td_version],
1775     [AC_COMPILE_IFELSE(
1776        [AC_LANG_PROGRAM(
1777           [#include <thread_db.h>],
1778           [int i = TD_VERSION;]
1779         )],
1780        [gdb_cv_thread_db_h_has_td_version=yes],
1781        [gdb_cv_thread_db_h_has_td_version=no]
1782      )]
1783   )
1784
1785   AC_CACHE_CHECK(
1786     [whether <thread_db.h> has TD_NOTLS],
1787     [gdb_cv_thread_db_h_has_td_notls],
1788     [AC_COMPILE_IFELSE(
1789        [AC_LANG_PROGRAM(
1790           [#include <thread_db.h>],
1791           [int i = TD_NOTLS;]
1792         )],
1793        [gdb_cv_thread_db_h_has_td_notls=yes],
1794        [gdb_cv_thread_db_h_has_td_notls=no]
1795      )]
1796   )
1797 fi
1798 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1799   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1800             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1801 fi
1802 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1803   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1804             [Define if <thread_db.h> has the TD_VERSION error code.])
1805 fi
1806 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1807   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1808             [Define if <thread_db.h> has the TD_NOTLS error code.])
1809 fi
1810
1811 dnl Set the host's .gdbinit filename.
1812 case $host_os in
1813   go32* | *djgpp*)
1814     gdbinit=gdb.ini
1815     ;;
1816   *)
1817     gdbinit=.gdbinit
1818     ;;
1819 esac
1820 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1821
1822 dnl Handle optional features that can be enabled.
1823
1824 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1825 # except that the argument to --with-sysroot is optional.
1826 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1827 if test "x$with_sysroot" = xyes; then
1828   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1829 fi
1830 AC_ARG_WITH(sysroot,
1831   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1832                  [search for usr/lib et al within DIR]),
1833   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1834 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1835               [search for usr/lib et al within DIR])
1836 AC_SUBST(TARGET_SYSTEM_ROOT)
1837 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1838
1839 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1840     [automatically load a system-wide gdbinit file],
1841     [])
1842 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1843     [automatically load system-wide gdbinit files from this directory],
1844     [])
1845
1846 AM_GDB_WARNINGS
1847 AM_GDB_UBSAN
1848
1849 # In the Cygwin environment, we need some additional flags.
1850 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1851 [AC_EGREP_CPP(^lose$, [
1852 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1853 lose
1854 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1855
1856
1857 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1858 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1859 case ${host} in
1860   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1861   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1862   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1863   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1864 esac
1865 AC_SUBST(SER_HARDWIRE)
1866
1867 # libreadline needs libuser32.a in a cygwin environment
1868 WIN32LIBS=
1869 if test x"$gdb_cv_os_cygwin" = xyes; then
1870     WIN32LIBS="-luser32"
1871     case "${target}" in
1872         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1873         ;;
1874     esac
1875 fi
1876
1877 # The ser-tcp.c module requires sockets.
1878 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1879 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1880
1881 # Add ELF support to GDB, but only if BFD includes ELF support.
1882 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1883                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1884 if test "$gdb_cv_var_elf" = yes; then
1885   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1886   AC_DEFINE(HAVE_ELF, 1,
1887             [Define if ELF support should be included.])
1888   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1889   if test "$plugins" = "yes"; then
1890     AC_SEARCH_LIBS(dlopen, dl)
1891   fi
1892 fi
1893
1894 # Add macho support to GDB, but only if BFD includes it.
1895 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1896                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1897 if test "$gdb_cv_var_macho" = yes; then
1898   CONFIG_OBS="$CONFIG_OBS machoread.o"
1899 fi
1900
1901 # Add any host-specific objects to GDB.
1902 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1903
1904 # If building on ELF, look for lzma support for embedded compressed debug info.
1905 if test "$gdb_cv_var_elf" = yes; then
1906   AC_ARG_WITH(lzma,
1907     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1908     [], [with_lzma=auto])
1909   AC_MSG_CHECKING([whether to use lzma])
1910   AC_MSG_RESULT([$with_lzma])
1911
1912   if test "${with_lzma}" != no; then
1913     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1914                           [lzma_index_iter iter;
1915                            lzma_index_iter_init (&iter, 0);
1916                            lzma_mf_is_supported (LZMA_MF_HC3);])
1917     if test "$HAVE_LIBLZMA" != yes; then
1918       if test "$with_lzma" = yes; then
1919         AC_MSG_ERROR([missing liblzma for --with-lzma])
1920       fi
1921     fi
1922   fi
1923 fi
1924
1925 LIBGUI="../libgui/src/libgui.a"
1926 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1927 AC_SUBST(LIBGUI)
1928 AC_SUBST(GUI_CFLAGS_X)
1929
1930 WIN32LDAPP=
1931 AC_SUBST(WIN32LIBS)
1932 AC_SUBST(WIN32LDAPP)
1933
1934 case "${host}" in
1935 *-*-cygwin* | *-*-mingw* )
1936     configdir="win"
1937     ;;
1938 *)
1939     configdir="unix"
1940     ;;
1941 esac
1942
1943 GDBTKLIBS=
1944 if test "${enable_gdbtk}" = "yes"; then
1945
1946     # Gdbtk must have an absolute path to srcdir in order to run
1947     # properly when not installed.
1948     here=`pwd`
1949     cd ${srcdir}
1950     GDBTK_SRC_DIR=`pwd`
1951     cd $here
1952
1953     SC_PATH_TCLCONFIG
1954
1955     # If $no_tk is nonempty, then we can't do Tk, and there is no
1956     # point to doing Tcl.
1957     SC_PATH_TKCONFIG
1958
1959     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1960         SC_LOAD_TCLCONFIG
1961
1962         # Check for in-tree tcl
1963         here=`pwd`
1964         cd ${srcdir}/..
1965         topdir=`pwd`
1966         cd ${here}
1967
1968         intree="no"
1969         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1970           intree="yes"
1971         fi
1972
1973         # Find Tcl private headers
1974         if test x"${intree}" = xno; then
1975           CY_AC_TCL_PRIVATE_HEADERS
1976           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1977           TCL_LIBRARY="${TCL_LIB_SPEC}"
1978           TCL_DEPS=""
1979         else
1980           # If building tcl in the same src tree, private headers
1981           # are not needed, but we need to be sure to use the right
1982           # headers library
1983           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1984           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1985           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1986         fi
1987         AC_SUBST(TCL_INCLUDE)
1988         AC_SUBST(TCL_LIBRARY)
1989         AC_SUBST(TCL_DEPS)
1990
1991         SC_LOAD_TKCONFIG
1992
1993         # Check for in-tree Tk
1994         intree="no"
1995         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1996           intree="yes"
1997         fi
1998
1999         # Find Tk private headers
2000         if test x"${intree}" = xno; then
2001           CY_AC_TK_PRIVATE_HEADERS
2002           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
2003           TK_LIBRARY=${TK_LIB_SPEC}
2004           TK_DEPS=""
2005         else
2006           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
2007           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
2008           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
2009         fi
2010         AC_SUBST(TK_INCLUDE)
2011         AC_SUBST(TK_LIBRARY)
2012         AC_SUBST(TK_DEPS)
2013         AC_SUBST(TK_XINCLUDES)
2014
2015         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2016
2017         # Include some libraries that Tcl and Tk want.
2018         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2019         # Yes, the ordering seems wrong here.  But it isn't.
2020         # TK_LIBS is the list of libraries that need to be linked
2021         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2022         # were in LIBS then any link tests after this point would
2023         # try to include things like `$(LIBGUI)', which wouldn't work.
2024         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2025
2026         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2027         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2028         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2029         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2030         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2031         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2032         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2033
2034         if test x"$gdb_cv_os_cygwin" = xyes; then
2035           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2036           WIN32LDAPP="-Wl,--subsystem,console"
2037           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2038         fi
2039
2040         AC_CONFIG_SUBDIRS(gdbtk)
2041     fi
2042 fi
2043
2044 AC_SUBST(X_CFLAGS)
2045 AC_SUBST(X_LDFLAGS)
2046 AC_SUBST(X_LIBS)
2047 AC_SUBST(GDBTKLIBS)
2048 AC_SUBST(GDBTK_CFLAGS)
2049 AC_SUBST(GDBTK_SRC_DIR)
2050
2051 AC_PATH_X
2052
2053 # Unlike the sim directory, whether a simulator is linked is controlled by
2054 # presence of a gdb_sim definition in the target configure.tgt entry.
2055 # This code just checks for a few cases where we'd like to ignore those
2056 # definitions, even when they're present in the '.mt' file.  These cases
2057 # are when --disable-sim is specified, or if the simulator directory is
2058 # not part of the source tree.
2059 #
2060 AC_ARG_ENABLE(sim,
2061 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2062 [echo "enable_sim = $enable_sim";
2063  echo "enableval = ${enableval}";
2064  case "${enableval}" in
2065   yes) ignore_sim=false ;;
2066   no)  ignore_sim=true ;;
2067   *)   ignore_sim=false ;;
2068  esac],
2069 [ignore_sim=false])
2070
2071 if test ! -d "${srcdir}/../sim"; then
2072   ignore_sim=true
2073 fi
2074
2075 SIM=
2076 SIM_OBS=
2077 if test "${ignore_sim}" = "false"; then
2078   if test x"${gdb_sim}" != x ; then
2079     SIM="${gdb_sim}"
2080     SIM_OBS="remote-sim.o"
2081     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2082
2083     # Some tdep code should only be compiled in when the ppc sim is
2084     # built.  PR sim/13418.
2085     case $target in
2086       powerpc*-*-*)
2087         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2088         ;;
2089     esac
2090   fi
2091 fi
2092 AC_SUBST(SIM)
2093 AC_SUBST(SIM_OBS)
2094
2095 AC_SUBST(ENABLE_CFLAGS)
2096 AC_SUBST(PROFILE_CFLAGS)
2097
2098 AC_SUBST(CONFIG_OBS)
2099 AC_SUBST(CONFIG_DEPS)
2100 AC_SUBST(CONFIG_SRCS)
2101 AC_SUBST(CONFIG_ALL)
2102 AC_SUBST(CONFIG_CLEAN)
2103 AC_SUBST(CONFIG_INSTALL)
2104 AC_SUBST(CONFIG_UNINSTALL)
2105
2106 # List of host floatformats.
2107 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2108 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2109 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2110
2111 # target_subdir is used by the testsuite to find the target libraries.
2112 target_subdir=
2113 if test "${host}" != "${target}"; then
2114     target_subdir="${target_alias}/"
2115 fi
2116 AC_SUBST(target_subdir)
2117
2118 # Import nat definitions.
2119 nat_makefile_frag=/dev/null
2120 if test "${gdb_native}" = "yes"; then
2121   . ${srcdir}/configure.nat
2122   nativefile=$NAT_FILE
2123 fi
2124
2125 AC_SUBST(NAT_FILE)
2126 AC_SUBST(NATDEPFILES)
2127 AC_SUBST(NAT_CDEPS)
2128 AC_SUBST(LOADLIBES)
2129 AC_SUBST(MH_CFLAGS)
2130 AC_SUBST(XM_CLIBS)
2131 AC_SUBST(NAT_GENERATED_FILES)
2132 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2133 AC_SUBST_FILE(nat_makefile_frag)
2134
2135 if test x"${gdb_osabi}" != x ; then
2136     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2137                        [Define to the default OS ABI for this configuration.])
2138 fi
2139
2140 # Check for babeltrace and babeltrace-ctf
2141 AC_ARG_WITH(babeltrace,
2142   AS_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2143   [], [with_babeltrace=auto])
2144 AC_MSG_CHECKING([whether to use babeltrace])
2145 AC_MSG_RESULT([$with_babeltrace])
2146
2147 if test "x$with_babeltrace" = "xno"; then
2148   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2149 else
2150   # Append -Werror to CFLAGS so that configure can catch the warning
2151   # "assignment from incompatible pointer type", which is related to
2152   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2153   # in GDB, while babeltrace 1.0.3 is broken.
2154   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2155   # safe to save and restore CFLAGS here.
2156   saved_CFLAGS=$CFLAGS
2157   CFLAGS="$CFLAGS -Werror"
2158   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2159                         [#include <babeltrace/babeltrace.h>
2160                          #include <babeltrace/ctf/events.h>
2161                          #include <babeltrace/ctf/iterator.h>],
2162                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2163                         struct bt_ctf_event *event = NULL;
2164                         const struct bt_definition *scope;
2165
2166                         pos->type = BT_SEEK_BEGIN;
2167                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2168                         scope = bt_ctf_get_top_level_scope (event,
2169                                                            BT_STREAM_EVENT_HEADER);
2170                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2171                         ])
2172   CFLAGS=$saved_CFLAGS
2173
2174   if test "$HAVE_LIBBABELTRACE" != yes; then
2175      if test "$with_babeltrace" = yes; then
2176        AC_MSG_ERROR([babeltrace is missing or unusable])
2177      else
2178        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2179      fi
2180   fi
2181 fi
2182
2183 # Check for xxhash
2184 AC_ARG_WITH(xxhash,
2185   AS_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2186   [], [with_xxhash=auto])
2187
2188 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
2189 if test x${enable_static} = xno; then
2190   LIBCTF="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
2191   CTF_DEPS="../libctf/.libs/libctf.so"
2192 else
2193   LIBCTF="../libctf/.libs/libctf.a"
2194   CTF_DEPS="$LIBCTF"
2195 fi
2196 if test "${enable_libctf}" = yes; then
2197   AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
2198 else
2199   LIBCTF=
2200   CTF_DEPS=
2201 fi
2202 AC_SUBST(ENABLE_LIBCTF)
2203 AC_SUBST(LIBCTF)
2204 AC_SUBST(CTF_DEPS)
2205
2206 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2207 # empty version.
2208
2209 if test "x$with_xxhash" != "xno"; then
2210   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2211                         [#include <xxhash.h>],
2212                         [XXH32("foo", 3, 0);
2213                         ])
2214   if test "$HAVE_LIBXXHASH" != yes; then
2215     if test "$with_xxhash" = yes; then
2216       AC_MSG_ERROR([xxhash is missing or unusable])
2217     fi
2218   fi
2219   if test "x$with_xxhash" = "xauto"; then
2220     with_xxhash="$HAVE_LIBXXHASH"
2221   fi
2222 fi
2223
2224 AC_MSG_CHECKING([whether to use xxhash])
2225 AC_MSG_RESULT([$with_xxhash])
2226
2227 NM_H=
2228 rm -f nm.h
2229 if test "${nativefile}" != ""; then
2230     case "${nativefile}" in
2231       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2232       * ) GDB_NM_FILE="${nativefile}"
2233     esac
2234     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2235                     [GDB_NM_FILE=$GDB_NM_FILE])
2236     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2237     NM_H=nm.h
2238 fi
2239 AC_SUBST(GDB_NM_FILE)
2240 AC_SUBST(NM_H)
2241
2242 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2243 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2244 if test "x$USE_MAINTAINER_MODE" = xyes; then
2245   if test "${XSLTPROC}" = missing; then
2246     AC_MSG_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2247   fi
2248 fi
2249 AC_SUBST(XSLTPROC)
2250
2251 dnl Check for exe extension set on certain hosts (e.g. Win32)
2252 AC_EXEEXT
2253
2254 dnl  Detect the character set used by this host.
2255 dnl  At the moment, we just assume it's UTF-8.
2256 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2257           [Define to be a string naming the default host character set.])
2258
2259 GDB_AC_SELFTEST([
2260   CONFIG_OBS="$CONFIG_OBS \$(SELFTESTS_OBS)"
2261   CONFIG_SRCS="$CONFIG_SRCS \$(SELFTESTS_SRCS)"
2262 ])
2263
2264 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2265 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2266 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2267 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2268
2269 AC_OUTPUT