ld/ldlex.l

   1 %option nounput noyywrap
   2
   3 %{
   4
   5 /* Copyright (C) 1991-2017 Free Software Foundation, Inc.
   6    Written by Steve Chamberlain of Cygnus Support.
   7
   8    This file is part of the GNU Binutils.
   9
  10    This program is free software; you can redistribute it and/or modify
  11    it under the terms of the GNU General Public License as published by
  12    the Free Software Foundation; either version 3 of the License, or
  13    (at your option) any later version.
  14
  15    This program is distributed in the hope that it will be useful,
  16    but WITHOUT ANY WARRANTY; without even the implied warranty of
  17    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18    GNU General Public License for more details.
  19
  20    You should have received a copy of the GNU General Public License
  21    along with this program; if not, write to the Free Software
  22    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
  23    MA 02110-1301, USA.  */
  24
  25 #include "bfd.h"
  26 #include "safe-ctype.h"
  27 #include "bfdlink.h"
  28 #include "ld.h"
  29 #include "ldmisc.h"
  30 #include "ldexp.h"
  31 #include "ldlang.h"
  32 #include <ldgram.h>
  33 #include "ldfile.h"
  34 #include "ldlex.h"
  35 #include "ldmain.h"
  36 #include "libiberty.h"
  37
  38 /* The type of top-level parser input.
  39    yylex and yyparse (indirectly) both check this.  */
  40 input_type parser_input;
  41
  42 /* Line number in the current input file.  */
  43 unsigned int lineno;
  44
  45 /* The string we are currently lexing, or NULL if we are reading a
  46    file.  */
  47 const char *lex_string = NULL;
  48
  49 /* Support for flex reading from more than one input file (stream).
  50    `include_stack' is flex's input state for each open file;
  51    `file_name_stack' is the file names.  `lineno_stack' is the current
  52    line numbers.
  53
  54    If `include_stack_ptr' is 0, we haven't started reading anything yet.
  55    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
  56
  57 #undef YY_INPUT
  58 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
  59
  60 #ifndef YY_NO_UNPUT
  61 #define YY_NO_UNPUT
  62 #endif
  63
  64 #define MAX_INCLUDE_DEPTH 10
  65 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
  66 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
  67 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
  68 static unsigned int sysrooted_stack[MAX_INCLUDE_DEPTH];
  69 static unsigned int include_stack_ptr = 0;
  70 static int vers_node_nesting = 0;
  71
  72 static int yy_input (char *, int);
  73 static void comment (void);
  74 static void lex_warn_invalid (char *where, char *what);
  75
  76 /* STATES
  77         EXPRESSION      definitely in an expression
  78         SCRIPT          definitely in a script
  79         INPUTLIST       definitely in a script, a filename-list
  80         BOTH            either EXPRESSION or SCRIPT
  81         DEFSYMEXP       in an argument to -defsym
  82         MRI             in an MRI script
  83         VERS_START      starting a Sun style mapfile
  84         VERS_SCRIPT     a Sun style mapfile
  85         VERS_NODE       a node within a Sun style mapfile
  86 */
  87 #define RTOKEN(x)  {  yylval.token = x; return x; }
  88
  89 %}
  90
  91 %a 4000
  92 %o 5000
  93
  94 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
  95 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
  96 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
  97 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
  98 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
  99 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
 100 WHITE           [ \t\n\r]+
 101
 102 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
 103
 104 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
 105 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
 106
 107 %s SCRIPT
 108 %s INPUTLIST
 109 %s EXPRESSION
 110 %s BOTH
 111 %s DEFSYMEXP
 112 %s MRI
 113 %s VERS_START
 114 %s VERS_SCRIPT
 115 %s VERS_NODE
 116 %%
 117
 118   if (parser_input != input_selected)
 119     {
 120       /* The first token of the input determines the initial parser state.  */
 121       input_type t = parser_input;
 122       parser_input = input_selected;
 123       switch (t)
 124         {
 125         case input_script: return INPUT_SCRIPT; break;
 126         case input_mri_script: return INPUT_MRI_SCRIPT; break;
 127         case input_version_script: return INPUT_VERSION_SCRIPT; break;
 128         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
 129         case input_defsym: return INPUT_DEFSYM; break;
 130         default: abort ();
 131         }
 132     }
 133
 134 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>"/*" { comment (); }
 135
 136
 137 <DEFSYMEXP>"-"                  { RTOKEN('-');}
 138 <DEFSYMEXP>"+"                  { RTOKEN('+');}
 139 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
 140 <DEFSYMEXP>"="                  { RTOKEN('='); }
 141
 142 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
 143                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
 144                                 yylval.bigint.str = NULL;
 145                                 return INT;
 146                         }
 147
 148 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
 149                                    int ibase ;
 150                                    switch (yytext[yyleng - 1]) {
 151                                     case 'X':
 152                                     case 'x':
 153                                     case 'H':
 154                                     case 'h':
 155                                      ibase = 16;
 156                                      break;
 157                                     case 'O':
 158                                     case 'o':
 159                                      ibase = 8;
 160                                      break;
 161                                     case 'B':
 162                                     case 'b':
 163                                      ibase = 2;
 164                                      break;
 165                                     default:
 166                                      ibase = 10;
 167                                    }
 168                                    yylval.integer = bfd_scan_vma (yytext, 0,
 169                                                                   ibase);
 170                                    yylval.bigint.str = NULL;
 171                                    return INT;
 172                                  }
 173 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
 174                                   char *s = yytext;
 175                                   int ibase = 0;
 176
 177                                   if (*s == '$')
 178                                     {
 179                                       ++s;
 180                                       ibase = 16;
 181                                     }
 182                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
 183                                   yylval.bigint.str = NULL;
 184                                   if (yytext[yyleng - 1] == 'M'
 185                                       || yytext[yyleng - 1] == 'm')
 186                                     {
 187                                       yylval.integer *= 1024 * 1024;
 188                                     }
 189                                   else if (yytext[yyleng - 1] == 'K'
 190                                       || yytext[yyleng - 1]=='k')
 191                                     {
 192                                       yylval.integer *= 1024;
 193                                     }
 194                                   else if (yytext[0] == '0'
 195                                            && (yytext[1] == 'x'
 196                                                || yytext[1] == 'X'))
 197                                     {
 198                                       yylval.bigint.str = xstrdup (yytext + 2);
 199                                     }
 200                                   return INT;
 201                                 }
 202 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
 203 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
 204 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
 205 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
 206 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
 207 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
 208 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
 209 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
 210 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
 211 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
 212 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
 213 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
 214 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
 215 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
 216 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
 217 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
 218 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
 219 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
 220 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
 221 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>","               { RTOKEN(',');}
 222 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
 223 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
 224 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
 225 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
 226 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
 227 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
 228 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
 229 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
 230 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
 231 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
 232 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
 233 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
 234 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
 235 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
 236 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>")"               { RTOKEN(')');}
 237 <BOTH,SCRIPT,EXPRESSION,MRI,INPUTLIST>"("               { RTOKEN('(');}
 238 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
 239 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
 240 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
 241 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
 242 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
 243 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
 244 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
 245 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
 246 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
 247 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
 248 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
 249 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
 250 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
 251 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
 252 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
 253 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
 254 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
 255 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
 256 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
 257 <EXPRESSION,BOTH>"LOG2CEIL"             { RTOKEN(LOG2CEIL); }
 258 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
 259 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
 260 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
 261 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
 262 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
 263 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
 264 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
 265 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
 266 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
 267 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
 268 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
 269 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
 270 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
 271 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
 272 <EXPRESSION,BOTH,SCRIPT,INPUTLIST>"AS_NEEDED"   { RTOKEN(AS_NEEDED);}
 273 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
 274 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
 275 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
 276 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
 277 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
 278 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
 279 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
 280 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
 281 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
 282 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
 283 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
 284 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
 285 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
 286 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
 287 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
 288 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
 289 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
 290 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
 291 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
 292 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
 293 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
 294 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
 295 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
 296 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS_TO" { RTOKEN(NOCROSSREFS_TO);}
 297 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
 298 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
 299 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
 300 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
 301 <BOTH,SCRIPT>"SORT_BY_INIT_PRIORITY"    { RTOKEN(SORT_BY_INIT_PRIORITY); }
 302 <BOTH,SCRIPT>"SORT_NONE"                { RTOKEN(SORT_NONE); }
 303 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
 304 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
 305 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
 306 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
 307 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
 308 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
 309 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
 310 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
 311 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
 312 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
 313 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
 314 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
 315 <EXPRESSION,BOTH,SCRIPT>"INPUT_SECTION_FLAGS"   { RTOKEN(INPUT_SECTION_FLAGS); }
 316 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
 317 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
 318 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
 319 <EXPRESSION,BOTH,SCRIPT>"ALIGN_WITH_INPUT"      { RTOKEN(ALIGN_WITH_INPUT);}
 320 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
 321 <EXPRESSION,BOTH,SCRIPT>"HIDDEN"        { RTOKEN(HIDDEN); }
 322 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
 323 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
 324 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
 325 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
 326 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
 327 <MRI>"#".*\n?                   { ++ lineno; }
 328 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
 329 <MRI>"*".*                      { /* Mri comment line */ }
 330 <MRI>";".*                      { /* Mri comment line */ }
 331 <MRI>"END"                      { RTOKEN(ENDWORD); }
 332 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
 333 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
 334 <MRI>"CHIP"                     { RTOKEN(CHIP); }
 335 <MRI>"BASE"                     { RTOKEN(BASE); }
 336 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
 337 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
 338 <MRI>"LOAD"                     { RTOKEN(LOAD); }
 339 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
 340 <MRI>"ORDER"                    { RTOKEN(ORDER); }
 341 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
 342 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
 343 <MRI>"CASE"                     { RTOKEN(CASE); }
 344 <MRI>"START"                    { RTOKEN(START); }
 345 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 346 <MRI>"SECT"                     { RTOKEN(SECT); }
 347 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
 348 <MRI>"end"                      { RTOKEN(ENDWORD); }
 349 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
 350 <MRI>"align"                    { RTOKEN(ALIGN_K);}
 351 <MRI>"chip"                     { RTOKEN(CHIP); }
 352 <MRI>"base"                     { RTOKEN(BASE); }
 353 <MRI>"alias"                    { RTOKEN(ALIAS); }
 354 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
 355 <MRI>"load"                     { RTOKEN(LOAD); }
 356 <MRI>"public"                   { RTOKEN(PUBLIC); }
 357 <MRI>"order"                    { RTOKEN(ORDER); }
 358 <MRI>"name"                     { RTOKEN(NAMEWORD); }
 359 <MRI>"format"                   { RTOKEN(FORMAT); }
 360 <MRI>"case"                     { RTOKEN(CASE); }
 361 <MRI>"extern"                   { RTOKEN(EXTERN); }
 362 <MRI>"start"                    { RTOKEN(START); }
 363 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
 364 <MRI>"sect"                     { RTOKEN(SECT); }
 365 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
 366
 367 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
 368 /* Filename without commas, needed to parse mri stuff */
 369                                  yylval.name = xstrdup (yytext);
 370                                   return NAME;
 371                                 }
 372
 373
 374 <BOTH,INPUTLIST>{FILENAMECHAR1}{FILENAMECHAR}*  {
 375                                  yylval.name = xstrdup (yytext);
 376                                   return NAME;
 377                                 }
 378 <INPUTLIST>"="{FILENAMECHAR1}{FILENAMECHAR}*    {
 379 /* Filename to be prefixed by --sysroot or when non-sysrooted, nothing.  */
 380                                  yylval.name = xstrdup (yytext);
 381                                   return NAME;
 382                                 }
 383 <BOTH,INPUTLIST>"-l"{FILENAMECHAR}+ {
 384                                   yylval.name = xstrdup (yytext + 2);
 385                                   return LNAME;
 386                                 }
 387 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
 388                                  yylval.name = xstrdup (yytext);
 389                                   return NAME;
 390                                 }
 391 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
 392                                   yylval.name = xstrdup (yytext + 2);
 393                                   return LNAME;
 394                                 }
 395 <SCRIPT>{WILDCHAR}* {
 396                 /* Annoyingly, this pattern can match comments, and we have
 397                    longest match issues to consider.  So if the first two
 398                    characters are a comment opening, put the input back and
 399                    try again.  */
 400                 if (yytext[0] == '/' && yytext[1] == '*')
 401                   {
 402                     yyless (2);
 403                     comment ();
 404                   }
 405                 else
 406                   {
 407                     yylval.name = xstrdup (yytext);
 408                     return NAME;
 409                   }
 410         }
 411
 412 <EXPRESSION,BOTH,SCRIPT,VERS_NODE,INPUTLIST>"\""[^\"]*"\"" {
 413                                         /* No matter the state, quotes
 414                                            give what's inside.  */
 415                                         bfd_size_type len;
 416                                         yylval.name = xstrdup (yytext + 1);
 417                                         /* PR ld/20906.  A corrupt input file
 418                                            can contain bogus strings.  */
 419                                         len = strlen (yylval.name);
 420                                         if (len > yyleng - 2)
 421                                           len = yyleng - 2;
 422                                         yylval.name[len] = 0;
 423                                         return NAME;
 424                                 }
 425 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
 426 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
 427
 428 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
 429
 430 <VERS_NODE>global               { RTOKEN(GLOBAL); }
 431
 432 <VERS_NODE>local                { RTOKEN(LOCAL); }
 433
 434 <VERS_NODE>extern               { RTOKEN(EXTERN); }
 435
 436 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
 437                                   return VERS_IDENTIFIER; }
 438
 439 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
 440                                   return VERS_TAG; }
 441
 442 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
 443
 444 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
 445                                   vers_node_nesting = 0;
 446                                   return *yytext;
 447                                 }
 448 <VERS_SCRIPT>"}"                { return *yytext; }
 449 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
 450 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
 451                                     BEGIN(VERS_SCRIPT);
 452                                   return *yytext;
 453                                 }
 454
 455 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[\n]        { lineno++; }
 456
 457 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
 458
 459 <VERS_START,VERS_NODE,VERS_SCRIPT,INPUTLIST>[ \t\r]+    { /* Eat up whitespace */ }
 460
 461 <<EOF>> {
 462   include_stack_ptr--;
 463   if (include_stack_ptr == 0)
 464     {
 465       lineno = 0;
 466       yyterminate ();
 467     }
 468   else
 469     yy_switch_to_buffer (include_stack[include_stack_ptr]);
 470
 471   lineno = lineno_stack[include_stack_ptr];
 472   input_flags.sysrooted = sysrooted_stack[include_stack_ptr];
 473
 474   return END;
 475 }
 476
 477 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
 478 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
 479
 480 %%
 481 \f
 482
 483 /* Switch flex to reading script file NAME, open on FILE,
 484    saving the current input info on the include stack.  */
 485
 486 void
 487 lex_push_file (FILE *file, const char *name, unsigned int sysrooted)
 488 {
 489   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 490     {
 491       einfo ("%F:includes nested too deeply\n");
 492     }
 493   file_name_stack[include_stack_ptr] = name;
 494   lineno_stack[include_stack_ptr] = lineno;
 495   sysrooted_stack[include_stack_ptr] = input_flags.sysrooted;
 496   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 497
 498   include_stack_ptr++;
 499   lineno = 1;
 500   input_flags.sysrooted = sysrooted;
 501   yyin = file;
 502   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
 503 }
 504
 505 /* Return a newly created flex input buffer containing STRING,
 506    which is SIZE bytes long.  */
 507
 508 static YY_BUFFER_STATE
 509 yy_create_string_buffer (const char *string, size_t size)
 510 {
 511   YY_BUFFER_STATE b;
 512
 513   /* Calls to m-alloc get turned by sed into xm-alloc.  */
 514   b = malloc (sizeof (struct yy_buffer_state));
 515   b->yy_input_file = 0;
 516   b->yy_buf_size = size;
 517
 518   /* yy_ch_buf has to be 2 characters longer than the size given because
 519      we need to put in 2 end-of-buffer characters.  */
 520   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
 521
 522   b->yy_ch_buf[0] = '\n';
 523   strcpy (b->yy_ch_buf+1, string);
 524   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
 525   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
 526   b->yy_n_chars = size+1;
 527   b->yy_buf_pos = &b->yy_ch_buf[1];
 528
 529   b->yy_is_our_buffer = 1;
 530   b->yy_is_interactive = 0;
 531   b->yy_at_bol = 1;
 532   b->yy_fill_buffer = 0;
 533
 534   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
 535      a flex internal interface in the first place!  */
 536 #ifdef YY_BUFFER_NEW
 537   b->yy_buffer_status = YY_BUFFER_NEW;
 538 #else
 539   b->yy_eof_status = EOF_NOT_SEEN;
 540 #endif
 541
 542   return b;
 543 }
 544
 545 /* Switch flex to reading from STRING, saving the current input info
 546    on the include stack.  */
 547
 548 void
 549 lex_redirect (const char *string, const char *fake_filename, unsigned int count)
 550 {
 551   YY_BUFFER_STATE tmp;
 552
 553   yy_init = 0;
 554   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
 555     {
 556       einfo("%F: macros nested too deeply\n");
 557     }
 558   file_name_stack[include_stack_ptr] = fake_filename;
 559   lineno_stack[include_stack_ptr] = lineno;
 560   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
 561   include_stack_ptr++;
 562   lineno = count;
 563   tmp = yy_create_string_buffer (string, strlen (string));
 564   yy_switch_to_buffer (tmp);
 565 }
 566 \f
 567 /* Functions to switch to a different flex start condition,
 568    saving the current start condition on `state_stack'.  */
 569
 570 static int state_stack[MAX_INCLUDE_DEPTH * 2];
 571 static int *state_stack_p = state_stack;
 572
 573 void
 574 ldlex_script (void)
 575 {
 576   *(state_stack_p)++ = yy_start;
 577   BEGIN (SCRIPT);
 578 }
 579
 580 void
 581 ldlex_inputlist (void)
 582 {
 583   *(state_stack_p)++ = yy_start;
 584   BEGIN (INPUTLIST);
 585 }
 586
 587 void
 588 ldlex_mri_script (void)
 589 {
 590   *(state_stack_p)++ = yy_start;
 591   BEGIN (MRI);
 592 }
 593
 594 void
 595 ldlex_version_script (void)
 596 {
 597   *(state_stack_p)++ = yy_start;
 598   BEGIN (VERS_START);
 599 }
 600
 601 void
 602 ldlex_version_file (void)
 603 {
 604   *(state_stack_p)++ = yy_start;
 605   BEGIN (VERS_SCRIPT);
 606 }
 607
 608 void
 609 ldlex_defsym (void)
 610 {
 611   *(state_stack_p)++ = yy_start;
 612   BEGIN (DEFSYMEXP);
 613 }
 614
 615 void
 616 ldlex_expression (void)
 617 {
 618   *(state_stack_p)++ = yy_start;
 619   BEGIN (EXPRESSION);
 620 }
 621
 622 void
 623 ldlex_both (void)
 624 {
 625   *(state_stack_p)++ = yy_start;
 626   BEGIN (BOTH);
 627 }
 628
 629 void
 630 ldlex_popstate (void)
 631 {
 632   yy_start = *(--state_stack_p);
 633 }
 634
 635 /* Return the current file name, or the previous file if no file is
 636    current.  */
 637
 638 const char*
 639 ldlex_filename (void)
 640 {
 641   return file_name_stack[include_stack_ptr - (include_stack_ptr != 0)];
 642 }
 643 \f
 644
 645 /* Place up to MAX_SIZE characters in BUF and return
 646    either the number of characters read, or 0 to indicate EOF.  */
 647
 648 static int
 649 yy_input (char *buf, int max_size)
 650 {
 651   int result = 0;
 652   if (YY_CURRENT_BUFFER->yy_input_file)
 653     {
 654       if (yyin)
 655         {
 656           result = fread (buf, 1, max_size, yyin);
 657           if (result < max_size && ferror (yyin))
 658             einfo ("%F%P: read in flex scanner failed\n");
 659         }
 660     }
 661   return result;
 662 }
 663
 664 /* Eat the rest of a C-style comment.  */
 665
 666 static void
 667 comment (void)
 668 {
 669   int c;
 670
 671   while (1)
 672   {
 673     c = input();
 674     while (c != '*' && c != EOF)
 675     {
 676       if (c == '\n')
 677         lineno++;
 678       c = input();
 679     }
 680
 681     if (c == '*')
 682     {
 683       c = input();
 684       while (c == '*')
 685        c = input();
 686       if (c == '/')
 687        break;                   /* found the end */
 688     }
 689
 690     if (c == '\n')
 691       lineno++;
 692
 693     if (c == EOF)
 694     {
 695       einfo( "%F%P: EOF in comment\n");
 696       break;
 697     }
 698   }
 699 }
 700
 701 /* Warn the user about a garbage character WHAT in the input
 702    in context WHERE.  */
 703
 704 static void
 705 lex_warn_invalid (char *where, char *what)
 706 {
 707   char buf[5];
 708
 709   /* If we have found an input file whose format we do not recognize,
 710      and we are therefore treating it as a linker script, and we find
 711      an invalid character, then most likely this is a real object file
 712      of some different format.  Treat it as such.  */
 713   if (ldfile_assumed_script)
 714     {
 715       bfd_set_error (bfd_error_file_not_recognized);
 716       einfo ("%F%s: file not recognized: %E\n", ldlex_filename ());
 717     }
 718
 719   if (! ISPRINT (*what))
 720     {
 721       sprintf (buf, "\\%03o", *(unsigned char *) what);
 722       what = buf;
 723     }
 724
 725   einfo ("%P:%S: ignoring invalid character `%s'%s\n", NULL, what, where);
 726 }