src/journal-remote/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2
   3 systemd_journal_upload_sources = files('''
   4         journal-upload.h
   5         journal-upload.c
   6         journal-upload-journal.c
   7 '''.split())
   8
   9 libsystemd_journal_remote_sources = files('''
  10         journal-remote-parse.h
  11         journal-remote-parse.c
  12         journal-remote-write.h
  13         journal-remote-write.c
  14         journal-remote.h
  15         journal-remote.c
  16 '''.split())
  17
  18 if conf.get('HAVE_MICROHTTPD') == 1
  19         libsystemd_journal_remote_sources += files('''
  20                 microhttpd-util.h
  21                 microhttpd-util.c
  22 '''.split())
  23 endif
  24
  25 libsystemd_journal_remote = static_library(
  26         'systemd-journal-remote',
  27         libsystemd_journal_remote_sources,
  28         include_directories : includes,
  29         dependencies : [threads,
  30                         libmicrohttpd,
  31                         libgnutls,
  32                         libxz,
  33                         liblz4],
  34         install : false)
  35
  36 systemd_journal_remote_sources = files('''
  37         journal-remote-main.c
  38 '''.split())
  39
  40 systemd_journal_gatewayd_sources = files('''
  41         journal-gatewayd.c
  42         microhttpd-util.h
  43         microhttpd-util.c
  44 '''.split())
  45
  46 if conf.get('ENABLE_REMOTE') ==1 and conf.get('HAVE_LIBCURL') == 1
  47         journal_upload_conf = configure_file(
  48                 input : 'journal-upload.conf.in',
  49                 output : 'journal-upload.conf',
  50                 configuration : substs)
  51         install_data(journal_upload_conf,
  52                      install_dir : pkgsysconfdir)
  53 endif
  54
  55 if conf.get('ENABLE_REMOTE') == 1 and conf.get('HAVE_MICROHTTPD') == 1
  56         journal_remote_conf = configure_file(
  57                 input : 'journal-remote.conf.in',
  58                 output : 'journal-remote.conf',
  59                 configuration : substs)
  60         install_data(journal_remote_conf,
  61                      install_dir : pkgsysconfdir)
  62
  63         install_data('browse.html',
  64                      install_dir : join_paths(pkgdatadir, 'gatewayd'))
  65
  66         if get_option('create-log-dirs')
  67                 meson.add_install_script('sh', '-c',
  68                                          mkdir_p.format('/var/log/journal/remote'))
  69                 meson.add_install_script('sh', '-c',
  70                                          '''chown 0:0 $DESTDIR/var/log/journal/remote &&
  71                                             chmod 755 $DESTDIR/var/log/journal/remote || :''')
  72         endif
  73 endif