ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2015 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 AC_PREREQ(2.59)
  21 m4_include([../bfd/version.m4])
  22 AC_INIT([ld], BFD_VERSION)
  23 AC_CONFIG_SRCDIR(ldmain.c)
  24
  25 AC_CANONICAL_TARGET
  26 AC_CANONICAL_BUILD
  27 AC_ISC_POSIX
  28
  29 AM_INIT_AUTOMAKE
  30 AM_MAINTAINER_MODE
  31
  32 AC_PROG_CC
  33 AC_PROG_CXX
  34 AC_PROG_GREP
  35 AC_GNU_SOURCE
  36 AC_USE_SYSTEM_EXTENSIONS
  37 AC_PROG_INSTALL
  38
  39 LT_INIT
  40 ACX_LARGEFILE
  41
  42 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  43 AC_ARG_ENABLE(targets,
  44 [  --enable-targets        alternative target configurations],
  45 [case "${enableval}" in
  46   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  47             ;;
  48   no)       enable_targets= ;;
  49   *)        enable_targets=$enableval ;;
  50 esac])dnl
  51 AC_ARG_ENABLE(64-bit-bfd,
  52 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  53 [case "${enableval}" in
  54   yes)  want64=true  ;;
  55   no)   want64=false ;;
  56   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  57 esac],[want64=false])dnl
  58
  59 AC_ARG_WITH(sysroot,
  60 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  61 [
  62  case ${with_sysroot} in
  63  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  64  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  65  esac
  66
  67  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  68  use_sysroot=yes
  69
  70  if test "x$prefix" = xNONE; then
  71   test_prefix=/usr/local
  72  else
  73   test_prefix=$prefix
  74  fi
  75  if test "x$exec_prefix" = xNONE; then
  76   test_exec_prefix=$test_prefix
  77  else
  78   test_exec_prefix=$exec_prefix
  79  fi
  80  case ${TARGET_SYSTEM_ROOT} in
  81  "${test_prefix}"|"${test_prefix}/"*|\
  82  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  83  '${prefix}'|'${prefix}/'*|\
  84  '${exec_prefix}'|'${exec_prefix}/'*)
  85    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  86    TARGET_SYSTEM_ROOT_DEFINE="$t"
  87    ;;
  88  esac
  89 ], [
  90  use_sysroot=no
  91  TARGET_SYSTEM_ROOT=
  92  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  93 ])
  94 AC_SUBST(use_sysroot)
  95 AC_SUBST(TARGET_SYSTEM_ROOT)
  96 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  97
  98 dnl Use --enable-gold to decide if this linker should be the default.
  99 dnl "install_as_default" is set to false if gold is the default linker.
 100 dnl "installed_linker" is the installed BFD linker name.
 101 AC_ARG_ENABLE(gold,
 102 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 103 [case "${enableval}" in
 104  default)
 105    install_as_default=no
 106    installed_linker=ld.bfd
 107    ;;
 108  yes|no)
 109    install_as_default=yes
 110    installed_linker=ld.bfd
 111    ;;
 112  *)
 113    AC_MSG_ERROR([invalid --enable-gold argument])
 114    ;;
 115  esac],
 116 [install_as_default=yes
 117  installed_linker=ld.bfd])
 118 AC_SUBST(install_as_default)
 119 AC_SUBST(installed_linker)
 120
 121 AC_ARG_ENABLE([got],
 122 AS_HELP_STRING([--enable-got=<type>],
 123                [GOT handling scheme (target, single, negative, multigot)]),
 124 [case "${enableval}" in
 125   target | single | negative | multigot)  got_handling=$enableval ;;
 126   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 127 esac],
 128 [got_handling=target])
 129
 130 case "${got_handling}" in
 131   target)
 132     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 133               [Define to choose default GOT handling scheme]) ;;
 134   single)
 135     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 136               [Define to choose default GOT handling scheme]) ;;
 137   negative)
 138     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 139               [Define to choose default GOT handling scheme]) ;;
 140   multigot)
 141     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 142               [Define to choose default GOT handling scheme]) ;;
 143   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 144 esac
 145
 146 # PR gas/19109
 147 # Decide the default method for compressing debug sections.
 148 ac_default_compressed_debug_sections=unset
 149 # Provide a configure time option to override our default.
 150 AC_ARG_ENABLE(compressed_debug_sections,
 151               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 152               [compress debug sections by default])],
 153 [case ,"${enableval}", in
 154   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 155   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 156 esac])dnl
 157
 158 AM_BINUTILS_WARNINGS
 159
 160 AM_LC_MESSAGES
 161
 162 AC_CONFIG_HEADERS([config.h:config.in])
 163
 164 # PR 14072
 165 AH_VERBATIM([00_CONFIG_H_CHECK],
 166 [/* Check that config.h is #included before system headers
 167    (this works only for glibc, but that should be enough).  */
 168 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 169 #  error config.h must be #included before system headers
 170 #endif
 171 #define __CONFIG_H__ 1])
 172
 173 if test -z "$target" ; then
 174     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 175 fi
 176 if test -z "$host" ; then
 177     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 178 fi
 179
 180 # host-specific stuff:
 181
 182 ALL_LINGUAS="fr sv tr es da vi zh_CN zh_TW ga fi id bg it uk"
 183 ZW_GNU_GETTEXT_SISTER_DIR
 184 AM_PO_SUBDIRS
 185
 186 AC_EXEEXT
 187
 188 AC_PROG_YACC
 189 AM_PROG_LEX
 190
 191 AM_MAINTAINER_MODE
 192 AM_CONDITIONAL(GENINSRC_NEVER, false)
 193 ACX_PROG_CMP_IGNORE_INITIAL
 194
 195 . ${srcdir}/configure.host
 196
 197 AC_SUBST(HDEFINES)
 198 AC_SUBST(HOSTING_CRT0)
 199 AC_SUBST(HOSTING_SCRT0)
 200 AC_SUBST(HOSTING_LIBS)
 201 AC_SUBST(HOSTING_SLIBS)
 202 AC_SUBST(NATIVE_LIB_DIRS)
 203
 204 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 205 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 206 ACX_HEADER_STRING
 207 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 208 AC_CHECK_FUNCS(open lseek close)
 209 AC_HEADER_DIRENT
 210
 211 dnl AC_CHECK_HEADERS(sys/mman.h)
 212 AC_FUNC_MMAP
 213
 214 AC_SEARCH_LIBS([dlopen], [dl])
 215 AM_CONDITIONAL([ENABLE_PLUGINS], [test x$plugins = xyes])
 216
 217 AC_ARG_ENABLE(initfini-array,
 218         [  --enable-initfini-array      use .init_array/.fini_array sections],
 219         [], [
 220 AC_CACHE_CHECK(for .preinit_array/.init_array/.fini_array support,
 221                  gcc_cv_initfini_array, [dnl
 222   if test "x${build}" = "x${target}" ; then
 223     AC_RUN_IFELSE([AC_LANG_SOURCE([
 224 static int x = -1;
 225 int main (void) { return x; }
 226 int foo (void) { x = 0; }
 227 int (*fp) (void) __attribute__ ((section (".init_array"))) = foo;])],
 228              [gcc_cv_initfini_array=yes], [gcc_cv_initfini_array=no],
 229              [gcc_cv_initfini_array=no])
 230    else
 231      gcc_cv_initfini_array=no
 232    fi])
 233   enable_initfini_array=$gcc_cv_initfini_array
 234 ])
 235 AC_SUBST(enable_initfini_array)
 236 if test $enable_initfini_array = yes; then
 237   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 238     [Define .init_array/.fini_array sections are available and working.])
 239 fi
 240
 241 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 242 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 243 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 244 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 245 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 246 if test $ld_cv_decl_getopt_unistd_h = yes; then
 247   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 248             [Is the prototype for getopt in <unistd.h> in the expected format?])
 249 fi
 250
 251 BFD_BINARY_FOPEN
 252
 253 AC_CHECK_DECLS([strstr, free, sbrk, getenv, environ])
 254
 255 # When converting linker scripts into strings for use in emulation
 256 # files, use astring.sed if the compiler supports ANSI string
 257 # concatenation, or ostring.sed otherwise.  This is to support the
 258 # broken Microsoft MSVC compiler, which limits the length of string
 259 # constants, while still supporting pre-ANSI compilers which do not
 260 # support string concatenation.
 261 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 262 AC_CACHE_VAL(ld_cv_string_concatenation,
 263 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 264   ld_cv_string_concatenation=yes,
 265   ld_cv_string_concatenation=no)])
 266 AC_MSG_RESULT($ld_cv_string_concatenation)
 267 if test "$ld_cv_string_concatenation" = "yes"; then
 268   STRINGIFY=astring.sed
 269 else
 270   STRINGIFY=ostring.sed
 271 fi
 272 AC_SUBST(STRINGIFY)
 273
 274 # target-specific stuff:
 275
 276 all_targets=
 277 EMUL=
 278 all_emuls=
 279 all_emul_extras=
 280 all_libpath=
 281
 282 dnl We need to get an arbitrary number of tdir definitions into
 283 dnl Makefile.  We can't do it using AC_SUBST, because autoconf does
 284 dnl not permit literal newlines in an AC_SUBST variables.  So we use a
 285 dnl file.
 286 rm -f tdirs
 287
 288 # If the host is 64-bit, then we enable 64-bit targets by default.
 289 # This is consistent with what ../bfd/configure.ac does.
 290 if test x${want64} = xfalse; then
 291   AC_CHECK_SIZEOF(void *)
 292   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 293     want64=true
 294   fi
 295 fi
 296
 297 elf_list_options=FALSE
 298 elf_shlib_list_options=FALSE
 299 elf_plt_unwind_list_options=FALSE
 300 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 301 do
 302   if test "$targ_alias" = "all"; then
 303     all_targets=true
 304     elf_list_options=TRUE
 305     elf_shlib_list_options=TRUE
 306     elf_plt_unwind_list_options=TRUE
 307   else
 308     # Canonicalize the secondary target names.
 309     result=`$ac_config_sub $targ_alias 2>/dev/null`
 310     if test -n "$result"; then
 311         targ=$result
 312     else
 313         targ=$targ_alias
 314     fi
 315
 316     . ${srcdir}/configure.tgt
 317
 318     if test "$targ" = "$target"; then
 319       EMUL=$targ_emul
 320     fi
 321
 322     if test x${want64} = xfalse; then
 323       . ${srcdir}/../bfd/config.bfd
 324     fi
 325
 326     if test x${want64} = xtrue; then
 327       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 328       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 329     fi
 330
 331     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 332         case " $all_emuls " in
 333         *" e${i}.o "*) ;;
 334         *)
 335           all_emuls="$all_emuls e${i}.o"
 336           eval result=\$tdir_$i
 337           test -z "$result" && result=$targ_alias
 338           echo tdir_$i=$result >> tdirs
 339           case "${i}" in
 340           *elf*)
 341             elf_list_options=TRUE
 342             ;;
 343           *)
 344             if $GREP "TEMPLATE_NAME=elf32" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 345               elf_list_options=TRUE
 346             fi
 347             ;;
 348           esac
 349           if test "$elf_list_options" = "TRUE"; then
 350             . ${srcdir}/emulparams/${i}.sh
 351             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 352               elf_shlib_list_options=TRUE
 353             fi
 354             if test x${PLT_UNWIND} = xyes; then
 355               elf_plt_unwind_list_options=TRUE
 356             fi
 357           fi
 358           ;;
 359         esac
 360     done
 361
 362     for i in $targ_emul $targ_extra_libpath; do
 363         case " $all_libpath " in
 364         *" ${i} "*) ;;
 365         *)
 366           if test -z "$all_libpath"; then
 367             all_libpath=${i}
 368           else
 369             all_libpath="$all_libpath ${i}"
 370           fi
 371           ;;
 372         esac
 373     done
 374
 375     for i in $targ_extra_ofiles; do
 376         case " $all_emul_extras " in
 377         *" ${i} "*) ;;
 378         *)
 379           all_emul_extras="$all_emul_extras ${i}"
 380           ;;
 381         esac
 382     done
 383
 384   fi
 385 done
 386
 387 if test x$ac_default_compressed_debug_sections == xyes ; then
 388   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 389 fi
 390
 391 AC_SUBST(elf_list_options)
 392 AC_SUBST(elf_shlib_list_options)
 393 AC_SUBST(elf_plt_unwind_list_options)
 394 AC_SUBST(EMUL)
 395
 396 TDIRS=tdirs
 397 AC_SUBST_FILE(TDIRS)
 398
 399 if test x${all_targets} = xtrue; then
 400   if test x${want64} = xtrue; then
 401     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 402     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 403   else
 404     EMULATION_OFILES='$(ALL_EMULATIONS)'
 405     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 406   fi
 407 else
 408   EMULATION_OFILES=$all_emuls
 409   EMUL_EXTRA_OFILES=$all_emul_extras
 410 fi
 411 AC_SUBST(EMULATION_OFILES)
 412 AC_SUBST(EMUL_EXTRA_OFILES)
 413 AC_SUBST(LIB_PATH)
 414
 415 EMULATION_LIBPATH=$all_libpath
 416 AC_SUBST(EMULATION_LIBPATH)
 417
 418 if test x${enable_static} = xno; then
 419   TESTBFDLIB="--rpath ../bfd/.libs ../bfd/.libs/libbfd.so"
 420 else
 421   TESTBFDLIB="../bfd/.libs/libbfd.a"
 422 fi
 423 AC_SUBST(TESTBFDLIB)
 424
 425 target_vendor=${target_vendor=$host_vendor}
 426 case "$target_vendor" in
 427   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 428   *)  EXTRA_SHLIB_EXTENSION= ;;
 429 esac
 430
 431 case "$target_os" in
 432   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 433 esac
 434
 435 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 436   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 437    [Additional extension a shared object might have.])
 438 fi
 439
 440 dnl Required by html, pdf, install-pdf and install-html
 441 AC_SUBST(datarootdir)
 442 AC_SUBST(docdir)
 443 AC_SUBST(htmldir)
 444 AC_SUBST(pdfdir)
 445
 446 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 447 AC_OUTPUT