ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2021 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 # PR gas/19109
 146 # Decide the default method for compressing debug sections.
 147 ac_default_compressed_debug_sections=unset
 148 # Provide a configure time option to override our default.
 149 AC_ARG_ENABLE(compressed_debug_sections,
 150               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 151               [compress debug sections by default])],
 152 [case ,"${enableval}", in
 153   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 154   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 155 esac])dnl
 156
 157 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 158 ac_default_new_dtags=unset
 159 # Provide a configure time option to override our default.
 160 AC_ARG_ENABLE(new_dtags,
 161               AS_HELP_STRING([--enable-new-dtags],
 162               [set DT_RUNPATH instead of DT_RPATH by default])],
 163 [case "${enableval}" in
 164   yes) ac_default_new_dtags=1 ;;
 165   no) ac_default_new_dtags=0 ;;
 166 esac])dnl
 167
 168 # Decide if -z relro should be enabled in ELF linker by default.
 169 ac_default_ld_z_relro=unset
 170 # Provide a configure time option to override our default.
 171 AC_ARG_ENABLE(relro,
 172               AS_HELP_STRING([--enable-relro],
 173               [enable -z relro in ELF linker by default]),
 174 [case "${enableval}" in
 175   yes)  ac_default_ld_z_relro=1 ;;
 176   no)  ac_default_ld_z_relro=0 ;;
 177 esac])dnl
 178
 179 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 180 ac_default_ld_textrel_check=unset
 181 AC_ARG_ENABLE([textrel-check],
 182               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 183                              [enable DT_TEXTREL check in ELF linker]),
 184 [case "${enableval}" in
 185   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 186 esac])
 187
 188 # Decide if -z separate-code should be enabled in ELF linker by default.
 189 ac_default_ld_z_separate_code=unset
 190 AC_ARG_ENABLE(separate-code,
 191               AS_HELP_STRING([--enable-separate-code],
 192               [enable -z separate-code in ELF linker by default]),
 193 [case "${enableval}" in
 194   yes) ac_default_ld_z_separate_code=1 ;;
 195   no) ac_default_ld_z_separate_code=0 ;;
 196 esac])
 197
 198 # Decide if --error-handling-script should be supported.
 199 ac_support_error_handling_script=unset
 200 AC_ARG_ENABLE(error-handling-script,
 201               AS_HELP_STRING([--enable-error-handling-script],
 202               [enable/disable support for the --error-handling-script option]),
 203 [case "${enableval}" in
 204   yes) ac_support_error_handling_script=1 ;;
 205   no)  ac_support_error_handling_script=0 ;;
 206 esac])
 207
 208 # Decide which "--hash-style" to use by default
 209 # Provide a configure time option to override our default.
 210 AC_ARG_ENABLE([default-hash-style],
 211 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 212                [use this default hash style]),
 213 [case "${enable_default_hash_style}" in
 214   sysv | gnu | both) ;;
 215   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 216 esac],
 217 [case "${target}" in
 218   # Enable gnu hash only on GNU targets, but not mips
 219   mips*-*-*) enable_default_hash_style=sysv ;;
 220   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 221   *) enable_default_hash_style=sysv ;;
 222 esac])
 223
 224 case "${enable_default_hash_style}" in
 225   sysv | both) ac_default_emit_sysv_hash=1 ;;
 226   *) ac_default_emit_sysv_hash=0 ;;
 227 esac
 228
 229 case "${enable_default_hash_style}" in
 230   gnu | both) ac_default_emit_gnu_hash=1 ;;
 231   *) ac_default_emit_gnu_hash=0 ;;
 232 esac
 233
 234 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 235 if test "${enable_libctf}" = yes; then
 236     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 237 fi
 238 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 239 AC_SUBST(enable_libctf)
 240
 241 AM_BINUTILS_WARNINGS
 242
 243 AM_LC_MESSAGES
 244
 245 AC_CONFIG_HEADERS([config.h:config.in])
 246
 247 # PR 14072
 248 AH_VERBATIM([00_CONFIG_H_CHECK],
 249 [/* Check that config.h is #included before system headers
 250    (this works only for glibc, but that should be enough).  */
 251 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 252 #  error config.h must be #included before system headers
 253 #endif
 254 #define __CONFIG_H__ 1])
 255
 256 if test -z "$target" ; then
 257     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 258 fi
 259 if test -z "$host" ; then
 260     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 261 fi
 262
 263 # host-specific stuff:
 264
 265 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 266 ZW_GNU_GETTEXT_SISTER_DIR
 267 AM_PO_SUBDIRS
 268
 269 AC_EXEEXT
 270
 271 AC_PROG_YACC
 272 AM_PROG_LEX
 273
 274 AM_MAINTAINER_MODE
 275 AM_CONDITIONAL(GENINSRC_NEVER, false)
 276 ACX_PROG_CMP_IGNORE_INITIAL
 277
 278 . ${srcdir}/configure.host
 279
 280 AC_SUBST(HDEFINES)
 281 AC_SUBST(NATIVE_LIB_DIRS)
 282
 283 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 284 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 285 ACX_HEADER_STRING
 286 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 287 AC_CHECK_FUNCS(open lseek close)
 288 AC_HEADER_DIRENT
 289
 290 dnl AC_CHECK_HEADERS(sys/mman.h)
 291 AC_FUNC_MMAP
 292
 293 AC_SEARCH_LIBS([dlopen], [dl])
 294
 295 AC_ARG_ENABLE(initfini-array,
 296 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 297 [case "${enableval}" in
 298  yes|no) ;;
 299  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 300  esac], [enable_initfini_array=yes])
 301 AC_SUBST(enable_initfini_array)
 302 if test $enable_initfini_array = yes; then
 303   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 304     [Define .init_array/.fini_array sections are available and working.])
 305 fi
 306
 307 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 308 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 309 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 310 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 311 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 312 if test $ld_cv_decl_getopt_unistd_h = yes; then
 313   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 314             [Is the prototype for getopt in <unistd.h> in the expected format?])
 315 fi
 316
 317 BFD_BINARY_FOPEN
 318
 319 AC_CHECK_DECLS([asprintf, environ, free, getenv, sbrk, strstr])
 320
 321 # Link in zlib if we can.  This allows us to read and write
 322 # compressed CTF sections.
 323 AM_ZLIB
 324
 325 # When converting linker scripts into strings for use in emulation
 326 # files, use astring.sed if the compiler supports ANSI string
 327 # concatenation, or ostring.sed otherwise.  This is to support the
 328 # broken Microsoft MSVC compiler, which limits the length of string
 329 # constants, while still supporting pre-ANSI compilers which do not
 330 # support string concatenation.
 331 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 332 AC_CACHE_VAL(ld_cv_string_concatenation,
 333 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 334   ld_cv_string_concatenation=yes,
 335   ld_cv_string_concatenation=no)])
 336 AC_MSG_RESULT($ld_cv_string_concatenation)
 337 if test "$ld_cv_string_concatenation" = "yes"; then
 338   STRINGIFY=astring.sed
 339 else
 340   STRINGIFY=ostring.sed
 341 fi
 342 AC_SUBST(STRINGIFY)
 343
 344 # target-specific stuff:
 345
 346 all_targets=
 347 EMUL=
 348 all_emuls=
 349 all_emul_extras=
 350 all_libpath=
 351 TDIRS=
 352
 353 # If the host is 64-bit, then we enable 64-bit targets by default.
 354 # This is consistent with what ../bfd/configure.ac does.
 355 if test x${want64} = xfalse; then
 356   AC_CHECK_SIZEOF(void *)
 357   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 358     want64=true
 359   fi
 360 fi
 361
 362 elf_list_options=FALSE
 363 elf_shlib_list_options=FALSE
 364 elf_plt_unwind_list_options=FALSE
 365 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 366 do
 367   if test "$targ_alias" = "all"; then
 368     all_targets=true
 369     elf_list_options=TRUE
 370     elf_shlib_list_options=TRUE
 371     elf_plt_unwind_list_options=TRUE
 372   else
 373     # Canonicalize the secondary target names.
 374     result=`$ac_config_sub $targ_alias 2>/dev/null`
 375     if test -n "$result"; then
 376         targ=$result
 377     else
 378         targ=$targ_alias
 379     fi
 380
 381     . ${srcdir}/configure.tgt
 382
 383     if test "$targ" = "$target"; then
 384       EMUL=$targ_emul
 385     fi
 386
 387     if test x${want64} = xfalse; then
 388       . ${srcdir}/../bfd/config.bfd
 389     fi
 390
 391     if test x${want64} = xtrue; then
 392       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 393       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 394     fi
 395
 396     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 397         case " $all_emuls " in
 398         *" e${i}.o "*) ;;
 399         *)
 400           all_emuls="$all_emuls e${i}.o"
 401           eval result=\$tdir_$i
 402           test -z "$result" && result=$targ_alias
 403           TDIRS="$TDIRS
 404 tdir_$i=$result"
 405           case "${i}" in
 406           *elf*)
 407             elf_list_options=TRUE
 408             ;;
 409           *)
 410             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 411               elf_list_options=TRUE
 412             fi
 413             ;;
 414           esac
 415           if test "$elf_list_options" = "TRUE"; then
 416             source_sh()
 417             {
 418               . $1
 419             }
 420             source_sh ${srcdir}/emulparams/${i}.sh
 421             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 422               elf_shlib_list_options=TRUE
 423             fi
 424             if test x${PLT_UNWIND} = xyes; then
 425               elf_plt_unwind_list_options=TRUE
 426             fi
 427           fi
 428           ;;
 429         esac
 430     done
 431
 432     for i in $targ_emul $targ_extra_libpath; do
 433         case " $all_libpath " in
 434         *" ${i} "*) ;;
 435         *)
 436           if test -z "$all_libpath"; then
 437             all_libpath=${i}
 438           else
 439             all_libpath="$all_libpath ${i}"
 440           fi
 441           ;;
 442         esac
 443     done
 444
 445     for i in $targ_extra_ofiles; do
 446         case " $all_emul_extras " in
 447         *" ${i} "*) ;;
 448         *)
 449           all_emul_extras="$all_emul_extras ${i}"
 450           ;;
 451         esac
 452     done
 453
 454   fi
 455 done
 456
 457 if test x$ac_default_compressed_debug_sections = xyes ; then
 458   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 459 fi
 460
 461 if test "${ac_default_new_dtags}" = unset; then
 462   ac_default_new_dtags=0
 463 fi
 464 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 465   $ac_default_new_dtags,
 466   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 467
 468 if test "${ac_default_ld_z_relro}" = unset; then
 469   ac_default_ld_z_relro=0
 470 fi
 471 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 472   $ac_default_ld_z_relro,
 473   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 474
 475 ac_default_ld_textrel_check_warning=0
 476 case "${ac_default_ld_textrel_check}" in
 477   unset|no)
 478     ac_default_ld_textrel_check=textrel_check_none
 479     ;;
 480   yes|warning)
 481     ac_default_ld_textrel_check=textrel_check_warning
 482     ac_default_ld_textrel_check_warning=1
 483     ;;
 484   error)
 485     ac_default_ld_textrel_check=textrel_check_error
 486     ;;
 487 esac
 488 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 489   $ac_default_ld_textrel_check,
 490   [The default method for DT_TEXTREL check in ELF linker.])
 491 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 492   $ac_default_ld_textrel_check_warning,
 493   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 494
 495 if test "${ac_default_ld_z_separate_code}" = unset; then
 496   ac_default_ld_z_separate_code=0
 497 fi
 498 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 499   $ac_default_ld_z_separate_code,
 500   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 501
 502 if test "${ac_support_error_handling_script}" = unset; then
 503   ac_support_error_handling_script=1
 504 fi
 505 AC_DEFINE_UNQUOTED(SUPPORT_ERROR_HANDLING_SCRIPT,
 506   $ac_support_error_handling_script,
 507   [Define to 1 if you want to support the --error-handling-script command line option.])
 508
 509 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 510   [$ac_default_emit_sysv_hash],
 511   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 512
 513 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 514   [$ac_default_emit_gnu_hash],
 515   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 516
 517 AC_SUBST(elf_list_options)
 518 AC_SUBST(elf_shlib_list_options)
 519 AC_SUBST(elf_plt_unwind_list_options)
 520 AC_SUBST(EMUL)
 521
 522 AC_SUBST(TDIRS)
 523 AM_SUBST_NOTMAKE(TDIRS)
 524
 525 if test x${all_targets} = xtrue; then
 526   if test x${want64} = xtrue; then
 527     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 528     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 529   else
 530     EMULATION_OFILES='$(ALL_EMULATIONS)'
 531     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 532   fi
 533 else
 534   EMULATION_OFILES=$all_emuls
 535   EMUL_EXTRA_OFILES=$all_emul_extras
 536 fi
 537 AC_SUBST(EMULATION_OFILES)
 538 AC_SUBST(EMUL_EXTRA_OFILES)
 539 AC_SUBST(LIB_PATH)
 540
 541 EMULATION_LIBPATH=$all_libpath
 542 AC_SUBST(EMULATION_LIBPATH)
 543
 544 if test x${enable_static} = xno; then
 545   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 546   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 547 else
 548   TESTBFDLIB="../bfd/.libs/libbfd.a"
 549   TESTCTFLIB="../libctf/.libs/libctf.a"
 550 fi
 551 if test "${enable_libctf}" = no; then
 552     TESTCTFLIB=
 553 fi
 554 AC_SUBST(TESTBFDLIB)
 555 AC_SUBST(TESTCTFLIB)
 556
 557 target_vendor=${target_vendor=$host_vendor}
 558 case "$target_vendor" in
 559   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 560   *)  EXTRA_SHLIB_EXTENSION= ;;
 561 esac
 562
 563 case "$target_os" in
 564   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 565 esac
 566
 567 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 568   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 569    [Additional extension a shared object might have.])
 570 fi
 571
 572 AC_CONFIG_COMMANDS([default],
 573 [[
 574 case "$srcdir" in
 575   .) srcdirpre= ;;
 576   *) srcdirpre='$(srcdir)/' ;;
 577 esac
 578 POFILES=
 579 GMOFILES=
 580 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 581   if test $lang != dummy; then
 582     POFILES="$POFILES $srcdirpre$lang.po"
 583     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 584   fi
 585 done
 586 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 587     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 588     -e "s,@POFILES@,$POFILES," \
 589     -e "s,@GMOFILES@,$GMOFILES," \
 590     po/Makefile.in > po/Makefile]],[[]])
 591
 592 dnl Required by html, pdf, install-pdf and install-html
 593 AC_SUBST(datarootdir)
 594 AC_SUBST(docdir)
 595 AC_SUBST(htmldir)
 596 AC_SUBST(pdfdir)
 597
 598 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 599 AC_OUTPUT