src/import/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4 #
   5 # systemd is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU Lesser General Public License as published by
   7 # the Free Software Foundation; either version 2.1 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # systemd is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
  13 # Lesser General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU Lesser General Public License
  16 # along with systemd; If not, see <http://www.gnu.org/licenses/>.
  17
  18 systemd_importd_sources = files('''
  19         importd.c
  20 '''.split())
  21
  22 systemd_pull_sources = files('''
  23         pull.c
  24         pull-raw.c
  25         pull-raw.h
  26         pull-tar.c
  27         pull-tar.h
  28         pull-job.c
  29         pull-job.h
  30         pull-common.c
  31         pull-common.h
  32         import-common.c
  33         import-common.h
  34         import-compress.c
  35         import-compress.h
  36         curl-util.c
  37         curl-util.h
  38         qcow2-util.c
  39         qcow2-util.h
  40 '''.split())
  41
  42 systemd_import_sources = files('''
  43         import.c
  44         import-raw.c
  45         import-raw.h
  46         import-tar.c
  47         import-tar.h
  48         import-common.c
  49         import-common.h
  50         import-compress.c
  51         import-compress.h
  52         qcow2-util.c
  53         qcow2-util.h
  54 '''.split())
  55
  56 systemd_export_sources = files('''
  57         export.c
  58         export-tar.c
  59         export-tar.h
  60         export-raw.c
  61         export-raw.h
  62         import-common.c
  63         import-common.h
  64         import-compress.c
  65         import-compress.h
  66 '''.split())
  67
  68 if conf.get('ENABLE_IMPORTD') == 1
  69         install_data('org.freedesktop.import1.conf',
  70                      install_dir : dbuspolicydir)
  71         install_data('org.freedesktop.import1.service',
  72                      install_dir : dbussystemservicedir)
  73
  74         i18n.merge_file(
  75                 'org.freedesktop.import1.policy',
  76                 input : 'org.freedesktop.import1.policy.in',
  77                 output : 'org.freedesktop.import1.policy',
  78                 po_dir : po_dir,
  79                 data_dirs : po_dir,
  80                 install : install_polkit,
  81                 install_dir : polkitpolicydir)
  82
  83         install_data('import-pubring.gpg',
  84                      install_dir : rootlibexecdir)
  85         # TODO: shouldn't this be in pkgdatadir?
  86 endif
  87
  88 tests += [
  89         [['src/import/test-qcow2.c',
  90           'src/import/qcow2-util.c',
  91           'src/import/qcow2-util.h'],
  92          [libshared],
  93          [libz],
  94          'HAVE_ZLIB', 'manual'],
  95 ]