ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2016 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_GREP
  35 AC_GNU_SOURCE
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_PROG_INSTALL
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41
  42 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  43 AC_ARG_ENABLE(targets,
  44 [  --enable-targets        alternative target configurations],
  45 [case "${enableval}" in
  46   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  47             ;;
  48   no)       enable_targets= ;;
  49   *)        enable_targets=$enableval ;;
  50 esac])dnl
  51 AC_ARG_ENABLE(64-bit-bfd,
  52 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  53 [case "${enableval}" in
  54   yes)  want64=true  ;;
  55   no)   want64=false ;;
  56   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  57 esac],[want64=false])dnl
  58
  59 AC_ARG_WITH(sysroot,
  60 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  61 [
  62  case ${with_sysroot} in
  63  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  64  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  65  esac
  66
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  68  use_sysroot=yes
  69
  70  if test "x$prefix" = xNONE; then
  71   test_prefix=/usr/local
  72  else
  73   test_prefix=$prefix
  74  fi
  75  if test "x$exec_prefix" = xNONE; then
  76   test_exec_prefix=$test_prefix
  77  else
  78   test_exec_prefix=$exec_prefix
  79  fi
  80  case ${TARGET_SYSTEM_ROOT} in
  81  "${test_prefix}"|"${test_prefix}/"*|\
  82  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  83  '${prefix}'|'${prefix}/'*|\
  84  '${exec_prefix}'|'${exec_prefix}/'*)
  85    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  86    TARGET_SYSTEM_ROOT_DEFINE="$t"
  87    ;;
  88  esac
  89 ], [
  90  use_sysroot=no
  91  TARGET_SYSTEM_ROOT=
  92  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  93 ])
  94 AC_SUBST(use_sysroot)
  95 AC_SUBST(TARGET_SYSTEM_ROOT)
  96 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  97
  98 dnl Use --enable-gold to decide if this linker should be the default.
  99 dnl "install_as_default" is set to false if gold is the default linker.
 100 dnl "installed_linker" is the installed BFD linker name.
 101 AC_ARG_ENABLE(gold,
 102 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 103 [case "${enableval}" in
 104  default)
 105    install_as_default=no
 106    installed_linker=ld.bfd
 107    ;;
 108  yes|no)
 109    install_as_default=yes
 110    installed_linker=ld.bfd
 111    ;;
 112  *)
 113    AC_MSG_ERROR([invalid --enable-gold argument])
 114    ;;
 115  esac],
 116 [install_as_default=yes
 117  installed_linker=ld.bfd])
 118 AC_SUBST(install_as_default)
 119 AC_SUBST(installed_linker)
 120
 121 AC_ARG_ENABLE([got],
 122 AS_HELP_STRING([--enable-got=<type>],
 123                [GOT handling scheme (target, single, negative, multigot)]),
 124 [case "${enableval}" in
 125   target | single | negative | multigot)  got_handling=$enableval ;;
 126   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 127 esac],
 128 [got_handling=target])
 129
 130 case "${got_handling}" in
 131   target)
 132     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 133               [Define to choose default GOT handling scheme]) ;;
 134   single)
 135     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 136               [Define to choose default GOT handling scheme]) ;;
 137   negative)
 138     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 139               [Define to choose default GOT handling scheme]) ;;
 140   multigot)
 141     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 142               [Define to choose default GOT handling scheme]) ;;
 143   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 144 esac
 145
 146 # PR gas/19109
 147 # Decide the default method for compressing debug sections.
 148 ac_default_compressed_debug_sections=unset
 149 # Provide a configure time option to override our default.
 150 AC_ARG_ENABLE(compressed_debug_sections,
 151               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 152               [compress debug sections by default])],
 153 [case ,"${enableval}", in
 154   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 155   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 156 esac])dnl
 157
 158 AM_BINUTILS_WARNINGS
 159
 160 AM_LC_MESSAGES
 161
 162 AC_CONFIG_HEADERS([config.h:config.in])
 163
 164 # PR 14072
 165 AH_VERBATIM([00_CONFIG_H_CHECK],
 166 [/* Check that config.h is #included before system headers
 167    (this works only for glibc, but that should be enough).  */
 168 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 169 #  error config.h must be #included before system headers
 170 #endif
 171 #define __CONFIG_H__ 1])
 172
 173 if test -z "$target" ; then
 174     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 175 fi
 176 if test -z "$host" ; then
 177     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 178 fi
 179
 180 # host-specific stuff:
 181
 182 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 183 ZW_GNU_GETTEXT_SISTER_DIR
 184 AM_PO_SUBDIRS
 185
 186 AC_EXEEXT
 187
 188 AC_PROG_YACC
 189 AM_PROG_LEX
 190
 191 AM_MAINTAINER_MODE
 192 AM_CONDITIONAL(GENINSRC_NEVER, false)
 193 ACX_PROG_CMP_IGNORE_INITIAL
 194
 195 . ${srcdir}/configure.host
 196
 197 AC_SUBST(HDEFINES)
 198 AC_SUBST(HOSTING_CRT0)
 199 AC_SUBST(HOSTING_SCRT0)
 200 AC_SUBST(HOSTING_LIBS)
 201 AC_SUBST(HOSTING_SLIBS)
 202 AC_SUBST(NATIVE_LIB_DIRS)
 203
 204 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 205 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 206 ACX_HEADER_STRING
 207 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 208 AC_CHECK_FUNCS(open lseek close)
 209 AC_HEADER_DIRENT
 210
 211 dnl AC_CHECK_HEADERS(sys/mman.h)
 212 AC_FUNC_MMAP
 213
 214 AC_SEARCH_LIBS([dlopen], [dl])
 215 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 216
 217 AC_ARG_ENABLE(initfini-array,
 218 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 219 [case "${enableval}" in
 220  yes|no) ;;
 221  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 222  esac], [enable_initfini_array=yes])
 223 AC_SUBST(enable_initfini_array)
 224 if test $enable_initfini_array = yes; then
 225   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 226     [Define .init_array/.fini_array sections are available and working.])
 227 fi
 228
 229 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 230 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 231 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 232 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 233 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 234 if test $ld_cv_decl_getopt_unistd_h = yes; then
 235   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 236             [Is the prototype for getopt in <unistd.h> in the expected format?])
 237 fi
 238
 239 BFD_BINARY_FOPEN
 240
 241 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 242
 243 # When converting linker scripts into strings for use in emulation
 244 # files, use astring.sed if the compiler supports ANSI string
 245 # concatenation, or ostring.sed otherwise.  This is to support the
 246 # broken Microsoft MSVC compiler, which limits the length of string
 247 # constants, while still supporting pre-ANSI compilers which do not
 248 # support string concatenation.
 249 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 250 AC_CACHE_VAL(ld_cv_string_concatenation,
 251 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 252   ld_cv_string_concatenation=yes,
 253   ld_cv_string_concatenation=no)])
 254 AC_MSG_RESULT($ld_cv_string_concatenation)
 255 if test "$ld_cv_string_concatenation" = "yes"; then
 256   STRINGIFY=astring.sed
 257 else
 258   STRINGIFY=ostring.sed
 259 fi
 260 AC_SUBST(STRINGIFY)
 261
 262 # target-specific stuff:
 263
 264 all_targets=
 265 EMUL=
 266 all_emuls=
 267 all_emul_extras=
 268 all_libpath=
 269
 270 dnl We need to get an arbitrary number of tdir definitions into
 271 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 272 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 273 dnl file.
 274 rm -f tdirs
 275
 276 # If the host is 64-bit, then we enable 64-bit targets by default.
 277 # This is consistent with what ../bfd/configure.ac does.
 278 if test x${want64} = xfalse; then
 279   AC_CHECK_SIZEOF(void *)
 280   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 281     want64=true
 282   fi
 283 fi
 284
 285 elf_list_options=FALSE
 286 elf_shlib_list_options=FALSE
 287 elf_plt_unwind_list_options=FALSE
 288 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 289 do
 290   if test "$targ_alias" = "all"; then
 291     all_targets=true
 292     elf_list_options=TRUE
 293     elf_shlib_list_options=TRUE
 294     elf_plt_unwind_list_options=TRUE
 295   else
 296     # Canonicalize the secondary target names.
 297     result=`$ac_config_sub $targ_alias 2>/dev/null`
 298     if test -n "$result"; then
 299         targ=$result
 300     else
 301         targ=$targ_alias
 302     fi
 303
 304     . ${srcdir}/configure.tgt
 305
 306     if test "$targ" = "$target"; then
 307       EMUL=$targ_emul
 308     fi
 309
 310     if test x${want64} = xfalse; then
 311       . ${srcdir}/../bfd/config.bfd
 312     fi
 313
 314     if test x${want64} = xtrue; then
 315       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 316       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 317     fi
 318
 319     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 320         case " $all_emuls " in
 321         *" e${i}.o "*) ;;
 322         *)
 323           all_emuls="$all_emuls e${i}.o"
 324           eval result=\$tdir_$i
 325           test -z "$result" && result=$targ_alias
 326           echo tdir_$i=$result >> tdirs
 327           case "${i}" in
 328           *elf*)
 329             elf_list_options=TRUE
 330             ;;
 331           *)
 332             if $GREP "TEMPLATE_NAME=elf32" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 333               elf_list_options=TRUE
 334             fi
 335             ;;
 336           esac
 337           if test "$elf_list_options" = "TRUE"; then
 338             . ${srcdir}/emulparams/${i}.sh
 339             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 340               elf_shlib_list_options=TRUE
 341             fi
 342             if test x${PLT_UNWIND} = xyes; then
 343               elf_plt_unwind_list_options=TRUE
 344             fi
 345           fi
 346           ;;
 347         esac
 348     done
 349
 350     for i in $targ_emul $targ_extra_libpath; do
 351         case " $all_libpath " in
 352         *" ${i} "*) ;;
 353         *)
 354           if test -z "$all_libpath"; then
 355             all_libpath=${i}
 356           else
 357             all_libpath="$all_libpath ${i}"
 358           fi
 359           ;;
 360         esac
 361     done
 362
 363     for i in $targ_extra_ofiles; do
 364         case " $all_emul_extras " in
 365         *" ${i} "*) ;;
 366         *)
 367           all_emul_extras="$all_emul_extras ${i}"
 368           ;;
 369         esac
 370     done
 371
 372   fi
 373 done
 374
 375 if test x$ac_default_compressed_debug_sections == xyes ; then
 376   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 377 fi
 378
 379 AC_SUBST(elf_list_options)
 380 AC_SUBST(elf_shlib_list_options)
 381 AC_SUBST(elf_plt_unwind_list_options)
 382 AC_SUBST(EMUL)
 383
 384 TDIRS=tdirs
 385 AC_SUBST_FILE(TDIRS)
 386
 387 if test x${all_targets} = xtrue; then
 388   if test x${want64} = xtrue; then
 389     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 390     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 391   else
 392     EMULATION_OFILES='$(ALL_EMULATIONS)'
 393     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 394   fi
 395 else
 396   EMULATION_OFILES=$all_emuls
 397   EMUL_EXTRA_OFILES=$all_emul_extras
 398 fi
 399 AC_SUBST(EMULATION_OFILES)
 400 AC_SUBST(EMUL_EXTRA_OFILES)
 401 AC_SUBST(LIB_PATH)
 402
 403 EMULATION_LIBPATH=$all_libpath
 404 AC_SUBST(EMULATION_LIBPATH)
 405
 406 if test x${enable_static} = xno; then
 407   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 408 else
 409   TESTBFDLIB="../bfd/.libs/libbfd.a"
 410 fi
 411 AC_SUBST(TESTBFDLIB)
 412
 413 target_vendor=${target_vendor=$host_vendor}
 414 case "$target_vendor" in
 415   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 416   *)  EXTRA_SHLIB_EXTENSION= ;;
 417 esac
 418
 419 case "$target_os" in
 420   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 421 esac
 422
 423 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 424   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 425    [Additional extension a shared object might have.])
 426 fi
 427
 428 dnl Required by html, pdf, install-pdf and install-html
 429 AC_SUBST(datarootdir)
 430 AC_SUBST(docdir)
 431 AC_SUBST(htmldir)
 432 AC_SUBST(pdfdir)
 433
 434 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 435 AC_OUTPUT