gdb/testsuite/gdb.asm/asm-source.exp

   1 # Copyright 1998, 2000, 2001, 2002, 2003, 2004, 2007, 2008, 2009, 2010
   2 # Free Software Foundation, Inc.
   3 #
   4 # This program is free software; you can redistribute it and/or modify
   5 # it under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  12 # GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  16 #
  17 # This file was written by Kendra.
  18
  19 if $tracelevel then {
  20     strace $tracelevel
  21 }
  22
  23 #
  24 # Test debugging assembly level programs.
  25 # This file uses asmsrc[12].s for input.
  26 #
  27
  28
  29 set asm-arch ""
  30 set asm-note "empty"
  31 set asm-flags ""
  32 set link-flags "-e _start"
  33 set debug-flags ""
  34
  35 switch -glob -- [istarget] {
  36     "alpha*-*-*" {
  37         set asm-arch alpha
  38         # ??? Won't work with ecoff systems like Tru64, but then we also
  39         # don't have any other -g flag that creates mdebug output.
  40         set asm-flags "-no-mdebug -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  41         set debug-flags "-gdwarf-2"
  42     }
  43     "*arm-*-*" {
  44         set asm-arch arm
  45     }
  46     "xscale-*-*" {
  47         set asm-arch arm
  48     }
  49     "frv-*-*" {
  50         set asm-arch frv
  51     }
  52     "s390-*-*" {
  53         set asm-arch s390
  54     }
  55     "s390x-*-*" {
  56         set asm-arch s390x
  57     }
  58     "x86_64-*-*" {
  59         set asm-arch x86_64
  60         set debug-flags "-gdwarf-2"
  61     }
  62     "i\[3456\]86-*-*" {
  63         set asm-arch i386
  64     }
  65     "lm32-*" {
  66         set asm-arch lm32
  67     }
  68     "m32r*-linux*" {
  69         set asm-arch m32r-linux
  70     }
  71     "m32c-*-*" {
  72         set asm-arch m32c
  73     }
  74     "m32r*-*" {
  75         set asm-arch m32r
  76         append link-flags "--whole-archive -lgloss --no-whole-archive"
  77     }
  78     "m6811-*-*" {
  79         set asm-arch m68hc11
  80         set asm-flags "-mshort-double -m68hc11 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  81         set debug-flags "-gdwarf-2"
  82         # This asm test is specific and uses the linker directly.
  83         # We must not use the target board linker script defined for other
  84         # tests.  Remove it and restore it later on.
  85         set board [target_info name]
  86         set old_ldscript [board_info $board ldscript]
  87         unset_board_info "ldscript"
  88     }
  89     "m6812-*-*" {
  90         set asm-arch m68hc11
  91         set asm-flags "-mshort-double -m68hc12 --no-warn -I${srcdir}/${subdir} -I${objdir}/${subdir}"
  92         set debug-flags "-gdwarf-2"
  93         # This asm test is specific and uses the linker directly.
  94         # We must not use the target board linker script defined for other
  95         # tests.  Remove it and restore it later on.
  96         set board [target_info name]
  97         set old_ldscript [board_info $board ldscript]
  98         set_board_info ldscript ""
  99     }
 100     "mips*-*" {
 101         set asm-arch mips
 102     }
 103     "powerpc*-*" {
 104         set asm-arch powerpc
 105     }
 106     "sh*-*-*" {
 107         set asm-arch sh
 108         set debug-flags "-gdwarf-2"
 109     }
 110     "sparc-*-*" {
 111         set asm-arch sparc
 112     }
 113     "sparc64-*-*" {
 114         set asm-arch sparc64
 115         set asm-flags "-xarch=v9 -I${srcdir}/${subdir} -I${objdir}/${subdir}"
 116         set debug-flags "-gdwarf-2"
 117     }
 118     "spu*-*-*" {
 119        set asm-arch spu
 120        set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir} --no-warn"
 121        set debug-flags "-gdwarf-2"
 122     }
 123     "xstormy16-*-*" {
 124         set asm-arch xstormy16
 125         set debug-flags "-gdwarf-2"
 126     }
 127     "v850-*-*" {
 128         set asm-arch v850
 129         set gdb_wrapper_initialized 1
 130     }
 131     "m68k-*-*" {
 132         set asm-arch m68k
 133     }
 134     "ia64-*-*" {
 135         set asm-arch ia64
 136         set debug-flags "-gdwarf-2"
 137     }
 138     "iq2000-*-*" {
 139         set asm-arch iq2000
 140     }
 141     "hppa*-linux-*" {
 142         set asm-arch pa
 143         set debug-flags "-gdwarf-2"
 144     }
 145     "hppa-*-openbsd*" {
 146         set asm-arch pa
 147         set debug-flags "-gdwarf-2"
 148     }
 149     "hppa64-*-hpux*" {
 150         set asm-arch pa64
 151         set debug-flags "-gdwarf-2"
 152     }
 153     "h83*-*" {
 154         set asm-arch h8300
 155         set debug-flags "-gdwarf-2"
 156     }
 157 }
 158
 159 if { "${asm-arch}" == "" } {
 160     untested asm-source.exp
 161     return -1
 162 }
 163
 164 # On NetBSD/ELF we need a special NetBSD-identifying note section.
 165 if { [istarget "*-*-netbsdelf*"]
 166      || [istarget "alpha-*-netbsd*"]
 167      || [istarget "mips*-*-netbsd*"]
 168      || [istarget "powerpc-*-netbsd*"]
 169      || [istarget "x86_64-*-netbsd*"] } then {
 170     set asm-note "netbsd"
 171 }
 172
 173 # On OpenBSD/ELF we need a similar note section.  We make no attempt
 174 # of handing a.out here since most OpenBSD/a.out systems use a rather
 175 # outdated assembler that doesn't assemble this test's code anyway.
 176 if { [istarget "*-*-openbsd*"] } then {
 177     set asm-note "openbsd"
 178 }
 179
 180 # Watch out, we are invoking the assembler, but the testsuite sets multilib
 181 # switches according to compiler syntax.  If we pass these options straight
 182 # to the assembler, they won't always make sense.  If we don't pass them to
 183 # the assembler, the final link will complain that the object files were
 184 # built with different defaults.  So no matter what we do, we lose.  We may as
 185 # well get out of this test sooner rather than later.
 186 set dest [target_info name]
 187 if [board_info $dest exists multilib_flags] {
 188         set multilib_flags [board_info $dest multilib_flags]
 189         if { "${multilib_flags}" != "" } {
 190            untested asm-source.exp
 191            return -1
 192            return;
 193          }
 194 }
 195
 196 set testfile "asm-source"
 197 set binfile ${objdir}/${subdir}/${testfile}
 198 set srcfile1 asmsrc1.s
 199 set srcfile2 asmsrc2.s
 200
 201 remote_exec build "rm -f ${subdir}/arch.inc"
 202 remote_download host ${srcdir}/${subdir}/${asm-arch}.inc ${subdir}/arch.inc
 203 remote_exec build "rm -f ${subdir}/note.inc"
 204 remote_download host ${srcdir}/${subdir}/${asm-note}.inc ${subdir}/note.inc
 205
 206 if { [string equal ${asm-flags} ""] } {
 207     set asm-flags "-I${srcdir}/${subdir} -I${objdir}/${subdir}"
 208 }
 209
 210 if { [string equal ${debug-flags} ""] } {
 211     set debug-flags "-gstabs"
 212 }
 213
 214 # Allow the target board to override the debug flags.
 215 if { [board_info $dest exists debug_flags] } then {
 216     set debug-flags "[board_info $dest debug_flags]"
 217 }
 218
 219 # The debug flags are in the format that gcc expects:
 220 # "-gdwarf-2", "-gstabs+", or "-gstabs".  To be compatible with the
 221 # other languages in the test suite, we accept this input format.
 222 # So the user can run the test suite with:
 223 #
 224 #   runtest --target_board unix/gdb:debug_flags=-gdwarf-2
 225 #   make check RUNTESTFLAGS="--target_board unix/gdb:debug_flags=-gdwarf-2"
 226 #
 227 # However, the GNU assembler has different spellings than gcc.
 228 # So I adjust the debug flags here.
 229
 230 # The GNU assembler spells "dwarf-2" as "dwarf2".
 231 regsub "--" "-gdwarf-2" "${debug-flags}" "-gdwarf2" debug-flags
 232
 233 # The GNU assembler before 2.15 did not support "stabs+".
 234 regsub "--" "-gstabs\[+\]" "${debug-flags}" "-gstabs" debug-flags
 235
 236 # The GNU assembler does not support level options like "-g2" or "-g3".
 237 regsub "--" "-g\[0-9\]" "${debug-flags}" "" debug-flags
 238
 239 if {[target_assemble ${srcdir}/${subdir}/${srcfile1} asmsrc1.o "${asm-flags} ${debug-flags}"] != ""} then {
 240      untested asm-source.exp
 241      return -1
 242 }
 243 if {[target_assemble ${srcdir}/${subdir}/${srcfile2} asmsrc2.o "${asm-flags} ${debug-flags}"] != ""} then {
 244      untested asm-source.exp
 245      return -1
 246 }
 247
 248 # We deliberately don't use gdb_compile here to link together the
 249 # assembled object files.  Using gdb_compile, and therefore the C
 250 # compiler, is conceptually wrong, since we're testing raw assembler
 251 # code here that provides its own startup code.  Using target_link
 252 # also avoids a lot of problems on many systems, most notably on
 253 # *-*-*bsd* and *-*-solaris2*.
 254 if {[target_link "asmsrc1.o asmsrc2.o" "${binfile}" ${link-flags}] != "" } then {
 255      untested asm-source.exp
 256      return -1
 257 }
 258
 259 # Restore the target board linker script for HC11/HC12.
 260 if { [istarget "m6811-*-*"] || [istarget "m6812-*-*"] } {
 261     set_board_info ldscript $old_ldscript
 262 }
 263
 264 remote_exec build "mv asmsrc1.o asmsrc2.o ${objdir}/${subdir}"
 265
 266 # Collect some line numbers.
 267 set line_main       [expr [gdb_get_line_number "main start" "asmsrc1.s"] + 1]
 268 set line_call_foo2  [expr [gdb_get_line_number "call foo2"  "asmsrc1.s"] + 1]
 269 set line_search_comment [expr [gdb_get_line_number "search" "asmsrc1.s"] + 1]
 270 set line_foo3       [expr [gdb_get_line_number "foo3 start" "asmsrc1.s"] + 1]
 271 set line_main_exit  [expr [gdb_get_line_number "main exit"  "asmsrc1.s"] + 1]
 272 set line_foo2       [expr [gdb_get_line_number "foo2 start" "asmsrc2.s"] + 1]
 273 set line_call_foo3  [expr [gdb_get_line_number "call foo3"  "asmsrc2.s"] + 1]
 274 set line_call_foo3_again [expr $line_call_foo3 + 1]
 275 set line_foo2_leave [expr [gdb_get_line_number "foo2 leave" "asmsrc2.s"] + 1]
 276
 277 gdb_start
 278 gdb_reinitialize_dir $srcdir/$subdir
 279 gdb_load ${binfile}
 280
 281 #
 282 # Run to `main' where we begin our tests.
 283 #
 284
 285 if ![runto_main] then {
 286     gdb_suppress_tests
 287 }
 288
 289 # Execute the `f' command and see if the result includes source info.
 290 gdb_test "f" "asmsrc1\[.\]s:$line_main.*several_nops" "f at main"
 291
 292 # See if we properly `next' over a macro with several insns.
 293 gdb_test "n" "$line_call_foo2\[         \]*.*foo2" "next over macro"
 294
 295 # See if we can properly `step' into a subroutine call.
 296 gdb_test "s" "$line_foo2\[      \]*.*" "step into foo2"
 297
 298 # Test 'info target', and incidentally capture the entry point address.
 299 set entry_point 0
 300 gdb_test_multiple "info target" "info target" {
 301     -re "Symbols from .*asm-source.*Entry point: 0x(\[01232456789abcdefABCDEF\]+).*$gdb_prompt $" {
 302         set entry_point $expect_out(1,string)
 303         pass "info target"
 304     }
 305 }
 306
 307 # Capture the start symbol (may be '_start' or 'start')
 308 set entry_symbol ""
 309 gdb_test_multiple "info symbol 0x$entry_point" "info symbol" {
 310     -re "info symbol 0x$entry_point\[\r\n\]+(\[^\r\n\]*) in section .*$gdb_prompt $" {
 311         # We match the echoed `info symbol' command here, to help us
 312         # reliably identify the beginning of the start symbol in the
 313         # command's output.  You might think we could just use '^' to
 314         # start matching at the beginning of the line, but
 315         # unfortunately, in Expect, '^' matches the beginning of the
 316         # input that hasn't been matched by any expect clause yet.  If
 317         # every expect clause consumes a complete line, along with its
 318         # terminating CR/LF, this is equivalent to the beginning of a
 319         # line.  But expect clauses that end with `.*' will consume as
 320         # much as happened to arrive from the TTY --- exactly where
 321         # they leave you depends on inter-process timing.  :(
 322         set entry_symbol $expect_out(1,string)
 323         pass "info symbol"
 324     }
 325 }
 326
 327 # Now try a 'list' from the other source file.
 328 gdb_test "list $entry_symbol" ".*gdbasm_startup.*" "list"
 329
 330 # Now try a source file search
 331 gdb_test "search A routine for foo2 to call" \
 332         "$line_search_comment\[ \t\]+comment \"A routine for foo2 to call.\"" "search"
 333
 334 # See if `f' prints the right source file.
 335 gdb_test "f" ".*asmsrc2\[.\]s:$line_foo2.*" "f in foo2"
 336
 337 # `next' one insn (or macro) to set up our stackframe (for the following bt).
 338 gdb_test "n" "$line_call_foo3\[         \]*.*foo3" "n in foo2"
 339
 340 # See if a simple `bt' prints the right source files and
 341 # doesn't fall off the stack.
 342
 343 gdb_test "bt 10" \
 344         "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2" \
 345         "bt ALL in foo2"
 346
 347 # See if a capped `bt' prints the right source files.
 348 gdb_test "bt 2" "\#0.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#1.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 2 in foo2"
 349
 350 # Step into another subroutine which lives back in the first source file.
 351 gdb_test "s" ".*" "s 2"
 352
 353 # Next over insns to set up the stack frame.
 354 gdb_test "n" ".*" "n 2"
 355
 356 # Now see if a capped `bt' is correct.
 357 gdb_test "bt 3" "\#0.*foo3.*asmsrc1\[.\]s:$line_foo3.*\#1.*foo2.*asmsrc2\[.\]s:$line_call_foo3.*\#2.*main.*asmsrc1\[.\]s:$line_call_foo2.*" "bt 3 in foo3"
 358
 359 # Try 'info source' from asmsrc1.s
 360 gdb_test "info source" \
 361         "Current source file is .*asmsrc1.s.*Source language is asm.*" \
 362         "info source asmsrc1.s"
 363
 364 # Try 'finishing' from foo3
 365 gdb_test "finish" "Run till exit from.*\[\r\n\]$line_call_foo3_again\[ \t\]+gdbasm_call foo3" \
 366         "finish from foo3"
 367
 368 # Try 'info source' from asmsrc2.s
 369 gdb_test "info source" \
 370         "Current source file is .*asmsrc2.s.*Source language is asm.*" \
 371         "info source asmsrc2.s"
 372
 373 # Try 'info sources'.  This can produce a lot of output on systems
 374 # with dynamic linking, where the system's shared libc was compiled
 375 # with debugging info; for example, on Linux, this produces 47kb of
 376 # output.  So we consume it as we go.
 377 set seen_asmsrc_1 0
 378 set seen_asmsrc_2 0
 379 gdb_test_multiple "info sources" "info sources" {
 380     -re "^\[^,\]*asmsrc1.s(, |\[\r\n\]+)" {
 381         set seen_asmsrc_1 1
 382         exp_continue
 383     }
 384     -re "^\[^,\]*asmsrc2.s(, |\[\r\n\]+)" {
 385         set seen_asmsrc_2 1
 386         exp_continue
 387     }
 388     -re ", " {
 389         exp_continue
 390     }
 391     -re "$gdb_prompt $" {
 392         if {$seen_asmsrc_1 && $seen_asmsrc_2} {
 393             pass "info sources"
 394         } else {
 395             fail "info sources"
 396         }
 397     }
 398 }
 399
 400
 401 # Try 'info line'
 402 gdb_test "info line" \
 403         "Line $line_call_foo3_again of.*asmsrc2.s.*starts at.*<foo2+.*> and ends at.*<foo2+.*>." \
 404         "info line"
 405
 406 # Try 'nexting' over next call to foo3
 407 gdb_test "next" "$line_foo2_leave\[ \t\]+gdbasm_leave" "next over foo3"
 408
 409 # Try 'return' from foo2
 410 gdb_test "return" "\#0  main .*$line_main_exit\[ \t\]+gdbasm_exit0" "return from foo2" \
 411         "Make (foo2|selected stack frame) return now\?.*" "y"
 412
 413 # Disassemble something, check the output
 414 proc test_dis { command var } {
 415     global gdb_prompt
 416     gdb_test_multiple "${command}" "${command}" {
 417         -re "${var}.*:.*(Cannot access|Bad address)" {
 418             # The "disassembler" was only accessing the local
 419             # executable and that would cause attempts to disassemble
 420             # variables to fail (memory not valid).
 421             fail "${command} (memory read error)"
 422         }
 423         -re "${var}.*:.*${gdb_prompt}" {
 424             pass "${command}"
 425         }
 426     }
 427 }
 428
 429 # See if we can look at a global variable, three ways
 430 gdb_test "print globalvar" ".* = 11" "look at global variable"
 431 test_dis "x/i &globalvar" "globalvar"
 432 test_dis "disassem &globalvar, &globalvar+1" "globalvar"
 433
 434 # See if we can look at a static variable, three ways
 435 gdb_test "print staticvar" ".* = 5" "look at static variable"
 436 test_dis "x/i &staticvar" "staticvar"
 437 test_dis "disassem &staticvar, &staticvar+1" "staticvar"
 438
 439 # See if we can look at a static function
 440 gdb_test "disassem foostatic" ".*<\\+0>:.*End of assembler dump." \
 441         "look at static function"
 442
 443 remote_exec build "rm -f ${subdir}/arch.inc"
 444 remote_exec build "rm -f ${subdir}/note.inc"