meta/recipes-kernel/lttng/lttng-modules_2.13.1.bb

   1 SECTION = "devel"
   2 SUMMARY = "Linux Trace Toolkit KERNEL MODULE"
   3 DESCRIPTION = "The lttng-modules 2.0 package contains the kernel tracer modules"
   4 HOMEPAGE = "https://lttng.org/"
   5 LICENSE = "LGPL-2.1-only & GPL-2.0-only & MIT"
   6 LIC_FILES_CHKSUM = "file://LICENSE;md5=0464cff101a009c403cd2ed65d01d4c4"
   7
   8 inherit module
   9
  10 include lttng-platforms.inc
  11
  12 SRC_URI = "https://lttng.org/files/${BPN}/${BPN}-${PV}.tar.bz2 \
  13            file://0001-fix-block-remove-GENHD_FL_SUPPRESS_PARTITION_INFO-v5.patch \
  14            file://0002-fix-block-remove-the-rq_disk-field-in-struct-request.patch \
  15            file://0003-fix-mm-compaction-fix-the-migration-stats-in-trace_m.patch \
  16            file://0004-fix-btrfs-pass-fs_info-to-trace_btrfs_transaction_co.patch \
  17            file://0005-fix-random-rather-than-entropy_store-abstraction-use.patch \
  18            file://0006-fix-net-skb-introduce-kfree_skb_reason-v5.17.patch \
  19            file://0007-fix-net-socket-rename-SKB_DROP_REASON_SOCKET_FILTER-.patch \
  20           "
  21 # Use :append here so that the patch is applied also when using devupstream
  22 SRC_URI:append = " file://0001-src-Kbuild-change-missing-CONFIG_TRACEPOINTS-to-warn.patch"
  23
  24 SRC_URI[sha256sum] = "a7c86d91c9bbe66d27f025aa04b8cfc6d7785ed2fc7ef774930800ee44d7f343"
  25
  26 export INSTALL_MOD_DIR="kernel/lttng-modules"
  27
  28 EXTRA_OEMAKE += "KERNELDIR='${STAGING_KERNEL_DIR}'"
  29
  30 MODULES_MODULE_SYMVERS_LOCATION = "src"
  31
  32 do_install:append() {
  33         # Delete empty directories to avoid QA failures if no modules were built
  34         if [ -d ${D}/${nonarch_base_libdir} ]; then
  35                 find ${D}/${nonarch_base_libdir} -depth -type d -empty -exec rmdir {} \;
  36         fi
  37 }
  38
  39 python do_package:prepend() {
  40     if not os.path.exists(os.path.join(d.getVar('D'), d.getVar('nonarch_base_libdir')[1:], 'modules')):
  41         bb.warn("%s: no modules were created; this may be due to CONFIG_TRACEPOINTS not being enabled in your kernel." % d.getVar('PN'))
  42 }
  43
  44 BBCLASSEXTEND = "devupstream:target"
  45 LIC_FILES_CHKSUM:class-devupstream = "file://LICENSE;md5=0464cff101a009c403cd2ed65d01d4c4"
  46 DEFAULT_PREFERENCE:class-devupstream = "-1"
  47 SRC_URI:class-devupstream = "git://git.lttng.org/lttng-modules;branch=stable-2.13"
  48
  49 SRCREV:class-devupstream = "7584cfc04914cb0842a986e9808686858b9c8630"
  50 PV:class-devupstream = "2.13.1+git${SRCPV}"
  51 S:class-devupstream = "${WORKDIR}/git"
  52 SRCREV_FORMAT ?= "lttng_git"