ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2017 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_GREP
  35 AC_GNU_SOURCE
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_PROG_INSTALL
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41
  42 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  43 AC_ARG_ENABLE(targets,
  44 [  --enable-targets        alternative target configurations],
  45 [case "${enableval}" in
  46   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  47             ;;
  48   no)       enable_targets= ;;
  49   *)        enable_targets=$enableval ;;
  50 esac])dnl
  51 AC_ARG_ENABLE(64-bit-bfd,
  52 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  53 [case "${enableval}" in
  54   yes)  want64=true  ;;
  55   no)   want64=false ;;
  56   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  57 esac],[want64=false])dnl
  58
  59 AC_ARG_WITH(sysroot,
  60 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  61 [
  62  case ${with_sysroot} in
  63  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  64  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  65  esac
  66
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  68  use_sysroot=yes
  69
  70  if test "x$prefix" = xNONE; then
  71   test_prefix=/usr/local
  72  else
  73   test_prefix=$prefix
  74  fi
  75  if test "x$exec_prefix" = xNONE; then
  76   test_exec_prefix=$test_prefix
  77  else
  78   test_exec_prefix=$exec_prefix
  79  fi
  80  case ${TARGET_SYSTEM_ROOT} in
  81  "${test_prefix}"|"${test_prefix}/"*|\
  82  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  83  '${prefix}'|'${prefix}/'*|\
  84  '${exec_prefix}'|'${exec_prefix}/'*)
  85    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  86    TARGET_SYSTEM_ROOT_DEFINE="$t"
  87    ;;
  88  esac
  89 ], [
  90  use_sysroot=no
  91  TARGET_SYSTEM_ROOT=
  92  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  93 ])
  94 AC_SUBST(use_sysroot)
  95 AC_SUBST(TARGET_SYSTEM_ROOT)
  96 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  97
  98 dnl Use --enable-gold to decide if this linker should be the default.
  99 dnl "install_as_default" is set to false if gold is the default linker.
 100 dnl "installed_linker" is the installed BFD linker name.
 101 AC_ARG_ENABLE(gold,
 102 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 103 [case "${enableval}" in
 104  default)
 105    install_as_default=no
 106    installed_linker=ld.bfd
 107    ;;
 108  yes|no)
 109    install_as_default=yes
 110    installed_linker=ld.bfd
 111    ;;
 112  *)
 113    AC_MSG_ERROR([invalid --enable-gold argument])
 114    ;;
 115  esac],
 116 [install_as_default=yes
 117  installed_linker=ld.bfd])
 118 AC_SUBST(install_as_default)
 119 AC_SUBST(installed_linker)
 120
 121 AC_ARG_ENABLE([got],
 122 AS_HELP_STRING([--enable-got=<type>],
 123                [GOT handling scheme (target, single, negative, multigot)]),
 124 [case "${enableval}" in
 125   target | single | negative | multigot)  got_handling=$enableval ;;
 126   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 127 esac],
 128 [got_handling=target])
 129
 130 case "${got_handling}" in
 131   target)
 132     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 133               [Define to choose default GOT handling scheme]) ;;
 134   single)
 135     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 136               [Define to choose default GOT handling scheme]) ;;
 137   negative)
 138     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 139               [Define to choose default GOT handling scheme]) ;;
 140   multigot)
 141     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 142               [Define to choose default GOT handling scheme]) ;;
 143   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 144 esac
 145
 146 # PR gas/19109
 147 # Decide the default method for compressing debug sections.
 148 ac_default_compressed_debug_sections=unset
 149 # Provide a configure time option to override our default.
 150 AC_ARG_ENABLE(compressed_debug_sections,
 151               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 152               [compress debug sections by default])],
 153 [case ,"${enableval}", in
 154   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 155   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 156 esac])dnl
 157
 158 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 159 ac_default_new_dtags=unset
 160 # Provide a configure time option to override our default.
 161 AC_ARG_ENABLE(new_dtags,
 162               AS_HELP_STRING([--enable-new-dtags],
 163               [set DT_RUNPATH instead of DT_RPATH by default])],
 164 [case "${enableval}" in
 165   yes) ac_default_new_dtags=1 ;;
 166   no) ac_default_new_dtags=0 ;;
 167 esac])dnl
 168
 169 # Decide if -z relro should be enabled in ELF linker by default.
 170 ac_default_ld_z_relro=unset
 171 # Provide a configure time option to override our default.
 172 AC_ARG_ENABLE(relro,
 173               AS_HELP_STRING([--enable-relro],
 174               [enable -z relro in ELF linker by default]),
 175 [case "${enableval}" in
 176   yes)  ac_default_ld_z_relro=1 ;;
 177   no)  ac_default_ld_z_relro=0 ;;
 178 esac])dnl
 179
 180 AM_BINUTILS_WARNINGS
 181
 182 AM_LC_MESSAGES
 183
 184 AC_CONFIG_HEADERS([config.h:config.in])
 185
 186 # PR 14072
 187 AH_VERBATIM([00_CONFIG_H_CHECK],
 188 [/* Check that config.h is #included before system headers
 189    (this works only for glibc, but that should be enough).  */
 190 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 191 #  error config.h must be #included before system headers
 192 #endif
 193 #define __CONFIG_H__ 1])
 194
 195 if test -z "$target" ; then
 196     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 197 fi
 198 if test -z "$host" ; then
 199     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 200 fi
 201
 202 # host-specific stuff:
 203
 204 ALL_LINGUAS="bg da de es fi fr ga id it ru sr sv tr uk vi zh_CN zh_TW"
 205 ZW_GNU_GETTEXT_SISTER_DIR
 206 AM_PO_SUBDIRS
 207
 208 AC_EXEEXT
 209
 210 AC_PROG_YACC
 211 AM_PROG_LEX
 212
 213 AM_MAINTAINER_MODE
 214 AM_CONDITIONAL(GENINSRC_NEVER, false)
 215 ACX_PROG_CMP_IGNORE_INITIAL
 216
 217 . ${srcdir}/configure.host
 218
 219 AC_SUBST(HDEFINES)
 220 AC_SUBST(NATIVE_LIB_DIRS)
 221
 222 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 223 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 224 ACX_HEADER_STRING
 225 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 226 AC_CHECK_FUNCS(open lseek close)
 227 AC_HEADER_DIRENT
 228
 229 dnl AC_CHECK_HEADERS(sys/mman.h)
 230 AC_FUNC_MMAP
 231
 232 AC_SEARCH_LIBS([dlopen], [dl])
 233 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 234
 235 AC_ARG_ENABLE(initfini-array,
 236 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 237 [case "${enableval}" in
 238  yes|no) ;;
 239  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 240  esac], [enable_initfini_array=yes])
 241 AC_SUBST(enable_initfini_array)
 242 if test $enable_initfini_array = yes; then
 243   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 244     [Define .init_array/.fini_array sections are available and working.])
 245 fi
 246
 247 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 248 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 249 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 250 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 251 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 252 if test $ld_cv_decl_getopt_unistd_h = yes; then
 253   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 254             [Is the prototype for getopt in <unistd.h> in the expected format?])
 255 fi
 256
 257 BFD_BINARY_FOPEN
 258
 259 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 260
 261 # When converting linker scripts into strings for use in emulation
 262 # files, use astring.sed if the compiler supports ANSI string
 263 # concatenation, or ostring.sed otherwise.  This is to support the
 264 # broken Microsoft MSVC compiler, which limits the length of string
 265 # constants, while still supporting pre-ANSI compilers which do not
 266 # support string concatenation.
 267 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 268 AC_CACHE_VAL(ld_cv_string_concatenation,
 269 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 270   ld_cv_string_concatenation=yes,
 271   ld_cv_string_concatenation=no)])
 272 AC_MSG_RESULT($ld_cv_string_concatenation)
 273 if test "$ld_cv_string_concatenation" = "yes"; then
 274   STRINGIFY=astring.sed
 275 else
 276   STRINGIFY=ostring.sed
 277 fi
 278 AC_SUBST(STRINGIFY)
 279
 280 # target-specific stuff:
 281
 282 all_targets=
 283 EMUL=
 284 all_emuls=
 285 all_emul_extras=
 286 all_libpath=
 287
 288 dnl We need to get an arbitrary number of tdir definitions into
 289 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 290 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 291 dnl file.
 292 rm -f tdirs
 293
 294 # If the host is 64-bit, then we enable 64-bit targets by default.
 295 # This is consistent with what ../bfd/configure.ac does.
 296 if test x${want64} = xfalse; then
 297   AC_CHECK_SIZEOF(void *)
 298   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 299     want64=true
 300   fi
 301 fi
 302
 303 elf_list_options=FALSE
 304 elf_shlib_list_options=FALSE
 305 elf_plt_unwind_list_options=FALSE
 306 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 307 do
 308   if test "$targ_alias" = "all"; then
 309     all_targets=true
 310     elf_list_options=TRUE
 311     elf_shlib_list_options=TRUE
 312     elf_plt_unwind_list_options=TRUE
 313   else
 314     # Canonicalize the secondary target names.
 315     result=`$ac_config_sub $targ_alias 2>/dev/null`
 316     if test -n "$result"; then
 317         targ=$result
 318     else
 319         targ=$targ_alias
 320     fi
 321
 322     . ${srcdir}/configure.tgt
 323
 324     if test "$targ" = "$target"; then
 325       EMUL=$targ_emul
 326     fi
 327
 328     if test x${want64} = xfalse; then
 329       . ${srcdir}/../bfd/config.bfd
 330     fi
 331
 332     if test x${want64} = xtrue; then
 333       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 334       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 335     fi
 336
 337     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 338         case " $all_emuls " in
 339         *" e${i}.o "*) ;;
 340         *)
 341           all_emuls="$all_emuls e${i}.o"
 342           eval result=\$tdir_$i
 343           test -z "$result" && result=$targ_alias
 344           echo tdir_$i=$result >> tdirs
 345           case "${i}" in
 346           *elf*)
 347             elf_list_options=TRUE
 348             ;;
 349           *)
 350             if $GREP "TEMPLATE_NAME=elf32" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 351               elf_list_options=TRUE
 352             fi
 353             ;;
 354           esac
 355           if test "$elf_list_options" = "TRUE"; then
 356             . ${srcdir}/emulparams/${i}.sh
 357             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 358               elf_shlib_list_options=TRUE
 359             fi
 360             if test x${PLT_UNWIND} = xyes; then
 361               elf_plt_unwind_list_options=TRUE
 362             fi
 363           fi
 364           ;;
 365         esac
 366     done
 367
 368     for i in $targ_emul $targ_extra_libpath; do
 369         case " $all_libpath " in
 370         *" ${i} "*) ;;
 371         *)
 372           if test -z "$all_libpath"; then
 373             all_libpath=${i}
 374           else
 375             all_libpath="$all_libpath ${i}"
 376           fi
 377           ;;
 378         esac
 379     done
 380
 381     for i in $targ_extra_ofiles; do
 382         case " $all_emul_extras " in
 383         *" ${i} "*) ;;
 384         *)
 385           all_emul_extras="$all_emul_extras ${i}"
 386           ;;
 387         esac
 388     done
 389
 390   fi
 391 done
 392
 393 if test x$ac_default_compressed_debug_sections = xyes ; then
 394   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 395 fi
 396
 397 if test "${ac_default_new_dtags}" = unset; then
 398   ac_default_new_dtags=0
 399 fi
 400 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 401   $ac_default_new_dtags,
 402   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 403
 404 if test "${ac_default_ld_z_relro}" = unset; then
 405   ac_default_ld_z_relro=0
 406 fi
 407 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 408   $ac_default_ld_z_relro,
 409   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 410
 411 AC_SUBST(elf_list_options)
 412 AC_SUBST(elf_shlib_list_options)
 413 AC_SUBST(elf_plt_unwind_list_options)
 414 AC_SUBST(EMUL)
 415
 416 TDIRS=tdirs
 417 AC_SUBST_FILE(TDIRS)
 418
 419 if test x${all_targets} = xtrue; then
 420   if test x${want64} = xtrue; then
 421     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 422     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 423   else
 424     EMULATION_OFILES='$(ALL_EMULATIONS)'
 425     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 426   fi
 427 else
 428   EMULATION_OFILES=$all_emuls
 429   EMUL_EXTRA_OFILES=$all_emul_extras
 430 fi
 431 AC_SUBST(EMULATION_OFILES)
 432 AC_SUBST(EMUL_EXTRA_OFILES)
 433 AC_SUBST(LIB_PATH)
 434
 435 EMULATION_LIBPATH=$all_libpath
 436 AC_SUBST(EMULATION_LIBPATH)
 437
 438 if test x${enable_static} = xno; then
 439   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 440 else
 441   TESTBFDLIB="../bfd/.libs/libbfd.a"
 442 fi
 443 AC_SUBST(TESTBFDLIB)
 444
 445 target_vendor=${target_vendor=$host_vendor}
 446 case "$target_vendor" in
 447   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 448   *)  EXTRA_SHLIB_EXTENSION= ;;
 449 esac
 450
 451 case "$target_os" in
 452   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 453 esac
 454
 455 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 456   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 457    [Additional extension a shared object might have.])
 458 fi
 459
 460 dnl Required by html, pdf, install-pdf and install-html
 461 AC_SUBST(datarootdir)
 462 AC_SUBST(docdir)
 463 AC_SUBST(htmldir)
 464 AC_SUBST(pdfdir)
 465
 466 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 467 AC_OUTPUT