src/libsystemd/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 sd_journal_sources = files(
   4         'sd-journal/audit-type.c',
   5         'sd-journal/catalog.c',
   6         'sd-journal/journal-file.c',
   7         'sd-journal/journal-send.c',
   8         'sd-journal/journal-vacuum.c',
   9         'sd-journal/journal-verify.c',
  10         'sd-journal/lookup3.c',
  11         'sd-journal/mmap-cache.c',
  12         'sd-journal/sd-journal.c',
  13 )
  14
  15 if conf.get('HAVE_GCRYPT') == 1
  16         sd_journal_sources += files(
  17                 'sd-journal/fsprg.c',
  18                 'sd-journal/journal-authenticate.c',
  19         )
  20 endif
  21
  22 audit_type_includes = [config_h,
  23                        missing_audit_h,
  24                        'linux/audit.h']
  25 if conf.get('HAVE_AUDIT') == 1
  26         audit_type_includes += 'libaudit.h'
  27 endif
  28
  29 generate_audit_type_list = find_program('sd-journal/generate-audit_type-list.sh')
  30 audit_type_list_txt = custom_target(
  31         'audit_type-list.txt',
  32         output : 'audit_type-list.txt',
  33         command : [generate_audit_type_list, cpp] + audit_type_includes,
  34         capture : true)
  35
  36 audit_type_to_name = custom_target(
  37         'audit_type-to-name.h',
  38         input : ['sd-journal/audit_type-to-name.awk', audit_type_list_txt],
  39         output : 'audit_type-to-name.h',
  40         command : [awk, '-f', '@INPUT0@', '@INPUT1@'],
  41         capture : true)
  42
  43 sd_journal_sources += [audit_type_to_name]
  44
  45 ############################################################
  46
  47 id128_sources = files(
  48         'sd-id128/id128-util.c',
  49         'sd-id128/sd-id128.c',
  50 )
  51
  52 ############################################################
  53
  54 sd_daemon_sources = files('sd-daemon/sd-daemon.c')
  55
  56 ############################################################
  57
  58 sd_event_sources = files(
  59         'sd-event/event-util.c',
  60         'sd-event/sd-event.c',
  61 )
  62
  63 ############################################################
  64
  65 sd_login_sources = files('sd-login/sd-login.c')
  66
  67 ############################################################
  68
  69 libsystemd_sources = files(
  70         'sd-bus/bus-common-errors.c',
  71         'sd-bus/bus-container.c',
  72         'sd-bus/bus-control.c',
  73         'sd-bus/bus-convenience.c',
  74         'sd-bus/bus-creds.c',
  75         'sd-bus/bus-dump.c',
  76         'sd-bus/bus-error.c',
  77         'sd-bus/bus-internal.c',
  78         'sd-bus/bus-introspect.c',
  79         'sd-bus/bus-kernel.c',
  80         'sd-bus/bus-match.c',
  81         'sd-bus/bus-message.c',
  82         'sd-bus/bus-objects.c',
  83         'sd-bus/bus-signature.c',
  84         'sd-bus/bus-slot.c',
  85         'sd-bus/bus-socket.c',
  86         'sd-bus/bus-track.c',
  87         'sd-bus/bus-type.c',
  88         'sd-bus/sd-bus.c',
  89         'sd-device/device-enumerator.c',
  90         'sd-device/device-filter.c',
  91         'sd-device/device-monitor.c',
  92         'sd-device/device-private.c',
  93         'sd-device/device-util.c',
  94         'sd-device/sd-device.c',
  95         'sd-hwdb/sd-hwdb.c',
  96         'sd-netlink/netlink-genl.c',
  97         'sd-netlink/netlink-message-nfnl.c',
  98         'sd-netlink/netlink-message-rtnl.c',
  99         'sd-netlink/netlink-message.c',
 100         'sd-netlink/netlink-slot.c',
 101         'sd-netlink/netlink-socket.c',
 102         'sd-netlink/netlink-types-genl.c',
 103         'sd-netlink/netlink-types-nfnl.c',
 104         'sd-netlink/netlink-types-rtnl.c',
 105         'sd-netlink/netlink-types.c',
 106         'sd-netlink/netlink-util.c',
 107         'sd-netlink/sd-netlink.c',
 108         'sd-network/network-util.c',
 109         'sd-network/sd-network.c',
 110         'sd-path/sd-path.c',
 111         'sd-resolve/sd-resolve.c',
 112 ) + sd_journal_sources + id128_sources + sd_daemon_sources + sd_event_sources + sd_login_sources
 113
 114
 115 libsystemd_c_args = ['-fvisibility=default']
 116
 117 libsystemd_static = static_library(
 118         'systemd_static',
 119         libsystemd_sources,
 120         include_directories : libsystemd_includes,
 121         c_args : libsystemd_c_args,
 122         link_with : [libbasic,
 123                      libbasic_compress],
 124         dependencies : [threads,
 125                         librt],
 126         build_by_default : false)
 127
 128 libsystemd_sym = files('libsystemd.sym')
 129 libsystemd_sym_path = meson.current_source_dir() / 'libsystemd.sym'
 130
 131 static_libsystemd = get_option('static-libsystemd')
 132 static_libsystemd_pic = static_libsystemd == 'true' or static_libsystemd == 'pic'
 133
 134 libsystemd_pc = custom_target(
 135         'libsystemd.pc',
 136         input : 'libsystemd.pc.in',
 137         output : 'libsystemd.pc',
 138         command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
 139         install : pkgconfiglibdir != 'no',
 140         install_tag : 'devel',
 141         install_dir : pkgconfiglibdir)
 142
 143 ############################################################
 144
 145 simple_tests += files(
 146         'sd-journal/test-audit-type.c',
 147         'sd-journal/test-catalog.c',
 148         'sd-journal/test-journal-file.c',
 149         'sd-journal/test-journal-init.c',
 150         'sd-journal/test-journal-match.c',
 151         'sd-journal/test-journal-send.c',
 152         'sd-journal/test-mmap-cache.c',
 153 )
 154
 155 tests += [
 156         [files('sd-journal/test-journal-enum.c'),
 157          [], [], [], '', 'timeout=360'],
 158 ]
 159
 160 ############################################################
 161
 162 simple_tests += files(
 163         'sd-bus/test-bus-creds.c',
 164         'sd-bus/test-bus-introspect.c',
 165         'sd-bus/test-bus-match.c',
 166         'sd-bus/test-bus-vtable.c',
 167         'sd-device/test-device-util.c',
 168         'sd-device/test-sd-device-monitor.c',
 169         'sd-device/test-sd-device.c',
 170         'sd-event/test-event.c',
 171         'sd-login/test-login.c',
 172         'sd-netlink/test-netlink.c',
 173 )
 174
 175 tests += [
 176         [files('sd-bus/test-bus-address.c'),
 177          [],
 178          [threads]],
 179
 180         [files('sd-bus/test-bus-marshal.c'),
 181          [],
 182          [threads,
 183           libglib,
 184           libgobject,
 185           libgio,
 186           libdbus,
 187           libm]],
 188
 189         [files('sd-bus/test-bus-signature.c'),
 190          [],
 191          [threads]],
 192
 193         [files('sd-bus/test-bus-queue-ref-cycle.c'),
 194          [],
 195          [threads]],
 196
 197         [files('sd-bus/test-bus-watch-bind.c'),
 198          [],
 199          [threads],
 200          [], '', 'timeout=120'],
 201
 202         [files('sd-bus/test-bus-chat.c'),
 203          [],
 204          [threads]],
 205
 206         [files('sd-bus/test-bus-cleanup.c'),
 207          [],
 208          [threads,
 209           libseccomp]],
 210
 211         [files('sd-bus/test-bus-track.c'),
 212          [],
 213          [libseccomp]],
 214
 215         [files('sd-bus/test-bus-server.c'),
 216          [],
 217          [threads]],
 218
 219         [files('sd-bus/test-bus-objects.c'),
 220          [],
 221          [threads]],
 222
 223         [files('sd-bus/test-bus-benchmark.c'),
 224          [],
 225          [threads],
 226          [], '', 'manual'],
 227
 228         [files('sd-resolve/test-resolve.c'),
 229          [],
 230          [threads],
 231          [], '', 'timeout=120'],
 232 ]
 233
 234 if cxx_cmd != ''
 235         simple_tests += files('sd-bus/test-bus-vtable-cc.cc')
 236 endif
 237
 238 ############################################################
 239
 240 fuzzers += [
 241         [files('sd-bus/fuzz-bus-message.c')],
 242
 243         [files('sd-bus/fuzz-bus-match.c')],
 244 ]