ld/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2 dnl
   3 dnl   Copyright (C) 2012-2020 Free Software Foundation, Inc.
   4 dnl
   5 dnl This file is free software; you can redistribute it and/or modify
   6 dnl it under the terms of the GNU General Public License as published by
   7 dnl the Free Software Foundation; either version 3 of the License, or
   8 dnl (at your option) any later version.
   9 dnl
  10 dnl This program is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 dnl GNU General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with this program; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18 dnl
  19
  20 m4_include([../bfd/version.m4])
  21 AC_INIT([ld], BFD_VERSION)
  22 AC_CONFIG_SRCDIR(ldmain.c)
  23
  24 AC_CANONICAL_TARGET
  25 AC_CANONICAL_BUILD
  26 AC_ISC_POSIX
  27
  28 AM_INIT_AUTOMAKE
  29 AM_MAINTAINER_MODE
  30
  31 AC_PROG_CC
  32 AC_PROG_CXX
  33 AC_PROG_GREP
  34 AC_GNU_SOURCE
  35 AC_USE_SYSTEM_EXTENSIONS
  36 AC_PROG_INSTALL
  37
  38 LT_INIT
  39 ACX_LARGEFILE
  40
  41 AC_ARG_WITH(lib-path, [  --with-lib-path=dir1:dir2...  set default LIB_PATH],LIB_PATH=$withval)
  42 AC_ARG_ENABLE(targets,
  43 [  --enable-targets        alternative target configurations],
  44 [case "${enableval}" in
  45   yes | "") AC_MSG_ERROR(enable-targets option must specify target names or 'all')
  46             ;;
  47   no)       enable_targets= ;;
  48   *)        enable_targets=$enableval ;;
  49 esac])dnl
  50 AC_ARG_ENABLE(64-bit-bfd,
  51 [  --enable-64-bit-bfd     64-bit support (on hosts with narrower word sizes)],
  52 [case "${enableval}" in
  53   yes)  want64=true  ;;
  54   no)   want64=false ;;
  55   *)    AC_MSG_ERROR(bad value ${enableval} for 64-bit-bfd option) ;;
  56 esac],[want64=false])dnl
  57
  58 AC_ARG_WITH(sysroot,
  59 [  --with-sysroot[=DIR] Search for usr/lib et al within DIR.],
  60 [
  61  case ${with_sysroot} in
  62  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_alias}/sys-root' ;;
  63  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
  64  esac
  65
  66  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
  67  use_sysroot=yes
  68
  69  if test "x$prefix" = xNONE; then
  70   test_prefix=/usr/local
  71  else
  72   test_prefix=$prefix
  73  fi
  74  if test "x$exec_prefix" = xNONE; then
  75   test_exec_prefix=$test_prefix
  76  else
  77   test_exec_prefix=$exec_prefix
  78  fi
  79  case ${TARGET_SYSTEM_ROOT} in
  80  "${test_prefix}"|"${test_prefix}/"*|\
  81  "${test_exec_prefix}"|"${test_exec_prefix}/"*|\
  82  '${prefix}'|'${prefix}/'*|\
  83  '${exec_prefix}'|'${exec_prefix}/'*)
  84    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
  85    TARGET_SYSTEM_ROOT_DEFINE="$t"
  86    ;;
  87  esac
  88 ], [
  89  use_sysroot=no
  90  TARGET_SYSTEM_ROOT=
  91  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"\"'
  92 ])
  93 AC_SUBST(use_sysroot)
  94 AC_SUBST(TARGET_SYSTEM_ROOT)
  95 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
  96
  97 dnl Use --enable-gold to decide if this linker should be the default.
  98 dnl "install_as_default" is set to false if gold is the default linker.
  99 dnl "installed_linker" is the installed BFD linker name.
 100 AC_ARG_ENABLE(gold,
 101 [[  --enable-gold[=ARG]     build gold [ARG={default,yes,no}]]],
 102 [case "${enableval}" in
 103  default)
 104    install_as_default=no
 105    installed_linker=ld.bfd
 106    ;;
 107  yes|no)
 108    install_as_default=yes
 109    installed_linker=ld.bfd
 110    ;;
 111  *)
 112    AC_MSG_ERROR([invalid --enable-gold argument])
 113    ;;
 114  esac],
 115 [install_as_default=yes
 116  installed_linker=ld.bfd])
 117 AC_SUBST(install_as_default)
 118 AC_SUBST(installed_linker)
 119
 120 AC_ARG_ENABLE([got],
 121 AS_HELP_STRING([--enable-got=<type>],
 122                [GOT handling scheme (target, single, negative, multigot)]),
 123 [case "${enableval}" in
 124   target | single | negative | multigot)  got_handling=$enableval ;;
 125   *)  AC_MSG_ERROR(bad value ${enableval} for --enable-got option) ;;
 126 esac],
 127 [got_handling=target])
 128
 129 case "${got_handling}" in
 130   target)
 131     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_TARGET_DEFAULT],
 132               [Define to choose default GOT handling scheme]) ;;
 133   single)
 134     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_SINGLE],
 135               [Define to choose default GOT handling scheme]) ;;
 136   negative)
 137     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_NEGATIVE],
 138               [Define to choose default GOT handling scheme]) ;;
 139   multigot)
 140     AC_DEFINE([GOT_HANDLING_DEFAULT], [GOT_HANDLING_MULTIGOT],
 141               [Define to choose default GOT handling scheme]) ;;
 142   *)  AC_MSG_ERROR(bad value ${got_handling} for --enable-got option) ;;
 143 esac
 144
 145 # PR gas/19109
 146 # Decide the default method for compressing debug sections.
 147 ac_default_compressed_debug_sections=unset
 148 # Provide a configure time option to override our default.
 149 AC_ARG_ENABLE(compressed_debug_sections,
 150               AS_HELP_STRING([--enable-compressed-debug-sections={all,ld,none}],
 151               [compress debug sections by default])],
 152 [case ,"${enableval}", in
 153   ,yes, | ,all, | *,ld,*) ac_default_compressed_debug_sections=yes ;;
 154   ,no, | ,none,)  ac_default_compressed_debug_sections=no ;;
 155 esac])dnl
 156
 157 # Decide setting DT_RUNPATH instead of DT_RPATH by default
 158 ac_default_new_dtags=unset
 159 # Provide a configure time option to override our default.
 160 AC_ARG_ENABLE(new_dtags,
 161               AS_HELP_STRING([--enable-new-dtags],
 162               [set DT_RUNPATH instead of DT_RPATH by default])],
 163 [case "${enableval}" in
 164   yes) ac_default_new_dtags=1 ;;
 165   no) ac_default_new_dtags=0 ;;
 166 esac])dnl
 167
 168 # Decide if -z relro should be enabled in ELF linker by default.
 169 ac_default_ld_z_relro=unset
 170 # Provide a configure time option to override our default.
 171 AC_ARG_ENABLE(relro,
 172               AS_HELP_STRING([--enable-relro],
 173               [enable -z relro in ELF linker by default]),
 174 [case "${enableval}" in
 175   yes)  ac_default_ld_z_relro=1 ;;
 176   no)  ac_default_ld_z_relro=0 ;;
 177 esac])dnl
 178
 179 # Decide if DT_TEXTREL check should be enabled in ELF linker.
 180 ac_default_ld_textrel_check=unset
 181 AC_ARG_ENABLE([textrel-check],
 182               AC_HELP_STRING([--enable-textrel-check=@<:@yes|no|warning|error@:>@],
 183                              [enable DT_TEXTREL check in ELF linker]),
 184 [case "${enableval}" in
 185   yes|no|warning|error) ac_default_ld_textrel_check=${enableval} ;;
 186 esac])
 187
 188 # Decide if -z separate-code should be enabled in ELF linker by default.
 189 ac_default_ld_z_separate_code=unset
 190 AC_ARG_ENABLE(separate-code,
 191               AS_HELP_STRING([--enable-separate-code],
 192               [enable -z separate-code in ELF linker by default]),
 193 [case "${enableval}" in
 194   yes) ac_default_ld_z_separate_code=1 ;;
 195   no) ac_default_ld_z_separate_code=0 ;;
 196 esac])
 197
 198 # Decide which "--hash-style" to use by default
 199 # Provide a configure time option to override our default.
 200 AC_ARG_ENABLE([default-hash-style],
 201 AS_HELP_STRING([--enable-default-hash-style={sysv,gnu,both}],
 202                [use this default hash style]),
 203 [case "${enable_default_hash_style}" in
 204   sysv | gnu | both) ;;
 205   *) AC_MSG_ERROR([bad value ${enable_default_hash_style} for enable-default-hash-style option]) ;;
 206 esac],
 207 [case "${target}" in
 208   # Enable gnu hash only on GNU targets, but not mips
 209   mips*-*-*) enable_default_hash_style=sysv ;;
 210   *-*-gnu* | *-*-linux* | *-*-nacl*) enable_default_hash_style=both ;;
 211   *) enable_default_hash_style=sysv ;;
 212 esac])
 213
 214 case "${enable_default_hash_style}" in
 215   sysv | both) ac_default_emit_sysv_hash=1 ;;
 216   *) ac_default_emit_sysv_hash=0 ;;
 217 esac
 218
 219 case "${enable_default_hash_style}" in
 220   gnu | both) ac_default_emit_gnu_hash=1 ;;
 221   *) ac_default_emit_gnu_hash=0 ;;
 222 esac
 223
 224 GCC_ENABLE([libctf], [yes], [], [Handle .ctf type-info sections])
 225 if test "${enable_libctf}" = yes; then
 226     AC_DEFINE(ENABLE_LIBCTF, 1, [Handle .ctf type-info sections])
 227 fi
 228 AM_CONDITIONAL(ENABLE_LIBCTF, test "${enable_libctf}" = yes)
 229 AC_SUBST(enable_libctf)
 230
 231 AM_BINUTILS_WARNINGS
 232
 233 AM_LC_MESSAGES
 234
 235 AC_CONFIG_HEADERS([config.h:config.in])
 236
 237 # PR 14072
 238 AH_VERBATIM([00_CONFIG_H_CHECK],
 239 [/* Check that config.h is #included before system headers
 240    (this works only for glibc, but that should be enough).  */
 241 #if defined(__GLIBC__) && !defined(__FreeBSD_kernel__) && !defined(__CONFIG_H__)
 242 #  error config.h must be #included before system headers
 243 #endif
 244 #define __CONFIG_H__ 1])
 245
 246 if test -z "$target" ; then
 247     AC_MSG_ERROR(Unrecognized target system type; please check config.sub.)
 248 fi
 249 if test -z "$host" ; then
 250     AC_MSG_ERROR(Unrecognized host system type; please check config.sub.)
 251 fi
 252
 253 # host-specific stuff:
 254
 255 ALL_LINGUAS="bg da de es fi fr ga id it ja pt_BR ru sr sv tr uk vi zh_CN zh_TW"
 256 ZW_GNU_GETTEXT_SISTER_DIR
 257 AM_PO_SUBDIRS
 258
 259 AC_EXEEXT
 260
 261 AC_PROG_YACC
 262 AM_PROG_LEX
 263
 264 AM_MAINTAINER_MODE
 265 AM_CONDITIONAL(GENINSRC_NEVER, false)
 266 ACX_PROG_CMP_IGNORE_INITIAL
 267
 268 . ${srcdir}/configure.host
 269
 270 AC_SUBST(HDEFINES)
 271 AC_SUBST(NATIVE_LIB_DIRS)
 272
 273 AC_CHECK_HEADERS(string.h strings.h stdlib.h unistd.h elf-hints.h limits.h locale.h sys/param.h)
 274 AC_CHECK_HEADERS(fcntl.h sys/file.h sys/time.h sys/stat.h)
 275 ACX_HEADER_STRING
 276 AC_CHECK_FUNCS(glob mkstemp realpath sbrk setlocale waitpid)
 277 AC_CHECK_FUNCS(open lseek close)
 278 AC_HEADER_DIRENT
 279
 280 dnl AC_CHECK_HEADERS(sys/mman.h)
 281 AC_FUNC_MMAP
 282
 283 AC_SEARCH_LIBS([dlopen], [dl])
 284
 285 AC_ARG_ENABLE(initfini-array,
 286 [  --disable-initfini-array do not use .init_array/.fini_array sections],
 287 [case "${enableval}" in
 288  yes|no) ;;
 289  *) AC_MSG_ERROR([invalid --enable-initfini-array argument]) ;;
 290  esac], [enable_initfini_array=yes])
 291 AC_SUBST(enable_initfini_array)
 292 if test $enable_initfini_array = yes; then
 293   AC_DEFINE(HAVE_INITFINI_ARRAY, 1,
 294     [Define .init_array/.fini_array sections are available and working.])
 295 fi
 296
 297 AC_MSG_CHECKING(for a known getopt prototype in unistd.h)
 298 AC_CACHE_VAL(ld_cv_decl_getopt_unistd_h,
 299 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <unistd.h>], [extern int getopt (int, char *const*, const char *);])],
 300 ld_cv_decl_getopt_unistd_h=yes, ld_cv_decl_getopt_unistd_h=no)])
 301 AC_MSG_RESULT($ld_cv_decl_getopt_unistd_h)
 302 if test $ld_cv_decl_getopt_unistd_h = yes; then
 303   AC_DEFINE([HAVE_DECL_GETOPT], 1,
 304             [Is the prototype for getopt in <unistd.h> in the expected format?])
 305 fi
 306
 307 BFD_BINARY_FOPEN
 308
 309 AC_CHECK_DECLS([asprintf, environ, free, getenv, sbrk, strstr])
 310
 311 # Link in zlib if we can.  This allows us to read and write
 312 # compressed CTF sections.
 313 AM_ZLIB
 314
 315 # When converting linker scripts into strings for use in emulation
 316 # files, use astring.sed if the compiler supports ANSI string
 317 # concatenation, or ostring.sed otherwise.  This is to support the
 318 # broken Microsoft MSVC compiler, which limits the length of string
 319 # constants, while still supporting pre-ANSI compilers which do not
 320 # support string concatenation.
 321 AC_MSG_CHECKING([whether ANSI C string concatenation works])
 322 AC_CACHE_VAL(ld_cv_string_concatenation,
 323 [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [char *a = "a" "a";])],
 324   ld_cv_string_concatenation=yes,
 325   ld_cv_string_concatenation=no)])
 326 AC_MSG_RESULT($ld_cv_string_concatenation)
 327 if test "$ld_cv_string_concatenation" = "yes"; then
 328   STRINGIFY=astring.sed
 329 else
 330   STRINGIFY=ostring.sed
 331 fi
 332 AC_SUBST(STRINGIFY)
 333
 334 # target-specific stuff:
 335
 336 all_targets=
 337 EMUL=
 338 all_emuls=
 339 all_emul_extras=
 340 all_libpath=
 341 TDIRS=
 342
 343 # If the host is 64-bit, then we enable 64-bit targets by default.
 344 # This is consistent with what ../bfd/configure.ac does.
 345 if test x${want64} = xfalse; then
 346   AC_CHECK_SIZEOF(void *)
 347   if test "x${ac_cv_sizeof_void_p}" = "x8"; then
 348     want64=true
 349   fi
 350 fi
 351
 352 elf_list_options=FALSE
 353 elf_shlib_list_options=FALSE
 354 elf_plt_unwind_list_options=FALSE
 355 for targ_alias in `echo $target_alias $enable_targets | sed 's/,/ /g'`
 356 do
 357   if test "$targ_alias" = "all"; then
 358     all_targets=true
 359     elf_list_options=TRUE
 360     elf_shlib_list_options=TRUE
 361     elf_plt_unwind_list_options=TRUE
 362   else
 363     # Canonicalize the secondary target names.
 364     result=`$ac_config_sub $targ_alias 2>/dev/null`
 365     if test -n "$result"; then
 366         targ=$result
 367     else
 368         targ=$targ_alias
 369     fi
 370
 371     . ${srcdir}/configure.tgt
 372
 373     if test "$targ" = "$target"; then
 374       EMUL=$targ_emul
 375     fi
 376
 377     if test x${want64} = xfalse; then
 378       . ${srcdir}/../bfd/config.bfd
 379     fi
 380
 381     if test x${want64} = xtrue; then
 382       targ_extra_emuls="$targ_extra_emuls $targ64_extra_emuls"
 383       targ_extra_libpath="$targ_extra_libpath $targ64_extra_libpath"
 384     fi
 385
 386     for i in $targ_emul $targ_extra_emuls $targ_extra_libpath; do
 387         case " $all_emuls " in
 388         *" e${i}.o "*) ;;
 389         *)
 390           all_emuls="$all_emuls e${i}.o"
 391           eval result=\$tdir_$i
 392           test -z "$result" && result=$targ_alias
 393           TDIRS="$TDIRS
 394 tdir_$i=$result"
 395           case "${i}" in
 396           *elf*)
 397             elf_list_options=TRUE
 398             ;;
 399           *)
 400             if $GREP "TEMPLATE_NAME=elf" ${srcdir}/emulparams/${i}.sh >/dev/null 2>/dev/null; then
 401               elf_list_options=TRUE
 402             fi
 403             ;;
 404           esac
 405           if test "$elf_list_options" = "TRUE"; then
 406             source_sh()
 407             {
 408               . $1
 409             }
 410             source_sh ${srcdir}/emulparams/${i}.sh
 411             if test x${GENERATE_SHLIB_SCRIPT} = xyes; then
 412               elf_shlib_list_options=TRUE
 413             fi
 414             if test x${PLT_UNWIND} = xyes; then
 415               elf_plt_unwind_list_options=TRUE
 416             fi
 417           fi
 418           ;;
 419         esac
 420     done
 421
 422     for i in $targ_emul $targ_extra_libpath; do
 423         case " $all_libpath " in
 424         *" ${i} "*) ;;
 425         *)
 426           if test -z "$all_libpath"; then
 427             all_libpath=${i}
 428           else
 429             all_libpath="$all_libpath ${i}"
 430           fi
 431           ;;
 432         esac
 433     done
 434
 435     for i in $targ_extra_ofiles; do
 436         case " $all_emul_extras " in
 437         *" ${i} "*) ;;
 438         *)
 439           all_emul_extras="$all_emul_extras ${i}"
 440           ;;
 441         esac
 442     done
 443
 444   fi
 445 done
 446
 447 if test x$ac_default_compressed_debug_sections = xyes ; then
 448   AC_DEFINE(DEFAULT_FLAG_COMPRESS_DEBUG, 1, [Define if you want compressed debug sections by default.])
 449 fi
 450
 451 if test "${ac_default_new_dtags}" = unset; then
 452   ac_default_new_dtags=0
 453 fi
 454 AC_DEFINE_UNQUOTED(DEFAULT_NEW_DTAGS,
 455   $ac_default_new_dtags,
 456   [Define to 1 if you want to set DT_RUNPATH instead of DT_RPATH by default.])
 457
 458 if test "${ac_default_ld_z_relro}" = unset; then
 459   ac_default_ld_z_relro=0
 460 fi
 461 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_RELRO,
 462   $ac_default_ld_z_relro,
 463   [Define to 1 if you want to enable -z relro in ELF linker by default.])
 464
 465 ac_default_ld_textrel_check_warning=0
 466 case "${ac_default_ld_textrel_check}" in
 467   unset|no)
 468     ac_default_ld_textrel_check=textrel_check_none
 469     ;;
 470   yes|warning)
 471     ac_default_ld_textrel_check=textrel_check_warning
 472     ac_default_ld_textrel_check_warning=1
 473     ;;
 474   error)
 475     ac_default_ld_textrel_check=textrel_check_error
 476     ;;
 477 esac
 478 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK,
 479   $ac_default_ld_textrel_check,
 480   [The default method for DT_TEXTREL check in ELF linker.])
 481 AC_DEFINE_UNQUOTED(DEFAULT_LD_TEXTREL_CHECK_WARNING,
 482   $ac_default_ld_textrel_check_warning,
 483   [Define to 1 if DT_TEXTREL check is warning in ELF linker by default.])
 484
 485 if test "${ac_default_ld_z_separate_code}" = unset; then
 486   ac_default_ld_z_separate_code=0
 487 fi
 488 AC_DEFINE_UNQUOTED(DEFAULT_LD_Z_SEPARATE_CODE,
 489   $ac_default_ld_z_separate_code,
 490   [Define to 1 if you want to enable -z separate-code in ELF linker by default.])
 491
 492 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_SYSV_HASH],
 493   [$ac_default_emit_sysv_hash],
 494   [Define to 1 if you want to emit sysv hash in the ELF linker by default.])
 495
 496 AC_DEFINE_UNQUOTED([DEFAULT_EMIT_GNU_HASH],
 497   [$ac_default_emit_gnu_hash],
 498   [Define to 1 if you want to emit gnu hash in the ELF linker by default.])
 499
 500 AC_SUBST(elf_list_options)
 501 AC_SUBST(elf_shlib_list_options)
 502 AC_SUBST(elf_plt_unwind_list_options)
 503 AC_SUBST(EMUL)
 504
 505 AC_SUBST(TDIRS)
 506 AM_SUBST_NOTMAKE(TDIRS)
 507
 508 if test x${all_targets} = xtrue; then
 509   if test x${want64} = xtrue; then
 510     EMULATION_OFILES='$(ALL_EMULATIONS) $(ALL_64_EMULATIONS)'
 511     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES) $(ALL_64_EMUL_EXTRA_OFILES)'
 512   else
 513     EMULATION_OFILES='$(ALL_EMULATIONS)'
 514     EMUL_EXTRA_OFILES='$(ALL_EMUL_EXTRA_OFILES)'
 515   fi
 516 else
 517   EMULATION_OFILES=$all_emuls
 518   EMUL_EXTRA_OFILES=$all_emul_extras
 519 fi
 520 AC_SUBST(EMULATION_OFILES)
 521 AC_SUBST(EMUL_EXTRA_OFILES)
 522 AC_SUBST(LIB_PATH)
 523
 524 EMULATION_LIBPATH=$all_libpath
 525 AC_SUBST(EMULATION_LIBPATH)
 526
 527 if test x${enable_static} = xno; then
 528   TESTBFDLIB="-Wl,--rpath,../bfd/.libs ../bfd/.libs/libbfd.so"
 529   TESTCTFLIB="-Wl,--rpath,../libctf/.libs ../libctf/.libs/libctf.so"
 530 else
 531   TESTBFDLIB="../bfd/.libs/libbfd.a"
 532   TESTCTFLIB="../libctf/.libs/libctf.a"
 533 fi
 534 if test "${enable_libctf}" = no; then
 535     TESTCTFLIB=
 536 fi
 537 AC_SUBST(TESTBFDLIB)
 538 AC_SUBST(TESTCTFLIB)
 539
 540 target_vendor=${target_vendor=$host_vendor}
 541 case "$target_vendor" in
 542   hp) EXTRA_SHLIB_EXTENSION=".sl" ;;
 543   *)  EXTRA_SHLIB_EXTENSION= ;;
 544 esac
 545
 546 case "$target_os" in
 547   lynxos) EXTRA_SHLIB_EXTENSION=".a" ;;
 548 esac
 549
 550 if test x${EXTRA_SHLIB_EXTENSION} != x ; then
 551   AC_DEFINE_UNQUOTED(EXTRA_SHLIB_EXTENSION, "$EXTRA_SHLIB_EXTENSION",
 552    [Additional extension a shared object might have.])
 553 fi
 554
 555 AC_CONFIG_COMMANDS([default],
 556 [[
 557 case "$srcdir" in
 558   .) srcdirpre= ;;
 559   *) srcdirpre='$(srcdir)/' ;;
 560 esac
 561 POFILES=
 562 GMOFILES=
 563 for lang in dummy $OBSOLETE_ALL_LINGUAS; do
 564   if test $lang != dummy; then
 565     POFILES="$POFILES $srcdirpre$lang.po"
 566     GMOFILES="$GMOFILES $srcdirpre$lang.gmo"
 567   fi
 568 done
 569 sed -e '/^SRC-POTFILES =/r po/SRC-POTFILES' \
 570     -e '/^BLD-POTFILES =/r po/BLD-POTFILES' \
 571     -e "s,@POFILES@,$POFILES," \
 572     -e "s,@GMOFILES@,$GMOFILES," \
 573     po/Makefile.in > po/Makefile]],[[]])
 574
 575 dnl Required by html, pdf, install-pdf and install-html
 576 AC_SUBST(datarootdir)
 577 AC_SUBST(docdir)
 578 AC_SUBST(htmldir)
 579 AC_SUBST(pdfdir)
 580
 581 AC_CONFIG_FILES(Makefile po/Makefile.in:po/Make-in)
 582 AC_OUTPUT