gdb/configure.ac

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2019 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 dnl Process this file with autoconf to produce a configure script.
  20
  21 AC_INIT(main.c)
  22 AC_CONFIG_HEADER(config.h:config.in)
  23 AM_MAINTAINER_MODE
  24
  25 # Set the 'development' global.
  26 . $srcdir/../bfd/development.sh
  27
  28 AC_PROG_CC
  29 AC_PROG_CXX
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32 ACX_LARGEFILE
  33 AM_PROG_CC_STDC
  34 AM_PROG_INSTALL_STRIP
  35
  36 AC_CONFIG_AUX_DIR(..)
  37 AC_CANONICAL_SYSTEM
  38 AC_ARG_PROGRAM
  39
  40 # We require a C++11 compiler.  Check if one is available, and if
  41 # necessary, set CXX_DIALECT to some -std=xxx switch.
  42 AX_CXX_COMPILE_STDCXX(11, , mandatory)
  43
  44 # Dependency checking.
  45 ZW_CREATE_DEPDIR
  46 ZW_PROG_COMPILER_DEPENDENCIES([CC])
  47
  48 dnl List of object files and targets accumulated by configure.
  49
  50 CONFIG_OBS=
  51 CONFIG_DEPS=
  52 CONFIG_SRCS=
  53 ENABLE_CFLAGS=
  54
  55 CONFIG_ALL=
  56 CONFIG_CLEAN=
  57 CONFIG_INSTALL=
  58 CONFIG_UNINSTALL=
  59
  60 dnl Set up for gettext.
  61 ZW_GNU_GETTEXT_SISTER_DIR
  62
  63 localedir='${datadir}/locale'
  64 AC_SUBST(localedir)
  65
  66 if test x"$USE_NLS" = xyes; then
  67    CONFIG_ALL="$CONFIG_ALL all-po"
  68    CONFIG_CLEAN="$CONFIG_CLEAN clean-po"
  69    CONFIG_INSTALL="$CONFIG_INSTALL install-po"
  70    CONFIG_UNINSTALL="$CONFIG_UNINSTALL uninstall-po"
  71 fi
  72
  73 PACKAGE=gdb
  74 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package. ])
  75 AC_SUBST(PACKAGE)
  76
  77 # We never need to detect it in this sub-configure.
  78 # But preserve it for config.status --recheck.
  79 AC_ARG_VAR(MAKEINFO,
  80   [Parent configure detects if it is of sufficient version.])
  81 AC_ARG_VAR(MAKEINFOFLAGS,
  82   [Parameters for MAKEINFO.])
  83
  84 MAKEINFO_EXTRA_FLAGS=""
  85 AC_CACHE_CHECK([whether $MAKEINFO supports @click], gdb_cv_have_makeinfo_click,
  86   [echo '@clicksequence{a @click{} b}' >conftest.texinfo
  87   if eval "$MAKEINFO conftest.texinfo >&5 2>&5"; then
  88     gdb_cv_have_makeinfo_click=yes
  89   else
  90     gdb_cv_have_makeinfo_click=no
  91   fi])
  92 if test x"$gdb_cv_have_makeinfo_click" = xyes; then
  93   MAKEINFO_EXTRA_FLAGS="$MAKEINFO_EXTRA_FLAGS -DHAVE_MAKEINFO_CLICK"
  94 fi
  95 AC_SUBST(MAKEINFO_EXTRA_FLAGS)
  96
  97 GDB_AC_WITH_DIR(DEBUGDIR, separate-debug-dir,
  98     [look for global separate debug info in this path @<:@LIBDIR/debug@:>@],
  99     [${libdir}/debug])
 100
 101 # We can't pass paths as command line arguments.
 102 # Mingw32 tries to be clever and will convert the paths for us.
 103 # For example -DBINDIR="/usr/local/bin" passed on the command line may get
 104 # converted to -DBINDIR="E:/msys/mingw32/msys/1.0/local/bin".
 105 # This breaks GDB's relocatable path conversions since paths passed in
 106 # config.h would not get so translated, the path prefixes no longer match.
 107 AC_DEFINE_DIR(BINDIR, bindir, [Directory of programs.])
 108
 109 # GDB's datadir relocation
 110
 111 GDB_AC_WITH_DIR(GDB_DATADIR, gdb-datadir,
 112     [look for global separate data files in this path @<:@DATADIR/gdb@:>@],
 113     [${datadir}/gdb])
 114
 115 AC_ARG_WITH(relocated-sources,
 116 AS_HELP_STRING([--with-relocated-sources=PATH], [automatically relocate this path for source files]),
 117 [reloc_srcdir="${withval}"
 118  AC_DEFINE_DIR(RELOC_SRCDIR, reloc_srcdir,
 119               [Relocated directory for source files. ])
 120 ])
 121
 122 AC_MSG_CHECKING([for default auto-load directory])
 123 AC_ARG_WITH(auto-load-dir,
 124 AS_HELP_STRING([--with-auto-load-dir=PATH],
 125   [directories from which to load auto-loaded scripts @<:@$debugdir:$datadir/auto-load@:>@]),,
 126   [with_auto_load_dir='$debugdir:$datadir/auto-load'])
 127 escape_dir=`echo $with_auto_load_dir | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 128 AC_DEFINE_DIR(AUTO_LOAD_DIR, escape_dir,
 129               [Directories from which to load auto-loaded scripts.])
 130 AC_MSG_RESULT([$with_auto_load_dir])
 131
 132 AC_MSG_CHECKING([for default auto-load safe-path])
 133 AC_ARG_WITH(auto-load-safe-path,
 134 AS_HELP_STRING([--with-auto-load-safe-path=PATH],
 135   [directories safe to hold auto-loaded files @<:@--with-auto-load-dir@:>@])
 136 AS_HELP_STRING([--without-auto-load-safe-path],
 137                [do not restrict auto-loaded files locations]),
 138     [if test "$with_auto_load_safe_path" = "no"; then
 139      with_auto_load_safe_path="/"
 140      fi],
 141 [with_auto_load_safe_path="$with_auto_load_dir"])
 142 escape_dir=`echo $with_auto_load_safe_path | sed -e 's/[[$]]datadir\>/\\\\\\\\\\\\&/g' -e 's/[[$]]debugdir\>/\\\\\\\\\\\\&/g'`
 143 AC_DEFINE_DIR(AUTO_LOAD_SAFE_PATH, escape_dir,
 144               [Directories safe to hold auto-loaded files.])
 145 AC_MSG_RESULT([$with_auto_load_safe_path])
 146
 147 AC_CONFIG_SUBDIRS(testsuite)
 148
 149 # Check whether to support alternative target configurations
 150 AC_ARG_ENABLE(targets,
 151 AS_HELP_STRING([--enable-targets=TARGETS], [alternative target configurations]),
 152 [case "${enableval}" in
 153   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 154             ;;
 155   no)       enable_targets= ;;
 156   *)        enable_targets=$enableval ;;
 157 esac])
 158
 159 # Check whether to enable 64-bit support on 32-bit hosts
 160 AC_ARG_ENABLE(64-bit-bfd,
 161 AS_HELP_STRING([--enable-64-bit-bfd], [64-bit support (on hosts with narrower word sizes)]),
 162 [case "${enableval}" in
 163   yes)  want64=true  ;;
 164   no)   want64=false ;;
 165   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
 166 esac],[want64=false])dnl
 167
 168 # Provide defaults for some variables set by the per-host and per-target
 169 # configuration.
 170 gdb_host_obs=posix-hdep.o
 171
 172 if test "${target}" = "${host}"; then
 173   gdb_native=yes
 174 else
 175   gdb_native=no
 176 fi
 177
 178 . $srcdir/configure.host
 179
 180 # Add in the common host objects.
 181 . $srcdir/gdbsupport/common.host
 182 gdb_host_obs="$gdb_host_obs $common_host_obs"
 183
 184 # Accumulate some settings from configure.tgt over all enabled targets
 185
 186 TARGET_OBS=
 187 all_targets=
 188 HAVE_NATIVE_GCORE_TARGET=
 189
 190 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 191 do
 192   if test "$targ_alias" = "all"; then
 193     all_targets=true
 194   else
 195     # Canonicalize the secondary target names.
 196     result=`$ac_config_sub $targ_alias 2>/dev/null`
 197     if test -n "$result"; then
 198         targ=$result
 199     else
 200         targ=$targ_alias
 201     fi
 202
 203     . ${srcdir}/configure.tgt
 204
 205     AS_IF([test -z "${gdb_target_obs}"],
 206       [AC_MSG_ERROR([configuration ${targ} is unsupported.])])
 207
 208     # Target-specific object files
 209     for i in ${gdb_target_obs}; do
 210         case " $TARGET_OBS " in
 211         *" ${i} "*) ;;
 212         *)
 213           TARGET_OBS="$TARGET_OBS ${i}"
 214           ;;
 215         esac
 216     done
 217
 218     # Check whether this target needs 64-bit CORE_ADDR
 219     if test x${want64} = xfalse; then
 220       . ${srcdir}/../bfd/config.bfd
 221     fi
 222
 223     # Check whether this target is native and supports gcore.
 224     if test $gdb_native = yes -a "$targ_alias" = "$target_alias" \
 225        && $gdb_have_gcore; then
 226       HAVE_NATIVE_GCORE_TARGET=1
 227     fi
 228   fi
 229 done
 230
 231 if test x${all_targets} = xtrue; then
 232
 233   # We want all 64-bit targets if we either:
 234   #  - run on a 64-bit host  or
 235   #  - already require 64-bit support for some other target  or
 236   #  - the --enable-64-bit-bfd option was supplied
 237   # Otherwise we only support all 32-bit targets.
 238   #
 239   # NOTE: This test must be in sync with the corresponding
 240   #       tests in BFD!
 241
 242   if test x${want64} = xfalse; then
 243     AC_CHECK_SIZEOF(long)
 244     if test "x${ac_cv_sizeof_long}" = "x8"; then
 245       want64=true
 246     fi
 247   fi
 248   if test x${want64} = xtrue; then
 249     TARGET_OBS='$(ALL_TARGET_OBS) $(ALL_64_TARGET_OBS)'
 250   else
 251     TARGET_OBS='$(ALL_TARGET_OBS)'
 252   fi
 253 fi
 254
 255 AC_SUBST(TARGET_OBS)
 256 AC_SUBST(HAVE_NATIVE_GCORE_TARGET)
 257
 258 # For other settings, only the main target counts.
 259 gdb_sim=
 260 gdb_osabi=
 261 build_gdbserver=
 262 targ=$target; . ${srcdir}/configure.tgt
 263
 264 # Fetch the default architecture and default target vector from BFD.
 265 targ=$target; . $srcdir/../bfd/config.bfd
 266
 267 # We only want the first architecture, so strip off the others if
 268 # there is more than one.
 269 targ_archs=`echo $targ_archs | sed 's/ .*//'`
 270
 271 if test "x$targ_archs" != x; then
 272   AC_DEFINE_UNQUOTED(DEFAULT_BFD_ARCH, $targ_archs,
 273     [Define to BFD's default architecture. ])
 274 fi
 275 if test "x$targ_defvec" != x; then
 276   AC_DEFINE_UNQUOTED(DEFAULT_BFD_VEC, $targ_defvec,
 277     [Define to BFD's default target vector. ])
 278 fi
 279
 280 # Enable MI.
 281 AC_ARG_ENABLE(gdbmi,
 282 AS_HELP_STRING([--disable-gdbmi], [disable machine-interface (MI)]),
 283   [case $enableval in
 284     yes | no)
 285       ;;
 286     *)
 287       AC_MSG_ERROR([bad value $enableval for --enable-gdbmi]) ;;
 288   esac],
 289   [enable_gdbmi=yes])
 290 if test x"$enable_gdbmi" = xyes; then
 291   if test -d $srcdir/mi; then
 292     CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_MI_OBS)"
 293     CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_MI_DEPS)"
 294     CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_MI_SRCS)"
 295     ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_MI_CFLAGS)"
 296   fi
 297 fi
 298
 299 # Enable TUI.
 300 AC_ARG_ENABLE(tui,
 301 AS_HELP_STRING([--enable-tui], [enable full-screen terminal user interface (TUI)]),
 302   [case $enableval in
 303     yes | no | auto)
 304       ;;
 305     *)
 306       AC_MSG_ERROR([bad value $enableval for --enable-tui]) ;;
 307   esac],enable_tui=auto)
 308
 309 # Enable gdbtk.
 310 AC_ARG_ENABLE(gdbtk,
 311 AS_HELP_STRING([--enable-gdbtk], [enable gdbtk graphical user interface (GUI)]),
 312   [case $enableval in
 313     yes | no)
 314       ;;
 315     *)
 316       AC_MSG_ERROR([bad value $enableval for --enable-gdbtk]) ;;
 317   esac],
 318   [if test -d $srcdir/gdbtk; then
 319     enable_gdbtk=yes
 320   else
 321     enable_gdbtk=no
 322   fi])
 323 # We unconditionally disable gdbtk tests on selected platforms.
 324 case $host_os in
 325   go32* | windows*)
 326     AC_MSG_WARN([gdbtk isn't supported on $host; disabling])
 327     enable_gdbtk=no ;;
 328 esac
 329
 330 # Libunwind support for ia64.
 331
 332 AC_ARG_WITH(libunwind-ia64,
 333 AS_HELP_STRING([--with-libunwind-ia64],
 334                [use libunwind frame unwinding for ia64 targets]),,
 335             [with_libunwind_ia64=auto])
 336
 337 # Backward compatibility option.
 338 if test "${with_libunwind+set}" = set; then
 339   if test x"$with_libunwind_ia64" != xauto; then
 340     AC_MSG_ERROR(
 341       [option --with-libunwind is deprecated, use --with-libunwind-ia64])
 342   fi
 343   AC_MSG_WARN([option --with-libunwind is deprecated, use --with-libunwind-ia64])
 344   with_libunwind_ia64="$with_libunwind"
 345 fi
 346
 347 case "$with_libunwind_ia64" in
 348   yes | no)
 349     ;;
 350   auto)
 351     AC_CHECK_HEADERS(libunwind-ia64.h)
 352     with_libunwind_ia64=$ac_cv_header_libunwind_ia64_h
 353     ;;
 354   *)
 355     AC_MSG_ERROR(
 356       [bad value $with_libunwind_ia64 for GDB --with-libunwind-ia64 option])
 357     ;;
 358 esac
 359
 360 if test x"$with_libunwind_ia64" = xyes; then
 361   AC_CHECK_HEADERS(libunwind-ia64.h)
 362   if test x"$ac_cv_header_libunwind_ia64_h" != xyes; then
 363     AC_MSG_ERROR([GDB option --with-libunwind-ia64 requires libunwind-ia64.h])
 364   fi
 365   CONFIG_OBS="$CONFIG_OBS ia64-libunwind-tdep.o"
 366   CONFIG_DEPS="$CONFIG_DEPS ia64-libunwind-tdep.o"
 367   CONFIG_SRCS="$CONFIG_SRCS ia64-libunwind-tdep.c"
 368 fi
 369
 370 opt_curses=no
 371 AC_ARG_WITH(curses, AS_HELP_STRING([--with-curses], [use the curses library instead of the termcap library]), opt_curses=$withval)
 372
 373 prefer_curses=no
 374 if test "$opt_curses" = "yes"; then
 375   prefer_curses=yes
 376 fi
 377
 378 # Profiling support.
 379 AC_ARG_ENABLE(profiling,
 380 AS_HELP_STRING([--enable-profiling], [enable profiling of GDB]),
 381   [case $enableval in
 382     yes | no)
 383       ;;
 384     *)
 385       AC_MSG_ERROR([bad value $enableval for --enable-profile]) ;;
 386   esac],
 387  [enable_profiling=no])
 388
 389 AC_CHECK_FUNCS(monstartup _mcleanup)
 390 AC_CACHE_CHECK([for _etext], ac_cv_var__etext,
 391 [AC_TRY_LINK(
 392 [#include <stdlib.h>
 393 extern char _etext;
 394 ],
 395 [free (&_etext);], ac_cv_var__etext=yes, ac_cv_var__etext=no)])
 396 if test $ac_cv_var__etext = yes; then
 397   AC_DEFINE(HAVE__ETEXT, 1,
 398             [Define to 1 if your system has the _etext variable. ])
 399 fi
 400 AC_CACHE_CHECK([for etext], ac_cv_var_etext,
 401 [AC_TRY_LINK(
 402 [#include <stdlib.h>
 403 extern char etext;
 404 ],
 405 [free (&etext);], ac_cv_var_etext=yes, ac_cv_var_etext=no)])
 406 if test $ac_cv_var_etext = yes; then
 407   AC_DEFINE(HAVE_ETEXT, 1,
 408             [Define to 1 if your system has the etext variable. ])
 409 fi
 410 if test "$enable_profiling" = yes ; then
 411   if test $ac_cv_func_monstartup = no || test $ac_cv_func__mcleanup = no; then
 412     AC_MSG_ERROR(--enable-profiling requires monstartup and _mcleanup)
 413   fi
 414   PROFILE_CFLAGS=-pg
 415   OLD_CFLAGS="$CFLAGS"
 416   CFLAGS="$CFLAGS $PROFILE_CFLAGS"
 417
 418   AC_CACHE_CHECK([whether $CC supports -pg], ac_cv_cc_supports_pg,
 419     [AC_TRY_COMPILE([], [int x;], ac_cv_cc_supports_pg=yes,
 420      ac_cv_cc_supports_pg=no)])
 421
 422   if test $ac_cv_cc_supports_pg = no; then
 423     AC_MSG_ERROR(--enable-profiling requires a compiler which supports -pg)
 424   fi
 425
 426   CFLAGS="$OLD_CFLAGS"
 427 fi
 428
 429 CODESIGN_CERT=
 430 AC_ARG_ENABLE([codesign],
 431   AS_HELP_STRING([--enable-codesign=CERT],
 432                  [sign gdb with 'codesign -s CERT']),
 433   [CODESIGN_CERT=$enableval])
 434 AC_SUBST([CODESIGN_CERT])
 435
 436 ACX_PKGVERSION([GDB])
 437 ACX_BUGURL([http://www.gnu.org/software/gdb/bugs/])
 438 AC_DEFINE_UNQUOTED([PKGVERSION], ["$PKGVERSION"], [Additional package description])
 439 AC_DEFINE_UNQUOTED([REPORT_BUGS_TO], ["$REPORT_BUGS_TO"], [Bug reporting address])
 440
 441 # --------------------- #
 442 # Checks for programs.  #
 443 # --------------------- #
 444
 445 AC_PROG_AWK
 446 AC_PROG_INSTALL
 447 AC_PROG_LN_S
 448 AC_PROG_RANLIB
 449 AC_PROG_YACC
 450
 451 AC_CHECK_TOOL(AR, ar)
 452 AC_CHECK_TOOL(DLLTOOL, dlltool)
 453 AC_CHECK_TOOL(WINDRES, windres)
 454
 455 case $host_os in
 456   gnu*)
 457     # Needed for GNU Hurd hosts.
 458     AC_CHECK_TOOL(MIG, mig)
 459     if test x"$MIG" = x; then
 460       AC_MSG_ERROR([MIG not found but required for $host hosts])
 461     fi
 462     ;;
 463 esac
 464
 465 # ---------------------- #
 466 # Checks for libraries.  #
 467 # ---------------------- #
 468
 469 # We might need to link with -lm; most simulators need it.
 470 AC_CHECK_LIB(m, main)
 471
 472 # Some systems (e.g. Solaris) have `gethostbyname' in libnsl.
 473 AC_SEARCH_LIBS(gethostbyname, nsl)
 474
 475 # Some systems (e.g. Solaris) have `socketpair' in libsocket.
 476 AC_SEARCH_LIBS(socketpair, socket)
 477
 478 # Link in zlib if we can.  This allows us to read compressed debug sections.
 479 AM_ZLIB
 480
 481 # On FreeBSD we may need libutil for kinfo_getvmmap (used by fbsd-nat.c).
 482 # On GNU/kFreeBSD systems, FreeBSD libutil is renamed to libutil-freebsd.
 483 AC_SEARCH_LIBS(kinfo_getvmmap, util util-freebsd,
 484   [AC_DEFINE(HAVE_KINFO_GETVMMAP, 1,
 485             [Define to 1 if your system has the kinfo_getvmmap function. ])])
 486
 487 # fbsd-nat.c can also use kinfo_getfile.
 488 AC_SEARCH_LIBS(kinfo_getfile, util util-freebsd,
 489   [AC_DEFINE(HAVE_KINFO_GETFILE, 1,
 490             [Define to 1 if your system has the kinfo_getfile function. ])])
 491
 492 AM_ICONV
 493
 494 # GDB may fork/exec the iconv program to get the list of supported character
 495 # sets.  Allow the user to specify where to find it.
 496 # There are several factors affecting the choice of option name:
 497 # - There is already --with-libiconv-prefix but we can't use it, it specifies
 498 #   the build-time location of libiconv files.
 499 # - The program we need to find is iconv, which comes with glibc.  The user
 500 #   doesn't necessarily have libiconv installed.  Therefore naming this
 501 #   --with-libiconv-foo feels wrong.
 502 # - We want the path to be relocatable, but GDB_AC_DEFINE_RELOCATABLE is
 503 #   defined to work on directories not files (though it really doesn't know
 504 #   the difference).
 505 # - Calling this --with-iconv-prefix is perceived to cause too much confusion
 506 #   with --with-libiconv-prefix.
 507 # Putting these together is why the option name is --with-iconv-bin.
 508
 509 AC_ARG_WITH(iconv-bin,
 510 AS_HELP_STRING([--with-iconv-bin=PATH], [specify where to find the iconv program]),
 511 [iconv_bin="${withval}"
 512  AC_DEFINE_UNQUOTED([ICONV_BIN], ["${iconv_bin}"],
 513                     [Path of directory of iconv program.])
 514  GDB_AC_DEFINE_RELOCATABLE(ICONV_BIN, iconv, ${iconv_bin})
 515 ])
 516
 517 # For the TUI, we need enhanced curses functionality.
 518 if test x"$enable_tui" != xno; then
 519   prefer_curses=yes
 520 fi
 521
 522 curses_found=no
 523 if test x"$prefer_curses" = xyes; then
 524   # FIXME: kettenis/20040905: We prefer ncurses over the vendor-supplied
 525   # curses library because the latter might not provide all the
 526   # functionality we need.  However, this leads to problems on systems
 527   # where the linker searches /usr/local/lib, but the compiler doesn't
 528   # search /usr/local/include, if ncurses is installed in /usr/local.  A
 529   # default installation of ncurses on alpha*-dec-osf* will lead to such
 530   # a situation.
 531   AC_SEARCH_LIBS(waddstr, [ncursesw ncurses cursesX curses])
 532
 533   if test "$ac_cv_search_waddstr" != no; then
 534     curses_found=yes
 535   fi
 536 fi
 537
 538 # Check whether we should enable the TUI, but only do so if we really
 539 # can.
 540 if test x"$enable_tui" != xno; then
 541   if test -d $srcdir/tui; then
 542     if test "$curses_found" != no; then
 543       CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_TUI_OBS)"
 544       CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_TUI_DEPS)"
 545       CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_TUI_SRCS)"
 546       ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_TUI_CFLAGS)"
 547     else
 548       if test x"$enable_tui" = xyes; then
 549         AC_MSG_ERROR([no enhanced curses library found; disable TUI])
 550       else
 551         AC_MSG_WARN([no enhanced curses library found; disabling TUI])
 552       fi
 553     fi
 554   fi
 555 fi
 556
 557 # Since GDB uses Readline, we need termcap functionality.  In many
 558 # cases this will be provided by the curses library, but some systems
 559 # have a separate termcap library, or no curses library at all.
 560
 561 case $host_os in
 562   cygwin*)
 563     if test -d $srcdir/libtermcap; then
 564       LIBS="../libtermcap/libtermcap.a $LIBS"
 565       ac_cv_search_tgetent="../libtermcap/libtermcap.a"
 566     fi ;;
 567   go32* | *djgpp*)
 568     ac_cv_search_tgetent="none required"
 569     ;;
 570 esac
 571
 572 # These are the libraries checked by Readline.
 573 AC_SEARCH_LIBS(tgetent, [termcap tinfow tinfo curses ncursesw ncurses])
 574
 575 if test "$ac_cv_search_tgetent" = no; then
 576   CONFIG_OBS="$CONFIG_OBS stub-termcap.o"
 577 fi
 578
 579 AC_ARG_WITH([system-readline],
 580   [AS_HELP_STRING([--with-system-readline],
 581                   [use installed readline library])])
 582
 583 if test "$with_system_readline" = yes; then
 584   READLINE=-lreadline
 585   READLINE_DEPS=
 586   READLINE_CFLAGS=
 587   READLINE_TEXI_INCFLAG=
 588 else
 589   READLINE='$(READLINE_DIR)/libreadline.a'
 590   READLINE_DEPS='$(READLINE)'
 591   READLINE_CFLAGS='-I$(READLINE_SRC)/..'
 592   READLINE_TEXI_INCFLAG='-I $(READLINE_DIR)'
 593 fi
 594 AC_SUBST(READLINE)
 595 AC_SUBST(READLINE_DEPS)
 596 AC_SUBST(READLINE_CFLAGS)
 597 AC_SUBST(READLINE_TEXI_INCFLAG)
 598
 599 # Generate jit-reader.h
 600
 601 # This is typedeffed to GDB_CORE_ADDR in jit-reader.h
 602 TARGET_PTR=
 603
 604 AC_CHECK_SIZEOF(unsigned long long)
 605 AC_CHECK_SIZEOF(unsigned long)
 606 AC_CHECK_SIZEOF(unsigned __int128)
 607
 608 if test "x${ac_cv_sizeof_unsigned_long}" = "x8"; then
 609   TARGET_PTR="unsigned long"
 610 elif test "x${ac_cv_sizeof_unsigned_long_long}" = "x8"; then
 611   TARGET_PTR="unsigned long long"
 612 elif test "x${ac_cv_sizeof_unsigned___int128}" = "x16"; then
 613   TARGET_PTR="unsigned __int128"
 614 else
 615   TARGET_PTR="unsigned long"
 616 fi
 617
 618 AC_SUBST(TARGET_PTR)
 619 AC_CONFIG_FILES([jit-reader.h:jit-reader.in])
 620
 621 AC_SEARCH_LIBS(dlopen, dl)
 622
 623 GDB_AC_WITH_DIR([JIT_READER_DIR], [jit-reader-dir],
 624                 [directory to load the JIT readers from],
 625                 [${libdir}/gdb])
 626
 627 AC_ARG_WITH(expat,
 628   AS_HELP_STRING([--with-expat], [include expat support (auto/yes/no)]),
 629   [], [with_expat=auto])
 630 AC_MSG_CHECKING([whether to use expat])
 631 AC_MSG_RESULT([$with_expat])
 632
 633 if test "${with_expat}" = no; then
 634   AC_MSG_WARN([expat support disabled; some features may be unavailable.])
 635   HAVE_LIBEXPAT=no
 636 else
 637   AC_LIB_HAVE_LINKFLAGS([expat], [], [#include "expat.h"],
 638                         [XML_Parser p = XML_ParserCreate (0);])
 639   if test "$HAVE_LIBEXPAT" != yes; then
 640     if test "$with_expat" = yes; then
 641       AC_MSG_ERROR([expat is missing or unusable])
 642     else
 643       AC_MSG_WARN([expat is missing or unusable; some features may be unavailable.])
 644     fi
 645   else
 646     save_LIBS=$LIBS
 647     LIBS="$LIBS $LIBEXPAT"
 648     AC_CHECK_FUNCS(XML_StopParser)
 649     LIBS=$save_LIBS
 650   fi
 651 fi
 652
 653 AC_ARG_WITH(mpfr,
 654   AS_HELP_STRING([--with-mpfr], [include MPFR support (auto/yes/no)]),
 655   [], [with_mpfr=auto])
 656 AC_MSG_CHECKING([whether to use MPFR])
 657 AC_MSG_RESULT([$with_mpfr])
 658
 659 if test "${with_mpfr}" = no; then
 660   AC_MSG_WARN([MPFR support disabled; some features may be unavailable.])
 661   HAVE_LIBMPFR=no
 662 else
 663   AC_LIB_HAVE_LINKFLAGS([mpfr], [gmp], [#include <mpfr.h>],
 664                         [mpfr_exp_t exp; mpfr_t x;
 665                          mpfr_frexp (&exp, x, x, MPFR_RNDN);])
 666   if test "$HAVE_LIBMPFR" != yes; then
 667     if test "$with_mpfr" = yes; then
 668       AC_MSG_ERROR([MPFR is missing or unusable])
 669     else
 670       AC_MSG_WARN([MPFR is missing or unusable; some features may be unavailable.])
 671     fi
 672   fi
 673 fi
 674
 675 # --------------------- #
 676 # Check for libpython.  #
 677 # --------------------- #
 678
 679 dnl Utility to simplify finding libpython.
 680 dnl $1 = pythonX.Y
 681 dnl $2 = the shell variable to assign the result to
 682 dnl      If libpython is found we store $version here.
 683 dnl $3 = additional flags to add to CPPFLAGS
 684 dnl $4 = additional flags to add to LIBS
 685
 686 AC_DEFUN([AC_TRY_LIBPYTHON],
 687 [
 688   version=$1
 689   define([have_libpython_var],$2)
 690   new_CPPFLAGS=$3
 691   new_LIBS=$4
 692   AC_MSG_CHECKING([for ${version}])
 693   save_CPPFLAGS=$CPPFLAGS
 694   save_LIBS=$LIBS
 695   CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
 696   LIBS="$new_LIBS $LIBS"
 697   found_usable_python=no
 698   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "Python.h"]],
 699                                  [[Py_Initialize ();]])],
 700                  [have_libpython_var=${version}
 701                   found_usable_python=yes
 702                   PYTHON_CPPFLAGS=$new_CPPFLAGS
 703                   PYTHON_LIBS=$new_LIBS])
 704   CPPFLAGS=$save_CPPFLAGS
 705   LIBS=$save_LIBS
 706   AC_MSG_RESULT([${found_usable_python}])
 707 ])
 708
 709 dnl There are several different values for --with-python:
 710 dnl
 711 dnl no -   Don't include python support.
 712 dnl yes -  Include python support, error if it's missing.
 713 dnl        If we find python in $PATH, use it to fetch configure options,
 714 dnl        otherwise assume the compiler can find it with no help from us.
 715 dnl        Python 2.7 and 2.6 are tried in turn.
 716 dnl auto - Same as "yes", but if python is missing from the system,
 717 dnl        fall back to "no".
 718 dnl /path/to/python/exec-prefix -
 719 dnl        Use the python located in this directory.
 720 dnl        If /path/to/python/exec-prefix/bin/python exists, use it to find
 721 dnl        the compilation parameters.  Otherwise use
 722 dnl        -I/path/to/python/exec-prefix/include,
 723 dnl        -L/path/to/python/exec-prefix/lib.
 724 dnl        Python 2.7 and 2.6 are tried in turn.
 725 dnl        NOTE: This case is historical.  It is what was done for 7.0/7.1
 726 dnl        but is deprecated.
 727 dnl /path/to/python/executable -
 728 dnl        Run python-config.py with this version of python to fetch the
 729 dnl        compilation parameters.
 730 dnl        NOTE: This needn't be the real python executable.
 731 dnl        In a cross-compilation scenario (build != host), this could be
 732 dnl        a shell script that provides what python-config.py provides for
 733 dnl        --ldflags, --includes, --exec-prefix.
 734 dnl python-executable -
 735 dnl        Find python-executable in $PATH, and then handle the same as
 736 dnl        /path/to/python/executable.
 737 dnl
 738 dnl If a python program is specified, it is used to run python-config.py and
 739 dnl is passed --ldflags, --includes, --exec-prefix.
 740
 741 AC_ARG_WITH(python,
 742   AS_HELP_STRING([--with-python@<:@=PYTHON@:>@], [include python support (auto/yes/no/<python-program>)]),
 743   [], [with_python=auto])
 744 AC_MSG_CHECKING([whether to use python])
 745 AC_MSG_RESULT([$with_python])
 746
 747 if test "${with_python}" = no; then
 748   AC_MSG_WARN([python support disabled; some features may be unavailable.])
 749   have_libpython=no
 750 else
 751   case "${with_python}" in
 752   [[\\/]]* | ?:[[\\/]]*)
 753     if test -d ${with_python}; then
 754       # Assume the python binary is ${with_python}/bin/python.
 755       python_prog="${with_python}/bin/python"
 756       python_prefix=
 757       # If python does not exit ${with_python}/bin, then try in
 758       # ${with_python}.  On Windows/MinGW, this is where the Python
 759       # executable is.
 760       if test ! -x "${python_prog}"; then
 761         python_prog="${with_python}/python"
 762         python_prefix=
 763       fi
 764       if test ! -x "${python_prog}"; then
 765         # Fall back to gdb 7.0/7.1 behaviour.
 766         python_prog=missing
 767         python_prefix=${with_python}
 768       fi
 769     elif test -x "${with_python}"; then
 770       # While we can't run python compiled for $host (unless host == build),
 771       # the user could write a script that provides the needed information,
 772       # so we support that.
 773       python_prog=${with_python}
 774       python_prefix=
 775     else
 776       AC_ERROR(invalid value for --with-python)
 777     fi
 778     ;;
 779   */*)
 780     # Disallow --with-python=foo/bar.
 781     AC_ERROR(invalid value for --with-python)
 782     ;;
 783   *)
 784     # The user has either specified auto, yes, or the name of the python
 785     # program assumed to be in $PATH.
 786     python_prefix=
 787     case "${with_python}" in
 788     yes | auto)
 789       if test ${build} = ${host}; then
 790         AC_PATH_PROG(python_prog_path, python, missing)
 791         if test "${python_prog_path}" = missing; then
 792           python_prog=missing
 793         else
 794           python_prog=${python_prog_path}
 795         fi
 796       else
 797         # Not much we can do except assume the cross-compiler will find the
 798         # right files.
 799         python_prog=missing
 800       fi
 801       ;;
 802     *)
 803       # While we can't run python compiled for $host (unless host == build),
 804       # the user could write a script that provides the needed information,
 805       # so we support that.
 806       python_prog="${with_python}"
 807       AC_PATH_PROG(python_prog_path, ${python_prog}, missing)
 808       if test "${python_prog_path}" = missing; then
 809         AC_ERROR(unable to find python program ${python_prog})
 810       fi
 811       ;;
 812     esac
 813   esac
 814
 815   if test "${python_prog}" != missing; then
 816     # We have a python program to use, but it may be too old.
 817     # Don't flag an error for --with-python=auto (the default).
 818     have_python_config=yes
 819     python_includes=`${python_prog} ${srcdir}/python/python-config.py --includes`
 820     if test $? != 0; then
 821       have_python_config=failed
 822       if test "${with_python}" != auto; then
 823         AC_ERROR(failure running python-config --includes)
 824       fi
 825     fi
 826     python_libs=`${python_prog} ${srcdir}/python/python-config.py --ldflags`
 827     if test $? != 0; then
 828       have_python_config=failed
 829       if test "${with_python}" != auto; then
 830         AC_ERROR(failure running python-config --ldflags)
 831       fi
 832     fi
 833     python_prefix=`${python_prog} ${srcdir}/python/python-config.py --exec-prefix`
 834     if test $? != 0; then
 835       have_python_config=failed
 836       if test "${with_python}" != auto; then
 837         AC_ERROR(failure running python-config --exec-prefix)
 838       fi
 839     fi
 840   else
 841     # We do not have a python executable we can use to determine where
 842     # to find the Python headers and libs.  We cannot guess the include
 843     # path from the python_prefix either, because that include path
 844     # depends on the Python version.  So, there is nothing much we can
 845     # do except assume that the compiler will be able to find those files.
 846     python_includes=
 847     python_libs=
 848     have_python_config=no
 849   fi
 850
 851   # If we have python-config, only try the configuration it provides.
 852   # Otherwise fallback on the old way of trying different versions of
 853   # python in turn.
 854
 855   have_libpython=no
 856   if test "${have_python_config}" = yes; then
 857     # Determine the Python version by extracting "-lpython<version>"
 858     # part of the python_libs. <version> is usually X.Y with X and Y
 859     # being decimal numbers, but can also be XY (seen on Windows).
 860     #
 861     # The extraction is performed using sed with a regular expression.
 862     # Initially, the regexp used was using the '?' quantifier to make
 863     # the dot in the version number optional.  Unfortunately, this
 864     # does not work with non-GNU versions of sed because, because of
 865     # what looks like a limitation (the '?' quantifier does not work
 866     # with back-references).  We work around this limitation by using
 867     # the '*' quantifier instead.  It means that, in theory, we might
 868     # match unexpected version strings such as "-lpython2..7", but
 869     # this seems unlikely in practice.  And even if that happens,
 870     # an error will be triggered later on, when checking that version
 871     # number.
 872     python_version=`echo " ${python_libs} " \
 873                          | sed -e 's,^.* -l\(python[[0-9]]*[[.]]*[[0-9]]*\).*$,\1,'`
 874     case "${python_version}" in
 875     python*)
 876       AC_TRY_LIBPYTHON(${python_version}, have_libpython,
 877                        ${python_includes}, ${python_libs})
 878       ;;
 879     *)
 880       AC_MSG_ERROR([unable to determine python version from ${python_libs}])
 881       ;;
 882     esac
 883   elif test "${have_python_config}" != failed; then
 884     if test "${have_libpython}" = no; then
 885       AC_TRY_LIBPYTHON(python2.7, have_libpython,
 886                        ${python_includes}, "-lpython2.7 ${python_libs}")
 887     fi
 888     if test "${have_libpython}" = no; then
 889       AC_TRY_LIBPYTHON(python2.6, have_libpython,
 890                        ${python_includes}, "-lpython2.6 ${python_libs}")
 891     fi
 892   fi
 893   if test "${have_libpython}" = python2.7 -o "${have_libpython}" = python27; then
 894     AC_DEFINE(HAVE_LIBPYTHON2_7, 1, [Define if Python 2.7 is being used.])
 895   elif test "${have_libpython}" = python2.6 -o "${have_libpython}" = python26; then
 896     AC_DEFINE(HAVE_LIBPYTHON2_6, 1, [Define if Python 2.6 is being used.])
 897   fi
 898
 899   if test "${have_libpython}" = no; then
 900     case "${with_python}" in
 901     yes)
 902       AC_MSG_ERROR([python is missing or unusable])
 903       ;;
 904     auto)
 905       AC_MSG_WARN([python is missing or unusable; some features may be unavailable.])
 906       ;;
 907     *)
 908       AC_MSG_ERROR([no usable python found at ${with_python}])
 909       ;;
 910     esac
 911   else
 912     if test -n "${python_prefix}"; then
 913       AC_DEFINE_UNQUOTED(WITH_PYTHON_PATH, "${python_prefix}",
 914                          [Define if --with-python provides a path, either directly or via python-config.py --exec-prefix.])
 915       GDB_AC_DEFINE_RELOCATABLE(PYTHON_PATH, python, ${python_prefix})
 916     fi
 917   fi
 918 fi
 919
 920 if test "${have_libpython}" != no; then
 921   AC_DEFINE(HAVE_PYTHON, 1, [Define if Python interpreter is being linked in.])
 922   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_PYTHON_OBS)"
 923   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_PYTHON_DEPS)"
 924   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_PYTHON_SRCS)"
 925   CONFIG_INSTALL="$CONFIG_INSTALL install-python"
 926   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_PYTHON_CFLAGS)"
 927
 928   # Flags needed to compile Python code (taken from python-config --cflags).
 929   # We cannot call python-config directly because it will output whatever was
 930   # used when compiling the Python interpreter itself, including flags which
 931   # would make the python-related objects be compiled differently from the
 932   # rest of GDB (e.g., -O2 and -fPIC).
 933   if test "${GCC}" = yes; then
 934     tentative_python_cflags="-fno-strict-aliasing -fwrapv"
 935     # Python headers recommend -DNDEBUG, but it's unclear if that just
 936     # refers to building Python itself.  In release mode, though, it
 937     # doesn't hurt for the Python code in gdb to follow.
 938     $development || tentative_python_cflags="$tentative_python_cflags -DNDEBUG"
 939   fi
 940
 941   if test "x${tentative_python_cflags}" != x; then
 942     AC_MSG_CHECKING(compiler flags for python code)
 943     for flag in ${tentative_python_cflags}; do
 944       # Check that the compiler accepts it
 945       saved_CFLAGS="$CFLAGS"
 946       CFLAGS="$CFLAGS $flag"
 947       AC_TRY_COMPILE([],[],PYTHON_CFLAGS="${PYTHON_CFLAGS} $flag",)
 948       CFLAGS="$saved_CFLAGS"
 949     done
 950     AC_MSG_RESULT(${PYTHON_CFLAGS})
 951   fi
 952
 953   # On x64 Windows, Python's include headers, and pyconfig.h in
 954   # particular, rely on MS_WIN64 macro to detect that it's a 64bit
 955   # version of Windows.  Unfortunately, MS_WIN64 is only defined if
 956   # _MSC_VER, a Microsoft-specific macro, is defined.  So, when
 957   # building on x64 Windows with GCC, we define MS_WIN64 ourselves.
 958   # The issue was reported to the Python community, but still isn't
 959   # solved as of 2012-10-02 (http://bugs.python.org/issue4709).
 960
 961   case "$gdb_host" in
 962     mingw64)
 963            if test "${GCC}" = yes; then
 964              CPPFLAGS="$CPPFLAGS -DMS_WIN64"
 965            fi
 966            ;;
 967   esac
 968
 969   # Note that "python -m threading" cannot be used to check for
 970   # threading support due to a bug in Python 2.7.3
 971   # (http://bugs.python.org/issue15567).
 972   AC_MSG_CHECKING(whether python supports threads)
 973   saved_CPPFLAGS="${CPPFLAGS}"
 974   CPPFLAGS="${PYTHON_CPPFLAGS}"
 975   # Note that the test is reversed so that python_has_threads=yes on
 976   # unexpected failures.
 977   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
 978 #include <Python.h>
 979 #ifdef WITH_THREAD
 980 # error
 981 #endif
 982   ]])], [python_has_threads=no], [python_has_threads=yes])
 983   AC_MSG_RESULT(${python_has_threads})
 984   CPPFLAGS="${saved_CPPFLAGS}"
 985 else
 986   # Even if Python support is not compiled in, we need to have this file
 987   # included so that the "python" command, et.al., still exists.
 988   CONFIG_OBS="$CONFIG_OBS python/python.o"
 989   CONFIG_SRCS="$CONFIG_SRCS python/python.c"
 990 fi
 991
 992 # Work around Python http://bugs.python.org/issue10112.  See also
 993 # http://bugs.python.org/issue11410, otherwise -Wl,--dynamic-list has
 994 # no effect.  Note that the only test after this that uses Python is
 995 # the -rdynamic/-Wl,--dynamic-list test, and we do want that one to be
 996 # run without -export-dynamic too.
 997 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/-Xlinker -export-dynamic//'`
 998
 999 AC_SUBST(PYTHON_CFLAGS)
1000 AC_SUBST(PYTHON_CPPFLAGS)
1001 AC_SUBST(PYTHON_LIBS)
1002 AM_CONDITIONAL(HAVE_PYTHON, test "${have_libpython}" != no)
1003
1004 # -------------------- #
1005 # Check for libguile.  #
1006 # -------------------- #
1007
1008 dnl Utility to simplify finding libguile.
1009 dnl $1 = pkg-config-program
1010 dnl $2 = space-separate list of guile versions to try
1011 dnl $3 = yes|no, indicating whether to flag errors or ignore them
1012 dnl $4 = the shell variable to assign the result to
1013 dnl      If libguile is found we store "yes" here.
1014
1015 AC_DEFUN([AC_TRY_LIBGUILE],
1016 [
1017   pkg_config=$1
1018   guile_version_list=$2
1019   flag_errors=$3
1020   define([have_libguile_var],$4)
1021   found_usable_guile=checking
1022   AC_MSG_CHECKING([for usable guile from ${pkg_config}])
1023   for guile_version in ${guile_version_list}; do
1024     ${pkg_config} --exists ${guile_version} 2>/dev/null
1025     if test $? != 0; then
1026       continue
1027     fi
1028     dnl pkg-config says the package exists, so if we get an error now,
1029     dnl that's bad.
1030     new_CPPFLAGS=`${pkg_config} --cflags ${guile_version}`
1031     if test $? != 0; then
1032       AC_MSG_ERROR([failure running pkg-config --cflags ${guile_version}])
1033     fi
1034     new_LIBS=`${pkg_config} --libs ${guile_version}`
1035     if test $? != 0; then
1036       AC_MSG_ERROR([failure running pkg-config --libs ${guile_version}])
1037     fi
1038     dnl If we get this far, great.
1039     found_usable_guile=${guile_version}
1040     break
1041   done
1042   if test "${found_usable_guile}" = "checking"; then
1043     if test "${flag_errors}" = "yes"; then
1044       AC_MSG_ERROR([unable to find usable guile version from "${guile_version_list}"])
1045     else
1046       found_usable_guile=no
1047     fi
1048   fi
1049   dnl One final sanity check.
1050   dnl The user could have said --with-guile=python-2.7.
1051   if test "${found_usable_guile}" != no; then
1052     save_CPPFLAGS=$CPPFLAGS
1053     save_LIBS=$LIBS
1054     CPPFLAGS="$CPPFLAGS $new_CPPFLAGS"
1055     LIBS="$LIBS $new_LIBS"
1056     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include "libguile.h"]],
1057                                    [[scm_init_guile ();]])],
1058                    [have_libguile_var=yes
1059                     GUILE_CPPFLAGS=$new_CPPFLAGS
1060                     GUILE_LIBS=$new_LIBS],
1061                    [found_usable_guile=no])
1062     dnl scm_set_automatic_finalization_enabled added in Guile 2.2.
1063     AC_CHECK_FUNC(scm_set_automatic_finalization_enabled,
1064       AC_DEFINE(HAVE_GUILE_MANUAL_FINALIZATION, 1,
1065                 [Define if Guile supports manual finalization.])
1066     )
1067     CPPFLAGS=$save_CPPFLAGS
1068     LIBS=$save_LIBS
1069     if test "${found_usable_guile}" = no; then
1070       if test "${flag_errors}" = yes; then
1071         AC_MSG_FAILURE([linking guile version ${guile_version} test program failed])
1072       fi
1073     fi
1074   fi
1075   AC_MSG_RESULT([${found_usable_guile}])
1076 ])
1077
1078 dnl There are several different values for --with-guile:
1079 dnl
1080 dnl no -   Don't include guile support.
1081 dnl yes -  Include guile support, error if it's missing.
1082 dnl        The pkg-config program must be in $PATH.
1083 dnl auto - Same as "yes", but if guile is missing from the system,
1084 dnl        fall back to "no".
1085 dnl guile-version [guile-version-choice-2 ...] -
1086 dnl        A space-separated list of guile package versions to try.
1087 dnl        These are passed to pkg-config as-is.
1088 dnl        E.g., guile-2.0 or guile-2.2-uninstalled
1089 dnl        This requires making sure PKG_CONFIG_PATH is set appropriately.
1090 dnl /path/to/pkg-config -
1091 dnl        Use this pkg-config program.
1092 dnl        NOTE: This needn't be the "real" pkg-config program.
1093 dnl        It could be a shell script.  It is invoked as:
1094 dnl        pkg-config --exists $version
1095 dnl        pkg-config --cflags $version
1096 dnl        pkg-config --libs $version
1097 dnl        pkg-config --variable guild $version
1098 dnl        The script will be called with $version having each value in
1099 dnl        $try_guile_versions until --exists indicates success.
1100
1101 AC_ARG_WITH(guile,
1102   AS_HELP_STRING([--with-guile@<:@=GUILE@:>@], [include guile support (auto/yes/no/<guile-version>/<pkg-config-program>)]),
1103   [], [with_guile=auto])
1104 AC_MSG_CHECKING([whether to use guile])
1105 AC_MSG_RESULT([$with_guile])
1106
1107 dnl We check guile with pkg-config.
1108 AC_PATH_PROG(pkg_config_prog_path, pkg-config, missing)
1109
1110 try_guile_versions="guile-2.0"
1111 have_libguile=no
1112 case "${with_guile}" in
1113 no)
1114   AC_MSG_WARN([guile support disabled; some features will be unavailable.])
1115   ;;
1116 auto)
1117   if test "${pkg_config_prog_path}" = "missing"; then
1118     AC_MSG_WARN([pkg-config not found, guile support disabled])
1119   else
1120     AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, no, have_libguile)
1121   fi
1122   ;;
1123 yes)
1124   if test "${pkg_config_prog_path}" = "missing"; then
1125     AC_MSG_ERROR([pkg-config not found])
1126   fi
1127   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${try_guile_versions}, yes, have_libguile)
1128   ;;
1129 [[\\/]]* | ?:[[\\/]]*)
1130   if test -x "${with_guile}"; then
1131     AC_TRY_LIBGUILE(${with_guile}, ${try_guile_versions}, yes, have_libguile)
1132   else
1133     AC_MSG_ERROR([Guile config program not executable: ${with_guile}])
1134   fi
1135   ;;
1136 "" | */*)
1137   # Disallow --with=guile="" and --with-guile=foo/bar.
1138   AC_MSG_ERROR([invalid value for --with-guile])
1139   ;;
1140 *)
1141   # A space separate list of guile versions to try, in order.
1142   if test "${pkg_config_prog_path}" = "missing"; then
1143     AC_MSG_ERROR([pkg-config not found])
1144   fi
1145   AC_TRY_LIBGUILE(${pkg_config_prog_path}, ${with_guile}, yes, have_libguile)
1146   ;;
1147 esac
1148
1149 if test "${have_libguile}" != no; then
1150   dnl Get the name of the 'guild' program.
1151   case "${with_guile}" in
1152   [[\\/]]* | ?:[[\\/]]*)
1153     GDB_GUILE_PROGRAM_NAMES(["${with_guile}"], ["${guile_version}"])
1154     ;;
1155   *)
1156     GDB_GUILE_PROGRAM_NAMES(["${pkg_config_prog_path}"], ["${guile_version}"])
1157     ;;
1158   esac
1159
1160   dnl Make sure guild can handle this host.
1161   GDB_TRY_GUILD([$srcdir/guile/lib/gdb/support.scm])
1162   dnl If not, disable guile support.
1163   if test "$ac_cv_guild_ok" = no; then
1164     have_libguile=no
1165     AC_MSG_WARN(disabling guile support, $GUILD fails compiling for $host)
1166   fi
1167 fi
1168
1169 if test "${have_libguile}" != no; then
1170   AC_DEFINE(HAVE_GUILE, 1, [Define if Guile interpreter is being linked in.])
1171   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_GUILE_OBS)"
1172   CONFIG_DEPS="$CONFIG_DEPS \$(SUBDIR_GUILE_DEPS)"
1173   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_GUILE_SRCS)"
1174   CONFIG_INSTALL="$CONFIG_INSTALL install-guile"
1175   ENABLE_CFLAGS="$ENABLE_CFLAGS \$(SUBDIR_GUILE_CFLAGS)"
1176
1177   dnl The 'scm_new_smob' function appeared in Guile 2.0.6.
1178   save_LIBS="$LIBS"
1179   save_CPPFLAGS="$CPPFLAGS"
1180   LIBS="$GUILE_LIBS"
1181   CPPFLAGS="$GUILE_CPPFLAGS"
1182   AC_CHECK_FUNCS([scm_new_smob])
1183   LIBS="$save_LIBS"
1184   CPPFLAGS="$save_CPPFLAGS"
1185 else
1186   # Even if Guile support is not compiled in, we need to have these files
1187   # included.
1188   CONFIG_OBS="$CONFIG_OBS guile/guile.o"
1189   CONFIG_SRCS="$CONFIG_SRCS guile/guile.c"
1190 fi
1191 AC_SUBST(GUILE_CPPFLAGS)
1192 AC_SUBST(GUILE_LIBS)
1193 AM_CONDITIONAL(HAVE_GUILE, test "${have_libguile}" != no)
1194
1195 # ---------------------------- #
1196 # Check for source highlight.  #
1197 # ---------------------------- #
1198
1199 SRCHIGH_LIBS=
1200 SRCHIGH_CFLAGS=
1201
1202 AC_ARG_ENABLE(source-highlight,
1203   AS_HELP_STRING([--enable-source-highlight],
1204     [enable source-highlight for source listings]),
1205   [case "${enableval}" in
1206   yes)  enable_source_highlight=yes ;;
1207   no)   enable_source_highlight=no  ;;
1208   *)    AC_MSG_ERROR(bad value ${enableval} for source-highlight option) ;;
1209 esac],
1210 [enable_source_highlight=auto])
1211
1212 if test "${enable_source_highlight}" != "no"; then
1213   AC_MSG_CHECKING([for the source-highlight library])
1214   if test "${pkg_config_prog_path}" = "missing"; then
1215     AC_MSG_RESULT([no - pkg-config not found])
1216     if test "${enable_source_highlight}" = "yes"; then
1217       AC_MSG_ERROR([pkg-config was not found in your system])
1218     fi
1219   else
1220     if ${pkg_config_prog_path} --exists source-highlight; then
1221       SRCHIGH_CFLAGS=`${pkg_config_prog_path} --cflags source-highlight`
1222       SRCHIGH_LIBS=`${pkg_config_prog_path} --libs source-highlight`
1223       AC_DEFINE([HAVE_SOURCE_HIGHLIGHT], 1,
1224                 [Define to 1 if the source-highlight library is available])
1225       AC_MSG_RESULT([yes])
1226     else
1227       AC_MSG_RESULT([no])
1228       if test "${enable_source_highlight}" = "yes"; then
1229         AC_MSG_ERROR([source-highlight was not found in your system])
1230       fi
1231     fi
1232   fi
1233 fi
1234 AC_SUBST(SRCHIGH_LIBS)
1235 AC_SUBST(SRCHIGH_CFLAGS)
1236
1237 AC_ARG_WITH(intel_pt,
1238   AS_HELP_STRING([--with-intel-pt], [include Intel Processor Trace support (auto/yes/no)]),
1239   [], [with_intel_pt=auto])
1240 AC_MSG_CHECKING([whether to use intel pt])
1241 AC_MSG_RESULT([$with_intel_pt])
1242
1243 if test "${with_intel_pt}" = no; then
1244   AC_MSG_WARN([Intel Processor Trace support disabled; some features may be unavailable.])
1245   HAVE_LIBIPT=no
1246 else
1247   AC_PREPROC_IFELSE([AC_LANG_SOURCE([[
1248 #include <linux/perf_event.h>
1249 #ifndef PERF_ATTR_SIZE_VER5
1250 # error
1251 #endif
1252   ]])], [perf_event=yes], [perf_event=no])
1253   if test "$perf_event" != yes; then
1254     if test "$with_intel_pt" = yes; then
1255       AC_MSG_ERROR([linux/perf_event.h missing or too old])
1256     else
1257       AC_MSG_WARN([linux/perf_event.h missing or too old; some features may be unavailable.])
1258     fi
1259   fi
1260
1261   AC_LIB_HAVE_LINKFLAGS([ipt], [], [#include "intel-pt.h"], [pt_insn_alloc_decoder (0);])
1262   if test "$HAVE_LIBIPT" != yes; then
1263     if test "$with_intel_pt" = yes; then
1264       AC_MSG_ERROR([libipt is missing or unusable])
1265     else
1266       AC_MSG_WARN([libipt is missing or unusable; some features may be unavailable.])
1267     fi
1268   else
1269     save_LIBS=$LIBS
1270     LIBS="$LIBS $LIBIPT"
1271     AC_CHECK_FUNCS(pt_insn_event)
1272     AC_CHECK_MEMBERS([struct pt_insn.enabled, struct pt_insn.resynced], [], [],
1273                      [#include <intel-pt.h>])
1274     LIBS=$save_LIBS
1275   fi
1276 fi
1277
1278 # ------------------------- #
1279 # Checks for header files.  #
1280 # ------------------------- #
1281
1282 AC_HEADER_STDC
1283 # elf_hp.h is for HP/UX 64-bit shared library support.
1284 AC_CHECK_HEADERS([nlist.h machine/reg.h poll.h sys/poll.h proc_service.h \
1285                   thread_db.h linux/elf.h \
1286                   sys/file.h sys/filio.h sys/ioctl.h sys/param.h \
1287                   sys/resource.h sys/procfs.h sys/ptrace.h ptrace.h \
1288                   sys/reg.h sys/debugreg.h sys/select.h \
1289                   termios.h elf_hp.h \
1290                   dlfcn.h])
1291 AC_CHECK_HEADERS(sys/user.h, [], [],
1292 [#if HAVE_SYS_PARAM_H
1293 # include <sys/param.h>
1294 #endif
1295 ])
1296
1297 AC_CHECK_HEADERS(curses.h cursesX.h ncurses.h ncursesw/ncurses.h ncurses/ncurses.h ncurses/term.h)
1298 AC_CHECK_HEADERS(term.h, [], [],
1299 [#if HAVE_CURSES_H
1300 # include <curses.h>
1301 #endif
1302 ])
1303
1304 # ------------------------- #
1305 # Checks for declarations.  #
1306 # ------------------------- #
1307
1308 libiberty_INIT
1309
1310 AC_CHECK_DECLS([snprintf])
1311 AM_LC_MESSAGES
1312
1313 # ----------------------- #
1314 # Checks for structures.  #
1315 # ----------------------- #
1316
1317 AC_CHECK_MEMBERS([struct stat.st_blocks, struct stat.st_blksize])
1318
1319 # ------------------ #
1320 # Checks for types.  #
1321 # ------------------ #
1322
1323 AC_CHECK_TYPES(socklen_t, [], [],
1324 [#include <sys/types.h>
1325 #include <sys/socket.h>
1326 ])
1327
1328 # ------------------------------------- #
1329 # Checks for compiler characteristics.  #
1330 # ------------------------------------- #
1331
1332 AC_C_CONST
1333 AC_C_INLINE
1334 AC_C_BIGENDIAN
1335
1336 # ------------------------------ #
1337 # Checks for library functions.  #
1338 # ------------------------------ #
1339
1340 AC_FUNC_MMAP
1341 AC_FUNC_VFORK
1342 AC_CHECK_FUNCS([getauxval getrusage getuid getgid \
1343                 pipe poll pread pread64 pwrite resize_term \
1344                 sbrk getpgid setpgid setpgrp setsid \
1345                 sigaction sigprocmask sigsetmask socketpair \
1346                 ttrace wborder wresize setlocale iconvlist libiconvlist btowc \
1347                 setrlimit getrlimit posix_madvise waitpid \
1348                 ptrace64 sigaltstack setns use_default_colors])
1349 AM_LANGINFO_CODESET
1350 GDB_AC_COMMON
1351
1352 # Check the return and argument types of ptrace.
1353 GDB_AC_PTRACE
1354
1355 dnl AC_FUNC_SETPGRP does not work when cross compiling
1356 dnl Instead, assume we will have a prototype for setpgrp if cross compiling.
1357 if test "$cross_compiling" = no; then
1358   AC_FUNC_SETPGRP
1359 else
1360   AC_CACHE_CHECK([whether setpgrp takes no argument], ac_cv_func_setpgrp_void,
1361     [AC_TRY_COMPILE([
1362 #include <unistd.h>
1363 ], [
1364   if (setpgrp(1,1) == -1)
1365     exit (0);
1366   else
1367     exit (1);
1368 ], ac_cv_func_setpgrp_void=no, ac_cv_func_setpgrp_void=yes)])
1369 if test $ac_cv_func_setpgrp_void = yes; then
1370   AC_DEFINE(SETPGRP_VOID, 1)
1371 fi
1372 fi
1373
1374 # Assume we'll default to using the included libiberty regex.
1375 gdb_use_included_regex=yes
1376
1377 # However, if the system regex is GNU regex, then default to *not*
1378 # using the included regex.
1379 AC_CACHE_CHECK(
1380   [for GNU regex],
1381   [gdb_cv_have_gnu_regex],
1382   [AC_TRY_COMPILE(
1383     [#include <gnu-versions.h>],
1384     [#define REGEX_INTERFACE_VERSION 1
1385 #if _GNU_REGEX_INTERFACE_VERSION != REGEX_INTERFACE_VERSION
1386 # error "Version mismatch"
1387 #endif],
1388     gdb_cv_have_gnu_regex=yes,
1389     gdb_cv_have_gnu_regex=no)])
1390 if test $gdb_cv_have_gnu_regex = yes; then
1391   gdb_use_included_regex=no
1392 fi
1393
1394 AC_ARG_WITH(included-regex,
1395   AS_HELP_STRING([--without-included-regex], [don't use included regex; this is the default on systems with version 2 of the GNU C library (use with caution on other system)]),
1396   gdb_with_regex=$withval,
1397   gdb_with_regex=$gdb_use_included_regex)
1398 if test "$gdb_with_regex" = yes; then
1399   AC_DEFINE(USE_INCLUDED_REGEX, 1,
1400     [Define to 1 if the regex included in libiberty should be used.])
1401 fi
1402
1403 # Check if <sys/proc.h> defines `struct thread' with a td_pcb member.
1404 AC_CHECK_MEMBERS([struct thread.td_pcb], [], [],
1405 [#include <sys/param.h>
1406 #include <sys/proc.h>
1407 ])
1408
1409 # See if <sys/lwp.h> defines `struct lwp`.
1410 AC_CACHE_CHECK([for struct lwp], gdb_cv_struct_lwp,
1411 [AC_TRY_COMPILE([#include <sys/param.h>
1412 #define _KMEMUSER
1413 #include <sys/lwp.h>], [struct lwp l;],
1414 gdb_cv_struct_lwp=yes, gdb_cv_struct_lwp=no)])
1415 if test $gdb_cv_struct_lwp = yes; then
1416   AC_DEFINE(HAVE_STRUCT_LWP, 1,
1417             [Define to 1 if your system has struct lwp.])
1418 fi
1419
1420 # See if <machine/reg.h> degines `struct reg'.
1421 AC_CACHE_CHECK([for struct reg in machine/reg.h], gdb_cv_struct_reg,
1422 [AC_TRY_COMPILE([#include <sys/types.h>
1423 #include <machine/reg.h>], [struct reg r;],
1424 gdb_cv_struct_reg=yes, gdb_cv_struct_reg=no)])
1425 if test $gdb_cv_struct_reg = yes; then
1426   AC_DEFINE(HAVE_STRUCT_REG, 1,
1427             [Define to 1 if your system has struct reg in <machine/reg.h>.])
1428 fi
1429
1430 # See if <machine/reg.h> supports the %fs and %gs i386 segment registers.
1431 # Older i386 BSD's don't have the r_fs and r_gs members of `struct reg'.
1432 AC_CHECK_MEMBERS([struct reg.r_fs, struct reg.r_gs], [], [],
1433                  [#include <sys/types.h>
1434 #include <machine/reg.h>])
1435
1436 # See if <sys/user.h> supports the %fs_base and %gs_bas amd64 segment registers.
1437 # Older amd64 Linux's don't have the fs_base and gs_base members of
1438 # `struct user_regs_struct'.
1439 AC_CHECK_MEMBERS([struct user_regs_struct.fs_base, struct user_regs_struct.gs_base],
1440      [], [], [#include <sys/types.h>
1441 #include <sys/user.h>])
1442
1443 # See if <sys/ptrace.h> provides the PTRACE_GETREGS request.
1444 AC_MSG_CHECKING(for PTRACE_GETREGS)
1445 AC_CACHE_VAL(gdb_cv_have_ptrace_getregs,
1446 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1447                 [PTRACE_GETREGS;],
1448                 [gdb_cv_have_ptrace_getregs=yes],
1449                 [gdb_cv_have_ptrace_getregs=no])])
1450 AC_MSG_RESULT($gdb_cv_have_ptrace_getregs)
1451 if test $gdb_cv_have_ptrace_getregs = yes; then
1452   AC_DEFINE(HAVE_PTRACE_GETREGS, 1,
1453   [Define if sys/ptrace.h defines the PTRACE_GETREGS request.])
1454 fi
1455
1456 # See if <sys/ptrace.h> provides the PTRACE_GETFPXREGS request.
1457 AC_MSG_CHECKING(for PTRACE_GETFPXREGS)
1458 AC_CACHE_VAL(gdb_cv_have_ptrace_getfpxregs,
1459 [AC_TRY_COMPILE([#include <sys/ptrace.h>],
1460                 [PTRACE_GETFPXREGS;],
1461                 [gdb_cv_have_ptrace_getfpxregs=yes],
1462                 [gdb_cv_have_ptrace_getfpxregs=no])])
1463 AC_MSG_RESULT($gdb_cv_have_ptrace_getfpxregs)
1464 if test $gdb_cv_have_ptrace_getfpxregs = yes; then
1465   AC_DEFINE(HAVE_PTRACE_GETFPXREGS, 1,
1466   [Define if sys/ptrace.h defines the PTRACE_GETFPXREGS request.])
1467 fi
1468
1469 # See if <sys/ptrace.h> provides the PT_GETDBREGS request.
1470 AC_MSG_CHECKING(for PT_GETDBREGS)
1471 AC_CACHE_VAL(gdb_cv_have_pt_getdbregs,
1472 [AC_TRY_COMPILE([#include <sys/types.h>
1473 #include <sys/ptrace.h>],
1474                 [PT_GETDBREGS;],
1475                 [gdb_cv_have_pt_getdbregs=yes],
1476                 [gdb_cv_have_pt_getdbregs=no])])
1477 AC_MSG_RESULT($gdb_cv_have_pt_getdbregs)
1478 if test $gdb_cv_have_pt_getdbregs = yes; then
1479   AC_DEFINE(HAVE_PT_GETDBREGS, 1,
1480   [Define if sys/ptrace.h defines the PT_GETDBREGS request.])
1481 fi
1482
1483 # See if <sys/ptrace.h> provides the PT_GETXMMREGS request.
1484 AC_MSG_CHECKING(for PT_GETXMMREGS)
1485 AC_CACHE_VAL(gdb_cv_have_pt_getxmmregs,
1486 [AC_TRY_COMPILE([#include <sys/types.h>
1487 #include <sys/ptrace.h>],
1488                 [PT_GETXMMREGS;],
1489                 [gdb_cv_have_pt_getxmmregs=yes],
1490                 [gdb_cv_have_pt_getxmmregs=no])])
1491 AC_MSG_RESULT($gdb_cv_have_pt_getxmmregs)
1492 if test $gdb_cv_have_pt_getxmmregs = yes; then
1493   AC_DEFINE(HAVE_PT_GETXMMREGS, 1,
1494   [Define if sys/ptrace.h defines the PT_GETXMMREGS request.])
1495 fi
1496
1497 # See if <sys/ptrace.h> supports LWP names on FreeBSD
1498 # Older FreeBSD versions don't have the pl_tdname member of
1499 # `struct ptrace_lwpinfo'.
1500 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_tdname], [], [],
1501                  [#include <sys/ptrace.h>])
1502
1503 # See if <sys/ptrace.h> supports syscall fields on FreeBSD.  The
1504 # pl_syscall_code member of `struct ptrace_lwpinfo' was added in
1505 # FreeBSD 10.3.
1506 AC_CHECK_MEMBERS([struct ptrace_lwpinfo.pl_syscall_code], [], [],
1507                  [#include <sys/ptrace.h>])
1508
1509 if test "$ac_cv_header_sys_procfs_h" = yes; then
1510   BFD_HAVE_SYS_PROCFS_TYPE(gregset_t)
1511   BFD_HAVE_SYS_PROCFS_TYPE(fpregset_t)
1512   BFD_HAVE_SYS_PROCFS_TYPE(prgregset_t)
1513   BFD_HAVE_SYS_PROCFS_TYPE(prfpregset_t)
1514   BFD_HAVE_SYS_PROCFS_TYPE(prgregset32_t)
1515   BFD_HAVE_SYS_PROCFS_TYPE(lwpid_t)
1516   BFD_HAVE_SYS_PROCFS_TYPE(psaddr_t)
1517   BFD_HAVE_SYS_PROCFS_TYPE(elf_fpregset_t)
1518 fi
1519
1520 # Check if the compiler supports the `long long' type.
1521
1522 AC_CACHE_CHECK([for long long support in compiler], gdb_cv_c_long_long,
1523                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM(
1524 [[extern long long foo;]],
1525 [[switch (foo & 2) { case 0: return 1; }]])],
1526                                   gdb_cv_c_long_long=yes,
1527                                   gdb_cv_c_long_long=no)])
1528 if test $gdb_cv_c_long_long != yes; then
1529   # libdecnumber requires long long.
1530   AC_MSG_ERROR([Compiler must support long long for GDB.])
1531 fi
1532
1533 # Check if the compiler and runtime support printing long longs.
1534
1535 AC_CACHE_CHECK([for long long support in printf],
1536                gdb_cv_printf_has_long_long,
1537                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1538 [[char buf[32];
1539   long long l = 0;
1540   l = (l << 16) + 0x0123;
1541   l = (l << 16) + 0x4567;
1542   l = (l << 16) + 0x89ab;
1543   l = (l << 16) + 0xcdef;
1544   sprintf (buf, "0x%016llx", l);
1545   return (strcmp ("0x0123456789abcdef", buf));]])],
1546                               gdb_cv_printf_has_long_long=yes,
1547                               gdb_cv_printf_has_long_long=no,
1548                               gdb_cv_printf_has_long_long=no)])
1549 if test $gdb_cv_printf_has_long_long = yes; then
1550   AC_DEFINE(PRINTF_HAS_LONG_LONG, 1,
1551             [Define to 1 if the "%ll" format works to print long longs.])
1552 fi
1553
1554 # Check if the compiler and runtime support printing decfloats.
1555
1556 AC_CACHE_CHECK([for decfloat support in printf],
1557                gdb_cv_printf_has_decfloat,
1558                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1559 [[char buf[64];
1560   _Decimal32 d32 = 1.2345df;
1561   _Decimal64 d64 = 1.2345dd;
1562   _Decimal128 d128 = 1.2345dl;
1563   sprintf (buf, "Decimal32: %H\nDecimal64: %D\nDecimal128: %DD", d32, d64, d128);
1564   return (strcmp ("Decimal32: 1.2345\nDecimal64: 1.2345\nDecimal128: 1.2345", buf));]])],
1565                               gdb_cv_printf_has_decfloat=yes,
1566                               gdb_cv_printf_has_decfloat=no,
1567                               gdb_cv_printf_has_decfloat=no)])
1568 if test $gdb_cv_printf_has_decfloat = yes; then
1569   AC_DEFINE(PRINTF_HAS_DECFLOAT, 1,
1570             [Define to 1 if the "%H, %D and %DD" formats work to print decfloats.])
1571 fi
1572
1573 # Check if the compiler supports the `long double' type.  We can't use
1574 # AC_C_LONG_DOUBLE because that one does additional checks on the
1575 # constants defined in <float.h> that fail on some systems,
1576 # e.g. FreeBSD/i386 4.7 and OpenBSD/i386 3.6.
1577
1578 AC_CACHE_CHECK([for long double support in compiler], gdb_cv_c_long_double,
1579                [AC_COMPILE_IFELSE([AC_LANG_SOURCE([[long double foo;]])],
1580                                   gdb_cv_c_long_double=yes,
1581                                   gdb_cv_c_long_double=no)])
1582 if test $gdb_cv_c_long_double = yes; then
1583   AC_DEFINE(HAVE_LONG_DOUBLE, 1,
1584            [Define to 1 if the compiler supports long double.])
1585 fi
1586
1587 # Check if the compiler and runtime support printing long doubles.
1588
1589 AC_CACHE_CHECK([for long double support in printf],
1590                gdb_cv_printf_has_long_double,
1591                [AC_RUN_IFELSE([AC_LANG_PROGRAM([AC_INCLUDES_DEFAULT],
1592 [[char buf[16];
1593   long double f = 3.141592653;
1594   sprintf (buf, "%Lg", f);
1595   return (strncmp ("3.14159", buf, 7));]])],
1596                               gdb_cv_printf_has_long_double=yes,
1597                               gdb_cv_printf_has_long_double=no,
1598                               gdb_cv_printf_has_long_double=no)])
1599 if test $gdb_cv_printf_has_long_double = yes; then
1600   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE, 1,
1601             [Define to 1 if the "%Lg" format works to print long doubles.])
1602 fi
1603
1604 # Check if the compiler and runtime support scanning long doubles.
1605
1606 AC_CACHE_CHECK([for long double support in scanf],
1607                gdb_cv_scanf_has_long_double,
1608                [AC_RUN_IFELSE([AC_LANG_PROGRAM(
1609 [[#include <stdio.h>]],
1610 [[char *buf = "3.141592653";
1611   long double f = 0;
1612   sscanf (buf, "%Lg", &f);
1613   return !(f > 3.14159 && f < 3.14160);]])],
1614                               gdb_cv_scanf_has_long_double=yes,
1615                               gdb_cv_scanf_has_long_double=no,
1616                               gdb_cv_scanf_has_long_double=no)])
1617 if test $gdb_cv_scanf_has_long_double = yes; then
1618   AC_DEFINE(SCANF_HAS_LONG_DOUBLE, 1,
1619             [Define to 1 if the "%Lg" format works to scan long doubles.])
1620 fi
1621
1622 case ${host_os} in
1623 aix*)
1624   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1625     SAVE_LDFLAGS=$LDFLAGS
1626
1627     case $GCC in
1628     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1629     *) gdb_cv_bigtoc=-bbigtoc ;;
1630     esac
1631
1632     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1633     AC_TRY_LINK([], [int i;], [], [gdb_cv_bigtoc=])
1634     LDFLAGS="${SAVE_LDFLAGS}"
1635   ])
1636   CONFIG_LDFLAGS="${CONFIG_LDFLAGS} ${gdb_cv_bigtoc}"
1637   ;;
1638 esac
1639
1640 AC_MSG_CHECKING(for the dynamic export flag)
1641 dynamic_list=false
1642 if test "${gdb_native}" = yes; then
1643    # The dynamically loaded libthread_db needs access to symbols in the gdb
1644    # executable.  Older GNU ld supports --export-dynamic but --dynamic-list
1645    # may not be supported there.
1646    old_LDFLAGS="$LDFLAGS"
1647    # Older GNU ld supports --export-dynamic but --dynamic-list it does not.
1648    RDYNAMIC="-Wl,--dynamic-list=${srcdir}/proc-service.list"
1649    LDFLAGS="$LDFLAGS $RDYNAMIC"
1650    if test "${have_libpython}" = no; then
1651      AC_TRY_LINK([], [], [dynamic_list=true])
1652    else
1653      # Workaround http://bugs.python.org/issue4434 where static
1654      # libpythonX.Y.a would get its symbols required for
1655      # pythonX.Y/lib-dynload/*.so modules hidden by -Wl,--dynamic-list.
1656      # Problem does not happen for the recommended libpythonX.Y.so linkage.
1657
1658      # Note the workaround for Python
1659      # http://bugs.python.org/issue10112 earlier has removed
1660      # -export-dynamic from PYTHON_LIBS.  That's exactly what we want
1661      # here too, as otherwise it'd make this -Wl,--dynamic-list test
1662      # always pass.
1663      old_CFLAGS="$CFLAGS"
1664      CFLAGS="$CFLAGS $PYTHON_CFLAGS"
1665      old_LIBS="$LIBS"
1666      LIBS="$LIBS $PYTHON_LIBS"
1667      old_CPPFLAGS="$CPPFLAGS"
1668      CPPFLAGS="$CPPFLAGS $PYTHON_CPPFLAGS"
1669      AC_RUN_IFELSE(
1670        [AC_LANG_PROGRAM(
1671          [#include "Python.h"],
1672          [int err;
1673           Py_Initialize ();
1674           err = PyRun_SimpleString ("import itertools\n");
1675           Py_Finalize ();
1676           return err == 0 ? 0 : 1;])],
1677        [dynamic_list=true], [], [true])
1678      LIBS="$old_LIBS"
1679      CFLAGS="$old_CFLAGS"
1680      CPPFLAGS="$old_CPPFLAGS"
1681    fi
1682    LDFLAGS="$old_LDFLAGS"
1683 fi
1684 if $dynamic_list; then
1685   found="-Wl,--dynamic-list"
1686   RDYNAMIC='-Wl,--dynamic-list=$(srcdir)/proc-service.list'
1687 else
1688   found="-rdynamic"
1689   RDYNAMIC="-rdynamic"
1690 fi
1691 AC_SUBST(RDYNAMIC)
1692 AC_MSG_RESULT($found)
1693
1694 dnl For certain native configurations, we need to check whether thread
1695 dnl support can be built in or not.
1696 dnl
1697 dnl Note that we only want this if we are both native (host == target),
1698 dnl and not doing a canadian cross build (build == host).
1699
1700 if test ${build} = ${host} -a ${host} = ${target} ; then
1701    case ${host_os} in
1702    aix*)
1703       AC_MSG_CHECKING(for AiX thread debugging library)
1704       AC_CACHE_VAL(gdb_cv_have_aix_thread_debug,
1705                    [AC_TRY_COMPILE([#include <sys/pthdebug.h>],
1706                                    [#ifndef PTHDB_VERSION_3
1707                                     #error
1708                                     #endif],
1709                                    gdb_cv_have_aix_thread_debug=yes,
1710                                    gdb_cv_have_aix_thread_debug=no)])
1711       AC_MSG_RESULT($gdb_cv_have_aix_thread_debug)
1712       if test $gdb_cv_have_aix_thread_debug = yes; then
1713          CONFIG_SRCS="${CONFIG_SRCS} aix-thread.c"
1714          CONFIG_OBS="${CONFIG_OBS} aix-thread.o"
1715          LIBS="$LIBS -lpthdebug"
1716
1717          # Older versions of AIX do not provide the declaration for
1718          # the getthrds function (it appears that it was introduced
1719          # with AIX 6.x).
1720          AC_CHECK_DECLS(getthrds, [], [], [[#include <procinfo.h>]])
1721       fi
1722       ;;
1723    esac
1724    AC_SUBST(CONFIG_LDFLAGS)
1725 fi
1726
1727 dnl See if we have a thread_db header file that has TD_NOTALLOC and
1728 dnl other error codes.
1729 if test "x$ac_cv_header_thread_db_h" = "xyes"; then
1730    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTALLOC],
1731                   gdb_cv_thread_db_h_has_td_notalloc,
1732      AC_TRY_COMPILE(
1733        [#include <thread_db.h>],
1734        [int i = TD_NOTALLOC;],
1735        gdb_cv_thread_db_h_has_td_notalloc=yes,
1736        gdb_cv_thread_db_h_has_td_notalloc=no
1737      )
1738    )
1739    AC_CACHE_CHECK([whether <thread_db.h> has TD_VERSION],
1740                   gdb_cv_thread_db_h_has_td_version,
1741      AC_TRY_COMPILE(
1742        [#include <thread_db.h>],
1743        [int i = TD_VERSION;],
1744        gdb_cv_thread_db_h_has_td_version=yes,
1745        gdb_cv_thread_db_h_has_td_version=no
1746      )
1747    )
1748    AC_CACHE_CHECK([whether <thread_db.h> has TD_NOTLS],
1749                   gdb_cv_thread_db_h_has_td_notls,
1750      AC_TRY_COMPILE(
1751        [#include <thread_db.h>],
1752        [int i = TD_NOTLS;],
1753        gdb_cv_thread_db_h_has_td_notls=yes,
1754        gdb_cv_thread_db_h_has_td_notls=no
1755      )
1756    )
1757 fi
1758 if test "x$gdb_cv_thread_db_h_has_td_notalloc" = "xyes"; then
1759   AC_DEFINE(THREAD_DB_HAS_TD_NOTALLOC, 1,
1760             [Define if <thread_db.h> has the TD_NOTALLOC error code.])
1761 fi
1762 if test "x$gdb_cv_thread_db_h_has_td_version" = "xyes"; then
1763   AC_DEFINE(THREAD_DB_HAS_TD_VERSION, 1,
1764             [Define if <thread_db.h> has the TD_VERSION error code.])
1765 fi
1766 if test "x$gdb_cv_thread_db_h_has_td_notls" = "xyes"; then
1767   AC_DEFINE(THREAD_DB_HAS_TD_NOTLS, 1,
1768             [Define if <thread_db.h> has the TD_NOTLS error code.])
1769 fi
1770
1771 dnl Check if we can disable the virtual address space randomization.
1772 dnl The functionality of setarch -R.
1773 AC_CHECK_DECLS([ADDR_NO_RANDOMIZE],,, [#include <sys/personality.h>])
1774 define([PERSONALITY_TEST], [AC_LANG_PROGRAM([#include <sys/personality.h>], [
1775 #      if !HAVE_DECL_ADDR_NO_RANDOMIZE
1776 #       define ADDR_NO_RANDOMIZE 0x0040000
1777 #      endif
1778        /* Test the flag could be set and stays set.  */
1779        personality (personality (0xffffffff) | ADDR_NO_RANDOMIZE);
1780        if (!(personality (personality (0xffffffff)) & ADDR_NO_RANDOMIZE))
1781            return 1])])
1782 AC_RUN_IFELSE([PERSONALITY_TEST],
1783               [have_personality=true],
1784               [have_personality=false],
1785               [AC_LINK_IFELSE([PERSONALITY_TEST],
1786                               [have_personality=true],
1787                               [have_personality=false])])
1788 if $have_personality
1789 then
1790     AC_DEFINE([HAVE_PERSONALITY], 1,
1791               [Define if you support the personality syscall.])
1792 fi
1793
1794 dnl Set the host's .gdbinit filename.
1795 case $host_os in
1796   go32* | *djgpp*)
1797     gdbinit=gdb.ini
1798     ;;
1799   *)
1800     gdbinit=.gdbinit
1801     ;;
1802 esac
1803 AC_DEFINE_UNQUOTED(GDBINIT,"$gdbinit",[The .gdbinit filename.])
1804
1805 dnl Handle optional features that can be enabled.
1806
1807 # Support for --with-sysroot is a copy of GDB_AC_WITH_DIR,
1808 # except that the argument to --with-sysroot is optional.
1809 # --with-sysroot (or --with-sysroot=yes) sets the default sysroot path.
1810 if test "x$with_sysroot" = xyes; then
1811   with_sysroot="${exec_prefix}/${target_alias}/sys-root"
1812 fi
1813 AC_ARG_WITH(sysroot,
1814   AS_HELP_STRING([--with-sysroot@<:@=DIR@:>@],
1815                  [search for usr/lib et al within DIR]),
1816   [TARGET_SYSTEM_ROOT=$withval], [TARGET_SYSTEM_ROOT=])
1817 AC_DEFINE_DIR(TARGET_SYSTEM_ROOT, TARGET_SYSTEM_ROOT,
1818               [search for usr/lib et al within DIR])
1819 AC_SUBST(TARGET_SYSTEM_ROOT)
1820 GDB_AC_DEFINE_RELOCATABLE(TARGET_SYSTEM_ROOT, sysroot, ${ac_define_dir})
1821
1822 GDB_AC_WITH_DIR(SYSTEM_GDBINIT, system-gdbinit,
1823     [automatically load a system-wide gdbinit file],
1824     [])
1825
1826 AM_GDB_WARNINGS
1827 AM_GDB_UBSAN
1828
1829 # In the Cygwin environment, we need some additional flags.
1830 AC_CACHE_CHECK([for cygwin], gdb_cv_os_cygwin,
1831 [AC_EGREP_CPP(^lose$, [
1832 #if defined (__CYGWIN__) || defined (__CYGWIN32__)
1833 lose
1834 #endif],[gdb_cv_os_cygwin=yes],[gdb_cv_os_cygwin=no])])
1835
1836
1837 dnl Figure out which of the many generic ser-*.c files the _host_ supports.
1838 SER_HARDWIRE="ser-base.o ser-unix.o ser-pipe.o ser-tcp.o"
1839 case ${host} in
1840   *go32* ) SER_HARDWIRE=ser-go32.o ;;
1841   *djgpp* ) SER_HARDWIRE=ser-go32.o ;;
1842   *mingw32*) SER_HARDWIRE="ser-base.o ser-tcp.o ser-mingw.o" ;;
1843   *) SER_HARDWIRE="$SER_HARDWIRE ser-uds.o" ;;
1844 esac
1845 AC_SUBST(SER_HARDWIRE)
1846
1847 # libreadline needs libuser32.a in a cygwin environment
1848 WIN32LIBS=
1849 if test x$gdb_cv_os_cygwin = xyes; then
1850     WIN32LIBS="-luser32"
1851     case "${target}" in
1852         *cygwin*) WIN32LIBS="$WIN32LIBS -limagehlp"
1853         ;;
1854     esac
1855 fi
1856
1857 # The ser-tcp.c module requires sockets.
1858 case ${host} in
1859   *mingw32*)
1860     AC_DEFINE(USE_WIN32API, 1,
1861               [Define if we should use the Windows API, instead of the
1862                POSIX API.  On Windows, we use the Windows API when
1863                building for MinGW, but the POSIX API when building
1864                for Cygwin.])
1865     WIN32LIBS="$WIN32LIBS -lws2_32"
1866     ;;
1867 esac
1868 AC_SUBST(WIN32LIBS)
1869
1870 # Add ELF support to GDB, but only if BFD includes ELF support.
1871 GDB_AC_CHECK_BFD([for ELF support in BFD], gdb_cv_var_elf,
1872                  [bfd_get_elf_phdr_upper_bound (NULL)], elf-bfd.h)
1873 if test $gdb_cv_var_elf = yes; then
1874   CONFIG_OBS="$CONFIG_OBS elfread.o stap-probe.o dtrace-probe.o"
1875   AC_DEFINE(HAVE_ELF, 1,
1876             [Define if ELF support should be included.])
1877   # -ldl is provided by bfd/Makfile.am (LIBDL) <PLUGINS>.
1878   if test "$plugins" = "yes"; then
1879     AC_SEARCH_LIBS(dlopen, dl)
1880   fi
1881 fi
1882
1883 # Add macho support to GDB, but only if BFD includes it.
1884 GDB_AC_CHECK_BFD([for Mach-O support in BFD], gdb_cv_var_macho,
1885                  [bfd_mach_o_lookup_command (NULL, 0, NULL)], mach-o.h)
1886 if test $gdb_cv_var_macho = yes; then
1887   CONFIG_OBS="$CONFIG_OBS machoread.o"
1888 fi
1889
1890 # Add any host-specific objects to GDB.
1891 CONFIG_OBS="${CONFIG_OBS} ${gdb_host_obs}"
1892
1893 # If building on ELF, look for lzma support for embedded compressed debug info.
1894 if test $gdb_cv_var_elf = yes; then
1895   AC_ARG_WITH(lzma,
1896     AS_HELP_STRING([--with-lzma], [support lzma compression (auto/yes/no)]),
1897     [], [with_lzma=auto])
1898   AC_MSG_CHECKING([whether to use lzma])
1899   AC_MSG_RESULT([$with_lzma])
1900
1901   if test "${with_lzma}" != no; then
1902     AC_LIB_HAVE_LINKFLAGS([lzma], [], [#include "lzma.h"],
1903                           [lzma_index_iter iter;
1904                            lzma_index_iter_init (&iter, 0);
1905                            lzma_mf_is_supported (LZMA_MF_HC3);])
1906     if test "$HAVE_LIBLZMA" != yes; then
1907       if test "$with_lzma" = yes; then
1908         AC_MSG_ERROR([missing liblzma for --with-lzma])
1909       fi
1910     fi
1911   fi
1912 fi
1913
1914 LIBGUI="../libgui/src/libgui.a"
1915 GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
1916 AC_SUBST(LIBGUI)
1917 AC_SUBST(GUI_CFLAGS_X)
1918
1919 WIN32LDAPP=
1920 AC_SUBST(WIN32LIBS)
1921 AC_SUBST(WIN32LDAPP)
1922
1923 case "${host}" in
1924 *-*-cygwin* | *-*-mingw* )
1925     configdir="win"
1926     ;;
1927 *)
1928     configdir="unix"
1929     ;;
1930 esac
1931
1932 GDBTKLIBS=
1933 if test "${enable_gdbtk}" = "yes"; then
1934
1935     # Gdbtk must have an absolute path to srcdir in order to run
1936     # properly when not installed.
1937     here=`pwd`
1938     cd ${srcdir}
1939     GDBTK_SRC_DIR=`pwd`
1940     cd $here
1941
1942     SC_PATH_TCLCONFIG
1943
1944     # If $no_tk is nonempty, then we can't do Tk, and there is no
1945     # point to doing Tcl.
1946     SC_PATH_TKCONFIG
1947
1948     if test -z "${no_tcl}" -a -z "${no_tk}"; then
1949         SC_LOAD_TCLCONFIG
1950
1951         # Check for in-tree tcl
1952         here=`pwd`
1953         cd ${srcdir}/..
1954         topdir=`pwd`
1955         cd ${here}
1956
1957         intree="no"
1958         if test "${TCL_SRC_DIR}" = "${topdir}/tcl"; then
1959           intree="yes"
1960         fi
1961
1962         # Find Tcl private headers
1963         if test x"${intree}" = xno; then
1964           CY_AC_TCL_PRIVATE_HEADERS
1965           TCL_INCLUDE="${TCL_INCLUDE_SPEC} ${TCL_PRIVATE_INCLUDE}"
1966           TCL_LIBRARY="${TCL_LIB_SPEC}"
1967           TCL_DEPS=""
1968         else
1969           # If building tcl in the same src tree, private headers
1970           # are not needed, but we need to be sure to use the right
1971           # headers library
1972           TCL_INCLUDE="-I${TCL_SRC_DIR}/generic"
1973           TCL_LIBRARY="${TCL_BUILD_LIB_SPEC}"
1974           TCL_DEPS="../tcl/${configdir}${TCL_LIB_FILE}"
1975         fi
1976         AC_SUBST(TCL_INCLUDE)
1977         AC_SUBST(TCL_LIBRARY)
1978         AC_SUBST(TCL_DEPS)
1979
1980         SC_LOAD_TKCONFIG
1981
1982         # Check for in-tree Tk
1983         intree="no"
1984         if test "${TK_SRC_DIR}" = "${topdir}/tk"; then
1985           intree="yes"
1986         fi
1987
1988         # Find Tk private headers
1989         if test x"${intree}" = xno; then
1990           CY_AC_TK_PRIVATE_HEADERS
1991           TK_INCLUDE="${TK_INCLUDE_SPEC} ${TK_PRIVATE_INCLUDE}"
1992           TK_LIBRARY=${TK_LIB_SPEC}
1993           TK_DEPS=""
1994         else
1995           TK_INCLUDE="-I${TK_SRC_DIR}/generic"
1996           TK_LIBRARY="${TK_BUILD_LIB_SPEC}"
1997           TK_DEPS="../tk/${configdir}/${TK_LIB_FILE}"
1998         fi
1999         AC_SUBST(TK_INCLUDE)
2000         AC_SUBST(TK_LIBRARY)
2001         AC_SUBST(TK_DEPS)
2002         AC_SUBST(TK_XINCLUDES)
2003
2004         ENABLE_CFLAGS="${ENABLE_CFLAGS} \$(SUBDIR_GDBTK_CFLAGS)"
2005
2006         # Include some libraries that Tcl and Tk want.
2007         TCL_LIBS='$(LIBGUI) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
2008         # Yes, the ordering seems wrong here.  But it isn't.
2009         # TK_LIBS is the list of libraries that need to be linked
2010         # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
2011         # were in LIBS then any link tests after this point would
2012         # try to include things like `$(LIBGUI)', which wouldn't work.
2013         GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
2014
2015         CONFIG_OBS="${CONFIG_OBS} \$(SUBDIR_GDBTK_OBS)"
2016         CONFIG_DEPS="${CONFIG_DEPS} \$(SUBDIR_GDBTK_DEPS)"
2017         CONFIG_SRCS="${CONFIG_SRCS} \$(SUBDIR_GDBTK_SRCS)"
2018         CONFIG_ALL="${CONFIG_ALL} all-gdbtk"
2019         CONFIG_CLEAN="${CONFIG_CLEAN} clean-gdbtk"
2020         CONFIG_INSTALL="${CONFIG_INSTALL} install-gdbtk"
2021         CONFIG_UNINSTALL="${CONFIG_UNINSTALL} uninstall-gdbtk"
2022
2023         if test x$gdb_cv_os_cygwin = xyes; then
2024           WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32"
2025           WIN32LDAPP="-Wl,--subsystem,console"
2026           CONFIG_OBS="${CONFIG_OBS} gdbres.o"
2027         fi
2028
2029         AC_CONFIG_SUBDIRS(gdbtk)
2030     fi
2031 fi
2032
2033 AC_SUBST(X_CFLAGS)
2034 AC_SUBST(X_LDFLAGS)
2035 AC_SUBST(X_LIBS)
2036 AC_SUBST(GDBTKLIBS)
2037 AC_SUBST(GDBTK_CFLAGS)
2038 AC_SUBST(GDBTK_SRC_DIR)
2039
2040 AC_PATH_X
2041
2042 # Unlike the sim directory, whether a simulator is linked is controlled by
2043 # presence of a gdb_sim definition in the target configure.tgt entry.
2044 # This code just checks for a few cases where we'd like to ignore those
2045 # definitions, even when they're present in the '.mt' file.  These cases
2046 # are when --disable-sim is specified, or if the simulator directory is
2047 # not part of the source tree.
2048 #
2049 AC_ARG_ENABLE(sim,
2050 AS_HELP_STRING([--enable-sim], [link gdb with simulator]),
2051 [echo "enable_sim = $enable_sim";
2052  echo "enableval = ${enableval}";
2053  case "${enableval}" in
2054   yes) ignore_sim=false ;;
2055   no)  ignore_sim=true ;;
2056   *)   ignore_sim=false ;;
2057  esac],
2058 [ignore_sim=false])
2059
2060 if test ! -d "${srcdir}/../sim"; then
2061   ignore_sim=true
2062 fi
2063
2064 SIM=
2065 SIM_OBS=
2066 if test "${ignore_sim}" = "false"; then
2067   if test x"${gdb_sim}" != x ; then
2068     SIM="${gdb_sim}"
2069     SIM_OBS="remote-sim.o"
2070     AC_DEFINE(WITH_SIM, 1, [Define if the simulator is being linked in.])
2071
2072     # Some tdep code should only be compiled in when the ppc sim is
2073     # built.  PR sim/13418.
2074     case $target in
2075       powerpc*-*-*)
2076         AC_DEFINE(WITH_PPC_SIM, 1, [Define if the PPC simulator is being linked in.])
2077         ;;
2078     esac
2079   fi
2080 fi
2081 AC_SUBST(SIM)
2082 AC_SUBST(SIM_OBS)
2083
2084 AC_SUBST(ENABLE_CFLAGS)
2085 AC_SUBST(PROFILE_CFLAGS)
2086
2087 AC_SUBST(CONFIG_OBS)
2088 AC_SUBST(CONFIG_DEPS)
2089 AC_SUBST(CONFIG_SRCS)
2090 AC_SUBST(CONFIG_ALL)
2091 AC_SUBST(CONFIG_CLEAN)
2092 AC_SUBST(CONFIG_INSTALL)
2093 AC_SUBST(CONFIG_UNINSTALL)
2094
2095 # List of host floatformats.
2096 AC_DEFINE_UNQUOTED(GDB_HOST_FLOAT_FORMAT,$gdb_host_float_format,[Host float floatformat])
2097 AC_DEFINE_UNQUOTED(GDB_HOST_DOUBLE_FORMAT,$gdb_host_double_format,[Host double floatformat])
2098 AC_DEFINE_UNQUOTED(GDB_HOST_LONG_DOUBLE_FORMAT,$gdb_host_long_double_format,[Host long double floatformat])
2099
2100 # target_subdir is used by the testsuite to find the target libraries.
2101 target_subdir=
2102 if test "${host}" != "${target}"; then
2103     target_subdir="${target_alias}/"
2104 fi
2105 AC_SUBST(target_subdir)
2106
2107 # Import nat definitions.
2108 nat_makefile_frag=/dev/null
2109 if test "${gdb_native}" = "yes"; then
2110   . ${srcdir}/configure.nat
2111   nativefile=$NAT_FILE
2112 fi
2113
2114 AC_SUBST(NAT_FILE)
2115 AC_SUBST(NATDEPFILES)
2116 AC_SUBST(NAT_CDEPS)
2117 AC_SUBST(LOADLIBES)
2118 AC_SUBST(MH_CFLAGS)
2119 AC_SUBST(XM_CLIBS)
2120 AC_SUBST(NAT_GENERATED_FILES)
2121 AC_SUBST(HAVE_NATIVE_GCORE_HOST)
2122 AC_SUBST_FILE(nat_makefile_frag)
2123
2124 if test x"${gdb_osabi}" != x ; then
2125     AC_DEFINE_UNQUOTED(GDB_OSABI_DEFAULT, $gdb_osabi,
2126                        [Define to the default OS ABI for this configuration.])
2127 fi
2128
2129 AC_ARG_ENABLE(gdbserver,
2130 AS_HELP_STRING([--enable-gdbserver],
2131                [automatically build gdbserver (yes/no/auto, default is auto)]),
2132 [case "${enableval}" in
2133   yes| no|auto) ;;
2134   *) AC_MSG_ERROR(bad value ${enableval} for --enable-gdbserver option) ;;
2135 esac],[enable_gdbserver=auto])
2136
2137 # We only build gdbserver automatically in a native configuration, and
2138 # only if the user did not explicitly disable its build.
2139 if test "$gdb_native" = "yes" -a "$enable_gdbserver" != "no"; then
2140   AC_MSG_CHECKING(whether gdbserver is supported on this host)
2141   if test "x$build_gdbserver" = xyes; then
2142     AC_MSG_RESULT(yes)
2143     AC_CONFIG_SUBDIRS(gdbserver)
2144     gdbserver_build_enabled=yes
2145   else
2146     AC_MSG_RESULT(no)
2147   fi
2148 fi
2149
2150 # If the user explicitly request the gdbserver to be built, verify that
2151 # we were in fact able to enable it.
2152 if test "$enable_gdbserver" = "yes" -a "$gdbserver_build_enabled" != "yes"; then
2153   AC_MSG_ERROR(Automatic gdbserver build is not supported for this configuration)
2154 fi
2155
2156 # Check for babeltrace and babeltrace-ctf
2157 AC_ARG_WITH(babeltrace,
2158   AC_HELP_STRING([--with-babeltrace], [include babeltrace support (auto/yes/no)]),
2159   [], [with_babeltrace=auto])
2160 AC_MSG_CHECKING([whether to use babeltrace])
2161 AC_MSG_RESULT([$with_babeltrace])
2162
2163 if test "x$with_babeltrace" = "xno"; then
2164   AC_MSG_WARN([babletrace support disabled; GDB is unable to read CTF data.])
2165 else
2166   # Append -Werror to CFLAGS so that configure can catch the warning
2167   # "assignment from incompatible pointer type", which is related to
2168   # the babeltrace change from 1.0.3 to 1.1.0.  Babeltrace 1.1.0 works
2169   # in GDB, while babeltrace 1.0.3 is broken.
2170   # AC_LIB_HAVE_LINKFLAGS may modify CPPFLAGS in it, so it should be
2171   # safe to save and restore CFLAGS here.
2172   saved_CFLAGS=$CFLAGS
2173   CFLAGS="$CFLAGS -Werror"
2174   AC_LIB_HAVE_LINKFLAGS([babeltrace], [babeltrace-ctf],
2175                         [#include <babeltrace/babeltrace.h>
2176                          #include <babeltrace/ctf/events.h>
2177                          #include <babeltrace/ctf/iterator.h>],
2178                         [struct bt_iter_pos *pos = bt_iter_get_pos (bt_ctf_get_iter (NULL));
2179                         struct bt_ctf_event *event = NULL;
2180                         const struct bt_definition *scope;
2181
2182                         pos->type = BT_SEEK_BEGIN;
2183                         bt_iter_set_pos (bt_ctf_get_iter (NULL), pos);
2184                         scope = bt_ctf_get_top_level_scope (event,
2185                                                            BT_STREAM_EVENT_HEADER);
2186                         bt_ctf_get_uint64 (bt_ctf_get_field (event, scope, "id"));
2187                         ])
2188   CFLAGS=$saved_CFLAGS
2189
2190   if test "$HAVE_LIBBABELTRACE" != yes; then
2191      if test "$with_babeltrace" = yes; then
2192        AC_MSG_ERROR([babeltrace is missing or unusable])
2193      else
2194        AC_MSG_WARN([babeltrace is missing or unusable; GDB is unable to read CTF data.])
2195      fi
2196   fi
2197 fi
2198
2199 # If nativefile (NAT_FILE) is not set in configure.nat, we link to an
2200 # empty version.
2201
2202 files=
2203 links=
2204
2205 rm -f nm.h
2206 if test "${nativefile}" != ""; then
2207     case "${nativefile}" in
2208       nm-*.h ) GDB_NM_FILE="config/${gdb_host_cpu}/${nativefile}" ;;
2209       * ) GDB_NM_FILE="${nativefile}"
2210     esac
2211     files="${files} ${GDB_NM_FILE}"
2212     links="${links} nm.h"
2213     AC_DEFINE_UNQUOTED(GDB_NM_FILE, "${GDB_NM_FILE}", [nativefile])
2214 fi
2215 AC_SUBST(GDB_NM_FILE)
2216
2217 dnl Add dependency for xsltproc if building with maintainer-mode enabled.
2218 AC_PATH_PROGS(XSLTPROC, xsltproc, missing)
2219 if test "x$USE_MAINTAINER_MODE" = xyes; then
2220   if test "${XSLTPROC}" = missing; then
2221     AC_ERROR(unable to find xsltproc.  maintainer-mode requires xsltproc.)
2222   fi
2223 fi
2224 AC_SUBST(XSLTPROC)
2225
2226 AC_LINK_FILES($files, $links)
2227
2228 dnl Check for exe extension set on certain hosts (e.g. Win32)
2229 AC_EXEEXT
2230
2231 dnl  Detect the character set used by this host.
2232 dnl  At the moment, we just assume it's UTF-8.
2233 AC_DEFINE(GDB_DEFAULT_HOST_CHARSET, "UTF-8",
2234           [Define to be a string naming the default host character set.])
2235
2236 GDB_AC_SELFTEST([
2237   CONFIG_OBS="$CONFIG_OBS \$(SUBDIR_UNITTESTS_OBS) gdbsupport/selftest.o selftest-arch.o"
2238   CONFIG_SRCS="$CONFIG_SRCS \$(SUBDIR_UNITTESTS_SRCS) gdbsupport/selftest.c selftest-arch.c"
2239 ])
2240
2241 GDB_AC_TRANSFORM([gdb], [GDB_TRANSFORM_NAME])
2242 GDB_AC_TRANSFORM([gcore], [GCORE_TRANSFORM_NAME])
2243 AC_CONFIG_FILES([gcore], [chmod +x gcore])
2244 AC_CONFIG_FILES([Makefile gdb-gdb.gdb gdb-gdb.py doc/Makefile data-directory/Makefile],
2245 [
2246 case x$CONFIG_HEADERS in
2247 xconfig.h:config.in)
2248 echo > stamp-h ;;
2249 esac
2250 ])
2251
2252 AC_OUTPUT