gdb/testsuite/lib/ada.exp

   1 # Copyright 2004-2022 Free Software Foundation, Inc.
   2 #
   3 # This program is free software; you can redistribute it and/or modify
   4 # it under the terms of the GNU General Public License as published by
   5 # the Free Software Foundation; either version 3 of the License, or
   6 # (at your option) any later version.
   7 #
   8 # This program is distributed in the hope that it will be useful,
   9 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  10 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  11 # GNU General Public License for more details.
  12 #
  13 # You should have received a copy of the GNU General Public License
  14 # along with this program.  If not, see <http://www.gnu.org/licenses/>.
  15
  16 # Call target_compile with SOURCE DEST TYPE and OPTIONS as argument,
  17 # after having temporarily changed the current working directory to
  18 # BUILDDIR.
  19
  20 proc target_compile_ada_from_dir {builddir source dest type options} {
  21     set saved_cwd [pwd]
  22
  23     global board
  24     set board [target_info name]
  25     set save_multilib_flag [board_info $board multilib_flags]
  26     set multilib_flag ""
  27     foreach op $save_multilib_flag {
  28         if { $op == "-pie" || $op == "-no-pie" } {
  29             # Pretend gnatmake supports -pie/-no-pie, route it to
  30             # linker.
  31             append multilib_flag " -largs $op -margs"
  32         } else {
  33             append multilib_flag " $op"
  34         }
  35     }
  36     if { $multilib_flag != "" } {
  37         unset_board_info "multilib_flags"
  38         set_board_info multilib_flags "$multilib_flag"
  39     }
  40
  41     catch {
  42         cd $builddir
  43         return [target_compile $source $dest $type $options]
  44     } result options
  45     cd $saved_cwd
  46
  47     if { $save_multilib_flag != "" } {
  48         unset_board_info "multilib_flags"
  49         set_board_info multilib_flags $save_multilib_flag
  50     }
  51
  52     return -options $options $result
  53 }
  54
  55 # Compile some Ada code.  Return "" if the compile was successful.
  56
  57 proc gdb_compile_ada_1 {source dest type options} {
  58
  59     set srcdir [file dirname $source]
  60     set gprdir [file dirname $srcdir]
  61     set objdir [file dirname $dest]
  62
  63     file delete $dest
  64
  65     # Although strictly not necessary, we force the recompilation
  66     # of all units (additional_flags=-f).  This is what is done
  67     # when using GCC to build programs in the other languages,
  68     # and it avoids using a stray objfile file from a long-past
  69     # run, for instance.
  70     append options " ada"
  71     append options " additional_flags=-f"
  72     append options " additional_flags=-I$srcdir"
  73
  74     set result [target_compile_ada_from_dir \
  75                     $objdir [file tail $source] $dest $type $options]
  76
  77     # The Ada build always produces some output, even when the build
  78     # succeeds. Thus, we can not use the output the same way we do in
  79     # gdb_compile to determine whether the build has succeeded or not.
  80     # We therefore simply check whether the dest file has been created
  81     # or not. Unless not present, the build has succeeded.
  82     if [file exists $dest] { set result "" }
  83     return $result
  84 }
  85
  86 # Compile some Ada code.  Generate "PASS: foo.exp: compilation SOURCE" if the
  87 # compile was successful.
  88
  89 proc gdb_compile_ada {source dest type options} {
  90     set result [gdb_compile_ada_1 $source $dest $type $options]
  91
  92     gdb_compile_test $source $result
  93     return $result
  94 }
  95
  96 # Like standard_testfile, but for Ada.  Historically the Ada tests
  97 # used a different naming convention from many of the other gdb tests,
  98 # and this difference was preserved during the conversion to
  99 # standard_testfile.  DIR defaults to the base name of the test case;
 100 # but can be overridden to find sources in a different subdirectory of
 101 # gdb.ada.
 102
 103 proc standard_ada_testfile {base_file {dir ""}} {
 104     global gdb_test_file_name srcdir subdir
 105     global testdir testfile srcfile binfile
 106
 107     if {$dir == ""} {
 108         set testdir $gdb_test_file_name
 109     } else {
 110         set testdir $dir
 111     }
 112
 113     set testfile $base_file
 114     set srcfile $srcdir/$subdir/$testdir/$testfile.adb
 115     set binfile [standard_output_file $testfile]
 116 }
 117
 118 # A helper function to find the appropriate version of a tool.
 119 # TOOL is the tool's name, e.g., "gnatbind" or "gnatlink".
 120
 121 proc find_ada_tool {tool} {
 122     set upper [string toupper $tool]
 123
 124     set targname ${upper}_FOR_TARGET
 125     global $targname
 126     if {[info exists $targname]} {
 127         return $targname
 128     }
 129
 130     global tool_root_dir
 131     set root "$tool_root_dir/gcc"
 132     set result ""
 133
 134     if {![is_remote host]} {
 135         set result [lookfor_file $root $tool]
 136         if { $result != "" && $tool == "gnatlink" } {
 137             set result "$result --GCC=$root/xgcc -B$root"
 138         }
 139     }
 140
 141     if {$result == ""} {
 142         set result [transform $tool]
 143     }
 144
 145     return $result
 146 }
 147
 148 # Return 1 if gnatmake is at least version $MAJOR.x.x
 149
 150 proc gnatmake_version_at_least { major } {
 151     set gnatmake [gdb_find_gnatmake]
 152     set gnatmake [lindex [split $gnatmake] 0]
 153     if {[catch {exec $gnatmake --version} output]} {
 154         return 0
 155     }
 156     if { [regexp {GNATMAKE ([^ .]+).([^ .]+).([^ .]+)} $output \
 157               match gnatmake_major gnatmake_minor gnatmake_micro] } {
 158         if { $gnatmake_major >= $major } {
 159             return 1
 160         } else {
 161             return 0
 162         }
 163     }
 164
 165     # Unknown, return 1
 166     return 1
 167 }
 168
 169 # Return 1 if the GNAT runtime appears to have debug info.
 170
 171 gdb_caching_proc gnat_runtime_has_debug_info {
 172     global srcdir
 173
 174     set src "$srcdir/lib/gnat_debug_info_test.adb"
 175     set dst [standard_output_file "gnat_debug_info_test"]
 176
 177     if { [gdb_compile_ada_1 $src $dst executable {debug}] != "" } {
 178         return 0
 179     }
 180
 181     clean_restart $dst
 182
 183     if { ! [runto "GNAT_Debug_Info_Test"] } {
 184         return 0
 185     }
 186
 187     set has_debug_info 0
 188
 189     gdb_test_multiple "whatis __gnat_debug_raise_exception" "" {
 190         -re -wrap "type = <text variable, no debug info>" { }
 191         -re -wrap "type = void" {
 192             set has_debug_info 1
 193         }
 194         default {
 195             # Some other unexpected output...
 196             fail $gdb_test_name
 197         }
 198     }
 199
 200     return $has_debug_info
 201 }