gdb/configure.in

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright 1995, 1996 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 2 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program; if not, write to the Free Software
  18 dnl Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
  19
  20 dnl Process this file with autoconf to produce a configure script.
  21
  22 AC_PREREQ(2.5)dnl
  23 AC_INIT(main.c)
  24 AC_CONFIG_HEADER(config.h:config.in)
  25
  26 AC_PROG_CC
  27 AC_AIX
  28 AC_MINIX
  29 AC_ISC_POSIX
  30
  31 DLLTOOL=${DLLTOOL-dlltool}
  32 AC_SUBST(DLLTOOL)
  33
  34 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  35 AC_CANONICAL_SYSTEM
  36
  37 dnl gdb doesn't use gettext, but bfd does.  We call this to ensure we
  38 dnl link with the correct libraries.
  39 ALL_LINGUAS=
  40 CY_GNU_GETTEXT
  41
  42 dnl List of object files added by configure.
  43
  44 CONFIG_OBS=
  45 CONFIG_DEPS=
  46 CONFIG_SRCS=
  47
  48 configdirs="doc testsuite"
  49
  50 dnl
  51 changequote(,)dnl
  52
  53 . ${srcdir}/configure.host
  54
  55 . ${srcdir}/configure.tgt
  56
  57 dnl
  58 changequote([,])dnl
  59
  60 AC_PROG_INSTALL
  61 AC_CHECK_TOOL(AR, ar)
  62 AC_CHECK_TOOL(RANLIB, ranlib, :)
  63 AC_PROG_YACC
  64 AC_PROG_AWK
  65
  66 AC_ARG_PROGRAM
  67
  68 AC_TYPE_SIGNAL
  69
  70 AC_HEADER_STDC
  71 AC_CHECK_HEADERS(limits.h memory.h string.h strings.h unistd.h termios.h termio.h sgtty.h stddef.h stdlib.h sys/procfs.h link.h endian.h objlist.h libintl.h wctype.h wchar.h)
  72
  73 AC_HEADER_STAT
  74
  75 AC_C_CONST
  76
  77 AC_CHECK_FUNCS(setpgid sbrk select poll sigaction isascii bzero bcopy memcpy btowc)
  78 AC_FUNC_ALLOCA
  79
  80 # If we are configured native on GNU/Linux, work around problems with sys/procfs.h
  81 if test "${target}" = "${host}"; then
  82   case "${host}" in
  83   i[[3456]]86-*-linux*)
  84         AC_DEFINE(START_INFERIOR_TRAPS_EXPECTED,2)
  85         AC_DEFINE(sys_quotactl)
  86         ;;
  87   esac
  88 fi
  89
  90 AC_MSG_CHECKING([for gregset_t type])
  91 AC_CACHE_VAL(gdb_cv_have_gregset_t,
  92 [AC_TRY_LINK([#include <sys/procfs.h>],[gregset_t *gregsetp = 0],
  93 gdb_cv_have_gregset_t=yes, gdb_cv_have_gregset_t=no)])
  94 AC_MSG_RESULT($gdb_cv_have_gregset_t)
  95 if test $gdb_cv_have_gregset_t = yes; then
  96   AC_DEFINE(HAVE_GREGSET_T)
  97 fi
  98
  99 AC_MSG_CHECKING([for fpregset_t type])
 100 AC_CACHE_VAL(gdb_cv_have_fpregset_t,
 101 [AC_TRY_LINK([#include <sys/procfs.h>],[fpregset_t *fpregsetp = 0],
 102 gdb_cv_have_fpregset_t=yes, gdb_cv_have_fpregset_t=no)])
 103 AC_MSG_RESULT($gdb_cv_have_fpregset_t)
 104 if test $gdb_cv_have_fpregset_t = yes; then
 105   AC_DEFINE(HAVE_FPREGSET_T)
 106 fi
 107
 108 dnl See if host has libm.  This is usually needed by simulators.
 109 AC_CHECK_LIB(m, main)
 110
 111 dnl See if compiler supports "long long" type.
 112
 113 AC_MSG_CHECKING(for long long support in compiler)
 114 AC_CACHE_VAL(gdb_cv_c_long_long,
 115 [AC_TRY_COMPILE(, [
 116   extern long long foo;
 117   switch (foo & 2) { case 0: return 1; }
 118 ],
 119 gdb_cv_c_long_long=yes, gdb_cv_c_long_long=no)])
 120 AC_MSG_RESULT($gdb_cv_c_long_long)
 121 if test $gdb_cv_c_long_long = yes; then
 122   AC_DEFINE(CC_HAS_LONG_LONG)
 123 fi
 124
 125 dnl See if the compiler and runtime support printing long long
 126
 127 AC_MSG_CHECKING(for long long support in printf)
 128 AC_CACHE_VAL(gdb_cv_printf_has_long_long,
 129 [AC_TRY_RUN([
 130 int main () {
 131   char buf[32];
 132   long long l = 0;
 133   l = (l << 16) + 0x0123;
 134   l = (l << 16) + 0x4567;
 135   l = (l << 16) + 0x89ab;
 136   l = (l << 16) + 0xcdef;
 137   sprintf (buf, "0x%016llx", l);
 138   return (strcmp ("0x0123456789abcdef", buf));
 139 }],
 140 gdb_cv_printf_has_long_long=yes,
 141 gdb_cv_printf_has_long_long=no,
 142 gdb_cv_printf_has_long_long=no)])
 143 if test $gdb_cv_printf_has_long_long = yes; then
 144   AC_DEFINE(PRINTF_HAS_LONG_LONG)
 145 fi
 146 AC_MSG_RESULT($gdb_cv_printf_has_long_long)
 147
 148 dnl See if compiler supports "long double" type.  Can't use AC_C_LONG_DOUBLE
 149 dnl because autoconf complains about cross-compilation issues.  However, this
 150 dnl code uses the same variables as the macro for compatibility.
 151
 152 AC_MSG_CHECKING(for long double support in compiler)
 153 AC_CACHE_VAL(ac_cv_c_long_double,
 154 [AC_TRY_COMPILE(, [long double foo;],
 155 ac_cv_c_long_double=yes, ac_cv_c_long_double=no)])
 156 AC_MSG_RESULT($ac_cv_c_long_double)
 157 if test $ac_cv_c_long_double = yes; then
 158   AC_DEFINE(HAVE_LONG_DOUBLE)
 159 fi
 160
 161 dnl See if the compiler and runtime support printing long doubles
 162
 163 AC_MSG_CHECKING(for long double support in printf)
 164 AC_CACHE_VAL(gdb_cv_printf_has_long_double,
 165 [AC_TRY_RUN([
 166 int main () {
 167   char buf[16];
 168   long double f = 3.141592653;
 169   sprintf (buf, "%Lg", f);
 170   return (strncmp ("3.14159", buf, 7));
 171 }],
 172 gdb_cv_printf_has_long_double=yes,
 173 gdb_cv_printf_has_long_double=no,
 174 gdb_cv_printf_has_long_double=no)])
 175 if test $gdb_cv_printf_has_long_double = yes; then
 176   AC_DEFINE(PRINTF_HAS_LONG_DOUBLE)
 177 fi
 178 AC_MSG_RESULT($gdb_cv_printf_has_long_double)
 179
 180 dnl See if the compiler and runtime support scanning long doubles
 181
 182 AC_MSG_CHECKING(for long double support in scanf)
 183 AC_CACHE_VAL(gdb_cv_scanf_has_long_double,
 184 [AC_TRY_RUN([
 185 int main () {
 186   char *buf = "3.141592653";
 187   long double f = 0;
 188   sscanf (buf, "%Lg", &f);
 189   return !(f > 3.14159 && f < 3.14160);
 190 }],
 191 gdb_cv_scanf_has_long_double=yes,
 192 gdb_cv_scanf_has_long_double=no,
 193 gdb_cv_scanf_has_long_double=no)])
 194 if test $gdb_cv_scanf_has_long_double = yes; then
 195   AC_DEFINE(SCANF_HAS_LONG_DOUBLE)
 196 fi
 197 AC_MSG_RESULT($gdb_cv_scanf_has_long_double)
 198
 199 AC_FUNC_MMAP
 200
 201 BFD_NEED_DECLARATION(malloc)
 202 BFD_NEED_DECLARATION(realloc)
 203 BFD_NEED_DECLARATION(free)
 204
 205 BFD_NEED_DECLARATION(strerror)
 206
 207 dnl See if thread_db library is around for Solaris thread debugging.  Note that
 208 dnl we must explicitly test for version 1 of the library because version 0
 209 dnl (present on Solaris 2.4 or earlier) doesn't have the same API.
 210
 211 dnl Note that we only want this if we are both native (host == target), and
 212 dnl not doing a canadian cross build (build == host).
 213
 214 if test ${build} = ${host} -a ${host} = ${target} ; then
 215    case ${host_os} in
 216    hpux*)
 217       AC_MSG_CHECKING(for HPUX/OSF thread support)
 218       if test -f /usr/include/dce/cma_config.h ; then
 219          if test "$GCC" = "yes" ; then
 220             AC_MSG_RESULT(yes)
 221             AC_DEFINE(HAVE_HPUX_THREAD_SUPPORT)
 222             CONFIG_OBS="${CONFIG_OJS} hpux-thread.o"
 223             CONFIG_SRCS="${CONFIG_SRCS} hpux-thread.c"
 224          else
 225             AC_MSG_RESULT(no (suppressed because you are not using GCC))
 226          fi
 227       else
 228          AC_MSG_RESULT(no)
 229       fi
 230       ;;
 231    solaris*)
 232       AC_MSG_CHECKING(for Solaris thread debugging library)
 233       if test -f /usr/lib/libthread_db.so.1 ; then
 234          AC_MSG_RESULT(yes)
 235          AC_DEFINE(HAVE_THREAD_DB_LIB)
 236          CONFIG_OBS="${CONFIG_OBS} sol-thread.o"
 237          CONFIG_SRCS="${CONFIG_SRCS} sol-thread.c"
 238          AC_CHECK_LIB(dl, dlopen)
 239          if test "$GCC" = "yes" ; then
 240             # The GNU linker requires the -export-dynamic option to make
 241             # all symbols visible in the dynamic symbol table.
 242             hold_ldflags=$LDFLAGS
 243             AC_MSG_CHECKING(for the ld -export-dynamic flag)
 244             LDFLAGS="${LDFLAGS} -Wl,-export-dynamic"
 245             AC_TRY_LINK(, [int i;], found=yes, found=no)
 246             LDFLAGS=$hold_ldflags
 247             AC_MSG_RESULT($found)
 248             if test $found = yes; then
 249                CONFIG_LDFLAGS="${CONFIG_LDFLAGS} -Wl,-export-dynamic"
 250             fi
 251          fi
 252       else
 253          AC_MSG_RESULT(no)
 254       fi
 255       ;;
 256    esac
 257    AC_SUBST(CONFIG_LDFLAGS)
 258 fi
 259
 260 dnl Handle optional features that can be enabled.
 261 ENABLE_CFLAGS=
 262
 263 AC_ARG_ENABLE(netrom,
 264 [  --enable-netrom ],
 265 [case "${enableval}" in
 266 yes)    enable_netrom=yes ;;
 267 no)     enable_netrom=no ;;
 268 *)      AC_MSG_ERROR(bad value ${enableval} given for netrom option) ;;
 269 esac])
 270
 271 if test "${enable_netrom}" = "yes"; then
 272         CONFIG_OBS="${CONFIG_OBS} remote-nrom.o"
 273         CONFIG_SRCS="${CONFIG_SRCS} remote-nrom.c"
 274 fi
 275
 276 MMALLOC_CFLAGS=
 277 MMALLOC=
 278 AC_SUBST(MMALLOC_CFLAGS)
 279 AC_SUBST(MMALLOC)
 280
 281 AC_ARG_WITH(mmalloc,
 282 [  --with-mmalloc             use memory mapped malloc package],
 283 [case "${withval}" in
 284   yes)  want_mmalloc=true ;;
 285   no)   want_mmalloc=false;;
 286   *)    AC_MSG_ERROR(bad value ${withval} for GDB with-mmalloc option) ;;
 287 esac],[want_mmalloc=false])dnl
 288
 289 if test x$want_mmalloc = xtrue; then
 290    AC_DEFINE(USE_MMALLOC)
 291    AC_DEFINE(MMCHECK_FORCE)
 292    MMALLOC_CFLAGS="-I$srcdir/../mmalloc"
 293    MMALLOC='../mmalloc/libmmalloc.a'
 294 fi
 295
 296 # start-sanitize-gdbtk
 297 ENABLE_IDE=
 298 AC_ARG_ENABLE(ide, [  --enable-ide            Enable IDE support])
 299 if test "$enable_ide" = yes; then
 300    enable_ide=yes
 301    ENABLE_IDE=1
 302 else
 303    enable_ide=no
 304 fi
 305 AC_SUBST(ENABLE_IDE)
 306
 307 ENABLE_GDBTK=
 308
 309 AC_ARG_ENABLE(gdbtk,
 310 [  --enable-gdbtk ],
 311 [case "${enableval}" in
 312     yes)
 313         case "$host" in
 314         *go32*)
 315             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 316             enable_gdbtk=no ;;
 317         *windows*)
 318             AC_MSG_WARN([GDB does not support GDBtk on host ${host}.  GDBtk will be disabled.])
 319             enable_gdbtk=no ;;
 320         *)
 321             enable_gdbtk=yes ;;
 322         esac ;;
 323     no)
 324         enable_gdbtk=no  ;;
 325     *)
 326         AC_MSG_ERROR(bad value ${enableval} given for gdbtk option) ;;
 327 esac],
 328 [
 329 # Default is on for everything but go32 and cygwin32
 330 case "$host" in
 331     *go32* | *windows*)
 332         ;;
 333     *)
 334         enable_gdbtk=yes ;;
 335     esac
 336 ])
 337
 338 # In the cygwin32 environment, we need some additional flags.
 339 AC_CACHE_CHECK([for cygwin32], gdb_cv_os_cygwin32,
 340 [AC_EGREP_CPP(lose, [
 341 #ifdef __CYGWIN32__
 342 lose
 343 #endif],[gdb_cv_os_cygwin32=yes],[gdb_cv_os_cygwin32=no])])
 344
 345 WIN32LIBS=
 346 WIN32LDAPP=
 347 AC_SUBST(WIN32LIBS)
 348 AC_SUBST(WIN32LDAPP)
 349
 350 WINDRES=${WINDRES-windres}
 351 AC_SUBST(WINDRES)
 352
 353 if test x$gdb_cv_os_cygwin32 = xyes; then
 354     if test x$enable_ide = xyes; then
 355         WIN32LIBS="-ladvapi32"
 356     fi
 357 fi
 358
 359 configdir="unix"
 360
 361 GDBTKLIBS=
 362 if test "${enable_gdbtk}" = "yes"; then
 363
 364     CY_AC_PATH_TCLCONFIG
 365     if test -z "${no_tcl}"; then
 366         CY_AC_LOAD_TCLCONFIG
 367         CY_AC_PATH_TKCONFIG
 368
 369         # If $no_tk is nonempty, then we can't do Tk, and there is no
 370         # point to doing Tcl.
 371         if test -z "${no_tk}"; then
 372            CY_AC_LOAD_TKCONFIG
 373            CY_AC_PATH_TCLH
 374            CY_AC_PATH_TKH
 375            CY_AC_PATH_ITCLH
 376            CY_AC_PATH_TIX
 377
 378            # now look for tix library stuff
 379            TIXVERSION=4.1.8.0
 380            . ${ac_cv_c_tclconfig}/tclConfig.sh
 381            case "${host}" in
 382            *-*-cygwin32*)
 383                 tixdir=../tix/win/tcl8.0
 384                 ;;
 385            *)
 386                 tixdir=../tix/unix/tk8.0
 387                 ;;
 388            esac
 389            if test "${TCL_SHARED_BUILD}" = "1"; then
 390                 TIX_LIB_EXT="${TCL_SHLIB_SUFFIX}"
 391
 392                 # Can't win them all: SunOS 4 (others?) appends a version
 393                 # number after the ".so"
 394                 case "${host}" in
 395                 *-*-sunos4*)
 396                     TIX_LIB_EXT="${TIX_LIB_EXT}.1.0" ;;
 397                 esac
 398
 399            else
 400                 TIX_LIB_EXT=".a"
 401            fi
 402
 403            if test "${TCL_LIB_VERSIONS_OK}" = "ok"; then
 404                 TIXLIB="-L${tixdir} -ltix${TIXVERSION}"
 405                 TIX_DEPS="${tixdir}/libtix${TIXVERSION}${TIX_LIB_EXT}"
 406            else
 407                 TIXLIB="-L${tixdir} -ltix`echo ${TIXVERSION} | tr -d .`"
 408                 TIX_DEPS="${tixdir}/libtix`echo ${TIXVERSION} | tr -d .`${TIX_LIB_EXT}"
 409            fi
 410
 411            ENABLE_GDBTK=1
 412            ENABLE_CFLAGS="${ENABLE_CFLAGS} -DGDBTK"
 413
 414            # Include some libraries that Tcl and Tk want.
 415            if test "${enable_ide}" = "yes"; then
 416               TCL_LIBS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 417               CONFIG_DEPS='$(LIBIDETCL) $(LIBIDE) $(LIBGUI) $(IDE_DEPS) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 418            else
 419               TCL_LIBS='$(LIBGUI) $(ITCL) $(TIX) $(TK) $(TCL) $(X11_LDFLAGS) $(X11_LIBS)'
 420               CONFIG_DEPS='$(LIBGUI) $(ITCL_DEPS) $(TIX_DEPS) $(TK_DEPS) $(TCL_DEPS)'
 421            fi
 422            # Yes, the ordering seems wrong here.  But it isn't.
 423            # TK_LIBS is the list of libraries that need to be linked
 424            # after Tcl/Tk.  Note that this isn't put into LIBS.  If it
 425            # were in LIBS then any link tests after this point would
 426            # try to include things like `$(LIBGUI)', which wouldn't work.
 427            GDBTKLIBS="${TCL_LIBS} ${TK_LIBS}"
 428            CONFIG_OBS="${CONFIG_OBS} gdbtk.o"
 429
 430            if test x$gdb_cv_os_cygwin32 = xyes; then
 431               WIN32LIBS="${WIN32LIBS} -lshell32 -lgdi32 -lcomdlg32 -ladvapi32 -luser32"
 432               WIN32LDAPP="-Wl,--subsystem,console"
 433               CONFIG_OBS="${CONFIG_OBS} gdbres.o"
 434            fi
 435         fi
 436     fi
 437 fi
 438
 439 AC_SUBST(ENABLE_GDBTK)
 440 AC_SUBST(X_CFLAGS)
 441 AC_SUBST(X_LDFLAGS)
 442 AC_SUBST(X_LIBS)
 443 AC_SUBST(TIXLIB)
 444 AC_SUBST(TIX_DEPS)
 445 AC_SUBST(GDBTKLIBS)
 446 # end-sanitize-gdbtk
 447
 448 AC_PATH_X
 449 # start-sanitize-sky
 450 # Enable GPU2 library for MIPS simulator
 451 AC_ARG_WITH(sim-gpu2,
 452 [  --with-sim-gpu2=path                 Use GPU2 library under given directory],
 453 [case "${target}" in
 454   mips*-sky-*)
 455     if test -d "${withval}"
 456     then
 457       LIBS="${LIBS} -L${withval}/lib -lgpu2 -L${x_libraries} -lX11 -lXext"
 458     else
 459       AC_MSG_WARN([Directory ${withval} does not exist.])
 460     fi ;;
 461   *)  AC_MSG_WARN([--with-sim-gpu2 option invalid for target ${target}])
 462 esac])dnl
 463
 464 # Enable target accurate FP library
 465 AC_ARG_WITH(sim-funit,
 466 [  --with-sim-funit=path                Use target FP lib under given directory],
 467 [case "${target}" in
 468   mips*-sky-*)
 469     if test -d "${withval}"
 470     then
 471       LIBS="${LIBS} -L${withval}/lib -lfunit"
 472     else
 473       AC_MSG_WARN([Directory ${withval} does not exist.])
 474     fi ;;
 475   *)  AC_MSG_WARN([--with-sim-funit option invalid for target ${target}])
 476 esac])dnl
 477 # end-sanitize-sky
 478
 479 dnl Solaris puts wctype in /usr/lib/libw.a
 480 AC_CHECK_LIB(w, wctype, [LIBS="$LIBS -lw"])
 481
 482 AC_SUBST(ENABLE_CFLAGS)
 483
 484 AC_SUBST(CONFIG_OBS)
 485 AC_SUBST(CONFIG_DEPS)
 486 AC_SUBST(CONFIG_SRCS)
 487
 488 # Begin stuff to support --enable-shared
 489 AC_ARG_ENABLE(shared,
 490 [  --enable-shared         use shared libraries],
 491 [case "${enableval}" in
 492   yes) shared=true ;;
 493   no)  shared=false ;;
 494   *) shared=true ;;
 495 esac])dnl
 496
 497 HLDFLAGS=
 498 HLDENV=
 499 # If we have shared libraries, try to set rpath reasonably.
 500 if test "${shared}" = "true"; then
 501   case "${host}" in
 502   *-*-hpux*)
 503     HLDFLAGS='-Wl,+s,+b,$(libdir)'
 504     ;;
 505   *-*-irix5* | *-*-irix6*)
 506     HLDFLAGS='-Wl,-rpath,$(libdir)'
 507     ;;
 508   *-*-linux*aout*)
 509     ;;
 510   *-*-linux* | *-pc-linux-gnu)
 511     HLDFLAGS='-Wl,-rpath,$(libdir)'
 512     ;;
 513   *-*-solaris*)
 514     HLDFLAGS='-R $(libdir)'
 515     ;;
 516   *-*-sysv4*)
 517     HLDENV='if test -z "$${LD_RUN_PATH}"; then LD_RUN_PATH=$(libdir); else LD_RUN_PATH=$${LD_RUN_PATH}:$(libdir); fi; export LD_RUN_PATH;'
 518     ;;
 519   esac
 520 fi
 521
 522 # On SunOS, if the linker supports the -rpath option, use it to
 523 # prevent ../bfd and ../opcodes from being included in the run time
 524 # search path.
 525 case "${host}" in
 526   *-*-sunos*)
 527     echo 'main () { }' > conftest.c
 528     ${CC} -o conftest -Wl,-rpath= conftest.c >/dev/null 2>conftest.t
 529     if grep 'unrecognized' conftest.t >/dev/null 2>&1; then
 530       :
 531     elif grep 'No such file' conftest.t >/dev/null 2>&1; then
 532       :
 533     elif grep 'do not mix' conftest.t >/dev/null 2>&1; then
 534       :
 535     elif grep 'some text already loaded' conftest.t >/dev/null 2>&1; then
 536       :
 537     elif test "${shared}" = "true"; then
 538       HLDFLAGS='-Wl,-rpath=$(libdir)'
 539     else
 540       HLDFLAGS='-Wl,-rpath='
 541     fi
 542     rm -f conftest.t conftest.c conftest
 543     ;;
 544 esac
 545 AC_SUBST(HLDFLAGS)
 546 AC_SUBST(HLDENV)
 547 # End stuff to support --enable-shared
 548
 549 # target_subdir is used by the testsuite to find the target libraries.
 550 target_subdir=
 551 if test "${host}" != "${target}"; then
 552     target_subdir="${target_alias}/"
 553 fi
 554 AC_SUBST(target_subdir)
 555
 556 frags=
 557 host_makefile_frag=${srcdir}/config/${gdb_host_cpu}/${gdb_host}.mh
 558 if test ! -f ${host_makefile_frag}; then
 559 AC_MSG_ERROR("*** Gdb does not support host ${host}")
 560 fi
 561 frags="$frags $host_makefile_frag"
 562
 563 target_makefile_frag=${srcdir}/config/${gdb_target_cpu}/${gdb_target}.mt
 564 if test ! -f ${target_makefile_frag}; then
 565 AC_MSG_ERROR("*** Gdb does not support target ${target}")
 566 fi
 567 frags="$frags $target_makefile_frag"
 568
 569 AC_SUBST_FILE(host_makefile_frag)
 570 AC_SUBST_FILE(target_makefile_frag)
 571 AC_SUBST(frags)
 572
 573 changequote(,)dnl
 574 hostfile=`sed -n '
 575 s/XM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 576 ' ${host_makefile_frag}`
 577
 578 targetfile=`sed -n '
 579 s/TM_FILE[      ]*=[    ]*\([^  ]*\)/\1/p
 580 ' ${target_makefile_frag}`
 581
 582 # these really aren't orthogonal true/false values of the same condition,
 583 # but shells are slow enough that I like to reuse the test conditions
 584 # whenever possible
 585 if test "${target}" = "${host}"; then
 586 nativefile=`sed -n '
 587 s/NAT_FILE[     ]*=[    ]*\([^  ]*\)/\1/p
 588 ' ${host_makefile_frag}`
 589 # else
 590 # GDBserver is only useful in a "native" enviroment
 591 # configdirs=`echo $configdirs | sed 's/gdbserver//'`
 592 fi
 593 changequote([,])
 594
 595 # If hostfile (XM_FILE) and/or targetfile (TM_FILE) and/or nativefile
 596 # (NAT_FILE) is not set in config/*/*.m[ht] files, we don't make the
 597 # corresponding links.  But we have to remove the xm.h files and tm.h
 598 # files anyway, e.g. when switching from "configure host" to
 599 # "configure none".
 600
 601 files=
 602 links=
 603 rm -f xm.h
 604 if test "${hostfile}" != ""; then
 605 files="${files} config/${gdb_host_cpu}/${hostfile}"
 606 links="${links} xm.h"
 607 fi
 608 rm -f tm.h
 609 if test "${targetfile}" != ""; then
 610 files="${files} config/${gdb_target_cpu}/${targetfile}"
 611 links="${links} tm.h"
 612 fi
 613 rm -f nm.h
 614 if test "${nativefile}" != ""; then
 615 files="${files} config/${gdb_host_cpu}/${nativefile}"
 616 links="${links} nm.h"
 617 else
 618 # A cross-only configuration.
 619 files="${files} config/nm-empty.h"
 620 links="${links} nm.h"
 621 fi
 622 # start-sanitize-gdbtk
 623 AC_PROG_LN_S
 624 # Make it possible to use the GUI without doing a full install
 625 if test "${enable_gdbtk}" = "yes" -a ! -d gdbtcl ; then
 626   if test "$LN_S" = "ln -s" -a ! -f gdbtcl ; then
 627   echo linking $srcdir/gdbtcl to gdbtcl
 628   $LN_S $srcdir/gdbtcl gdbtcl
 629   else
 630   echo Warning: Unable to link $srcdir/gdbtcl to gdbtcl.  You will need to do a
 631   echo "         " make install before you are able to run the GUI.
 632   fi
 633 fi
 634 # end-sanitize-gdbtk
 635
 636 AC_LINK_FILES($files, $links)
 637
 638 dnl Check for exe extension set on certain hosts (e.g. Win32)
 639 AM_EXEEXT
 640
 641 AC_CONFIG_SUBDIRS($configdirs)
 642 AC_OUTPUT(Makefile .gdbinit:gdbinit.in,
 643 [
 644 dnl Autoconf doesn't provide a mechanism for modifying definitions
 645 dnl provided by makefile fragments.
 646 dnl
 647 if test "${nativefile}" = ""; then
 648 sed -e '/^NATDEPFILES[[         ]]*=[[  ]]*/s//# NATDEPFILES=/' \
 649         < Makefile > Makefile.tem
 650 mv -f Makefile.tem Makefile
 651 fi
 652
 653 changequote(,)dnl
 654 sed -e '/^TM_FILE[      ]*=/s,^TM_FILE[         ]*=[    ]*,&config/'"${gdb_target_cpu}"'/,
 655 /^XM_FILE[      ]*=/s,^XM_FILE[         ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,
 656 /^NAT_FILE[     ]*=/s,^NAT_FILE[        ]*=[    ]*,&config/'"${gdb_host_cpu}"'/,' <Makefile >Makefile.tmp
 657 mv -f Makefile.tmp Makefile
 658 changequote([,])dnl
 659
 660 case x$CONFIG_HEADERS in
 661 xconfig.h:config.in)
 662 echo > stamp-h ;;
 663 esac
 664 ],
 665 [
 666 gdb_host_cpu=$gdb_host_cpu
 667 gdb_target_cpu=$gdb_target_cpu
 668 nativefile=$nativefile
 669 ])
 670
 671 exit 0
 672