libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([xmalloc.c])
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  We don't use libtool yet, but some day we might, so...
  11 ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 dnl We use these options to decide which functions to include.
  14 AC_ARG_WITH(target-subdir,
  15 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  16 AC_ARG_WITH(build-subdir,
  17 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  18 AC_ARG_WITH(cross-host,
  19 [  --with-cross-host=HOST           Configuring with a cross compiler])
  20 AC_ARG_WITH(newlib,
  21 [  --with-newlib                    Configuring with newlib])
  22
  23 if test "${srcdir}" = "."; then
  24   if test -n "${with_build_subdir}"; then
  25     libiberty_topdir="${srcdir}/../.."
  26     with_target_subdir=
  27   elif test -z "${with_target_subdir}"; then
  28     libiberty_topdir="${srcdir}/.."
  29   else
  30     if test "${with_target_subdir}" != "."; then
  31       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  32     else
  33       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  34     fi
  35   fi
  36 else
  37   libiberty_topdir="${srcdir}/.."
  38 fi
  39 AC_SUBST(libiberty_topdir)
  40 AC_CONFIG_AUX_DIR($libiberty_topdir)
  41
  42 dnl Very limited version of automake's enable-maintainer-mode
  43
  44 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  45   dnl maintainer-mode is disabled by default
  46   AC_ARG_ENABLE(maintainer-mode,
  47 [  --enable-maintainer-mode
  48                           enable make rules and dependencies not useful
  49                           (and sometimes confusing) to the casual installer],
  50       maintainer_mode=$enableval,
  51       maintainer_mode=no)
  52
  53 AC_MSG_RESULT($maintainer_mode)
  54
  55 if test "$maintainer_mode" = "yes"; then
  56   MAINT=''
  57   NOTMAINT='#'
  58 else
  59   MAINT='#'
  60   NOTMAINT=''
  61 fi
  62 AC_SUBST(MAINT)dnl
  63 AC_SUBST(NOTMAINT)dnl
  64
  65 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  66 # rely on it - libiberty is built before texinfo.
  67 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  68 if test "x$MAKEINFO" = "x"; then
  69     MAKEINFO="@echo makeinfo missing; true"
  70     BUILD_INFO=
  71 else
  72     BUILD_INFO=info
  73     case "$MAKEINFO" in
  74       */missing\ makeinfo*)
  75         BUILD_INFO=
  76         AC_MSG_WARN([
  77 *** Makeinfo is missing. Info documentation will not be built.])
  78         ;;
  79       *)
  80         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  81           x*\ [[1-3]].* )
  82             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  83             BUILD_INFO=
  84             AC_MSG_WARN([
  85 *** Makeinfo is too old. Info documentation will not be built.])
  86           ;;
  87         esac
  88         ;;
  89     esac
  90 fi
  91 AC_SUBST(MAKEINFO)
  92 AC_SUBST(BUILD_INFO)
  93
  94 AC_CHECK_PROG(PERL, perl, perl, )
  95 if test x"$PERL" = x""; then
  96   HAVE_PERL='#'
  97 else
  98   HAVE_PERL=''
  99 fi
 100 AC_SUBST(HAVE_PERL)
 101
 102 AC_CANONICAL_HOST
 103
 104 dnl When we start using automake:
 105 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 106
 107 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 108 dnl to call AC_CHECK_PROG.
 109 AC_CHECK_TOOL(AR, ar)
 110 AC_CHECK_TOOL(RANLIB, ranlib, :)
 111
 112 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 113 # Add --enable-multilib to configure.
 114 # Default to --enable-multilib
 115 AC_ARG_ENABLE(multilib,
 116 [  --enable-multilib       build many library versions (default)],
 117 [case "$enableval" in
 118   yes) multilib=yes ;;
 119   no)  multilib=no ;;
 120   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 121  esac],
 122               [multilib=yes])
 123
 124 # Even if the default multilib is not a cross compilation,
 125 # it may be that some of the other multilibs are.
 126 if test $cross_compiling = no && test $multilib = yes \
 127    && test "x${with_multisubdir}" != x ; then
 128    cross_compiling=maybe
 129 fi
 130
 131 GCC_NO_EXECUTABLES
 132 AC_PROG_CC
 133 AC_SYS_LARGEFILE
 134 AC_PROG_CPP_WERROR
 135
 136 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 137                           -Wstrict-prototypes], [ac_libiberty_warn_cflags])
 138 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 139
 140 AC_PROG_CC_C_O
 141 # autoconf is lame and doesn't give us any substitution variable for this.
 142 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 143   NO_MINUS_C_MINUS_O=yes
 144 else
 145   OUTPUT_OPTION='-o $@'
 146 fi
 147 AC_SUBST(NO_MINUS_C_MINUS_O)
 148 AC_SUBST(OUTPUT_OPTION)
 149
 150 AC_C_CONST
 151 AC_C_INLINE
 152 AC_C_BIGENDIAN
 153
 154 dnl When we start using libtool:
 155 dnl Default to a non shared library.  This may be overridden by the
 156 dnl configure option --enable-shared.
 157 dnl AM_DISABLE_SHARED
 158
 159 dnl When we start using libtool:
 160 dnl AM_PROG_LIBTOOL
 161
 162 dnl When we start using automake:
 163 dnl AM_CONFIG_HEADER(config.h:config.in)
 164 AC_CONFIG_HEADER(config.h:config.in)
 165
 166 dnl When we start using automake:
 167 dnl AM_MAINTAINER_MODE
 168 dnl AC_EXEEXT
 169
 170 dnl When we start using automake:
 171 dnl AM_PROG_INSTALL
 172 AC_PROG_INSTALL
 173
 174 # Don't build the shared library for build.
 175 if [[ -n "${with_build_subdir}" ]]; then
 176   enable_shared=no
 177 fi
 178
 179 frag=
 180 case "${host}" in
 181   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 182                         frag=mh-aix ;;
 183   *-*-cxux7*)           frag=mh-cxux7 ;;
 184   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 185   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 186   i370-*-opened*)       frag=mh-openedition ;;
 187   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 188 esac
 189
 190 if [[ -n "${frag}" ]]; then
 191   frag=${libiberty_topdir}/libiberty/config/$frag
 192 fi
 193
 194 # If they didn't specify --enable-shared, don't generate shared libs.
 195 case "${enable_shared}" in
 196   yes) shared=yes ;;
 197   no) shared=no ;;
 198   "") shared=no ;;
 199   *) shared=yes ;;
 200 esac
 201 if [[ "${shared}" = "yes" ]]; then
 202   case "${host}" in
 203     *-*-cygwin*)        ;;
 204     alpha*-*-linux*)    PICFLAG=-fPIC ;;
 205     arm*-*-*)           PICFLAG=-fPIC ;;
 206     hppa*-*-*)          PICFLAG=-fPIC ;;
 207     i370-*-*)           PICFLAG=-fPIC ;;
 208     ia64-*-*)           PICFLAG=-fpic ;;
 209     i[[34567]]86-*-* | x86_64-*-*)
 210                         PICFLAG=-fpic ;;
 211     m68k-*-*)           PICFLAG=-fpic ;;
 212     mips*-*-linux*)     PICFLAG=-fPIC ;;
 213     powerpc*-*-aix*)    ;;
 214     powerpc*-*-*)       PICFLAG=-fPIC ;;
 215     sparc*-*-*)         case "${CFLAGS}" in
 216                           *-fpic* ) PICFLAG=-fpic ;;
 217                           * ) PICFLAG=-fPIC ;;
 218                         esac ;;
 219     s390*-*-*)          PICFLAG=-fpic ;;
 220     sh*-*-*)            PICFLAG=-fPIC ;;
 221   esac
 222 fi
 223 AC_SUBST(PICFLAG)
 224
 225 echo "# Warning: this fragment is automatically generated" > temp-frag
 226
 227 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 228   echo "Appending ${frag} to xhost-mkfrag"
 229   echo "# Following fragment copied from ${frag}" >> temp-frag
 230   cat ${frag} >> temp-frag
 231 fi
 232
 233 # record if we want to build shared libs.
 234 if [[ "${shared}" = "yes" ]]; then
 235   echo enable_shared = yes >> temp-frag
 236 else
 237   echo enable_shared = no >> temp-frag
 238 fi
 239
 240 frag=xhost-mkfrag
 241 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 242
 243 host_makefile_frag=${frag}
 244 AC_SUBST_FILE(host_makefile_frag)
 245
 246 # It's OK to check for header files.  Although the compiler may not be
 247 # able to link anything, it had better be able to at least compile
 248 # something.
 249 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h)
 250 AC_HEADER_SYS_WAIT
 251 AC_HEADER_TIME
 252
 253 libiberty_AC_DECLARE_ERRNO
 254
 255 # Determine the size of an int for struct fibnode.
 256 AC_CHECK_SIZEOF([int])
 257
 258 # Look for a 64-bit type.
 259 AC_MSG_CHECKING([for a 64-bit type])
 260 AC_CACHE_VAL(liberty_cv_uint64,
 261 [AC_TRY_COMPILE(
 262 [#ifdef HAVE_STDINT_H
 263 #include <stdint.h>
 264 #endif],
 265 [extern uint64_t foo;],
 266 liberty_cv_uint64=uint64_t,
 267 [AC_TRY_COMPILE(
 268 [#ifdef HAVE_LIMITS_H
 269 #include <limits.h>
 270 #endif
 271 #ifndef CHAR_BIT
 272 #define CHAR_BIT 8
 273 #endif],
 274 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 275 liberty_cv_uint64="unsigned long",
 276 [AC_TRY_COMPILE(
 277 [#ifdef HAVE_LIMITS_H
 278 #include <limits.h>
 279 #endif
 280 #ifndef CHAR_BIT
 281 #define CHAR_BIT 8
 282 #endif],
 283 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 284 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 285 AC_MSG_RESULT($liberty_cv_uint64)
 286 if test "$liberty_cv_uint64" != none; then
 287   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 288                      [Define to an unsigned 64-bit type available in the compiler.])
 289 fi
 290
 291 AC_TYPE_INTPTR_T
 292 AC_TYPE_UINTPTR_T
 293 AC_TYPE_SSIZE_T
 294
 295 # Given the above check, we always have uintptr_t or a fallback
 296 # definition.  So define HAVE_UINTPTR_T in case any imported code
 297 # relies on it.
 298 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 299
 300 AC_TYPE_PID_T
 301
 302 # This is the list of functions which libiberty will provide if they
 303 # are not available on the host.
 304
 305 funcs="asprintf"
 306 funcs="$funcs atexit"
 307 funcs="$funcs basename"
 308 funcs="$funcs bcmp"
 309 funcs="$funcs bcopy"
 310 funcs="$funcs bsearch"
 311 funcs="$funcs bzero"
 312 funcs="$funcs calloc"
 313 funcs="$funcs clock"
 314 funcs="$funcs ffs"
 315 funcs="$funcs getcwd"
 316 funcs="$funcs getpagesize"
 317 funcs="$funcs gettimeofday"
 318 funcs="$funcs index"
 319 funcs="$funcs insque"
 320 funcs="$funcs memchr"
 321 funcs="$funcs memcmp"
 322 funcs="$funcs memcpy"
 323 funcs="$funcs memmem"
 324 funcs="$funcs memmove"
 325 funcs="$funcs mempcpy"
 326 funcs="$funcs memset"
 327 funcs="$funcs mkstemps"
 328 funcs="$funcs putenv"
 329 funcs="$funcs random"
 330 funcs="$funcs rename"
 331 funcs="$funcs rindex"
 332 funcs="$funcs setenv"
 333 funcs="$funcs snprintf"
 334 funcs="$funcs sigsetmask"
 335 funcs="$funcs stpcpy"
 336 funcs="$funcs stpncpy"
 337 funcs="$funcs strcasecmp"
 338 funcs="$funcs strchr"
 339 funcs="$funcs strdup"
 340 funcs="$funcs strncasecmp"
 341 funcs="$funcs strndup"
 342 funcs="$funcs strrchr"
 343 funcs="$funcs strstr"
 344 funcs="$funcs strtod"
 345 funcs="$funcs strtol"
 346 funcs="$funcs strtoul"
 347 funcs="$funcs strverscmp"
 348 funcs="$funcs tmpnam"
 349 funcs="$funcs vasprintf"
 350 funcs="$funcs vfprintf"
 351 funcs="$funcs vprintf"
 352 funcs="$funcs vsnprintf"
 353 funcs="$funcs vsprintf"
 354 funcs="$funcs waitpid"
 355 funcs="$funcs setproctitle"
 356
 357 # Also in the old function.def file: alloca, vfork, getopt.
 358
 359 vars="sys_errlist sys_nerr sys_siglist"
 360
 361 checkfuncs="getrusage on_exit psignal strerror strsignal sysconf times sbrk gettimeofday"
 362 checkfuncs="$checkfuncs realpath canonicalize_file_name pstat_getstatic pstat_getdynamic sysmp"
 363 checkfuncs="$checkfuncs getsysinfo table sysctl wait3 wait4 __fsetlocking"
 364
 365 # These are neither executed nor required, but they help keep
 366 # autoheader happy without adding a bunch of text to acconfig.h.
 367 if test "x" = "y"; then
 368   AC_CHECK_FUNCS(asprintf atexit \
 369     basename bcmp bcopy bsearch bzero \
 370     calloc canonicalize_file_name clock \
 371     ffs __fsetlocking \
 372     getcwd getpagesize getrusage getsysinfo gettimeofday \
 373     index insque \
 374     memchr memcmp memcpy memmem memmove memset mkstemps \
 375     on_exit \
 376     psignal pstat_getdynamic pstat_getstatic putenv \
 377     random realpath rename rindex \
 378     sbrk setenv setproctitle sigsetmask snprintf stpcpy stpncpy strcasecmp strchr \
 379     strdup \
 380      strerror strncasecmp strndup strrchr strsignal strstr strtod strtol \
 381      strtoul strverscmp sysconf sysctl sysmp \
 382     table times tmpnam \
 383     vasprintf vfprintf vprintf vsprintf \
 384     wait3 wait4 waitpid)
 385   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 386   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 387   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 388   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 389 fi
 390
 391 # For each of these functions, if the host does not provide the
 392 # function we want to put FN.o in LIBOBJS, and if the host does
 393 # provide the function, we want to define HAVE_FN in config.h.
 394
 395 setobjs=
 396 CHECK=
 397 target_header_dir=
 398 if test -n "${with_target_subdir}"; then
 399
 400   # We are being configured as a target library.  AC_REPLACE_FUNCS
 401   # may not work correctly, because the compiler may not be able to
 402   # link executables.  Note that we may still be being configured
 403   # native.
 404
 405   # If we are being configured for newlib, we know which functions
 406   # newlib provide and which ones we will be expected to provide.
 407
 408   if test "x${with_newlib}" = "xyes"; then
 409     AC_LIBOBJ([asprintf])
 410     AC_LIBOBJ([basename])
 411     AC_LIBOBJ([insque])
 412     AC_LIBOBJ([random])
 413     AC_LIBOBJ([strdup])
 414     AC_LIBOBJ([vasprintf])
 415
 416     for f in $funcs; do
 417       case "$f" in
 418         asprintf | basename | insque | random | strdup | vasprintf)
 419           ;;
 420         *)
 421           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 422           AC_DEFINE_UNQUOTED($n)
 423           ;;
 424       esac
 425     done
 426
 427     # newlib doesnt provide any of the variables in $vars, so we
 428     # dont have to check them here.
 429
 430     # Of the functions in $checkfuncs, newlib only has strerror.
 431     AC_DEFINE(HAVE_STRERROR)
 432
 433     setobjs=yes
 434
 435   fi
 436
 437   # If we are being configured for Mingw, we know which functions
 438   # Mingw provides and which ones we will be expected to provide.
 439
 440   case "${host}" in
 441   *-*-mingw*)
 442     AC_LIBOBJ([asprintf])
 443     AC_LIBOBJ([basename])
 444     AC_LIBOBJ([bcmp])
 445     AC_LIBOBJ([bcopy])
 446     AC_LIBOBJ([bzero])
 447     AC_LIBOBJ([clock])
 448     AC_LIBOBJ([ffs])
 449     AC_LIBOBJ([getpagesize])
 450     AC_LIBOBJ([index])
 451     AC_LIBOBJ([insque])
 452     AC_LIBOBJ([mempcpy])
 453     AC_LIBOBJ([mkstemps])
 454     AC_LIBOBJ([random])
 455     AC_LIBOBJ([rindex])
 456     AC_LIBOBJ([sigsetmask])
 457     AC_LIBOBJ([stpcpy])
 458     AC_LIBOBJ([stpncpy])
 459     AC_LIBOBJ([strndup])
 460     AC_LIBOBJ([strverscmp])
 461     AC_LIBOBJ([vasprintf])
 462     AC_LIBOBJ([waitpid])
 463
 464     for f in $funcs; do
 465       case "$f" in
 466         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strverscmp | vasprintf | waitpid)
 467           ;;
 468         *)
 469           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 470           AC_DEFINE_UNQUOTED($n)
 471           ;;
 472       esac
 473     done
 474
 475     # Mingw doesnt provide any of the variables in $vars, so we
 476     # dont have to check them here.
 477
 478     # Of the functions in $checkfuncs, Mingw only has strerror.
 479     AC_DEFINE(HAVE_STRERROR)
 480
 481     setobjs=yes
 482     ;;
 483
 484   *-*-msdosdjgpp)
 485     AC_LIBOBJ([vasprintf])
 486     AC_LIBOBJ([vsnprintf])
 487     AC_LIBOBJ([snprintf])
 488     AC_LIBOBJ([asprintf])
 489
 490     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 491              getcwd getpagesize getrusage gettimeofday \
 492              index insque memchr memcmp memcpy memmove memset psignal \
 493              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 494              strchr strdup strerror strncasecmp strrchr strstr strtod \
 495              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 496              vsprintf waitpid
 497     do
 498       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 499       AC_DEFINE_UNQUOTED($n)
 500     done
 501
 502
 503     setobjs=yes
 504     ;;
 505
 506   esac
 507
 508   # We may wish to install the target headers somewhere.
 509   AC_ARG_ENABLE(install-libiberty,
 510   [  --enable-install-libiberty       Install headers for end users],
 511   enable_install_libiberty=$enableval,
 512   enable_install_libiberty=no)dnl
 513
 514   # Option parsed, now set things appropriately.
 515   case x"$enable_install_libiberty" in
 516     xyes|x)
 517       target_header_dir=libiberty
 518       ;;
 519     xno)
 520       target_header_dir=
 521       ;;
 522     *)
 523       # This could be sanity-checked in various ways...
 524       target_header_dir="${enable_install_libiberty}"
 525       ;;
 526   esac
 527
 528
 529 else
 530
 531    # Not a target library, so we set things up to run the test suite.
 532    CHECK=really-check
 533
 534 fi
 535
 536 AC_SUBST(CHECK)
 537 AC_SUBST(target_header_dir)
 538
 539 # check for prctl PR_SET_NAME
 540 AC_LINK_IFELSE([AC_LANG_SOURCE([[
 541 #include <sys/prctl.h>
 542 int main()
 543 {
 544   return (prctl(PR_SET_NAME, "foo") == 0) ? 0 : 1;
 545 }
 546 ]])], AC_DEFINE(HAVE_PRCTL_SET_NAME, 1,
 547         [Define if you have prctl PR_SET_NAME]))
 548
 549 case "${host}" in
 550   *-*-cygwin* | *-*-mingw*)
 551     AC_DEFINE(HAVE_SYS_ERRLIST)
 552     AC_DEFINE(HAVE_SYS_NERR)
 553     ;;
 554 esac
 555
 556 if test -z "${setobjs}"; then
 557   case "${host}" in
 558
 559   *-*-vxworks*)
 560     # Handle VxWorks configuration specially, since on VxWorks the
 561     # libraries are actually on the target board, not in the file
 562     # system.
 563     AC_LIBOBJ([basename])
 564     AC_LIBOBJ([getpagesize])
 565     AC_LIBOBJ([insque])
 566     AC_LIBOBJ([random])
 567     AC_LIBOBJ([strcasecmp])
 568     AC_LIBOBJ([strncasecmp])
 569     AC_LIBOBJ([strdup])
 570     AC_LIBOBJ([vfork])
 571     AC_LIBOBJ([waitpid])
 572     AC_LIBOBJ([vasprintf])
 573     for f in $funcs; do
 574       case "$f" in
 575         basename | getpagesize | insque | random | strcasecmp)
 576           ;;
 577         strncasecmp | strdup | vfork | waitpid | vasprintf)
 578           ;;
 579         *)
 580           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 581           AC_DEFINE_UNQUOTED($n)
 582           ;;
 583       esac
 584     done
 585
 586     # VxWorks doesn't provide any of the variables in $vars, so we
 587     # don't have to check them here.
 588
 589     # Of the functions in $checkfuncs, VxWorks only has strerror.
 590     AC_DEFINE(HAVE_STRERROR)
 591
 592     setobjs=yes
 593     ;;
 594
 595   esac
 596 fi
 597
 598 if test -z "${setobjs}"; then
 599
 600   case "${host}" in
 601
 602   *-*-mingw32*)
 603     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 604     # macros, so the test below won't find them.
 605     libiberty_cv_var_sys_nerr=yes
 606     libiberty_cv_var_sys_errlist=yes
 607     ;;
 608
 609   *-*-msdosdjgpp*)
 610     # vfork and fork are stubs.
 611     ac_cv_func_vfork_works=no
 612     ;;
 613
 614   *-*-uwin*)
 615     # Under some versions of uwin, vfork is notoriously buggy and the test
 616     # can hang configure; on other versions, vfork exists just as a stub.
 617     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 618     ac_cv_func_vfork_works=no
 619     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 620     # macros (actually, these are imported from a DLL, but the end effect
 621     # is the same), so the test below won't find them.
 622     libiberty_cv_var_sys_nerr=yes
 623     libiberty_cv_var_sys_errlist=yes
 624     ;;
 625
 626   *-*-*vms*)
 627     # Under VMS, vfork works very different than on Unix. The standard test
 628     # won't work, and it isn't easily adaptable. It makes more sense to
 629     # just force it.
 630     ac_cv_func_vfork_works=yes
 631     ;;
 632
 633   esac
 634
 635   # We haven't set the list of objects yet.  Use the standard autoconf
 636   # tests.  This will only work if the compiler works.
 637   AC_ISC_POSIX
 638   AC_REPLACE_FUNCS($funcs)
 639   libiberty_AC_FUNC_C_ALLOCA
 640   AC_FUNC_FORK
 641   if test $ac_cv_func_vfork_works = no; then
 642     AC_LIBOBJ([vfork])
 643   fi
 644   # We only need _doprnt if we might use it to implement v*printf.
 645   if test $ac_cv_func_vprintf != yes \
 646      || test $ac_cv_func_vfprintf != yes \
 647      || test $ac_cv_func_vsprintf != yes; then
 648     AC_REPLACE_FUNCS(_doprnt)
 649   else
 650     AC_CHECK_FUNCS(_doprnt)
 651   fi
 652
 653   for v in $vars; do
 654     AC_MSG_CHECKING([for $v])
 655     AC_CACHE_VAL(libiberty_cv_var_$v,
 656       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[int *p;]],[[extern int $v []; p = $v;]])],
 657                       [eval "libiberty_cv_var_$v=yes"],
 658                       [eval "libiberty_cv_var_$v=no"])])
 659     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 660       AC_MSG_RESULT(yes)
 661       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 662       AC_DEFINE_UNQUOTED($n)
 663     else
 664       AC_MSG_RESULT(no)
 665     fi
 666   done
 667
 668   # special check for _system_configuration because AIX <4.3.2 do not
 669   # contain the `physmem' member.
 670   AC_MSG_CHECKING([for external symbol _system_configuration])
 671   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 672                         [[double x = _system_configuration.physmem;]])],
 673     [AC_MSG_RESULT([yes])
 674     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 675               [Define if you have the _system_configuration variable.])],
 676     [AC_MSG_RESULT([no])])
 677
 678   AC_CHECK_FUNCS($checkfuncs)
 679   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 680   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc, sbrk])
 681   AC_CHECK_DECLS([strverscmp])
 682   libiberty_NEED_DECLARATION(canonicalize_file_name)
 683 fi
 684
 685 # Figure out which version of pexecute to use.
 686 case "${host}" in
 687      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 688      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 689      *-*-msdos*)                pexecute=pex-msdos  ;;
 690      *)                         pexecute=pex-unix   ;;
 691 esac
 692 AC_SUBST(pexecute)
 693
 694 libiberty_AC_FUNC_STRNCMP
 695
 696 # Install a library built with a cross compiler in $(tooldir) rather
 697 # than $(libdir).
 698 if test -z "${with_cross_host}"; then
 699   INSTALL_DEST=libdir
 700 else
 701   INSTALL_DEST=tooldir
 702 fi
 703 AC_SUBST(INSTALL_DEST)
 704
 705 m4_pattern_allow(LIBOBJS)
 706 L=""
 707 for l in x $LIBOBJS; do
 708   case $l in
 709     x) ;;
 710     *) L="$L ./$l" ;;
 711   esac
 712 done
 713 LIBOBJS="$L"
 714
 715 dnl Required by html and install-html
 716 AC_SUBST(datarootdir)
 717 AC_SUBST(docdir)
 718 AC_SUBST(htmldir)
 719
 720 # We need multilib support, but only if configuring for the target.
 721 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 722 AC_CONFIG_COMMANDS([default],
 723   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 724 if test -n "$CONFIG_FILES"; then
 725   if test -n "${with_target_subdir}"; then
 726     # FIXME: We shouldn't need to set ac_file
 727     ac_file=Makefile
 728     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 729     . ${libiberty_topdir}/config-ml.in
 730   fi
 731 fi]],
 732 [[srcdir=${srcdir}
 733 host=${host}
 734 target=${target}
 735 with_target_subdir=${with_target_subdir}
 736 with_multisubdir=${with_multisubdir}
 737 ac_configure_args="--enable-multilib ${ac_configure_args}"
 738 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 739 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 740 libiberty_topdir=${libiberty_topdir}
 741 ]])
 742 AC_OUTPUT