ld/ldlex.l

   1 %{
   2
   3 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
   4    2000, 2001, 2002, 2003  Free Software Foundation, Inc.
   5
   6 This file is part of GLD, the Gnu Linker.
   7
   8 GLD is free software; you can redistribute it and/or modify
   9 it under the terms of the GNU General Public License as published by
  10 the Free Software Foundation; either version 2, or (at your option)
  11 any later version.
  12
  13 GLD is distributed in the hope that it will be useful,
  14 but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 GNU General Public License for more details.
  17
  18 You should have received a copy of the GNU General Public License
  19 along with GLD; see the file COPYING.  If not, write to the Free
  20 Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  21 02111-1307, USA.  */
  22
  23 /*
  24 This was written by steve chamberlain
  25                     sac@cygnus.com
  26 */
  27
  28
  29 #include <stdio.h>
  30
  31 #include "bfd.h"
  32 #include "sysdep.h"
  33 #include "safe-ctype.h"
  34 #include "bfdlink.h"
  35 #include "ld.h"
  36 #include "ldmisc.h"
  37 #include "ldexp.h"
  38 #include "ldlang.h"
  39 #include <ldgram.h>
  40 #include "ldfile.h"
  41 #include "ldlex.h"
  42 #include "ldmain.h"
  43 #include "libiberty.h"
  44
  45 /* The type of top-level parser input.
  46    yylex and yyparse (indirectly) both check this.  */
  47 input_type parser_input;
  48
  49 /* Line number in the current input file.
  50    (FIXME Actually, it doesn't appear to get reset for each file?)  */
  51 unsigned int lineno = 1;
  52
  53 /* The string we are currently lexing, or NULL if we are reading a
  54    file.  */
  55 const char *lex_string = NULL;
  56
  57 /* Support for flex reading from more than one input file (stream).
  58    `include_stack' is flex's input state for each open file;
  59    `file_name_stack' is the file names.  `lineno_stack' is the current
  60    line numbers.
  61
  62    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  63    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  64
  65 #undef YY_INPUT
  66 #define YY_INPUT(buf,result,max_size) yy_input (buf, &result, max_size)
  67
  68 #define MAX_INCLUDE_DEPTH 10
  69 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  70 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  71 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  72 static unsigned int include_stack_ptr = 0;
  73 static int vers_node_nesting = 0;
  74
  75 static void yy_input (char *, int *, int);
  76 static void comment (void);
  77 static void lex_warn_invalid (char *where, char *what);
  78
  79 /* STATES
  80         EXPRESSION      definitely in an expression
  81         SCRIPT          definitely in a script
  82         BOTH            either EXPRESSION or SCRIPT
  83         DEFSYMEXP       in an argument to -defsym
  84         MRI             in an MRI script
  85         VERS_START      starting a Sun style mapfile
  86         VERS_SCRIPT     a Sun style mapfile
  87         VERS_NODE       a node within a Sun style mapfile
  88 */
  89 #define RTOKEN(x)  {  yylval.token = x; return x; }
  90
  91 /* Some versions of flex want this.  */
  92 #ifndef yywrap
  93 int yywrap (void) { return 1; }
  94 #endif
  95 %}
  96
  97 %a 4000
  98 %o 5000
  99
 100 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
 101 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
 102 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
 103 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
 104 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
 105 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*]
 106 WHITE           [ \t\n\r]+
 107
 108 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 109
 110 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 111 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 112
 113 %s SCRIPT
 114 %s EXPRESSION
 115 %s BOTH
 116 %s DEFSYMEXP
 117 %s MRI
 118 %s VERS_START
 119 %s VERS_SCRIPT
 120 %s VERS_NODE
 121 %%
 122
 123   if (parser_input != input_selected)
 124     {
 125       /* The first token of the input determines the initial parser state.  */
 126       input_type t = parser_input;
 127       parser_input = input_selected;
 128       switch (t)
 129         {
 130         case input_script: return INPUT_SCRIPT; break;
 131         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 132         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 133         case input_defsym: return INPUT_DEFSYM; break;
 134         default: abort ();
 135         }
 136     }
 137
 138 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
 139
 140
 141 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 142 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 143 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 144 <DEFSYMEXP>"="                  { RTOKEN('='); }
 145
 146 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 147                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 148                                 yylval.bigint.str = NULL;
 149                                 return INT;
 150                         }
 151
 152 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 153                                    int ibase ;
 154                                    switch (yytext[yyleng - 1]) {
 155                                     case 'X':
 156                                     case 'x':
 157                                     case 'H':
 158                                     case 'h':
 159                                      ibase = 16;
 160                                      break;
 161                                     case 'O':
 162                                     case 'o':
 163                                      ibase = 8;
 164                                      break;
 165                                     case 'B':
 166                                     case 'b':
 167                                      ibase = 2;
 168                                      break;
 169                                     default:
 170                                      ibase = 10;
 171                                    }
 172                                    yylval.integer = bfd_scan_vma (yytext, 0,
 173                                                                   ibase);
 174                                    yylval.bigint.str = NULL;
 175                                    return INT;
 176                                  }
 177 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 178                                   char *s = yytext;
 179                                   int ibase = 0;
 180
 181                                   if (*s == '$')
 182                                     {
 183                                       ++s;
 184                                       ibase = 16;
 185                                     }
 186                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 187                                   yylval.bigint.str = NULL;
 188                                   if (yytext[yyleng - 1] == 'M'
 189                                       || yytext[yyleng - 1] == 'm')
 190                                     {
 191                                       yylval.integer *= 1024 * 1024;
 192                                     }
 193                                   else if (yytext[yyleng - 1] == 'K'
 194                                       || yytext[yyleng - 1]=='k')
 195                                     {
 196                                       yylval.integer *= 1024;
 197                                     }
 198                                   else if (yytext[0] == '0'
 199                                            && (yytext[1] == 'x'
 200                                                || yytext[1] == 'X'))
 201                                     {
 202                                       yylval.bigint.str = xstrdup (yytext + 2);
 203                                     }
 204                                   return INT;
 205                                 }
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 221 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 236 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI>"="          { RTOKEN('=');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>"}"                 { RTOKEN('}') ; }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>"{"                 { RTOKEN('{'); }
 240 <BOTH,SCRIPT,EXPRESSION,MRI>")"                 { RTOKEN(')');}
 241 <BOTH,SCRIPT,EXPRESSION,MRI>"("                 { RTOKEN('(');}
 242 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 243 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 244 <BOTH,SCRIPT>"MEMORY"           { RTOKEN(MEMORY);}
 245 <BOTH,SCRIPT>"ORIGIN"           { RTOKEN(ORIGIN);}
 246 <BOTH,SCRIPT>"VERSION"          { RTOKEN(VERSIONK);}
 247 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 248 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 249 <BOTH,SCRIPT>"LENGTH"           { RTOKEN(LENGTH);}
 250 <EXPRESSION,BOTH,SCRIPT>"ALIGN"                 { RTOKEN(ALIGN_K);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 252 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 253 <EXPRESSION,BOTH,SCRIPT>"ADDR"                  { RTOKEN(ADDR);}
 254 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"              { RTOKEN(LOADADDR);}
 255 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 256 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 257 <EXPRESSION,BOTH>"ASSERT"               { RTOKEN(ASSERT_K); }
 258 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 259 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 260 <EXPRESSION,BOTH,SCRIPT>"NEXT"                  { RTOKEN(NEXT);}
 261 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 262 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 263 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 264 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"                { RTOKEN(SIZEOF);}
 265 <BOTH,SCRIPT>"TARGET"           { RTOKEN(TARGET_K);}
 266 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 267 <BOTH,SCRIPT>"OUTPUT"           { RTOKEN(OUTPUT);}
 268 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 269 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 270 <EXPRESSION,BOTH,SCRIPT>"DEFINED"               { RTOKEN(DEFINED);}
 271 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 272 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 273 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION" { RTOKEN(FORCE_COMMON_ALLOCATION);}
 274 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 275 <BOTH,SCRIPT>"SECTIONS"         { RTOKEN(SECTIONS);}
 276 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 277 <BOTH,SCRIPT>"STARTUP"          { RTOKEN(STARTUP);}
 278 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 279 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 280 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 281 <BOTH,SCRIPT>"SYSLIB"           { RTOKEN(SYSLIB);}
 282 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 283 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 284 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 285 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 286 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 287 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 288 <BOTH,SCRIPT>"NOFLOAT"          { RTOKEN(NOFLOAT);}
 289 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 290 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 291 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT); }
 292 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 293 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 294 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 295 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 296 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 297 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 298 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 299 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 300 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 301 <BOTH,SCRIPT>"INCLUDE"                  { RTOKEN(INCLUDE);}
 302 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 303 <EXPRESSION,BOTH,SCRIPT>"AT"                    { RTOKEN(AT);}
 304 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"              { RTOKEN(SUBALIGN);}
 305 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"               { RTOKEN(PROVIDE); }
 306 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 307 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"        { RTOKEN(EXCLUDE_FILE); }
 308 <MRI>"#".*\n?                   { ++ lineno; }
 309 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 310 <MRI>"*".*                      { /* Mri comment line */ }
 311 <MRI>";".*                      { /* Mri comment line */ }
 312 <MRI>"END"                      { RTOKEN(ENDWORD); }
 313 <MRI>"ALIGNMOD"         { RTOKEN(ALIGNMOD);}
 314 <MRI>"ALIGN"            { RTOKEN(ALIGN_K);}
 315 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 316 <MRI>"BASE"                     { RTOKEN(BASE); }
 317 <MRI>"ALIAS"                     { RTOKEN(ALIAS); }
 318 <MRI>"TRUNCATE"                     { RTOKEN(TRUNCATE); }
 319 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 320 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 321 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 322 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 323 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 324 <MRI>"CASE"                     { RTOKEN(CASE); }
 325 <MRI>"START"                    { RTOKEN(START); }
 326 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 327 <MRI>"SECT"                     { RTOKEN(SECT); }
 328 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 329 <MRI>"end"                      { RTOKEN(ENDWORD); }
 330 <MRI>"alignmod"         { RTOKEN(ALIGNMOD);}
 331 <MRI>"align"            { RTOKEN(ALIGN_K);}
 332 <MRI>"chip"                     { RTOKEN(CHIP); }
 333 <MRI>"base"                     { RTOKEN(BASE); }
 334 <MRI>"alias"                     { RTOKEN(ALIAS); }
 335 <MRI>"truncate"                     { RTOKEN(TRUNCATE); }
 336 <MRI>"load"                     { RTOKEN(LOAD); }
 337 <MRI>"public"                   { RTOKEN(PUBLIC); }
 338 <MRI>"order"                    { RTOKEN(ORDER); }
 339 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 340 <MRI>"format"                   { RTOKEN(FORMAT); }
 341 <MRI>"case"                     { RTOKEN(CASE); }
 342 <MRI>"extern"                   { RTOKEN(EXTERN); }
 343 <MRI>"start"                    { RTOKEN(START); }
 344 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 345 <MRI>"sect"                     { RTOKEN(SECT); }
 346 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 347
 348 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 349 /* Filename without commas, needed to parse mri stuff */
 350                                  yylval.name = xstrdup (yytext);
 351                                   return NAME;
 352                                 }
 353
 354
 355 <BOTH,EXPRESSION>{FILENAMECHAR1}{FILENAMECHAR}* {
 356                                  yylval.name = xstrdup (yytext);
 357                                   return NAME;
 358                                 }
 359 <BOTH,EXPRESSION>"-l"{FILENAMECHAR}+ {
 360                                   yylval.name = xstrdup (yytext + 2);
 361                                   return LNAME;
 362                                 }
 363 <SCRIPT>{WILDCHAR}* {
 364                 /* Annoyingly, this pattern can match comments, and we have
 365                    longest match issues to consider.  So if the first two
 366                    characters are a comment opening, put the input back and
 367                    try again.  */
 368                 if (yytext[0] == '/' && yytext[1] == '*')
 369                   {
 370                     yyless (2);
 371                     comment ();
 372                   }
 373                 else
 374                   {
 375                     yylval.name = xstrdup (yytext);
 376                     return NAME;
 377                   }
 378         }
 379
 380 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
 381                                         /* No matter the state, quotes
 382                                            give what's inside */
 383                                         yylval.name = xstrdup (yytext + 1);
 384                                         yylval.name[yyleng - 2] = 0;
 385                                         return NAME;
 386                                 }
 387 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 388 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 389
 390 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 391
 392 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 393
 394 <VERS_NODE>local                { RTOKEN(LOCAL); }
 395
 396 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 397
 398 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 399                                   return VERS_IDENTIFIER; }
 400
 401 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 402                                   return VERS_TAG; }
 403
 404 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 405
 406 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 407                                   vers_node_nesting = 0;
 408                                   return *yytext;
 409                                 }
 410 <VERS_SCRIPT>"}"                { return *yytext; }
 411 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 412 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 413                                     BEGIN(VERS_SCRIPT);
 414                                   return *yytext;
 415                                 }
 416
 417 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
 418
 419 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 420
 421 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
 422
 423 <<EOF>> {
 424   include_stack_ptr--;
 425
 426   if (include_stack_ptr == 0)
 427   {
 428     yyterminate ();
 429   }
 430   else
 431   {
 432     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 433   }
 434
 435   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
 436   lineno = lineno_stack[include_stack_ptr];
 437
 438   return END;
 439 }
 440
 441 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 442 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 443
 444 %%
 445 \f
 446
 447 /* Switch flex to reading script file NAME, open on FILE,
 448    saving the current input info on the include stack.  */
 449
 450 void
 451 lex_push_file (FILE *file, const char *name)
 452 {
 453   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 454     {
 455       einfo ("%F:includes nested too deeply\n");
 456     }
 457   file_name_stack[include_stack_ptr] = name;
 458   lineno_stack[include_stack_ptr] = lineno;
 459   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 460
 461   include_stack_ptr++;
 462   lineno = 1;
 463   yyin = file;
 464   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 465 }
 466
 467 /* Return a newly created flex input buffer containing STRING,
 468    which is SIZE bytes long.  */
 469
 470 static YY_BUFFER_STATE
 471 yy_create_string_buffer (const char *string, size_t size)
 472 {
 473   YY_BUFFER_STATE b;
 474
 475   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 476   b = malloc (sizeof (struct yy_buffer_state));
 477   b->yy_input_file = 0;
 478   b->yy_buf_size = size;
 479
 480   /* yy_ch_buf has to be 2 characters longer than the size given because
 481      we need to put in 2 end-of-buffer characters.  */
 482   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 483
 484   b->yy_ch_buf[0] = '\n';
 485   strcpy (b->yy_ch_buf+1, string);
 486   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 487   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 488   b->yy_n_chars = size+1;
 489   b->yy_buf_pos = &b->yy_ch_buf[1];
 490
 491   b->yy_is_our_buffer = 1;
 492   b->yy_is_interactive = 0;
 493   b->yy_at_bol = 1;
 494   b->yy_fill_buffer = 0;
 495
 496   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 497      a flex internal interface in the first place!  */
 498 #ifdef YY_BUFFER_NEW
 499   b->yy_buffer_status = YY_BUFFER_NEW;
 500 #else
 501   b->yy_eof_status = EOF_NOT_SEEN;
 502 #endif
 503
 504   return b;
 505 }
 506
 507 /* Switch flex to reading from STRING, saving the current input info
 508    on the include stack.  */
 509
 510 void
 511 lex_redirect (const char *string)
 512 {
 513   YY_BUFFER_STATE tmp;
 514
 515   yy_init = 0;
 516   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 517     {
 518       einfo("%F: macros nested too deeply\n");
 519     }
 520   file_name_stack[include_stack_ptr] = "redirect";
 521   lineno_stack[include_stack_ptr] = lineno;
 522   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 523   include_stack_ptr++;
 524   lineno = 1;
 525   tmp = yy_create_string_buffer (string, strlen (string));
 526   yy_switch_to_buffer (tmp);
 527 }
 528 \f
 529 /* Functions to switch to a different flex start condition,
 530    saving the current start condition on `state_stack'.  */
 531
 532 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 533 static int *state_stack_p = state_stack;
 534
 535 void
 536 ldlex_script (void)
 537 {
 538   *(state_stack_p)++ = yy_start;
 539   BEGIN (SCRIPT);
 540 }
 541
 542 void
 543 ldlex_mri_script (void)
 544 {
 545   *(state_stack_p)++ = yy_start;
 546   BEGIN (MRI);
 547 }
 548
 549 void
 550 ldlex_version_script (void)
 551 {
 552   *(state_stack_p)++ = yy_start;
 553   BEGIN (VERS_START);
 554 }
 555
 556 void
 557 ldlex_version_file (void)
 558 {
 559   *(state_stack_p)++ = yy_start;
 560   BEGIN (VERS_SCRIPT);
 561 }
 562
 563 void
 564 ldlex_defsym (void)
 565 {
 566   *(state_stack_p)++ = yy_start;
 567   BEGIN (DEFSYMEXP);
 568 }
 569
 570 void
 571 ldlex_expression (void)
 572 {
 573   *(state_stack_p)++ = yy_start;
 574   BEGIN (EXPRESSION);
 575 }
 576
 577 void
 578 ldlex_both (void)
 579 {
 580   *(state_stack_p)++ = yy_start;
 581   BEGIN (BOTH);
 582 }
 583
 584 void
 585 ldlex_popstate (void)
 586 {
 587   yy_start = *(--state_stack_p);
 588 }
 589 \f
 590
 591 /* Place up to MAX_SIZE characters in BUF and return in *RESULT
 592    either the number of characters read, or 0 to indicate EOF.  */
 593
 594 static void
 595 yy_input (char *buf, int *result, int max_size)
 596 {
 597   *result = 0;
 598   if (YY_CURRENT_BUFFER->yy_input_file)
 599     {
 600       if (yyin)
 601         {
 602           *result = fread (buf, 1, max_size, yyin);
 603           if (*result < max_size && ferror (yyin))
 604             einfo ("%F%P: read in flex scanner failed\n");
 605         }
 606     }
 607 }
 608
 609 /* Eat the rest of a C-style comment.  */
 610
 611 static void
 612 comment (void)
 613 {
 614   int c;
 615
 616   while (1)
 617   {
 618     c = input();
 619     while (c != '*' && c != EOF)
 620     {
 621       if (c == '\n')
 622         lineno++;
 623       c = input();
 624     }
 625
 626     if (c == '*')
 627     {
 628       c = input();
 629       while (c == '*')
 630        c = input();
 631       if (c == '/')
 632        break;                   /* found the end */
 633     }
 634
 635     if (c == '\n')
 636       lineno++;
 637
 638     if (c == EOF)
 639     {
 640       einfo( "%F%P: EOF in comment\n");
 641       break;
 642     }
 643   }
 644 }
 645
 646 /* Warn the user about a garbage character WHAT in the input
 647    in context WHERE.  */
 648
 649 static void
 650 lex_warn_invalid (char *where, char *what)
 651 {
 652   char buf[5];
 653
 654   /* If we have found an input file whose format we do not recognize,
 655      and we are therefore treating it as a linker script, and we find
 656      an invalid character, then most likely this is a real object file
 657      of some different format.  Treat it as such.  */
 658   if (ldfile_assumed_script)
 659     {
 660       bfd_set_error (bfd_error_file_not_recognized);
 661       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
 662     }
 663
 664   if (! ISPRINT (*what))
 665     {
 666       sprintf (buf, "\\%03o", (unsigned int) *what);
 667       what = buf;
 668     }
 669
 670   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
 671 }