libiberty/configure.ac

   1 dnl Process this file with autoconf to produce a configure script
   2
   3 AC_INIT
   4 AC_CONFIG_SRCDIR([xmalloc.c])
   5
   6 # This works around the fact that libtool configuration may change LD
   7 # for this particular configuration, but some shells, instead of
   8 # keeping the changes in LD private, export them just because LD is
   9 # exported.  We don't use libtool yet, but some day we might, so...
  10 ORIGINAL_LD_FOR_MULTILIBS=$LD
  11
  12 dnl We use these options to decide which functions to include.
  13 AC_ARG_WITH(target-subdir,
  14 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  15 AC_ARG_WITH(build-subdir,
  16 [  --with-build-subdir=SUBDIR       Configuring in a subdirectory for build])
  17 AC_ARG_WITH(cross-host,
  18 [  --with-cross-host=HOST           Configuring with a cross compiler])
  19 AC_ARG_WITH(newlib,
  20 [  --with-newlib                    Configuring with newlib])
  21
  22 if test "${srcdir}" = "."; then
  23   if test -n "${with_build_subdir}"; then
  24     libiberty_topdir="${srcdir}/../.."
  25     with_target_subdir=
  26   elif test -z "${with_target_subdir}"; then
  27     libiberty_topdir="${srcdir}/.."
  28   else
  29     if test "${with_target_subdir}" != "."; then
  30       libiberty_topdir="${srcdir}/${with_multisrctop}../.."
  31     else
  32       libiberty_topdir="${srcdir}/${with_multisrctop}.."
  33     fi
  34   fi
  35 else
  36   libiberty_topdir="${srcdir}/.."
  37 fi
  38 AC_SUBST(libiberty_topdir)
  39 AC_CONFIG_AUX_DIR($libiberty_topdir)
  40
  41 dnl Very limited version of automake's enable-maintainer-mode
  42
  43 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  44   dnl maintainer-mode is disabled by default
  45   AC_ARG_ENABLE(maintainer-mode,
  46 [  --enable-maintainer-mode
  47                           enable make rules and dependencies not useful
  48                           (and sometimes confusing) to the casual installer],
  49       maintainer_mode=$enableval,
  50       maintainer_mode=no)
  51
  52 AC_MSG_RESULT($maintainer_mode)
  53
  54 if test "$maintainer_mode" = "yes"; then
  55   MAINT=''
  56   NOTMAINT='#'
  57 else
  58   MAINT='#'
  59   NOTMAINT=''
  60 fi
  61 AC_SUBST(MAINT)dnl
  62 AC_SUBST(NOTMAINT)dnl
  63
  64 if test -z "$ETAGS"; then
  65   ETAGS=etags
  66 fi
  67 AC_SUBST([ETAGS])
  68
  69 # Do we have a single-tree copy of texinfo?  Even if we do, we can't
  70 # rely on it - libiberty is built before texinfo.
  71 AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, )
  72 if test "x$MAKEINFO" = "x"; then
  73     MAKEINFO="@echo makeinfo missing; true"
  74     BUILD_INFO=
  75 else
  76     BUILD_INFO=info
  77     case "$MAKEINFO" in
  78       */missing\ makeinfo*)
  79         BUILD_INFO=
  80         AC_MSG_WARN([
  81 *** Makeinfo is missing. Info documentation will not be built.])
  82         ;;
  83       *)
  84         case x"`$MAKEINFO --version | grep 'GNU texinfo'`" in
  85           x*\ [[1-3]].* )
  86             MAKEINFO="@echo $MAKEINFO is too old, 4.0 or newer required; true"
  87             BUILD_INFO=
  88             AC_MSG_WARN([
  89 *** Makeinfo is too old. Info documentation will not be built.])
  90           ;;
  91         esac
  92         ;;
  93     esac
  94 fi
  95 AC_SUBST(MAKEINFO)
  96 AC_SUBST(BUILD_INFO)
  97
  98 AC_CHECK_PROG(PERL, perl, perl, )
  99 if test x"$PERL" = x""; then
 100   HAVE_PERL='#'
 101 else
 102   HAVE_PERL=''
 103 fi
 104 AC_SUBST(HAVE_PERL)
 105
 106 AC_CANONICAL_HOST
 107
 108 dnl When we start using automake:
 109 dnl AM_INIT_AUTOMAKE(libiberty, 1.0)
 110
 111 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 112 dnl to call AC_CHECK_PROG.
 113 AC_CHECK_TOOL(AR, ar)
 114 AC_CHECK_TOOL(RANLIB, ranlib, :)
 115
 116 dnl When switching to automake, replace the following with AM_ENABLE_MULTILIB.
 117 # Add --enable-multilib to configure.
 118 # Default to --enable-multilib
 119 AC_ARG_ENABLE(multilib,
 120 [  --enable-multilib       build many library versions (default)],
 121 [case "$enableval" in
 122   yes) multilib=yes ;;
 123   no)  multilib=no ;;
 124   *)   AC_MSG_ERROR([bad value $enableval for multilib option]) ;;
 125  esac],
 126               [multilib=yes])
 127
 128 # Even if the default multilib is not a cross compilation,
 129 # it may be that some of the other multilibs are.
 130 if test $cross_compiling = no && test $multilib = yes \
 131    && test "x${with_multisubdir}" != x ; then
 132    cross_compiling=maybe
 133 fi
 134
 135 # We may wish to install the target headers somewhere.
 136 AC_MSG_CHECKING([whether to install libiberty headers and static library])
 137 dnl install-libiberty is disabled by default
 138
 139 AC_ARG_ENABLE(install-libiberty,
 140 [  --enable-install-libiberty       Install headers and library for end users],
 141 enable_install_libiberty=$enableval,
 142 enable_install_libiberty=no)dnl
 143
 144 # Option parsed, now set things appropriately.
 145 case x"$enable_install_libiberty" in
 146   xyes|x)
 147     target_header_dir=libiberty
 148     ;;
 149   xno)
 150     target_header_dir=
 151     ;;
 152   *)
 153     # This could be sanity-checked in various ways...
 154     target_header_dir="${enable_install_libiberty}"
 155     ;;
 156 esac
 157 AC_MSG_RESULT($enable_install_libiberty)
 158 AC_MSG_NOTICE([target_header_dir = $target_header_dir])
 159
 160 GCC_NO_EXECUTABLES
 161 AC_PROG_CC
 162 AC_GNU_SOURCE
 163 AC_SYS_LARGEFILE
 164 AC_PROG_CPP_WERROR
 165
 166 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wc++-compat \
 167                           -Wstrict-prototypes \
 168                           -Wshadow=local], [ac_libiberty_warn_cflags])
 169 ACX_PROG_CC_WARNING_ALMOST_PEDANTIC([], [ac_libiberty_warn_cflags])
 170
 171 AC_PROG_CC_C_O
 172 # autoconf is lame and doesn't give us any substitution variable for this.
 173 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 174   NO_MINUS_C_MINUS_O=yes
 175 else
 176   OUTPUT_OPTION='-o $@'
 177 fi
 178 AC_SUBST(NO_MINUS_C_MINUS_O)
 179 AC_SUBST(OUTPUT_OPTION)
 180
 181 AC_C_CONST
 182 AC_C_INLINE
 183 AC_C_BIGENDIAN
 184
 185 dnl When we start using libtool:
 186 dnl Default to a non shared library.  This may be overridden by the
 187 dnl configure option --enable-shared.
 188 dnl AM_DISABLE_SHARED
 189
 190 dnl When we start using libtool:
 191 dnl AM_PROG_LIBTOOL
 192
 193 dnl When we start using automake:
 194 dnl AM_CONFIG_HEADER(config.h:config.in)
 195 AC_CONFIG_HEADER(config.h:config.in)
 196
 197 dnl When we start using automake:
 198 dnl AM_MAINTAINER_MODE
 199 dnl AC_EXEEXT
 200
 201 dnl When we start using automake:
 202 dnl AM_PROG_INSTALL
 203 AC_PROG_INSTALL
 204
 205 # Don't build the shared library for build.
 206 if [[ -n "${with_build_subdir}" ]]; then
 207   enable_shared=no
 208 fi
 209
 210 frag=
 211 case "${host}" in
 212   rs6000-ibm-aix3.1 | rs6000-ibm-aix)
 213                         frag=mh-aix ;;
 214   *-*-cxux7*)           frag=mh-cxux7 ;;
 215   *-*-freebsd2.1.*)     frag=mh-fbsd21 ;;
 216   *-*-freebsd2.2.[[012]])       frag=mh-fbsd21 ;;
 217   i370-*-opened*)       frag=mh-openedition ;;
 218   i[[34567]]86-*-windows*)      frag=mh-windows ;;
 219 esac
 220
 221 if [[ -n "${frag}" ]]; then
 222   frag=${libiberty_topdir}/libiberty/config/$frag
 223 fi
 224
 225 GCC_PICFLAG
 226
 227 # If they didn't specify --enable-shared, don't generate shared libs.
 228 case "${enable_shared}" in
 229   yes) shared=yes ;;
 230   no) shared=no ;;
 231   "") shared=no ;;
 232   *) shared=yes ;;
 233 esac
 234
 235 # ...unless --enable-host-shared was passed from top-level config:
 236 if [[ "${enable_host_shared}" = "yes" ]]; then
 237   shared=yes
 238 fi
 239
 240 if [[ "${shared}" != "yes" ]]; then
 241   PICFLAG=
 242 fi
 243 AC_SUBST(PICFLAG)
 244
 245 NOASANFLAG=
 246 case " ${CFLAGS} " in
 247   *\ -fsanitize=address\ *) NOASANFLAG=-fno-sanitize=address ;;
 248   *\ -fsanitize=hwaddress\ *) NOASANFLAG=-fno-sanitize=hwaddress ;;
 249 esac
 250 AC_SUBST(NOASANFLAG)
 251
 252 GCC_CET_HOST_FLAGS(CET_HOST_FLAGS)
 253 AC_SUBST(CET_HOST_FLAGS)
 254
 255 echo "# Warning: this fragment is automatically generated" > temp-frag
 256
 257 if [[ -n "${frag}" ]] && [[ -f "${frag}" ]]; then
 258   echo "Appending ${frag} to xhost-mkfrag"
 259   echo "# Following fragment copied from ${frag}" >> temp-frag
 260   cat ${frag} >> temp-frag
 261 fi
 262
 263 # record if we want to build shared libs.
 264 if [[ "${shared}" = "yes" ]]; then
 265   echo enable_shared = yes >> temp-frag
 266 else
 267   echo enable_shared = no >> temp-frag
 268 fi
 269
 270 frag=xhost-mkfrag
 271 ${CONFIG_SHELL-/bin/sh} ${libiberty_topdir}/move-if-change temp-frag xhost-mkfrag
 272
 273 host_makefile_frag=${frag}
 274 AC_SUBST_FILE(host_makefile_frag)
 275
 276 # It's OK to check for header files.  Although the compiler may not be
 277 # able to link anything, it had better be able to at least compile
 278 # something.
 279 AC_CHECK_HEADERS(sys/file.h sys/param.h limits.h stdlib.h malloc.h string.h unistd.h strings.h sys/time.h time.h sys/resource.h sys/stat.h sys/mman.h fcntl.h alloca.h sys/pstat.h sys/sysmp.h sys/sysinfo.h machine/hal_sysinfo.h sys/table.h sys/sysctl.h sys/systemcfg.h stdint.h stdio_ext.h process.h sys/prctl.h)
 280 AC_HEADER_SYS_WAIT
 281 AC_HEADER_TIME
 282
 283 libiberty_AC_DECLARE_ERRNO
 284
 285 # Determine sizes of some types.
 286 AC_CHECK_SIZEOF([int])
 287 AC_CHECK_SIZEOF([long])
 288 AC_CHECK_SIZEOF([size_t])
 289
 290 # Check for presense of long long
 291 AC_CHECK_TYPE([long long],
 292   [AC_DEFINE(HAVE_LONG_LONG, 1, [Define if you have the `long long' type.]) AC_CHECK_SIZEOF([long long])],
 293   [])
 294
 295 # Look for a 64-bit type.
 296 AC_MSG_CHECKING([for a 64-bit type])
 297 AC_CACHE_VAL(liberty_cv_uint64,
 298 [AC_TRY_COMPILE(
 299 [#ifdef HAVE_STDINT_H
 300 #include <stdint.h>
 301 #endif],
 302 [extern uint64_t foo;],
 303 liberty_cv_uint64=uint64_t,
 304 [AC_TRY_COMPILE(
 305 [#ifdef HAVE_LIMITS_H
 306 #include <limits.h>
 307 #endif
 308 #ifndef CHAR_BIT
 309 #define CHAR_BIT 8
 310 #endif],
 311 [extern char foo[sizeof(long) * CHAR_BIT >= 64 ? 1 : -1];],
 312 liberty_cv_uint64="unsigned long",
 313 [AC_TRY_COMPILE(
 314 [#ifdef HAVE_LIMITS_H
 315 #include <limits.h>
 316 #endif
 317 #ifndef CHAR_BIT
 318 #define CHAR_BIT 8
 319 #endif],
 320 [extern char foo[sizeof(long long) * CHAR_BIT >= 64 ? 1 : -1];],
 321 liberty_cv_uint64="unsigned long long", liberty_cv_uint64=none)])])])
 322 AC_MSG_RESULT($liberty_cv_uint64)
 323 if test "$liberty_cv_uint64" != none; then
 324   AC_DEFINE_UNQUOTED(UNSIGNED_64BIT_TYPE, $liberty_cv_uint64,
 325                      [Define to an unsigned 64-bit type available in the compiler.])
 326 fi
 327
 328 AC_TYPE_INTPTR_T
 329 AC_TYPE_UINTPTR_T
 330 AC_TYPE_SSIZE_T
 331
 332 # Given the above check, we always have uintptr_t or a fallback
 333 # definition.  So define HAVE_UINTPTR_T in case any imported code
 334 # relies on it.
 335 AC_DEFINE(HAVE_UINTPTR_T, 1, [Define if you have the \`uintptr_t' type.])
 336
 337 AC_TYPE_PID_T
 338
 339 # This is the list of functions which libiberty will provide if they
 340 # are not available on the host.
 341
 342 funcs="asprintf"
 343 funcs="$funcs atexit"
 344 funcs="$funcs basename"
 345 funcs="$funcs bcmp"
 346 funcs="$funcs bcopy"
 347 funcs="$funcs bsearch"
 348 funcs="$funcs bzero"
 349 funcs="$funcs calloc"
 350 funcs="$funcs clock"
 351 funcs="$funcs ffs"
 352 funcs="$funcs getcwd"
 353 funcs="$funcs getpagesize"
 354 funcs="$funcs gettimeofday"
 355 funcs="$funcs index"
 356 funcs="$funcs insque"
 357 funcs="$funcs memchr"
 358 funcs="$funcs memcmp"
 359 funcs="$funcs memcpy"
 360 funcs="$funcs memmem"
 361 funcs="$funcs memmove"
 362 funcs="$funcs mempcpy"
 363 funcs="$funcs memset"
 364 funcs="$funcs mkstemps"
 365 funcs="$funcs putenv"
 366 funcs="$funcs random"
 367 funcs="$funcs rename"
 368 funcs="$funcs rindex"
 369 funcs="$funcs setenv"
 370 funcs="$funcs snprintf"
 371 funcs="$funcs sigsetmask"
 372 funcs="$funcs stpcpy"
 373 funcs="$funcs stpncpy"
 374 funcs="$funcs strcasecmp"
 375 funcs="$funcs strchr"
 376 funcs="$funcs strdup"
 377 funcs="$funcs strncasecmp"
 378 funcs="$funcs strndup"
 379 funcs="$funcs strnlen"
 380 funcs="$funcs strrchr"
 381 funcs="$funcs strstr"
 382 funcs="$funcs strtod"
 383 funcs="$funcs strtol"
 384 funcs="$funcs strtoul"
 385 funcs="$funcs strtoll"
 386 funcs="$funcs strtoull"
 387 funcs="$funcs strverscmp"
 388 funcs="$funcs tmpnam"
 389 funcs="$funcs vasprintf"
 390 funcs="$funcs vfprintf"
 391 funcs="$funcs vprintf"
 392 funcs="$funcs vsnprintf"
 393 funcs="$funcs vsprintf"
 394 funcs="$funcs waitpid"
 395 funcs="$funcs setproctitle"
 396
 397 # Also in the old function.def file: alloca, vfork, getopt.
 398
 399 vars="sys_errlist sys_nerr sys_siglist"
 400
 401 checkfuncs="__fsetlocking canonicalize_file_name dup3 getrlimit getrusage \
 402  getsysinfo gettimeofday on_exit pipe2 psignal pstat_getdynamic pstat_getstatic \
 403  realpath setrlimit spawnve spawnvpe strerror strsignal sysconf sysctl \
 404  sysmp table times wait3 wait4"
 405
 406 # Darwin has sbrk, but it is deprecated and that produces build-time warnings
 407 # so do not check for it.
 408 case "${host}" in
 409   *-*-darwin*) ;;
 410   *) checkfuncs="$checkfuncs sbrk"
 411 esac
 412
 413 # These are neither executed nor required, but they help keep
 414 # autoheader happy without adding a bunch of text to acconfig.h.
 415 if test "x" = "y"; then
 416   AC_CHECK_FUNCS(asprintf atexit \
 417     basename bcmp bcopy bsearch bzero \
 418     calloc canonicalize_file_name clock \
 419     dup3 \
 420     ffs __fsetlocking \
 421     getcwd getpagesize getrlimit getrusage getsysinfo gettimeofday \
 422     index insque \
 423     memchr memcmp memcpy memmem memmove memset mkstemps \
 424     on_exit \
 425     pipe2 psignal pstat_getdynamic pstat_getstatic putenv \
 426     random realpath rename rindex \
 427     sbrk setenv setproctitle setrlimit sigsetmask snprintf spawnve spawnvpe \
 428      stpcpy stpncpy strcasecmp strchr strdup \
 429      strerror strncasecmp strndup strnlen strrchr strsignal strstr strtod \
 430      strtol strtoul strtoll strtoull strverscmp sysconf sysctl sysmp \
 431     table times tmpnam \
 432     vasprintf vfprintf vprintf vsprintf \
 433     wait3 wait4 waitpid)
 434   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf, strtol, strtoul, strtoll, strtoull, strnlen])
 435   AC_DEFINE(HAVE_SYS_ERRLIST, 1, [Define if you have the sys_errlist variable.])
 436   AC_DEFINE(HAVE_SYS_NERR,    1, [Define if you have the sys_nerr variable.])
 437   AC_DEFINE(HAVE_SYS_SIGLIST, 1, [Define if you have the sys_siglist variable.])
 438 fi
 439
 440 # For each of these functions, if the host does not provide the
 441 # function we want to put FN.o in LIBOBJS, and if the host does
 442 # provide the function, we want to define HAVE_FN in config.h.
 443
 444 setobjs=
 445 CHECK=
 446 if test -n "${with_target_subdir}"; then
 447
 448   # We are being configured as a target library.  AC_REPLACE_FUNCS
 449   # may not work correctly, because the compiler may not be able to
 450   # link executables.  Note that we may still be being configured
 451   # native.
 452
 453   # If we are being configured for newlib, we know which functions
 454   # newlib provide and which ones we will be expected to provide.
 455
 456   if test "x${with_newlib}" = "xyes"; then
 457     AC_LIBOBJ([asprintf])
 458     AC_LIBOBJ([basename])
 459     AC_LIBOBJ([insque])
 460     AC_LIBOBJ([random])
 461     AC_LIBOBJ([strdup])
 462     AC_LIBOBJ([vasprintf])
 463
 464     for f in $funcs; do
 465       case "$f" in
 466         asprintf | basename | insque | random | strdup | vasprintf)
 467           ;;
 468         *)
 469           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 470           AC_DEFINE_UNQUOTED($n)
 471           ;;
 472       esac
 473     done
 474
 475     # newlib doesnt provide any of the variables in $vars, so we
 476     # dont have to check them here.
 477
 478     # Of the functions in $checkfuncs, newlib only has strerror.
 479     AC_DEFINE(HAVE_STRERROR)
 480
 481     setobjs=yes
 482
 483   fi
 484
 485   # If we are being configured for Mingw, we know which functions
 486   # Mingw provides and which ones we will be expected to provide.
 487
 488   case "${host}" in
 489   *-*-mingw*)
 490     AC_LIBOBJ([asprintf])
 491     AC_LIBOBJ([basename])
 492     AC_LIBOBJ([bcmp])
 493     AC_LIBOBJ([bcopy])
 494     AC_LIBOBJ([bzero])
 495     AC_LIBOBJ([clock])
 496     AC_LIBOBJ([ffs])
 497     AC_LIBOBJ([getpagesize])
 498     AC_LIBOBJ([index])
 499     AC_LIBOBJ([insque])
 500     AC_LIBOBJ([mempcpy])
 501     AC_LIBOBJ([mkstemps])
 502     AC_LIBOBJ([random])
 503     AC_LIBOBJ([rindex])
 504     AC_LIBOBJ([sigsetmask])
 505     AC_LIBOBJ([stpcpy])
 506     AC_LIBOBJ([stpncpy])
 507     AC_LIBOBJ([strndup])
 508     AC_LIBOBJ([strnlen])
 509     AC_LIBOBJ([strverscmp])
 510     AC_LIBOBJ([vasprintf])
 511     AC_LIBOBJ([waitpid])
 512
 513     for f in $funcs; do
 514       case "$f" in
 515         asprintf | basename | bcmp | bcopy | bzero | clock | ffs | getpagesize | index | insque | mempcpy | mkstemps | random | rindex | sigsetmask | stpcpy | stpncpy | strdup | strndup | strnlen | strverscmp | vasprintf | waitpid)
 516           ;;
 517         *)
 518           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 519           AC_DEFINE_UNQUOTED($n)
 520           ;;
 521       esac
 522     done
 523
 524     # Mingw doesnt provide any of the variables in $vars, so we
 525     # dont have to check them here.
 526
 527     # Of the functions in $checkfuncs, Mingw only has strerror.
 528     AC_DEFINE(HAVE_STRERROR)
 529
 530     setobjs=yes
 531     ;;
 532
 533   *-*-msdosdjgpp)
 534     AC_LIBOBJ([vasprintf])
 535     AC_LIBOBJ([vsnprintf])
 536     AC_LIBOBJ([snprintf])
 537     AC_LIBOBJ([asprintf])
 538
 539     for f in atexit basename bcmp bcopy bsearch bzero calloc clock ffs \
 540              getcwd getpagesize getrusage gettimeofday \
 541              index insque memchr memcmp memcpy memmove memset psignal \
 542              putenv random rename rindex sbrk setenv stpcpy strcasecmp \
 543              strchr strdup strerror strncasecmp strrchr strstr strtod \
 544              strtol strtoul sysconf times tmpnam vfprintf vprintf \
 545              vsprintf waitpid
 546     do
 547       n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 548       AC_DEFINE_UNQUOTED($n)
 549     done
 550
 551
 552     setobjs=yes
 553     ;;
 554
 555   esac
 556
 557 else
 558
 559    # Not a target library, so we set things up to run the test suite.
 560    CHECK=really-check
 561
 562 fi
 563
 564 AC_SUBST(CHECK)
 565 AC_SUBST(target_header_dir)
 566
 567 case "${host}" in
 568   *-*-cygwin* | *-*-mingw*)
 569     AC_DEFINE(HAVE_SYS_ERRLIST)
 570     AC_DEFINE(HAVE_SYS_NERR)
 571     ;;
 572 esac
 573
 574 if test -z "${setobjs}"; then
 575   case "${host}" in
 576
 577   *-*-vxworks*)
 578     # Handle VxWorks configuration specially, since on VxWorks the
 579     # libraries are actually on the target board, not in the file
 580     # system.
 581     AC_LIBOBJ([basename])
 582     AC_LIBOBJ([getpagesize])
 583     AC_LIBOBJ([insque])
 584     AC_LIBOBJ([random])
 585     AC_LIBOBJ([strcasecmp])
 586     AC_LIBOBJ([strncasecmp])
 587     AC_LIBOBJ([strdup])
 588     AC_LIBOBJ([vfork])
 589     AC_LIBOBJ([waitpid])
 590     AC_LIBOBJ([vasprintf])
 591     for f in $funcs; do
 592       case "$f" in
 593         basename | getpagesize | insque | random | strcasecmp)
 594           ;;
 595         strncasecmp | strdup | vfork | waitpid | vasprintf)
 596           ;;
 597         *)
 598           n=HAVE_`echo $f | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 599           AC_DEFINE_UNQUOTED($n)
 600           ;;
 601       esac
 602     done
 603
 604     # VxWorks doesn't provide any of the variables in $vars, so we
 605     # don't have to check them here.
 606
 607     # Of the functions in $checkfuncs, VxWorks only has strerror.
 608     AC_DEFINE(HAVE_STRERROR)
 609
 610     setobjs=yes
 611     ;;
 612
 613   esac
 614 fi
 615
 616 if test -z "${setobjs}"; then
 617
 618   case "${host}" in
 619
 620   *-*-android*)
 621     # On android, getpagesize is defined in unistd.h as a static inline
 622     # function, which AC_CHECK_FUNCS does not handle properly.
 623     ac_cv_func_getpagesize=yes
 624     ;;
 625
 626   hppa*-*-hpux*)
 627     # Replace system snprintf and vsnprintf with libiberty implementations.
 628     AC_LIBOBJ([snprintf])
 629     AC_LIBOBJ([vsnprintf])
 630     ;;
 631
 632   *-*-mingw32*)
 633     # Under mingw32, sys_nerr and sys_errlist exist, but they are
 634     # macros, so the test below won't find them.
 635     libiberty_cv_var_sys_nerr=yes
 636     libiberty_cv_var_sys_errlist=yes
 637     ;;
 638
 639   *-*-msdosdjgpp*)
 640     # vfork and fork are stubs.
 641     ac_cv_func_vfork_works=no
 642     ;;
 643
 644   *-*-uwin*)
 645     # Under some versions of uwin, vfork is notoriously buggy and the test
 646     # can hang configure; on other versions, vfork exists just as a stub.
 647     # FIXME: This should be removed once vfork in uwin's runtime is fixed.
 648     ac_cv_func_vfork_works=no
 649     # Under uwin 2.0+, sys_nerr and sys_errlist exist, but they are
 650     # macros (actually, these are imported from a DLL, but the end effect
 651     # is the same), so the test below won't find them.
 652     libiberty_cv_var_sys_nerr=yes
 653     libiberty_cv_var_sys_errlist=yes
 654     ;;
 655
 656   *-*-*vms*)
 657     # Under VMS, vfork works very different than on Unix. The standard test
 658     # won't work, and it isn't easily adaptable. It makes more sense to
 659     # just force it.
 660     ac_cv_func_vfork_works=yes
 661     ;;
 662
 663   esac
 664
 665   # We haven't set the list of objects yet.  Use the standard autoconf
 666   # tests.  This will only work if the compiler works.
 667   AC_ISC_POSIX
 668   AC_REPLACE_FUNCS($funcs)
 669   libiberty_AC_FUNC_C_ALLOCA
 670   AC_FUNC_FORK
 671   if test $ac_cv_func_vfork_works = no; then
 672     AC_LIBOBJ([vfork])
 673   fi
 674   # We only need _doprnt if we might use it to implement v*printf.
 675   if test $ac_cv_func_vprintf != yes \
 676      || test $ac_cv_func_vfprintf != yes \
 677      || test $ac_cv_func_vsprintf != yes; then
 678     AC_REPLACE_FUNCS(_doprnt)
 679   else
 680     AC_CHECK_FUNCS(_doprnt)
 681   fi
 682
 683   for v in $vars; do
 684     AC_MSG_CHECKING([for $v])
 685     AC_CACHE_VAL(libiberty_cv_var_$v,
 686       [AC_LINK_IFELSE([AC_LANG_PROGRAM([[extern int $v [];]],[[if ($v [0]) return 1;]])],
 687                       [eval "libiberty_cv_var_$v=yes"],
 688                       [eval "libiberty_cv_var_$v=no"])])
 689     if eval "test \"`echo '$libiberty_cv_var_'$v`\" = yes"; then
 690       AC_MSG_RESULT(yes)
 691       n=HAVE_`echo $v | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 692       AC_DEFINE_UNQUOTED($n)
 693     else
 694       AC_MSG_RESULT(no)
 695     fi
 696   done
 697
 698   # special check for _system_configuration because AIX <4.3.2 do not
 699   # contain the `physmem' member.
 700   AC_MSG_CHECKING([for external symbol _system_configuration])
 701   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/systemcfg.h>]],
 702                         [[double x = _system_configuration.physmem;]])],
 703     [AC_MSG_RESULT([yes])
 704     AC_DEFINE(HAVE__SYSTEM_CONFIGURATION, 1,
 705               [Define if you have the _system_configuration variable.])],
 706     [AC_MSG_RESULT([no])])
 707
 708   AC_CHECK_FUNCS($checkfuncs)
 709   AC_CHECK_DECLS([basename(char *), ffs, asprintf, vasprintf, snprintf, vsnprintf])
 710   AC_CHECK_DECLS([calloc, getenv, getopt, malloc, realloc])
 711   case "${host}" in
 712       *-*-darwin*) ;; # Darwin's sbrk implementation is deprecated.
 713       *) AC_CHECK_DECLS([sbrk]);;
 714   esac
 715   AC_CHECK_DECLS([strtol, strtoul, strtoll, strtoull])
 716   AC_CHECK_DECLS([strverscmp])
 717   AC_CHECK_DECLS([strnlen])
 718   libiberty_NEED_DECLARATION(canonicalize_file_name)
 719 fi
 720
 721 # Figure out which version of pexecute to use.
 722 case "${host}" in
 723      *-*-mingw* | *-*-winnt*)   pexecute=pex-win32  ;;
 724      *-*-msdosdjgpp*)           pexecute=pex-djgpp  ;;
 725      *-*-msdos*)                pexecute=pex-msdos  ;;
 726      *)                         pexecute=pex-unix   ;;
 727 esac
 728 AC_SUBST(pexecute)
 729
 730 libiberty_AC_FUNC_STRNCMP
 731
 732 # Install a library built with a cross compiler in $(tooldir) rather
 733 # than $(libdir).
 734 if test -z "${with_cross_host}"; then
 735   INSTALL_DEST=libdir
 736 else
 737   INSTALL_DEST=tooldir
 738 fi
 739 AC_SUBST(INSTALL_DEST)
 740
 741 m4_pattern_allow(LIBOBJS)
 742 L=""
 743 for l in x $LIBOBJS; do
 744   case $l in
 745     x) ;;
 746     *) L="$L ./$l" ;;
 747   esac
 748 done
 749 LIBOBJS="$L"
 750
 751 dnl Required by html and install-html
 752 AC_SUBST(datarootdir)
 753 AC_SUBST(docdir)
 754 AC_SUBST(htmldir)
 755
 756 # We need multilib support, but only if configuring for the target.
 757 AC_CONFIG_FILES([Makefile testsuite/Makefile])
 758 AC_CONFIG_COMMANDS([default],
 759   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 760 if test -n "$CONFIG_FILES"; then
 761   if test -n "${with_target_subdir}"; then
 762     # FIXME: We shouldn't need to set ac_file
 763     ac_file=Makefile
 764     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 765     . ${libiberty_topdir}/config-ml.in
 766   fi
 767 fi]],
 768 [[srcdir=${srcdir}
 769 host=${host}
 770 target=${target}
 771 with_target_subdir=${with_target_subdir}
 772 with_multisubdir=${with_multisubdir}
 773 ac_configure_args="--enable-multilib ${ac_configure_args}"
 774 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 775 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 776 libiberty_topdir=${libiberty_topdir}
 777 ]])
 778 AC_OUTPUT