gdb/warning.m4

   1 dnl Autoconf configure script for GDB, the GNU debugger.
   2 dnl Copyright (C) 1995-2018 Free Software Foundation, Inc.
   3 dnl
   4 dnl This file is part of GDB.
   5 dnl
   6 dnl This program is free software; you can redistribute it and/or modify
   7 dnl it under the terms of the GNU General Public License as published by
   8 dnl the Free Software Foundation; either version 3 of the License, or
   9 dnl (at your option) any later version.
  10 dnl
  11 dnl This program is distributed in the hope that it will be useful,
  12 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 dnl GNU General Public License for more details.
  15 dnl
  16 dnl You should have received a copy of the GNU General Public License
  17 dnl along with this program.  If not, see <http://www.gnu.org/licenses/>.
  18
  19 AC_DEFUN([AM_GDB_WARNINGS],[
  20 AC_ARG_ENABLE(werror,
  21   AS_HELP_STRING([--enable-werror], [treat compile warnings as errors]),
  22   [case "${enableval}" in
  23      yes | y) ERROR_ON_WARNING="yes" ;;
  24      no | n)  ERROR_ON_WARNING="no" ;;
  25      *) AC_MSG_ERROR(bad value ${enableval} for --enable-werror) ;;
  26    esac])
  27
  28 # Enable -Werror by default when using gcc.  Turn it off for releases.
  29 if test "${GCC}" = yes -a -z "${ERROR_ON_WARNING}" && $development; then
  30     ERROR_ON_WARNING=yes
  31 fi
  32
  33 WERROR_CFLAGS=""
  34 if test "${ERROR_ON_WARNING}" = yes ; then
  35     WERROR_CFLAGS="-Werror"
  36 fi
  37
  38 # The options we'll try to enable.
  39 build_warnings="-Wall -Wpointer-arith \
  40 -Wno-unused -Wunused-value -Wunused-function \
  41 -Wno-switch -Wno-char-subscripts \
  42 -Wempty-body -Wunused-but-set-parameter -Wunused-but-set-variable \
  43 -Wno-sign-compare -Wno-narrowing -Wno-error=maybe-uninitialized \
  44 -Wno-mismatched-tags"
  45
  46 case "${host}" in
  47   *-*-mingw32*)
  48     # Enable -Wno-format by default when using gcc on mingw since many
  49     # GCC versions complain about %I64.
  50     build_warnings="$build_warnings -Wno-format" ;;
  51   *-*-solaris*)
  52     # Solaris 11.4 <python2.7/ceval.h> uses #pragma no_inline that GCC
  53     # doesn't understand.
  54     build_warnings="$build_warnings -Wno-unknown-pragmas"
  55     # Solaris 11 <unistd.h> marks vfork deprecated.
  56     build_warnings="$build_warnings -Wno-deprecated-declarations" ;;
  57   *) build_warnings="$build_warnings -Wformat-nonliteral" ;;
  58 esac
  59
  60 AC_ARG_ENABLE(build-warnings,
  61 AS_HELP_STRING([--enable-build-warnings], [enable build-time compiler warnings if gcc is used]),
  62 [case "${enableval}" in
  63   yes)  ;;
  64   no)   build_warnings="-w";;
  65   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  66         build_warnings="${build_warnings} ${t}";;
  67   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  68         build_warnings="${t} ${build_warnings}";;
  69   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  70 esac
  71 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  72   echo "Setting compiler warning flags = $build_warnings" 6>&1
  73 fi])dnl
  74 AC_ARG_ENABLE(gdb-build-warnings,
  75 AS_HELP_STRING([--enable-gdb-build-warnings], [enable GDB specific build-time compiler warnings if gcc is used]),
  76 [case "${enableval}" in
  77   yes)  ;;
  78   no)   build_warnings="-w";;
  79   ,*)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  80         build_warnings="${build_warnings} ${t}";;
  81   *,)   t=`echo "${enableval}" | sed -e "s/,/ /g"`
  82         build_warnings="${t} ${build_warnings}";;
  83   *)    build_warnings=`echo "${enableval}" | sed -e "s/,/ /g"`;;
  84 esac
  85 if test x"$silent" != x"yes" && test x"$build_warnings" != x""; then
  86   echo "Setting GDB specific compiler warning flags = $build_warnings" 6>&1
  87 fi])dnl
  88
  89 # The set of warnings supported by a C++ compiler is not the same as
  90 # of the C compiler.
  91 AC_LANG_PUSH([C++])
  92
  93 WARN_CFLAGS=""
  94 if test "x${build_warnings}" != x -a "x$GCC" = xyes
  95 then
  96     AC_MSG_CHECKING(compiler warning flags)
  97     # Separate out the -Werror flag as some files just cannot be
  98     # compiled with it enabled.
  99     for w in ${build_warnings}; do
 100         # GCC does not complain about -Wno-unknown-warning.  Invert
 101         # and test -Wunknown-warning instead.
 102         case $w in
 103         -Wno-*)
 104                 wtest=`echo $w | sed 's/-Wno-/-W/g'` ;;
 105         *)
 106                 wtest=$w ;;
 107         esac
 108
 109         case $w in
 110         -Werr*) WERROR_CFLAGS=-Werror ;;
 111         *)
 112             # Check whether GCC accepts it.
 113             saved_CFLAGS="$CFLAGS"
 114             CFLAGS="$CFLAGS -Werror $wtest"
 115             saved_CXXFLAGS="$CXXFLAGS"
 116             CXXFLAGS="$CXXFLAGS -Werror $wtest"
 117             AC_TRY_COMPILE([],[],WARN_CFLAGS="${WARN_CFLAGS} $w",)
 118             CFLAGS="$saved_CFLAGS"
 119             CXXFLAGS="$saved_CXXFLAGS"
 120         esac
 121     done
 122     AC_MSG_RESULT(${WARN_CFLAGS} ${WERROR_CFLAGS})
 123 fi
 124 AC_SUBST(WARN_CFLAGS)
 125 AC_SUBST(WERROR_CFLAGS)
 126
 127 AC_LANG_POP([C++])
 128 ])