gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996, 1997, 1998 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_ISC_POSIX
  29
  30 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  31 AC_CANONICAL_SYSTEM
  32
  33 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  34 dnl link with the correct libraries.
  35 ALL_LINGUAS=
  36 CY_GNU_GETTEXT
  37
  38 dnl List of object files added by configure.
  39
  40 CONFIG_OBS=
  41 CONFIG_DEPS=
  42 CONFIG_SRCS=
  43
  44 configdirs="doc testsuite"
  45
  46 dnl
  47 changequote(,)dnl
  48
  49 . ${srcdir}/configure.host
  50
  51 . ${srcdir}/configure.tgt
  52
  53 dnl
  54 changequote([,])dnl
  55
  56 AC_PROG_INSTALL
  57 AC_CHECK_TOOL(AR, ar)
  58 AC_CHECK_TOOL(RANLIB, ranlib, :)
  59 AC_PROG_YACC
  60
  61 AC_ARG_PROGRAM
  62
  63 AC_TYPE_SIGNAL
  64
  65 AC_HEADER_STDC
  66 AC_CHECK_HEADERS(ctype.h curses.h endian.h libintl.h link.h \
  67                  memory.h objlist.h ptrace.h sgtty.h stddef.h stdlib.h \
  68                  string.h sys/procfs.h sys/ptrace.h sys/reg.h \
  69                  term.h termio.h termios.h unistd.h wait.h sys/wait.h \
  70                  wchar.h wctype.h asm/debugreg.h)
  71
  72 AC_HEADER_STAT
  73
  74 AC_C_CONST
  75
  76 AC_CHECK_FUNCS(setpgid sbrk sigaction isascii bzero bcopy btowc)
  77 AC_FUNC_ALLOCA
  78
  79 BFD_NEED_DECLARATION(malloc)
  80 BFD_NEED_DECLARATION(realloc)
  81 BFD_NEED_DECLARATION(free)
  82 BFD_NEED_DECLARATION(strerror)
  83 BFD_NEED_DECLARATION(strdup)
  84
  85 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  86 if test "${target}" = "${host}"; then
  87   case "${host}" in
  88   i[[3456]]86-*-linux*)
  89         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  90         AC_DEFINE(sys_quotactl)
  91         ;;
  92   esac
  93 fi
  94
  95 AC_MSG_CHECKING([for gregset_t type])
  96 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  97 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  98 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  99 AC_MSG_RESULT($gdb_cv_have_gregset_t)
 100 if test $gdb_cv_have_gregset_t = yes; then
 101   AC_DEFINE(HAVE_GREGSET_T)
 102 fi
 103
 104 AC_MSG_CHECKING([for fpregset_t type])
 105 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 106 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 107 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 108 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 109 if test $gdb_cv_have_fpregset_t = yes; then
 110   AC_DEFINE(HAVE_FPREGSET_T)
 111 fi
 112
 113 dnl See if host has libm.  This is usually needed by simulators.
 114 AC_CHECK_LIB(m, main)
 115
 116 dnl See if compiler supports "long long" type.
 117
 118 AC_MSG_CHECKING(for long long support in compiler)
 119 AC_CACHE_VAL(gdb_cv_c_long_long,
 120 [AC_TRY_COMPILE(, [
 121   extern long long foo;
 122   switch (foo & 2) { case 0: return 1; }
 123 ],
 124 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 125 AC_MSG_RESULT($gdb_cv_c_long_long)
 126 if test $gdb_cv_c_long_long = yes; then
 127   AC_DEFINE(CC_HAS_LONG_LONG)
 128 fi
 129
 130 dnl See if the compiler and runtime support printing long long
 131
 132 AC_MSG_CHECKING(for long long support in printf)
 133 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 134 [AC_TRY_RUN([
 135 int main () {
 136   char buf[32];
 137   long long l = 0;
 138   l = (l << 16) + 0x0123;
 139   l = (l << 16) + 0x4567;
 140   l = (l << 16) + 0x89ab;
 141   l = (l << 16) + 0xcdef;
 142   sprintf (buf, "0x%016llx", l);
 143   return (strcmp ("0x0123456789abcdef", buf));
 144 }],
 145 gdb_cv_printf_has_long_long=yes,
 146 gdb_cv_printf_has_long_long=no,
 147 gdb_cv_printf_has_long_long=no)])
 148 if test $gdb_cv_printf_has_long_long = yes; then
 149   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 150 fi
 151 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 152
 153 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 154 dnl because autoconf complains about cross-compilation issues.  However, this
 155 dnl code uses the same variables as the macro for compatibility.
 156
 157 AC_MSG_CHECKING(for long double support in compiler)
 158 AC_CACHE_VAL(ac_cv_c_long_double,
 159 [AC_TRY_COMPILE(, [long double foo;],
 160 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 161 AC_MSG_RESULT($ac_cv_c_long_double)
 162 if test $ac_cv_c_long_double = yes; then
 163   AC_DEFINE(HAVE_LONG_DOUBLE)
 164 fi
 165
 166 dnl See if the compiler and runtime support printing long doubles
 167
 168 AC_MSG_CHECKING(for long double support in printf)
 169 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 170 [AC_TRY_RUN([
 171 int main () {
 172   char buf[16];
 173   long double f = 3.141592653;
 174   sprintf (buf, "%Lg", f);
 175   return (strncmp ("3.14159", buf, 7));
 176 }],
 177 gdb_cv_printf_has_long_double=yes,
 178 gdb_cv_printf_has_long_double=no,
 179 gdb_cv_printf_has_long_double=no)])
 180 if test $gdb_cv_printf_has_long_double = yes; then
 181   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 182 fi
 183 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 184
 185 dnl See if the compiler and runtime support scanning long doubles
 186
 187 AC_MSG_CHECKING(for long double support in scanf)
 188 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 189 [AC_TRY_RUN([
 190 int main () {
 191   char *buf = "3.141592653";
 192   long double f = 0;
 193   sscanf (buf, "%Lg", &f);
 194   return !(f > 3.14159 && f < 3.14160);
 195 }],
 196 gdb_cv_scanf_has_long_double=yes,
 197 gdb_cv_scanf_has_long_double=no,
 198 gdb_cv_scanf_has_long_double=no)])
 199 if test $gdb_cv_scanf_has_long_double = yes; then
 200   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 201 fi
 202 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 203
 204 AC_FUNC_MMAP
 205
 206 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 207 dnl we must explicitly test for version 1 of the library because version 0
 208 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 209
 210 dnl Note that we only want this if we are both native (host == target), and
 211 dnl not doing a canadian cross build (build == host).
 212
 213 if test ${build} = ${host} -a ${host} = ${target} ; then
 214    case ${host_os} in
 215    hpux*)
 216       AC_MSG_CHECKING(for HPUX/OSF thread support)
 217       if test -f /usr/include/dce/cma_config.h ; then
 218          if test "$GCC" = "yes" ; then
 219             AC_MSG_RESULT(yes)
 220             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 221             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 222             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 223          else
 224             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 225          fi
 226       else
 227          AC_MSG_RESULT(no)
 228       fi
 229       ;;
 230    solaris*)
 231       AC_MSG_CHECKING(for Solaris thread debugging library)
 232       if test -f /usr/lib/libthread_db.so.1 ; then
 233          AC_MSG_RESULT(yes)
 234          AC_DEFINE(HAVE_THREAD_DB_LIB)
 235          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 236          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 237          AC_CHECK_LIB(dl, dlopen)
 238          if test "$GCC" = "yes" ; then
 239             # The GNU linker requires the -export-dynamic option to make
 240             # all symbols visible in the dynamic symbol table.
 241             hold_ldflags=$LDFLAGS
 242             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 243             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 244             AC_TRY_LINK(, [int i;], found=yes, found=no)
 245             LDFLAGS=$hold_ldflags
 246             AC_MSG_RESULT($found)
 247             if test $found = yes; then
 248                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 249             fi
 250          fi
 251          # Sun randomly tweaked the prototypes in <proc_service.h>
 252          # at one point.
 253          AC_MSG_CHECKING(if <proc_service.h> is old)
 254          AC_CACHE_VAL(gdb_cv_proc_service_is_old,[
 255             AC_TRY_COMPILE([
 256                 #include <proc_service.h>
 257                 ps_err_e ps_pdwrite
 258                     (struct ps_prochandle*, psaddr_t, const void*, size_t);
 259             ],, gdb_cv_proc_service_is_old=no,
 260                 gdb_cv_proc_service_is_old=yes)
 261          ])
 262          AC_MSG_RESULT($gdb_cv_proc_service_is_old)
 263          if test $gdb_cv_proc_service_is_old = yes; then
 264             AC_DEFINE(PROC_SERVICE_IS_OLD)
 265          fi
 266       else
 267          AC_MSG_RESULT(no)
 268       fi
 269       ;;
 270    esac
 271    AC_SUBST(CONFIG_LDFLAGS)
 272 fi
 273
 274 dnl Handle optional features that can be enabled.
 275 ENABLE_CFLAGS=
 276
 277 AC_ARG_ENABLE(netrom,
 278 [  --enable-netrom ],
 279 [case "${enableval}" in
 280 yes)    enable_netrom=yes ;;
 281 no)     enable_netrom=no ;;
 282 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 283 esac])
 284
 285 if test "${enable_netrom}" = "yes"; then
 286         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 287         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 288 fi
 289
 290 AC_ARG_ENABLE(warnings,
 291 [  --enable-build-warnings Enable compiler warnings if gcc is used],
 292 [case "${enableval}" in
 293 yes)    enable_build_warnings=yes ;;
 294 no)     enable_build_warnings=no ;;
 295 *)      AC_MSG_ERROR(bad value ${enableval} given for warnings options) ;;
 296 esac])
 297
 298 if test "x$enable_build_warnings" = xyes -a "x$GCC" = xyes
 299 then
 300    WARN_CFLAGS="-Wall -Wstrict-prototypes -Wmissing-prototypes"
 301 else
 302    WARN_CFLAGS=""
 303 fi
 304 AC_SUBST(WARN_CFLAGS)
 305
 306 MMALLOC_CFLAGS=
 307 MMALLOC=
 308 AC_SUBST(MMALLOC_CFLAGS)
 309 AC_SUBST(MMALLOC)
 310
 311 AC_ARG_WITH(mmalloc,
 312 [  --with-mmalloc          Use memory mapped malloc package],
 313 [case "${withval}" in
 314   yes)  want_mmalloc=true ;;
 315   no)   want_mmalloc=false;;
 316   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 317 esac],[want_mmalloc=false])dnl
 318
 319 if test x$want_mmalloc = xtrue; then
 320    AC_DEFINE(USE_MMALLOC)
 321    AC_DEFINE(MMCHECK_FORCE)
 322    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 323    MMALLOC='../mmalloc/libmmalloc.a'
 324 fi
 325
 326 # start-sanitize-carp
 327 # The below takes an educated guess at the targets that
 328 # should be built.  It is an interum version that provides
 329 # significant backward compatibility.
 330
 331 AC_ARG_ENABLE(carp,
 332 [  --enable-carp        Configure alternative readaptive paradigm ],
 333 [case "${enableval}" in
 334   yes) enable_carp=yes ;;
 335   no)  enable_carp=no ;;
 336   *)   AC_MSG_ERROR([bad value ${enableval} for carp option]) ;;
 337 esac],[enable_carp=no])dnl
 338
 339 AC_ARG_ENABLE(targets,
 340 [  --enable-targets        alternative target configurations],
 341 [case "${enableval}" in
 342   yes | "") AC_ERROR(enable-targets option must specify target names or 'all')
 343             ;;
 344   no)       enable_targets= ;;
 345   *)        enable_targets="$enableval" ;;
 346 esac])dnl
 347
 348 # Canonicalize the secondary target names.
 349 all_targets=false
 350 if test -n "$enable_targets" ; then
 351     if test "$enable_targets" = all ; then
 352         all_targets=true
 353     else
 354         for targ in `echo $enable_targets | sed 's/,/ /g'`
 355         do
 356             result=`${CONFIG_SHELL-/bin/sh} $ac_config_sub $targ 2>/dev/null`
 357             if test -n "$result" ; then
 358                 canon_targets="$canon_targets $result"
 359             fi
 360         done
 361     fi
 362 fi
 363
 364 # Convert the target names into GDB [*]-tdep.c names
 365 changequote(,)dnl
 366 selarchs=
 367 for targ in $target $canon_targets
 368 do
 369     if test "x$targ" = "xall" ; then
 370         all_targets=true
 371     else
 372         t_cpu=`echo $targ    | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\1/'`
 373         t_vendor=`echo $targ | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\2/'`
 374         t_os=`echo $targ     | sed 's/^\([^-]*\)-\([^-]*\)-\(.*\)$/\3/'`
 375         mt=`
 376 target=$targ
 377 target_cpu=$t_cpu
 378 target_vendor=$t_vendor
 379 target_os=$t_os
 380 . ${srcdir}/configure.tgt
 381 echo ${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt`
 382         if test -r ${mt} ; then
 383             # This gets confused over .mt files that have multiple -tdep.o
 384             tdep=`sed -n '
 385 s/^.*[  =]\([^  ]*\)-tdep.o.*/\1/p
 386 ' $mt`
 387             selarchs="$selarchs $tdep"
 388         fi
 389     fi
 390 done
 391 changequote([,])dnl
 392
 393 # We don't do any links based on the target system, just makefile config.
 394
 395 if test x${all_targets} = xfalse ; then
 396
 397     # Target architecture .o files.
 398     ta=
 399
 400     for arch in $selarchs
 401     do
 402         archdefs="$archdefs -DARCH_$arch"
 403         ta="$ta ${arch}-tdep.o"
 404         # Special cases
 405         case "$arch" in
 406             dvp)  ta="$ta mips-tdep.o dvp-tdep.o" ;;
 407         esac
 408     done
 409
 410     # Weed out duplicate .o files.
 411     f=""
 412     for i in $ta ; do
 413         case " $f " in
 414             *" $i "*) ;;
 415             *) f="$f $i" ;;
 416         esac
 417     done
 418     ta="$f"
 419
 420     # And duplicate -D flags.
 421     f=""
 422     for i in $archdefs ; do
 423         case " $f " in
 424             *" $i "*) ;;
 425             *) f="$f $i" ;;
 426         esac
 427     done
 428     archdefs="$f"
 429
 430     MACHINE_OBS="$ta"
 431
 432 else    # all_targets is true
 433     archdefs=-DARCH_all
 434     MACHINE_OBS='$(ALL_MACHINES)'
 435 fi
 436
 437 dnl Don't define an archdefs list
 438 dnl AC_SUBST(archdefs)
 439 dnl XXXX this name will change several more times
 440 if test "${enable_carp}" = yes ; then
 441     gdb_target=carp
 442     gdb_target_cpu=carp
 443 else
 444     MACHINE_OBS="# $MACHINE_OBS"
 445 fi
 446 AC_SUBST(MACHINE_OBS)
 447
 448 # end-sanitize-carp
 449 # start-sanitize-gdbtk
 450 # start-sanitize-ide
 451 ENABLE_IDE=
 452 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 453 if test "$enable_ide" = yes; then
 454    enable_ide=yes
 455    ENABLE_IDE=1
 456 else
 457    enable_ide=no
 458 fi
 459 AC_SUBST(ENABLE_IDE)
 460
 461 AC_ARG_WITH(foundry-libs,
 462 [  --with-foundry-libs=DIR Use the Foundry SDK in DIR],
 463 [FOUNDRY_LIB_BASE=${withval}])
 464 AC_SUBST(FOUNDRY_LIB_BASE)
 465
 466 #
 467 # This is the Foundry SDK
 468 #
 469 # These variables are used to determine where the Foundry libs and
 470 # header files are located.
 471 #
 472 if test "$FOUNDRY_LIB_BASE" != ""; then
 473     LIBGUI="${FOUNDRY_LIB_BASE}/lib/libgui.a"
 474     GUI_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 475     if test x$enable_ide = xyes; then
 476         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include -DIDE"
 477         IDE_X="-L${FOUNDRY_LIB_BASE}/lib -lilu-Tk -lilu-c -lilu"
 478     else
 479         IDE_CFLAGS_X="-I${FOUNDRY_LIB_BASE}/include"
 480     fi
 481     LIBIDETCL="${FOUNDRY_LIB_BASE}/lib/libidetcl.a"
 482     LIBIDE="${FOUNDRY_LIB_BASE}/lib/libide.a"
 483     IDE_DEPS="${FOUNDRY_LIB_BASE}/lib/libilu-Tk.a ${FOUNDRY_LIB_BASE}/lib/libilu-c.a ${FOUNDRY_LIB_BASE}/lib/libilu.a"
 484 else
 485     LIBGUI="../libgui/src/libgui.a"
 486     GUI_CFLAGS_X="-I${srcdir}/../libgui/src"
 487     if test x$enable_ide = xyes; then
 488         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src -DIDE -I${srcdir}/../ilu/runtime/mainloop"
 489         IDE_X="-L../ilu/runtime/mainloop -lilu-Tk -L../ilu/runtime/c -lilu-c -L../ilu/runtime/kernel -lilu"
 490     else
 491         IDE_CFLAGS_X="-I${srcdir}/../libidetcl/src -I${srcdir}/../libide/src"
 492     fi
 493     LIBIDETCL="../libidetcl/src/libidetcl.a"
 494     LIBIDE="../libide/src/libide.a"
 495     IDE_DEPS="../ilu/runtime/mainloop/libilu-Tk.a ../ilu/runtime/c/libilu-c.a ../ilu/runtime/kernel/libilu.a"
 496 fi
 497 AC_SUBST(LIBGUI)
 498 AC_SUBST(GUI_CFLAGS_X)
 499 AC_SUBST(IDE_CFLAGS_X)
 500 AC_SUBST(IDE_X)
 501 AC_SUBST(LIBIDETCL)
 502 AC_SUBST(LIBIDE)
 503 AC_SUBST(IDE_DEPS)
 504 # end-sanitize-ide
 505
 506 ENABLE_GDBTK=
 507
 508 AC_ARG_ENABLE(gdbtk,
 509 [  --enable-gdbtk          Enable GDBTK GUI front end],
 510 [case "${enableval}" in
 511     yes)
 512         case "$host" in
 513         *go32*)
 514             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 515             enable_gdbtk=no ;;
 516         *windows*)
 517             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 518             enable_gdbtk=no ;;
 519         *)
 520             enable_gdbtk=yes ;;
 521         esac ;;
 522     no)
 523         enable_gdbtk=no  ;;
 524     *)
 525         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 526 esac],
 527 [
 528 # Default is on for everything but go32 and cygwin32
 529 case "$host" in
 530     *go32* | *windows*)
 531         ;;
 532     *)
 533         enable_gdbtk=yes ;;
 534     esac
 535 ])
 536
 537 # In the cygwin32 environment, we need some additional flags.
 538 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 539 [AC_EGREP_CPP(lose, [
 540 #ifdef __CYGWIN32__
 541 lose
 542 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 543
 544 WIN32LIBS=
 545 WIN32LDAPP=
 546 AC_SUBST(WIN32LIBS)
 547 AC_SUBST(WIN32LDAPP)
 548
 549 DLLTOOL=${DLLTOOL-dlltool}
 550 WINDRES=${WINDRES-windres}
 551 AC_SUBST(DLLTOOL)
 552 AC_SUBST(WINDRES)
 553
 554 if test x$gdb_cv_os_cygwin32 = xyes; then
 555     if test x$enable_ide = xyes; then
 556         WIN32LIBS="-ladvapi32"
 557     fi
 558 fi
 559
 560 configdir="unix"
 561
 562 GDBTKLIBS=
 563 if test "${enable_gdbtk}" = "yes"; then
 564
 565     CY_AC_PATH_TCLCONFIG
 566     if test -z "${no_tcl}"; then
 567         CY_AC_LOAD_TCLCONFIG
 568         CY_AC_PATH_TKCONFIG
 569
 570         # If $no_tk is nonempty, then we can't do Tk, and there is no
 571         # point to doing Tcl.
 572         if test -z "${no_tk}"; then
 573            CY_AC_LOAD_TKCONFIG
 574            CY_AC_PATH_TCLH
 575            CY_AC_PATH_TKH
 576            CY_AC_PATH_ITCLH
 577            CY_AC_PATH_TIX
 578
 579            # now look for tix library stuff
 580            TIXVERSION=4.1.8.0
 581            . ${ac_cv_c_tclconfig}/tclConfig.sh
 582            case "${host}" in
 583            *-*-cygwin32*)
 584                 tixdir=../tix/win/tcl8.0
 585                 ;;
 586            *)
 587                 tixdir=../tix/unix/tk8.0
 588                 ;;
 589            esac
 590            if test "${TCL_SHARED_BUILD}" = "1"; then
 591                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 592
 593                 # Can't win them all: SunOS 4 (others?) appends a version
 594                 # number after the ".so"
 595                 case "${host}" in
 596                 *-*-sunos4*)
 597                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 598                 esac
 599
 600            else
 601                 TIX_LIB_EXT=".a"
 602            fi
 603
 604            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 605                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 606                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 607            else
 608                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 609                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 610            fi
 611
 612            ENABLE_GDBTK=1
 613            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 614
 615            # Include some libraries that Tcl and Tk want.
 616            if test "${enable_ide}" = "yes"; then
 617               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 618               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 619            else
 620               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 621               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 622            fi
 623            # Yes, the ordering seems wrong here.  But it isn't.
 624            # TK_LIBS is the list of libraries that need to be linked
 625            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 626            # were in LIBS then any link tests after this point would
 627            # try to include things like `$(LIBGUI)', which wouldn't work.
 628            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 629            CONFIG_OBS="${CONFIG_OBS} gdbtk.o gdbtk-cmds.o gdbtk-hooks.o"
 630
 631            if test x$gdb_cv_os_cygwin32 = xyes; then
 632               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 633               WIN32LDAPP="-Wl,--subsystem,console"
 634               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 635            fi
 636         fi
 637     fi
 638 fi
 639
 640 AC_SUBST(ENABLE_GDBTK)
 641 AC_SUBST(X_CFLAGS)
 642 AC_SUBST(X_LDFLAGS)
 643 AC_SUBST(X_LIBS)
 644 AC_SUBST(TIXLIB)
 645 AC_SUBST(TIX_DEPS)
 646 AC_SUBST(GDBTKLIBS)
 647 # end-sanitize-gdbtk
 648
 649 AC_PATH_X
 650 # start-sanitize-sky
 651 # Enable GPU2 library for MIPS simulator
 652 AC_ARG_WITH(sim-gpu2,
 653 [  --with-sim-gpu2=DIR     Use GPU2 library under given DIR],
 654 [case "${target}" in
 655   mips*-sky-*)
 656     if test -d "${withval}"
 657     then
 658       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 659     else
 660       AC_MSG_WARN([Directory ${withval} does not exist.])
 661     fi ;;
 662   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 663 esac])dnl
 664
 665 # Enable target accurate FP library
 666 AC_ARG_WITH(sim-funit,
 667 [  --with-sim-funit=DIR    Use target FP lib under given DIR],
 668 [case "${target}" in
 669   mips*-sky-*)
 670     if test -d "${withval}"
 671     then
 672       LIBS="${LIBS} -L${withval}/lib -lfunit"
 673     else
 674       AC_MSG_WARN([Directory ${withval} does not exist.])
 675     fi ;;
 676   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 677 esac])dnl
 678 # end-sanitize-sky
 679
 680 dnl Solaris puts wctype in /usr/lib/libw.a
 681 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 682
 683 AC_SUBST(ENABLE_CFLAGS)
 684
 685 AC_SUBST(CONFIG_OBS)
 686 AC_SUBST(CONFIG_DEPS)
 687 AC_SUBST(CONFIG_SRCS)
 688
 689 # Begin stuff to support --enable-shared
 690 AC_ARG_ENABLE(shared,
 691 [  --enable-shared         Use shared libraries],
 692 [case "${enableval}" in
 693   yes) shared=true ;;
 694   no)  shared=false ;;
 695   *) shared=true ;;
 696 esac])dnl
 697
 698 HLDFLAGS=
 699 HLDENV=
 700 # If we have shared libraries, try to set rpath reasonably.
 701 if test "${shared}" = "true"; then
 702   case "${host}" in
 703   *-*-hpux*)
 704     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 705     ;;
 706   *-*-irix5* | *-*-irix6*)
 707     HLDFLAGS='-Wl,-rpath,$(libdir)'
 708     ;;
 709   *-*-linux*aout*)
 710     ;;
 711   *-*-linux* | *-pc-linux-gnu)
 712     HLDFLAGS='-Wl,-rpath,$(libdir)'
 713     ;;
 714   *-*-solaris*)
 715     HLDFLAGS='-R $(libdir)'
 716     ;;
 717   *-*-sysv4*)
 718     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 719     ;;
 720   esac
 721 fi
 722
 723 # On SunOS, if the linker supports the -rpath option, use it to
 724 # prevent ../bfd and ../opcodes from being included in the run time
 725 # search path.
 726 case "${host}" in
 727   *-*-sunos*)
 728     echo 'main () { }' > conftest.c
 729     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 730     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 731       :
 732     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 733       :
 734     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 735       :
 736     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 737       :
 738     elif test "${shared}" = "true"; then
 739       HLDFLAGS='-Wl,-rpath=$(libdir)'
 740     else
 741       HLDFLAGS='-Wl,-rpath='
 742     fi
 743     rm -f conftest.t conftest.c conftest
 744     ;;
 745 esac
 746 AC_SUBST(HLDFLAGS)
 747 AC_SUBST(HLDENV)
 748 # End stuff to support --enable-shared
 749
 750 # target_subdir is used by the testsuite to find the target libraries.
 751 target_subdir=
 752 if test "${host}" != "${target}"; then
 753     target_subdir="${target_alias}/"
 754 fi
 755 AC_SUBST(target_subdir)
 756
 757 frags=
 758 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 759 if test ! -f ${host_makefile_frag}; then
 760 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 761 fi
 762 frags="$frags $host_makefile_frag"
 763
 764 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 765 if test ! -f ${target_makefile_frag}; then
 766 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 767 fi
 768 frags="$frags $target_makefile_frag"
 769
 770 AC_SUBST_FILE(host_makefile_frag)
 771 AC_SUBST_FILE(target_makefile_frag)
 772 AC_SUBST(frags)
 773
 774 changequote(,)dnl
 775 hostfile=`sed -n '
 776 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 777 ' ${host_makefile_frag}`
 778
 779 targetfile=`sed -n '
 780 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 781 ' ${target_makefile_frag}`
 782
 783 # these really aren't orthogonal true/false values of the same condition,
 784 # but shells are slow enough that I like to reuse the test conditions
 785 # whenever possible
 786 if test "${target}" = "${host}"; then
 787 nativefile=`sed -n '
 788 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 789 ' ${host_makefile_frag}`
 790 # else
 791 # GDBserver is only useful in a "native" enviroment
 792 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 793 fi
 794 changequote([,])
 795
 796 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 797 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 798 # corresponding links.  But we have to remove the xm.h files and tm.h
 799 # files anyway, e.g. when switching from "configure host" to
 800 # "configure none".
 801
 802 files=
 803 links=
 804 rm -f xm.h
 805 if test "${hostfile}" != ""; then
 806 files="${files} config/${gdb_host_cpu}/${hostfile}"
 807 links="${links} xm.h"
 808 fi
 809 rm -f tm.h
 810 if test "${targetfile}" != ""; then
 811 files="${files} config/${gdb_target_cpu}/${targetfile}"
 812 links="${links} tm.h"
 813 fi
 814 rm -f nm.h
 815 if test "${nativefile}" != ""; then
 816 files="${files} config/${gdb_host_cpu}/${nativefile}"
 817 links="${links} nm.h"
 818 else
 819 # A cross-only configuration.
 820 files="${files} config/nm-empty.h"
 821 links="${links} nm.h"
 822 fi
 823 # start-sanitize-gdbtk
 824 AC_PROG_LN_S
 825 # Make it possible to use the GUI without doing a full install
 826 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl2 ; then
 827   if test "$LN_S" = "ln -s" -a ! -f gdbtcl2 ; then
 828   echo linking $srcdir/gdbtcl2 to gdbtcl2
 829   $LN_S $srcdir/gdbtcl2 gdbtcl2
 830   else
 831   echo Warning: Unable to link $srcdir/gdbtcl2 to gdbtcl2.  You will need to do a
 832   echo "         " make install before you are able to run the GUI.
 833   fi
 834 fi
 835 # end-sanitize-gdbtk
 836
 837 AC_LINK_FILES($files, $links)
 838
 839 dnl Check for exe extension set on certain hosts (e.g. Win32)
 840 AM_EXEEXT
 841
 842 AC_CONFIG_SUBDIRS($configdirs)
 843 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 844 [
 845 dnl Autoconf doesn't provide a mechanism for modifying definitions
 846 dnl provided by makefile fragments.
 847 dnl
 848 if test "${nativefile}" = ""; then
 849 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 850         < Makefile > Makefile.tem
 851 mv -f Makefile.tem Makefile
 852 fi
 853
 854 changequote(,)dnl
 855 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 856 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 857 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 858 mv -f Makefile.tmp Makefile
 859 changequote([,])dnl
 860
 861 case x$CONFIG_HEADERS in
 862 xconfig.h:config.in)
 863 echo > stamp-h ;;
 864 esac
 865 ],
 866 [
 867 gdb_host_cpu=$gdb_host_cpu
 868 gdb_target_cpu=$gdb_target_cpu
 869 nativefile=$nativefile
 870 ])
 871
 872 exit 0