gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998-2014 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15 #
  16 # This file was written by Kendra.
  17
  18 #
  19 # Test debugging assembly level programs.
  20 # This file uses asmsrc[12].s for input.
  21 #
  22
  23
  24 set asm-arch ""
  25 set asm-note "empty"
  26 set asm-flags ""
  27 set link-flags "-e _start"
  28 set debug-flags ""
  29
  30 set obj_include -I[standard_output_file {}]
  31
  32 switch -glob -- [istarget] {
  33     "alpha*-*-*" {
  34         set asm-arch alpha
  35         # ??? Won't work with ecoff systems like Tru64, but then we also
  36         # don't have any other -g flag that creates mdebug output.
  37         set asm-flags "-no-mdebug -I${srcdir}/${subdir} $obj_include"
  38         set debug-flags "-gdwarf-2"
  39     }
  40     "arm*-*-*" {
  41         set asm-arch arm
  42     }
  43     "bfin-*-*" {
  44         set asm-arch bfin
  45     }
  46     "frv-*-*" {
  47         set asm-arch frv
  48     }
  49     "s390-*-*" {
  50         set asm-arch s390
  51     }
  52     "s390x-*-*" {
  53         set asm-arch s390x
  54     }
  55     "x86_64-*-*" {
  56         set asm-arch x86_64
  57         set debug-flags "-gdwarf-2"
  58     }
  59     "i\[3456\]86-*-*" {
  60         set asm-arch i386
  61     }
  62     "lm32-*" {
  63         set asm-arch lm32
  64     }
  65     "m32r*-linux*" {
  66         set asm-arch m32r-linux
  67     }
  68     "m32c-*-*" {
  69         set asm-arch m32c
  70     }
  71     "m32r*-*" {
  72         set asm-arch m32r
  73         append link-flags "--whole-archive -lgloss --no-whole-archive"
  74     }
  75     "m6811-*-*" {
  76         set asm-arch m68hc11
  77         set asm-flags "-mshort-double -m68hc11 --no-warn -I${srcdir}/${subdir} $obj_include"
  78         set debug-flags "-gdwarf-2"
  79         # This asm test is specific and uses the linker directly.
  80         # We must not use the target board linker script defined for other
  81         # tests.  Remove it and restore it later on.
  82         set board [target_info name]
  83         set old_ldscript [board_info $board ldscript]
  84         unset_board_info "ldscript"
  85     }
  86     "m6812-*-*" {
  87         set asm-arch m68hc11
  88         set asm-flags "-mshort-double -m68hc12 --no-warn -I${srcdir}/${subdir} $obj_include"
  89         set debug-flags "-gdwarf-2"
  90         # This asm test is specific and uses the linker directly.
  91         # We must not use the target board linker script defined for other
  92         # tests.  Remove it and restore it later on.
  93         set board [target_info name]
  94         set old_ldscript [board_info $board ldscript]
  95         set_board_info ldscript ""
  96     }
  97     "mips*-*" {
  98         set asm-arch mips
  99     }
 100     "powerpc*-*" {
 101         if { [is_lp64_target] } {
 102             set asm-arch powerpc64
 103             set asm-flags "-a64 -I${srcdir}/${subdir} $obj_include"
 104             append link-flags " -m elf64ppc"
 105         } else {
 106             set asm-arch powerpc
 107             set asm-flags "-a32 -I${srcdir}/${subdir} $obj_include"
 108             append link-flags " -m elf32ppc"
 109         }
 110     }
 111     "sh*-*-*" {
 112         set asm-arch sh
 113         set debug-flags "-gdwarf-2"
 114     }
 115     "sparc-*-*" {
 116         set asm-arch sparc
 117     }
 118     "sparc64-*-*" {
 119         set asm-arch sparc64
 120         set asm-flags "-xarch=v9 -I${srcdir}/${subdir} $obj_include"
 121         set debug-flags "-gdwarf-2"
 122     }
 123     "spu*-*-*" {
 124        set asm-arch spu
 125        set asm-flags "-I${srcdir}/${subdir} $obj_include --no-warn"
 126        set debug-flags "-gdwarf-2"
 127     }
 128     "xstormy16-*-*" {
 129         set asm-arch xstormy16
 130         set debug-flags "-gdwarf-2"
 131     }
 132     "v850-*-*" {
 133         set asm-arch v850
 134         set gdb_wrapper_initialized 1
 135     }
 136     "m68k-*-*" {
 137         set asm-arch m68k
 138     }
 139     "ia64-*-*" {
 140         set asm-arch ia64
 141         set debug-flags "-gdwarf-2"
 142     }
 143     "iq2000-*-*" {
 144         set asm-arch iq2000
 145     }
 146     "hppa*-linux-*" {
 147         set asm-arch pa
 148         set debug-flags "-gdwarf-2"
 149     }
 150     "hppa-*-openbsd*" {
 151         set asm-arch pa
 152         set debug-flags "-gdwarf-2"
 153     }
 154     "hppa64-*-hpux*" {
 155         set asm-arch pa64
 156         set debug-flags "-gdwarf-2"
 157     }
 158     "h83*-*" {
 159         set asm-arch h8300
 160         set debug-flags "-gdwarf-2"
 161     }
 162 }
 163
 164 if { "${asm-arch}" == "" } {
 165     untested asm-source.exp
 166     return -1
 167 }
 168
 169 # On NetBSD/ELF we need a special NetBSD-identifying note section.
 170 if { [istarget "*-*-netbsdelf*"]
 171      || [istarget "alpha-*-netbsd*"]
 172      || [istarget "mips*-*-netbsd*"]
 173      || [istarget "powerpc-*-netbsd*"]
 174      || [istarget "x86_64-*-netbsd*"] } then {
 175     set asm-note "netbsd"
 176 }
 177
 178 # On OpenBSD/ELF we need a similar note section.  We make no attempt
 179 # of handing a.out here since most OpenBSD/a.out systems use a rather
 180 # outdated assembler that doesn't assemble this test's code anyway.
 181 if { [istarget "*-*-openbsd*"] } then {
 182     set asm-note "openbsd"
 183 }
 184
 185 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 186 # switches according to compiler syntax.  If we pass these options straight
 187 # to the assembler, they won't always make sense.  If we don't pass them to
 188 # the assembler, the final link will complain that the object files were
 189 # built with different defaults.  So no matter what we do, we lose.  We may as
 190 # well get out of this test sooner rather than later.
 191 set dest [target_info name]
 192 if [board_info $dest exists multilib_flags] {
 193         set multilib_flags [board_info $dest multilib_flags]
 194         if { "${multilib_flags}" != "" } {
 195            untested asm-source.exp
 196            return -1
 197            return
 198          }
 199 }
 200
 201 standard_testfile asmsrc1.s asmsrc2.s
 202
 203 set arch_inc [standard_output_file arch.inc]
 204 set note_inc [standard_output_file note.inc]
 205
 206 remote_exec build "rm -f $arch_inc"
 207 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc $arch_inc
 208 remote_exec build "rm -f $note_inc"
 209 remote_download host ${srcdir}/${subdir}/${asm-note}.inc $note_inc
 210
 211 if { [string equal ${asm-flags} ""] } {
 212     set asm-flags "-I${srcdir}/${subdir} $obj_include"
 213 }
 214
 215 if { [string equal ${debug-flags} ""] } {
 216     set debug-flags "-gstabs"
 217 }
 218
 219 # Allow the target board to override the debug flags.
 220 if { [board_info $dest exists debug_flags] } then {
 221     set debug-flags "[board_info $dest debug_flags]"
 222 }
 223
 224 # The debug flags are in the format that gcc expects:
 225 # "-gdwarf-2", "-gstabs+", or "-gstabs".  To be compatible with the
 226 # other languages in the test suite, we accept this input format.
 227 # So the user can run the test suite with:
 228 #
 229 #   runtest --target_board unix/gdb:debug_flags=-gdwarf-2
 230 #   make check RUNTESTFLAGS="--target_board unix/gdb:debug_flags=-gdwarf-2"
 231 #
 232 # However, the GNU assembler has different spellings than gcc.
 233 # So I adjust the debug flags here.
 234
 235 # The GNU assembler spells "dwarf-2" as "dwarf2".
 236 regsub "--" "-gdwarf-2" "${debug-flags}" "-gdwarf2" debug-flags
 237
 238 # The GNU assembler before 2.15 did not support "stabs+".
 239 regsub "--" "-gstabs\[+\]" "${debug-flags}" "-gstabs" debug-flags
 240
 241 # The GNU assembler does not support level options like "-g2" or "-g3".
 242 regsub "--" "-g\[0-9\]" "${debug-flags}" "" debug-flags
 243
 244 set asm1obj [standard_output_file asmrc1.o]
 245 set asm2obj [standard_output_file asmrc2.o]
 246
 247 if {[target_assemble ${srcdir}/${subdir}/${srcfile} $asm1obj "${asm-flags} ${debug-flags}"] != ""} then {
 248      untested asm-source.exp
 249      return -1
 250 }
 251 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} $asm2obj "${asm-flags} ${debug-flags}"] != ""} then {
 252      untested asm-source.exp
 253      return -1
 254 }
 255
 256 # We deliberately don't use gdb_compile here to link together the
 257 # assembled object files.  Using gdb_compile, and therefore the C
 258 # compiler, is conceptually wrong, since we're testing raw assembler
 259 # code here that provides its own startup code.  Using target_link
 260 # also avoids a lot of problems on many systems, most notably on
 261 # *-*-*bsd* and *-*-solaris2*.
 262 if {[target_link [list $asm1obj $asm2obj] "${binfile}" ${link-flags}] != "" } then {
 263      untested asm-source.exp
 264      return -1
 265 }
 266
 267 # Restore the target board linker script for HC11/HC12.
 268 if { [istarget "m6811-*-*"] || [istarget "m6812-*-*"] } {
 269     set_board_info ldscript $old_ldscript
 270 }
 271
 272 # Collect some line numbers.
 273 set line_main       [expr [gdb_get_line_number "main start" "asmsrc1.s"] + 1]
 274 set line_call_foo2  [expr [gdb_get_line_number "call foo2"  "asmsrc1.s"] + 1]
 275 set line_search_comment [expr [gdb_get_line_number "search" "asmsrc1.s"] + 1]
 276 set line_foo3       [expr [gdb_get_line_number "foo3 start" "asmsrc1.s"] + 1]
 277 set line_main_exit  [expr [gdb_get_line_number "main exit"  "asmsrc1.s"] + 1]
 278 set line_foo2       [expr [gdb_get_line_number "foo2 start" "asmsrc2.s"] + 1]
 279 set line_call_foo3  [expr [gdb_get_line_number "call foo3"  "asmsrc2.s"] + 1]
 280 set line_call_foo3_again [expr $line_call_foo3 + 1]
 281 set line_foo2_leave [expr [gdb_get_line_number "foo2 leave" "asmsrc2.s"] + 1]
 282
 283 gdb_start
 284 gdb_reinitialize_dir $srcdir/$subdir
 285 gdb_load ${binfile}
 286
 287 #
 288 # Run to `main' where we begin our tests.
 289 #
 290
 291 if ![runto_main] then {
 292     gdb_suppress_tests
 293 }
 294
 295 # Execute the `f' command and see if the result includes source info.
 296 gdb_test "f" "asmsrc1\[.\]s:$line_main.*several_nops" "f at main"
 297
 298 # See if we properly `next' over a macro with several insns.
 299 gdb_test "n" "$line_call_foo2\[         \]*.*foo2" "next over macro"
 300
 301 # See if we can properly `step' into a subroutine call.
 302 gdb_test "s" "$line_foo2\[      \]*.*" "step into foo2"
 303
 304 # Test 'info target', and incidentally capture the entry point address.
 305 set entry_point 0
 306 gdb_test_multiple "info target" "info target" {
 307     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 308         set entry_point $expect_out(1,string)
 309         pass "info target"
 310     }
 311 }
 312
 313 # Capture the start symbol (may be '_start' or 'start')
 314 set entry_symbol ""
 315 gdb_test_multiple "info symbol 0x$entry_point" "info symbol" {
 316     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 317         # We match the echoed `info symbol' command here, to help us
 318         # reliably identify the beginning of the start symbol in the
 319         # command's output.  You might think we could just use '^' to
 320         # start matching at the beginning of the line, but
 321         # unfortunately, in Expect, '^' matches the beginning of the
 322         # input that hasn't been matched by any expect clause yet.  If
 323         # every expect clause consumes a complete line, along with its
 324         # terminating CR/LF, this is equivalent to the beginning of a
 325         # line.  But expect clauses that end with `.*' will consume as
 326         # much as happened to arrive from the TTY --- exactly where
 327         # they leave you depends on inter-process timing.  :(
 328         set entry_symbol $expect_out(1,string)
 329         pass "info symbol"
 330     }
 331 }
 332
 333 # Now try a 'list' from the other source file.
 334 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 335
 336 # Now try a source file search
 337 gdb_test "search A routine for foo2 to call" \
 338         "$line_search_comment\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 339
 340 # See if `f' prints the right source file.
 341 gdb_test "f" ".*asmsrc2\[.\]s:$line_foo2.*" "f in foo2"
 342
 343 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 344 gdb_test "n" "$line_call_foo3\[         \]*.*foo3" "n in foo2"
 345
 346 # See if a simple `bt' prints the right source files and
 347 # doesn't fall off the stack.
 348
 349 gdb_test "bt 10" \
 350         "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2" \
 351         "bt ALL in foo2"
 352
 353 # See if a capped `bt' prints the right source files.
 354 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 2 in foo2"
 355
 356 # Step into another subroutine which lives back in the first source file.
 357 gdb_test "s" ".*" "s 2"
 358
 359 # Next over insns to set up the stack frame.
 360 gdb_test "n" ".*" "n 2"
 361
 362 # Now see if a capped `bt' is correct.
 363 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:$line_foo3.*\#1.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#2.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 3 in foo3"
 364
 365 # Try 'info source' from asmsrc1.s
 366 gdb_test "info source" \
 367         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 368         "info source asmsrc1.s"
 369
 370 # Try 'finishing' from foo3
 371 # Some architectures will have one or more instructions after the
 372 # call instruction which still is part of the call sequence, so we
 373 # must be prepared for a "finish" to show us the caller line
 374 # again as well as the statement after.
 375 gdb_test_multiple "finish" "finish from foo3" {
 376     -re "Run till exit from.*\[\r\n\]$line_call_foo3\[ \t\]+gdbasm_call foo3.*$gdb_prompt $" {
 377         pass "finish from foo3"
 378         gdb_test "s" ".*" "s after finish"
 379     }
 380     -re "Run till exit from.*\[\r\n\]$line_call_foo3_again\[ \t\]+gdbasm_call foo3.*$gdb_prompt $" {
 381         pass "finish from foo3"
 382     }
 383 }
 384
 385 # Try 'info source' from asmsrc2.s
 386 gdb_test "info source" \
 387         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 388         "info source asmsrc2.s"
 389
 390 # Try 'info sources'.  This can produce a lot of output on systems
 391 # with dynamic linking, where the system's shared libc was compiled
 392 # with debugging info; for example, on Linux, this produces 47kb of
 393 # output.  So we consume it as we go.
 394 set seen_asmsrc_1 0
 395 set seen_asmsrc_2 0
 396 gdb_test_multiple "info sources" "info sources" {
 397     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 398         set seen_asmsrc_1 1
 399         exp_continue
 400     }
 401     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 402         set seen_asmsrc_2 1
 403         exp_continue
 404     }
 405     -re ", " {
 406         exp_continue
 407     }
 408     -re "$gdb_prompt $" {
 409         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 410             pass "info sources"
 411         } else {
 412             fail "info sources"
 413         }
 414     }
 415 }
 416
 417
 418 # Try 'info line'
 419 gdb_test "info line" \
 420         "Line $line_call_foo3_again of.*asmsrc2.s.*starts at.*<\\.?foo2+.*> and ends at.*<\\.?foo2+.*>." \
 421         "info line"
 422
 423 # Try 'nexting' over next call to foo3
 424 gdb_test "next" "$line_foo2_leave\[ \t\]+gdbasm_leave" "next over foo3"
 425
 426 # Try 'return' from foo2
 427 # Like "finish", "return" command also can return to the caller
 428 # line again or the statement after, depending on the architecture.
 429 gdb_test_multiple "return" "return from foo2" {
 430     -re "Make (foo2|selected stack frame) return now\?.*" {
 431         send_gdb "y\n"
 432         exp_continue
 433     }
 434     -re "\#0.*main .*$line_call_foo2\[ \t\]+gdbasm_call foo2.*$gdb_prompt $" {
 435         pass "return from foo2"
 436         gdb_test "s" ".*" "s after return"
 437     }
 438     -re "\#0.*main .*$line_main_exit\[ \t\]+gdbasm_exit0.*$gdb_prompt $" {
 439         pass "return from foo2"
 440     }
 441 }
 442
 443 # Disassemble something, check the output
 444 proc test_dis { command var } {
 445     global gdb_prompt
 446     gdb_test_multiple "${command}" "${command}" {
 447         -re "${var}.*:.*(Cannot access|Bad address)" {
 448             # The "disassembler" was only accessing the local
 449             # executable and that would cause attempts to disassemble
 450             # variables to fail (memory not valid).
 451             fail "${command} (memory read error)"
 452         }
 453         -re "${var}.*:.*${gdb_prompt}" {
 454             pass "${command}"
 455         }
 456     }
 457 }
 458
 459 # See if we can look at a global variable, three ways
 460 gdb_test "print globalvar" ".* = 11" "look at global variable"
 461 test_dis "x/i &globalvar" "globalvar"
 462 test_dis "disassem &globalvar, &globalvar+1" "globalvar"
 463
 464 # See if we can look at a static variable, three ways
 465 gdb_test "print staticvar" ".* = 5" "look at static variable"
 466 test_dis "x/i &staticvar" "staticvar"
 467 test_dis "disassem &staticvar, &staticvar+1" "staticvar"
 468
 469 # See if we can look at a static function
 470 gdb_test "disassem foostatic" ".*<\\+0>:.*End of assembler dump." \
 471         "look at static function"
 472
 473 remote_exec build "rm -f $arch_inc"
 474 remote_exec build "rm -f $note_inc"