nand_spl/board/sheldon/simpc8313/u-boot.lds

   1 /*
   2  * (C) Copyright 2006
   3  * Wolfgang Denk, DENX Software Engineering, wd@denx.de.
   4  *
   5  * Copyright 2008 Freescale Semiconductor, Inc.
   6  *
   7  * SPDX-License-Identifier:     GPL-2.0+
   8  */
   9
  10 OUTPUT_ARCH(powerpc)
  11 SECTIONS
  12 {
  13         . = 0xfff00000;
  14         .text : {
  15                 *(.text*)
  16                 . = ALIGN(16);
  17                 *(.eh_frame)
  18                 *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*)))
  19         }
  20
  21         . = ALIGN(8);
  22         .data : {
  23                 *(.data*)
  24                 *(.sdata*)
  25                 _GOT2_TABLE_ = .;
  26                 *(.got2)
  27                 KEEP(*(.got))
  28                 PROVIDE(_GLOBAL_OFFSET_TABLE_ = . + 4);
  29         }
  30         __got2_entries = ((_GLOBAL_OFFSET_TABLE_ - _GOT2_TABLE_) >> 2) - 1;
  31
  32         . = ALIGN(8);
  33         __bss_start = .;
  34         .bss (NOLOAD) : { *(.*bss) }
  35         __bss_end = .;
  36 }
  37 ENTRY(_start)
  38 ASSERT(__bss_end <= 0xfff01000, "NAND bootstrap too big");