src/login/meson.build

   1 systemd_logind_sources = files('''
   2         logind.c
   3         logind.h
   4 '''.split())
   5
   6 logind_gperf_c = custom_target(
   7         'logind_gperf.c',
   8         input : 'logind-gperf.gperf',
   9         output : 'logind-gperf.c',
  10         command : [gperf, '@INPUT@', '--output-file', '@OUTPUT@'])
  11
  12 systemd_logind_sources += [logind_gperf_c]
  13
  14
  15 liblogind_core_sources = files('''
  16         logind-core.c
  17         logind-device.c
  18         logind-device.h
  19         logind-button.c
  20         logind-button.h
  21         logind-action.c
  22         logind-action.h
  23         logind-seat.c
  24         logind-seat.h
  25         logind-session.c
  26         logind-session.h
  27         logind-session-device.c
  28         logind-session-device.h
  29         logind-user.c
  30         logind-user.h
  31         logind-inhibit.c
  32         logind-inhibit.h
  33         logind-dbus.c
  34         logind-session-dbus.c
  35         logind-seat-dbus.c
  36         logind-user-dbus.c
  37         logind-utmp.c
  38         logind-acl.h
  39 '''.split())
  40
  41 logind_acl_c = files('logind-acl.c')
  42 if conf.get('HAVE_ACL') == 1
  43         liblogind_core_sources += logind_acl_c
  44 endif
  45
  46 liblogind_core = static_library(
  47         'logind-core',
  48         liblogind_core_sources,
  49         include_directories : includes,
  50         dependencies : [libacl])
  51
  52 loginctl_sources = files('''
  53         loginctl.c
  54         sysfs-show.h
  55         sysfs-show.c
  56 '''.split())
  57
  58 if conf.get('ENABLE_LOGIND') == 1
  59         logind_conf = configure_file(
  60                 input : 'logind.conf.in',
  61                 output : 'logind.conf',
  62                 configuration : substs)
  63         install_data(logind_conf,
  64                      install_dir : pkgsysconfdir)
  65
  66         pam_systemd_sym = 'src/login/pam_systemd.sym'
  67         pam_systemd_c = files('pam_systemd.c')
  68
  69         install_data('org.freedesktop.login1.conf',
  70                      install_dir : dbuspolicydir)
  71         install_data('org.freedesktop.login1.service',
  72                      install_dir : dbussystemservicedir)
  73
  74         i18n.merge_file(
  75                 'org.freedesktop.login1.policy',
  76                 input : 'org.freedesktop.login1.policy.in',
  77                 output : 'org.freedesktop.login1.policy',
  78                 po_dir : po_dir,
  79                 data_dirs : po_dir,
  80                 install : install_polkit,
  81                 install_dir : polkitpolicydir)
  82
  83         install_data('70-power-switch.rules',
  84                      '70-uaccess.rules',
  85                      install_dir : udevrulesdir)
  86
  87         foreach file : ['71-seat.rules',
  88                         '73-seat-late.rules']
  89                 gen = configure_file(
  90                         input : file + '.in',
  91                         output : file,
  92                         configuration : substs)
  93                 install_data(gen,
  94                              install_dir : udevrulesdir)
  95         endforeach
  96
  97         custom_target(
  98                 'systemd-user',
  99                 input : 'systemd-user.m4',
 100                 output: 'systemd-user',
 101                 command : [m4, '-P'] + m4_defines + ['@INPUT@'],
 102                 capture : true,
 103                 install : pamconfdir != 'no',
 104                 install_dir : pamconfdir)
 105 endif