gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2020 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 m4_include(../config/debuginfod.m4)
  22
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADERS(config.h:config.in, [echo > stamp-h])
  25 AM_MAINTAINER_MODE
  26
  27 # Set the 'development' global.
  28 . $srcdir/../bfd/development.sh
  29
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32
  33 AC_USE_SYSTEM_EXTENSIONS
  34 ACX_LARGEFILE
  35 AM_PROG_CC_STDC
  36 AM_PROG_INSTALL_STRIP
  37
  38 AC_CONFIG_AUX_DIR(..)
  39 AC_CANONICAL_SYSTEM
  40 AC_ARG_PROGRAM
  41
  42 # We require a C++11 compiler.  Check if one is available, and if
  43 # necessary, set CXX_DIALECT to some -std=xxx switch.
  44 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  45
  46 # Dependency checking.
  47 ZW_CREATE_DEPDIR
  48 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  49
  50 dnl List of object files and targets accumulated by configure.
  51
  52 CONFIG_OBS=
  53 CONFIG_DEPS=
  54 CONFIG_SRCS=
  55 ENABLE_CFLAGS=
  56
  57 CONFIG_ALL=
  58 CONFIG_CLEAN=
  59 CONFIG_INSTALL=
  60 CONFIG_UNINSTALL=
  61
  62 dnl Set up for gettext.
  63 ZW_GNU_GETTEXT_SISTER_DIR
  64
  65 localedir='${datadir}/locale'
  66 AC_SUBST(localedir)
  67
  68 if test x"$USE_NLS" = xyes; then
  69    CONFIG_ALL="$CONFIG_ALL all-po"
  70    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  71    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  72    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  73 fi
  74
  75 PACKAGE=gdb
  76 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  77 AC_SUBST(PACKAGE)
  78
  79 # We never need to detect it in this sub-configure.
  80 # But preserve it for config.status --recheck.
  81 AC_ARG_VAR(MAKEINFO,
  82   [Parent configure detects if it is of sufficient version.])
  83 AC_ARG_VAR(MAKEINFOFLAGS,
  84   [Parameters for MAKEINFO.])
  85
  86 MAKEINFO_EXTRA_FLAGS=""
  87 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  88   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  89   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  90     gdb_cv_have_makeinfo_click=yes
  91   else
  92     gdb_cv_have_makeinfo_click=no
  93   fi])
  94 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  95   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  96 fi
  97 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  98
  99 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
 100     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
 101     [${libdir}/debug])
 102
 103 # We can't pass paths as command line arguments.
 104 # Mingw32 tries to be clever and will convert the paths for us.
 105 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 106 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 107 # This breaks GDB's relocatable path conversions since paths passed in
 108 # config.h would not get so translated, the path prefixes no longer match.
 109 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 110
 111 # GDB's datadir relocation
 112
 113 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 114     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 115     [${datadir}/gdb])
 116
 117 AC_ARG_WITH(relocated-sources,
 118 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 119 [reloc_srcdir="${withval}"
 120  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 121               [Relocated directory for source files. ])
 122 ])
 123
 124 AC_MSG_CHECKING([for default auto-load directory])
 125 AC_ARG_WITH(auto-load-dir,
 126 AS_HELP_STRING([--with-auto-load-dir=PATH],
 127   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 128   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 129 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 130 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 131               [Directories from which to load auto-loaded scripts.])
 132 AC_MSG_RESULT([$with_auto_load_dir])
 133
 134 AC_MSG_CHECKING([for default auto-load safe-path])
 135 AC_ARG_WITH(auto-load-safe-path,
 136 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 137   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 138 AS_HELP_STRING([--without-auto-load-safe-path],
 139                [do not restrict auto-loaded files locations]),
 140     [if test "$with_auto_load_safe_path" = "no"; then
 141      with_auto_load_safe_path="/"
 142      fi],
 143 [with_auto_load_safe_path="$with_auto_load_dir"])
 144 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 145 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 146               [Directories safe to hold auto-loaded files.])
 147 AC_MSG_RESULT([$with_auto_load_safe_path])
 148
 149 AC_CONFIG_SUBDIRS(testsuite)
 150
 151 # Check whether to support alternative target configurations
 152 AC_ARG_ENABLE(targets,
 153 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 154 [case "${enableval}" in
 155   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 156             ;;
 157   no)       enable_targets= ;;
 158   *)        enable_targets=$enableval ;;
 159 esac])
 160
 161 # Check whether to enable 64-bit support on 32-bit hosts
 162 AC_ARG_ENABLE(64-bit-bfd,
 163 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 164 [case "${enableval}" in
 165   yes)  want64=true  ;;
 166   no)   want64=false ;;
 167   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 168 esac],[want64=false])dnl
 169
 170 # Provide defaults for some variables set by the per-host and per-target
 171 # configuration.
 172 gdb_host_obs=posix-hdep.o
 173
 174 if test "${target}" = "${host}"; then
 175   gdb_native=yes
 176 else
 177   gdb_native=no
 178 fi
 179
 180 . $srcdir/configure.host
 181
 182 # Accumulate some settings from configure.tgt over all enabled targets
 183
 184 TARGET_OBS=
 185 all_targets=
 186 HAVE_NATIVE_GCORE_TARGET=
 187
 188 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 189 do
 190   if test "$targ_alias" = "all"; then
 191     all_targets=true
 192   else
 193     # Canonicalize the secondary target names.
 194     result=`$ac_config_sub $targ_alias 2>/dev/null`
 195     if test -n "$result"; then
 196         targ=$result
 197     else
 198         targ=$targ_alias
 199     fi
 200
 201     . ${srcdir}/configure.tgt
 202
 203     AS_IF([test -z "${gdb_target_obs}"],
 204       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 205
 206     # Target-specific object files
 207     for i in ${gdb_target_obs}; do
 208         case " $TARGET_OBS " in
 209         *" ${i} "*) ;;
 210         *)
 211           TARGET_OBS="$TARGET_OBS ${i}"
 212           ;;
 213         esac
 214     done
 215
 216     # Check whether this target needs 64-bit CORE_ADDR
 217     if test x${want64} = xfalse; then
 218       . ${srcdir}/../bfd/config.bfd
 219     fi
 220
 221     # Check whether this target is native and supports gcore.
 222     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 223        && $gdb_have_gcore; then
 224       HAVE_NATIVE_GCORE_TARGET=1
 225     fi
 226   fi
 227 done
 228
 229 if test x${all_targets} = xtrue; then
 230
 231   # We want all 64-bit targets if we either:
 232   #  - run on a 64-bit host  or
 233   #  - already require 64-bit support for some other target  or
 234   #  - the --enable-64-bit-bfd option was supplied
 235   # Otherwise we only support all 32-bit targets.
 236   #
 237   # NOTE: This test must be in sync with the corresponding
 238   #       tests in BFD!
 239
 240   if test x${want64} = xfalse; then
 241     AC_CHECK_SIZEOF(long)
 242     if test "x${ac_cv_sizeof_long}" = "x8"; then
 243       want64=true
 244     fi
 245   fi
 246   if test x${want64} = xtrue; then
 247     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 248   else
 249     TARGET_OBS='$(ALL_TARGET_OBS)'
 250   fi
 251 fi
 252
 253 AC_SUBST(TARGET_OBS)
 254 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 255
 256 # For other settings, only the main target counts.
 257 gdb_sim=
 258 gdb_osabi=
 259 targ=$target; . ${srcdir}/configure.tgt
 260
 261 # Fetch the default architecture and default target vector from BFD.
 262 targ=$target; . $srcdir/../bfd/config.bfd
 263
 264 # We only want the first architecture, so strip off the others if
 265 # there is more than one.
 266 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 267
 268 if test "x$targ_archs" != x; then
 269   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 270     [Define to BFD's default architecture. ])
 271 fi
 272 if test "x$targ_defvec" != x; then
 273   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 274     [Define to BFD's default target vector. ])
 275 fi
 276
 277 # Enable MI.
 278 AC_ARG_ENABLE(gdbmi,
 279 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 280   [case $enableval in
 281     yes | no)
 282       ;;
 283     *)
 284       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 285   esac],
 286   [enable_gdbmi=yes])
 287 if test x"$enable_gdbmi" = xyes; then
 288   if test -d "$srcdir/mi"; then
 289     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 290     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 291     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 292     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 293   fi
 294 fi
 295
 296 # Enable TUI.
 297 AC_ARG_ENABLE(tui,
 298 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 299   [case $enableval in
 300     yes | no | auto)
 301       ;;
 302     *)
 303       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 304   esac],enable_tui=auto)
 305
 306 # Enable gdbtk.
 307 AC_ARG_ENABLE(gdbtk,
 308 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 309   [case $enableval in
 310     yes | no)
 311       ;;
 312     *)
 313       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 314   esac],
 315   [if test -d "$srcdir/gdbtk"; then
 316     enable_gdbtk=yes
 317   else
 318     enable_gdbtk=no
 319   fi])
 320 # We unconditionally disable gdbtk tests on selected platforms.
 321 case $host_os in
 322   go32* | windows*)
 323     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 324     enable_gdbtk=no ;;
 325 esac
 326
 327 # Handle optional debuginfod support
 328 AC_DEBUGINFOD
 329
 330 # Libunwind support for ia64.
 331 AC_ARG_WITH(libunwind-ia64,
 332 AS_HELP_STRING([--with-libunwind-ia64],
 333                [use libunwind frame unwinding for ia64 targets]),,
 334             [with_libunwind_ia64=auto])
 335
 336 # Backward compatibility option.
 337 if test "${with_libunwind+set}" = set; then
 338   if test x"$with_libunwind_ia64" != xauto; then
 339     AC_MSG_ERROR(
 340       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 341   fi
 342   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 343   with_libunwind_ia64="$with_libunwind"
 344 fi
 345
 346 case "$with_libunwind_ia64" in
 347   yes | no)
 348     ;;
 349   auto)
 350     AC_CHECK_HEADERS(libunwind-ia64.h)
 351     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 352     ;;
 353   *)
 354     AC_MSG_ERROR(
 355       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 356     ;;
 357 esac
 358
 359 if test x"$with_libunwind_ia64" = xyes; then
 360   AC_CHECK_HEADERS(libunwind-ia64.h)
 361   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 362     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 363   fi
 364   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 365   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 366   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 367 fi
 368
 369 opt_curses=no
 370 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 371
 372 prefer_curses=no
 373 if test "$opt_curses" = "yes"; then
 374   prefer_curses=yes
 375 fi
 376
 377 # Profiling support.
 378 AC_ARG_ENABLE(profiling,
 379 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 380   [case $enableval in
 381     yes | no)
 382       ;;
 383     *)
 384       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 385   esac],
 386  [enable_profiling=no])
 387
 388 AC_CHECK_FUNCS(monstartup _mcleanup)
 389 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 390 [AC_TRY_LINK(
 391 [#include <stdlib.h>
 392 extern char _etext;
 393 ],
 394 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 395 if test "$ac_cv_var__etext" = yes; then
 396   AC_DEFINE(HAVE__ETEXT, 1,
 397             [Define to 1 if your system has the _etext variable. ])
 398 fi
 399 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 400 [AC_TRY_LINK(
 401 [#include <stdlib.h>
 402 extern char etext;
 403 ],
 404 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 405 if test "$ac_cv_var_etext" = yes; then
 406   AC_DEFINE(HAVE_ETEXT, 1,
 407             [Define to 1 if your system has the etext variable. ])
 408 fi
 409 if test "$enable_profiling" = yes ; then
 410   if test "$ac_cv_func_monstartup" = no || test "$ac_cv_func__mcleanup" = no; then
 411     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 412   fi
 413   PROFILE_CFLAGS=-pg
 414   OLD_CFLAGS="$CFLAGS"
 415   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 416
 417   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 418     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 419      ac_cv_cc_supports_pg=no)])
 420
 421   if test "$ac_cv_cc_supports_pg" = no; then
 422     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 423   fi
 424
 425   CFLAGS="$OLD_CFLAGS"
 426 fi
 427
 428 CODESIGN_CERT=
 429 AC_ARG_ENABLE([codesign],
 430   AS_HELP_STRING([--enable-codesign=CERT],
 431                  [sign gdb with 'codesign -s CERT']),
 432   [CODESIGN_CERT=$enableval])
 433 AC_SUBST([CODESIGN_CERT])
 434
 435 ACX_PKGVERSION([GDB])
 436 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 437 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 438 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 439
 440 # --------------------- #
 441 # Checks for programs.  #
 442 # --------------------- #
 443
 444 AC_PROG_AWK
 445 AC_PROG_INSTALL
 446 AC_PROG_LN_S
 447 AC_PROG_RANLIB
 448 AC_PROG_YACC
 449
 450 AC_CHECK_TOOL(AR, ar)
 451 AC_CHECK_TOOL(DLLTOOL, dlltool)
 452 AC_CHECK_TOOL(WINDRES, windres)
 453
 454 case $host_os in
 455   gnu*)
 456     # Needed for GNU Hurd hosts.
 457     AC_CHECK_TOOL(MIG, mig)
 458     if test x"$MIG" = x; then
 459       AC_MSG_ERROR([MIG not found but required for $host hosts])
 460     fi
 461     ;;
 462 esac
 463
 464 # ---------------------- #
 465 # Checks for libraries.  #
 466 # ---------------------- #
 467
 468 # We might need to link with -lm; most simulators need it.
 469 AC_CHECK_LIB(m, main)
 470
 471 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 472 AC_SEARCH_LIBS(gethostbyname, nsl)
 473
 474 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 475 AC_SEARCH_LIBS(socketpair, socket)
 476
 477 # Link in zlib if we can.  This allows us to read compressed debug sections.
 478 AM_ZLIB
 479
 480 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 481 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 482 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 483   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 484             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 485
 486 AM_ICONV
 487
 488 # GDB may fork/exec the iconv program to get the list of supported character
 489 # sets.  Allow the user to specify where to find it.
 490 # There are several factors affecting the choice of option name:
 491 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 492 #   the build-time location of libiconv files.
 493 # - The program we need to find is iconv, which comes with glibc.  The user
 494 #   doesn't necessarily have libiconv installed.  Therefore naming this
 495 #   --with-libiconv-foo feels wrong.
 496 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 497 #   defined to work on directories not files (though it really doesn't know
 498 #   the difference).
 499 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 500 #   with --with-libiconv-prefix.
 501 # Putting these together is why the option name is --with-iconv-bin.
 502
 503 AC_ARG_WITH(iconv-bin,
 504 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 505 [iconv_bin="${withval}"
 506  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 507                     [Path of directory of iconv program.])
 508  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 509 ])
 510
 511 # For the TUI, we need enhanced curses functionality.
 512 if test x"$enable_tui" != xno; then
 513   prefer_curses=yes
 514 fi
 515
 516 curses_found=no
 517 if test x"$prefer_curses" = xyes; then
 518   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 519   # curses library because the latter might not provide all the
 520   # functionality we need.  However, this leads to problems on systems
 521   # where the linker searches /usr/local/lib, but the compiler doesn't
 522   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 523   # default installation of ncurses on alpha*-dec-osf* will lead to such
 524   # a situation.
 525   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 526
 527   if test "$ac_cv_search_waddstr" != no; then
 528     curses_found=yes
 529   fi
 530 fi
 531
 532 # Check whether we should enable the TUI, but only do so if we really
 533 # can.
 534 if test x"$enable_tui" != xno; then
 535   if test -d "$srcdir/tui"; then
 536     if test "$curses_found" != no; then
 537       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 538       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 539       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 540       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 541     else
 542       if test x"$enable_tui" = xyes; then
 543         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 544       else
 545         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 546       fi
 547     fi
 548   fi
 549 fi
 550
 551 # Since GDB uses Readline, we need termcap functionality.  In many
 552 # cases this will be provided by the curses library, but some systems
 553 # have a separate termcap library, or no curses library at all.
 554
 555 case $host_os in
 556   cygwin*)
 557     if test -d "$srcdir/libtermcap"; then
 558       LIBS="../libtermcap/libtermcap.a $LIBS"
 559       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 560     fi ;;
 561   go32* | *djgpp*)
 562     ac_cv_search_tgetent="none required"
 563     ;;
 564 esac
 565
 566 # These are the libraries checked by Readline.
 567 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 568
 569 if test "$ac_cv_search_tgetent" = no; then
 570   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 571 fi
 572
 573 AC_ARG_WITH([system-readline],
 574   [AS_HELP_STRING([--with-system-readline],
 575                   [use installed readline library])])
 576
 577 if test "$with_system_readline" = yes; then
 578    AC_CACHE_CHECK([whether system readline is new enough],
 579      [gdb_cv_readline_ok],
 580      [AC_TRY_COMPILE(
 581        [#include <stdio.h>
 582 #include <readline/readline.h>],
 583        [#if RL_VERSION_MAJOR < 7
 584 # error "readline version 7 required"
 585 #endif],
 586     gdb_cv_readline_ok=yes,
 587     gdb_cv_readline_ok=no)])
 588   if test "$gdb_cv_readline_ok" != yes; then
 589     AC_MSG_ERROR([system readline is not new enough])
 590   fi
 591
 592   READLINE=-lreadline
 593   READLINE_DEPS=
 594   READLINE_CFLAGS=
 595   READLINE_TEXI_INCFLAG=
 596 else
 597   READLINE='$(READLINE_DIR)/libreadline.a'
 598   READLINE_DEPS='$(READLINE)'
 599   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 600   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 601 fi
 602 AC_SUBST(READLINE)
 603 AC_SUBST(READLINE_DEPS)
 604 AC_SUBST(READLINE_CFLAGS)
 605 AC_SUBST(READLINE_TEXI_INCFLAG)
 606
 607 # Generate jit-reader.h
 608
 609 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 610 TARGET_PTR=
 611
 612 AC_CHECK_SIZEOF(unsigned long long)
 613 AC_CHECK_SIZEOF(unsigned long)
 614 AC_CHECK_SIZEOF(unsigned __int128)
 615
 616 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 617   TARGET_PTR="unsigned long"
 618 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 619   TARGET_PTR="unsigned long long"
 620 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 621   TARGET_PTR="unsigned __int128"
 622 else
 623   TARGET_PTR="unsigned long"
 624 fi
 625
 626 AC_SUBST(TARGET_PTR)
 627 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 628
 629 AC_SEARCH_LIBS(dlopen, dl)
 630
 631 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 632                 [directory to load the JIT readers from],
 633                 [${libdir}/gdb])
 634
 635 AC_ARG_WITH(expat,
 636   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 637   [], [with_expat=auto])
 638 AC_MSG_CHECKING([whether to use expat])
 639 AC_MSG_RESULT([$with_expat])
 640
 641 if test "${with_expat}" = no; then
 642   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 643   HAVE_LIBEXPAT=no
 644 else
 645   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 646                         [XML_Parser p = XML_ParserCreate (0);])
 647   if test "$HAVE_LIBEXPAT" != yes; then
 648     if test "$with_expat" = yes; then
 649       AC_MSG_ERROR([expat is missing or unusable])
 650     else
 651       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 652     fi
 653   else
 654     save_LIBS=$LIBS
 655     LIBS="$LIBS $LIBEXPAT"
 656     AC_CHECK_FUNCS(XML_StopParser)
 657     LIBS=$save_LIBS
 658   fi
 659 fi
 660
 661 AC_ARG_WITH(mpfr,
 662   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 663   [], [with_mpfr=auto])
 664 AC_MSG_CHECKING([whether to use MPFR])
 665 AC_MSG_RESULT([$with_mpfr])
 666
 667 if test "${with_mpfr}" = no; then
 668   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 669   HAVE_LIBMPFR=no
 670 else
 671   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 672                         [mpfr_exp_t exp; mpfr_t x;
 673                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 674   if test "$HAVE_LIBMPFR" != yes; then
 675     if test "$with_mpfr" = yes; then
 676       AC_MSG_ERROR([MPFR is missing or unusable])
 677     else
 678       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 679     fi
 680   fi
 681 fi
 682
 683 # --------------------- #
 684 # Check for libpython.  #
 685 # --------------------- #
 686
 687 dnl Utility to simplify finding libpython.
 688 dnl $1 = the shell variable to assign the result to
 689 dnl      If libpython is found we store $version here.
 690 dnl $2 = additional flags to add to CPPFLAGS
 691 dnl $3 = additional flags to add to LIBS
 692
 693 AC_DEFUN([AC_TRY_LIBPYTHON],
 694 [
 695   define([have_libpython_var],$1)
 696   new_CPPFLAGS=$2
 697   new_LIBS=$3
 698   AC_MSG_CHECKING([for python])
 699   save_CPPFLAGS=$CPPFLAGS
 700   save_LIBS=$LIBS
 701   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 702   LIBS="$new_LIBS $LIBS"
 703   found_usable_python=no
 704   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 705                                  [[Py_Initialize ();]])],
 706                  [have_libpython_var=yes
 707                   found_usable_python=yes
 708                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 709                   PYTHON_LIBS=$new_LIBS])
 710   CPPFLAGS=$save_CPPFLAGS
 711   LIBS=$save_LIBS
 712   AC_MSG_RESULT([${found_usable_python}])
 713 ])
 714
 715 dnl There are several different values for --with-python:
 716 dnl
 717 dnl no -   Don't include python support.
 718 dnl yes -  Include python support, error if it's missing.
 719 dnl        If we find python in $PATH, use it to fetch configure options,
 720 dnl        otherwise assume the compiler can find it with no help from us.
 721 dnl        Python 2.7 and 2.6 are tried in turn.
 722 dnl auto - Same as "yes", but if python is missing from the system,
 723 dnl        fall back to "no".
 724 dnl /path/to/python/exec-prefix -
 725 dnl        Use the python located in this directory.
 726 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 727 dnl        the compilation parameters.  Otherwise use
 728 dnl        -I/path/to/python/exec-prefix/include,
 729 dnl        -L/path/to/python/exec-prefix/lib.
 730 dnl        Python 2.7 and 2.6 are tried in turn.
 731 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 732 dnl        but is deprecated.
 733 dnl /path/to/python/executable -
 734 dnl        Run python-config.py with this version of python to fetch the
 735 dnl        compilation parameters.
 736 dnl        NOTE: This needn't be the real python executable.
 737 dnl        In a cross-compilation scenario (build != host), this could be
 738 dnl        a shell script that provides what python-config.py provides for
 739 dnl        --ldflags, --includes, --exec-prefix.
 740 dnl python-executable -
 741 dnl        Find python-executable in $PATH, and then handle the same as
 742 dnl        /path/to/python/executable.
 743 dnl
 744 dnl If a python program is specified, it is used to run python-config.py and
 745 dnl is passed --ldflags, --includes, --exec-prefix.
 746
 747 AC_ARG_WITH(python,
 748   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 749   [], [with_python=auto])
 750 AC_MSG_CHECKING([whether to use python])
 751 AC_MSG_RESULT([$with_python])
 752
 753 if test "${with_python}" = no; then
 754   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 755   have_libpython=no
 756 else
 757   case "${with_python}" in
 758   [[\\/]]* | ?:[[\\/]]*)
 759     if test -d "${with_python}"; then
 760       # Assume the python binary is ${with_python}/bin/python.
 761       python_prog="${with_python}/bin/python"
 762       python_prefix=
 763       # If python does not exit ${with_python}/bin, then try in
 764       # ${with_python}.  On Windows/MinGW, this is where the Python
 765       # executable is.
 766       if test ! -x "${python_prog}"; then
 767         python_prog="${with_python}/python"
 768         python_prefix=
 769       fi
 770       if test ! -x "${python_prog}"; then
 771         # Fall back to gdb 7.0/7.1 behaviour.
 772         python_prog=missing
 773         python_prefix=${with_python}
 774       fi
 775     elif test -x "${with_python}"; then
 776       # While we can't run python compiled for $host (unless host == build),
 777       # the user could write a script that provides the needed information,
 778       # so we support that.
 779       python_prog=${with_python}
 780       python_prefix=
 781     else
 782       AC_ERROR(invalid value for --with-python)
 783     fi
 784     ;;
 785   */*)
 786     # Disallow --with-python=foo/bar.
 787     AC_ERROR(invalid value for --with-python)
 788     ;;
 789   *)
 790     # The user has either specified auto, yes, or the name of the python
 791     # program assumed to be in $PATH.
 792     python_prefix=
 793     case "${with_python}" in
 794     yes | auto)
 795       if test "${build}" = "${host}"; then
 796         AC_PATH_PROG(python_prog_path, python, missing)
 797         if test "${python_prog_path}" = missing; then
 798           python_prog=missing
 799         else
 800           python_prog=${python_prog_path}
 801         fi
 802       else
 803         # Not much we can do except assume the cross-compiler will find the
 804         # right files.
 805         python_prog=missing
 806       fi
 807       ;;
 808     *)
 809       # While we can't run python compiled for $host (unless host == build),
 810       # the user could write a script that provides the needed information,
 811       # so we support that.
 812       python_prog="${with_python}"
 813       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 814       if test "${python_prog_path}" = missing; then
 815         AC_ERROR(unable to find python program ${python_prog})
 816       fi
 817       ;;
 818     esac
 819   esac
 820
 821   if test "${python_prog}" != missing; then
 822     # We have a python program to use, but it may be too old.
 823     # Don't flag an error for --with-python=auto (the default).
 824     have_python_config=yes
 825     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 826     if test $? != 0; then
 827       have_python_config=failed
 828       if test "${with_python}" != auto; then
 829         AC_ERROR(failure running python-config --includes)
 830       fi
 831     fi
 832     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 833     if test $? != 0; then
 834       have_python_config=failed
 835       if test "${with_python}" != auto; then
 836         AC_ERROR(failure running python-config --ldflags)
 837       fi
 838     fi
 839     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 840     if test $? != 0; then
 841       have_python_config=failed
 842       if test "${with_python}" != auto; then
 843         AC_ERROR(failure running python-config --exec-prefix)
 844       fi
 845     fi
 846   else
 847     # We do not have a python executable we can use to determine where
 848     # to find the Python headers and libs.  We cannot guess the include
 849     # path from the python_prefix either, because that include path
 850     # depends on the Python version.  So, there is nothing much we can
 851     # do except assume that the compiler will be able to find those files.
 852     python_includes=
 853     python_libs=
 854     have_python_config=no
 855   fi
 856
 857   # If we have python-config, only try the configuration it provides.
 858   # Otherwise fallback on the old way of trying different versions of
 859   # python in turn.
 860
 861   have_libpython=no
 862   if test "${have_python_config}" = yes; then
 863     AC_TRY_LIBPYTHON(have_libpython,
 864                      ${python_includes}, ${python_libs})
 865   elif test "${have_python_config}" != failed; then
 866     if test "${have_libpython}" = no; then
 867       AC_TRY_LIBPYTHON(have_libpython,
 868                        ${python_includes}, "-lpython2.7 ${python_libs}")
 869     fi
 870     if test "${have_libpython}" = no; then
 871       AC_TRY_LIBPYTHON(have_libpython,
 872                        ${python_includes}, "-lpython2.6 ${python_libs}")
 873     fi
 874   fi
 875
 876   if test "${have_libpython}" = no; then
 877     case "${with_python}" in
 878     yes)
 879       AC_MSG_ERROR([python is missing or unusable])
 880       ;;
 881     auto)
 882       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 883       ;;
 884     *)
 885       AC_MSG_ERROR([no usable python found at ${with_python}])
 886       ;;
 887     esac
 888   else
 889     if test -n "${python_prefix}"; then
 890       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 891                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 892       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 893     fi
 894   fi
 895 fi
 896
 897 dnl Use --with-python-libdir to control where GDB looks for the Python
 898 dnl libraries.
 899 dnl
 900 dnl If this is not given then the default will be based on the value
 901 dnl passed to --with-python, which is in the python_prefix variable.
 902 dnl If the --with-python option wasn't given then the default value in
 903 dnl python_prefix is based on running the 'gdb/python/python-config
 904 dnl --exec-prefix' script.
 905 AC_ARG_WITH(python-libdir,
 906   AS_HELP_STRING([--with-python-libdir@<:@=DIR@:>@], [search for python's libraries in DIR]),
 907   [],[
 908     # If no python libdir is specified then select one based on
 909     # python's prefix path.
 910     if test -n "${python_prefix}"; then
 911       with_python_libdir=${python_prefix}/lib
 912     fi
 913   ])
 914
 915 if test "${have_libpython}" != no; then
 916   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 917   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 918   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 919   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 920   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 921   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 922
 923   if test -n "${with_python_libdir}"; then
 924     AC_DEFINE_UNQUOTED(WITH_PYTHON_LIBDIR, "${with_python_libdir}",
 925                        [Directory containing Python's standard libraries from --with-python-libdir.])
 926     GDB_AC_DEFINE_RELOCATABLE(PYTHON_LIBDIR, [python lib], ${with_python_libdir})
 927   fi
 928
 929   # Flags needed to compile Python code (taken from python-config --cflags).
 930   # We cannot call python-config directly because it will output whatever was
 931   # used when compiling the Python interpreter itself, including flags which
 932   # would make the python-related objects be compiled differently from the
 933   # rest of GDB (e.g., -O2 and -fPIC).
 934   if test "${GCC}" = yes; then
 935     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 936     # Python headers recommend -DNDEBUG, but it's unclear if that just
 937     # refers to building Python itself.  In release mode, though, it
 938     # doesn't hurt for the Python code in gdb to follow.
 939     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 940   fi
 941
 942   if test "x${tentative_python_cflags}" != x; then
 943     AC_MSG_CHECKING(compiler flags for python code)
 944     for flag in ${tentative_python_cflags}; do
 945       # Check that the compiler accepts it
 946       saved_CFLAGS="$CFLAGS"
 947       CFLAGS="$CFLAGS $flag"
 948       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 949       CFLAGS="$saved_CFLAGS"
 950     done
 951     AC_MSG_RESULT(${PYTHON_CFLAGS})
 952   fi
 953
 954   # On x64 Windows, Python's include headers, and pyconfig.h in
 955   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 956   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 957   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 958   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 959   # The issue was reported to the Python community, but still isn't
 960   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 961
 962   case "$gdb_host" in
 963     mingw64)
 964            if test "${GCC}" = yes; then
 965              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 966            fi
 967            ;;
 968   esac
 969 else
 970   # Even if Python support is not compiled in, we need to have this file
 971   # included so that the "python" command, et.al., still exists.
 972   CONFIG_OBS="$CONFIG_OBS python/python.o"
 973   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 974 fi
 975
 976 # Work around Python http://bugs.python.org/issue10112.  See also
 977 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 978 # no effect.  Note that the only test after this that uses Python is
 979 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 980 # run without -export-dynamic too.
 981 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 982
 983 AC_SUBST(PYTHON_CFLAGS)
 984 AC_SUBST(PYTHON_CPPFLAGS)
 985 AC_SUBST(PYTHON_LIBS)
 986 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
 987
 988 # -------------------- #
 989 # Check for libguile.  #
 990 # -------------------- #
 991
 992 dnl Utility to simplify finding libguile.
 993 dnl $1 = pkg-config-program
 994 dnl $2 = space-separate list of guile versions to try
 995 dnl $3 = yes|no, indicating whether to flag errors or ignore them
 996 dnl $4 = the shell variable to assign the result to
 997 dnl      If libguile is found we store "yes" here.
 998
 999 AC_DEFUN([AC_TRY_LIBGUILE],
1000 [
1001   pkg_config=$1
1002   guile_version_list=$2
1003   flag_errors=$3
1004   define([have_libguile_var],$4)
1005   found_usable_guile=checking
1006   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1007   for guile_version in ${guile_version_list}; do
1008     ${pkg_config} --exists ${guile_version} 2>/dev/null
1009     if test $? != 0; then
1010       continue
1011     fi
1012     dnl pkg-config says the package exists, so if we get an error now,
1013     dnl that's bad.
1014     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1015     if test $? != 0; then
1016       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1017     fi
1018     new_LIBS=`${pkg_config} --libs ${guile_version}`
1019     if test $? != 0; then
1020       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1021     fi
1022     dnl If we get this far, great.
1023     found_usable_guile=${guile_version}
1024     break
1025   done
1026   if test "${found_usable_guile}" = "checking"; then
1027     if test "${flag_errors}" = "yes"; then
1028       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1029     else
1030       found_usable_guile=no
1031     fi
1032   fi
1033   dnl One final sanity check.
1034   dnl The user could have said --with-guile=python-2.7.
1035   if test "${found_usable_guile}" != no; then
1036     save_CPPFLAGS=$CPPFLAGS
1037     save_LIBS=$LIBS
1038     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1039     LIBS="$LIBS $new_LIBS"
1040     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1041                                    [[scm_init_guile ();]])],
1042                    [have_libguile_var=yes
1043                     GUILE_CPPFLAGS=$new_CPPFLAGS
1044                     GUILE_LIBS=$new_LIBS],
1045                    [found_usable_guile=no])
1046     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1047     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1048       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1049                 [Define if Guile supports manual finalization.])
1050     )
1051     CPPFLAGS=$save_CPPFLAGS
1052     LIBS=$save_LIBS
1053     if test "${found_usable_guile}" = no; then
1054       if test "${flag_errors}" = yes; then
1055         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1056       fi
1057     fi
1058   fi
1059   AC_MSG_RESULT([${found_usable_guile}])
1060 ])
1061
1062 dnl There are several different values for --with-guile:
1063 dnl
1064 dnl no -   Don't include guile support.
1065 dnl yes -  Include guile support, error if it's missing.
1066 dnl        The pkg-config program must be in $PATH.
1067 dnl auto - Same as "yes", but if guile is missing from the system,
1068 dnl        fall back to "no".
1069 dnl guile-version [guile-version-choice-2 ...] -
1070 dnl        A space-separated list of guile package versions to try.
1071 dnl        These are passed to pkg-config as-is.
1072 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1073 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1074 dnl /path/to/pkg-config -
1075 dnl        Use this pkg-config program.
1076 dnl        NOTE: This needn't be the "real" pkg-config program.
1077 dnl        It could be a shell script.  It is invoked as:
1078 dnl        pkg-config --exists $version
1079 dnl        pkg-config --cflags $version
1080 dnl        pkg-config --libs $version
1081 dnl        pkg-config --variable guild $version
1082 dnl        The script will be called with $version having each value in
1083 dnl        $try_guile_versions until --exists indicates success.
1084
1085 AC_ARG_WITH(guile,
1086   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1087   [], [with_guile=auto])
1088 AC_MSG_CHECKING([whether to use guile])
1089 AC_MSG_RESULT([$with_guile])
1090
1091 dnl We check guile with pkg-config.
1092 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1093
1094 try_guile_versions="guile-2.0"
1095 have_libguile=no
1096 case "${with_guile}" in
1097 no)
1098   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1099   ;;
1100 auto)
1101   if test "${pkg_config_prog_path}" = "missing"; then
1102     AC_MSG_WARN([pkg-config not found, guile support disabled])
1103   else
1104     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1105   fi
1106   ;;
1107 yes)
1108   if test "${pkg_config_prog_path}" = "missing"; then
1109     AC_MSG_ERROR([pkg-config not found])
1110   fi
1111   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1112   ;;
1113 [[\\/]]* | ?:[[\\/]]*)
1114   if test -x "${with_guile}"; then
1115     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1116   else
1117     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1118   fi
1119   ;;
1120 "" | */*)
1121   # Disallow --with=guile="" and --with-guile=foo/bar.
1122   AC_MSG_ERROR([invalid value for --with-guile])
1123   ;;
1124 *)
1125   # A space separate list of guile versions to try, in order.
1126   if test "${pkg_config_prog_path}" = "missing"; then
1127     AC_MSG_ERROR([pkg-config not found])
1128   fi
1129   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1130   ;;
1131 esac
1132
1133 if test "${have_libguile}" != no; then
1134   dnl Get the name of the 'guild' program.
1135   case "${with_guile}" in
1136   [[\\/]]* | ?:[[\\/]]*)
1137     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1138     ;;
1139   *)
1140     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1141     ;;
1142   esac
1143
1144   dnl Make sure guild can handle this host.
1145   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1146   dnl If not, disable guile support.
1147   if test "$ac_cv_guild_ok" = no; then
1148     have_libguile=no
1149     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1150   fi
1151 fi
1152
1153 if test "${have_libguile}" != no; then
1154   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1155   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1156   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1157   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1158   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1159   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1160
1161   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1162   save_LIBS="$LIBS"
1163   save_CPPFLAGS="$CPPFLAGS"
1164   LIBS="$GUILE_LIBS"
1165   CPPFLAGS="$GUILE_CPPFLAGS"
1166   AC_CHECK_FUNCS([scm_new_smob])
1167   LIBS="$save_LIBS"
1168   CPPFLAGS="$save_CPPFLAGS"
1169 else
1170   # Even if Guile support is not compiled in, we need to have these files
1171   # included.
1172   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1173   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1174 fi
1175 AC_SUBST(GUILE_CPPFLAGS)
1176 AC_SUBST(GUILE_LIBS)
1177 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1178
1179 # ---------------------------- #
1180 # Check for source highlight.  #
1181 # ---------------------------- #
1182
1183 SRCHIGH_LIBS=
1184 SRCHIGH_CFLAGS=
1185
1186 AC_ARG_ENABLE(source-highlight,
1187   AS_HELP_STRING([--enable-source-highlight],
1188     [enable source-highlight for source listings]),
1189   [case "${enableval}" in
1190   yes)  enable_source_highlight=yes ;;
1191   no)   enable_source_highlight=no  ;;
1192   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1193 esac],
1194 [enable_source_highlight=auto])
1195
1196 if test "${enable_source_highlight}" != "no"; then
1197   AC_MSG_CHECKING([for the source-highlight library])
1198   if test "${pkg_config_prog_path}" = "missing"; then
1199     AC_MSG_RESULT([no - pkg-config not found])
1200     if test "${enable_source_highlight}" = "yes"; then
1201       AC_MSG_ERROR([pkg-config was not found in your system])
1202     fi
1203   else
1204     case "$LDFLAGS" in
1205       *static-libstdc*)
1206         AC_MSG_ERROR([source highlight is incompatible with -static-libstdc++; dnl
1207 either use --disable-source-highlight or dnl
1208 --without-static-standard-libraries])
1209         ;;
1210     esac
1211
1212     if ${pkg_config_prog_path} --exists source-highlight; then
1213       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1214       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1215       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1216                 [Define to 1 if the source-highlight library is available])
1217       AC_MSG_RESULT([yes])
1218     else
1219       AC_MSG_RESULT([no])
1220       if test "${enable_source_highlight}" = "yes"; then
1221         AC_MSG_ERROR([source-highlight was not found in your system])
1222       fi
1223     fi
1224   fi
1225 fi
1226 AC_SUBST(SRCHIGH_LIBS)
1227 AC_SUBST(SRCHIGH_CFLAGS)
1228
1229 # ------------------------- #
1230 # Checks for header files.  #
1231 # ------------------------- #
1232
1233 AC_HEADER_STDC
1234 # elf_hp.h is for HP/UX 64-bit shared library support.
1235 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h \
1236                   thread_db.h \
1237                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1238                   sys/resource.h sys/ptrace.h ptrace.h \
1239                   sys/reg.h sys/debugreg.h sys/select.h \
1240                   termios.h elf_hp.h])
1241 AC_CHECK_HEADERS(sys/user.h, [], [],
1242 [#if HAVE_SYS_PARAM_H
1243 # include <sys/param.h>
1244 #endif
1245 ])
1246
1247 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1248 AC_CHECK_HEADERS(term.h, [], [],
1249 [#if HAVE_CURSES_H
1250 # include <curses.h>
1251 #endif
1252 ])
1253
1254 # ------------------------- #
1255 # Checks for declarations.  #
1256 # ------------------------- #
1257
1258 libiberty_INIT
1259
1260 AC_CHECK_DECLS([snprintf])
1261 AM_LC_MESSAGES
1262
1263 # ------------------ #
1264 # Checks for types.  #
1265 # ------------------ #
1266
1267 AC_CHECK_TYPES(socklen_t, [], [],
1268 [#include <sys/types.h>
1269 #include <sys/socket.h>
1270 ])
1271
1272 # ------------------------------------- #
1273 # Checks for compiler characteristics.  #
1274 # ------------------------------------- #
1275
1276 AC_C_CONST
1277 AC_C_INLINE
1278 AC_C_BIGENDIAN
1279
1280 # ------------------------------ #
1281 # Checks for library functions.  #
1282 # ------------------------------ #
1283
1284 AC_CHECK_FUNCS([getuid getgid \
1285                 pipe poll pread pread64 pwrite resize_term \
1286                 getpgid setsid \
1287                 sigaction sigsetmask socketpair \
1288                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1289                 setrlimit getrlimit posix_madvise waitpid \
1290                 use_default_colors])
1291 AM_LANGINFO_CODESET
1292 GDB_AC_COMMON
1293
1294 # Check the return and argument types of ptrace.
1295 GDB_AC_PTRACE
1296
1297 dnl AC_FUNC_SETPGRP does not work when cross compiling
1298 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1299 if test "$cross_compiling" = no; then
1300   AC_FUNC_SETPGRP
1301 else
1302   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1303     [AC_TRY_COMPILE([
1304 #include <unistd.h>
1305 ], [
1306   if (setpgrp(1,1) == -1)
1307     exit (0);
1308   else
1309     exit (1);
1310 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1311 if test "$ac_cv_func_setpgrp_void" = yes; then
1312   AC_DEFINE(SETPGRP_VOID, 1)
1313 fi
1314 fi
1315
1316 # Assume we'll default to using the included libiberty regex.
1317 gdb_use_included_regex=yes
1318
1319 # However, if the system regex is GNU regex, then default to *not*
1320 # using the included regex.
1321 AC_CACHE_CHECK(
1322   [for GNU regex],
1323   [gdb_cv_have_gnu_regex],
1324   [AC_TRY_COMPILE(
1325     [#include <gnu-versions.h>],
1326     [#define REGEX_INTERFACE_VERSION 1
1327 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1328 # error "Version mismatch"
1329 #endif],
1330     gdb_cv_have_gnu_regex=yes,
1331     gdb_cv_have_gnu_regex=no)])
1332 if test "$gdb_cv_have_gnu_regex" = yes; then
1333   gdb_use_included_regex=no
1334 fi
1335
1336 AC_ARG_WITH(included-regex,
1337   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1338   gdb_with_regex=$withval,
1339   gdb_with_regex=$gdb_use_included_regex)
1340 if test "$gdb_with_regex" = yes; then
1341   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1342     [Define to 1 if the regex included in libiberty should be used.])
1343 fi
1344
1345 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1346 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1347 [#include <sys/param.h>
1348 #include <sys/proc.h>
1349 ])
1350
1351 # See if <sys/lwp.h> defines `struct lwp`.
1352 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1353 [AC_TRY_COMPILE([#include <sys/param.h>
1354 #define _KMEMUSER
1355 #include <sys/lwp.h>], [struct lwp l;],
1356 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1357 if test "$gdb_cv_struct_lwp" = yes; then
1358   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1359             [Define to 1 if your system has struct lwp.])
1360 fi
1361
1362 # See if <machine/reg.h> degines `struct reg'.
1363 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1364 [AC_TRY_COMPILE([#include <sys/types.h>
1365 #include <machine/reg.h>], [struct reg r;],
1366 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1367 if test "$gdb_cv_struct_reg" = yes; then
1368   AC_DEFINE(HAVE_STRUCT_REG, 1,
1369             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1370 fi
1371
1372 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1373 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1374 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1375                  [#include <sys/types.h>
1376 #include <machine/reg.h>])
1377
1378 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1379 # Older amd64 Linux's don't have the fs_base and gs_base members of
1380 # `struct user_regs_struct'.
1381 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1382      [], [], [#include <sys/types.h>
1383 #include <sys/user.h>])
1384
1385 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1386 AC_MSG_CHECKING(for PTRACE_GETREGS)
1387 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1388 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1389                 [PTRACE_GETREGS;],
1390                 [gdb_cv_have_ptrace_getregs=yes],
1391                 [gdb_cv_have_ptrace_getregs=no])])
1392 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1393 if test "$gdb_cv_have_ptrace_getregs" = yes; then
1394   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1395   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1396 fi
1397
1398 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1399 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1400 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1401 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1402                 [PTRACE_GETFPXREGS;],
1403                 [gdb_cv_have_ptrace_getfpxregs=yes],
1404                 [gdb_cv_have_ptrace_getfpxregs=no])])
1405 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1406 if test "$gdb_cv_have_ptrace_getfpxregs" = yes; then
1407   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1408   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1409 fi
1410
1411 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1412 AC_MSG_CHECKING(for PT_GETDBREGS)
1413 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1414 [AC_TRY_COMPILE([#include <sys/types.h>
1415 #include <sys/ptrace.h>],
1416                 [PT_GETDBREGS;],
1417                 [gdb_cv_have_pt_getdbregs=yes],
1418                 [gdb_cv_have_pt_getdbregs=no])])
1419 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1420 if test "$gdb_cv_have_pt_getdbregs" = yes; then
1421   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1422   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1423 fi
1424
1425 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1426 AC_MSG_CHECKING(for PT_GETXMMREGS)
1427 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1428 [AC_TRY_COMPILE([#include <sys/types.h>
1429 #include <sys/ptrace.h>],
1430                 [PT_GETXMMREGS;],
1431                 [gdb_cv_have_pt_getxmmregs=yes],
1432                 [gdb_cv_have_pt_getxmmregs=no])])
1433 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1434 if test "$gdb_cv_have_pt_getxmmregs" = yes; then
1435   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1436   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1437 fi
1438
1439 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1440 # Older FreeBSD versions don't have the pl_tdname member of
1441 # `struct ptrace_lwpinfo'.
1442 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1443                  [#include <sys/ptrace.h>])
1444
1445 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1446 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1447 # FreeBSD 10.3.
1448 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1449                  [#include <sys/ptrace.h>])
1450
1451 # Check if the compiler supports the `long long' type.
1452
1453 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1454                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1455 [[extern long long foo;]],
1456 [[switch (foo & 2) { case 0: return 1; }]])],
1457                                   gdb_cv_c_long_long=yes,
1458                                   gdb_cv_c_long_long=no)])
1459 if test "$gdb_cv_c_long_long" != yes; then
1460   # libdecnumber requires long long.
1461   AC_MSG_ERROR([Compiler must support long long for GDB.])
1462 fi
1463
1464 # Check if the compiler and runtime support printing long longs.
1465
1466 AC_CACHE_CHECK([for long long support in printf],
1467                gdb_cv_printf_has_long_long,
1468                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1469 [[char buf[32];
1470   long long l = 0;
1471   l = (l << 16) + 0x0123;
1472   l = (l << 16) + 0x4567;
1473   l = (l << 16) + 0x89ab;
1474   l = (l << 16) + 0xcdef;
1475   sprintf (buf, "0x%016llx", l);
1476   return (strcmp ("0x0123456789abcdef", buf));]])],
1477                               gdb_cv_printf_has_long_long=yes,
1478                               gdb_cv_printf_has_long_long=no,
1479                               gdb_cv_printf_has_long_long=no)])
1480 if test "$gdb_cv_printf_has_long_long" = yes; then
1481   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1482             [Define to 1 if the "%ll" format works to print long longs.])
1483 fi
1484
1485 # Check if the compiler and runtime support printing decfloats.
1486
1487 AC_CACHE_CHECK([for decfloat support in printf],
1488                gdb_cv_printf_has_decfloat,
1489                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1490 [[char buf[64];
1491   _Decimal32 d32 = 1.2345df;
1492   _Decimal64 d64 = 1.2345dd;
1493   _Decimal128 d128 = 1.2345dl;
1494   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1495   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1496                               gdb_cv_printf_has_decfloat=yes,
1497                               gdb_cv_printf_has_decfloat=no,
1498                               gdb_cv_printf_has_decfloat=no)])
1499 if test "$gdb_cv_printf_has_decfloat" = yes; then
1500   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1501             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1502 fi
1503
1504 # Check if the compiler supports the `long double' type.  We can't use
1505 # AC_C_LONG_DOUBLE because that one does additional checks on the
1506 # constants defined in <float.h> that fail on some systems,
1507 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1508
1509 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1510                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1511                                   gdb_cv_c_long_double=yes,
1512                                   gdb_cv_c_long_double=no)])
1513 if test "$gdb_cv_c_long_double" = yes; then
1514   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1515            [Define to 1 if the compiler supports long double.])
1516 fi
1517
1518 # Check if the compiler and runtime support printing long doubles.
1519
1520 AC_CACHE_CHECK([for long double support in printf],
1521                gdb_cv_printf_has_long_double,
1522                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1523 [[char buf[16];
1524   long double f = 3.141592653;
1525   sprintf (buf, "%Lg", f);
1526   return (strncmp ("3.14159", buf, 7));]])],
1527                               gdb_cv_printf_has_long_double=yes,
1528                               gdb_cv_printf_has_long_double=no,
1529                               gdb_cv_printf_has_long_double=no)])
1530 if test "$gdb_cv_printf_has_long_double" = yes; then
1531   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1532             [Define to 1 if the "%Lg" format works to print long doubles.])
1533 fi
1534
1535 # Check if the compiler and runtime support scanning long doubles.
1536
1537 AC_CACHE_CHECK([for long double support in scanf],
1538                gdb_cv_scanf_has_long_double,
1539                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1540 [[#include <stdio.h>]],
1541 [[char *buf = "3.141592653";
1542   long double f = 0;
1543   sscanf (buf, "%Lg", &f);
1544   return !(f > 3.14159 && f < 3.14160);]])],
1545                               gdb_cv_scanf_has_long_double=yes,
1546                               gdb_cv_scanf_has_long_double=no,
1547                               gdb_cv_scanf_has_long_double=no)])
1548 if test "$gdb_cv_scanf_has_long_double" = yes; then
1549   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1550             [Define to 1 if the "%Lg" format works to scan long doubles.])
1551 fi
1552
1553 case ${host_os} in
1554 aix*)
1555   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1556     SAVE_LDFLAGS=$LDFLAGS
1557
1558     case $GCC in
1559     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1560     *) gdb_cv_bigtoc=-bbigtoc ;;
1561     esac
1562
1563     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1564     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1565     LDFLAGS="${SAVE_LDFLAGS}"
1566   ])
1567   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1568   ;;
1569 esac
1570
1571 AC_MSG_CHECKING(for the dynamic export flag)
1572 dynamic_list=false
1573 if test "${gdb_native}" = yes; then
1574    # The dynamically loaded libthread_db needs access to symbols in the gdb
1575    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1576    # may not be supported there.
1577    old_LDFLAGS="$LDFLAGS"
1578    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1579    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1580    LDFLAGS="$LDFLAGS $RDYNAMIC"
1581    if test "${have_libpython}" = no; then
1582      AC_TRY_LINK([], [], [dynamic_list=true])
1583    else
1584      # Workaround http://bugs.python.org/issue4434 where static
1585      # libpythonX.Y.a would get its symbols required for
1586      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1587      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1588
1589      # Note the workaround for Python
1590      # http://bugs.python.org/issue10112 earlier has removed
1591      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1592      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1593      # always pass.
1594      old_CFLAGS="$CFLAGS"
1595      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1596      old_LIBS="$LIBS"
1597      LIBS="$LIBS $PYTHON_LIBS"
1598      old_CPPFLAGS="$CPPFLAGS"
1599      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1600      AC_RUN_IFELSE(
1601        [AC_LANG_PROGRAM(
1602          [#include "Python.h"],
1603          [int err;
1604           Py_Initialize ();
1605           err = PyRun_SimpleString ("import itertools\n");
1606           Py_Finalize ();
1607           return err == 0 ? 0 : 1;])],
1608        [dynamic_list=true], [], [true])
1609      LIBS="$old_LIBS"
1610      CFLAGS="$old_CFLAGS"
1611      CPPFLAGS="$old_CPPFLAGS"
1612    fi
1613    LDFLAGS="$old_LDFLAGS"
1614 fi
1615 if $dynamic_list; then
1616   found="-Wl,--dynamic-list"
1617   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1618 else
1619   found="-rdynamic"
1620   RDYNAMIC="-rdynamic"
1621 fi
1622 AC_SUBST(RDYNAMIC)
1623 AC_MSG_RESULT($found)
1624
1625 dnl For certain native configurations, we need to check whether thread
1626 dnl support can be built in or not.
1627 dnl
1628 dnl Note that we only want this if we are both native (host == target),
1629 dnl and not doing a canadian cross build (build == host).
1630
1631 if test "${build}" = "${host}" -a "${host}" = "${target}" ; then
1632    case ${host_os} in
1633    aix*)
1634       AC_MSG_CHECKING(for AiX thread debugging library)
1635       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1636                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1637                                    [#ifndef PTHDB_VERSION_3
1638                                     #error
1639                                     #endif],
1640                                    gdb_cv_have_aix_thread_debug=yes,
1641                                    gdb_cv_have_aix_thread_debug=no)])
1642       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1643       if test "$gdb_cv_have_aix_thread_debug" = yes; then
1644          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1645          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1646          LIBS="$LIBS -lpthdebug"
1647
1648          # Older versions of AIX do not provide the declaration for
1649          # the getthrds function (it appears that it was introduced
1650          # with AIX 6.x).
1651          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1652       fi
1653       ;;
1654    esac
1655    AC_SUBST(CONFIG_LDFLAGS)
1656 fi
1657
1658 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1659 dnl other error codes.
1660 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1661    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1662                   gdb_cv_thread_db_h_has_td_notalloc,
1663      AC_TRY_COMPILE(
1664        [#include <thread_db.h>],
1665        [int i = TD_NOTALLOC;],
1666        gdb_cv_thread_db_h_has_td_notalloc=yes,
1667        gdb_cv_thread_db_h_has_td_notalloc=no
1668      )
1669    )
1670    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1671                   gdb_cv_thread_db_h_has_td_version,
1672      AC_TRY_COMPILE(
1673        [#include <thread_db.h>],
1674        [int i = TD_VERSION;],
1675        gdb_cv_thread_db_h_has_td_version=yes,
1676        gdb_cv_thread_db_h_has_td_version=no
1677      )
1678    )
1679    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1680                   gdb_cv_thread_db_h_has_td_notls,
1681      AC_TRY_COMPILE(
1682        [#include <thread_db.h>],
1683        [int i = TD_NOTLS;],
1684        gdb_cv_thread_db_h_has_td_notls=yes,
1685        gdb_cv_thread_db_h_has_td_notls=no
1686      )
1687    )
1688 fi
1689 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1690   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1691             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1692 fi
1693 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1694   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1695             [Define if <thread_db.h> has the TD_VERSION error code.])
1696 fi
1697 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1698   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1699             [Define if <thread_db.h> has the TD_NOTLS error code.])
1700 fi
1701
1702 dnl Set the host's .gdbinit filename.
1703 case $host_os in
1704   go32* | *djgpp*)
1705     gdbinit=gdb.ini
1706     ;;
1707   *)
1708     gdbinit=.gdbinit
1709     ;;
1710 esac
1711 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1712
1713 dnl Handle optional features that can be enabled.
1714
1715 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1716 # except that the argument to --with-sysroot is optional.
1717 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1718 if test "x$with_sysroot" = xyes; then
1719   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1720 fi
1721 AC_ARG_WITH(sysroot,
1722   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1723                  [search for usr/lib et al within DIR]),
1724   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1725 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1726               [search for usr/lib et al within DIR])
1727 AC_SUBST(TARGET_SYSTEM_ROOT)
1728 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1729
1730 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1731     [automatically load a system-wide gdbinit file],
1732     [])
1733 GDB_AC_WITH_DIR(SYSTEM_GDBINIT_DIR, system-gdbinit-dir,
1734     [automatically load system-wide gdbinit files from this directory],
1735     [])
1736
1737 AM_GDB_WARNINGS
1738 AM_GDB_UBSAN
1739
1740 # In the Cygwin environment, we need some additional flags.
1741 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1742 [AC_EGREP_CPP(^lose$, [
1743 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1744 lose
1745 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1746
1747
1748 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1749 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1750 case ${host} in
1751   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1752   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1753   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1754   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1755 esac
1756 AC_SUBST(SER_HARDWIRE)
1757
1758 # libreadline needs libuser32.a in a cygwin environment
1759 WIN32LIBS=
1760 if test x"$gdb_cv_os_cygwin" = xyes; then
1761     WIN32LIBS="-luser32"
1762     case "${target}" in
1763         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1764         ;;
1765     esac
1766 fi
1767
1768 # The ser-tcp.c module requires sockets.
1769 # Note that WIN32APILIBS is set by GDB_AC_COMMON.
1770 WIN32LIBS="$WIN32LIBS $WIN32APILIBS"
1771
1772 # Add ELF support to GDB, but only if BFD includes ELF support.
1773 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1774                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1775 if test "$gdb_cv_var_elf" = yes; then
1776   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1777   AC_DEFINE(HAVE_ELF, 1,
1778             [Define if ELF support should be included.])
1779   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1780   if test "$plugins" = "yes"; then
1781     AC_SEARCH_LIBS(dlopen, dl)
1782   fi
1783 fi
1784
1785 # Add macho support to GDB, but only if BFD includes it.
1786 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1787                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1788 if test "$gdb_cv_var_macho" = yes; then
1789   CONFIG_OBS="$CONFIG_OBS machoread.o"
1790 fi
1791
1792 # Add any host-specific objects to GDB.
1793 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1794
1795 # If building on ELF, look for lzma support for embedded compressed debug info.
1796 if test "$gdb_cv_var_elf" = yes; then
1797   AC_ARG_WITH(lzma,
1798     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1799     [], [with_lzma=auto])
1800   AC_MSG_CHECKING([whether to use lzma])
1801   AC_MSG_RESULT([$with_lzma])
1802
1803   if test "${with_lzma}" != no; then
1804     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1805                           [lzma_index_iter iter;
1806                            lzma_index_iter_init (&iter, 0);
1807                            lzma_mf_is_supported (LZMA_MF_HC3);])
1808     if test "$HAVE_LIBLZMA" != yes; then
1809       if test "$with_lzma" = yes; then
1810         AC_MSG_ERROR([missing liblzma for --with-lzma])
1811       fi
1812     fi
1813   fi
1814 fi
1815
1816 LIBGUI="../libgui/src/libgui.a"
1817 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1818 AC_SUBST(LIBGUI)
1819 AC_SUBST(GUI_CFLAGS_X)
1820
1821 WIN32LDAPP=
1822 AC_SUBST(WIN32LIBS)
1823 AC_SUBST(WIN32LDAPP)
1824
1825 case "${host}" in
1826 *-*-cygwin* | *-*-mingw* )
1827     configdir="win"
1828     ;;
1829 *)
1830     configdir="unix"
1831     ;;
1832 esac
1833
1834 GDBTKLIBS=
1835 if test "${enable_gdbtk}" = "yes"; then
1836
1837     # Gdbtk must have an absolute path to srcdir in order to run
1838     # properly when not installed.
1839     here=`pwd`
1840     cd ${srcdir}
1841     GDBTK_SRC_DIR=`pwd`
1842     cd $here
1843
1844     SC_PATH_TCLCONFIG
1845
1846     # If $no_tk is nonempty, then we can't do Tk, and there is no
1847     # point to doing Tcl.
1848     SC_PATH_TKCONFIG
1849
1850     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1851         SC_LOAD_TCLCONFIG
1852
1853         # Check for in-tree tcl
1854         here=`pwd`
1855         cd ${srcdir}/..
1856         topdir=`pwd`
1857         cd ${here}
1858
1859         intree="no"
1860         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1861           intree="yes"
1862         fi
1863
1864         # Find Tcl private headers
1865         if test x"${intree}" = xno; then
1866           CY_AC_TCL_PRIVATE_HEADERS
1867           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1868           TCL_LIBRARY="${TCL_LIB_SPEC}"
1869           TCL_DEPS=""
1870         else
1871           # If building tcl in the same src tree, private headers
1872           # are not needed, but we need to be sure to use the right
1873           # headers library
1874           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1875           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1876           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1877         fi
1878         AC_SUBST(TCL_INCLUDE)
1879         AC_SUBST(TCL_LIBRARY)
1880         AC_SUBST(TCL_DEPS)
1881
1882         SC_LOAD_TKCONFIG
1883
1884         # Check for in-tree Tk
1885         intree="no"
1886         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1887           intree="yes"
1888         fi
1889
1890         # Find Tk private headers
1891         if test x"${intree}" = xno; then
1892           CY_AC_TK_PRIVATE_HEADERS
1893           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1894           TK_LIBRARY=${TK_LIB_SPEC}
1895           TK_DEPS=""
1896         else
1897           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1898           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1899           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1900         fi
1901         AC_SUBST(TK_INCLUDE)
1902         AC_SUBST(TK_LIBRARY)
1903         AC_SUBST(TK_DEPS)
1904         AC_SUBST(TK_XINCLUDES)
1905
1906         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
1907
1908         # Include some libraries that Tcl and Tk want.
1909         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
1910         # Yes, the ordering seems wrong here.  But it isn't.
1911         # TK_LIBS is the list of libraries that need to be linked
1912         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
1913         # were in LIBS then any link tests after this point would
1914         # try to include things like `$(LIBGUI)', which wouldn't work.
1915         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
1916
1917         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
1918         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
1919         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
1920         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
1921         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
1922         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
1923         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
1924
1925         if test x"$gdb_cv_os_cygwin" = xyes; then
1926           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
1927           WIN32LDAPP="-Wl,--subsystem,console"
1928           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
1929         fi
1930
1931         AC_CONFIG_SUBDIRS(gdbtk)
1932     fi
1933 fi
1934
1935 AC_SUBST(X_CFLAGS)
1936 AC_SUBST(X_LDFLAGS)
1937 AC_SUBST(X_LIBS)
1938 AC_SUBST(GDBTKLIBS)
1939 AC_SUBST(GDBTK_CFLAGS)
1940 AC_SUBST(GDBTK_SRC_DIR)
1941
1942 AC_PATH_X
1943
1944 # Unlike the sim directory, whether a simulator is linked is controlled by
1945 # presence of a gdb_sim definition in the target configure.tgt entry.
1946 # This code just checks for a few cases where we'd like to ignore those
1947 # definitions, even when they're present in the '.mt' file.  These cases
1948 # are when --disable-sim is specified, or if the simulator directory is
1949 # not part of the source tree.
1950 #
1951 AC_ARG_ENABLE(sim,
1952 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
1953 [echo "enable_sim = $enable_sim";
1954  echo "enableval = ${enableval}";
1955  case "${enableval}" in
1956   yes) ignore_sim=false ;;
1957   no)  ignore_sim=true ;;
1958   *)   ignore_sim=false ;;
1959  esac],
1960 [ignore_sim=false])
1961
1962 if test ! -d "${srcdir}/../sim"; then
1963   ignore_sim=true
1964 fi
1965
1966 SIM=
1967 SIM_OBS=
1968 if test "${ignore_sim}" = "false"; then
1969   if test x"${gdb_sim}" != x ; then
1970     SIM="${gdb_sim}"
1971     SIM_OBS="remote-sim.o"
1972     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
1973
1974     # Some tdep code should only be compiled in when the ppc sim is
1975     # built.  PR sim/13418.
1976     case $target in
1977       powerpc*-*-*)
1978         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
1979         ;;
1980     esac
1981   fi
1982 fi
1983 AC_SUBST(SIM)
1984 AC_SUBST(SIM_OBS)
1985
1986 AC_SUBST(ENABLE_CFLAGS)
1987 AC_SUBST(PROFILE_CFLAGS)
1988
1989 AC_SUBST(CONFIG_OBS)
1990 AC_SUBST(CONFIG_DEPS)
1991 AC_SUBST(CONFIG_SRCS)
1992 AC_SUBST(CONFIG_ALL)
1993 AC_SUBST(CONFIG_CLEAN)
1994 AC_SUBST(CONFIG_INSTALL)
1995 AC_SUBST(CONFIG_UNINSTALL)
1996
1997 # List of host floatformats.
1998 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
1999 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2000 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2001
2002 # target_subdir is used by the testsuite to find the target libraries.
2003 target_subdir=
2004 if test "${host}" != "${target}"; then
2005     target_subdir="${target_alias}/"
2006 fi
2007 AC_SUBST(target_subdir)
2008
2009 # Import nat definitions.
2010 nat_makefile_frag=/dev/null
2011 if test "${gdb_native}" = "yes"; then
2012   . ${srcdir}/configure.nat
2013   nativefile=$NAT_FILE
2014 fi
2015
2016 AC_SUBST(NAT_FILE)
2017 AC_SUBST(NATDEPFILES)
2018 AC_SUBST(NAT_CDEPS)
2019 AC_SUBST(LOADLIBES)
2020 AC_SUBST(MH_CFLAGS)
2021 AC_SUBST(XM_CLIBS)
2022 AC_SUBST(NAT_GENERATED_FILES)
2023 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2024 AC_SUBST_FILE(nat_makefile_frag)
2025
2026 if test x"${gdb_osabi}" != x ; then
2027     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2028                        [Define to the default OS ABI for this configuration.])
2029 fi
2030
2031 # Check for babeltrace and babeltrace-ctf
2032 AC_ARG_WITH(babeltrace,
2033   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2034   [], [with_babeltrace=auto])
2035 AC_MSG_CHECKING([whether to use babeltrace])
2036 AC_MSG_RESULT([$with_babeltrace])
2037
2038 if test "x$with_babeltrace" = "xno"; then
2039   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2040 else
2041   # Append -Werror to CFLAGS so that configure can catch the warning
2042   # "assignment from incompatible pointer type", which is related to
2043   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2044   # in GDB, while babeltrace 1.0.3 is broken.
2045   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2046   # safe to save and restore CFLAGS here.
2047   saved_CFLAGS=$CFLAGS
2048   CFLAGS="$CFLAGS -Werror"
2049   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2050                         [#include <babeltrace/babeltrace.h>
2051                          #include <babeltrace/ctf/events.h>
2052                          #include <babeltrace/ctf/iterator.h>],
2053                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2054                         struct bt_ctf_event *event = NULL;
2055                         const struct bt_definition *scope;
2056
2057                         pos->type = BT_SEEK_BEGIN;
2058                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2059                         scope = bt_ctf_get_top_level_scope (event,
2060                                                            BT_STREAM_EVENT_HEADER);
2061                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2062                         ])
2063   CFLAGS=$saved_CFLAGS
2064
2065   if test "$HAVE_LIBBABELTRACE" != yes; then
2066      if test "$with_babeltrace" = yes; then
2067        AC_MSG_ERROR([babeltrace is missing or unusable])
2068      else
2069        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2070      fi
2071   fi
2072 fi
2073
2074 # Check for xxhash
2075 AC_ARG_WITH(xxhash,
2076   AC_HELP_STRING([--with-xxhash], [use libxxhash for hashing (faster) (auto/yes/no)]),
2077   [], [with_xxhash=auto])
2078
2079 if test "x$with_xxhash" != "xno"; then
2080   AC_LIB_HAVE_LINKFLAGS([xxhash], [],
2081                         [#include <xxhash.h>],
2082                         [XXH32("foo", 3, 0);
2083                         ])
2084   if test "$HAVE_LIBXXHASH" != yes; then
2085     if test "$with_xxhash" = yes; then
2086       AC_MSG_ERROR([xxhash is missing or unusable])
2087     fi
2088   fi
2089   if test "x$with_xxhash" = "xauto"; then
2090     with_xxhash="$HAVE_LIBXXHASH"
2091   fi
2092 fi
2093
2094 AC_MSG_CHECKING([whether to use xxhash])
2095 AC_MSG_RESULT([$with_xxhash])
2096
2097 NM_H=
2098 rm -f nm.h
2099 if test "${nativefile}" != ""; then
2100     case "${nativefile}" in
2101       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2102       * ) GDB_NM_FILE="${nativefile}"
2103     esac
2104     AC_CONFIG_LINKS([nm.h:$GDB_NM_FILE], [echo > stamp-nmh],
2105                     [GDB_NM_FILE=$GDB_NM_FILE])
2106     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2107     NM_H=nm.h
2108 fi
2109 AC_SUBST(GDB_NM_FILE)
2110 AC_SUBST(NM_H)
2111
2112 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2113 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2114 if test "x$USE_MAINTAINER_MODE" = xyes; then
2115   if test "${XSLTPROC}" = missing; then
2116     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2117   fi
2118 fi
2119 AC_SUBST(XSLTPROC)
2120
2121 dnl Check for exe extension set on certain hosts (e.g. Win32)
2122 AC_EXEEXT
2123
2124 dnl  Detect the character set used by this host.
2125 dnl  At the moment, we just assume it's UTF-8.
2126 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2127           [Define to be a string naming the default host character set.])
2128
2129 GDB_AC_SELFTEST([
2130   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) selftest-arch.o"
2131   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) selftest-arch.c"
2132 ])
2133
2134 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2135 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2136 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2137 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile])
2138
2139 AC_OUTPUT