ld/ldlex.l

   1 %option nounput
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2016 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ld.h"
  29 #include "ldmisc.h"
  30 #include "ldexp.h"
  31 #include "ldlang.h"
  32 #include <ldgram.h>
  33 #include "ldfile.h"
  34 #include "ldlex.h"
  35 #include "ldmain.h"
  36 #include "libiberty.h"
  37
  38 /* The type of top-level parser input.
  39    yylex and yyparse (indirectly) both check this.  */
  40 input_type parser_input;
  41
  42 /* Line number in the current input file.
  43    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  44 unsigned int lineno = 1;
  45
  46 /* The string we are currently lexing, or NULL if we are reading a
  47    file.  */
  48 const char *lex_string = NULL;
  49
  50 /* Support for flex reading from more than one input file (stream).
  51    `include_stack' is flex's input state for each open file;
  52    `file_name_stack' is the file names.  `lineno_stack' is the current
  53    line numbers.
  54
  55    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  56    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  57
  58 #undef YY_INPUT
  59 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  60
  61 #ifndef YY_NO_UNPUT
  62 #define YY_NO_UNPUT
  63 #endif
  64
  65 #define MAX_INCLUDE_DEPTH 10
  66 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  67 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  70 static unsigned int include_stack_ptr = 0;
  71 static int vers_node_nesting = 0;
  72
  73 static int yy_input (char *, int);
  74 static void comment (void);
  75 static void lex_warn_invalid (char *where, char *what);
  76
  77 /* STATES
  78         EXPRESSION      definitely in an expression
  79         SCRIPT          definitely in a script
  80         INPUTLIST       definitely in a script, a filename-list
  81         BOTH            either EXPRESSION or SCRIPT
  82         DEFSYMEXP       in an argument to -defsym
  83         MRI             in an MRI script
  84         VERS_START      starting a Sun style mapfile
  85         VERS_SCRIPT     a Sun style mapfile
  86         VERS_NODE       a node within a Sun style mapfile
  87 */
  88 #define RTOKEN(x)  {  yylval.token = x; return x; }
  89
  90 /* Some versions of flex want this.  */
  91 #ifndef yywrap
  92 int yywrap (void) { return 1; }
  93 #endif
  94 %}
  95
  96 %a 4000
  97 %o 5000
  98
  99 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 100 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 101 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 102 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 103 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 104 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
 105 WHITE           [ \t\n\r]+
 106
 107 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 108
 109 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 110 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 111
 112 %s SCRIPT
 113 %s INPUTLIST
 114 %s EXPRESSION
 115 %s BOTH
 116 %s DEFSYMEXP
 117 %s MRI
 118 %s VERS_START
 119 %s VERS_SCRIPT
 120 %s VERS_NODE
 121 %%
 122
 123   if (parser_input != input_selected)
 124     {
 125       /* The first token of the input determines the initial parser state.  */
 126       input_type t = parser_input;
 127       parser_input = input_selected;
 128       switch (t)
 129         {
 130         case input_script: return INPUT_SCRIPT; break;
 131         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 132         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 133         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 134         case input_defsym: return INPUT_DEFSYM; break;
 135         default: abort ();
 136         }
 137     }
 138
 139 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 140
 141
 142 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 143 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 144 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 145 <DEFSYMEXP>"="                  { RTOKEN('='); }
 146
 147 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 148                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 149                                 yylval.bigint.str = NULL;
 150                                 return INT;
 151                         }
 152
 153 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 154                                    int ibase ;
 155                                    switch (yytext[yyleng - 1]) {
 156                                     case 'X':
 157                                     case 'x':
 158                                     case 'H':
 159                                     case 'h':
 160                                      ibase = 16;
 161                                      break;
 162                                     case 'O':
 163                                     case 'o':
 164                                      ibase = 8;
 165                                      break;
 166                                     case 'B':
 167                                     case 'b':
 168                                      ibase = 2;
 169                                      break;
 170                                     default:
 171                                      ibase = 10;
 172                                    }
 173                                    yylval.integer = bfd_scan_vma (yytext, 0,
 174                                                                   ibase);
 175                                    yylval.bigint.str = NULL;
 176                                    return INT;
 177                                  }
 178 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 179                                   char *s = yytext;
 180                                   int ibase = 0;
 181
 182                                   if (*s == '$')
 183                                     {
 184                                       ++s;
 185                                       ibase = 16;
 186                                     }
 187                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 188                                   yylval.bigint.str = NULL;
 189                                   if (yytext[yyleng - 1] == 'M'
 190                                       || yytext[yyleng - 1] == 'm')
 191                                     {
 192                                       yylval.integer *= 1024 * 1024;
 193                                     }
 194                                   else if (yytext[yyleng - 1] == 'K'
 195                                       || yytext[yyleng - 1]=='k')
 196                                     {
 197                                       yylval.integer *= 1024;
 198                                     }
 199                                   else if (yytext[0] == '0'
 200                                            && (yytext[1] == 'x'
 201                                                || yytext[1] == 'X'))
 202                                     {
 203                                       yylval.bigint.str = xstrdup (yytext + 2);
 204                                     }
 205                                   return INT;
 206                                 }
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 240 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 241 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 243 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 244 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 245 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 246 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 247 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 248 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 249 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 250 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 251 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 252 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 253 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 254 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 255 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 256 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 257 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 258 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 259 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 260 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 261 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 262 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 263 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 264 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 265 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 266 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 267 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 268 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 269 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 270 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 271 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 272 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 273 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 274 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 275 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 276 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 277 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 278 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 279 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 280 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 281 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 282 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 283 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 284 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 285 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 286 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 287 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 288 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 289 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 290 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 291 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 292 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 293 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 294 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 295 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 296 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 297 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 298 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 299 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 300 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 301 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 302 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 303 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 304 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 305 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 306 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 307 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 308 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 309 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 310 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 311 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 312 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 313 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 314 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 315 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 316 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 317 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 318 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 319 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 320 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 321 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 322 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 323 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 324 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 325 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 326 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 327 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 328 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 329 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 330 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 331 <MRI>"#".*\n?                   { ++ lineno; }
 332 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 333 <MRI>"*".*                      { /* Mri comment line */ }
 334 <MRI>";".*                      { /* Mri comment line */ }
 335 <MRI>"END"                      { RTOKEN(ENDWORD); }
 336 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 337 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 338 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 339 <MRI>"BASE"                     { RTOKEN(BASE); }
 340 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 341 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 342 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 343 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 344 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 345 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 346 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 347 <MRI>"CASE"                     { RTOKEN(CASE); }
 348 <MRI>"START"                    { RTOKEN(START); }
 349 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 350 <MRI>"SECT"                     { RTOKEN(SECT); }
 351 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 352 <MRI>"end"                      { RTOKEN(ENDWORD); }
 353 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 354 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 355 <MRI>"chip"                     { RTOKEN(CHIP); }
 356 <MRI>"base"                     { RTOKEN(BASE); }
 357 <MRI>"alias"                    { RTOKEN(ALIAS); }
 358 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 359 <MRI>"load"                     { RTOKEN(LOAD); }
 360 <MRI>"public"                   { RTOKEN(PUBLIC); }
 361 <MRI>"order"                    { RTOKEN(ORDER); }
 362 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 363 <MRI>"format"                   { RTOKEN(FORMAT); }
 364 <MRI>"case"                     { RTOKEN(CASE); }
 365 <MRI>"extern"                   { RTOKEN(EXTERN); }
 366 <MRI>"start"                    { RTOKEN(START); }
 367 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 368 <MRI>"sect"                     { RTOKEN(SECT); }
 369 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 370
 371 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 372 /* Filename without commas, needed to parse mri stuff */
 373                                  yylval.name = xstrdup (yytext);
 374                                   return NAME;
 375                                 }
 376
 377
 378 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 379                                  yylval.name = xstrdup (yytext);
 380                                   return NAME;
 381                                 }
 382 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 383 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 384                                  yylval.name = xstrdup (yytext);
 385                                   return NAME;
 386                                 }
 387 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 388                                   yylval.name = xstrdup (yytext + 2);
 389                                   return LNAME;
 390                                 }
 391 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 392                                  yylval.name = xstrdup (yytext);
 393                                   return NAME;
 394                                 }
 395 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 396                                   yylval.name = xstrdup (yytext + 2);
 397                                   return LNAME;
 398                                 }
 399 <SCRIPT>{WILDCHAR}* {
 400                 /* Annoyingly, this pattern can match comments, and we have
 401                    longest match issues to consider.  So if the first two
 402                    characters are a comment opening, put the input back and
 403                    try again.  */
 404                 if (yytext[0] == '/' && yytext[1] == '*')
 405                   {
 406                     yyless (2);
 407                     comment ();
 408                   }
 409                 else
 410                   {
 411                     yylval.name = xstrdup (yytext);
 412                     return NAME;
 413                   }
 414         }
 415
 416 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 417                                         /* No matter the state, quotes
 418                                            give what's inside */
 419                                         yylval.name = xstrdup (yytext + 1);
 420                                         yylval.name[yyleng - 2] = 0;
 421                                         return NAME;
 422                                 }
 423 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 424 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 425
 426 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 427
 428 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 429
 430 <VERS_NODE>local                { RTOKEN(LOCAL); }
 431
 432 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 433
 434 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 435                                   return VERS_IDENTIFIER; }
 436
 437 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 438                                   return VERS_TAG; }
 439
 440 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 441
 442 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 443                                   vers_node_nesting = 0;
 444                                   return *yytext;
 445                                 }
 446 <VERS_SCRIPT>"}"                { return *yytext; }
 447 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 448 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 449                                     BEGIN(VERS_SCRIPT);
 450                                   return *yytext;
 451                                 }
 452
 453 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n]        { lineno++; }
 454
 455 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 456
 457 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 458
 459 <<EOF>> {
 460   include_stack_ptr--;
 461   if (include_stack_ptr == 0)
 462     yyterminate ();
 463   else
 464     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 465
 466   lineno = lineno_stack[include_stack_ptr];
 467   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 468
 469   return END;
 470 }
 471
 472 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 473 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 474
 475 %%
 476 \f
 477
 478 /* Switch flex to reading script file NAME, open on FILE,
 479    saving the current input info on the include stack.  */
 480
 481 void
 482 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 483 {
 484   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 485     {
 486       einfo ("%F:includes nested too deeply\n");
 487     }
 488   file_name_stack[include_stack_ptr] = name;
 489   lineno_stack[include_stack_ptr] = lineno;
 490   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 491   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 492
 493   include_stack_ptr++;
 494   lineno = 1;
 495   input_flags.sysrooted = sysrooted;
 496   yyin = file;
 497   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 498 }
 499
 500 /* Return a newly created flex input buffer containing STRING,
 501    which is SIZE bytes long.  */
 502
 503 static YY_BUFFER_STATE
 504 yy_create_string_buffer (const char *string, size_t size)
 505 {
 506   YY_BUFFER_STATE b;
 507
 508   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 509   b = malloc (sizeof (struct yy_buffer_state));
 510   b->yy_input_file = 0;
 511   b->yy_buf_size = size;
 512
 513   /* yy_ch_buf has to be 2 characters longer than the size given because
 514      we need to put in 2 end-of-buffer characters.  */
 515   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 516
 517   b->yy_ch_buf[0] = '\n';
 518   strcpy (b->yy_ch_buf+1, string);
 519   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 520   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 521   b->yy_n_chars = size+1;
 522   b->yy_buf_pos = &b->yy_ch_buf[1];
 523
 524   b->yy_is_our_buffer = 1;
 525   b->yy_is_interactive = 0;
 526   b->yy_at_bol = 1;
 527   b->yy_fill_buffer = 0;
 528
 529   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 530      a flex internal interface in the first place!  */
 531 #ifdef YY_BUFFER_NEW
 532   b->yy_buffer_status = YY_BUFFER_NEW;
 533 #else
 534   b->yy_eof_status = EOF_NOT_SEEN;
 535 #endif
 536
 537   return b;
 538 }
 539
 540 /* Switch flex to reading from STRING, saving the current input info
 541    on the include stack.  */
 542
 543 void
 544 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 545 {
 546   YY_BUFFER_STATE tmp;
 547
 548   yy_init = 0;
 549   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 550     {
 551       einfo("%F: macros nested too deeply\n");
 552     }
 553   file_name_stack[include_stack_ptr] = fake_filename;
 554   lineno_stack[include_stack_ptr] = lineno;
 555   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 556   include_stack_ptr++;
 557   lineno = count;
 558   tmp = yy_create_string_buffer (string, strlen (string));
 559   yy_switch_to_buffer (tmp);
 560 }
 561 \f
 562 /* Functions to switch to a different flex start condition,
 563    saving the current start condition on `state_stack'.  */
 564
 565 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 566 static int *state_stack_p = state_stack;
 567
 568 void
 569 ldlex_script (void)
 570 {
 571   *(state_stack_p)++ = yy_start;
 572   BEGIN (SCRIPT);
 573 }
 574
 575 void
 576 ldlex_inputlist (void)
 577 {
 578   *(state_stack_p)++ = yy_start;
 579   BEGIN (INPUTLIST);
 580 }
 581
 582 void
 583 ldlex_mri_script (void)
 584 {
 585   *(state_stack_p)++ = yy_start;
 586   BEGIN (MRI);
 587 }
 588
 589 void
 590 ldlex_version_script (void)
 591 {
 592   *(state_stack_p)++ = yy_start;
 593   BEGIN (VERS_START);
 594 }
 595
 596 void
 597 ldlex_version_file (void)
 598 {
 599   *(state_stack_p)++ = yy_start;
 600   BEGIN (VERS_SCRIPT);
 601 }
 602
 603 void
 604 ldlex_defsym (void)
 605 {
 606   *(state_stack_p)++ = yy_start;
 607   BEGIN (DEFSYMEXP);
 608 }
 609
 610 void
 611 ldlex_expression (void)
 612 {
 613   *(state_stack_p)++ = yy_start;
 614   BEGIN (EXPRESSION);
 615 }
 616
 617 void
 618 ldlex_both (void)
 619 {
 620   *(state_stack_p)++ = yy_start;
 621   BEGIN (BOTH);
 622 }
 623
 624 void
 625 ldlex_popstate (void)
 626 {
 627   yy_start = *(--state_stack_p);
 628 }
 629
 630 /* Return the current file name, or the previous file if no file is
 631    current.  */
 632
 633 const char*
 634 ldlex_filename (void)
 635 {
 636   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 637 }
 638 \f
 639
 640 /* Place up to MAX_SIZE characters in BUF and return
 641    either the number of characters read, or 0 to indicate EOF.  */
 642
 643 static int
 644 yy_input (char *buf, int max_size)
 645 {
 646   int result = 0;
 647   if (YY_CURRENT_BUFFER->yy_input_file)
 648     {
 649       if (yyin)
 650         {
 651           result = fread (buf, 1, max_size, yyin);
 652           if (result < max_size && ferror (yyin))
 653             einfo ("%F%P: read in flex scanner failed\n");
 654         }
 655     }
 656   return result;
 657 }
 658
 659 /* Eat the rest of a C-style comment.  */
 660
 661 static void
 662 comment (void)
 663 {
 664   int c;
 665
 666   while (1)
 667   {
 668     c = input();
 669     while (c != '*' && c != EOF)
 670     {
 671       if (c == '\n')
 672         lineno++;
 673       c = input();
 674     }
 675
 676     if (c == '*')
 677     {
 678       c = input();
 679       while (c == '*')
 680        c = input();
 681       if (c == '/')
 682        break;                   /* found the end */
 683     }
 684
 685     if (c == '\n')
 686       lineno++;
 687
 688     if (c == EOF)
 689     {
 690       einfo( "%F%P: EOF in comment\n");
 691       break;
 692     }
 693   }
 694 }
 695
 696 /* Warn the user about a garbage character WHAT in the input
 697    in context WHERE.  */
 698
 699 static void
 700 lex_warn_invalid (char *where, char *what)
 701 {
 702   char buf[5];
 703
 704   /* If we have found an input file whose format we do not recognize,
 705      and we are therefore treating it as a linker script, and we find
 706      an invalid character, then most likely this is a real object file
 707      of some different format.  Treat it as such.  */
 708   if (ldfile_assumed_script)
 709     {
 710       bfd_set_error (bfd_error_file_not_recognized);
 711       einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
 712     }
 713
 714   if (! ISPRINT (*what))
 715     {
 716       sprintf (buf, "\\%03o", *(unsigned char *) what);
 717       what = buf;
 718     }
 719
 720   einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
 721 }