sim/mips/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.59)dnl
   3 AC_INIT(Makefile.in)
   4 AC_CONFIG_HEADER(config.h:config.in)
   5
   6 sinclude(../common/aclocal.m4)
   7
   8 # Bugs in autoconf 2.59 break the call to SIM_AC_COMMON, hack around
   9 # it by inlining the macro's contents.
  10 sinclude(../common/common.m4)
  11
  12 dnl Options available in this module
  13 SIM_AC_OPTION_INLINE()
  14 SIM_AC_OPTION_ALIGNMENT(NONSTRICT_ALIGNMENT)
  15 SIM_AC_OPTION_HOSTENDIAN
  16 SIM_AC_OPTION_WARNINGS
  17 SIM_AC_OPTION_RESERVED_BITS(1)
  18
  19 # DEPRECATED
  20 #
  21 # Instead of defining a `subtarget' macro, code should be checking
  22 # the value of {STATE,CPU}_ARCHITECTURE to identify the architecture
  23 # in question.
  24 #
  25 case "${target}" in
  26   mips64vr*-*-*)        SIM_SUBTARGET="-DTARGET_ENABLE_FR=1" ;;
  27   mips*tx39*)           SIM_SUBTARGET="-DSUBTARGET_R3900=1";;
  28   mips*-sde-elf*)       SIM_SUBTARGET="-DTARGET_ENABLE_FR=1";;
  29   mipsisa32*-*-*)       SIM_SUBTARGET="-DTARGET_ENABLE_FR=1";;
  30   mipsisa64*-*-*)       SIM_SUBTARGET="-DTARGET_ENABLE_FR=1";;
  31   *)                    SIM_SUBTARGET="";;
  32 esac
  33 AC_SUBST(SIM_SUBTARGET)
  34
  35
  36
  37 #
  38 # Select the byte order of the target
  39 #
  40 mips_endian=
  41 default_endian=
  42 case "${target}" in
  43   mips64el*-*-*)        mips_endian=LITTLE_ENDIAN ;;
  44   mips64vr*el-*-*)      default_endian=LITTLE_ENDIAN ;;
  45   mips64*-*-*)          default_endian=BIG_ENDIAN ;;
  46   mips16*-*-*)          default_endian=BIG_ENDIAN ;;
  47   mipsisa32*-*-*)       default_endian=BIG_ENDIAN ;;
  48   mipsisa64*-*-*)       default_endian=BIG_ENDIAN ;;
  49   mips*-*-*)            default_endian=BIG_ENDIAN ;;
  50   *)                    default_endian=BIG_ENDIAN ;;
  51 esac
  52 SIM_AC_OPTION_ENDIAN($mips_endian,$default_endian)
  53
  54
  55
  56 #
  57 # Select the bitsize of the target
  58 #
  59 mips_addr_bitsize=
  60 case "${target}" in
  61   mips64*-*-*)          mips_bitsize=64 ; mips_msb=63 ;;
  62   mips16*-*-*)          mips_bitsize=64 ; mips_msb=63 ;;
  63   mips*-sde-elf*)       mips_bitsize=64 ; mips_msb=63 ;;
  64   mipsisa32*-*-*)       mips_bitsize=32 ; mips_msb=31 ;;
  65   mipsisa64*-*-*)       mips_bitsize=64 ; mips_msb=63 ;;
  66   mips*-*-*)            mips_bitsize=32 ; mips_msb=31 ;;
  67   *)                    mips_bitsize=64 ; mips_msb=63 ;;
  68 esac
  69 SIM_AC_OPTION_BITSIZE($mips_bitsize,$mips_msb,$mips_addr_bitsize)
  70
  71
  72
  73 #
  74 # Select the floating hardware support of the target
  75 #
  76 mips_fpu=HARDWARE_FLOATING_POINT
  77 mips_fpu_bitsize=
  78 case "${target}" in
  79   mips*tx39*)           mips_fpu=HARD_FLOATING_POINT
  80                         mips_fpu_bitsize=32
  81                         ;;
  82   mips64*-*-*)          mips_fpu=HARD_FLOATING_POINT ;;
  83   mips16*-*-*)          mips_fpu=HARD_FLOATING_POINT ;;
  84   mips*-sde-elf*)       mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=64 ;;
  85   mipsisa32*-*-*)       mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=64 ;;
  86   mipsisa64*-*-*)       mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=64 ;;
  87   mips*-*-*)            mips_fpu=HARD_FLOATING_POINT ; mips_fpu_bitsize=32 ;;
  88   *)                    mips_fpu=HARD_FLOATING_POINT ;;
  89 esac
  90 SIM_AC_OPTION_FLOAT($mips_fpu,$mips_fpu_bitsize)
  91
  92
  93
  94 #
  95 # Select the level of SMP support
  96 #
  97 case "${target}" in
  98   *)                    mips_smp=0 ;;
  99 esac
 100 SIM_AC_OPTION_SMP($mips_smp)
 101
 102
 103
 104 #
 105 # Select the IGEN architecture
 106 #
 107 sim_gen=IGEN
 108 sim_igen_machine="-M mipsIV"
 109 sim_m16_machine="-M mips16,mipsIII"
 110 sim_igen_filter="32,64,f"
 111 sim_m16_filter="16"
 112 sim_mach_default="mips8000"
 113
 114 case "${target}" in
 115   mips*tx39*)           sim_gen=IGEN
 116                         sim_igen_filter="32,f"
 117                         sim_igen_machine="-M r3900"
 118                         ;;
 119   mips64vr43*-*-*)      sim_gen=IGEN
 120                         sim_igen_machine="-M mipsIV"
 121                         sim_mach_default="mips8000"
 122                         ;;
 123   mips64vr5*-*-*)       sim_gen=IGEN
 124                         sim_igen_machine="-M vr5000"
 125                         sim_mach_default="mips5000"
 126                         ;;
 127   mips64vr41*)          sim_gen=M16
 128                         sim_igen_machine="-M vr4100"
 129                         sim_m16_machine="-M vr4100"
 130                         sim_igen_filter="32,64,f"
 131                         sim_m16_filter="16"
 132                         sim_mach_default="mips4100"
 133                         ;;
 134   mips64vr-*-* | mips64vrel-*-*)
 135                         sim_gen=MULTI
 136                         sim_multi_configs="\
 137                           vr4100:mipsIII,mips16,vr4100:32,64:mips4100,mips4111\
 138                           vr4120:mipsIII,mips16,vr4120:32,64:mips4120\
 139                           vr5000:mipsIV:32,64,f:mips4300,mips5000\
 140                           vr5400:mipsIV,vr5400:32,64,f:mips5400\
 141                           vr5500:mipsIV,vr5500:32,64,f:mips5500"
 142                         sim_multi_default=mips5000
 143                         ;;
 144   mips*-sde-elf*)       sim_gen=M16
 145                         sim_igen_machine="-M mips64r2,mips3d,mips16,mips16e,mdmx,dsp,smartmips"
 146                         sim_m16_machine="-M mips16,mips16e,mips64r2"
 147                         sim_igen_filter="32,64,f"
 148                         sim_mach_default="mipsisa64r2"
 149                         ;;
 150   mips64*-*-*)          sim_igen_filter="32,64,f"
 151                         sim_gen=IGEN
 152                         ;;
 153   mips16*-*-*)          sim_gen=M16
 154                         sim_igen_filter="32,64,f"
 155                         sim_m16_filter="16"
 156                         ;;
 157   mipsisa32r2*-*-*)     sim_gen=M16
 158                         sim_igen_machine="-M mips32r2,mips16,mips16e,mdmx,dsp,smartmips"
 159                         sim_m16_machine="-M mips16,mips16e,mips32r2"
 160                         sim_igen_filter="32,f"
 161                         sim_mach_default="mipsisa32r2"
 162                         ;;
 163   mipsisa32*-*-*)       sim_gen=M16
 164                         sim_igen_machine="-M mips32,mips16,mips16e,smartmips"
 165                         sim_m16_machine="-M mips16,mips16e,mips32"
 166                         sim_igen_filter="32,f"
 167                         sim_mach_default="mipsisa32"
 168                         ;;
 169   mipsisa64r2*-*-*)     sim_gen=M16
 170                         sim_igen_machine="-M mips64r2,mips3d,mips16,mips16e,mdmx,dsp"
 171                         sim_m16_machine="-M mips16,mips16e,mips64r2"
 172                         sim_igen_filter="32,64,f"
 173                         sim_mach_default="mipsisa64r2"
 174                         ;;
 175   mipsisa64sb1*-*-*)    sim_gen=IGEN
 176                         sim_igen_machine="-M mips64,mips3d,sb1"
 177                         sim_igen_filter="32,64,f"
 178                         sim_mach_default="mips_sb1"
 179                         ;;
 180   mipsisa64*-*-*)       sim_gen=M16
 181                         sim_igen_machine="-M mips64,mips3d,mips16,mips16e,mdmx"
 182                         sim_m16_machine="-M mips16,mips16e,mips64"
 183                         sim_igen_filter="32,64,f"
 184                         sim_mach_default="mipsisa64"
 185                         ;;
 186   mips*lsi*)            sim_gen=M16
 187                         sim_igen_machine="-M mipsIII,mips16"
 188                         sim_m16_machine="-M mips16,mipsIII"
 189                         sim_igen_filter="32,f"
 190                         sim_m16_filter="16"
 191                         sim_mach_default="mips4000"
 192                         ;;
 193   mips*-*-*)            sim_gen=IGEN
 194                         sim_igen_filter="32,f"
 195                         ;;
 196 esac
 197
 198 # The MULTI generator can combine several simulation engines into one.
 199 # executable.  A configuration which uses the MULTI should set two
 200 # variables: ${sim_multi_configs} and ${sim_multi_default}.
 201 #
 202 # ${sim_multi_configs} is the list of engines to build.  Each
 203 # space-separated entry has the form NAME:MACHINE:FILTER:BFDMACHS,
 204 # where:
 205 #
 206 # - NAME is a C-compatible prefix for the engine,
 207 # - MACHINE is a -M argument,
 208 # - FILTER is a -F argument, and
 209 # - BFDMACHS is a comma-separated list of bfd machines that the
 210 #     simulator can run.
 211 #
 212 # Each entry will have a separate simulation engine whose prefix is
 213 # m32<NAME>.  If the machine list includes "mips16", there will also
 214 # be a mips16 engine, prefix m16<NAME>.  The mips16 engine will be
 215 # generated using the same machine list as the 32-bit version,
 216 # but the filter will be "16" instead of FILTER.
 217 #
 218 # The simulator compares the bfd mach against BFDMACHS to decide
 219 # which engine to use.  Entries in BFDMACHS should be bfd_mach
 220 # values with "bfd_mach_" removed.  ${sim_multi_default} says
 221 # which entry should be the default.
 222 if test ${sim_gen} = MULTI; then
 223
 224   # Simple sanity check.
 225   if test -z "${sim_multi_configs}" || test -z "${sim_multi_default}"; then
 226     AC_MSG_ERROR(Error in configure.in: MULTI simulator not set up correctly)
 227   fi
 228
 229   # Start in a known state.
 230   rm -f multi-include.h multi-run.c
 231   sim_multi_flags=
 232   sim_multi_src=
 233   sim_multi_obj=multi-run.o
 234   sim_multi_igen_configs=
 235   sim_seen_default=no
 236
 237   cat << __EOF__ > multi-run.c
 238 /* Main entry point for MULTI simulators.
 239    Copyright (C) 2003 Free Software Foundation, Inc.
 240
 241    This program is free software; you can redistribute it and/or modify
 242    it under the terms of the GNU General Public License as published by
 243    the Free Software Foundation; either version 2 of the License, or
 244    (at your option) any later version.
 245
 246    This program is distributed in the hope that it will be useful,
 247    but WITHOUT ANY WARRANTY; without even the implied warranty of
 248    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
 249    GNU General Public License for more details.
 250
 251    You should have received a copy of the GNU General Public License
 252    along with this program; if not, write to the Free Software
 253    Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
 254
 255    --
 256
 257    This file was generated by sim/mips/configure.  */
 258
 259 #include "sim-main.h"
 260 #include "multi-include.h"
 261
 262 #define SD sd
 263 #define CPU cpu
 264
 265 void
 266 sim_engine_run (SIM_DESC sd,
 267                 int next_cpu_nr,
 268                 int nr_cpus,
 269                 int signal) /* ignore */
 270 {
 271   int mach;
 272
 273   if (STATE_ARCHITECTURE (sd) == NULL)
 274     mach = bfd_mach_${sim_multi_default};
 275   else
 276     mach = STATE_ARCHITECTURE (SD)->mach;
 277
 278   switch (mach)
 279     {
 280 __EOF__
 281
 282   for fc in ${sim_multi_configs}; do
 283
 284     # Split up the entry.  ${c} contains the first three elements.
 285     # Note: outer sqaure brackets are m4 quotes.
 286     c=`echo ${fc} | sed ['s/:[^:]*$//']`
 287     bfdmachs=`echo ${fc} | sed 's/.*://'`
 288     name=`echo ${c} | sed 's/:.*//'`
 289     machine=`echo ${c} | sed 's/.*:\(.*\):.*/\1/'`
 290     filter=`echo ${c} | sed 's/.*://'`
 291
 292     # Build the following lists:
 293     #
 294     #   sim_multi_flags: all -M and -F flags used by the simulator
 295     #   sim_multi_src: all makefile-generated source files
 296     #   sim_multi_obj: the objects for ${sim_multi_src}
 297     #   sim_multi_igen_configs: igen configuration strings.
 298     #
 299     # Each entry in ${sim_multi_igen_configs} is a prefix (m32
 300     # or m16) followed by the NAME, MACHINE and FILTER part of
 301     # the ${sim_multi_configs} entry.
 302     sim_multi_flags="${sim_multi_flags} -F ${filter} -M ${machine}"
 303
 304     # Check whether mips16 handling is needed.
 305     case ${c} in
 306       *:*mips16*:*)
 307         # Run igen twice, once for normal mode and once for mips16.
 308         ws="m32 m16"
 309
 310         # The top-level function for the mips16 simulator is
 311         # in a file m16${name}_run.c, generated by the
 312         # tmp-run-multi Makefile rule.
 313         sim_multi_src="${sim_multi_src} m16${name}_run.c"
 314         sim_multi_obj="${sim_multi_obj} m16${name}_run.o"
 315         sim_multi_flags="${sim_multi_flags} -F 16"
 316         ;;
 317       *)
 318         ws=m32
 319         ;;
 320     esac
 321
 322     # Now add the list of igen-generated files to ${sim_multi_src}
 323     # and ${sim_multi_obj}.
 324     for w in ${ws}; do
 325       for base in engine icache idecode model semantics support; do
 326         sim_multi_src="${sim_multi_src} ${w}${name}_${base}.c"
 327         sim_multi_src="${sim_multi_src} ${w}${name}_${base}.h"
 328         sim_multi_obj="${sim_multi_obj} ${w}${name}_${base}.o"
 329       done
 330       sim_multi_igen_configs="${sim_multi_igen_configs} ${w}${c}"
 331     done
 332
 333     # Add an include for the engine.h file.  This file declares the
 334     # top-level foo_engine_run() function.
 335     echo "#include \"${w}${name}_engine.h\"" >> multi-include.h
 336
 337     # Add case statements for this engine to sim_engine_run().
 338     for mach in `echo ${bfdmachs} | sed 's/,/ /g'`; do
 339       echo "    case bfd_mach_${mach}:" >> multi-run.c
 340       if test ${mach} = ${sim_multi_default}; then
 341         echo "    default:" >> multi-run.c
 342         sim_seen_default=yes
 343       fi
 344     done
 345     echo "      ${w}${name}_engine_run (sd, next_cpu_nr, nr_cpus, signal);" \
 346       >> multi-run.c
 347     echo "      break;" >> multi-run.c
 348   done
 349
 350   # Check whether we added a 'default:' label.
 351   if test ${sim_seen_default} = no; then
 352     AC_MSG_ERROR(Error in configure.in: \${sim_multi_configs} doesn't have an entry for \${sim_multi_default})
 353   fi
 354
 355   cat << __EOF__ >> multi-run.c
 356     }
 357 }
 358
 359 int
 360 mips_mach_multi (SIM_DESC sd)
 361 {
 362   if (STATE_ARCHITECTURE (sd) == NULL)
 363     return bfd_mach_${sim_multi_default};
 364
 365   switch (STATE_ARCHITECTURE (SD)->mach)
 366     {
 367 __EOF__
 368
 369   # Add case statements for this engine to mips_mach_multi().
 370   for fc in ${sim_multi_configs}; do
 371
 372     # Split up the entry.  ${c} contains the first three elements.
 373     # Note: outer sqaure brackets are m4 quotes.
 374     c=`echo ${fc} | sed ['s/:[^:]*$//']`
 375     bfdmachs=`echo ${fc} | sed 's/.*://'`
 376
 377     for mach in `echo ${bfdmachs} | sed 's/,/ /g'`; do
 378       echo "    case bfd_mach_${mach}:" >> multi-run.c
 379     done
 380   done
 381
 382   cat << __EOF__ >> multi-run.c
 383       return (STATE_ARCHITECTURE (SD)->mach);
 384     default:
 385       return bfd_mach_${sim_multi_default};
 386     }
 387 }
 388 __EOF__
 389
 390   SIM_SUBTARGET="$SIM_SUBTARGET -DMIPS_MACH_MULTI"
 391 else
 392   # For clean-extra
 393   sim_multi_src=doesnt-exist.c
 394
 395   if test x"${sim_mach_default}" = x""; then
 396     AC_MSG_ERROR(Error in configure.in: \${sim_mach_default} not defined)
 397   fi
 398   SIM_SUBTARGET="$SIM_SUBTARGET -DMIPS_MACH_DEFAULT=bfd_mach_${sim_mach_default}"
 399 fi
 400 sim_igen_flags="-F ${sim_igen_filter} ${sim_igen_machine} ${sim_igen_smp}"
 401 sim_m16_flags=" -F ${sim_m16_filter}  ${sim_m16_machine}  ${sim_igen_smp}"
 402 AC_SUBST(sim_igen_flags)
 403 AC_SUBST(sim_m16_flags)
 404 AC_SUBST(sim_gen)
 405 AC_SUBST(sim_multi_flags)
 406 AC_SUBST(sim_multi_igen_configs)
 407 AC_SUBST(sim_multi_src)
 408 AC_SUBST(sim_multi_obj)
 409
 410
 411 #
 412 # Add simulated hardware devices
 413 #
 414 hw_enabled=no
 415 case "${target}" in
 416   mips*tx39*)
 417         hw_enabled=yes
 418         hw_extra_devices="tx3904cpu tx3904irc tx3904tmr tx3904sio"
 419         mips_extra_objs="dv-sockser.o"
 420         SIM_SUBTARGET="$SIM_SUBTARGET -DTARGET_TX3904=1"
 421         ;;
 422   *)
 423         mips_extra_objs=""
 424         ;;
 425 esac
 426 SIM_AC_OPTION_HARDWARE($hw_enabled,$hw_devices,$hw_extra_devices)
 427 AC_SUBST(mips_extra_objs)
 428
 429
 430 # Choose simulator engine
 431 case "${target}" in
 432   *)    mips_igen_engine="engine.o"
 433         ;;
 434 esac
 435 AC_SUBST(mips_igen_engine)
 436
 437
 438 AC_PATH_X
 439 mips_extra_libs=""
 440 AC_SUBST(mips_extra_libs)
 441
 442 AC_CHECK_HEADERS(string.h strings.h stdlib.h stdlib.h)
 443 AC_CHECK_LIB(m, fabs)
 444 AC_CHECK_FUNCS(aint anint sqrt)
 445
 446 SIM_AC_OUTPUT