src/login/meson.build

   1 # SPDX-License-Identifier: LGPL-2.1+
   2 #
   3 # Copyright 2017 Zbigniew Jędrzejewski-Szmek
   4
   5 systemd_logind_sources = files('''
   6         logind.c
   7         logind.h
   8 '''.split())
   9
  10 logind_gperf_c = custom_target(
  11         'logind_gperf.c',
  12         input : 'logind-gperf.gperf',
  13         output : 'logind-gperf.c',
  14         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  15
  16 liblogind_core_sources = files('''
  17         logind-core.c
  18         logind-device.c
  19         logind-device.h
  20         logind-button.c
  21         logind-button.h
  22         logind-action.c
  23         logind-action.h
  24         logind-seat.c
  25         logind-seat.h
  26         logind-session.c
  27         logind-session.h
  28         logind-session-device.c
  29         logind-session-device.h
  30         logind-user.c
  31         logind-user.h
  32         logind-inhibit.c
  33         logind-inhibit.h
  34         logind-dbus.c
  35         logind-session-dbus.c
  36         logind-seat-dbus.c
  37         logind-user-dbus.c
  38         logind-utmp.c
  39         logind-acl.h
  40 '''.split())
  41
  42 liblogind_core_sources += [logind_gperf_c]
  43
  44 logind_acl_c = files('logind-acl.c')
  45 if conf.get('HAVE_ACL') == 1
  46         liblogind_core_sources += logind_acl_c
  47 endif
  48
  49 liblogind_core = static_library(
  50         'logind-core',
  51         liblogind_core_sources,
  52         include_directories : includes,
  53         dependencies : [libacl])
  54
  55 loginctl_sources = files('''
  56         loginctl.c
  57         sysfs-show.h
  58         sysfs-show.c
  59 '''.split())
  60
  61 user_runtime_dir_sources = files('''
  62         user-runtime-dir.c
  63         logind.h
  64 '''.split())
  65
  66 if conf.get('ENABLE_LOGIND') == 1
  67         logind_conf = configure_file(
  68                 input : 'logind.conf.in',
  69                 output : 'logind.conf',
  70                 configuration : substs)
  71         install_data(logind_conf,
  72                      install_dir : pkgsysconfdir)
  73
  74         pam_systemd_sym = 'src/login/pam_systemd.sym'
  75         pam_systemd_c = files('pam_systemd.c')
  76
  77         install_data('org.freedesktop.login1.conf',
  78                      install_dir : dbuspolicydir)
  79         install_data('org.freedesktop.login1.service',
  80                      install_dir : dbussystemservicedir)
  81         install_data('org.freedesktop.login1.policy',
  82                      install_dir : polkitpolicydir)
  83
  84         install_data('70-power-switch.rules', install_dir : udevrulesdir)
  85
  86         if conf.get('HAVE_ACL') == 1
  87                 install_data('70-uaccess.rules', install_dir : udevrulesdir)
  88         endif
  89
  90         seat_rules = configure_file(
  91                 input : '71-seat.rules.in',
  92                 output : '71-seat.rules',
  93                 configuration : substs)
  94         install_data(seat_rules,
  95                      install_dir : udevrulesdir)
  96
  97         custom_target(
  98                 '73-seat-late.rules',
  99                 input : '73-seat-late.rules.m4',
 100                 output: '73-seat-late.rules',
 101                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
 102                 capture : true,
 103                 install : true,
 104                 install_dir : udevrulesdir)
 105
 106         custom_target(
 107                 'systemd-user',
 108                 input : 'systemd-user.m4',
 109                 output: 'systemd-user',
 110                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
 111                 capture : true,
 112                 install : pamconfdir != 'no',
 113                 install_dir : pamconfdir)
 114 endif