ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2021 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26
  27 AM_INIT_AUTOMAKE
  28 AM_SILENT_RULES([yes])
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 ac_checking=
  42 . ${srcdir}/../bfd/development.sh
  43 test "$development" = true && ac_checking=yes
  44 AC_ARG_ENABLE(checking,
  45 [  --enable-checking       enable run-time checks],
  46 [case "${enableval}" in
  47   no|none)  ac_checking= ;;
  48   *)        ac_checking=yes ;;
  49 esac])dnl
  50 if test x$ac_checking != x ; then
  51   AC_DEFINE(ENABLE_CHECKING, 1, [Define if you want run-time sanity checks.])
  52 fi
  53
  54 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  55 AC_ARG_ENABLE(targets,
  56 [  --enable-targets        alternative target configurations],
  57 [case "${enableval}" in
  58   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  59             ;;
  60   no)       enable_targets= ;;
  61   *)        enable_targets=$enableval ;;
  62 esac])dnl
  63
  64 BFD_64_BIT
  65
  66 AC_ARG_WITH(sysroot,
  67 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  68 [
  69  case ${with_sysroot} in
  70  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  71  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  72  esac
  73
  74  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  75  use_sysroot=yes
  76
  77  if test "x$prefix" = xNONE; then
  78   test_prefix=/usr/local
  79  else
  80   test_prefix=$prefix
  81  fi
  82  if test "x$exec_prefix" = xNONE; then
  83   test_exec_prefix=$test_prefix
  84  else
  85   test_exec_prefix=$exec_prefix
  86  fi
  87  case ${TARGET_SYSTEM_ROOT} in
  88  "${test_prefix}"|"${test_prefix}/"*|\
  89  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  90  '${prefix}'|'${prefix}/'*|\
  91  '${exec_prefix}'|'${exec_prefix}/'*)
  92    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  93    TARGET_SYSTEM_ROOT_DEFINE="$t"
  94    ;;
  95  esac
  96 ], [
  97  use_sysroot=no
  98  TARGET_SYSTEM_ROOT=
  99  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
 100 ])
 101 AC_SUBST(use_sysroot)
 102 AC_SUBST(TARGET_SYSTEM_ROOT)
 103 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 104
 105 dnl Use --enable-gold to decide if this linker should be the default.
 106 dnl "install_as_default" is set to false if gold is the default linker.
 107 dnl "installed_linker" is the installed BFD linker name.
 108 AC_ARG_ENABLE(gold,
 109 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 110 [case "${enableval}" in
 111  default)
 112    install_as_default=no
 113    installed_linker=ld.bfd
 114    ;;
 115  yes|no)
 116    install_as_default=yes
 117    installed_linker=ld.bfd
 118    ;;
 119  *)
 120    AC_MSG_ERROR([invalid --enable-gold argument])
 121    ;;
 122  esac],
 123 [install_as_default=yes
 124  installed_linker=ld.bfd])
 125 AC_SUBST(install_as_default)
 126 AC_SUBST(installed_linker)
 127
 128 AC_ARG_ENABLE([got],
 129 AS_HELP_STRING([--enable-got=<type>],
 130                [GOT handling scheme (target, single, negative, multigot)]),
 131 [case "${enableval}" in
 132   target | single | negative | multigot)  got_handling=$enableval ;;
 133   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 134 esac],
 135 [got_handling=target])
 136
 137 case "${got_handling}" in
 138   target)
 139     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 140               [Define to choose default GOT handling scheme]) ;;
 141   single)
 142     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 143               [Define to choose default GOT handling scheme]) ;;
 144   negative)
 145     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 146               [Define to choose default GOT handling scheme]) ;;
 147   multigot)
 148     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 149               [Define to choose default GOT handling scheme]) ;;
 150   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 151 esac
 152
 153 # PR gas/19109
 154 # Decide the default method for compressing debug sections.
 155 ac_default_compressed_debug_sections=unset
 156 # Provide a configure time option to override our default.
 157 AC_ARG_ENABLE(compressed_debug_sections,
 158               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 159               [compress debug sections by default])],
 160 [case ,"${enableval}", in
 161   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 162   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 163 esac])dnl
 164
 165 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 166 ac_default_new_dtags=unset
 167 # Provide a configure time option to override our default.
 168 AC_ARG_ENABLE(new_dtags,
 169               AS_HELP_STRING([--enable-new-dtags],
 170               [set DT_RUNPATH instead of DT_RPATH by default])],
 171 [case "${enableval}" in
 172   yes) ac_default_new_dtags=1 ;;
 173   no) ac_default_new_dtags=0 ;;
 174 esac])dnl
 175
 176 # Decide if -z relro should be enabled in ELF linker by default.
 177 ac_default_ld_z_relro=unset
 178 # Provide a configure time option to override our default.
 179 AC_ARG_ENABLE(relro,
 180               AS_HELP_STRING([--enable-relro],
 181               [enable -z relro in ELF linker by default]),
 182 [case "${enableval}" in
 183   yes)  ac_default_ld_z_relro=1 ;;
 184   no)  ac_default_ld_z_relro=0 ;;
 185 esac])dnl
 186
 187 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 188 ac_default_ld_textrel_check=unset
 189 AC_ARG_ENABLE([textrel-check],
 190               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 191                              [enable DT_TEXTREL check in ELF linker]),
 192 [case "${enableval}" in
 193   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 194 esac])
 195
 196 # Decide if -z separate-code should be enabled in ELF linker by default.
 197 ac_default_ld_z_separate_code=unset
 198 AC_ARG_ENABLE(separate-code,
 199               AS_HELP_STRING([--enable-separate-code],
 200               [enable -z separate-code in ELF linker by default]),
 201 [case "${enableval}" in
 202   yes) ac_default_ld_z_separate_code=1 ;;
 203   no) ac_default_ld_z_separate_code=0 ;;
 204 esac])
 205
 206 # Decide if --error-handling-script should be supported.
 207 ac_support_error_handling_script=unset
 208 AC_ARG_ENABLE(error-handling-script,
 209               AS_HELP_STRING([--enable-error-handling-script],
 210               [enable/disable support for the --error-handling-script option]),
 211 [case "${enableval}" in
 212   yes) ac_support_error_handling_script=1 ;;
 213   no)  ac_support_error_handling_script=0 ;;
 214 esac])
 215
 216 # Decide which "--hash-style" to use by default
 217 # Provide a configure time option to override our default.
 218 AC_ARG_ENABLE([default-hash-style],
 219 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 220                [use this default hash style]),
 221 [case "${enable_default_hash_style}" in
 222   sysv | gnu | both) ;;
 223   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 224 esac],
 225 [case "${target}" in
 226   # Enable gnu hash only on GNU targets, but not mips
 227   mips*-*-*) enable_default_hash_style=sysv ;;
 228   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 229   *) enable_default_hash_style=sysv ;;
 230 esac])
 231
 232 case "${enable_default_hash_style}" in
 233   sysv | both) ac_default_emit_sysv_hash=1 ;;
 234   *) ac_default_emit_sysv_hash=0 ;;
 235 esac
 236
 237 case "${enable_default_hash_style}" in
 238   gnu | both) ac_default_emit_gnu_hash=1 ;;
 239   *) ac_default_emit_gnu_hash=0 ;;
 240 esac
 241
 242 AC_ARG_ENABLE(initfini-array,
 243 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 244 [case "${enableval}" in
 245  yes|no) ;;
 246  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 247  esac], [enable_initfini_array=yes])
 248 AC_SUBST(enable_initfini_array)
 249 if test $enable_initfini_array = yes; then
 250   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 251     [Define .init_array/.fini_array sections are available and working.])
 252 fi
 253
 254 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 255 if test "${enable_libctf}" = yes; then
 256     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 257 fi
 258 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 259 AC_SUBST(enable_libctf)
 260
 261 AM_BINUTILS_WARNINGS
 262
 263 AM_LC_MESSAGES
 264
 265 AC_CONFIG_HEADERS([config.h:config.in])
 266
 267 # PR 14072
 268 AH_VERBATIM([00_CONFIG_H_CHECK],
 269 [/* Check that config.h is #included before system headers
 270    (this works only for glibc, but that should be enough).  */
 271 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 272 #  error config.h must be #included before system headers
 273 #endif
 274 #define __CONFIG_H__ 1])
 275
 276 if test -z "$target" ; then
 277     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 278 fi
 279 if test -z "$host" ; then
 280     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 281 fi
 282
 283 # host-specific stuff:
 284
 285 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 286 ZW_GNU_GETTEXT_SISTER_DIR
 287 AM_PO_SUBDIRS
 288
 289 AC_EXEEXT
 290
 291 AC_PROG_YACC
 292 AM_PROG_LEX
 293
 294 AM_MAINTAINER_MODE
 295 AM_CONDITIONAL(GENINSRC_NEVER, false)
 296 ACX_PROG_CMP_IGNORE_INITIAL
 297
 298 . ${srcdir}/configure.host
 299
 300 AC_SUBST(HDEFINES)
 301 AC_SUBST(NATIVE_LIB_DIRS)
 302
 303 # We use headers from include/ that check various HAVE_*_H macros, thus
 304 # should ensure they are set by configure.  This is true even when C99
 305 # guarantees they are available.
 306 # sha1.h and md4.h test HAVE_LIMITS_H, HAVE_SYS_TYPES_H and HAVE_STDINT_H
 307 # plugin-api.h tests HAVE_STDINT_H and HAVE_INTTYPES_H
 308 # Besides those, we need to check anything used in ld/ not in C99.
 309 AC_CHECK_HEADERS(fcntl.h elf-hints.h limits.h inttypes.h stdint.h \
 310                  sys/file.h sys/mman.h sys/param.h sys/stat.h sys/time.h \
 311                  sys/types.h unistd.h)
 312 AC_CHECK_FUNCS(close glob lseek mkstemp open realpath sbrk waitpid)
 313
 314 BFD_BINARY_FOPEN
 315
 316 AC_CHECK_DECLS([asprintf, environ, sbrk])
 317
 318 AC_FUNC_MMAP
 319
 320 AC_SEARCH_LIBS([dlopen], [dl])
 321
 322 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 323 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 324 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 325 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 326 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 327 if test $ld_cv_decl_getopt_unistd_h = yes; then
 328   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 329             [Is the prototype for getopt in <unistd.h> in the expected format?])
 330 fi
 331
 332 # Link in zlib if we can.  This allows us to read and write
 333 # compressed CTF sections.
 334 AM_ZLIB
 335
 336 # When converting linker scripts into strings for use in emulation
 337 # files, use astring.sed if the compiler supports ANSI string
 338 # concatenation, or ostring.sed otherwise.  This is to support the
 339 # broken Microsoft MSVC compiler, which limits the length of string
 340 # constants, while still supporting pre-ANSI compilers which do not
 341 # support string concatenation.
 342 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 343 AC_CACHE_VAL(ld_cv_string_concatenation,
 344 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 345   ld_cv_string_concatenation=yes,
 346   ld_cv_string_concatenation=no)])
 347 AC_MSG_RESULT($ld_cv_string_concatenation)
 348 if test "$ld_cv_string_concatenation" = "yes"; then
 349   STRINGIFY=astring.sed
 350 else
 351   STRINGIFY=ostring.sed
 352 fi
 353 AC_SUBST(STRINGIFY)
 354
 355 # target-specific stuff:
 356
 357 all_targets=
 358 EMUL=
 359 all_emuls=
 360 all_emul_extras=
 361 all_libpath=
 362 TDIRS=
 363
 364 elf_list_options=false
 365 elf_shlib_list_options=false
 366 elf_plt_unwind_list_options=false
 367 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 368 do
 369   if test "$targ_alias" = "all"; then
 370     all_targets=true
 371     elf_list_options=true
 372     elf_shlib_list_options=true
 373     elf_plt_unwind_list_options=true
 374   else
 375     # Canonicalize the secondary target names.
 376     result=`$ac_config_sub $targ_alias 2>/dev/null`
 377     if test -n "$result"; then
 378         targ=$result
 379     else
 380         targ=$targ_alias
 381     fi
 382
 383     . ${srcdir}/configure.tgt
 384
 385     if test "$targ" = "$target"; then
 386       EMUL=$targ_emul
 387     fi
 388
 389     if test x${enable_64_bit_bfd} = xno; then
 390       . ${srcdir}/../bfd/config.bfd
 391     fi
 392
 393     if test x${enable_64_bit_bfd} = xyes; then
 394       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 395       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 396     fi
 397
 398     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 399         case " $all_emuls " in
 400         *" e${i}.o "*) ;;
 401         *)
 402           all_emuls="$all_emuls e${i}.o"
 403           eval result=\$tdir_$i
 404           test -z "$result" && result=$targ_alias
 405           TDIRS="$TDIRS
 406 tdir_$i=$result"
 407           case "${i}" in
 408           *elf*)
 409             elf_list_options=true
 410             ;;
 411           *)
 412             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 413               elf_list_options=true
 414             fi
 415             ;;
 416           esac
 417           if test "$elf_list_options" = "true"; then
 418             source_sh()
 419             {
 420               . $1
 421             }
 422             source_sh ${srcdir}/emulparams/${i}.sh
 423             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 424               elf_shlib_list_options=true
 425             fi
 426             if test x${PLT_UNWIND} = xyes; then
 427               elf_plt_unwind_list_options=true
 428             fi
 429           fi
 430           ;;
 431         esac
 432     done
 433
 434     for i in $targ_emul $targ_extra_libpath; do
 435         case " $all_libpath " in
 436         *" ${i} "*) ;;
 437         *)
 438           if test -z "$all_libpath"; then
 439             all_libpath=${i}
 440           else
 441             all_libpath="$all_libpath ${i}"
 442           fi
 443           ;;
 444         esac
 445     done
 446
 447     for i in $targ_extra_ofiles; do
 448         case " $all_emul_extras " in
 449         *" ${i} "*) ;;
 450         *)
 451           all_emul_extras="$all_emul_extras ${i}"
 452           ;;
 453         esac
 454     done
 455
 456   fi
 457 done
 458
 459 if test x$ac_default_compressed_debug_sections = xyes ; then
 460   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 461 fi
 462
 463 if test "${ac_default_new_dtags}" = unset; then
 464   ac_default_new_dtags=0
 465 fi
 466 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 467   $ac_default_new_dtags,
 468   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 469
 470 if test "${ac_default_ld_z_relro}" = unset; then
 471   ac_default_ld_z_relro=0
 472 fi
 473 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 474   $ac_default_ld_z_relro,
 475   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 476
 477 ac_default_ld_textrel_check_warning=0
 478 case "${ac_default_ld_textrel_check}" in
 479   unset|no)
 480     ac_default_ld_textrel_check=textrel_check_none
 481     ;;
 482   yes|warning)
 483     ac_default_ld_textrel_check=textrel_check_warning
 484     ac_default_ld_textrel_check_warning=1
 485     ;;
 486   error)
 487     ac_default_ld_textrel_check=textrel_check_error
 488     ;;
 489 esac
 490 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 491   $ac_default_ld_textrel_check,
 492   [The default method for DT_TEXTREL check in ELF linker.])
 493 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 494   $ac_default_ld_textrel_check_warning,
 495   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 496
 497 if test "${ac_default_ld_z_separate_code}" = unset; then
 498   ac_default_ld_z_separate_code=0
 499 fi
 500 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 501   $ac_default_ld_z_separate_code,
 502   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 503
 504 if test "${ac_support_error_handling_script}" = unset; then
 505   ac_support_error_handling_script=1
 506 fi
 507 AC_DEFINE_UNQUOTED(SUPPORT_ERROR_HANDLING_SCRIPT,
 508   $ac_support_error_handling_script,
 509   [Define to 1 if you want to support the --error-handling-script command line option.])
 510
 511 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 512   [$ac_default_emit_sysv_hash],
 513   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 514
 515 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 516   [$ac_default_emit_gnu_hash],
 517   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 518
 519 AC_SUBST(elf_list_options)
 520 AC_SUBST(elf_shlib_list_options)
 521 AC_SUBST(elf_plt_unwind_list_options)
 522 AC_SUBST(EMUL)
 523
 524 AC_SUBST(TDIRS)
 525 AM_SUBST_NOTMAKE(TDIRS)
 526
 527 if test x${all_targets} = xtrue; then
 528   if test x${enable_64_bit_bfd} = xyes; then
 529     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 530     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 531   else
 532     EMULATION_OFILES='$(ALL_EMULATIONS)'
 533     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 534   fi
 535 else
 536   EMULATION_OFILES=$all_emuls
 537   EMUL_EXTRA_OFILES=$all_emul_extras
 538 fi
 539 AC_SUBST(EMULATION_OFILES)
 540 AC_SUBST(EMUL_EXTRA_OFILES)
 541 AC_SUBST(LIB_PATH)
 542
 543 EMULATION_LIBPATH=$all_libpath
 544 AC_SUBST(EMULATION_LIBPATH)
 545
 546 if test x${enable_static} = xno; then
 547   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 548   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 549 else
 550   TESTBFDLIB="../bfd/.libs/libbfd.a"
 551   TESTCTFLIB="../libctf/.libs/libctf.a"
 552 fi
 553 if test "${enable_libctf}" = no; then
 554     TESTCTFLIB=
 555 fi
 556 AC_SUBST(TESTBFDLIB)
 557 AC_SUBST(TESTCTFLIB)
 558
 559 target_vendor=${target_vendor=$host_vendor}
 560 case "$target_vendor" in
 561   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 562   *)  EXTRA_SHLIB_EXTENSION= ;;
 563 esac
 564
 565 case "$target_os" in
 566   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 567 esac
 568
 569 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 570   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 571    [Additional extension a shared object might have.])
 572 fi
 573
 574 AC_CONFIG_COMMANDS([default],
 575 [[
 576 case "$srcdir" in
 577   .) srcdirpre= ;;
 578   *) srcdirpre='$(srcdir)/' ;;
 579 esac
 580 POFILES=
 581 GMOFILES=
 582 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 583   if test $lang != dummy; then
 584     POFILES="$POFILES $srcdirpre$lang.po"
 585     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 586   fi
 587 done
 588 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 589     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 590     -e "s,@POFILES@,$POFILES," \
 591     -e "s,@GMOFILES@,$GMOFILES," \
 592     po/Makefile.in > po/Makefile]],[[]])
 593
 594 dnl Required by html, pdf, install-pdf and install-html
 595 AC_SUBST(datarootdir)
 596 AC_SUBST(docdir)
 597 AC_SUBST(htmldir)
 598 AC_SUBST(pdfdir)
 599
 600 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 601 AC_OUTPUT
 602
 603 GNU_MAKE_JOBSERVER