src/libsystemd/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1-or-later
   2
   3 sd_journal_sources = files(
   4         'sd-journal/audit-type.c',
   5         'sd-journal/audit-type.h',
   6         'sd-journal/catalog.c',
   7         'sd-journal/catalog.h',
   8         'sd-journal/journal-def.h',
   9         'sd-journal/journal-file.c',
  10         'sd-journal/journal-file.h',
  11         'sd-journal/journal-internal.h',
  12         'sd-journal/journal-send.c',
  13         'sd-journal/journal-send.h',
  14         'sd-journal/journal-vacuum.c',
  15         'sd-journal/journal-vacuum.h',
  16         'sd-journal/journal-verify.c',
  17         'sd-journal/journal-verify.h',
  18         'sd-journal/lookup3.c',
  19         'sd-journal/lookup3.h',
  20         'sd-journal/mmap-cache.c',
  21         'sd-journal/mmap-cache.h',
  22         'sd-journal/sd-journal.c',
  23 )
  24
  25 if conf.get('HAVE_GCRYPT') == 1
  26         sd_journal_sources += files(
  27                 'sd-journal/fsprg.c',
  28                 'sd-journal/fsprg.h',
  29                 'sd-journal/journal-authenticate.c',
  30                 'sd-journal/journal-authenticate.h',
  31         )
  32 endif
  33
  34 audit_type_includes = [config_h,
  35                        missing_audit_h,
  36                        'linux/audit.h']
  37 if conf.get('HAVE_AUDIT') == 1
  38         audit_type_includes += 'libaudit.h'
  39 endif
  40
  41 generate_audit_type_list = find_program('sd-journal/generate-audit_type-list.sh')
  42 audit_type_list_txt = custom_target(
  43         'audit_type-list.txt',
  44         output : 'audit_type-list.txt',
  45         command : [generate_audit_type_list, cpp] + audit_type_includes,
  46         capture : true)
  47
  48 audit_type_to_name = custom_target(
  49         'audit_type-to-name.h',
  50         input : ['sd-journal/audit_type-to-name.awk', audit_type_list_txt],
  51         output : 'audit_type-to-name.h',
  52         command : [awk, '-f', '@INPUT0@', '@INPUT1@'],
  53         capture : true)
  54
  55 sd_journal_sources += [audit_type_to_name]
  56
  57 ############################################################
  58
  59 id128_sources = files(
  60         'sd-id128/id128-util.c',
  61         'sd-id128/id128-util.h',
  62         'sd-id128/sd-id128.c',
  63 )
  64
  65 ############################################################
  66
  67 sd_daemon_sources = files('sd-daemon/sd-daemon.c')
  68
  69 ############################################################
  70
  71 sd_event_sources = files(
  72         'sd-event/event-source.h',
  73         'sd-event/event-util.c',
  74         'sd-event/event-util.h',
  75         'sd-event/sd-event.c',
  76 )
  77
  78 ############################################################
  79
  80 sd_login_sources = files('sd-login/sd-login.c')
  81
  82 ############################################################
  83
  84 libsystemd_sources = files(
  85         'sd-bus/bus-common-errors.c',
  86         'sd-bus/bus-common-errors.h',
  87         'sd-bus/bus-container.c',
  88         'sd-bus/bus-container.h',
  89         'sd-bus/bus-control.c',
  90         'sd-bus/bus-control.h',
  91         'sd-bus/bus-convenience.c',
  92         'sd-bus/bus-creds.c',
  93         'sd-bus/bus-creds.h',
  94         'sd-bus/bus-dump.c',
  95         'sd-bus/bus-dump.h',
  96         'sd-bus/bus-error.c',
  97         'sd-bus/bus-error.h',
  98         'sd-bus/bus-internal.c',
  99         'sd-bus/bus-internal.h',
 100         'sd-bus/bus-introspect.c',
 101         'sd-bus/bus-introspect.h',
 102         'sd-bus/bus-kernel.c',
 103         'sd-bus/bus-kernel.h',
 104         'sd-bus/bus-match.c',
 105         'sd-bus/bus-match.h',
 106         'sd-bus/bus-message.c',
 107         'sd-bus/bus-message.h',
 108         'sd-bus/bus-objects.c',
 109         'sd-bus/bus-objects.h',
 110         'sd-bus/bus-protocol.h',
 111         'sd-bus/bus-signature.c',
 112         'sd-bus/bus-signature.h',
 113         'sd-bus/bus-slot.c',
 114         'sd-bus/bus-slot.h',
 115         'sd-bus/bus-socket.c',
 116         'sd-bus/bus-socket.h',
 117         'sd-bus/bus-track.c',
 118         'sd-bus/bus-track.h',
 119         'sd-bus/bus-type.c',
 120         'sd-bus/bus-type.h',
 121         'sd-bus/sd-bus.c',
 122         'sd-device/device-enumerator-private.h',
 123         'sd-device/device-enumerator.c',
 124         'sd-device/device-filter.c',
 125         'sd-device/device-filter.h',
 126         'sd-device/device-internal.h',
 127         'sd-device/device-monitor-private.h',
 128         'sd-device/device-monitor.c',
 129         'sd-device/device-private.c',
 130         'sd-device/device-private.h',
 131         'sd-device/device-util.c',
 132         'sd-device/device-util.h',
 133         'sd-device/sd-device.c',
 134         'sd-hwdb/hwdb-internal.h',
 135         'sd-hwdb/sd-hwdb.c',
 136         'sd-netlink/netlink-genl.c',
 137         'sd-netlink/netlink-genl.h',
 138         'sd-netlink/netlink-internal.h',
 139         'sd-netlink/netlink-message-nfnl.c',
 140         'sd-netlink/netlink-message-rtnl.c',
 141         'sd-netlink/netlink-message.c',
 142         'sd-netlink/netlink-slot.c',
 143         'sd-netlink/netlink-slot.h',
 144         'sd-netlink/netlink-socket.c',
 145         'sd-netlink/netlink-types-genl.c',
 146         'sd-netlink/netlink-types-internal.h',
 147         'sd-netlink/netlink-types-nfnl.c',
 148         'sd-netlink/netlink-types-rtnl.c',
 149         'sd-netlink/netlink-types.c',
 150         'sd-netlink/netlink-types.h',
 151         'sd-netlink/netlink-util.c',
 152         'sd-netlink/netlink-util.h',
 153         'sd-netlink/sd-netlink.c',
 154         'sd-network/network-util.c',
 155         'sd-network/network-util.h',
 156         'sd-network/sd-network.c',
 157         'sd-path/sd-path.c',
 158         'sd-resolve/resolve-private.h',
 159         'sd-resolve/sd-resolve.c',
 160 ) + sd_journal_sources + id128_sources + sd_daemon_sources + sd_event_sources + sd_login_sources
 161
 162
 163 libsystemd_c_args = ['-fvisibility=default']
 164
 165 libsystemd_static = static_library(
 166         'systemd_static',
 167         libsystemd_sources,
 168         include_directories : libsystemd_includes,
 169         c_args : libsystemd_c_args,
 170         link_with : [libbasic,
 171                      libbasic_compress],
 172         dependencies : [threads,
 173                         librt],
 174         build_by_default : false)
 175
 176 libsystemd_sym = files('libsystemd.sym')
 177 libsystemd_sym_path = meson.current_source_dir() / 'libsystemd.sym'
 178
 179 static_libsystemd = get_option('static-libsystemd')
 180 static_libsystemd_pic = static_libsystemd == 'true' or static_libsystemd == 'pic'
 181
 182 libsystemd_pc = custom_target(
 183         'libsystemd.pc',
 184         input : 'libsystemd.pc.in',
 185         output : 'libsystemd.pc',
 186         command : [jinja2_cmdline, '@INPUT@', '@OUTPUT@'],
 187         install : pkgconfiglibdir != 'no',
 188         install_tag : 'devel',
 189         install_dir : pkgconfiglibdir)
 190
 191 ############################################################
 192
 193 tests += [
 194         [files('sd-journal/test-journal-send.c')],
 195
 196         [files('sd-journal/test-journal-match.c')],
 197
 198         [files('sd-journal/test-journal-enum.c'),
 199          [], [], [], '', 'timeout=360'],
 200
 201         [files('sd-journal/test-journal-init.c')],
 202
 203         [files('sd-journal/test-mmap-cache.c')],
 204
 205         [files('sd-journal/test-catalog.c')],
 206
 207         [files('sd-journal/test-audit-type.c')],
 208 ]
 209
 210 ############################################################
 211
 212 tests += [
 213         [files('sd-bus/test-bus-address.c'),
 214          [],
 215          [threads]],
 216
 217         [files('sd-bus/test-bus-marshal.c'),
 218          [],
 219          [threads,
 220           libglib,
 221           libgobject,
 222           libgio,
 223           libdbus,
 224           libm]],
 225
 226         [files('sd-bus/test-bus-signature.c'),
 227          [],
 228          [threads]],
 229
 230         [files('sd-bus/test-bus-queue-ref-cycle.c'),
 231          [],
 232          [threads]],
 233
 234         [files('sd-bus/test-bus-watch-bind.c'),
 235          [],
 236          [threads],
 237          [], '', 'timeout=120'],
 238
 239         [files('sd-bus/test-bus-chat.c'),
 240          [],
 241          [threads]],
 242
 243         [files('sd-bus/test-bus-cleanup.c'),
 244          [],
 245          [threads,
 246           libseccomp]],
 247
 248         [files('sd-bus/test-bus-track.c'),
 249          [],
 250          [libseccomp]],
 251
 252         [files('sd-bus/test-bus-server.c'),
 253          [],
 254          [threads]],
 255
 256         [files('sd-bus/test-bus-objects.c'),
 257          [],
 258          [threads]],
 259
 260         [files('sd-bus/test-bus-vtable.c',
 261                'sd-bus/test-vtable-data.h')],
 262
 263         [files('sd-bus/test-bus-creds.c')],
 264
 265         [files('sd-bus/test-bus-match.c')],
 266
 267         [files('sd-bus/test-bus-benchmark.c'),
 268          [],
 269          [threads],
 270          [], '', 'manual'],
 271
 272         [files('sd-bus/test-bus-introspect.c',
 273                'sd-bus/test-vtable-data.h')],
 274
 275         [files('sd-event/test-event.c')],
 276
 277         [files('sd-netlink/test-netlink.c')],
 278
 279         [files('sd-resolve/test-resolve.c'),
 280          [],
 281          [threads],
 282          [], '', 'timeout=120'],
 283
 284         [files('sd-login/test-login.c')],
 285
 286         [files('sd-device/test-sd-device.c')],
 287
 288         [files('sd-device/test-device-util.c')],
 289
 290         [files('sd-device/test-sd-device-monitor.c')],
 291 ]
 292
 293 if cxx_cmd != ''
 294         tests += [
 295                 [files('sd-bus/test-bus-vtable-cc.cc')],
 296         ]
 297 endif
 298
 299 ############################################################
 300
 301 fuzzers += [
 302         [files('sd-bus/fuzz-bus-message.c')],
 303
 304         [files('sd-bus/fuzz-bus-match.c')],
 305 ]