ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2014 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  33 AC_ARG_ENABLE(targets,
  34 [  --enable-targets        alternative target configurations],
  35 [case "${enableval}" in
  36   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  37             ;;
  38   no)       enable_targets= ;;
  39   *)        enable_targets=$enableval ;;
  40 esac])dnl
  41 AC_ARG_ENABLE(64-bit-bfd,
  42 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  43 [case "${enableval}" in
  44   yes)  want64=true  ;;
  45   no)   want64=false ;;
  46   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  47 esac],[want64=false])dnl
  48
  49 AC_ARG_WITH(sysroot,
  50 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  51 [
  52  case ${with_sysroot} in
  53  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  54  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  55  esac
  56
  57  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  58  use_sysroot=yes
  59
  60  if test "x$prefix" = xNONE; then
  61   test_prefix=/usr/local
  62  else
  63   test_prefix=$prefix
  64  fi
  65  if test "x$exec_prefix" = xNONE; then
  66   test_exec_prefix=$test_prefix
  67  else
  68   test_exec_prefix=$exec_prefix
  69  fi
  70  case ${TARGET_SYSTEM_ROOT} in
  71  "${test_prefix}"|"${test_prefix}/"*|\
  72  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  73  '${prefix}'|'${prefix}/'*|\
  74  '${exec_prefix}'|'${exec_prefix}/'*)
  75    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  76    TARGET_SYSTEM_ROOT_DEFINE="$t"
  77    ;;
  78  esac
  79 ], [
  80  use_sysroot=no
  81  TARGET_SYSTEM_ROOT=
  82  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  83 ])
  84 AC_SUBST(use_sysroot)
  85 AC_SUBST(TARGET_SYSTEM_ROOT)
  86 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  87
  88 dnl Use --enable-gold to decide if this linker should be the default.
  89 dnl "install_as_default" is set to false if gold is the default linker.
  90 dnl "installed_linker" is the installed BFD linker name.
  91 AC_ARG_ENABLE(gold,
  92 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
  93 [case "${enableval}" in
  94  default)
  95    install_as_default=no
  96    installed_linker=ld.bfd
  97    ;;
  98  yes|no)
  99    install_as_default=yes
 100    installed_linker=ld.bfd
 101    ;;
 102  *)
 103    AC_MSG_ERROR([invalid --enable-gold argument])
 104    ;;
 105  esac],
 106 [install_as_default=yes
 107  installed_linker=ld.bfd])
 108 AC_SUBST(install_as_default)
 109 AC_SUBST(installed_linker)
 110
 111 AC_ARG_ENABLE([got],
 112 AS_HELP_STRING([--enable-got=<type>],
 113                [GOT handling scheme (target, single, negative, multigot)]),
 114 [case "${enableval}" in
 115   target | single | negative | multigot)  got_handling=$enableval ;;
 116   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 117 esac],
 118 [got_handling=target])
 119
 120 case "${got_handling}" in
 121   target)
 122     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 123               [Define to choose default GOT handling scheme]) ;;
 124   single)
 125     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 126               [Define to choose default GOT handling scheme]) ;;
 127   negative)
 128     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 129               [Define to choose default GOT handling scheme]) ;;
 130   multigot)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 134 esac
 135
 136 AM_BINUTILS_WARNINGS
 137
 138 AM_LC_MESSAGES
 139
 140 AC_CONFIG_HEADERS([config.h:config.in])
 141
 142 # PR 14072
 143 AH_VERBATIM([00_CONFIG_H_CHECK],
 144 [/* Check that config.h is #included before system headers
 145    (this works only for glibc, but that should be enough).  */
 146 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 147 #  error config.h must be #included before system headers
 148 #endif
 149 #define __CONFIG_H__ 1])
 150
 151 if test -z "$target" ; then
 152     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 153 fi
 154 if test -z "$host" ; then
 155     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 156 fi
 157
 158 # host-specific stuff:
 159
 160 AC_PROG_CC
 161 AC_PROG_CXX
 162 AC_GNU_SOURCE
 163 AC_USE_SYSTEM_EXTENSIONS
 164 ACX_LARGEFILE
 165 AC_PROG_INSTALL
 166
 167 LT_INIT
 168
 169 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 170 ZW_GNU_GETTEXT_SISTER_DIR
 171 AM_PO_SUBDIRS
 172
 173 AC_EXEEXT
 174
 175 AC_PROG_YACC
 176 AM_PROG_LEX
 177
 178 AM_MAINTAINER_MODE
 179 AM_CONDITIONAL(GENINSRC_NEVER, false)
 180 ACX_PROG_CMP_IGNORE_INITIAL
 181
 182 . ${srcdir}/configure.host
 183
 184 AC_SUBST(HDEFINES)
 185 AC_SUBST(HOSTING_CRT0)
 186 AC_SUBST(HOSTING_SCRT0)
 187 AC_SUBST(HOSTING_LIBS)
 188 AC_SUBST(HOSTING_SLIBS)
 189 AC_SUBST(NATIVE_LIB_DIRS)
 190
 191 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 192 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 193 ACX_HEADER_STRING
 194 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 195 AC_CHECK_FUNCS(open lseek close)
 196 AC_HEADER_DIRENT
 197
 198 # Check for dlopen support and enable plugins if possible.
 199 enable_plugins=yes
 200 AC_CHECK_HEADER([dlfcn.h],[],[enable_plugins=no],[AC_INCLUDES_DEFAULT])
 201 AC_SEARCH_LIBS([dlopen],[dl],[],[enable_plugins=no],[])
 202 AC_CHECK_FUNCS([dlopen dlsym dlclose],[],[enable_plugins=no])
 203 # We also support plugins on Windows (MinGW).
 204 if test x$enable_plugins = xno ; then
 205   AC_CHECK_HEADERS([windows.h],[enable_plugins=yes],[],[AC_INCLUDES_DEFAULT])
 206 fi
 207 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$enable_plugins = xyes])
 208
 209 AC_ARG_ENABLE(initfini-array,
 210         [  --enable-initfini-array      use .init_array/.fini_array sections],
 211         [], [
 212 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 213                  gcc_cv_initfini_array, [dnl
 214   if test "x${build}" = "x${target}" ; then
 215     AC_RUN_IFELSE([AC_LANG_SOURCE([
 216 static int x = -1;
 217 int main (void) { return x; }
 218 int foo (void) { x = 0; }
 219 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 220              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 221              [gcc_cv_initfini_array=no])
 222    else
 223      gcc_cv_initfini_array=no
 224    fi])
 225   enable_initfini_array=$gcc_cv_initfini_array
 226 ])
 227 AC_SUBST(enable_initfini_array)
 228 if test $enable_initfini_array = yes; then
 229   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 230     [Define .init_array/.fini_array sections are available and working.])
 231 fi
 232
 233 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 234 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 235 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 236 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 237 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 238 if test $ld_cv_decl_getopt_unistd_h = yes; then
 239   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 240             [Is the prototype for getopt in <unistd.h> in the expected format?])
 241 fi
 242
 243 BFD_BINARY_FOPEN
 244
 245 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 246
 247 # Link in zlib if we can.  This is needed only for the bootstrap tests
 248 # right now, since those tests use libbfd, which depends on zlib.
 249 AM_ZLIB
 250
 251 # When converting linker scripts into strings for use in emulation
 252 # files, use astring.sed if the compiler supports ANSI string
 253 # concatenation, or ostring.sed otherwise.  This is to support the
 254 # broken Microsoft MSVC compiler, which limits the length of string
 255 # constants, while still supporting pre-ANSI compilers which do not
 256 # support string concatenation.
 257 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 258 AC_CACHE_VAL(ld_cv_string_concatenation,
 259 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 260   ld_cv_string_concatenation=yes,
 261   ld_cv_string_concatenation=no)])
 262 AC_MSG_RESULT($ld_cv_string_concatenation)
 263 if test "$ld_cv_string_concatenation" = "yes"; then
 264   STRINGIFY=astring.sed
 265 else
 266   STRINGIFY=ostring.sed
 267 fi
 268 AC_SUBST(STRINGIFY)
 269
 270 # target-specific stuff:
 271
 272 all_targets=
 273 EMUL=
 274 all_emuls=
 275 all_emul_extras=
 276 all_libpath=
 277
 278 dnl We need to get an arbitrary number of tdir definitions into
 279 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 280 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 281 dnl file.
 282 rm -f tdirs
 283
 284 # If the host is 64-bit, then we enable 64-bit targets by default.
 285 # This is consistent with what ../bfd/configure.in does.
 286 if test x${want64} = xfalse; then
 287   AC_CHECK_SIZEOF(void *)
 288   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 289     want64=true
 290   fi
 291 fi
 292
 293 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 294 do
 295   if test "$targ_alias" = "all"; then
 296     all_targets=true
 297   else
 298     # Canonicalize the secondary target names.
 299     result=`$ac_config_sub $targ_alias 2>/dev/null`
 300     if test -n "$result"; then
 301         targ=$result
 302     else
 303         targ=$targ_alias
 304     fi
 305
 306     . ${srcdir}/configure.tgt
 307
 308     if test "$targ" = "$target"; then
 309       EMUL=$targ_emul
 310     fi
 311
 312     if test x${want64} = xfalse; then
 313       . ${srcdir}/../bfd/config.bfd
 314     fi
 315
 316     if test x${want64} = xtrue; then
 317       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 318       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 319     fi
 320
 321     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 322         case " $all_emuls " in
 323         *" e${i}.o "*) ;;
 324         *)
 325           all_emuls="$all_emuls e${i}.o"
 326           eval result=\$tdir_$i
 327           test -z "$result" && result=$targ_alias
 328           echo tdir_$i=$result >> tdirs
 329           ;;
 330         esac
 331     done
 332
 333     for i in $targ_emul $targ_extra_libpath; do
 334         case " $all_libpath " in
 335         *" ${i} "*) ;;
 336         *)
 337           if test -z "$all_libpath"; then
 338             all_libpath=${i}
 339           else
 340             all_libpath="$all_libpath ${i}"
 341           fi
 342           ;;
 343         esac
 344     done
 345
 346     for i in $targ_extra_ofiles; do
 347         case " $all_emul_extras " in
 348         *" ${i} "*) ;;
 349         *)
 350           all_emul_extras="$all_emul_extras ${i}"
 351           ;;
 352         esac
 353     done
 354
 355   fi
 356 done
 357
 358 AC_SUBST(EMUL)
 359
 360 TDIRS=tdirs
 361 AC_SUBST_FILE(TDIRS)
 362
 363 if test x${all_targets} = xtrue; then
 364   if test x${want64} = xtrue; then
 365     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 366     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 367   else
 368     EMULATION_OFILES='$(ALL_EMULATIONS)'
 369     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 370   fi
 371 else
 372   EMULATION_OFILES=$all_emuls
 373   EMUL_EXTRA_OFILES=$all_emul_extras
 374 fi
 375 AC_SUBST(EMULATION_OFILES)
 376 AC_SUBST(EMUL_EXTRA_OFILES)
 377 AC_SUBST(LIB_PATH)
 378
 379 EMULATION_LIBPATH=$all_libpath
 380 AC_SUBST(EMULATION_LIBPATH)
 381
 382 if test x${enable_static} = xno; then
 383   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 384 else
 385   TESTBFDLIB="../bfd/.libs/libbfd.a"
 386 fi
 387 AC_SUBST(TESTBFDLIB)
 388
 389 target_vendor=${target_vendor=$host_vendor}
 390 case "$target_vendor" in
 391   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 392   *)  EXTRA_SHLIB_EXTENSION= ;;
 393 esac
 394
 395 case "$target_os" in
 396   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 397 esac
 398
 399 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 400   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 401    [Additional extension a shared object might have.])
 402 fi
 403
 404 dnl Required by html, pdf, install-pdf and install-html
 405 AC_SUBST(datarootdir)
 406 AC_SUBST(docdir)
 407 AC_SUBST(htmldir)
 408 AC_SUBST(pdfdir)
 409
 410 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 411 AC_OUTPUT